qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADCVAR("w_prop_interval");
 362                 BADPREFIX("crypto_");
 363                 BADPREFIX("gameversion_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("g_ctf_captimerecord_");
 366                 BADPREFIX("g_hats_");
 367                 BADPREFIX("g_maplist_");
 368                 BADPREFIX("g_mod_");
 369                 BADPREFIX("g_respawn_");
 370                 BADPREFIX("net_");
 371                 BADPREFIX("notification_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("skill_");
 374                 BADPREFIX("sv_allow_");
 375                 BADPREFIX("sv_cullentities_");
 376                 BADPREFIX("sv_maxidle_");
 377                 BADPREFIX("sv_minigames_");
 378                 BADPREFIX("sv_radio_");
 379                 BADPREFIX("sv_timeout_");
 380                 BADPREFIX("sv_vote_");
 381                 BADPREFIX("timelimit_");
 382
 383                 // allowed changes to server admins (please sync this to server.cfg)
 384                 // vi commands:
 385                 //   :/"impure"/,$d
 386                 //   :g!,^\/\/[^ /],d
 387                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 388                 //   :%!sort
 389                 // yes, this does contain some redundant stuff, don't really care
 390                 BADCVAR("bot_config_file");
 391                 BADCVAR("bot_number");
 392                 BADCVAR("bot_prefix");
 393                 BADCVAR("bot_suffix");
 394                 BADCVAR("capturelimit_override");
 395                 BADCVAR("fraglimit_override");
 396                 BADCVAR("gametype");
 397                 BADCVAR("g_antilag");
 398                 BADCVAR("g_balance_teams");
 399                 BADCVAR("g_balance_teams_prevent_imbalance");
 400                 BADCVAR("g_balance_teams_scorefactor");
 401                 BADCVAR("g_ban_sync_trusted_servers");
 402                 BADCVAR("g_ban_sync_uri");
 403                 BADCVAR("g_buffs");
 404                 BADCVAR("g_ca_teams_override");
 405                 BADCVAR("g_ctf_ignore_frags");
 406                 BADCVAR("g_ctf_leaderboard");
 407                 BADCVAR("g_domination_point_limit");
 408                 BADCVAR("g_domination_teams_override");
 409                 BADCVAR("g_freezetag_teams_override");
 410                 BADCVAR("g_friendlyfire");
 411                 BADCVAR("g_fullbrightitems");
 412                 BADCVAR("g_fullbrightplayers");
 413                 BADCVAR("g_keyhunt_point_limit");
 414                 BADCVAR("g_keyhunt_teams_override");
 415                 BADCVAR("g_lms_lives_override");
 416                 BADCVAR("g_maplist");
 417                 BADCVAR("g_maxplayers");
 418                 BADCVAR("g_mirrordamage");
 419                 BADCVAR("g_nexball_goallimit");
 420                 BADCVAR("g_norecoil");
 421                 BADCVAR("g_physics_clientselect");
 422                 BADCVAR("g_pinata");
 423                 BADCVAR("g_powerups");
 424                 BADCVAR("g_spawnshieldtime");
 425                 BADCVAR("g_start_delay");
 426                 BADCVAR("g_superspectate");
 427                 BADCVAR("g_tdm_teams_override");
 428                 BADCVAR("g_warmup");
 429                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 430                 BADCVAR("hostname");
 431                 BADCVAR("log_file");
 432                 BADCVAR("maxplayers");
 433                 BADCVAR("minplayers");
 434                 BADCVAR("minplayers_per_team");
 435                 BADCVAR("net_address");
 436                 BADCVAR("port");
 437                 BADCVAR("rcon_password");
 438                 BADCVAR("rcon_restricted_commands");
 439                 BADCVAR("rcon_restricted_password");
 440                 BADCVAR("skill");
 441                 BADCVAR("sv_adminnick");
 442                 BADCVAR("sv_autoscreenshot");
 443                 BADCVAR("sv_autotaunt");
 444                 BADCVAR("sv_curl_defaulturl");
 445                 BADCVAR("sv_defaultcharacter");
 446                 BADCVAR("sv_defaultcharacterskin");
 447                 BADCVAR("sv_defaultplayercolors");
 448                 BADCVAR("sv_defaultplayermodel");
 449                 BADCVAR("sv_defaultplayerskin");
 450                 BADCVAR("sv_maxidle");
 451                 BADCVAR("sv_maxrate");
 452                 BADCVAR("sv_motd");
 453                 BADCVAR("sv_public");
 454                 BADCVAR("sv_ready_restart");
 455                 BADCVAR("sv_status_privacy");
 456                 BADCVAR("sv_taunt");
 457                 BADCVAR("sv_vote_call");
 458                 BADCVAR("sv_vote_commands");
 459                 BADCVAR("sv_vote_majority_factor");
 460                 BADCVAR("sv_vote_master");
 461                 BADCVAR("sv_vote_master_commands");
 462                 BADCVAR("sv_vote_master_password");
 463                 BADCVAR("sv_vote_simple_majority_factor");
 464                 BADCVAR("teamplay_mode");
 465                 BADCVAR("timelimit_override");
 466                 BADPREFIX("g_warmup_");
 467                 BADPREFIX("sv_info_");
 468                 BADPREFIX("sv_ready_restart_");
 469
 470                 // mutators that announce themselves properly to the server browser
 471                 BADCVAR("g_instagib");
 472                 BADCVAR("g_new_toys");
 473                 BADCVAR("g_nix");
 474                 BADCVAR("g_grappling_hook");
 475                 BADCVAR("g_jetpack");
 476
 477 #undef BADPRESUFFIX
 478 #undef BADPREFIX
 479 #undef BADCVAR
 480
 481                 if(pureadding)
 482                 {
 483                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 484                         if(strlen(cvar_purechanges) > 16384)
 485                         {
 486                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 487                                 pureadding = 0;
 488                         }
 489                 }
 490                 ++cvar_purechanges_count;
 491                 // WARNING: this variable is used for the server list
 492                 // NEVER dare to skip this code!
 493                 // Hacks to intentionally appearing as "pure server" even though you DO have
 494                 // modified settings may be punished by removal from the server list.
 495                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 496                 // though.
 497         }
 498         buf_del(h);
 499         if(cvar_changes == "")
 500                 cvar_changes = "// this server runs at default server settings\n";
 501         else
 502                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 503         cvar_changes = strzone(cvar_changes);
 504         if(cvar_purechanges == "")
 505                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 506         else
 507                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 508         cvar_purechanges = strzone(cvar_purechanges);
 509 }
 510
 511 entity randomseed;
 512 bool RandomSeed_Send(entity this, entity to, int sf)
 513 {
 514         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 515         WriteShort(MSG_ENTITY, this.cnt);
 516         return true;
 517 }
 518 void RandomSeed_Think(entity this)
 519 {
 520         this.cnt = bound(0, floor(random() * 65536), 65535);
 521         this.nextthink = time + 5;
 522
 523         this.SendFlags |= 1;
 524 }
 525 void RandomSeed_Spawn()
 526 {
 527         randomseed = new_pure(randomseed);
 528         setthink(randomseed, RandomSeed_Think);
 529         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 530
 531         getthink(randomseed)(randomseed); // sets random seed and nextthink
 532 }
 533
 534 spawnfunc(__init_dedicated_server)
 535 {
 536         // handler for _init/_init map (only for dedicated server initialization)
 537
 538         world_initialized = -1; // don't complain
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         delete_fn = remove_unsafely;
 544
 545         entity e = spawn();
 546         setthink(e, GotoFirstMap);
 547         e.nextthink = time; // this is usually 1 at this point
 548
 549         e = new(info_player_deathmatch);  // safeguard against player joining
 550
 551     // assign reflectively to avoid "assignment to world" warning
 552     for (int i = 0, n = numentityfields(); i < n; ++i) {
 553         string k = entityfieldname(i);
 554         if (k == "classname") {
 555             // safeguard against various stuff ;)
 556             putentityfieldstring(i, this, "worldspawn");
 557             break;
 558         }
 559     }
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         static_init_late();
 564         static_init_precache();
 565
 566         IL_PUSH(g_spawnpoints, e); // just incase
 567
 568         MapInfo_Enumerate();
 569         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 570 }
 571
 572 void __init_dedicated_server_shutdown() {
 573         MapInfo_Shutdown();
 574 }
 575
 576 STATIC_INIT_EARLY(maxclients)
 577 {
 578         maxclients = 0;
 579         for (entity head = nextent(NULL); head; head = nextent(head)) {
 580                 ++maxclients;
 581         }
 582 }
 583
 584 void default_delayedinit(entity this)
 585 {
 586         if(!scores_initialized)
 587                 ScoreRules_generic();
 588 }
 589
 590 void InitGameplayMode()
 591 {
 592         VoteReset();
 593
 594         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 595         get_mi_min_max(1);
 596         // assign reflectively to avoid "assignment to world" warning
 597         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 598             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 599             if (v) {
 600             putentityfieldstring(i, world, sprintf("%v", v));
 601             if (++done == 2) break;
 602         }
 603         }
 604         // currently, NetRadiant's limit is 131072 qu for each side
 605         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 606         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 607         // in case somebody makes extremely large maps
 608         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 609
 610         MapInfo_LoadMapSettings(mapname);
 611         GameRules_teams(false);
 612
 613         if (!cvar_value_issafe(world.fog))
 614         {
 615                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 616                 world.fog = string_null;
 617         }
 618         if(MapInfo_Map_fog != "")
 619         {
 620                 if(MapInfo_Map_fog == "none")
 621                         world.fog = string_null;
 622                 else
 623                         world.fog = strzone(MapInfo_Map_fog);
 624         }
 625         clientstuff = strzone(MapInfo_Map_clientstuff);
 626
 627         MapInfo_ClearTemps();
 628
 629         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 630
 631         cache_mutatormsg = strzone("");
 632         cache_lastmutatormsg = strzone("");
 633
 634         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 635 }
 636
 637 void Map_MarkAsRecent(string m);
 638 float world_already_spawned;
 639 spawnfunc(worldspawn)
 640 {
 641         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 642
 643         bool wantrestart = false;
 644         {
 645                 if (!server_is_dedicated)
 646                 {
 647                         // force unloading of server pk3 files when starting a listen server
 648                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 649                         // restore csqc_progname too
 650                         string expect = "csprogs.dat";
 651                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 652                         cvar_set_normal("csqc_progname", expect);
 653                 }
 654                 else
 655                 {
 656                         // Try to use versioned csprogs from pk3
 657                         // Only ever use versioned csprogs.dat files on dedicated servers;
 658                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 659                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 660                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 661                         string select = "csprogs.dat";
 662                         if (fexists(pk3csprogs)) select = pk3csprogs;
 663                         if (cvar_string_normal("csqc_progname") != select)
 664                         {
 665                                 cvar_set_normal("csqc_progname", select);
 666                                 wantrestart = true;
 667                         }
 668                         // Check for updates on startup
 669                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 670                         int sentinel = fopen("progs.txt", FILE_READ);
 671                         if (sentinel >= 0)
 672                         {
 673                                 string switchversion = fgets(sentinel);
 674                                 fclose(sentinel);
 675                                 if (switchversion != "" && switchversion != WATERMARK)
 676                                 {
 677                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 678                                         // if it doesn't exist, assume either:
 679                                         //   a) the current program was overwritten
 680                                         //   b) this is a client only update
 681                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 682                                         if (fexists(newprogs))
 683                                         {
 684                                                 cvar_set_normal("sv_progs", newprogs);
 685                                                 wantrestart = true;
 686                                         }
 687                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 688                                         if (fexists(newcsprogs))
 689                                         {
 690                                                 cvar_set_normal("csqc_progname", newcsprogs);
 691                                                 wantrestart = true;
 692                                         }
 693                                 }
 694                         }
 695                 }
 696                 if (wantrestart)
 697                 {
 698                         LOG_INFO("Restart requested");
 699                         changelevel(mapname);
 700                         // let initialization continue, shutdown depends on it
 701                 }
 702         }
 703
 704         cvar = cvar_normal;
 705         cvar_string = cvar_string_normal;
 706         cvar_set = cvar_set_normal;
 707
 708         if(world_already_spawned)
 709                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 710         world_already_spawned = true;
 711
 712         delete_fn = remove_safely; // during spawning, watch what you remove!
 713
 714         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 715
 716         // needs to be done so early because of the constants they create
 717         static_init();
 718
 719         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 720
 721         TemporaryDB = db_create();
 722
 723         // 0 normal
 724         lightstyle(0, "m");
 725
 726         // 1 FLICKER (first variety)
 727         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 728
 729         // 2 SLOW STRONG PULSE
 730         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 731
 732         // 3 CANDLE (first variety)
 733         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 734
 735         // 4 FAST STROBE
 736         lightstyle(4, "mamamamamama");
 737
 738         // 5 GENTLE PULSE 1
 739         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 740
 741         // 6 FLICKER (second variety)
 742         lightstyle(6, "nmonqnmomnmomomno");
 743
 744         // 7 CANDLE (second variety)
 745         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 746
 747         // 8 CANDLE (third variety)
 748         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 749
 750         // 9 SLOW STROBE (fourth variety)
 751         lightstyle(9, "aaaaaaaazzzzzzzz");
 752
 753         // 10 FLUORESCENT FLICKER
 754         lightstyle(10, "mmamammmmammamamaaamammma");
 755
 756         // 11 SLOW PULSE NOT FADE TO BLACK
 757         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 758
 759         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 760
 761         // 63 testing
 762         lightstyle(63, "a");
 763
 764         if(autocvar_g_campaign)
 765                 CampaignPreInit();
 766
 767         Map_MarkAsRecent(mapname);
 768
 769         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 770
 771         InitGameplayMode();
 772         static_init_late();
 773         static_init_precache();
 774         readlevelcvars();
 775         GrappleHookInit();
 776
 777         GameRules_limit_fallbacks();
 778
 779         if(warmup_limit == 0)
 780                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 781
 782         player_count = 0;
 783         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 784         if(bot_waypoints_for_items == 1)
 785                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 786                         bot_waypoints_for_items = 0;
 787
 788         precache();
 789
 790         WaypointSprite_Init();
 791
 792         GameLogInit(); // prepare everything
 793         // NOTE for matchid:
 794         // changing the logic generating it is okay. But:
 795         // it HAS to stay <= 64 chars
 796         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 797         if(autocvar_sv_eventlog)
 798         {
 799                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 800                 matchid = strzone(s);
 801
 802                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 803                 s = ":gameinfo:mutators:LIST";
 804
 805                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 806                 s = M_ARGV(0, string);
 807
 808                 // initialiation stuff, not good in the mutator system
 809                 if(!autocvar_g_use_ammunition)
 810                         s = strcat(s, ":no_use_ammunition");
 811
 812                 // initialiation stuff, not good in the mutator system
 813                 if(autocvar_g_pickup_items == 0)
 814                         s = strcat(s, ":no_pickup_items");
 815                 if(autocvar_g_pickup_items > 0)
 816                         s = strcat(s, ":pickup_items");
 817
 818                 // initialiation stuff, not good in the mutator system
 819                 if(autocvar_g_weaponarena != "0")
 820                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 821
 822                 // TODO to mutator system
 823                 if(autocvar_g_norecoil)
 824                         s = strcat(s, ":norecoil");
 825
 826                 // TODO to mutator system
 827                 if(autocvar_g_powerups == 0)
 828                         s = strcat(s, ":no_powerups");
 829                 if(autocvar_g_powerups > 0)
 830                         s = strcat(s, ":powerups");
 831
 832                 GameLogEcho(s);
 833                 GameLogEcho(":gameinfo:end");
 834         }
 835         else
 836                 matchid = strzone(ftos(random()));
 837
 838         cvar_set("nextmap", "");
 839
 840         SetDefaultAlpha();
 841
 842         if(autocvar_g_campaign)
 843                 CampaignPostInit();
 844
 845         Ban_LoadBans();
 846
 847         MapInfo_Enumerate();
 848         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 849
 850         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 851         {
 852                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 853                 if(fd != -1)
 854                 {
 855                         string s;
 856                         while((s = fgets(fd)))
 857                         {
 858                                 int l = tokenize_console(s);
 859                                 if(l < 2)
 860                                         continue;
 861                                 if(argv(0) == "cd")
 862                                 {
 863                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 864                                         LOG_INFO("  cdtrack ", argv(2));
 865                                 }
 866                                 else if(argv(0) == "fog")
 867                                 {
 868                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 869                                         LOG_INFO("  \"fog\" \"", s, "\"");
 870                                 }
 871                                 else if(argv(0) == "set")
 872                                 {
 873                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 874                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 875                                 }
 876                                 else if(argv(0) != "//")
 877                                 {
 878                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 879                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 880                                 }
 881                         }
 882                         fclose(fd);
 883                 }
 884         }
 885
 886         WeaponStats_Init();
 887
 888         Nagger_Init();
 889
 890         next_pingtime = time + 5;
 891
 892         // set up information replies for clients and server to use
 893         maplist_reply = strzone(getmaplist());
 894         lsmaps_reply = strzone(getlsmaps());
 895         monsterlist_reply = strzone(getmonsterlist());
 896         for(int i = 0; i < 10; ++i)
 897         {
 898                 string s = getrecords(i);
 899                 if (s)
 900                         records_reply[i] = strzone(s);
 901         }
 902         ladder_reply = strzone(getladder());
 903         rankings_reply = strzone(getrankings());
 904
 905         // begin other init
 906         ClientInit_Spawn();
 907         RandomSeed_Spawn();
 908         PingPLReport_Spawn();
 909
 910         CheatInit();
 911
 912         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 913
 914         // fill sv_curl_serverpackages from .serverpackage files
 915         if (autocvar_sv_curl_serverpackages_auto)
 916         {
 917                 string s = "csprogs-" WATERMARK ".txt";
 918                 // remove automatically managed files from the list to prevent duplicates
 919                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 920                 {
 921                         string pkg = argv(i);
 922                         if (startsWith(pkg, "csprogs-")) continue;
 923                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 924                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 925                         s = cons(s, pkg);
 926                 }
 927                 // add automatically managed files to the list
 928                 #define X(match) MACRO_BEGIN \
 929                         int fd = search_begin(match, true, false); \
 930                         if (fd >= 0) \
 931                         { \
 932                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 933                                 { \
 934                                         s = cons(s, search_getfilename(fd, i)); \
 935                                 } \
 936                                 search_end(fd); \
 937                         } \
 938                 MACRO_END
 939                 X("*-serverpackage.txt");
 940                 X("*.serverpackage");
 941                 #undef X
 942                 cvar_set("sv_curl_serverpackages", s);
 943         }
 944
 945         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 946         modname = "Xonotic";
 947         // physics/balance/config changes that count as mod
 948         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 949                 modname = cvar_string("g_mod_physics");
 950         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 951                 modname = cvar_string("g_mod_balance");
 952         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 953                 modname = cvar_string("g_mod_config");
 954         // extra mutators that deserve to count as mod
 955         MUTATOR_CALLHOOK(SetModname, modname);
 956         modname = M_ARGV(0, string);
 957
 958         // save it for later
 959         modname = strzone(modname);
 960
 961         WinningConditionHelper(this); // set worldstatus
 962
 963         world_initialized = 1;
 964         __spawnfunc_spawn_all();
 965 }
 966
 967 spawnfunc(light)
 968 {
 969         //makestatic (this); // Who the f___ did that?
 970         delete(this);
 971 }
 972
 973 string GetGametype()
 974 {
 975         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 976 }
 977
 978 string GetMapname()
 979 {
 980         return mapname;
 981 }
 982
 983 float Map_Count, Map_Current;
 984 string Map_Current_Name;
 985
 986 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 987 float GetMaplistPosition()
 988 {
 989         float pos, idx;
 990         string map;
 991
 992         map = GetMapname();
 993         idx = autocvar_g_maplist_index;
 994
 995         if(idx >= 0)
 996                 if(idx < Map_Count)
 997                         if(map == argv(idx))
 998                                 return idx;
 999
1000         for(pos = 0; pos < Map_Count; ++pos)
1001                 if(map == argv(pos))
1002                         return pos;
1003
1004         // resume normal maplist rotation if current map is not in g_maplist
1005         return idx;
1006 }
1007
1008 bool MapHasRightSize(string map)
1009 {
1010         int minplayers = max(0, floor(autocvar_minplayers));
1011         if (teamplay)
1012                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1013         if (autocvar_g_maplist_check_waypoints
1014                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1015         {
1016                 string checkwp_msg = strcat("checkwp ", map);
1017                 if(!fexists(strcat("maps/", map, ".waypoints")))
1018                 {
1019                         LOG_TRACE(checkwp_msg, ": no waypoints");
1020                         return false;
1021                 }
1022                 LOG_TRACE(checkwp_msg, ": has waypoints");
1023         }
1024
1025         if(autocvar_g_maplist_ignore_sizes)
1026                 return true;
1027
1028         // open map size restriction file
1029         string opensize_msg = strcat("opensize ", map);
1030         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1031         if(fh >= 0)
1032         {
1033                 opensize_msg = strcat(opensize_msg, ": ok, ");
1034                 int mapmin = stoi(fgets(fh));
1035                 int mapmax = stoi(fgets(fh));
1036                 fclose(fh);
1037                 if(player_count < mapmin)
1038                 {
1039                         LOG_TRACE(opensize_msg, "not enough");
1040                         return false;
1041                 }
1042                 if(mapmax && player_count > mapmax)
1043                 {
1044                         LOG_TRACE(opensize_msg, "too many");
1045                         return false;
1046                 }
1047                 LOG_TRACE(opensize_msg, "right size");
1048                 return true;
1049         }
1050         LOG_TRACE(opensize_msg, ": not found");
1051         return true;
1052 }
1053
1054 string Map_Filename(float position)
1055 {
1056         return strcat("maps/", argv(position), ".bsp");
1057 }
1058
1059 void Map_MarkAsRecent(string m)
1060 {
1061         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1062 }
1063
1064 float Map_IsRecent(string m)
1065 {
1066         return strhasword(autocvar_g_maplist_mostrecent, m);
1067 }
1068
1069 float Map_Check(float position, float pass)
1070 {
1071         string filename;
1072         string map_next;
1073         map_next = argv(position);
1074         if(pass <= 1)
1075         {
1076                 if(Map_IsRecent(map_next))
1077                         return 0;
1078         }
1079         filename = Map_Filename(position);
1080         if(MapInfo_CheckMap(map_next))
1081         {
1082                 if(pass == 2)
1083                         return 1;
1084                 if(MapHasRightSize(map_next))
1085                         return 1;
1086                 return 0;
1087         }
1088         else
1089                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1090
1091         return 0;
1092 }
1093
1094 void Map_Goto_SetStr(string nextmapname)
1095 {
1096         if(getmapname_stored != "")
1097                 strunzone(getmapname_stored);
1098         if(nextmapname == "")
1099                 getmapname_stored = "";
1100         else
1101                 getmapname_stored = strzone(nextmapname);
1102 }
1103
1104 void Map_Goto_SetFloat(float position)
1105 {
1106         cvar_set("g_maplist_index", ftos(position));
1107         Map_Goto_SetStr(argv(position));
1108 }
1109
1110 void Map_Goto(float reinit)
1111 {
1112         MapInfo_LoadMap(getmapname_stored, reinit);
1113 }
1114
1115 // return codes of map selectors:
1116 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1117 //   -2 = permanent failure
1118 float MaplistMethod_Iterate() // usual method
1119 {
1120         float pass, i;
1121
1122         LOG_TRACE("Trying MaplistMethod_Iterate");
1123
1124         for(pass = 1; pass <= 2; ++pass)
1125         {
1126                 for(i = 1; i < Map_Count; ++i)
1127                 {
1128                         float mapindex;
1129                         mapindex = (i + Map_Current) % Map_Count;
1130                         if(Map_Check(mapindex, pass))
1131                                 return mapindex;
1132                 }
1133         }
1134         return -1;
1135 }
1136
1137 float MaplistMethod_Repeat() // fallback method
1138 {
1139         LOG_TRACE("Trying MaplistMethod_Repeat");
1140
1141         if(Map_Check(Map_Current, 2))
1142                 return Map_Current;
1143         return -2;
1144 }
1145
1146 float MaplistMethod_Random() // random map selection
1147 {
1148         float i, imax;
1149
1150         LOG_TRACE("Trying MaplistMethod_Random");
1151
1152         imax = 42;
1153
1154         for(i = 0; i <= imax; ++i)
1155         {
1156                 float mapindex;
1157                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1158                 if(Map_Check(mapindex, 1))
1159                         return mapindex;
1160         }
1161         return -1;
1162 }
1163
1164 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1165 // the exponent sets a bias on the map selection:
1166 // the higher the exponent, the less likely "shortly repeated" same maps are
1167 {
1168         float i, j, imax, insertpos;
1169
1170         LOG_TRACE("Trying MaplistMethod_Shuffle");
1171
1172         imax = 42;
1173
1174         for(i = 0; i <= imax; ++i)
1175         {
1176                 string newlist;
1177
1178                 // now reinsert this at another position
1179                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1180                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1181                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1182                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1183
1184                 // insert the current map there
1185                 newlist = "";
1186                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1187                         newlist = strcat(newlist, " ", argv(j));
1188                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1189                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1190                         newlist = strcat(newlist, " ", argv(j));
1191                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1192                 cvar_set("g_maplist", newlist);
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194
1195                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1196                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1197                 if(Map_Check(Map_Current, 1))
1198                         return Map_Current;
1199         }
1200         return -1;
1201 }
1202
1203 void Maplist_Init()
1204 {
1205         float i = Map_Count = 0;
1206         if(autocvar_g_maplist != "")
1207         {
1208                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1209                 for (i = 0; i < Map_Count; ++i)
1210                 {
1211                         if (Map_Check(i, 2))
1212                                 break;
1213                 }
1214         }
1215
1216         if (i == Map_Count)
1217         {
1218                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1219                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1220                 if(autocvar_g_maplist_shuffle)
1221                         ShuffleMaplist();
1222                 if(!server_is_dedicated)
1223                         localcmd("\nmenu_cmd sync\n");
1224                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1225         }
1226         if(Map_Count == 0)
1227                 error("empty maplist, cannot select a new map");
1228         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1229
1230         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1231         // this may or may not be correct, but who cares, in the worst case a map
1232         // isn't chosen in the first pass that should have been
1233 }
1234
1235 string GetNextMap()
1236 {
1237         float nextMap;
1238
1239         Maplist_Init();
1240         nextMap = -1;
1241
1242         if(nextMap == -1)
1243                 if(autocvar_g_maplist_shuffle > 0)
1244                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1245
1246         if(nextMap == -1)
1247                 if(autocvar_g_maplist_selectrandom)
1248                         nextMap = MaplistMethod_Random();
1249
1250         if(nextMap == -1)
1251                 nextMap = MaplistMethod_Iterate();
1252
1253         if(nextMap == -1)
1254                 nextMap = MaplistMethod_Repeat();
1255
1256         if(nextMap >= 0)
1257         {
1258                 Map_Goto_SetFloat(nextMap);
1259                 return getmapname_stored;
1260         }
1261
1262         return "";
1263 }
1264
1265 float DoNextMapOverride(float reinit)
1266 {
1267         if(autocvar_g_campaign)
1268         {
1269                 CampaignPostIntermission();
1270                 alreadychangedlevel = true;
1271                 return true;
1272         }
1273         if(autocvar_quit_when_empty)
1274         {
1275                 if(player_count <= currentbots)
1276                 {
1277                         localcmd("quit\n");
1278                         alreadychangedlevel = true;
1279                         return true;
1280                 }
1281         }
1282         if(autocvar_quit_and_redirect != "")
1283         {
1284                 redirection_target = strzone(autocvar_quit_and_redirect);
1285                 alreadychangedlevel = true;
1286                 return true;
1287         }
1288         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1289         {
1290                 localcmd("restart\n");
1291                 alreadychangedlevel = true;
1292                 return true;
1293         }
1294         if(autocvar_nextmap != "")
1295         {
1296                 string m;
1297                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1298                 cvar_set("nextmap",m);
1299
1300                 if(!m || gametypevote)
1301                         return false;
1302                 if(autocvar_sv_vote_gametype)
1303                 {
1304                         Map_Goto_SetStr(m);
1305                         return false;
1306                 }
1307
1308                 if(MapInfo_CheckMap(m))
1309                 {
1310                         Map_Goto_SetStr(m);
1311                         Map_Goto(reinit);
1312                         alreadychangedlevel = true;
1313                         return true;
1314                 }
1315         }
1316         if(!reinit && autocvar_lastlevel)
1317         {
1318                 cvar_settemp_restore();
1319                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1320                 alreadychangedlevel = true;
1321                 return true;
1322         }
1323         return false;
1324 }
1325
1326 void GotoNextMap(float reinit)
1327 {
1328         //string nextmap;
1329         //float n, nummaps;
1330         //string s;
1331         if (alreadychangedlevel)
1332                 return;
1333         alreadychangedlevel = true;
1334
1335         string nextMap;
1336
1337         nextMap = GetNextMap();
1338         if(nextMap == "")
1339                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1340         Map_Goto(reinit);
1341 }
1342
1343
1344 /*
1345 ============
1346 IntermissionThink
1347
1348 When the player presses attack or jump, change to the next level
1349 ============
1350 */
1351 .float autoscreenshot;
1352 void IntermissionThink(entity this)
1353 {
1354         FixIntermissionClient(this);
1355
1356         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1357         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1358
1359         if( (server_screenshot || client_screenshot)
1360                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1361         {
1362                 this.autoscreenshot = -1;
1363                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1364                 return;
1365         }
1366
1367         if (time < intermission_exittime)
1368                 return;
1369
1370         if(!mapvote_initialized)
1371                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1372                         return;
1373
1374         MapVote_Start();
1375 }
1376
1377 /*
1378 ============
1379 FindIntermission
1380
1381 Returns the entity to view from
1382 ============
1383 */
1384 /*
1385 entity FindIntermission()
1386 {
1387         local   entity spot;
1388         local   float cyc;
1389
1390 // look for info_intermission first
1391         spot = find(NULL, classname, "info_intermission");
1392         if (spot)
1393         {       // pick a random one
1394                 cyc = random() * 4;
1395                 while (cyc > 1)
1396                 {
1397                         spot = find(spot, classname, "info_intermission");
1398                         if (!spot)
1399                                 spot = find(spot, classname, "info_intermission");
1400                         cyc = cyc - 1;
1401                 }
1402                 return spot;
1403         }
1404
1405 // then look for the start position
1406         spot = find(NULL, classname, "info_player_start");
1407         if (spot)
1408                 return spot;
1409
1410 // testinfo_player_start is only found in regioned levels
1411         spot = find(NULL, classname, "testplayerstart");
1412         if (spot)
1413                 return spot;
1414
1415 // then look for the start position
1416         spot = find(NULL, classname, "info_player_deathmatch");
1417         if (spot)
1418                 return spot;
1419
1420         //objerror ("FindIntermission: no spot");
1421         return NULL;
1422 }
1423 */
1424
1425 /*
1426 ===============================================================================
1427
1428 RULES
1429
1430 ===============================================================================
1431 */
1432
1433 void DumpStats(float final)
1434 {
1435         float file;
1436         string s;
1437         float to_console;
1438         float to_eventlog;
1439         float to_file;
1440         float i;
1441
1442         to_console = autocvar_sv_logscores_console;
1443         to_eventlog = autocvar_sv_eventlog;
1444         to_file = autocvar_sv_logscores_file;
1445
1446         if(!final)
1447         {
1448                 to_console = true; // always print printstats replies
1449                 to_eventlog = false; // but never print them to the event log
1450         }
1451
1452         if(to_eventlog)
1453                 if(autocvar_sv_eventlog_console)
1454                         to_console = false; // otherwise we get the output twice
1455
1456         if(final)
1457                 s = ":scores:";
1458         else
1459                 s = ":status:";
1460         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1461
1462         if(to_console)
1463                 LOG_INFO(s);
1464         if(to_eventlog)
1465                 GameLogEcho(s);
1466
1467         file = -1;
1468         if(to_file)
1469         {
1470                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1471                 if(file == -1)
1472                         to_file = false;
1473                 else
1474                         fputs(file, strcat(s, "\n"));
1475         }
1476
1477         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1478         if(to_console)
1479                 LOG_INFO(s);
1480         if(to_eventlog)
1481                 GameLogEcho(s);
1482         if(to_file)
1483                 fputs(file, strcat(s, "\n"));
1484
1485         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1486                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1487                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1488                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1489                         s = strcat(s, ftos(it.team), ":");
1490                 else
1491                         s = strcat(s, "spectator:");
1492
1493                 if(to_console)
1494                         LOG_INFO(s, playername(it, false));
1495                 if(to_eventlog)
1496                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1497                 if(to_file)
1498                         fputs(file, strcat(s, playername(it, false), "\n"));
1499         });
1500
1501         if(teamplay)
1502         {
1503                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1504                 if(to_console)
1505                         LOG_INFO(s);
1506                 if(to_eventlog)
1507                         GameLogEcho(s);
1508                 if(to_file)
1509                         fputs(file, strcat(s, "\n"));
1510
1511                 for(i = 1; i < 16; ++i)
1512                 {
1513                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1514                         s = strcat(s, ":", ftos(i));
1515                         if(to_console)
1516                                 LOG_INFO(s);
1517                         if(to_eventlog)
1518                                 GameLogEcho(s);
1519                         if(to_file)
1520                                 fputs(file, strcat(s, "\n"));
1521                 }
1522         }
1523
1524         if(to_console)
1525                 LOG_INFO(":end");
1526         if(to_eventlog)
1527                 GameLogEcho(":end");
1528         if(to_file)
1529         {
1530                 fputs(file, ":end\n");
1531                 fclose(file);
1532         }
1533 }
1534
1535 void FixIntermissionClient(entity e)
1536 {
1537         if(!e.autoscreenshot) // initial call
1538         {
1539                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1540                 SetResourceExplicit(e, RES_HEALTH, -2342);
1541                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1542                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1543                 {
1544                     .entity weaponentity = weaponentities[slot];
1545                         if(e.(weaponentity))
1546                         {
1547                                 e.(weaponentity).effects = EF_NODRAW;
1548                                 if (e.(weaponentity).weaponchild)
1549                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1550                         }
1551                 }
1552                 if(IS_REAL_CLIENT(e))
1553                 {
1554                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1555                         RandomSelection_Init();
1556                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1557                                 RandomSelection_AddString(it, 1, 1);
1558                         });
1559                         if (RandomSelection_chosen_string != "")
1560                         {
1561                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1562                         }
1563                         msg_entity = e;
1564                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1565                 }
1566         }
1567 }
1568
1569 /*
1570 go to the next level for deathmatch
1571 only called if a time or frag limit has expired
1572 */
1573 void NextLevel()
1574 {
1575         game_stopped = true;
1576         intermission_running = 1; // game over
1577
1578         // enforce a wait time before allowing changelevel
1579         if(player_count > 0)
1580                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1581         else
1582                 intermission_exittime = -1;
1583
1584         /*
1585         WriteByte (MSG_ALL, SVC_CDTRACK);
1586         WriteByte (MSG_ALL, 3);
1587         WriteByte (MSG_ALL, 3);
1588         // done in FixIntermission
1589         */
1590
1591         //pos = FindIntermission ();
1592
1593         VoteReset();
1594
1595         DumpStats(true);
1596
1597         // send statistics
1598         PlayerStats_GameReport(true);
1599         WeaponStats_Shutdown();
1600
1601         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1602
1603         if(autocvar_sv_eventlog)
1604                 GameLogEcho(":gameover");
1605
1606         GameLogClose();
1607
1608         FOREACH_CLIENT(IS_PLAYER(it), {
1609                 FixIntermissionClient(it);
1610                 if(it.winning)
1611                         bprint(playername(it, false), " ^7wins.\n");
1612         });
1613
1614         target_music_kill();
1615
1616         if(autocvar_g_campaign)
1617                 CampaignPreIntermission();
1618
1619         MUTATOR_CALLHOOK(MatchEnd);
1620
1621         localcmd("\nsv_hook_gameend\n");
1622 }
1623
1624
1625 float InitiateSuddenDeath()
1626 {
1627         // Check first whether normal overtimes could be added before initiating suddendeath mode
1628         // - for this timelimit_overtime needs to be >0 of course
1629         // - also check the winning condition calculated in the previous frame and only add normal overtime
1630         //   again, if at the point at which timelimit would be extended again, still no winner was found
1631         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1632                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1633                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1634         {
1635                 return 1; // need to call InitiateOvertime later
1636         }
1637         else
1638         {
1639                 if(!checkrules_suddendeathend)
1640                 {
1641                         if(autocvar_g_campaign)
1642                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1643                         else
1644                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1645                         if(g_race && !g_race_qualifying)
1646                                 race_StartCompleting();
1647                 }
1648                 return 0;
1649         }
1650 }
1651
1652 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1653 {
1654         ++checkrules_overtimesadded;
1655         //add one more overtime by simply extending the timelimit
1656         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1657         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1658 }
1659
1660 float GetWinningCode(float fraglimitreached, float equality)
1661 {
1662         if(autocvar_g_campaign == 1)
1663         {
1664                 if(fraglimitreached)
1665                         return WINNING_YES;
1666                 else
1667                         return WINNING_NO;
1668         }
1669         else
1670         {
1671                 if(equality)
1672                 {
1673                         if(fraglimitreached)
1674                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1675                         else
1676                                 return WINNING_NEVER;
1677                 }
1678                 else
1679                 {
1680                         if(fraglimitreached)
1681                                 return WINNING_YES;
1682                         else
1683                                 return WINNING_NO;
1684                 }
1685         }
1686 }
1687
1688 // set the .winning flag for exactly those players with a given field value
1689 void SetWinners(.float field, float value)
1690 {
1691         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1692 }
1693
1694 // set the .winning flag for those players with a given field value
1695 void AddWinners(.float field, float value)
1696 {
1697         FOREACH_CLIENT(IS_PLAYER(it), {
1698                 if(it.(field) == value)
1699                         it.winning = 1;
1700         });
1701 }
1702
1703 // clear the .winning flags
1704 void ClearWinners()
1705 {
1706         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1707 }
1708
1709 void ShuffleMaplist()
1710 {
1711         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1712 }
1713
1714 float leaderfrags;
1715 float WinningCondition_Scores(float limit, float leadlimit)
1716 {
1717         float limitreached;
1718
1719         // TODO make everything use THIS winning condition (except LMS)
1720         WinningConditionHelper(NULL);
1721
1722         if(teamplay)
1723         {
1724                 for (int i = 1; i < 5; ++i)
1725                 {
1726                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1727                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1728                 }
1729         }
1730
1731         ClearWinners();
1732         if(WinningConditionHelper_winner)
1733                 WinningConditionHelper_winner.winning = 1;
1734         if(WinningConditionHelper_winnerteam >= 0)
1735                 SetWinners(team, WinningConditionHelper_winnerteam);
1736
1737         if(WinningConditionHelper_lowerisbetter)
1738         {
1739                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1740                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1741                 limit = -limit;
1742         }
1743
1744         if(WinningConditionHelper_zeroisworst)
1745                 leadlimit = 0; // not supported in this mode
1746
1747         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1748         // these modes always score in increments of 1, thus this makes sense
1749         {
1750                 if(leaderfrags != WinningConditionHelper_topscore)
1751                 {
1752                         leaderfrags = WinningConditionHelper_topscore;
1753
1754                         if (limit)
1755                         {
1756                                 if (leaderfrags == limit - 1)
1757                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1758                                 else if (leaderfrags == limit - 2)
1759                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1760                                 else if (leaderfrags == limit - 3)
1761                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1762                         }
1763                 }
1764         }
1765
1766         limitreached = false;
1767         if (limit && WinningConditionHelper_topscore >= limit)
1768                 limitreached = true;
1769         if(leadlimit)
1770         {
1771                 float leadlimitreached;
1772                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1773                 if(autocvar_leadlimit_and_fraglimit)
1774                         limitreached = (limitreached && leadlimitreached);
1775                 else
1776                         limitreached = (limitreached || leadlimitreached);
1777         }
1778
1779         if(limit)
1780                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1781
1782         return GetWinningCode(
1783                 WinningConditionHelper_topscore && limitreached,
1784                 WinningConditionHelper_equality
1785         );
1786 }
1787
1788 float WinningCondition_RanOutOfSpawns()
1789 {
1790         if(have_team_spawns <= 0)
1791                 return WINNING_NO;
1792
1793         if(!autocvar_g_spawn_useallspawns)
1794                 return WINNING_NO;
1795
1796         if(!some_spawn_has_been_used)
1797                 return WINNING_NO;
1798
1799         for (int i = 1; i < 5; ++i)
1800         {
1801                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1802         }
1803
1804         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1805         {
1806                 if (Team_IsValidTeam(it.team))
1807                 {
1808                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1809                 }
1810         });
1811
1812         IL_EACH(g_spawnpoints, true,
1813         {
1814                 if (Team_IsValidTeam(it.team))
1815                 {
1816                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1817                 }
1818         });
1819
1820         ClearWinners();
1821         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1822         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1823         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1824         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1825         if(team1_score + team2_score + team3_score + team4_score == 0)
1826         {
1827                 checkrules_equality = true;
1828                 return WINNING_YES;
1829         }
1830         else if(team1_score + team2_score + team3_score + team4_score == 1)
1831         {
1832                 float t, i;
1833                 if(team1_score)
1834                         t = 1;
1835                 else if(team2_score)
1836                         t = 2;
1837                 else if(team3_score)
1838                         t = 3;
1839                 else // if(team4_score)
1840                         t = 4;
1841                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1842                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1843                 {
1844                         for (int j = 1; j <= NUM_TEAMS; ++j)
1845                         {
1846                                 if (t == j)
1847                                 {
1848                                         continue;
1849                                 }
1850                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1851                                 {
1852                                         continue;
1853                                 }
1854                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1855                         }
1856                 }
1857
1858                 AddWinners(team, t);
1859                 return WINNING_YES;
1860         }
1861         else
1862                 return WINNING_NO;
1863 }
1864
1865 /*
1866 ============
1867 CheckRules_World
1868
1869 Exit deathmatch games upon conditions
1870 ============
1871 */
1872 void CheckRules_World()
1873 {
1874         float timelimit;
1875         float fraglimit;
1876         float leadlimit;
1877
1878         VoteThink();
1879         MapVote_Think();
1880
1881         SetDefaultAlpha();
1882
1883         if (intermission_running) // someone else quit the game already
1884         {
1885                 if(player_count == 0) // Nobody there? Then let's go to the next map
1886                         MapVote_Start();
1887                         // this will actually check the player count in the next frame
1888                         // again, but this shouldn't hurt
1889                 return;
1890         }
1891
1892         timelimit = autocvar_timelimit * 60;
1893         fraglimit = autocvar_fraglimit;
1894         leadlimit = autocvar_leadlimit;
1895
1896         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1897         {
1898                 if(timelimit > 0)
1899                         timelimit = 0; // timelimit is not made for warmup
1900                 if(fraglimit > 0)
1901                         fraglimit = 0; // no fraglimit for now
1902                 leadlimit = 0; // no leadlimit for now
1903         }
1904
1905         if(timelimit > 0)
1906         {
1907                 timelimit += game_starttime;
1908         }
1909         else if (timelimit < 0)
1910         {
1911                 // endmatch
1912                 NextLevel();
1913                 return;
1914         }
1915
1916         float wantovertime;
1917         wantovertime = 0;
1918
1919         if(timelimit > game_starttime)
1920                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1921         else
1922                 game_completion_ratio = 0;
1923
1924         if(checkrules_suddendeathend)
1925         {
1926                 if(!checkrules_suddendeathwarning)
1927                 {
1928                         checkrules_suddendeathwarning = true;
1929                         if(g_race && !g_race_qualifying)
1930                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1931                         else
1932                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1933                 }
1934         }
1935         else
1936         {
1937                 if (timelimit && time >= timelimit)
1938                 {
1939                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1940                         {
1941                                 float totalplayers;
1942                                 float playerswithlaps;
1943                                 float readyplayers;
1944                                 totalplayers = playerswithlaps = readyplayers = 0;
1945                                 FOREACH_CLIENT(IS_PLAYER(it), {
1946                                         ++totalplayers;
1947                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1948                                                 ++playerswithlaps;
1949                                         if(it.ready)
1950                                                 ++readyplayers;
1951                                 });
1952
1953                                 // at least 2 of the players have completed a lap: start the RACE
1954                                 // otherwise, the players should end the qualifying on their own
1955                                 if(readyplayers || playerswithlaps >= 2)
1956                                 {
1957                                         checkrules_suddendeathend = 0;
1958                                         ReadyRestart(); // go to race
1959                                         return;
1960                                 }
1961                                 else
1962                                         wantovertime |= InitiateSuddenDeath();
1963                         }
1964                         else
1965                                 wantovertime |= InitiateSuddenDeath();
1966                 }
1967         }
1968
1969         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1970         {
1971                 NextLevel();
1972                 return;
1973         }
1974
1975         int checkrules_status = WinningCondition_RanOutOfSpawns();
1976         if(checkrules_status == WINNING_YES)
1977                 bprint("Hey! Someone ran out of spawns!\n");
1978         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1979                 checkrules_status = M_ARGV(0, float);
1980         else
1981                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1982
1983         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1984         {
1985                 checkrules_status = WINNING_NEVER;
1986                 checkrules_overtimesadded = -1;
1987                 wantovertime |= InitiateSuddenDeath();
1988         }
1989
1990         if(checkrules_status == WINNING_NEVER)
1991                 // equality cases! Nobody wins if the overtime ends in a draw.
1992                 ClearWinners();
1993
1994         if(wantovertime)
1995         {
1996                 if(checkrules_status == WINNING_NEVER)
1997                         InitiateOvertime();
1998                 else
1999                         checkrules_status = WINNING_YES;
2000         }
2001
2002         if(checkrules_suddendeathend)
2003                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2004                         checkrules_status = WINNING_YES;
2005
2006         if(checkrules_status == WINNING_YES)
2007         {
2008                 //print("WINNING\n");
2009                 NextLevel();
2010         }
2011 }
2012
2013 string GotoMap(string m)
2014 {
2015         m = GameTypeVote_MapInfo_FixName(m);
2016         if (!m)
2017                 return "The map you suggested is not available on this server.";
2018         if (!autocvar_sv_vote_gametype)
2019         if(!MapInfo_CheckMap(m))
2020                 return "The map you suggested does not support the current game mode.";
2021         cvar_set("nextmap", m);
2022         cvar_set("timelimit", "-1");
2023         if(mapvote_initialized || alreadychangedlevel)
2024         {
2025                 if(DoNextMapOverride(0))
2026                         return "Map switch initiated.";
2027                 else
2028                         return "Hm... no. For some reason I like THIS map more.";
2029         }
2030         else
2031                 return "Map switch will happen after scoreboard.";
2032 }
2033
2034 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2035 void RunThink(entity this)
2036 {
2037         // don't let things stay in the past.
2038         // it is possible to start that way by a trigger with a local time.
2039         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2040                 return;
2041
2042         float oldtime = time; // do we need to save this?
2043
2044         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2045         {
2046                 time = max(oldtime, this.nextthink);
2047                 this.nextthink = 0;
2048
2049                 if(getthink(this))
2050                         getthink(this)(this);
2051                 // mods often set nextthink to time to cause a think every frame,
2052                 // we don't want to loop in that case, so exit if the new nextthink is
2053                 // <= the time the qc was told, also exit if it is past the end of the
2054                 // frame
2055                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2056                         break;
2057         }
2058
2059         time = oldtime;
2060 }
2061
2062 bool autocvar_sv_freezenonclients;
2063 bool autocvar_sv_gameplayfix_delayprojectiles;
2064 void Physics_Frame()
2065 {
2066         if(autocvar_sv_freezenonclients)
2067                 return;
2068
2069         FOREACH_ENTITY_FLOAT(pure_data, false,
2070         {
2071                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2072                         continue;
2073
2074                 //set_movetype(it, it.move_movetype);
2075                 // inline the set_movetype function, since this is called a lot
2076                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2077
2078                 if(it.move_movetype == MOVETYPE_NONE)
2079                         continue;
2080
2081                 if(it.move_qcphysics)
2082                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2083
2084                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2085                 {
2086                         // handle thinking here
2087                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2088                                 RunThink(it);
2089                 }
2090         });
2091
2092         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2093                 return;
2094
2095         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2096         {
2097                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2098                         continue;
2099                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2100         });
2101 }
2102
2103 void systems_update();
2104 void EndFrame()
2105 {
2106         anticheat_endframe();
2107
2108         Physics_Frame();
2109
2110         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2111                 entity e = IS_SPEC(it) ? it.enemy : it;
2112                 if (e.typehitsound) {
2113                         STAT(TYPEHIT_TIME, it) = time;
2114                 } else if (e.killsound) {
2115                         STAT(KILL_TIME, it) = time;
2116                 } else if (e.damage_dealt) {
2117                         STAT(HIT_TIME, it) = time;
2118                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2119                 }
2120         });
2121         // add 1 frametime because after this, engine SV_Physics
2122         // increases time by a frametime and then networks the frame
2123         // add another frametime because client shows everything with
2124         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2125         // needed!
2126         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2127         FOREACH_CLIENT(true, {
2128                 it.typehitsound = false;
2129                 it.damage_dealt = 0;
2130                 it.killsound = false;
2131                 antilag_record(it, CS(it), altime);
2132         });
2133         IL_EACH(g_monsters, true,
2134         {
2135                 antilag_record(it, it, altime);
2136         });
2137         IL_EACH(g_projectiles, it.classname == "nade",
2138         {
2139                 antilag_record(it, it, altime);
2140         });
2141         systems_update();
2142         IL_ENDFRAME();
2143 }
2144
2145
2146 /*
2147  * RedirectionThink:
2148  * returns true if redirecting
2149  */
2150 float redirection_timeout;
2151 float redirection_nextthink;
2152 float RedirectionThink()
2153 {
2154         float clients_found;
2155
2156         if(redirection_target == "")
2157                 return false;
2158
2159         if(!redirection_timeout)
2160         {
2161                 cvar_set("sv_public", "-2");
2162                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2163                 if(redirection_target == "self")
2164                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2165                 else
2166                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2167         }
2168
2169         if(time < redirection_nextthink)
2170                 return true;
2171
2172         redirection_nextthink = time + 1;
2173
2174         clients_found = 0;
2175         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2176                 // TODO add timer
2177                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2178                 if(redirection_target == "self")
2179                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2180                 else
2181                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2182                 ++clients_found;
2183         });
2184
2185         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2186
2187         if(time > redirection_timeout || clients_found == 0)
2188                 localcmd("\nwait; wait; wait; quit\n");
2189
2190         return true;
2191 }
2192
2193 void RestoreGame()
2194 {
2195         // Loaded from a save game
2196         // some things then break, so let's work around them...
2197
2198         // Progs DB (capture records)
2199         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2200
2201         // Mapinfo
2202         MapInfo_Shutdown();
2203         MapInfo_Enumerate();
2204         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2205         WeaponStats_Init();
2206
2207         TargetMusic_RestoreGame();
2208 }
2209
2210 void Shutdown()
2211 {
2212         game_stopped = 2;
2213
2214         if(world_initialized > 0)
2215         {
2216                 world_initialized = 0;
2217                 LOG_TRACE("Saving persistent data...");
2218                 Ban_SaveBans();
2219
2220                 // playerstats with unfinished match
2221                 PlayerStats_GameReport(false);
2222
2223                 if(!cheatcount_total)
2224                 {
2225                         if(autocvar_sv_db_saveasdump)
2226                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2227                         else
2228                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2229                 }
2230                 if(autocvar_developer)
2231                 {
2232                         if(autocvar_sv_db_saveasdump)
2233                                 db_dump(TemporaryDB, "server-temp.db");
2234                         else
2235                                 db_save(TemporaryDB, "server-temp.db");
2236                 }
2237                 CheatShutdown(); // must be after cheatcount check
2238                 db_close(ServerProgsDB);
2239                 db_close(TemporaryDB);
2240                 LOG_TRACE("Saving persistent data... done!");
2241                 // tell the bot system the game is ending now
2242                 bot_endgame();
2243
2244                 WeaponStats_Shutdown();
2245                 MapInfo_Shutdown();
2246         }
2247         else if(world_initialized == 0)
2248         {
2249                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2250         }
2251         else
2252         {
2253                 __init_dedicated_server_shutdown();
2254         }
2255 }