qcsrc/server/g_world.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qc"
   5     #include "../dpdefs/dpextensions.qc"
   6     #include "sys-post.qh"
   7     #include "../common/constants.qh"
   8     #include "../common/stats.qh"
   9     #include "../common/teams.qh"
  10     #include "../common/util.qh"
  11     #include "../common/monsters/sv_monsters.qh"
  12     #include "../common/weapons/weapons.qh"
  13     #include "weapons/weaponstats.qh"
  14     #include "autocvars.qh"
  15     #include "constants.qh"
  16     #include "defs.qh"
  17     #include "../common/notifications.qh"
  18     #include "mutators/mutators_include.qh"
  19     #include "campaign.qh"
  20     #include "../common/mapinfo.qh"
  21     #include "command/common.qh"
  22     #include "command/vote.qh"
  23     #include "command/getreplies.qh"
  24     #include "command/sv_cmd.qh"
  25     #include "anticheat.qh"
  26     #include "cheats.qh"
  27     #include "../common/playerstats.qh"
  28     #include "g_hook.qh"
  29     #include "scores.qh"
  30     #include "mapvoting.qh"
  31     #include "ipban.qh"
  32     #include "race.qh"
  33     #include "antilag.qh"
  34     #include "secret.qh"
  35 #endif
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void GotoNextMap(float reinit);
  96 void ShuffleMaplist();
  97 float(float reinit) DoNextMapOverride;
  98
  99 void SetDefaultAlpha()
 100 {
 101         if(autocvar_g_running_guns)
 102         {
 103                 default_player_alpha = -1;
 104                 default_weapon_alpha = +1;
 105         }
 106         else if(g_cloaked)
 107         {
 108                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111         else
 112         {
 113                 default_player_alpha = autocvar_g_player_alpha;
 114                 if(default_player_alpha == 0)
 115                         default_player_alpha = 1;
 116                 default_weapon_alpha = default_player_alpha;
 117         }
 118 }
 119
 120 void GotoFirstMap()
 121 {
 122         float n;
 123         if(autocvar__sv_init)
 124         {
 125                 // cvar_set("_sv_init", "0");
 126                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 127                 // to this "init" map on a dedicated server will cause no permanent
 128                 // harm
 129                 if(autocvar_g_maplist_shuffle)
 130                         ShuffleMaplist();
 131                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 132                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 133
 134                 MapInfo_Enumerate();
 135                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 136
 137                 if(!DoNextMapOverride(1))
 138                         GotoNextMap(1);
 139
 140                 return;
 141         }
 142
 143         if(time < 5)
 144         {
 145                 self.nextthink = time;
 146         }
 147         else
 148         {
 149                 self.nextthink = time + 1;
 150                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 151         }
 152 }
 153
 154 void cvar_changes_init()
 155 {
 156         float h;
 157         string k, v, d;
 158         float n, i, adding, pureadding;
 159
 160         if(cvar_changes)
 161                 strunzone(cvar_changes);
 162         cvar_changes = string_null;
 163         if(cvar_purechanges)
 164                 strunzone(cvar_purechanges);
 165         cvar_purechanges = string_null;
 166         cvar_purechanges_count = 0;
 167
 168         h = buf_create();
 169         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 170         n = buf_getsize(h);
 171
 172         adding = true;
 173         pureadding = true;
 174
 175         for(i = 0; i < n; ++i)
 176         {
 177                 k = bufstr_get(h, i);
 178
 179 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 180 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 181 #define BADCVAR(p) if(k == p) continue
 182
 183                 // general excludes and namespaces for server admin used cvars
 184                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 185
 186                 // internal
 187                 BADPREFIX("csqc_");
 188                 BADPREFIX("cvar_check_");
 189                 BADCVAR("gamecfg");
 190                 BADCVAR("g_configversion");
 191                 BADCVAR("g_maplist_index");
 192                 BADCVAR("halflifebsp");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_qualifying_timelimit");
 283                 BADCVAR("g_tdm");
 284                 BADCVAR("g_tdm_teams");
 285                 BADCVAR("leadlimit");
 286                 BADCVAR("nextmap");
 287                 BADCVAR("teamplay");
 288                 BADCVAR("timelimit");
 289
 290                 // long
 291                 BADCVAR("hostname");
 292                 BADCVAR("g_maplist");
 293                 BADCVAR("g_maplist_mostrecent");
 294                 BADCVAR("sv_motd");
 295
 296                 v = cvar_string(k);
 297                 d = cvar_defstring(k);
 298                 if(v == d)
 299                         continue;
 300
 301                 if(adding)
 302                 {
 303                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 304                         if(strlen(cvar_changes) > 16384)
 305                         {
 306                                 cvar_changes = "// too many settings have been changed to show them here\n";
 307                                 adding = 0;
 308                         }
 309                 }
 310
 311                 // now check if the changes are actually gameplay relevant
 312
 313                 // does nothing visible
 314                 BADCVAR("captureleadlimit_override");
 315                 BADCVAR("g_balance_kill_delay");
 316                 BADCVAR("g_ca_point_leadlimit");
 317                 BADCVAR("g_ctf_captimerecord_always");
 318                 BADCVAR("g_ctf_flag_glowtrails");
 319                 BADCVAR("g_ctf_flag_pickup_verbosename");
 320                 BADCVAR("g_domination_point_leadlimit");
 321                 BADCVAR("g_forced_respawn");
 322                 BADCVAR("g_keyhunt_point_leadlimit");
 323                 BADPREFIX("g_mod_");
 324                 BADCVAR("g_nexball_goalleadlimit");
 325                 BADCVAR("leadlimit_and_fraglimit");
 326                 BADCVAR("leadlimit_override");
 327                 BADCVAR("pausable");
 328                 BADCVAR("sv_allow_fullbright");
 329                 BADCVAR("sv_checkforpacketsduringsleep");
 330                 BADCVAR("sv_fraginfo");
 331                 BADCVAR("sv_timeout");
 332                 BADPREFIX("sv_timeout_");
 333                 BADPREFIX("crypto_");
 334                 BADPREFIX("g_chat_");
 335                 BADPREFIX("g_ctf_captimerecord_");
 336                 BADPREFIX("g_maplist_votable_");
 337                 BADPREFIX("net_");
 338                 BADPREFIX("prvm_");
 339                 BADPREFIX("skill_");
 340                 BADPREFIX("sv_cullentities_");
 341                 BADPREFIX("sv_fraginfo_");
 342                 BADPREFIX("sv_maxidle_");
 343                 BADPREFIX("sv_vote_");
 344                 BADPREFIX("timelimit_");
 345                 BADCVAR("gameversion");
 346                 BADPREFIX("gameversion_");
 347                 BADCVAR("sv_namechangetimer");
 348
 349                 // allowed changes to server admins (please sync this to server.cfg)
 350                 // vi commands:
 351                 //   :/"impure"/,$d
 352                 //   :g!,^\/\/[^ /],d
 353                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 354                 //   :%!sort
 355                 // yes, this does contain some redundant stuff, don't really care
 356                 BADCVAR("bot_config_file");
 357                 BADCVAR("bot_number");
 358                 BADCVAR("bot_prefix");
 359                 BADCVAR("bot_suffix");
 360                 BADCVAR("capturelimit_override");
 361                 BADCVAR("fraglimit_override");
 362                 BADCVAR("gametype");
 363                 BADCVAR("g_antilag");
 364                 BADCVAR("g_balance_teams");
 365                 BADCVAR("g_balance_teams_prevent_imbalance");
 366                 BADCVAR("g_balance_teams_scorefactor");
 367                 BADCVAR("g_ban_sync_trusted_servers");
 368                 BADCVAR("g_ban_sync_uri");
 369                 BADCVAR("g_ca_teams_override");
 370                 BADCVAR("g_ctf_ignore_frags");
 371                 BADCVAR("g_domination_point_limit");
 372                 BADCVAR("g_freezetag_teams_override");
 373                 BADCVAR("g_friendlyfire");
 374                 BADCVAR("g_fullbrightitems");
 375                 BADCVAR("g_fullbrightplayers");
 376                 BADCVAR("g_keyhunt_point_limit");
 377                 BADCVAR("g_keyhunt_teams_override");
 378                 BADCVAR("g_lms_lives_override");
 379                 BADCVAR("g_maplist");
 380                 BADCVAR("g_maplist_check_waypoints");
 381                 BADCVAR("g_maplist_mostrecent_count");
 382                 BADCVAR("g_maplist_shuffle");
 383                 BADCVAR("g_maplist_votable");
 384                 BADCVAR("g_maplist_votable_abstain");
 385                 BADCVAR("g_maplist_votable_nodetail");
 386                 BADCVAR("g_maplist_votable_suggestions");
 387                 BADCVAR("g_maxplayers");
 388                 BADCVAR("g_mirrordamage");
 389                 BADCVAR("g_nexball_goallimit");
 390                 BADCVAR("g_powerups");
 391                 BADCVAR("g_start_delay");
 392                 BADCVAR("g_warmup");
 393                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 394                 BADCVAR("hostname");
 395                 BADCVAR("log_file");
 396                 BADCVAR("maxplayers");
 397                 BADCVAR("minplayers");
 398                 BADCVAR("net_address");
 399                 BADCVAR("port");
 400                 BADCVAR("rcon_password");
 401                 BADCVAR("rcon_restricted_commands");
 402                 BADCVAR("rcon_restricted_password");
 403                 BADCVAR("skill");
 404                 BADCVAR("sv_adminnick");
 405                 BADCVAR("sv_autoscreenshot");
 406                 BADCVAR("sv_autotaunt");
 407                 BADCVAR("sv_curl_defaulturl");
 408                 BADCVAR("sv_defaultcharacter");
 409                 BADCVAR("sv_defaultplayercolors");
 410                 BADCVAR("sv_defaultplayermodel");
 411                 BADCVAR("sv_defaultplayerskin");
 412                 BADCVAR("sv_maxidle");
 413                 BADCVAR("sv_maxrate");
 414                 BADCVAR("sv_motd");
 415                 BADCVAR("sv_public");
 416                 BADCVAR("sv_ready_restart");
 417                 BADCVAR("sv_status_privacy");
 418                 BADCVAR("sv_taunt");
 419                 BADCVAR("sv_vote_call");
 420                 BADCVAR("sv_vote_commands");
 421                 BADCVAR("sv_vote_majority_factor");
 422                 BADCVAR("sv_vote_master");
 423                 BADCVAR("sv_vote_master_commands");
 424                 BADCVAR("sv_vote_master_password");
 425                 BADCVAR("sv_vote_simple_majority_factor");
 426                 BADCVAR("teamplay_mode");
 427                 BADCVAR("timelimit_override");
 428                 BADCVAR("g_spawnshieldtime");
 429                 BADPREFIX("g_warmup_");
 430                 BADPREFIX("sv_ready_restart_");
 431
 432                 // mutators that announce themselves properly to the server browser
 433                 BADCVAR("g_instagib");
 434                 BADCVAR("g_new_toys");
 435                 BADCVAR("g_nix");
 436                 BADCVAR("g_grappling_hook");
 437                 BADCVAR("g_jetpack");
 438
 439 #undef BADPREFIX
 440 #undef BADCVAR
 441
 442                 if(pureadding)
 443                 {
 444                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 445                         if(strlen(cvar_purechanges) > 16384)
 446                         {
 447                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 448                                 pureadding = 0;
 449                         }
 450                 }
 451                 ++cvar_purechanges_count;
 452                 // WARNING: this variable is used for the server list
 453                 // NEVER dare to skip this code!
 454                 // Hacks to intentionally appearing as "pure server" even though you DO have
 455                 // modified settings may be punished by removal from the server list.
 456                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 457                 // though.
 458         }
 459         buf_del(h);
 460         if(cvar_changes == "")
 461                 cvar_changes = "// this server runs at default server settings\n";
 462         else
 463                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 464         cvar_changes = strzone(cvar_changes);
 465         if(cvar_purechanges == "")
 466                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 467         else
 468                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 469         cvar_purechanges = strzone(cvar_purechanges);
 470 }
 471
 472 void detect_maptype()
 473 {
 474 #if 0
 475         vector o, v;
 476         float i;
 477
 478         for(0;;)
 479         {
 480                 o = world.mins;
 481                 o.x += random() * (world.maxs.x - world.mins.x);
 482                 o.y += random() * (world.maxs.y - world.mins.y);
 483                 o.z += random() * (world.maxs.z - world.mins.z);
 484
 485                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 486                 if(trace_fraction == 1)
 487                         continue;
 488
 489                 v = trace_endpos;
 490
 491                 for(i = 0; i < 64; i += 4)
 492                 {
 493                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 494         if(trace_fraction == 1)
 495                 continue;
 496                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 497                 }
 498
 499                 break;
 500         }
 501 #endif
 502 }
 503
 504 entity randomseed;
 505 float RandomSeed_Send(entity to, float sf)
 506 {
 507         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 508         WriteShort(MSG_ENTITY, self.cnt);
 509         return true;
 510 }
 511 void RandomSeed_Think()
 512 {
 513         self.cnt = bound(0, floor(random() * 65536), 65535);
 514         self.nextthink = time + 5;
 515
 516         self.SendFlags |= 1;
 517 }
 518 void RandomSeed_Spawn()
 519 {
 520         randomseed = spawn();
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         entity oldself;
 525         oldself = self;
 526         self = randomseed;
 527         self.think(); // sets random seed and nextthink
 528         self = oldself;
 529 }
 530
 531 void spawnfunc___init_dedicated_server(void)
 532 {
 533         // handler for _init/_init map (only for dedicated server initialization)
 534
 535         world_initialized = -1; // don't complain
 536         cvar = cvar_normal;
 537         cvar_string = cvar_string_normal;
 538         cvar_set = cvar_set_normal;
 539
 540         remove = remove_unsafely;
 541
 542         entity e;
 543         e = spawn();
 544         e.think = GotoFirstMap;
 545         e.nextthink = time; // this is usually 1 at this point
 546
 547         e = spawn();
 548         e.classname = "info_player_deathmatch"; // safeguard against player joining
 549
 550         self.classname = "worldspawn"; // safeguard against various stuff ;)
 551
 552         // needs to be done so early because of the constants they create
 553         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 554         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 557         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 558         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 559
 560         MapInfo_Enumerate();
 561         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 562 }
 563
 564 void Map_MarkAsRecent(string m);
 565 float world_already_spawned;
 566 void Nagger_Init();
 567 void ClientInit_Spawn();
 568 void WeaponStats_Init();
 569 void WeaponStats_Shutdown();
 570 void spawnfunc_worldspawn (void)
 571 {
 572         float fd, l, i, j, n;
 573         string s;
 574
 575         cvar = cvar_normal;
 576         cvar_string = cvar_string_normal;
 577         cvar_set = cvar_set_normal;
 578
 579         if(world_already_spawned)
 580                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 581         world_already_spawned = true;
 582
 583         remove = remove_safely; // during spawning, watch what you remove!
 584
 585         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 586
 587         compressShortVector_init();
 588
 589         entity head;
 590         head = nextent(world);
 591         maxclients = 0;
 592         while(head)
 593         {
 594                 ++maxclients;
 595                 head = nextent(head);
 596         }
 597
 598         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 599
 600         // needs to be done so early because of the constants they create
 601         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 602         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 603         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 604         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 605         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 606         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 607
 608         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 609
 610         TemporaryDB = db_create();
 611
 612         // 0 normal
 613         lightstyle(0, "m");
 614
 615         // 1 FLICKER (first variety)
 616         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 617
 618         // 2 SLOW STRONG PULSE
 619         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 620
 621         // 3 CANDLE (first variety)
 622         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 623
 624         // 4 FAST STROBE
 625         lightstyle(4, "mamamamamama");
 626
 627         // 5 GENTLE PULSE 1
 628         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 629
 630         // 6 FLICKER (second variety)
 631         lightstyle(6, "nmonqnmomnmomomno");
 632
 633         // 7 CANDLE (second variety)
 634         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 635
 636         // 8 CANDLE (third variety)
 637         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 638
 639         // 9 SLOW STROBE (fourth variety)
 640         lightstyle(9, "aaaaaaaazzzzzzzz");
 641
 642         // 10 FLUORESCENT FLICKER
 643         lightstyle(10, "mmamammmmammamamaaamammma");
 644
 645         // 11 SLOW PULSE NOT FADE TO BLACK
 646         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 647
 648         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 649
 650         // 63 testing
 651         lightstyle(63, "a");
 652
 653         if(autocvar_g_campaign)
 654                 CampaignPreInit();
 655
 656         Map_MarkAsRecent(mapname);
 657
 658         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 659
 660         precache_model ("null"); // we need this one before InitGameplayMode
 661         InitGameplayMode();
 662         readlevelcvars();
 663         GrappleHookInit();
 664
 665         player_count = 0;
 666         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 667         if(bot_waypoints_for_items == 1)
 668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 669                         bot_waypoints_for_items = 0;
 670
 671         precache();
 672
 673         WaypointSprite_Init();
 674
 675         GameLogInit(); // prepare everything
 676         // NOTE for matchid:
 677         // changing the logic generating it is okay. But:
 678         // it HAS to stay <= 64 chars
 679         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 680         if(autocvar_sv_eventlog)
 681         {
 682                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 683                 matchid = strzone(s);
 684
 685                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 686                 s = ":gameinfo:mutators:LIST";
 687
 688                 ret_string = s;
 689                 MUTATOR_CALLHOOK(BuildMutatorsString);
 690                 s = ret_string;
 691
 692                 // simple, probably not good in the mutator system
 693                 if(autocvar_g_grappling_hook)
 694                         s = strcat(s, ":grappling_hook");
 695
 696                 // initialiation stuff, not good in the mutator system
 697                 if(!autocvar_g_use_ammunition)
 698                         s = strcat(s, ":no_use_ammunition");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_pickup_items == 0)
 702                         s = strcat(s, ":no_pickup_items");
 703                 if(autocvar_g_pickup_items > 0)
 704                         s = strcat(s, ":pickup_items");
 705
 706                 // initialiation stuff, not good in the mutator system
 707                 if(autocvar_g_weaponarena != "0")
 708                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 709
 710                 // TODO to mutator system
 711                 if(autocvar_g_norecoil)
 712                         s = strcat(s, ":norecoil");
 713
 714                 // TODO to mutator system
 715                 if(autocvar_g_powerups == 0)
 716                         s = strcat(s, ":no_powerups");
 717                 if(autocvar_g_powerups > 0)
 718                         s = strcat(s, ":powerups");
 719
 720                 GameLogEcho(s);
 721                 GameLogEcho(":gameinfo:end");
 722         }
 723         else
 724                 matchid = strzone(ftos(random()));
 725
 726         cvar_set("nextmap", "");
 727
 728         SetDefaultAlpha();
 729
 730         if(autocvar_g_campaign)
 731                 CampaignPostInit();
 732
 733         Ban_LoadBans();
 734
 735         MapInfo_Enumerate();
 736         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 737
 738         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 739         {
 740                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 741                 if(fd != -1)
 742                 {
 743                         while((s = fgets(fd)))
 744                         {
 745                                 l = tokenize_console(s);
 746                                 if(l < 2)
 747                                         continue;
 748                                 if(argv(0) == "cd")
 749                                 {
 750                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 751                                         print("  cdtrack ", argv(2), "\n");
 752                                 }
 753                                 else if(argv(0) == "fog")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 756                                         print("  \"fog\" \"", s, "\"\n");
 757                                 }
 758                                 else if(argv(0) == "set")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 762                                 }
 763                                 else if(argv(0) != "//")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 766                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 767                                 }
 768                         }
 769                         fclose(fd);
 770                 }
 771         }
 772
 773         WeaponStats_Init();
 774
 775         WepSet_AddStat();
 776         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 777         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 778         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 779         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 780         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 781         Nagger_Init();
 782
 783         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 784         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 785         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 786         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 787         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 788         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 789         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 790         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 791         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 792         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 793         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 794         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 795         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 796         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 797         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 798
 799         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 800         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 801
 802         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 803
 804         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 805
 806         // freeze attacks
 807         addstat(STAT_FROZEN, AS_INT, frozen);
 808         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 809
 810         // g_movementspeed hack
 811         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 812         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 813         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 814         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 815
 816         // secrets
 817         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 818         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 819
 820         // monsters
 821         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 822         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 823
 824         // misc
 825         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 826
 827         next_pingtime = time + 5;
 828
 829         detect_maptype();
 830
 831         // set up information replies for clients and server to use
 832         maplist_reply = strzone(getmaplist());
 833         lsmaps_reply = strzone(getlsmaps());
 834         monsterlist_reply = strzone(getmonsterlist());
 835         for(i = 0; i < 10; ++i)
 836         {
 837                 s = getrecords(i);
 838                 if (s)
 839                         records_reply[i] = strzone(s);
 840         }
 841         ladder_reply = strzone(getladder());
 842         rankings_reply = strzone(getrankings());
 843
 844         // begin other init
 845         ClientInit_Spawn();
 846         RandomSeed_Spawn();
 847         PingPLReport_Spawn();
 848
 849         CheatInit();
 850
 851         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 852
 853         // fill sv_curl_serverpackages from .serverpackage files
 854         if(autocvar_sv_curl_serverpackages_auto)
 855         {
 856                 s = "";
 857                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 858                 for(i = 0; i < n; ++i)
 859                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 860                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 861                                 s = strcat(s, " ", argv(i));
 862                 fd = search_begin("*-serverpackage.txt", true, false);
 863                 if(fd >= 0)
 864                 {
 865                         j = search_getsize(fd);
 866                         for(i = 0; i < j; ++i)
 867                                 s = strcat(s, " ", search_getfilename(fd, i));
 868                         search_end(fd);
 869                 }
 870                 fd = search_begin("*.serverpackage", true, false);
 871                 if(fd >= 0)
 872                 {
 873                         j = search_getsize(fd);
 874                         for(i = 0; i < j; ++i)
 875                                 s = strcat(s, " ", search_getfilename(fd, i));
 876                         search_end(fd);
 877                 }
 878                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 879         }
 880
 881         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 882         modname = "Xonotic";
 883         // physics/balance/config changes that count as mod
 884         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 885                 modname = cvar_string("g_mod_physics");
 886         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 887                 modname = cvar_string("g_mod_balance");
 888         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 889                 modname = cvar_string("g_mod_config");
 890         // extra mutators that deserve to count as mod
 891         MUTATOR_CALLHOOK(SetModname);
 892
 893         // save it for later
 894         modname = strzone(modname);
 895
 896         WinningConditionHelper(); // set worldstatus
 897
 898         world_initialized = 1;
 899 }
 900
 901 void spawnfunc_light (void)
 902 {
 903         //makestatic (self); // Who the f___ did that?
 904         remove(self);
 905 }
 906
 907 string GetGametype()
 908 {
 909         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 910 }
 911
 912 string GetMapname()
 913 {
 914         return mapname;
 915 }
 916
 917 float Map_Count, Map_Current;
 918 string Map_Current_Name;
 919
 920 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 921 float GetMaplistPosition()
 922 {
 923         float pos, idx;
 924         string map;
 925
 926         map = GetMapname();
 927         idx = autocvar_g_maplist_index;
 928
 929         if(idx >= 0)
 930                 if(idx < Map_Count)
 931                         if(map == argv(idx))
 932                                 return idx;
 933
 934         for(pos = 0; pos < Map_Count; ++pos)
 935                 if(map == argv(pos))
 936                         return pos;
 937
 938         // resume normal maplist rotation if current map is not in g_maplist
 939         return idx;
 940 }
 941
 942 float MapHasRightSize(string map)
 943 {
 944         float fh;
 945         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 946         if(autocvar_g_maplist_check_waypoints)
 947         {
 948                 dprint("checkwp "); dprint(map);
 949                 if(!fexists(strcat("maps/", map, ".waypoints")))
 950                 {
 951                         dprint(": no waypoints\n");
 952                         return false;
 953                 }
 954                 dprint(": has waypoints\n");
 955         }
 956
 957         // open map size restriction file
 958         dprint("opensize "); dprint(map);
 959         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 960         if(fh >= 0)
 961         {
 962                 float mapmin, mapmax;
 963                 dprint(": ok, ");
 964                 mapmin = stof(fgets(fh));
 965                 mapmax = stof(fgets(fh));
 966                 fclose(fh);
 967                 if(player_count < mapmin)
 968                 {
 969                         dprint("not enough\n");
 970                         return false;
 971                 }
 972                 if(player_count > mapmax)
 973                 {
 974                         dprint("too many\n");
 975                         return false;
 976                 }
 977                 dprint("right size\n");
 978                 return true;
 979         }
 980         dprint(": not found\n");
 981         return true;
 982 }
 983
 984 string Map_Filename(float position)
 985 {
 986         return strcat("maps/", argv(position), ".bsp");
 987 }
 988
 989 string strwords(string s, float w)
 990 {
 991         float endpos;
 992         for(endpos = 0; w && endpos >= 0; --w)
 993                 endpos = strstrofs(s, " ", endpos + 1);
 994         if(endpos < 0)
 995                 return s;
 996         else
 997                 return substring(s, 0, endpos);
 998 }
 999
1000 float strhasword(string s, string w)
1001 {
1002         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1003 }
1004
1005 void Map_MarkAsRecent(string m)
1006 {
1007         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1008 }
1009
1010 float Map_IsRecent(string m)
1011 {
1012         return strhasword(autocvar_g_maplist_mostrecent, m);
1013 }
1014
1015 float Map_Check(float position, float pass)
1016 {
1017         string filename;
1018         string map_next;
1019         map_next = argv(position);
1020         if(pass <= 1)
1021         {
1022                 if(Map_IsRecent(map_next))
1023                         return 0;
1024         }
1025         filename = Map_Filename(position);
1026         if(MapInfo_CheckMap(map_next))
1027         {
1028                 if(pass == 2)
1029                         return 1;
1030                 if(MapHasRightSize(map_next))
1031                         return 1;
1032                 return 0;
1033         }
1034         else
1035                 dprint( "Couldn't select '", filename, "'..\n" );
1036
1037         return 0;
1038 }
1039
1040 void Map_Goto_SetStr(string nextmapname)
1041 {
1042         if(getmapname_stored != "")
1043                 strunzone(getmapname_stored);
1044         if(nextmapname == "")
1045                 getmapname_stored = "";
1046         else
1047                 getmapname_stored = strzone(nextmapname);
1048 }
1049
1050 void Map_Goto_SetFloat(float position)
1051 {
1052         cvar_set("g_maplist_index", ftos(position));
1053         Map_Goto_SetStr(argv(position));
1054 }
1055
1056 void Map_Goto(float reinit)
1057 {
1058         MapInfo_LoadMap(getmapname_stored, reinit);
1059 }
1060
1061 // return codes of map selectors:
1062 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1063 //   -2 = permanent failure
1064 float() MaplistMethod_Iterate = // usual method
1065 {
1066         float pass, i;
1067
1068         dprint("Trying MaplistMethod_Iterate\n");
1069
1070         for(pass = 1; pass <= 2; ++pass)
1071         {
1072                 for(i = 1; i < Map_Count; ++i)
1073                 {
1074                         float mapindex;
1075                         mapindex = (i + Map_Current) % Map_Count;
1076                         if(Map_Check(mapindex, pass))
1077                                 return mapindex;
1078                 }
1079         }
1080         return -1;
1081 }
1082
1083 float() MaplistMethod_Repeat = // fallback method
1084 {
1085         dprint("Trying MaplistMethod_Repeat\n");
1086
1087         if(Map_Check(Map_Current, 2))
1088                 return Map_Current;
1089         return -2;
1090 }
1091
1092 float() MaplistMethod_Random = // random map selection
1093 {
1094         float i, imax;
1095
1096         dprint("Trying MaplistMethod_Random\n");
1097
1098         imax = 42;
1099
1100         for(i = 0; i <= imax; ++i)
1101         {
1102                 float mapindex;
1103                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1104                 if(Map_Check(mapindex, 1))
1105                         return mapindex;
1106         }
1107         return -1;
1108 }
1109
1110 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1111 // the exponent sets a bias on the map selection:
1112 // the higher the exponent, the less likely "shortly repeated" same maps are
1113 {
1114         float i, j, imax, insertpos;
1115
1116         dprint("Trying MaplistMethod_Shuffle\n");
1117
1118         imax = 42;
1119
1120         for(i = 0; i <= imax; ++i)
1121         {
1122                 string newlist;
1123
1124                 // now reinsert this at another position
1125                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1126                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1127                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1128                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1129
1130                 // insert the current map there
1131                 newlist = "";
1132                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1133                         newlist = strcat(newlist, " ", argv(j));
1134                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1135                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1136                         newlist = strcat(newlist, " ", argv(j));
1137                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1138                 cvar_set("g_maplist", newlist);
1139                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1140
1141                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1142                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1143                 if(Map_Check(Map_Current, 1))
1144                         return Map_Current;
1145         }
1146         return -1;
1147 }
1148
1149 void Maplist_Init()
1150 {
1151         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1152         float i;
1153         for (i = 0; i < Map_Count; ++i)
1154                 if (Map_Check(i, 2))
1155                         break;
1156         if (i == Map_Count)
1157         {
1158                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1159                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1160                 if(autocvar_g_maplist_shuffle)
1161                         ShuffleMaplist();
1162                 localcmd("\nmenu_cmd sync\n");
1163                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1164         }
1165         if(Map_Count == 0)
1166                 error("empty maplist, cannot select a new map");
1167         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1168
1169         if(Map_Current_Name)
1170                 strunzone(Map_Current_Name);
1171         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1172         // this may or may not be correct, but who cares, in the worst case a map
1173         // isn't chosen in the first pass that should have been
1174 }
1175
1176 string GetNextMap()
1177 {
1178         float nextMap;
1179
1180         Maplist_Init();
1181         nextMap = -1;
1182
1183         if(nextMap == -1)
1184                 if(autocvar_g_maplist_shuffle > 0)
1185                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1186
1187         if(nextMap == -1)
1188                 if(autocvar_g_maplist_selectrandom)
1189                         nextMap = MaplistMethod_Random();
1190
1191         if(nextMap == -1)
1192                 nextMap = MaplistMethod_Iterate();
1193
1194         if(nextMap == -1)
1195                 nextMap = MaplistMethod_Repeat();
1196
1197         if(nextMap >= 0)
1198         {
1199                 Map_Goto_SetFloat(nextMap);
1200                 return getmapname_stored;
1201         }
1202
1203         return "";
1204 }
1205
1206 float DoNextMapOverride(float reinit)
1207 {
1208         if(autocvar_g_campaign)
1209         {
1210                 CampaignPostIntermission();
1211                 alreadychangedlevel = true;
1212                 return true;
1213         }
1214         if(autocvar_quit_when_empty)
1215         {
1216                 if(player_count <= currentbots)
1217                 {
1218                         localcmd("quit\n");
1219                         alreadychangedlevel = true;
1220                         return true;
1221                 }
1222         }
1223         if(autocvar_quit_and_redirect != "")
1224         {
1225                 redirection_target = strzone(autocvar_quit_and_redirect);
1226                 alreadychangedlevel = true;
1227                 return true;
1228         }
1229         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1230         {
1231                 localcmd("restart\n");
1232                 alreadychangedlevel = true;
1233                 return true;
1234         }
1235         if(autocvar_nextmap != "")
1236         {
1237                 string m;
1238                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1239                 cvar_set("nextmap",m);
1240
1241                 if(!m || gametypevote)
1242                         return false;
1243                 if(autocvar_sv_vote_gametype)
1244                 {
1245                         Map_Goto_SetStr(m);
1246                         return false;
1247                 }
1248
1249                 if(MapInfo_CheckMap(m))
1250                 {
1251                         Map_Goto_SetStr(m);
1252                         Map_Goto(reinit);
1253                         alreadychangedlevel = true;
1254                         return true;
1255                 }
1256         }
1257         if(!reinit && autocvar_lastlevel)
1258         {
1259                 cvar_settemp_restore();
1260                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1261                 alreadychangedlevel = true;
1262                 return true;
1263         }
1264         return false;
1265 }
1266
1267 void GotoNextMap(float reinit)
1268 {
1269         //string nextmap;
1270         //float n, nummaps;
1271         //string s;
1272         if (alreadychangedlevel)
1273                 return;
1274         alreadychangedlevel = true;
1275
1276         string nextMap;
1277
1278         nextMap = GetNextMap();
1279         if(nextMap == "")
1280                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1281         Map_Goto(reinit);
1282 }
1283
1284
1285 /*
1286 ============
1287 IntermissionThink
1288
1289 When the player presses attack or jump, change to the next level
1290 ============
1291 */
1292 .float autoscreenshot;
1293 void IntermissionThink()
1294 {
1295         FixIntermissionClient(self);
1296
1297         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1298         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1299
1300         if( (server_screenshot || client_screenshot)
1301                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1302         {
1303                 self.autoscreenshot = -1;
1304                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1305                 return;
1306         }
1307
1308         if (time < intermission_exittime)
1309                 return;
1310
1311         if(!mapvote_initialized)
1312                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1313                         return;
1314
1315         MapVote_Start();
1316 }
1317
1318 /*
1319 ============
1320 FindIntermission
1321
1322 Returns the entity to view from
1323 ============
1324 */
1325 /*
1326 entity FindIntermission()
1327 {
1328         local   entity spot;
1329         local   float cyc;
1330
1331 // look for info_intermission first
1332         spot = find (world, classname, "info_intermission");
1333         if (spot)
1334         {       // pick a random one
1335                 cyc = random() * 4;
1336                 while (cyc > 1)
1337                 {
1338                         spot = find (spot, classname, "info_intermission");
1339                         if (!spot)
1340                                 spot = find (spot, classname, "info_intermission");
1341                         cyc = cyc - 1;
1342                 }
1343                 return spot;
1344         }
1345
1346 // then look for the start position
1347         spot = find (world, classname, "info_player_start");
1348         if (spot)
1349                 return spot;
1350
1351 // testinfo_player_start is only found in regioned levels
1352         spot = find (world, classname, "testplayerstart");
1353         if (spot)
1354                 return spot;
1355
1356 // then look for the start position
1357         spot = find (world, classname, "info_player_deathmatch");
1358         if (spot)
1359                 return spot;
1360
1361         //objerror ("FindIntermission: no spot");
1362         return world;
1363 }
1364 */
1365
1366 /*
1367 ===============================================================================
1368
1369 RULES
1370
1371 ===============================================================================
1372 */
1373
1374 void DumpStats(float final)
1375 {
1376         float file;
1377         string s;
1378         float to_console;
1379         float to_eventlog;
1380         float to_file;
1381         float i;
1382
1383         to_console = autocvar_sv_logscores_console;
1384         to_eventlog = autocvar_sv_eventlog;
1385         to_file = autocvar_sv_logscores_file;
1386
1387         if(!final)
1388         {
1389                 to_console = true; // always print printstats replies
1390                 to_eventlog = false; // but never print them to the event log
1391         }
1392
1393         if(to_eventlog)
1394                 if(autocvar_sv_eventlog_console)
1395                         to_console = false; // otherwise we get the output twice
1396
1397         if(final)
1398                 s = ":scores:";
1399         else
1400                 s = ":status:";
1401         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1402
1403         if(to_console)
1404                 print(s, "\n");
1405         if(to_eventlog)
1406                 GameLogEcho(s);
1407
1408         file = -1;
1409         if(to_file)
1410         {
1411                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1412                 if(file == -1)
1413                         to_file = false;
1414                 else
1415                         fputs(file, strcat(s, "\n"));
1416         }
1417
1418         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1419         if(to_console)
1420                 print(s, "\n");
1421         if(to_eventlog)
1422                 GameLogEcho(s);
1423         if(to_file)
1424                 fputs(file, strcat(s, "\n"));
1425
1426         FOR_EACH_CLIENT(other)
1427         {
1428                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1429                 {
1430                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1431                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1432                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1433                                 s = strcat(s, ftos(other.team), ":");
1434                         else
1435                                 s = strcat(s, "spectator:");
1436
1437                         if(to_console)
1438                                 print(s, other.netname, "\n");
1439                         if(to_eventlog)
1440                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1441                         if(to_file)
1442                                 fputs(file, strcat(s, other.netname, "\n"));
1443                 }
1444         }
1445
1446         if(teamplay)
1447         {
1448                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1449                 if(to_console)
1450                         print(s, "\n");
1451                 if(to_eventlog)
1452                         GameLogEcho(s);
1453                 if(to_file)
1454                         fputs(file, strcat(s, "\n"));
1455
1456                 for(i = 1; i < 16; ++i)
1457                 {
1458                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1459                         s = strcat(s, ":", ftos(i));
1460                         if(to_console)
1461                                 print(s, "\n");
1462                         if(to_eventlog)
1463                                 GameLogEcho(s);
1464                         if(to_file)
1465                                 fputs(file, strcat(s, "\n"));
1466                 }
1467         }
1468
1469         if(to_console)
1470                 print(":end\n");
1471         if(to_eventlog)
1472                 GameLogEcho(":end");
1473         if(to_file)
1474         {
1475                 fputs(file, ":end\n");
1476                 fclose(file);
1477         }
1478 }
1479
1480 void FixIntermissionClient(entity e)
1481 {
1482         string s;
1483         if(!e.autoscreenshot) // initial call
1484         {
1485                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1486                 e.health = -2342;
1487                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1488                 e.solid = SOLID_NOT;
1489                 e.movetype = MOVETYPE_NONE;
1490                 e.takedamage = DAMAGE_NO;
1491                 if(e.weaponentity)
1492                 {
1493                         e.weaponentity.effects = EF_NODRAW;
1494                         if (e.weaponentity.weaponentity)
1495                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1496                 }
1497                 if(IS_REAL_CLIENT(e))
1498                 {
1499                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1500                         s = autocvar_sv_intermission_cdtrack;
1501                         if(s != "")
1502                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1503                         msg_entity = e;
1504                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1505                 }
1506         }
1507 }
1508
1509 /*
1510 go to the next level for deathmatch
1511 only called if a time or frag limit has expired
1512 */
1513 void NextLevel()
1514 {
1515         gameover = true;
1516
1517         intermission_running = 1;
1518
1519 // enforce a wait time before allowing changelevel
1520         if(player_count > 0)
1521                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1522         else
1523                 intermission_exittime = -1;
1524
1525         /*
1526         WriteByte (MSG_ALL, SVC_CDTRACK);
1527         WriteByte (MSG_ALL, 3);
1528         WriteByte (MSG_ALL, 3);
1529         // done in FixIntermission
1530         */
1531
1532         //pos = FindIntermission ();
1533
1534         VoteReset();
1535
1536         DumpStats(true);
1537
1538         // send statistics
1539         PlayerStats_GameReport(true);
1540         WeaponStats_Shutdown();
1541
1542         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1543
1544         if(autocvar_sv_eventlog)
1545                 GameLogEcho(":gameover");
1546
1547         GameLogClose();
1548
1549         FOR_EACH_PLAYER(other) {
1550                 FixIntermissionClient(other);
1551                 if(other.winning)
1552                         bprint(other.netname, " ^7wins.\n");
1553         }
1554
1555         if(autocvar_g_campaign)
1556                 CampaignPreIntermission();
1557
1558         MUTATOR_CALLHOOK(MatchEnd);
1559
1560         localcmd("\nsv_hook_gameend\n");
1561 }
1562
1563 /*
1564 ============
1565 CheckRules_Player
1566
1567 Exit deathmatch games upon conditions
1568 ============
1569 */
1570 void CheckRules_Player()
1571 {
1572         if (gameover)   // someone else quit the game already
1573                 return;
1574
1575         if(self.deadflag == DEAD_NO)
1576                 self.play_time += frametime;
1577
1578         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1579         //   (div0: and that in CheckRules_World please)
1580 }
1581
1582 float checkrules_equality;
1583 float checkrules_suddendeathwarning;
1584 float checkrules_suddendeathend;
1585 float checkrules_overtimesadded; //how many overtimes have been already added
1586
1587 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1588 const float WINNING_YES = 1; // winner found
1589 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1590 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1591
1592 float InitiateSuddenDeath()
1593 {
1594         // Check first whether normal overtimes could be added before initiating suddendeath mode
1595         // - for this timelimit_overtime needs to be >0 of course
1596         // - also check the winning condition calculated in the previous frame and only add normal overtime
1597         //   again, if at the point at which timelimit would be extended again, still no winner was found
1598         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1599         {
1600                 return 1; // need to call InitiateOvertime later
1601         }
1602         else
1603         {
1604                 if(!checkrules_suddendeathend)
1605                 {
1606                         if(autocvar_g_campaign)
1607                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1608                         else
1609                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1610                         if(g_race && !g_race_qualifying)
1611                                 race_StartCompleting();
1612                 }
1613                 return 0;
1614         }
1615 }
1616
1617 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1618 {
1619         ++checkrules_overtimesadded;
1620         //add one more overtime by simply extending the timelimit
1621         float tl;
1622         tl = autocvar_timelimit;
1623         tl += autocvar_timelimit_overtime;
1624         cvar_set("timelimit", ftos(tl));
1625
1626         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1627 }
1628
1629 float GetWinningCode(float fraglimitreached, float equality)
1630 {
1631         if(autocvar_g_campaign == 1)
1632                 if(fraglimitreached)
1633                         return WINNING_YES;
1634                 else
1635                         return WINNING_NO;
1636
1637         else
1638                 if(equality)
1639                         if(fraglimitreached)
1640                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1641                         else
1642                                 return WINNING_NEVER;
1643                 else
1644                         if(fraglimitreached)
1645                                 return WINNING_YES;
1646                         else
1647                                 return WINNING_NO;
1648 }
1649
1650 // set the .winning flag for exactly those players with a given field value
1651 void SetWinners(.float field, float value)
1652 {
1653         entity head;
1654         FOR_EACH_PLAYER(head)
1655                 head.winning = (head.field == value);
1656 }
1657
1658 // set the .winning flag for those players with a given field value
1659 void AddWinners(.float field, float value)
1660 {
1661         entity head;
1662         FOR_EACH_PLAYER(head)
1663                 if(head.field == value)
1664                         head.winning = 1;
1665 }
1666
1667 // clear the .winning flags
1668 void ClearWinners(void)
1669 {
1670         entity head;
1671         FOR_EACH_PLAYER(head)
1672                 head.winning = 0;
1673 }
1674
1675 // Onslaught winning condition:
1676 // game terminates if only one team has a working generator (or none)
1677 float WinningCondition_Onslaught()
1678 {
1679         entity head;
1680         float t1, t2, t3, t4;
1681
1682         WinningConditionHelper(); // set worldstatus
1683
1684         if(warmup_stage)
1685                 return WINNING_NO;
1686
1687         // first check if the game has ended
1688         t1 = t2 = t3 = t4 = 0;
1689         head = find(world, classname, "onslaught_generator");
1690         while (head)
1691         {
1692                 if (head.health > 0)
1693                 {
1694                         if (head.team == NUM_TEAM_1) t1 = 1;
1695                         if (head.team == NUM_TEAM_2) t2 = 1;
1696                         if (head.team == NUM_TEAM_3) t3 = 1;
1697                         if (head.team == NUM_TEAM_4) t4 = 1;
1698                 }
1699                 head = find(head, classname, "onslaught_generator");
1700         }
1701         if (t1 + t2 + t3 + t4 < 2)
1702         {
1703                 // game over, only one team remains (or none)
1704                 ClearWinners();
1705                 if (t1) SetWinners(team, NUM_TEAM_1);
1706                 if (t2) SetWinners(team, NUM_TEAM_2);
1707                 if (t3) SetWinners(team, NUM_TEAM_3);
1708                 if (t4) SetWinners(team, NUM_TEAM_4);
1709                 dprint("Have a winner, ending game.\n");
1710                 return WINNING_YES;
1711         }
1712
1713         // Two or more teams remain
1714         return WINNING_NO;
1715 }
1716
1717 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1718 // they win. Otherwise the defending team wins once the timelimit passes.
1719 void assault_new_round();
1720 float WinningCondition_Assault()
1721 {
1722         float status;
1723
1724         WinningConditionHelper(); // set worldstatus
1725
1726         status = WINNING_NO;
1727         // as the timelimit has not yet passed just assume the defending team will win
1728         if(assault_attacker_team == NUM_TEAM_1)
1729         {
1730                 SetWinners(team, NUM_TEAM_2);
1731         }
1732         else
1733         {
1734                 SetWinners(team, NUM_TEAM_1);
1735         }
1736
1737         entity ent;
1738         ent = find(world, classname, "target_assault_roundend");
1739         if(ent)
1740         {
1741                 if(ent.winning) // round end has been triggered by attacking team
1742                 {
1743                         bprint("ASSAULT: round completed...\n");
1744                         SetWinners(team, assault_attacker_team);
1745
1746                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1747
1748                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1749                         {
1750                                 status = WINNING_YES;
1751                         }
1752                         else
1753                         {
1754                                 entity oldself;
1755                                 oldself = self;
1756                                 self = ent;
1757                                 assault_new_round();
1758                                 self = oldself;
1759                         }
1760                 }
1761         }
1762
1763         return status;
1764 }
1765
1766 // LMS winning condition: game terminates if and only if there's at most one
1767 // one player who's living lives. Top two scores being equal cancels the time
1768 // limit.
1769 float WinningCondition_LMS()
1770 {
1771         entity head, head2;
1772         float have_player;
1773         float have_players;
1774         float l;
1775
1776         have_player = false;
1777         have_players = false;
1778         l = LMS_NewPlayerLives();
1779
1780         head = find(world, classname, "player");
1781         if(head)
1782                 have_player = true;
1783         head2 = find(head, classname, "player");
1784         if(head2)
1785                 have_players = true;
1786
1787         if(have_player)
1788         {
1789                 // we have at least one player
1790                 if(have_players)
1791                 {
1792                         // two or more active players - continue with the game
1793                 }
1794                 else
1795                 {
1796                         // exactly one player?
1797
1798                         ClearWinners();
1799                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1800
1801                         if(l)
1802                         {
1803                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1804                                 return WINNING_NO;
1805                         }
1806                         else
1807                         {
1808                                 // a winner!
1809                                 // and assign him his first place
1810                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1811                                 return WINNING_YES;
1812                         }
1813                 }
1814         }
1815         else
1816         {
1817                 // nobody is playing at all...
1818                 if(l)
1819                 {
1820                         // wait for players...
1821                 }
1822                 else
1823                 {
1824                         // SNAFU (maybe a draw game?)
1825                         ClearWinners();
1826                         dprint("No players, ending game.\n");
1827                         return WINNING_YES;
1828                 }
1829         }
1830
1831         // When we get here, we have at least two players who are actually LIVING,
1832         // now check if the top two players have equal score.
1833         WinningConditionHelper();
1834
1835         ClearWinners();
1836         if(WinningConditionHelper_winner)
1837                 WinningConditionHelper_winner.winning = true;
1838         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1839                 return WINNING_NEVER;
1840
1841         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1842         return WINNING_NO;
1843 }
1844
1845 void ShuffleMaplist()
1846 {
1847         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1848 }
1849
1850 float leaderfrags;
1851 float WinningCondition_Scores(float limit, float leadlimit)
1852 {
1853         float limitreached;
1854
1855         // TODO make everything use THIS winning condition (except LMS)
1856         WinningConditionHelper();
1857
1858         if(teamplay)
1859         {
1860                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1861                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1862                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1863                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1864         }
1865
1866         ClearWinners();
1867         if(WinningConditionHelper_winner)
1868                 WinningConditionHelper_winner.winning = 1;
1869         if(WinningConditionHelper_winnerteam >= 0)
1870                 SetWinners(team, WinningConditionHelper_winnerteam);
1871
1872         if(WinningConditionHelper_lowerisbetter)
1873         {
1874                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1875                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1876                 limit = -limit;
1877         }
1878
1879         if(WinningConditionHelper_zeroisworst)
1880                 leadlimit = 0; // not supported in this mode
1881
1882         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1883         // these modes always score in increments of 1, thus this makes sense
1884         {
1885                 if(leaderfrags != WinningConditionHelper_topscore)
1886                 {
1887                         leaderfrags = WinningConditionHelper_topscore;
1888
1889                         if (limit)
1890                         if (leaderfrags == limit - 1)
1891                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1892                         else if (leaderfrags == limit - 2)
1893                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1894                         else if (leaderfrags == limit - 3)
1895                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1896                 }
1897         }
1898
1899         limitreached = false;
1900         if(limit)
1901                 if(WinningConditionHelper_topscore >= limit)
1902                         limitreached = true;
1903         if(leadlimit)
1904         {
1905                 float leadlimitreached;
1906                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1907                 if(autocvar_leadlimit_and_fraglimit)
1908                         limitreached = (limitreached && leadlimitreached);
1909                 else
1910                         limitreached = (limitreached || leadlimitreached);
1911         }
1912
1913         if(limit)
1914                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1915
1916         return GetWinningCode(
1917                 WinningConditionHelper_topscore && limitreached,
1918                 WinningConditionHelper_equality
1919         );
1920 }
1921
1922 float WinningCondition_Race(float fraglimit)
1923 {
1924         float wc;
1925         entity p;
1926         float n, c;
1927
1928         n = 0;
1929         c = 0;
1930         FOR_EACH_PLAYER(p)
1931         {
1932                 ++n;
1933                 if(p.race_completed)
1934                         ++c;
1935         }
1936         if(n && (n == c))
1937                 return WINNING_YES;
1938         wc = WinningCondition_Scores(fraglimit, 0);
1939
1940         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1941         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1942         // do NOT support equality when the laps are all raced!
1943                 return WINNING_STARTSUDDENDEATHOVERTIME;
1944         else
1945                 return WINNING_NEVER;
1946 }
1947
1948 float WinningCondition_QualifyingThenRace(float limit)
1949 {
1950         float wc;
1951         wc = WinningCondition_Scores(limit, 0);
1952
1953         // NEVER initiate overtime
1954         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1955         {
1956                 return WINNING_YES;
1957         }
1958
1959         return wc;
1960 }
1961
1962 float WinningCondition_RanOutOfSpawns()
1963 {
1964         entity head;
1965
1966         if(have_team_spawns <= 0)
1967                 return WINNING_NO;
1968
1969         if(autocvar_g_spawn_useallspawns <= 0)
1970                 return WINNING_NO;
1971
1972         if(!some_spawn_has_been_used)
1973                 return WINNING_NO;
1974
1975         team1_score = team2_score = team3_score = team4_score = 0;
1976
1977         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1978         {
1979                 if(head.team == NUM_TEAM_1)
1980                         team1_score = 1;
1981                 else if(head.team == NUM_TEAM_2)
1982                         team2_score = 1;
1983                 else if(head.team == NUM_TEAM_3)
1984                         team3_score = 1;
1985                 else if(head.team == NUM_TEAM_4)
1986                         team4_score = 1;
1987         }
1988
1989         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1990         {
1991                 if(head.team == NUM_TEAM_1)
1992                         team1_score = 1;
1993                 else if(head.team == NUM_TEAM_2)
1994                         team2_score = 1;
1995                 else if(head.team == NUM_TEAM_3)
1996                         team3_score = 1;
1997                 else if(head.team == NUM_TEAM_4)
1998                         team4_score = 1;
1999         }
2000
2001         ClearWinners();
2002         if(team1_score + team2_score + team3_score + team4_score == 0)
2003         {
2004                 checkrules_equality = true;
2005                 return WINNING_YES;
2006         }
2007         else if(team1_score + team2_score + team3_score + team4_score == 1)
2008         {
2009                 float t, i;
2010                 if(team1_score)
2011                         t = NUM_TEAM_1;
2012                 else if(team2_score)
2013                         t = NUM_TEAM_2;
2014                 else if(team3_score)
2015                         t = NUM_TEAM_3;
2016                 else // if(team4_score)
2017                         t = NUM_TEAM_4;
2018                 CheckAllowedTeams(world);
2019                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2020                 {
2021                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2022                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2023                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2024                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2025                 }
2026
2027                 AddWinners(team, t);
2028                 return WINNING_YES;
2029         }
2030         else
2031                 return WINNING_NO;
2032 }
2033
2034 /*
2035 ============
2036 CheckRules_World
2037
2038 Exit deathmatch games upon conditions
2039 ============
2040 */
2041 void ReadyRestart();
2042 void CheckRules_World()
2043 {
2044         float timelimit;
2045         float fraglimit;
2046         float leadlimit;
2047
2048         VoteThink();
2049         MapVote_Think();
2050
2051         SetDefaultAlpha();
2052
2053         if (gameover)   // someone else quit the game already
2054         {
2055                 if(player_count == 0) // Nobody there? Then let's go to the next map
2056                         MapVote_Start();
2057                         // this will actually check the player count in the next frame
2058                         // again, but this shouldn't hurt
2059                 return;
2060         }
2061
2062         timelimit = autocvar_timelimit * 60;
2063         fraglimit = autocvar_fraglimit;
2064         leadlimit = autocvar_leadlimit;
2065
2066         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2067         {
2068                 if(timelimit > 0)
2069                         timelimit = 0; // timelimit is not made for warmup
2070                 if(fraglimit > 0)
2071                         fraglimit = 0; // no fraglimit for now
2072                 leadlimit = 0; // no leadlimit for now
2073         }
2074
2075         if(timelimit > 0)
2076         {
2077                 timelimit += game_starttime;
2078         }
2079         else if (timelimit < 0)
2080         {
2081                 // endmatch
2082                 NextLevel();
2083                 return;
2084         }
2085
2086         if(g_onslaught)
2087                 timelimit = 0; // ONS has its own overtime rule
2088
2089         float wantovertime;
2090         wantovertime = 0;
2091
2092         if(timelimit > game_starttime)
2093                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2094         else
2095                 game_completion_ratio = 0;
2096
2097         if(checkrules_suddendeathend)
2098         {
2099                 if(!checkrules_suddendeathwarning)
2100                 {
2101                         checkrules_suddendeathwarning = true;
2102                         if(g_race && !g_race_qualifying)
2103                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2104                         else
2105                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2106                 }
2107         }
2108         else
2109         {
2110                 if (timelimit && time >= timelimit)
2111                 {
2112                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2113                         {
2114                                 float totalplayers;
2115                                 float playerswithlaps;
2116                                 float readyplayers;
2117                                 entity head;
2118                                 totalplayers = playerswithlaps = readyplayers = 0;
2119                                 FOR_EACH_PLAYER(head)
2120                                 {
2121                                         ++totalplayers;
2122                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2123                                                 ++playerswithlaps;
2124                                         if(head.ready)
2125                                                 ++readyplayers;
2126                                 }
2127
2128                                 // at least 2 of the players have completed a lap: start the RACE
2129                                 // otherwise, the players should end the qualifying on their own
2130                                 if(readyplayers || playerswithlaps >= 2)
2131                                 {
2132                                         checkrules_suddendeathend = 0;
2133                                         ReadyRestart(); // go to race
2134                                         return;
2135                                 }
2136                                 else
2137                                         wantovertime |= InitiateSuddenDeath();
2138                         }
2139                         else
2140                                 wantovertime |= InitiateSuddenDeath();
2141                 }
2142         }
2143
2144         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2145         {
2146                 NextLevel();
2147                 return;
2148         }
2149
2150         float checkrules_status;
2151         checkrules_status = WinningCondition_RanOutOfSpawns();
2152         if(checkrules_status == WINNING_YES)
2153         {
2154                 bprint("Hey! Someone ran out of spawns!\n");
2155         }
2156         else if(g_race && !g_race_qualifying && timelimit >= 0)
2157         {
2158                 checkrules_status = WinningCondition_Race(fraglimit);
2159                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2160         }
2161         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2162         {
2163                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2164                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2165         }
2166         else if(g_assault)
2167         {
2168                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2169         }
2170         else if(g_lms)
2171         {
2172                 checkrules_status = WinningCondition_LMS();
2173         }
2174         else if (g_onslaught)
2175         {
2176                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2177         }
2178         else
2179         {
2180                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2181                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2182         }
2183
2184         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2185         {
2186                 checkrules_status = WINNING_NEVER;
2187                 checkrules_overtimesadded = -1;
2188                 wantovertime |= InitiateSuddenDeath();
2189         }
2190
2191         if(checkrules_status == WINNING_NEVER)
2192                 // equality cases! Nobody wins if the overtime ends in a draw.
2193                 ClearWinners();
2194
2195         if(wantovertime)
2196         {
2197                 if(checkrules_status == WINNING_NEVER)
2198                         InitiateOvertime();
2199                 else
2200                         checkrules_status = WINNING_YES;
2201         }
2202
2203         if(checkrules_suddendeathend)
2204                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2205                         checkrules_status = WINNING_YES;
2206
2207         if(checkrules_status == WINNING_YES)
2208         {
2209                 //print("WINNING\n");
2210                 NextLevel();
2211         }
2212 }
2213
2214 string GotoMap(string m)
2215 {
2216         m = GameTypeVote_MapInfo_FixName(m);
2217         if (!m)
2218                 return "The map you suggested is not available on this server.";
2219         if (!autocvar_sv_vote_gametype)
2220         if(!MapInfo_CheckMap(m))
2221                 return "The map you suggested does not support the current game mode.";
2222         cvar_set("nextmap", m);
2223         cvar_set("timelimit", "-1");
2224         if(mapvote_initialized || alreadychangedlevel)
2225         {
2226                 if(DoNextMapOverride(0))
2227                         return "Map switch initiated.";
2228                 else
2229                         return "Hm... no. For some reason I like THIS map more.";
2230         }
2231         else
2232                 return "Map switch will happen after scoreboard.";
2233 }
2234
2235
2236 void EndFrame()
2237 {
2238         anticheat_endframe();
2239
2240         float altime;
2241         FOR_EACH_REALCLIENT(self)
2242         {
2243                 entity e = IS_SPEC(self) ? self.enemy : self;
2244                 if(e.typehitsound)
2245                         self.typehit_time = time;
2246                 else if(e.damage_dealt)
2247                 {
2248                         self.hit_time = time;
2249                         self.damage_dealt_total += ceil(e.damage_dealt);
2250                 }
2251         }
2252         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2253         // add 1 frametime because after this, engine SV_Physics
2254         // increases time by a frametime and then networks the frame
2255         // add another frametime because client shows everything with
2256         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2257         // needed!
2258         FOR_EACH_CLIENT(self)
2259         {
2260                 self.typehitsound = false;
2261                 self.damage_dealt = 0;
2262                 antilag_record(self, altime);
2263         }
2264         FOR_EACH_MONSTER(self)
2265                 antilag_record(self, altime);
2266 }
2267
2268
2269 /*
2270  * RedirectionThink:
2271  * returns true if redirecting
2272  */
2273 float redirection_timeout;
2274 float redirection_nextthink;
2275 float RedirectionThink()
2276 {
2277         float clients_found;
2278
2279         if(redirection_target == "")
2280                 return false;
2281
2282         if(!redirection_timeout)
2283         {
2284                 cvar_set("sv_public", "-2");
2285                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2286                 if(redirection_target == "self")
2287                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2288                 else
2289                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2290         }
2291
2292         if(time < redirection_nextthink)
2293                 return true;
2294
2295         redirection_nextthink = time + 1;
2296
2297         clients_found = 0;
2298         FOR_EACH_REALCLIENT(self)
2299         {
2300                 // TODO add timer
2301                 print("Redirecting: sending connect command to ", self.netname, "\n");
2302                 if(redirection_target == "self")
2303                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2304                 else
2305                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2306                 ++clients_found;
2307         }
2308
2309         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2310
2311         if(time > redirection_timeout || clients_found == 0)
2312                 localcmd("\nwait; wait; wait; quit\n");
2313
2314         return true;
2315 }
2316
2317 void TargetMusic_RestoreGame();
2318 void RestoreGame()
2319 {
2320         // Loaded from a save game
2321         // some things then break, so let's work around them...
2322
2323         // Progs DB (capture records)
2324         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2325
2326         // Mapinfo
2327         MapInfo_Shutdown();
2328         MapInfo_Enumerate();
2329         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2330         WeaponStats_Init();
2331
2332         TargetMusic_RestoreGame();
2333 }
2334
2335 void Shutdown()
2336 {
2337         gameover = 2;
2338
2339         if(world_initialized > 0)
2340         {
2341                 world_initialized = 0;
2342                 print("Saving persistent data...\n");
2343                 Ban_SaveBans();
2344
2345                 // playerstats with unfinished match
2346                 PlayerStats_GameReport(false);
2347
2348                 if(!cheatcount_total)
2349                 {
2350                         if(autocvar_sv_db_saveasdump)
2351                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2352                         else
2353                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2354                 }
2355                 if(autocvar_developer)
2356                 {
2357                         if(autocvar_sv_db_saveasdump)
2358                                 db_dump(TemporaryDB, "server-temp.db");
2359                         else
2360                                 db_save(TemporaryDB, "server-temp.db");
2361                 }
2362                 CheatShutdown(); // must be after cheatcount check
2363                 db_close(ServerProgsDB);
2364                 db_close(TemporaryDB);
2365                 print("done!\n");
2366                 // tell the bot system the game is ending now
2367                 bot_endgame();
2368
2369                 WeaponStats_Shutdown();
2370                 MapInfo_Shutdown();
2371         }
2372         else if(world_initialized == 0)
2373         {
2374                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2375         }
2376 }