qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(autocvar__sv_init)
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(autocvar_g_maplist_shuffle)
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 239 #define BADCVAR(p) if(k == p) continue
 240
 241                 // general excludes and namespaces for server admin used cvars
 242                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 243
 244                 // internal
 245                 BADPREFIX("csqc_");
 246                 BADPREFIX("cvar_check_");
 247                 BADCVAR("gamecfg");
 248                 BADCVAR("g_configversion");
 249                 BADCVAR("g_maplist_index");
 250                 BADCVAR("halflifebsp");
 251                 BADPREFIX("sv_world");
 252
 253                 // client
 254                 BADPREFIX("chase_");
 255                 BADPREFIX("cl_");
 256                 BADPREFIX("con_");
 257                 BADPREFIX("scoreboard_");
 258                 BADPREFIX("g_campaign");
 259                 BADPREFIX("gl_");
 260                 BADPREFIX("joy");
 261                 BADPREFIX("hud_");
 262                 BADPREFIX("m_");
 263                 BADPREFIX("menu_");
 264                 BADPREFIX("net_slist_");
 265                 BADPREFIX("r_");
 266                 BADPREFIX("sbar_");
 267                 BADPREFIX("scr_");
 268                 BADPREFIX("snd_");
 269                 BADPREFIX("show");
 270                 BADPREFIX("sensitivity");
 271                 BADPREFIX("userbind");
 272                 BADPREFIX("v_");
 273                 BADPREFIX("vid_");
 274                 BADPREFIX("crosshair");
 275                 BADCVAR("mod_q3bsp_lightmapmergepower");
 276                 BADCVAR("mod_q3bsp_nolightmaps");
 277                 BADCVAR("fov");
 278                 BADCVAR("mastervolume");
 279                 BADCVAR("volume");
 280                 BADCVAR("bgmvolume");
 281
 282                 // private
 283                 BADCVAR("developer");
 284                 BADCVAR("g_banned_list");
 285                 BADCVAR("log_dest_udp");
 286                 BADCVAR("log_file");
 287                 BADCVAR("net_address");
 288                 BADCVAR("net_address_ipv6");
 289                 BADCVAR("port");
 290                 BADCVAR("savedgamecfg");
 291                 BADCVAR("serverconfig");
 292                 BADCVAR("sv_heartbeatperiod");
 293                 BADCVAR("sv_vote_master_password");
 294                 BADCVAR("sys_colortranslation");
 295                 BADCVAR("sys_specialcharactertranslation");
 296                 BADCVAR("timestamps");
 297                 BADPREFIX("developer_");
 298                 BADPREFIX("g_ban_");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_voice_flood_");
 301                 BADPREFIX("rcon_");
 302                 BADPREFIX("settemp_");
 303                 BADPREFIX("sv_allowdownloads_");
 304                 BADPREFIX("sv_autodemo");
 305                 BADPREFIX("sv_curl_");
 306                 BADPREFIX("sv_eventlog");
 307                 BADPREFIX("sv_logscores_");
 308                 BADPREFIX("sv_master");
 309                 BADPREFIX("sv_weaponstats_");
 310
 311                 // these can contain player IDs, so better hide
 312                 BADCVAR("g_forced_team_red");
 313                 BADCVAR("g_forced_team_blue");
 314                 BADCVAR("g_forced_team_yellow");
 315                 BADCVAR("g_forced_team_pink");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_checkforpacketsduringsleep");
 387                 BADCVAR("sv_timeout");
 388                 BADCVAR("welcome_message_time");
 389                 BADPREFIX("crypto_");
 390                 BADPREFIX("g_chat_");
 391                 BADPREFIX("g_ctf_captimerecord_");
 392                 BADPREFIX("g_maplist_votable_");
 393                 BADPREFIX("net_");
 394                 BADPREFIX("prvm_");
 395                 BADPREFIX("skill_");
 396                 BADPREFIX("sv_fragmessage_");
 397                 BADPREFIX("sv_maxidle_");
 398                 BADPREFIX("sv_vote_");
 399                 BADPREFIX("timelimit_");
 400
 401                 // allowed changes to server admins (please sync this to server.cfg)
 402                 // vi commands:
 403                 //   :/"impure"/,$d
 404                 //   :g!,^\/\/[^ /],d
 405                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 406                 //   :%!sort
 407                 // yes, this does contain some redundant stuff, don't really care
 408                 BADCVAR("bot_number");
 409                 BADCVAR("bot_prefix");
 410                 BADCVAR("bot_suffix");
 411                 BADCVAR("capturelimit_override");
 412                 BADCVAR("fraglimit_override");
 413                 BADCVAR("gametype");
 414                 BADCVAR("g_antilag");
 415                 BADCVAR("g_balance_teams");
 416                 BADCVAR("g_balance_teams_force");
 417                 BADCVAR("g_ban_sync_trusted_servers");
 418                 BADCVAR("g_ban_sync_uri");
 419                 BADCVAR("g_ctf_capture_limit");
 420                 BADCVAR("g_ctf_ignore_frags");
 421                 BADCVAR("g_ctf_win_mode");
 422                 BADCVAR("g_domination_point_limit");
 423                 BADCVAR("g_fullbrightitems");
 424                 BADCVAR("g_fullbrightplayers");
 425                 BADCVAR("g_keyhunt_point_limit");
 426                 BADCVAR("g_keyhunt_teams_override");
 427                 BADCVAR("g_lms_lives_override");
 428                 BADCVAR("g_maplist");
 429                 BADCVAR("g_maplist_check_waypoints");
 430                 BADCVAR("g_maplist_mostrecent_count");
 431                 BADCVAR("g_maplist_shuffle");
 432                 BADCVAR("g_maplist_votable");
 433                 BADCVAR("g_maplist_votable_abstain");
 434                 BADCVAR("g_maplist_votable_nodetail");
 435                 BADCVAR("g_maplist_votable_suggestions");
 436                 BADCVAR("g_minstagib");
 437                 BADCVAR("g_nexball_goallimit");
 438                 BADCVAR("g_runematch_point_limit");
 439                 BADCVAR("g_start_delay");
 440                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 441                 BADCVAR("hostname");
 442                 BADCVAR("log_file");
 443                 BADCVAR("maxplayers");
 444                 BADCVAR("g_maxplayers");
 445                 BADCVAR("minplayers");
 446                 BADCVAR("net_address");
 447                 BADCVAR("port");
 448                 BADCVAR("rcon_password");
 449                 BADCVAR("rcon_restricted_commands");
 450                 BADCVAR("rcon_restricted_password");
 451                 BADCVAR("skill");
 452                 BADCVAR("sv_adminnick");
 453                 BADCVAR("sv_autoscreenshot");
 454                 BADCVAR("sv_curl_defaulturl");
 455                 BADCVAR("sv_defaultcharacter");
 456                 BADCVAR("sv_defaultplayercolors");
 457                 BADCVAR("sv_defaultplayermodel");
 458                 BADCVAR("sv_defaultplayerskin");
 459                 BADCVAR("sv_maxidle");
 460                 BADCVAR("sv_maxrate");
 461                 BADCVAR("sv_motd");
 462                 BADCVAR("sv_public");
 463                 BADCVAR("sv_ready_restart");
 464                 BADCVAR("sv_status_privacy");
 465                 BADCVAR("sv_vote_call");
 466                 BADCVAR("sv_vote_commands");
 467                 BADCVAR("sv_vote_majority_factor");
 468                 BADCVAR("sv_vote_master");
 469                 BADCVAR("sv_vote_master_commands");
 470                 BADCVAR("sv_vote_master_password");
 471                 BADCVAR("sv_vote_simple_majority_factor");
 472                 BADCVAR("timelimit_override");
 473                 BADCVAR("g_warmup");
 474                 BADPREFIX("g_warmup_");
 475                 BADCVAR("teamplay_mode");
 476
 477                 if(autocvar_g_minstagib)
 478                 {
 479                         BADCVAR("g_grappling_hook");
 480                         BADCVAR("g_jetpack");
 481                 }
 482 #undef BADPREFIX
 483 #undef BADCVAR
 484
 485                 if(pureadding)
 486                 {
 487                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 488                         if(strlen(cvar_purechanges) > 16384)
 489                         {
 490                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 491                                 pureadding = 0;
 492                         }
 493                 }
 494                 ++cvar_purechanges_count;
 495                 // WARNING: this variable is used for the server list
 496                 // NEVER dare to skip this code!
 497                 // Hacks to intentionally appearing as "pure server" even though you DO have
 498                 // modified settings may be punished by removal from the server list.
 499                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 500                 // though.
 501         }
 502         buf_del(h);
 503         if(cvar_changes == "")
 504                 cvar_changes = "// this server runs at default server settings\n";
 505         else
 506                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 507         cvar_changes = strzone(cvar_changes);
 508         if(cvar_purechanges == "")
 509                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 510         else
 511                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 512         cvar_purechanges = strzone(cvar_purechanges);
 513 }
 514
 515 void detect_maptype()
 516 {
 517 #if 0
 518         vector o, v;
 519         float i;
 520
 521         for(;;)
 522         {
 523                 o = world.mins;
 524                 o_x += random() * (world.maxs_x - world.mins_x);
 525                 o_y += random() * (world.maxs_y - world.mins_y);
 526                 o_z += random() * (world.maxs_z - world.mins_z);
 527
 528                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 529                 if(trace_fraction == 1)
 530                         continue;
 531
 532                 v = trace_endpos;
 533
 534                 for(i = 0; i < 64; i += 4)
 535                 {
 536                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 537         if(trace_fraction == 1)
 538                 continue;
 539                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 540                 }
 541
 542                 break;
 543         }
 544 #endif
 545 }
 546
 547 entity randomseed;
 548 float RandomSeed_Send(entity to, float sf)
 549 {
 550         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 551         WriteShort(MSG_ENTITY, self.cnt);
 552         return TRUE;
 553 }
 554 void RandomSeed_Think()
 555 {
 556         self.cnt = bound(0, floor(random() * 65536), 65535);
 557         self.nextthink = time + 5;
 558
 559         self.SendFlags |= 1;
 560 }
 561 void RandomSeed_Spawn()
 562 {
 563         randomseed = spawn();
 564         randomseed.think = RandomSeed_Think;
 565         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 566
 567         entity oldself;
 568         oldself = self;
 569         self = randomseed;
 570         self.think(); // sets random seed and nextthink
 571         self = oldself;
 572 }
 573
 574 void spawnfunc___init_dedicated_server(void)
 575 {
 576         // handler for _init/_init map (only for dedicated server initialization)
 577
 578         world_initialized = -1; // don't complain
 579         cvar = cvar_normal;
 580         cvar_string = cvar_string_normal;
 581         cvar_set = cvar_set_normal;
 582
 583         remove = remove_unsafely;
 584
 585         entity e;
 586         e = spawn();
 587         e.think = GotoFirstMap;
 588         e.nextthink = time; // this is usually 1 at this point
 589
 590         e = spawn();
 591         e.classname = "info_player_deathmatch"; // safeguard against player joining
 592
 593         self.classname = "worldspawn"; // safeguard against various stuff ;)
 594
 595         MapInfo_Enumerate();
 596         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 597 }
 598
 599 void Map_MarkAsRecent(string m);
 600 float world_already_spawned;
 601 void RegisterWeapons();
 602 void Nagger_Init();
 603 void ClientInit_Spawn();
 604 void WeaponStats_Init();
 605 void WeaponStats_Shutdown();
 606 void spawnfunc_worldspawn (void)
 607 {
 608         float fd, l, i, j, n;
 609         string s, col;
 610
 611         cvar = cvar_normal;
 612         cvar_string = cvar_string_normal;
 613         cvar_set = cvar_set_normal;
 614
 615         if(world_already_spawned)
 616                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 617         world_already_spawned = TRUE;
 618
 619         remove = remove_safely; // during spawning, watch what you remove!
 620
 621         check_unacceptable_compiler_bugs();
 622
 623         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 624
 625         compressShortVector_init();
 626
 627         allowed_to_spawn = TRUE;
 628
 629         local entity head;
 630         head = nextent(world);
 631         maxclients = 0;
 632         while(head)
 633         {
 634                 ++maxclients;
 635                 head = nextent(head);
 636         }
 637
 638         // needs to be done so early as they would still spawn
 639         RegisterWeapons();
 640
 641         ServerProgsDB = db_load("server.db");
 642
 643         TemporaryDB = db_create();
 644
 645         // 0 normal
 646         lightstyle(0, "m");
 647
 648         // 1 FLICKER (first variety)
 649         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 650
 651         // 2 SLOW STRONG PULSE
 652         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 653
 654         // 3 CANDLE (first variety)
 655         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 656
 657         // 4 FAST STROBE
 658         lightstyle(4, "mamamamamama");
 659
 660         // 5 GENTLE PULSE 1
 661         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 662
 663         // 6 FLICKER (second variety)
 664         lightstyle(6, "nmonqnmomnmomomno");
 665
 666         // 7 CANDLE (second variety)
 667         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 668
 669         // 8 CANDLE (third variety)
 670         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 671
 672         // 9 SLOW STROBE (fourth variety)
 673         lightstyle(9, "aaaaaaaazzzzzzzz");
 674
 675         // 10 FLUORESCENT FLICKER
 676         lightstyle(10, "mmamammmmammamamaaamammma");
 677
 678         // 11 SLOW PULSE NOT FADE TO BLACK
 679         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 680
 681         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 682
 683         // 63 testing
 684         lightstyle(63, "a");
 685
 686         if(autocvar_g_campaign)
 687                 CampaignPreInit();
 688
 689         Map_MarkAsRecent(mapname);
 690
 691         precache_model ("null"); // we need this one before InitGameplayMode
 692         InitGameplayMode();
 693         readlevelcvars();
 694         GrappleHookInit();
 695         ElectroInit();
 696         LaserInit();
 697
 698         player_count = 0;
 699         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 700         if(bot_waypoints_for_items == 1)
 701                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 702                         bot_waypoints_for_items = 0;
 703
 704         // for setting by mapinfo
 705         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 706         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 707
 708         precache();
 709
 710         WaypointSprite_Init();
 711
 712         //if (g_domination)
 713         //      dom_init();
 714
 715         GameLogInit(); // prepare everything
 716         if(autocvar_sv_eventlog)
 717         {
 718                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 719                 s = strcat(s, ftos(random()));
 720                 matchid = strzone(s);
 721
 722                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 723                 s = ":gameinfo:mutators:LIST";
 724
 725                 ret_string = s;
 726                 MUTATOR_CALLHOOK(BuildMutatorsString);
 727                 s = ret_string;
 728
 729                 // simple, probably not good in the mutator system
 730                 if(autocvar_g_grappling_hook)
 731                         s = strcat(s, ":grappling_hook");
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_pickup_items)
 739                         s = strcat(s, ":no_pickup_items");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(autocvar_g_weaponarena != "0")
 743                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 744
 745                 // TODO to mutator system
 746                 if(autocvar_g_norecoil)
 747                         s = strcat(s, ":norecoil");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_midair)
 751                         s = strcat(s, ":midair");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_minstagib)
 755                         s = strcat(s, ":minstagib");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         fteqcc_testbugs();
 771
 772         Ban_LoadBans();
 773
 774         MapInfo_Enumerate();
 775         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 776
 777         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 778         {
 779                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 780                 if(fd != -1)
 781                 {
 782                         while((s = fgets(fd)))
 783                         {
 784                                 l = tokenize_console(s);
 785                                 if(l < 2)
 786                                         continue;
 787                                 if(argv(0) == "cd")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 790                                         print("  cdtrack ", argv(2), "\n");
 791                                 }
 792                                 else if(argv(0) == "fog")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 795                                         print("  \"fog\" \"", s, "\"\n");
 796                                 }
 797                                 else if(argv(0) == "set")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 801                                 }
 802                                 else if(argv(0) != "//")
 803                                 {
 804                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 805                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 806                                 }
 807                         }
 808                         fclose(fd);
 809                 }
 810         }
 811
 812         WeaponStats_Init();
 813
 814         addstat(STAT_WEAPONS, AS_INT, weapons);
 815         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 816         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 817         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 818         Nagger_Init();
 819
 820         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 821         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 822         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 823         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 824         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 825         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 826         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 827         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 828         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 829         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 830         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 831         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 832
 833         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 834         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 835
 836         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 837
 838         if(g_ca || g_freezetag)
 839         {
 840                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 841                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 842                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 843                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 844         }
 845         if(g_freezetag)
 846         {
 847                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 848                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 849         }
 850
 851         // g_movementspeed hack
 852         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 853         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 854         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 855         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 856
 857         next_pingtime = time + 5;
 858
 859         detect_maptype();
 860
 861         lsmaps_reply = "^7Maps available: ";
 862         lsnewmaps_reply = "^7Maps without a record set: ";
 863         for(i = 0, j = 0; i < MapInfo_count; ++i)
 864         {
 865                 if(MapInfo_Get_ByID(i))
 866                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 867                         {
 868                                 if(mod(i, 2))
 869                                         col = "^2";
 870                                 else
 871                                         col = "^3";
 872                                 ++j;
 873                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 874                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 875                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 876                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 877                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 878                         }
 879         }
 880         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 881         if (!g_race && !g_cts)
 882                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 883         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 884
 885         maplist_reply = "^7Maps in list: ";
 886         n = tokenize_console(autocvar_g_maplist);
 887         for(i = 0, j = 0; i < n; ++i)
 888         {
 889                 if(MapInfo_CheckMap(argv(i)))
 890                 {
 891                         if(mod(j, 2))
 892                                 col = "^2";
 893                         else
 894                                 col = "^3";
 895                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 896                         ++j;
 897                 }
 898         }
 899         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 900         MapInfo_ClearTemps();
 901
 902         for(i = 0; i < 10; ++i)
 903         {
 904                 records_reply[i] = strzone(getrecords(i));
 905         }
 906         if(g_cts)
 907                 ladder_reply = strzone(getladder());
 908
 909         rankings_reply = strzone(getrankings());
 910
 911         ClientInit_Spawn();
 912         RandomSeed_Spawn();
 913         PingPLReport_Spawn();
 914
 915         CheatInit();
 916
 917         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 918
 919         // fill sv_curl_serverpackages from .serverpackage files
 920         if(autocvar_sv_curl_serverpackages_auto)
 921         {
 922                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 923                 s = "";
 924                 if(fd >= 0)
 925                 {
 926                         j = search_getsize(fd);
 927                         for(i = 0; i < j; ++i)
 928                                 s = strcat(s, " ", search_getfilename(fd, i));
 929                         search_end(fd);
 930                 }
 931                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 932         }
 933
 934         PlayerStats_Init();
 935
 936         world_initialized = 1;
 937 }
 938
 939 void spawnfunc_light (void)
 940 {
 941         //makestatic (self); // Who the f___ did that?
 942         remove(self);
 943 }
 944
 945 float TryFile( string pFilename )
 946 {
 947         local float lHandle;
 948         dprint("TryFile(\"", pFilename, "\")\n");
 949         lHandle = fopen( pFilename, FILE_READ );
 950         if( lHandle != -1 ) {
 951                 fclose( lHandle );
 952                 return TRUE;
 953         } else {
 954                 return FALSE;
 955         }
 956 };
 957
 958 string GetGametype()
 959 {
 960         return GametypeNameFromType(game);
 961 }
 962
 963 string getmapname_stored;
 964 string GetMapname()
 965 {
 966         return mapname;
 967 }
 968
 969 float Map_Count, Map_Current;
 970 string Map_Current_Name;
 971
 972 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 973 float GetMaplistPosition()
 974 {
 975         float pos, idx;
 976         string map;
 977
 978         map = GetMapname();
 979         idx = autocvar_g_maplist_index;
 980
 981         if(idx >= 0)
 982                 if(idx < Map_Count)
 983                         if(map == argv(idx))
 984                                 return idx;
 985
 986         for(pos = 0; pos < Map_Count; ++pos)
 987                 if(map == argv(pos))
 988                         return pos;
 989
 990         // resume normal maplist rotation if current map is not in g_maplist
 991         return idx;
 992 }
 993
 994 float MapHasRightSize(string map)
 995 {
 996         float fh;
 997         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 998         if(autocvar_g_maplist_check_waypoints)
 999         {
1000                 dprint("checkwp "); dprint(map);
1001                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
1002                 if(fh < 0)
1003                 {
1004                         dprint(": no waypoints\n");
1005                         return FALSE;
1006                 }
1007                 dprint(": has waypoints\n");
1008                 fclose(fh);
1009         }
1010
1011         // open map size restriction file
1012         dprint("opensize "); dprint(map);
1013         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1014         if(fh >= 0)
1015         {
1016                 float mapmin, mapmax;
1017                 dprint(": ok, ");
1018                 mapmin = stof(fgets(fh));
1019                 mapmax = stof(fgets(fh));
1020                 fclose(fh);
1021                 if(player_count < mapmin)
1022                 {
1023                         dprint("not enough\n");
1024                         return FALSE;
1025                 }
1026                 if(player_count > mapmax)
1027                 {
1028                         dprint("too many\n");
1029                         return FALSE;
1030                 }
1031                 dprint("right size\n");
1032                 return TRUE;
1033         }
1034         dprint(": not found\n");
1035         return TRUE;
1036 }
1037
1038 string Map_Filename(float position)
1039 {
1040         return strcat("maps/", argv(position), ".bsp");
1041 }
1042
1043 string strwords(string s, float w)
1044 {
1045         float endpos;
1046         for(endpos = 0; w && endpos >= 0; --w)
1047                 endpos = strstrofs(s, " ", endpos + 1);
1048         if(endpos < 0)
1049                 return s;
1050         else
1051                 return substring(s, 0, endpos);
1052 }
1053
1054 float strhasword(string s, string w)
1055 {
1056         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1057 }
1058
1059 void Map_MarkAsRecent(string m)
1060 {
1061         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1062 }
1063
1064 float Map_IsRecent(string m)
1065 {
1066         return strhasword(autocvar_g_maplist_mostrecent, m);
1067 }
1068
1069 float Map_Check(float position, float pass)
1070 {
1071         string filename;
1072         string map_next;
1073         map_next = argv(position);
1074         if(pass <= 1)
1075         {
1076                 if(Map_IsRecent(map_next))
1077                         return 0;
1078         }
1079         filename = Map_Filename(position);
1080         if(MapInfo_CheckMap(map_next))
1081         {
1082                 if(pass == 2)
1083                         return 1;
1084                 if(MapHasRightSize(map_next))
1085                         return 1;
1086                 return 0;
1087         }
1088         else
1089                 dprint( "Couldn't select '", filename, "'..\n" );
1090
1091         return 0;
1092 }
1093
1094 void Map_Goto_SetStr(string nextmapname)
1095 {
1096         if(getmapname_stored != "")
1097                 strunzone(getmapname_stored);
1098         if(nextmapname == "")
1099                 getmapname_stored = "";
1100         else
1101                 getmapname_stored = strzone(nextmapname);
1102 }
1103
1104 void Map_Goto_SetFloat(float position)
1105 {
1106         cvar_set("g_maplist_index", ftos(position));
1107         Map_Goto_SetStr(argv(position));
1108 }
1109
1110 void GameResetCfg()
1111 {
1112         // settings persist, except...
1113         localcmd("\nsettemp_restore\n");
1114 };
1115
1116 void Map_Goto()
1117 {
1118         GameResetCfg();
1119         MapInfo_LoadMap(getmapname_stored);
1120 }
1121
1122 // return codes of map selectors:
1123 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1124 //   -2 = permanent failure
1125 float() MaplistMethod_Iterate = // usual method
1126 {
1127         float pass, i;
1128
1129         for(pass = 1; pass <= 2; ++pass)
1130         {
1131                 for(i = 1; i < Map_Count; ++i)
1132                 {
1133                         float mapindex;
1134                         mapindex = mod(i + Map_Current, Map_Count);
1135                         if(Map_Check(mapindex, pass))
1136                                 return mapindex;
1137                 }
1138         }
1139         return -1;
1140 }
1141
1142 float() MaplistMethod_Repeat = // fallback method
1143 {
1144         if(Map_Check(Map_Current, 2))
1145                 return Map_Current;
1146         return -2;
1147 }
1148
1149 float() MaplistMethod_Random = // random map selection
1150 {
1151         float i, imax;
1152
1153         imax = 42;
1154
1155         for(i = 0; i <= imax; ++i)
1156         {
1157                 float mapindex;
1158                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1159                 if(Map_Check(mapindex, 1))
1160                         return mapindex;
1161         }
1162         return -1;
1163 }
1164
1165 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1166 // the exponent sets a bias on the map selection:
1167 // the higher the exponent, the less likely "shortly repeated" same maps are
1168 {
1169         float i, j, imax, insertpos;
1170
1171         imax = 42;
1172
1173         for(i = 0; i <= imax; ++i)
1174         {
1175                 string newlist;
1176
1177                 // now reinsert this at another position
1178                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1179                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1180                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1181                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1182
1183                 // insert the current map there
1184                 newlist = "";
1185                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1186                         newlist = strcat(newlist, " ", argv(j));
1187                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1188                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1189                         newlist = strcat(newlist, " ", argv(j));
1190                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1191                 cvar_set("g_maplist", newlist);
1192                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1193
1194                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1195                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1196                 if(Map_Check(Map_Current, 1))
1197                         return Map_Current;
1198         }
1199         return -1;
1200 }
1201
1202 void Maplist_Init()
1203 {
1204         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1205         if(Map_Count == 0)
1206         {
1207                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1208                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1209                 if(autocvar_g_maplist_shuffle)
1210                         ShuffleMaplist();
1211                 localcmd("\nmenu_cmd sync\n");
1212                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1213         }
1214         if(Map_Count == 0)
1215                 error("empty maplist, cannot select a new map");
1216         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1217
1218         if(Map_Current_Name)
1219                 strunzone(Map_Current_Name);
1220         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1221         // this may or may not be correct, but who cares, in the worst case a map
1222         // isn't chosen in the first pass that should have been
1223 }
1224
1225 string GetNextMap()
1226 {
1227         float nextMap;
1228
1229         Maplist_Init();
1230         nextMap = -1;
1231
1232         if(nextMap == -1)
1233                 if(autocvar_g_maplist_shuffle > 0)
1234                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1235
1236         if(nextMap == -1)
1237                 if(autocvar_g_maplist_selectrandom)
1238                         nextMap = MaplistMethod_Random();
1239
1240         if(nextMap == -1)
1241                 nextMap = MaplistMethod_Iterate();
1242
1243         if(nextMap == -1)
1244                 nextMap = MaplistMethod_Repeat();
1245
1246         if(nextMap >= 0)
1247         {
1248                 Map_Goto_SetFloat(nextMap);
1249                 return getmapname_stored;
1250         }
1251
1252         return "";
1253 };
1254
1255 float DoNextMapOverride()
1256 {
1257         if(autocvar_g_campaign)
1258         {
1259                 CampaignPostIntermission();
1260                 alreadychangedlevel = TRUE;
1261                 return TRUE;
1262         }
1263         if(autocvar_quit_when_empty)
1264         {
1265                 if(player_count <= currentbots)
1266                 {
1267                         localcmd("quit\n");
1268                         alreadychangedlevel = TRUE;
1269                         return TRUE;
1270                 }
1271         }
1272         if(autocvar_quit_and_redirect != "")
1273         {
1274                 redirection_target = strzone(autocvar_quit_and_redirect);
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         if (autocvar_samelevel) // if samelevel is set, stay on same level
1279         {
1280                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1281                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1282                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1283                 localcmd("restart\n");
1284                 //changelevel (mapname);
1285                 alreadychangedlevel = TRUE;
1286                 return TRUE;
1287         }
1288         if(autocvar_nextmap != "")
1289                 if(MapInfo_CheckMap(autocvar_nextmap))
1290                 {
1291                         Map_Goto_SetStr(autocvar_nextmap);
1292                         Map_Goto();
1293                         alreadychangedlevel = TRUE;
1294                         return TRUE;
1295                 }
1296         if(autocvar_lastlevel)
1297         {
1298                 GameResetCfg();
1299                 localcmd("set lastlevel 0\ntogglemenu\n");
1300                 alreadychangedlevel = TRUE;
1301                 return TRUE;
1302         }
1303         return FALSE;
1304 };
1305
1306 void GotoNextMap()
1307 {
1308         //local string nextmap;
1309         //local float n, nummaps;
1310         //local string s;
1311         if (alreadychangedlevel)
1312                 return;
1313         alreadychangedlevel = TRUE;
1314
1315         {
1316                 string nextMap;
1317                 float allowReset;
1318
1319                 for(allowReset = 1; allowReset >= 0; --allowReset)
1320                 {
1321                         nextMap = GetNextMap();
1322                         if(nextMap != "")
1323                                 break;
1324
1325                         if(allowReset)
1326                         {
1327                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1328                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1329                                 if(autocvar_g_maplist_shuffle)
1330                                         ShuffleMaplist();
1331                                 localcmd("\nmenu_cmd sync\n");
1332                         }
1333                         else
1334                         {
1335                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1336                         }
1337                 }
1338                 Map_Goto();
1339         }
1340 };
1341
1342
1343 /*
1344 ============
1345 IntermissionThink
1346
1347 When the player presses attack or jump, change to the next level
1348 ============
1349 */
1350 .float autoscreenshot;
1351 void() MapVote_Start;
1352 void() MapVote_Think;
1353 float mapvote_initialized;
1354 void IntermissionThink()
1355 {
1356         FixIntermissionClient(self);
1357
1358         if(autocvar_sv_autoscreenshot)
1359         if(self.autoscreenshot > 0)
1360         if(time > self.autoscreenshot)
1361         {
1362                 self.autoscreenshot = -1;
1363                 if(clienttype(self) == CLIENTTYPE_REAL)
1364                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1365                 return;
1366         }
1367
1368         if (time < intermission_exittime)
1369                 return;
1370
1371         if(!mapvote_initialized)
1372                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1373                         return;
1374
1375         MapVote_Start();
1376 };
1377
1378 /*
1379 ============
1380 FindIntermission
1381
1382 Returns the entity to view from
1383 ============
1384 */
1385 /*
1386 entity FindIntermission()
1387 {
1388         local   entity spot;
1389         local   float cyc;
1390
1391 // look for info_intermission first
1392         spot = find (world, classname, "info_intermission");
1393         if (spot)
1394         {       // pick a random one
1395                 cyc = random() * 4;
1396                 while (cyc > 1)
1397                 {
1398                         spot = find (spot, classname, "info_intermission");
1399                         if (!spot)
1400                                 spot = find (spot, classname, "info_intermission");
1401                         cyc = cyc - 1;
1402                 }
1403                 return spot;
1404         }
1405
1406 // then look for the start position
1407         spot = find (world, classname, "info_player_start");
1408         if (spot)
1409                 return spot;
1410
1411 // testinfo_player_start is only found in regioned levels
1412         spot = find (world, classname, "testplayerstart");
1413         if (spot)
1414                 return spot;
1415
1416 // then look for the start position
1417         spot = find (world, classname, "info_player_deathmatch");
1418         if (spot)
1419                 return spot;
1420
1421         //objerror ("FindIntermission: no spot");
1422         return world;
1423 };
1424 */
1425
1426 /*
1427 ===============================================================================
1428
1429 RULES
1430
1431 ===============================================================================
1432 */
1433
1434 void DumpStats(float final)
1435 {
1436         float file;
1437         string s;
1438         float to_console;
1439         float to_eventlog;
1440         float to_file;
1441         float i;
1442
1443         to_console = autocvar_sv_logscores_console;
1444         to_eventlog = autocvar_sv_eventlog;
1445         to_file = autocvar_sv_logscores_file;
1446
1447         if(!final)
1448         {
1449                 to_console = TRUE; // always print printstats replies
1450                 to_eventlog = FALSE; // but never print them to the event log
1451         }
1452
1453         if(to_eventlog)
1454                 if(autocvar_sv_eventlog_console)
1455                         to_console = FALSE; // otherwise we get the output twice
1456
1457         if(final)
1458                 s = ":scores:";
1459         else
1460                 s = ":status:";
1461         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1462
1463         if(to_console)
1464                 print(s, "\n");
1465         if(to_eventlog)
1466                 GameLogEcho(s);
1467         if(to_file)
1468         {
1469                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1470                 if(file == -1)
1471                         to_file = FALSE;
1472                 else
1473                         fputs(file, strcat(s, "\n"));
1474         }
1475
1476         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1477         if(to_console)
1478                 print(s, "\n");
1479         if(to_eventlog)
1480                 GameLogEcho(s);
1481         if(to_file)
1482                 fputs(file, strcat(s, "\n"));
1483
1484         FOR_EACH_CLIENT(other)
1485         {
1486                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1487                 {
1488                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1489                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1490                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1491                                 s = strcat(s, ftos(other.team), ":");
1492                         else
1493                                 s = strcat(s, "spectator:");
1494
1495                         if(to_console)
1496                                 print(s, other.netname, "\n");
1497                         if(to_eventlog)
1498                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1499                         if(to_file)
1500                                 fputs(file, strcat(s, other.netname, "\n"));
1501                 }
1502         }
1503
1504         if(teams_matter)
1505         {
1506                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1507                 if(to_console)
1508                         print(s, "\n");
1509                 if(to_eventlog)
1510                         GameLogEcho(s);
1511                 if(to_file)
1512                         fputs(file, strcat(s, "\n"));
1513
1514                 for(i = 1; i < 16; ++i)
1515                 {
1516                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1517                         s = strcat(s, ":", ftos(i));
1518                         if(to_console)
1519                                 print(s, "\n");
1520                         if(to_eventlog)
1521                                 GameLogEcho(s);
1522                         if(to_file)
1523                                 fputs(file, strcat(s, "\n"));
1524                 }
1525         }
1526
1527         if(to_console)
1528                 print(":end\n");
1529         if(to_eventlog)
1530                 GameLogEcho(":end");
1531         if(to_file)
1532         {
1533                 fputs(file, ":end\n");
1534                 fclose(file);
1535         }
1536 }
1537
1538 void FixIntermissionClient(entity e)
1539 {
1540         string s;
1541         if(!e.autoscreenshot) // initial call
1542         {
1543                 e.angles = e.v_angle;
1544                 e.angles_x = -e.angles_x;
1545                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1546                 e.health = -2342;
1547                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1548                 e.solid = SOLID_NOT;
1549                 e.movetype = MOVETYPE_NONE;
1550                 e.takedamage = DAMAGE_NO;
1551                 if(e.weaponentity)
1552                 {
1553                         e.weaponentity.effects = EF_NODRAW;
1554                         if (e.weaponentity.weaponentity)
1555                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1556                 }
1557                 if(clienttype(e) == CLIENTTYPE_REAL)
1558                 {
1559                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1560                         s = autocvar_sv_intermission_cdtrack;
1561                         if(s != "")
1562                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1563                         msg_entity = e;
1564                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1565                 }
1566         }
1567
1568         //e.velocity = '0 0 0';
1569         //e.fixangle = TRUE;
1570
1571         // TODO halt weapon animation
1572 }
1573
1574
1575 /*
1576 go to the next level for deathmatch
1577 only called if a time or frag limit has expired
1578 */
1579 void NextLevel()
1580 {
1581         gameover = TRUE;
1582
1583         intermission_running = 1;
1584
1585 // enforce a wait time before allowing changelevel
1586         if(player_count > 0)
1587                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1588         else
1589                 intermission_exittime = -1;
1590
1591         /*
1592         WriteByte (MSG_ALL, SVC_CDTRACK);
1593         WriteByte (MSG_ALL, 3);
1594         WriteByte (MSG_ALL, 3);
1595         // done in FixIntermission
1596         */
1597
1598         //pos = FindIntermission ();
1599
1600         VoteReset();
1601
1602         DumpStats(TRUE);
1603
1604         // send statistics
1605         entity e;
1606         PlayerStats_EndMatch(1);
1607         FOR_EACH_CLIENT(e)
1608                 PlayerStats_AddGlobalInfo(e);
1609         PlayerStats_Shutdown();
1610
1611         if(autocvar_sv_eventlog)
1612                 GameLogEcho(":gameover");
1613
1614         GameLogClose();
1615
1616         FOR_EACH_PLAYER(other) {
1617                 FixIntermissionClient(other);
1618                 if(other.winning)
1619                         bprint(other.netname, " ^7wins.\n");
1620         }
1621
1622         if(autocvar_g_campaign)
1623                 CampaignPreIntermission();
1624
1625         localcmd("\nsv_hook_gameend\n");
1626 }
1627
1628 /*
1629 ============
1630 CheckRules_Player
1631
1632 Exit deathmatch games upon conditions
1633 ============
1634 */
1635 void CheckRules_Player()
1636 {
1637         if (gameover)   // someone else quit the game already
1638                 return;
1639
1640         if(self.deadflag == DEAD_NO)
1641                 self.play_time += frametime;
1642
1643         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1644         //   (div0: and that in CheckRules_World please)
1645 };
1646
1647 float checkrules_equality;
1648 float checkrules_suddendeathwarning;
1649 float checkrules_suddendeathend;
1650 float checkrules_overtimesadded; //how many overtimes have been already added
1651
1652 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1653 float WINNING_YES = 1; // winner found
1654 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1655 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1656
1657 float InitiateSuddenDeath()
1658 {
1659         // Check first whether normal overtimes could be added before initiating suddendeath mode
1660         // - for this timelimit_overtime needs to be >0 of course
1661         // - also check the winning condition calculated in the previous frame and only add normal overtime
1662         //   again, if at the point at which timelimit would be extended again, still no winner was found
1663         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1664         {
1665                 return 1; // need to call InitiateOvertime later
1666         }
1667         else
1668         {
1669                 if(!checkrules_suddendeathend)
1670                 {
1671                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1672                         if(g_race && !g_race_qualifying)
1673                                 race_StartCompleting();
1674                 }
1675                 return 0;
1676         }
1677 }
1678
1679 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1680 {
1681         ++checkrules_overtimesadded;
1682         //add one more overtime by simply extending the timelimit
1683         float tl;
1684         tl = autocvar_timelimit;
1685         tl += autocvar_timelimit_overtime;
1686         cvar_set("timelimit", ftos(tl));
1687         string minutesPlural;
1688         if (autocvar_timelimit_overtime == 1)
1689                 minutesPlural = " ^3minute";
1690         else
1691                 minutesPlural = " ^3minutes";
1692
1693         bcenterprint(
1694                 strcat(
1695                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1696                         ftos(autocvar_timelimit_overtime),
1697                         minutesPlural,
1698                         " to the game!"
1699                 )
1700         );
1701 }
1702
1703 float GetWinningCode(float fraglimitreached, float equality)
1704 {
1705         if(autocvar_g_campaign == 1)
1706                 if(fraglimitreached)
1707                         return WINNING_YES;
1708                 else
1709                         return WINNING_NO;
1710
1711         else
1712                 if(equality)
1713                         if(fraglimitreached)
1714                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1715                         else
1716                                 return WINNING_NEVER;
1717                 else
1718                         if(fraglimitreached)
1719                                 return WINNING_YES;
1720                         else
1721                                 return WINNING_NO;
1722 }
1723
1724 // set the .winning flag for exactly those players with a given field value
1725 void SetWinners(.float field, float value)
1726 {
1727         entity head;
1728         FOR_EACH_PLAYER(head)
1729                 head.winning = (head.field == value);
1730 }
1731
1732 // set the .winning flag for those players with a given field value
1733 void AddWinners(.float field, float value)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 if(head.field == value)
1738                         head.winning = 1;
1739 }
1740
1741 // clear the .winning flags
1742 void ClearWinners(void)
1743 {
1744         entity head;
1745         FOR_EACH_PLAYER(head)
1746                 head.winning = 0;
1747 }
1748
1749 // Onslaught winning condition:
1750 // game terminates if only one team has a working generator (or none)
1751 float WinningCondition_Onslaught()
1752 {
1753         entity head;
1754         local float t1, t2, t3, t4;
1755
1756         WinningConditionHelper(); // set worldstatus
1757
1758         if(inWarmupStage)
1759                 return WINNING_NO;
1760
1761         // first check if the game has ended
1762         t1 = t2 = t3 = t4 = 0;
1763         head = find(world, classname, "onslaught_generator");
1764         while (head)
1765         {
1766                 if (head.health > 0)
1767                 {
1768                         if (head.team == COLOR_TEAM1) t1 = 1;
1769                         if (head.team == COLOR_TEAM2) t2 = 1;
1770                         if (head.team == COLOR_TEAM3) t3 = 1;
1771                         if (head.team == COLOR_TEAM4) t4 = 1;
1772                 }
1773                 head = find(head, classname, "onslaught_generator");
1774         }
1775         if (t1 + t2 + t3 + t4 < 2)
1776         {
1777                 // game over, only one team remains (or none)
1778                 ClearWinners();
1779                 if (t1) SetWinners(team, COLOR_TEAM1);
1780                 if (t2) SetWinners(team, COLOR_TEAM2);
1781                 if (t3) SetWinners(team, COLOR_TEAM3);
1782                 if (t4) SetWinners(team, COLOR_TEAM4);
1783                 dprint("Have a winner, ending game.\n");
1784                 return WINNING_YES;
1785         }
1786
1787         // Two or more teams remain
1788         return WINNING_NO;
1789 }
1790
1791 float LMS_NewPlayerLives()
1792 {
1793         float fl;
1794         fl = autocvar_fraglimit;
1795         if(fl == 0)
1796                 fl = 999;
1797
1798         // first player has left the game for dying too much? Nobody else can get in.
1799         if(lms_lowest_lives < 1)
1800                 return 0;
1801
1802         if(!autocvar_g_lms_join_anytime)
1803                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1804                         return 0;
1805
1806         return bound(1, lms_lowest_lives, fl);
1807 }
1808
1809 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1810 // they win. Otherwise the defending team wins once the timelimit passes.
1811 void assault_new_round();
1812 float WinningCondition_Assault()
1813 {
1814         local float status;
1815
1816         WinningConditionHelper(); // set worldstatus
1817
1818         status = WINNING_NO;
1819         // as the timelimit has not yet passed just assume the defending team will win
1820         if(assault_attacker_team == COLOR_TEAM1)
1821         {
1822                 SetWinners(team, COLOR_TEAM2);
1823         }
1824         else
1825         {
1826                 SetWinners(team, COLOR_TEAM1);
1827         }
1828
1829         local entity ent;
1830         ent = find(world, classname, "target_assault_roundend");
1831         if(ent)
1832         {
1833                 if(ent.winning) // round end has been triggered by attacking team
1834                 {
1835                         bprint("ASSAULT: round completed...\n");
1836                         SetWinners(team, assault_attacker_team);
1837
1838                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1839
1840                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1841                         {
1842                                 status = WINNING_YES;
1843                         }
1844                         else
1845                         {
1846                                 local entity oldself;
1847                                 oldself = self;
1848                                 self = ent;
1849                                 assault_new_round();
1850                                 self = oldself;
1851                         }
1852                 }
1853         }
1854
1855         return status;
1856 }
1857
1858 // LMS winning condition: game terminates if and only if there's at most one
1859 // one player who's living lives. Top two scores being equal cancels the time
1860 // limit.
1861 float WinningCondition_LMS()
1862 {
1863         entity head, head2;
1864         float have_player;
1865         float have_players;
1866         float l;
1867
1868         have_player = FALSE;
1869         have_players = FALSE;
1870         l = LMS_NewPlayerLives();
1871
1872         head = find(world, classname, "player");
1873         if(head)
1874                 have_player = TRUE;
1875         head2 = find(head, classname, "player");
1876         if(head2)
1877                 have_players = TRUE;
1878
1879         if(have_player)
1880         {
1881                 // we have at least one player
1882                 if(have_players)
1883                 {
1884                         // two or more active players - continue with the game
1885                 }
1886                 else
1887                 {
1888                         // exactly one player?
1889
1890                         ClearWinners();
1891                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1892
1893                         if(l)
1894                         {
1895                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1896                                 return WINNING_NO;
1897                         }
1898                         else
1899                         {
1900                                 // a winner!
1901                                 // and assign him his first place
1902                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1903                                 return WINNING_YES;
1904                         }
1905                 }
1906         }
1907         else
1908         {
1909                 // nobody is playing at all...
1910                 if(l)
1911                 {
1912                         // wait for players...
1913                 }
1914                 else
1915                 {
1916                         // SNAFU (maybe a draw game?)
1917                         ClearWinners();
1918                         dprint("No players, ending game.\n");
1919                         return WINNING_YES;
1920                 }
1921         }
1922
1923         // When we get here, we have at least two players who are actually LIVING,
1924         // now check if the top two players have equal score.
1925         WinningConditionHelper();
1926
1927         ClearWinners();
1928         if(WinningConditionHelper_winner)
1929                 WinningConditionHelper_winner.winning = TRUE;
1930         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1931                 return WINNING_NEVER;
1932
1933         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1934         return WINNING_NO;
1935 }
1936
1937 void ShuffleMaplist()
1938 {
1939         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1940 }
1941
1942 float leaderfrags;
1943 float WinningCondition_Scores(float limit, float leadlimit)
1944 {
1945         float limitreached;
1946
1947         // TODO make everything use THIS winning condition (except LMS)
1948         WinningConditionHelper();
1949
1950         if(teams_matter)
1951         {
1952                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1953                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1954                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1955                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1956         }
1957
1958         ClearWinners();
1959         if(WinningConditionHelper_winner)
1960                 WinningConditionHelper_winner.winning = 1;
1961         if(WinningConditionHelper_winnerteam >= 0)
1962                 SetWinners(team, WinningConditionHelper_winnerteam);
1963
1964         if(WinningConditionHelper_lowerisbetter)
1965         {
1966                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1967                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1968                 limit = -limit;
1969         }
1970
1971         if(WinningConditionHelper_zeroisworst)
1972                 leadlimit = 0; // not supported in this mode
1973
1974         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1975         // these modes always score in increments of 1, thus this makes sense
1976         {
1977                 if(leaderfrags != WinningConditionHelper_topscore)
1978                 {
1979                         leaderfrags = WinningConditionHelper_topscore;
1980
1981                         if (limit)
1982                         if (leaderfrags == limit - 1)
1983                                 Announce("1fragleft");
1984                         else if (leaderfrags == limit - 2)
1985                                 Announce("2fragsleft");
1986                         else if (leaderfrags == limit - 3)
1987                                 Announce("3fragsleft");
1988                 }
1989         }
1990
1991         limitreached = FALSE;
1992         if(limit)
1993                 if(WinningConditionHelper_topscore >= limit)
1994                         limitreached = TRUE;
1995         if(leadlimit)
1996         {
1997                 float leadlimitreached;
1998                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1999                 if(autocvar_leadlimit_and_fraglimit)
2000                         limitreached = (limitreached && leadlimitreached);
2001                 else
2002                         limitreached = (limitreached || leadlimitreached);
2003         }
2004
2005         return GetWinningCode(
2006                 WinningConditionHelper_topscore && limitreached,
2007                 WinningConditionHelper_equality
2008         );
2009 }
2010
2011 float WinningCondition_Race(float fraglimit)
2012 {
2013         float wc;
2014         entity p;
2015         float n, c;
2016
2017         n = 0;
2018         c = 0;
2019         FOR_EACH_PLAYER(p)
2020         {
2021                 ++n;
2022                 if(p.race_completed)
2023                         ++c;
2024         }
2025         if(n && (n == c))
2026                 return WINNING_YES;
2027         wc = WinningCondition_Scores(fraglimit, 0);
2028
2029         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2030         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2031         // do NOT support equality when the laps are all raced!
2032                 return WINNING_STARTSUDDENDEATHOVERTIME;
2033         else
2034                 return WINNING_NEVER;
2035         return wc;
2036 }
2037
2038 void ReadyRestart();
2039 float WinningCondition_QualifyingThenRace(float limit)
2040 {
2041         float wc;
2042         wc = WinningCondition_Scores(limit, 0);
2043
2044         // NEVER initiate overtime
2045         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2046         {
2047                 return WINNING_YES;
2048         }
2049
2050         return wc;
2051 }
2052
2053 float WinningCondition_RanOutOfSpawns()
2054 {
2055         entity head;
2056
2057         if(have_team_spawns <= 0)
2058                 return WINNING_NO;
2059
2060         if(!some_spawn_has_been_used)
2061                 return WINNING_NO;
2062
2063         team1_score = team2_score = team3_score = team4_score = 0;
2064
2065         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2066         {
2067                 if(head.team == COLOR_TEAM1)
2068                         team1_score = 1;
2069                 else if(head.team == COLOR_TEAM2)
2070                         team2_score = 1;
2071                 else if(head.team == COLOR_TEAM3)
2072                         team3_score = 1;
2073                 else if(head.team == COLOR_TEAM4)
2074                         team4_score = 1;
2075         }
2076
2077         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2078         {
2079                 if(head.team == COLOR_TEAM1)
2080                         team1_score = 1;
2081                 else if(head.team == COLOR_TEAM2)
2082                         team2_score = 1;
2083                 else if(head.team == COLOR_TEAM3)
2084                         team3_score = 1;
2085                 else if(head.team == COLOR_TEAM4)
2086                         team4_score = 1;
2087         }
2088
2089         ClearWinners();
2090         if(team1_score + team2_score + team3_score + team4_score == 0)
2091         {
2092                 checkrules_equality = TRUE;
2093                 return WINNING_YES;
2094         }
2095         else if(team1_score + team2_score + team3_score + team4_score == 1)
2096         {
2097                 float t, i;
2098                 if(team1_score) t = COLOR_TEAM1;
2099                 if(team2_score) t = COLOR_TEAM2;
2100                 if(team3_score) t = COLOR_TEAM3;
2101                 if(team4_score) t = COLOR_TEAM4;
2102                 CheckAllowedTeams(world);
2103                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2104                 {
2105                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2106                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2107                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2108                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2109                 }
2110
2111                 AddWinners(team, t);
2112                 return WINNING_YES;
2113         }
2114         else
2115                 return WINNING_NO;
2116 }
2117
2118 /*
2119 ============
2120 CheckRules_World
2121
2122 Exit deathmatch games upon conditions
2123 ============
2124 */
2125 void CheckRules_World()
2126 {
2127         float timelimit;
2128         float fraglimit;
2129         float leadlimit;
2130
2131         VoteThink();
2132         MapVote_Think();
2133
2134         SetDefaultAlpha();
2135
2136         /*
2137         MapVote_Think should now do that part
2138         if (intermission_running)
2139                 if (time >= intermission_exittime + 60)
2140                 {
2141                         if(!DoNextMapOverride())
2142                                 GotoNextMap();
2143                         return;
2144                 }
2145         */
2146
2147         if (gameover)   // someone else quit the game already
2148         {
2149                 if(player_count == 0) // Nobody there? Then let's go to the next map
2150                         MapVote_Start();
2151                         // this will actually check the player count in the next frame
2152                         // again, but this shouldn't hurt
2153                 return;
2154         }
2155
2156         timelimit = autocvar_timelimit * 60;
2157         fraglimit = autocvar_fraglimit;
2158         leadlimit = autocvar_leadlimit;
2159
2160         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2161         {
2162                 if(timelimit > 0)
2163                         timelimit = 0; // timelimit is not made for warmup
2164                 if(fraglimit > 0)
2165                         fraglimit = 0; // no fraglimit for now
2166                 leadlimit = 0; // no leadlimit for now
2167         }
2168
2169         if(g_onslaught)
2170                 timelimit = 0; // ONS has its own overtime rule
2171
2172         if(timelimit > 0)
2173         {
2174                 timelimit += game_starttime;
2175         }
2176         else if (timelimit < 0)
2177         {
2178                 // endmatch
2179                 NextLevel();
2180                 return;
2181         }
2182
2183         float wantovertime;
2184         wantovertime = 0;
2185
2186         if(checkrules_suddendeathend)
2187         {
2188                 if(!checkrules_suddendeathwarning)
2189                 {
2190                         checkrules_suddendeathwarning = TRUE;
2191                         if(g_race && !g_race_qualifying)
2192                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2193                         else
2194                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2195                 }
2196         }
2197         else
2198         {
2199                 if (timelimit && time >= timelimit)
2200                 {
2201                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2202                         {
2203                                 float totalplayers;
2204                                 float playerswithlaps;
2205                                 float readyplayers;
2206                                 entity head;
2207                                 totalplayers = playerswithlaps = readyplayers = 0;
2208                                 FOR_EACH_PLAYER(head)
2209                                 {
2210                                         ++totalplayers;
2211                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2212                                                 ++playerswithlaps;
2213                                         if(head.ready)
2214                                                 ++readyplayers;
2215                                 }
2216
2217                                 // at least 2 of the players have completed a lap: start the RACE
2218                                 // otherwise, the players should end the qualifying on their own
2219                                 if(readyplayers || playerswithlaps >= 2)
2220                                 {
2221                                         checkrules_suddendeathend = 0;
2222                                         ReadyRestart(); // go to race
2223                                         return;
2224                                 }
2225                                 else
2226                                         wantovertime |= InitiateSuddenDeath();
2227                         }
2228                         else
2229                                 wantovertime |= InitiateSuddenDeath();
2230                 }
2231         }
2232
2233         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2234         {
2235                 NextLevel();
2236                 return;
2237         }
2238
2239         float checkrules_status;
2240         checkrules_status = WinningCondition_RanOutOfSpawns();
2241         if(checkrules_status == WINNING_YES)
2242         {
2243                 bprint("Hey! Someone ran out of spawns!\n");
2244         }
2245         else if(g_race && !g_race_qualifying && timelimit >= 0)
2246         {
2247                 checkrules_status = WinningCondition_Race(fraglimit);
2248                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2249         }
2250         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2251         {
2252                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2253                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2254         }
2255         else if(g_assault)
2256         {
2257                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2258         }
2259         else if(g_lms)
2260         {
2261                 checkrules_status = WinningCondition_LMS();
2262         }
2263         else if (g_onslaught)
2264         {
2265                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2266         }
2267         else
2268         {
2269                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2270                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2271         }
2272
2273         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2274         {
2275                 checkrules_status = WINNING_NEVER;
2276                 checkrules_overtimesadded = -1;
2277                 wantovertime |= InitiateSuddenDeath();
2278         }
2279
2280         if(checkrules_status == WINNING_NEVER)
2281                 // equality cases! Nobody wins if the overtime ends in a draw.
2282                 ClearWinners();
2283
2284         if(wantovertime)
2285         {
2286                 if(checkrules_status == WINNING_NEVER)
2287                         InitiateOvertime();
2288                 else
2289                         checkrules_status = WINNING_YES;
2290         }
2291
2292         if(checkrules_suddendeathend)
2293                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2294                         checkrules_status = WINNING_YES;
2295
2296         if(checkrules_status == WINNING_YES)
2297         {
2298                 //print("WINNING\n");
2299                 NextLevel();
2300         }
2301 };
2302
2303 float mapvote_nextthink;
2304 float mapvote_initialized;
2305 float mapvote_keeptwotime;
2306 float mapvote_timeout;
2307 string mapvote_message;
2308 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2309 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2310 float mapvote_screenshot_dirs_count;
2311
2312 float mapvote_count;
2313 float mapvote_count_real;
2314 string mapvote_maps[MAPVOTE_COUNT];
2315 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2316 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2317 float mapvote_maps_suggested[MAPVOTE_COUNT];
2318 string mapvote_suggestions[MAPVOTE_COUNT];
2319 float mapvote_suggestion_ptr;
2320 float mapvote_maxlen;
2321 float mapvote_voters;
2322 float mapvote_votes[MAPVOTE_COUNT];
2323 float mapvote_run;
2324 float mapvote_detail;
2325 float mapvote_abstain;
2326 .float mapvote;
2327
2328 void MapVote_ClearAllVotes()
2329 {
2330         FOR_EACH_CLIENT(other)
2331                 other.mapvote = 0;
2332 }
2333
2334 string MapVote_Suggest(string m)
2335 {
2336         float i;
2337         if(m == "")
2338                 return "That's not how to use this command.";
2339         if(!autocvar_g_maplist_votable_suggestions)
2340                 return "Suggestions are not accepted on this server.";
2341         if(mapvote_initialized)
2342                 return "Can't suggest - voting is already in progress!";
2343         m = MapInfo_FixName(m);
2344         if(!m)
2345                 return "The map you suggested is not available on this server.";
2346         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2347                 if(Map_IsRecent(m))
2348                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2349
2350         if(!MapInfo_CheckMap(m))
2351                 return "The map you suggested does not support the current game mode.";
2352         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2353                 if(mapvote_suggestions[i] == m)
2354                         return "This map was already suggested.";
2355         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2356         {
2357                 i = floor(random() * mapvote_suggestion_ptr);
2358         }
2359         else
2360         {
2361                 i = mapvote_suggestion_ptr;
2362                 mapvote_suggestion_ptr += 1;
2363         }
2364         if(mapvote_suggestions[i] != "")
2365                 strunzone(mapvote_suggestions[i]);
2366         mapvote_suggestions[i] = strzone(m);
2367         if(autocvar_sv_eventlog)
2368                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2369         return strcat("Suggestion of ", m, " accepted.");
2370 }
2371
2372 void MapVote_AddVotable(string nextMap, float isSuggestion)
2373 {
2374         float j, i, o;
2375         string pakfile, mapfile;
2376
2377         if(nextMap == "")
2378                 return;
2379         for(j = 0; j < mapvote_count; ++j)
2380                 if(mapvote_maps[j] == nextMap)
2381                         return;
2382         if(strlen(nextMap) > mapvote_maxlen)
2383                 mapvote_maxlen = strlen(nextMap);
2384         mapvote_maps[mapvote_count] = strzone(nextMap);
2385         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2386
2387         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2388         {
2389                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2390                 pakfile = whichpack(strcat(mapfile, ".tga"));
2391                 if(pakfile == "")
2392                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2393                 if(pakfile == "")
2394                         pakfile = whichpack(strcat(mapfile, ".png"));
2395                 if(pakfile != "")
2396                         break;
2397         }
2398         if(i >= mapvote_screenshot_dirs_count)
2399                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2400         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2401                 pakfile = substring(pakfile, o, -1);
2402
2403         mapvote_maps_screenshot_dir[mapvote_count] = i;
2404         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2405
2406         mapvote_count += 1;
2407 }
2408
2409 void MapVote_Spawn();
2410 void MapVote_Init()
2411 {
2412         float i;
2413         float nmax, smax;
2414
2415         MapVote_ClearAllVotes();
2416
2417         mapvote_count = 0;
2418         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2419         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2420
2421         if(mapvote_abstain)
2422                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2423         else
2424                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2425         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2426
2427         // we need this for AddVotable, as that cycles through the screenshot dirs
2428         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2429         if(mapvote_screenshot_dirs_count == 0)
2430                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2431         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2432         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2433                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2434
2435         if(mapvote_suggestion_ptr)
2436                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2437                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2438
2439         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2440                 MapVote_AddVotable(GetNextMap(), FALSE);
2441
2442         if(mapvote_count == 0)
2443         {
2444                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2445                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2446                 if(autocvar_g_maplist_shuffle)
2447                         ShuffleMaplist();
2448                 localcmd("\nmenu_cmd sync\n");
2449                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2450                         MapVote_AddVotable(GetNextMap(), FALSE);
2451         }
2452
2453         mapvote_count_real = mapvote_count;
2454         if(mapvote_abstain)
2455                 MapVote_AddVotable("don't care", 0);
2456
2457         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2458
2459         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2460         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2461         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2462                 mapvote_keeptwotime = 0;
2463         mapvote_message = "Choose a map and press its key!";
2464
2465         MapVote_Spawn();
2466 }
2467
2468 void MapVote_SendPicture(float id)
2469 {
2470         msg_entity = self;
2471         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2472         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2473         WriteByte(MSG_ONE, id);
2474         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2475 }
2476
2477 float GameCommand_MapVote(string cmd)
2478 {
2479         if(!intermission_running)
2480                 return FALSE;
2481
2482         if(cmd == "mv_getpic")
2483         {
2484                 MapVote_SendPicture(stof(argv(1)));
2485                 return TRUE;
2486         }
2487
2488         return FALSE;
2489 }
2490
2491 float MapVote_GetMapMask()
2492 {
2493         float mask, i, power;
2494         mask = 0;
2495         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2496                 if(mapvote_maps[i] != "")
2497                         mask |= power;
2498         return mask;
2499 }
2500
2501 entity mapvote_ent;
2502 float MapVote_SendEntity(entity to, float sf)
2503 {
2504         float i;
2505
2506         if(sf & 1)
2507                 sf &~= 2; // if we send 1, we don't need to also send 2
2508
2509         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2510         WriteByte(MSG_ENTITY, sf);
2511
2512         if(sf & 1)
2513         {
2514                 // flag 1 == initialization
2515                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2516                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2517                 WriteString(MSG_ENTITY, "");
2518                 WriteByte(MSG_ENTITY, mapvote_count);
2519                 WriteByte(MSG_ENTITY, mapvote_abstain);
2520                 WriteByte(MSG_ENTITY, mapvote_detail);
2521                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2522                 if(mapvote_count <= 8)
2523                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2524                 else
2525                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2526                 for(i = 0; i < mapvote_count; ++i)
2527                         if(mapvote_maps[i] != "")
2528                         {
2529                                 if(mapvote_abstain && i == mapvote_count - 1)
2530                                 {
2531                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2532                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2533                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2534                                 }
2535                                 else
2536                                 {
2537                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2538                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2539                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2540                                 }
2541                         }
2542         }
2543
2544         if(sf & 2)
2545         {
2546                 // flag 2 == update of mask
2547                 if(mapvote_count <= 8)
2548                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2549                 else
2550                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2551         }
2552
2553         if(sf & 4)
2554         {
2555                 if(mapvote_detail)
2556                         for(i = 0; i < mapvote_count; ++i)
2557                                 if(mapvote_maps[i] != "")
2558                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2559
2560                 WriteByte(MSG_ENTITY, to.mapvote);
2561         }
2562
2563         return TRUE;
2564 }
2565
2566 void MapVote_Spawn()
2567 {
2568         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2569 }
2570
2571 void MapVote_TouchMask()
2572 {
2573         mapvote_ent.SendFlags |= 2;
2574 }
2575
2576 void MapVote_TouchVotes(entity voter)
2577 {
2578         mapvote_ent.SendFlags |= 4;
2579 }
2580
2581 float MapVote_Finished(float mappos)
2582 {
2583         string result;
2584         float i;
2585         float didntvote;
2586
2587         if(autocvar_sv_eventlog)
2588         {
2589                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2590                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2591                 didntvote = mapvote_voters;
2592                 for(i = 0; i < mapvote_count; ++i)
2593                         if(mapvote_maps[i] != "")
2594                         {
2595                                 didntvote -= mapvote_votes[i];
2596                                 if(i != mappos)
2597                                 {
2598                                         result = strcat(result, ":", mapvote_maps[i]);
2599                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2600                                 }
2601                         }
2602                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2603
2604                 GameLogEcho(result);
2605                 if(mapvote_maps_suggested[mappos])
2606                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2607         }
2608
2609         FOR_EACH_REALCLIENT(other)
2610                 FixClientCvars(other);
2611
2612         Map_Goto_SetStr(mapvote_maps[mappos]);
2613         Map_Goto();
2614         alreadychangedlevel = TRUE;
2615         return TRUE;
2616 }
2617 void MapVote_CheckRules_1()
2618 {
2619         float i;
2620
2621         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2622         {
2623                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2624                 mapvote_votes[i] = 0;
2625         }
2626
2627         mapvote_voters = 0;
2628         FOR_EACH_REALCLIENT(other)
2629         {
2630                 ++mapvote_voters;
2631                 if(other.mapvote)
2632                 {
2633                         i = other.mapvote - 1;
2634                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2635                         mapvote_votes[i] = mapvote_votes[i] + 1;
2636                 }
2637         }
2638 }
2639
2640 float MapVote_CheckRules_2()
2641 {
2642         float i;
2643         float firstPlace, secondPlace;
2644         float firstPlaceVotes, secondPlaceVotes;
2645         float mapvote_voters_real;
2646         string result;
2647
2648         if(mapvote_count_real == 1)
2649                 return MapVote_Finished(0);
2650
2651         mapvote_voters_real = mapvote_voters;
2652         if(mapvote_abstain)
2653                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2654
2655         RandomSelection_Init();
2656         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2657                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2658         firstPlace = RandomSelection_chosen_float;
2659         firstPlaceVotes = RandomSelection_best_priority;
2660         //dprint("First place: ", ftos(firstPlace), "\n");
2661         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2662
2663         RandomSelection_Init();
2664         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2665                 if(i != firstPlace)
2666                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2667         secondPlace = RandomSelection_chosen_float;
2668         secondPlaceVotes = RandomSelection_best_priority;
2669         //dprint("Second place: ", ftos(secondPlace), "\n");
2670         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2671
2672         if(firstPlace == -1)
2673                 error("No first place in map vote... WTF?");
2674
2675         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2676                 return MapVote_Finished(firstPlace);
2677
2678         if(mapvote_keeptwotime)
2679                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2680                 {
2681                         float didntvote;
2682                         MapVote_TouchMask();
2683                         mapvote_message = "Now decide between the TOP TWO!";
2684                         mapvote_keeptwotime = 0;
2685                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2686                         result = strcat(result, ":", ftos(firstPlaceVotes));
2687                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2688                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2689                         didntvote = mapvote_voters;
2690                         for(i = 0; i < mapvote_count; ++i)
2691                                 if(mapvote_maps[i] != "")
2692                                 {
2693                                         didntvote -= mapvote_votes[i];
2694                                         if(i != firstPlace)
2695                                                 if(i != secondPlace)
2696                                                 {
2697                                                         result = strcat(result, ":", mapvote_maps[i]);
2698                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2699                                                         if(i < mapvote_count_real)
2700                                                         {
2701                                                                 strunzone(mapvote_maps[i]);
2702                                                                 mapvote_maps[i] = "";
2703                                                                 strunzone(mapvote_maps_pakfile[i]);
2704                                                                 mapvote_maps_pakfile[i] = "";
2705                                                         }
2706                                                 }
2707                                 }
2708                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2709                         if(autocvar_sv_eventlog)
2710                                 GameLogEcho(result);
2711                 }
2712
2713         return FALSE;
2714 }
2715 void MapVote_Tick()
2716 {
2717         float keeptwo;
2718         float totalvotes;
2719
2720         keeptwo = mapvote_keeptwotime;
2721         MapVote_CheckRules_1(); // count
2722         if(MapVote_CheckRules_2()) // decide
2723                 return;
2724
2725         totalvotes = 0;
2726         FOR_EACH_REALCLIENT(other)
2727         {
2728                 // hide scoreboard again
2729                 if(other.health != 2342)
2730                 {
2731                         other.health = 2342;
2732                         other.impulse = 0;
2733                         if(clienttype(other) == CLIENTTYPE_REAL)
2734                         {
2735                                 msg_entity = other;
2736                                 WriteByte(MSG_ONE, SVC_FINALE);
2737                                 WriteString(MSG_ONE, "");
2738                         }
2739                 }
2740
2741                 // clear possibly invalid votes
2742                 if(mapvote_maps[other.mapvote - 1] == "")
2743                         other.mapvote = 0;
2744                 // use impulses as new vote
2745                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2746                         if(mapvote_maps[other.impulse - 1] != "")
2747                         {
2748                                 other.mapvote = other.impulse;
2749                                 MapVote_TouchVotes(other);
2750                         }
2751                 other.impulse = 0;
2752
2753                 if(other.mapvote)
2754                         ++totalvotes;
2755         }
2756
2757         MapVote_CheckRules_1(); // just count
2758 }
2759 void MapVote_Start()
2760 {
2761         if(mapvote_run)
2762                 return;
2763
2764         // wait for stats to be sent first
2765         if(!playerstats_waitforme)
2766                 return;
2767
2768         MapInfo_Enumerate();
2769         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2770                 mapvote_run = TRUE;
2771 }
2772 void MapVote_Think()
2773 {
2774         if(!mapvote_run)
2775                 return;
2776
2777         if(alreadychangedlevel)
2778                 return;
2779
2780         if(time < mapvote_nextthink)
2781                 return;
2782         //dprint("tick\n");
2783
2784         mapvote_nextthink = time + 0.5;
2785
2786         if(!mapvote_initialized)
2787         {
2788                 if(autocvar_rescan_pending == 1)
2789                 {
2790                         cvar_set("rescan_pending", "2");
2791                         localcmd("fs_rescan\nrescan_pending 3\n");
2792                         return;
2793                 }
2794                 else if(autocvar_rescan_pending == 2)
2795                 {
2796                         return;
2797                 }
2798                 else if(autocvar_rescan_pending == 3)
2799                 {
2800                         // now build missing mapinfo files
2801                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2802                                 return;
2803
2804                         // we're done, start the timer
2805                         cvar_set("rescan_pending", "0");
2806                 }
2807
2808                 mapvote_initialized = TRUE;
2809                 if(DoNextMapOverride())
2810                         return;
2811                 if(!autocvar_g_maplist_votable || player_count <= 0)
2812                 {
2813                         GotoNextMap();
2814                         return;
2815                 }
2816                 MapVote_Init();
2817         }
2818
2819         MapVote_Tick();
2820 };
2821
2822 string GotoMap(string m)
2823 {
2824         if(!MapInfo_CheckMap(m))
2825                 return "The map you chose is not available on this server.";
2826         cvar_set("nextmap", m);
2827         cvar_set("timelimit", "-1");
2828         if(mapvote_initialized || alreadychangedlevel)
2829         {
2830                 if(DoNextMapOverride())
2831                         return "Map switch initiated.";
2832                 else
2833                         return "Hm... no. For some reason I like THIS map more.";
2834         }
2835         else
2836                 return "Map switch will happen after scoreboard.";
2837 }
2838
2839
2840 void EndFrame()
2841 {
2842         float altime;
2843         FOR_EACH_REALCLIENT(self)
2844         {
2845                 if(self.classname == "spectator")
2846                 {
2847                         if(self.enemy.typehitsound)
2848                                 self.typehit_time = time;
2849                         else if(self.enemy.hitsound)
2850                                 self.hit_time = time;
2851                 }
2852                 else
2853                 {
2854                         if(self.typehitsound)
2855                                 self.typehit_time = time;
2856                         else if(self.hitsound)
2857                                 self.hit_time = time;
2858                 }
2859         }
2860         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2861         // add 1 frametime because after this, engine SV_Physics
2862         // increases time by a frametime and then networks the frame
2863         // add another frametime because client shows everything with
2864         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2865         // needed!
2866         FOR_EACH_CLIENT(self)
2867         {
2868                 self.hitsound = FALSE;
2869                 self.typehitsound = FALSE;
2870                 antilag_record(self, altime);
2871         }
2872 }
2873
2874
2875 /*
2876  * RedirectionThink:
2877  * returns TRUE if redirecting
2878  */
2879 float redirection_timeout;
2880 float redirection_nextthink;
2881 float RedirectionThink()
2882 {
2883         float clients_found;
2884
2885         if(redirection_target == "")
2886                 return FALSE;
2887
2888         if(!redirection_timeout)
2889         {
2890                 cvar_set("sv_public", "-2");
2891                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2892                 if(redirection_target == "self")
2893                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2894                 else
2895                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2896         }
2897
2898         if(time < redirection_nextthink)
2899                 return TRUE;
2900
2901         redirection_nextthink = time + 1;
2902
2903         clients_found = 0;
2904         FOR_EACH_REALCLIENT(self)
2905         {
2906                 print("Redirecting: sending connect command to ", self.netname, "\n");
2907                 if(redirection_target == "self")
2908                         stuffcmd(self, "\ndisconnect; reconnect\n");
2909                 else
2910                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2911                 ++clients_found;
2912         }
2913
2914         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2915
2916         if(time > redirection_timeout || clients_found == 0)
2917                 localcmd("\nwait; wait; wait; quit\n");
2918
2919         return TRUE;
2920 }
2921
2922 void TargetMusic_RestoreGame();
2923 void RestoreGame()
2924 {
2925         // Loaded from a save game
2926         // some things then break, so let's work around them...
2927
2928         // Progs DB (capture records)
2929         ServerProgsDB = db_load("server.db");
2930
2931         // Mapinfo
2932         MapInfo_Shutdown();
2933         MapInfo_Enumerate();
2934         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2935         WeaponStats_Init();
2936
2937         TargetMusic_RestoreGame();
2938 }
2939
2940 void SV_Shutdown()
2941 {
2942         entity e;
2943
2944         if(gameover > 1) // shutting down already?
2945                 return;
2946
2947         gameover = 2; // 2 = server shutting down
2948
2949         if(world_initialized > 0)
2950         {
2951                 world_initialized = 0;
2952                 print("Saving persistent data...\n");
2953                 Ban_SaveBans();
2954
2955                 PlayerStats_EndMatch(0);
2956                 FOR_EACH_CLIENT(e)
2957                         PlayerStats_AddGlobalInfo(e);
2958                 PlayerStats_Shutdown();
2959
2960                 if(!cheatcount_total)
2961                 {
2962                         if(autocvar_sv_db_saveasdump)
2963                                 db_dump(ServerProgsDB, "server.db");
2964                         else
2965                                 db_save(ServerProgsDB, "server.db");
2966                 }
2967                 if(autocvar_developer)
2968                 {
2969                         if(autocvar_sv_db_saveasdump)
2970                                 db_dump(TemporaryDB, "server-temp.db");
2971                         else
2972                                 db_save(TemporaryDB, "server-temp.db");
2973                 }
2974                 CheatShutdown(); // must be after cheatcount check
2975                 db_close(ServerProgsDB);
2976                 db_close(TemporaryDB);
2977                 print("done!\n");
2978                 // tell the bot system the game is ending now
2979                 bot_endgame();
2980
2981                 WeaponStats_Shutdown();
2982                 MapInfo_Shutdown();
2983         }
2984         else if(world_initialized == 0)
2985         {
2986                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2987         }
2988 }