qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/all.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications/all.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37 #include "../common/state.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new_pure(pingplreport);
  85         pingplreport.think = PingPLReport_Think;
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap()
 108 {SELFPARAM();
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 self.nextthink = time;
 133         }
 134         else
 135         {
 136                 self.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250
 251                 // mapinfo
 252                 BADCVAR("fraglimit");
 253                 BADCVAR("g_assault");
 254                 BADCVAR("g_ca");
 255                 BADCVAR("g_ca_teams");
 256                 BADCVAR("g_ctf");
 257                 BADCVAR("g_cts");
 258                 BADCVAR("g_dm");
 259                 BADCVAR("g_domination");
 260                 BADCVAR("g_domination_default_teams");
 261                 BADCVAR("g_freezetag");
 262                 BADCVAR("g_freezetag_teams");
 263                 BADCVAR("g_invasion_teams");
 264                 BADCVAR("g_keepaway");
 265                 BADCVAR("g_keyhunt");
 266                 BADCVAR("g_keyhunt_teams");
 267                 BADCVAR("g_lms");
 268                 BADCVAR("g_nexball");
 269                 BADCVAR("g_onslaught");
 270                 BADCVAR("g_race");
 271                 BADCVAR("g_race_laps_limit");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_race_qualifying_timelimit_override");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing gameplay relevant
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("gameversion");
 307                 BADCVAR("g_allow_oldvortexbeam");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_campcheck_distance");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ca_point_limit");
 312                 BADCVAR("g_ctf_captimerecord_always");
 313                 BADCVAR("g_ctf_flag_glowtrails");
 314                 BADCVAR("g_ctf_flag_pickup_verbosename");
 315                 BADCVAR("g_domination_point_leadlimit");
 316                 BADCVAR("g_forced_respawn");
 317                 BADCVAR("g_freezetag_point_leadlimit");
 318                 BADCVAR("g_freezetag_point_limit");
 319                 BADCVAR("g_hats");
 320                 BADCVAR("g_invasion_point_limit");
 321                 BADCVAR("g_keyhunt_point_leadlimit");
 322                 BADCVAR("g_nexball_goalleadlimit");
 323                 BADCVAR("g_tdm_point_leadlimit");
 324                 BADCVAR("g_tdm_point_limit");
 325                 BADCVAR("leadlimit_and_fraglimit");
 326                 BADCVAR("leadlimit_override");
 327                 BADCVAR("pausable");
 328                 BADCVAR("sv_allow_fullbright");
 329                 BADCVAR("sv_checkforpacketsduringsleep");
 330                 BADCVAR("sv_intermission_cdtrack");
 331                 BADCVAR("sv_minigames");
 332                 BADCVAR("sv_namechangetimer");
 333                 BADCVAR("sv_precacheplayermodels");
 334                 BADCVAR("sv_timeout");
 335                 BADPREFIX("crypto_");
 336                 BADPREFIX("gameversion_");
 337                 BADPREFIX("g_chat_");
 338                 BADPREFIX("g_ctf_captimerecord_");
 339                 BADPREFIX("g_maplist_votable_");
 340                 BADPREFIX("g_mod_");
 341                 BADPREFIX("g_respawn_");
 342                 BADPREFIX("net_");
 343                 BADPREFIX("prvm_");
 344                 BADPREFIX("skill_");
 345                 BADPREFIX("sv_cullentities_");
 346                 BADPREFIX("sv_maxidle_");
 347                 BADPREFIX("sv_minigames_");
 348                 BADPREFIX("sv_timeout_");
 349                 BADPREFIX("sv_vote_");
 350                 BADPREFIX("timelimit_");
 351
 352                 // allowed changes to server admins (please sync this to server.cfg)
 353                 // vi commands:
 354                 //   :/"impure"/,$d
 355                 //   :g!,^\/\/[^ /],d
 356                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 357                 //   :%!sort
 358                 // yes, this does contain some redundant stuff, don't really care
 359                 BADCVAR("bot_config_file");
 360                 BADCVAR("bot_number");
 361                 BADCVAR("bot_prefix");
 362                 BADCVAR("bot_suffix");
 363                 BADCVAR("capturelimit_override");
 364                 BADCVAR("fraglimit_override");
 365                 BADCVAR("gametype");
 366                 BADCVAR("g_antilag");
 367                 BADCVAR("g_balance_teams");
 368                 BADCVAR("g_balance_teams_prevent_imbalance");
 369                 BADCVAR("g_balance_teams_scorefactor");
 370                 BADCVAR("g_ban_sync_trusted_servers");
 371                 BADCVAR("g_ban_sync_uri");
 372                 BADCVAR("g_ca_teams_override");
 373                 BADCVAR("g_ctf_ignore_frags");
 374                 BADCVAR("g_domination_point_limit");
 375                 BADCVAR("g_domination_teams_override");
 376                 BADCVAR("g_freezetag_teams_override");
 377                 BADCVAR("g_friendlyfire");
 378                 BADCVAR("g_fullbrightitems");
 379                 BADCVAR("g_fullbrightplayers");
 380                 BADCVAR("g_keyhunt_point_limit");
 381                 BADCVAR("g_keyhunt_teams_override");
 382                 BADCVAR("g_lms_lives_override");
 383                 BADCVAR("g_maplist");
 384                 BADCVAR("g_maplist_check_waypoints");
 385                 BADCVAR("g_maplist_mostrecent_count");
 386                 BADCVAR("g_maplist_shuffle");
 387                 BADCVAR("g_maplist_votable");
 388                 BADCVAR("g_maplist_votable_abstain");
 389                 BADCVAR("g_maplist_votable_nodetail");
 390                 BADCVAR("g_maplist_votable_suggestions");
 391                 BADCVAR("g_maxplayers");
 392                 BADCVAR("g_mirrordamage");
 393                 BADCVAR("g_nexball_goallimit");
 394                 BADCVAR("g_powerups");
 395                 BADCVAR("g_spawnshieldtime");
 396                 BADCVAR("g_start_delay");
 397                 BADCVAR("g_superspectate");
 398                 BADCVAR("g_tdm_teams_override");
 399                 BADCVAR("g_warmup");
 400                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 401                 BADCVAR("hostname");
 402                 BADCVAR("log_file");
 403                 BADCVAR("maxplayers");
 404                 BADCVAR("minplayers");
 405                 BADCVAR("net_address");
 406                 BADCVAR("port");
 407                 BADCVAR("rcon_password");
 408                 BADCVAR("rcon_restricted_commands");
 409                 BADCVAR("rcon_restricted_password");
 410                 BADCVAR("skill");
 411                 BADCVAR("sv_adminnick");
 412                 BADCVAR("sv_autoscreenshot");
 413                 BADCVAR("sv_autotaunt");
 414                 BADCVAR("sv_curl_defaulturl");
 415                 BADCVAR("sv_defaultcharacter");
 416                 BADCVAR("sv_defaultplayercolors");
 417                 BADCVAR("sv_defaultplayermodel");
 418                 BADCVAR("sv_defaultplayerskin");
 419                 BADCVAR("sv_maxidle");
 420                 BADCVAR("sv_maxrate");
 421                 BADCVAR("sv_motd");
 422                 BADCVAR("sv_public");
 423                 BADCVAR("sv_ready_restart");
 424                 BADCVAR("sv_status_privacy");
 425                 BADCVAR("sv_taunt");
 426                 BADCVAR("sv_vote_call");
 427                 BADCVAR("sv_vote_commands");
 428                 BADCVAR("sv_vote_majority_factor");
 429                 BADCVAR("sv_vote_master");
 430                 BADCVAR("sv_vote_master_commands");
 431                 BADCVAR("sv_vote_master_password");
 432                 BADCVAR("sv_vote_simple_majority_factor");
 433                 BADCVAR("teamplay_mode");
 434                 BADCVAR("timelimit_override");
 435                 BADPREFIX("g_warmup_");
 436                 BADPREFIX("sv_ready_restart_");
 437
 438                 // mutators that announce themselves properly to the server browser
 439                 BADCVAR("g_instagib");
 440                 BADCVAR("g_new_toys");
 441                 BADCVAR("g_nix");
 442                 BADCVAR("g_grappling_hook");
 443                 BADCVAR("g_jetpack");
 444
 445 #undef BADPREFIX
 446 #undef BADCVAR
 447
 448                 if(pureadding)
 449                 {
 450                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 451                         if(strlen(cvar_purechanges) > 16384)
 452                         {
 453                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 454                                 pureadding = 0;
 455                         }
 456                 }
 457                 ++cvar_purechanges_count;
 458                 // WARNING: this variable is used for the server list
 459                 // NEVER dare to skip this code!
 460                 // Hacks to intentionally appearing as "pure server" even though you DO have
 461                 // modified settings may be punished by removal from the server list.
 462                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 463                 // though.
 464         }
 465         buf_del(h);
 466         if(cvar_changes == "")
 467                 cvar_changes = "// this server runs at default server settings\n";
 468         else
 469                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 470         cvar_changes = strzone(cvar_changes);
 471         if(cvar_purechanges == "")
 472                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 473         else
 474                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 475         cvar_purechanges = strzone(cvar_purechanges);
 476 }
 477
 478 void detect_maptype()
 479 {
 480 #if 0
 481         vector o, v;
 482         float i;
 483
 484         for (;;)
 485         {
 486                 o = world.mins;
 487                 o.x += random() * (world.maxs.x - world.mins.x);
 488                 o.y += random() * (world.maxs.y - world.mins.y);
 489                 o.z += random() * (world.maxs.z - world.mins.z);
 490
 491                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, world);
 492                 if(trace_fraction == 1)
 493                         continue;
 494
 495                 v = trace_endpos;
 496
 497                 for(i = 0; i < 64; i += 4)
 498                 {
 499                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 500         if(trace_fraction == 1)
 501                 continue;
 502                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 503                 }
 504
 505                 break;
 506         }
 507 #endif
 508 }
 509
 510 entity randomseed;
 511 bool RandomSeed_Send(entity this, entity to, int sf)
 512 {
 513         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 514         WriteShort(MSG_ENTITY, self.cnt);
 515         return true;
 516 }
 517 void RandomSeed_Think()
 518 {SELFPARAM();
 519         self.cnt = bound(0, floor(random() * 65536), 65535);
 520         self.nextthink = time + 5;
 521
 522         self.SendFlags |= 1;
 523 }
 524 void RandomSeed_Spawn()
 525 {SELFPARAM();
 526         randomseed = new_pure(randomseed);
 527         randomseed.think = RandomSeed_Think;
 528         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 529
 530         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 531 }
 532
 533 spawnfunc(__init_dedicated_server)
 534 {
 535         // handler for _init/_init map (only for dedicated server initialization)
 536
 537         world_initialized = -1; // don't complain
 538         cvar = cvar_normal;
 539         cvar_string = cvar_string_normal;
 540         cvar_set = cvar_set_normal;
 541
 542         remove = remove_unsafely;
 543
 544         entity e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = new(info_player_deathmatch);  // safeguard against player joining
 549
 550         self.classname = "worldspawn"; // safeguard against various stuff ;)
 551
 552         // needs to be done so early because of the constants they create
 553         static_init();
 554         static_init_late();
 555         static_init_precache();
 556
 557         MapInfo_Enumerate();
 558         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 559 }
 560
 561 void __init_dedicated_server_shutdown() {
 562         MapInfo_Shutdown();
 563 }
 564
 565 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 566 {
 567         if(!autocvar_g_campaign)
 568         {
 569                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 570                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 571                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 572                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 573         }
 574         limits_are_set = true;
 575 }
 576
 577 void Map_MarkAsRecent(string m);
 578 float world_already_spawned;
 579 void Nagger_Init();
 580 void ClientInit_Spawn();
 581 void WeaponStats_Init();
 582 void WeaponStats_Shutdown();
 583 spawnfunc(worldspawn)
 584 {
 585         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 586
 587         {
 588                 bool wantrestart = false;
 589
 590                 if (!server_is_dedicated)
 591                 {
 592                         // force unloading of server pk3 files when starting a listen server
 593                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 594                         // restore csqc_progname too
 595                         string expect = "csprogs.dat";
 596                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 597                         cvar_set_normal("csqc_progname", expect);
 598                 }
 599                 else
 600                 {
 601                         // Try to use versioned csprogs from pk3
 602                         // Only ever use versioned csprogs.dat files on dedicated servers;
 603                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 604                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 605                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 606                         string select = "csprogs.dat";
 607                         if (fexists(pk3csprogs)) select = pk3csprogs;
 608                         if (cvar_string_normal("csqc_progname") != select)
 609                         {
 610                                 cvar_set_normal("csqc_progname", select);
 611                                 wantrestart = true;
 612                         }
 613                         // Check for updates on startup
 614                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 615                         int sentinel = fopen("progs.txt", FILE_READ);
 616                         if (sentinel >= 0)
 617                         {
 618                                 string switchversion = fgets(sentinel);
 619                                 fclose(sentinel);
 620                                 if (switchversion != "" && switchversion != WATERMARK)
 621                                 {
 622                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 623                                         // if it doesn't exist, assume either:
 624                                         //   a) the current program was overwritten
 625                                         //   b) this is a client only update
 626                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 627                                         if (fexists(newprogs))
 628                                         {
 629                                                 cvar_set_normal("sv_progs", newprogs);
 630                                                 wantrestart = true;
 631                                         }
 632                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 633                                         if (fexists(newcsprogs))
 634                                         {
 635                                                 cvar_set_normal("csqc_progname", newcsprogs);
 636                                                 wantrestart = true;
 637                                         }
 638                                 }
 639                         }
 640                 }
 641                 if (wantrestart)
 642                 {
 643                         LOG_INFOF("Restart requested\n");
 644                         changelevel(mapname);
 645                         // let initialization continue, shutdown depends on it
 646                 }
 647         }
 648
 649         float fd, l;
 650         string s;
 651
 652         cvar = cvar_normal;
 653         cvar_string = cvar_string_normal;
 654         cvar_set = cvar_set_normal;
 655
 656         if(world_already_spawned)
 657                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 658         world_already_spawned = true;
 659
 660         remove = remove_safely; // during spawning, watch what you remove!
 661
 662         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 663
 664         compressShortVector_init();
 665
 666         maxclients = 0;
 667         for (entity head = nextent(world); head; head = nextent(head))
 668         {
 669                 ++maxclients;
 670         }
 671
 672         // needs to be done so early because of the constants they create
 673         static_init();
 674
 675         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 676
 677         TemporaryDB = db_create();
 678
 679         // 0 normal
 680         lightstyle(0, "m");
 681
 682         // 1 FLICKER (first variety)
 683         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 684
 685         // 2 SLOW STRONG PULSE
 686         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 687
 688         // 3 CANDLE (first variety)
 689         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 690
 691         // 4 FAST STROBE
 692         lightstyle(4, "mamamamamama");
 693
 694         // 5 GENTLE PULSE 1
 695         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 696
 697         // 6 FLICKER (second variety)
 698         lightstyle(6, "nmonqnmomnmomomno");
 699
 700         // 7 CANDLE (second variety)
 701         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 702
 703         // 8 CANDLE (third variety)
 704         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 705
 706         // 9 SLOW STROBE (fourth variety)
 707         lightstyle(9, "aaaaaaaazzzzzzzz");
 708
 709         // 10 FLUORESCENT FLICKER
 710         lightstyle(10, "mmamammmmammamamaaamammma");
 711
 712         // 11 SLOW PULSE NOT FADE TO BLACK
 713         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 714
 715         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 716
 717         // 63 testing
 718         lightstyle(63, "a");
 719
 720         if(autocvar_g_campaign)
 721                 CampaignPreInit();
 722
 723         Map_MarkAsRecent(mapname);
 724
 725         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 726
 727         InitGameplayMode();
 728         static_init_late();
 729         static_init_precache();
 730         readlevelcvars();
 731         GrappleHookInit();
 732
 733         if(!limits_are_set)
 734                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 735
 736         player_count = 0;
 737         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 738         if(bot_waypoints_for_items == 1)
 739                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 740                         bot_waypoints_for_items = 0;
 741
 742         precache();
 743
 744         WaypointSprite_Init();
 745
 746         GameLogInit(); // prepare everything
 747         // NOTE for matchid:
 748         // changing the logic generating it is okay. But:
 749         // it HAS to stay <= 64 chars
 750         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 751         if(autocvar_sv_eventlog)
 752         {
 753                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 754                 matchid = strzone(s);
 755
 756                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 757                 s = ":gameinfo:mutators:LIST";
 758
 759                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 760                 s = ret_string;
 761
 762                 // initialiation stuff, not good in the mutator system
 763                 if(!autocvar_g_use_ammunition)
 764                         s = strcat(s, ":no_use_ammunition");
 765
 766                 // initialiation stuff, not good in the mutator system
 767                 if(autocvar_g_pickup_items == 0)
 768                         s = strcat(s, ":no_pickup_items");
 769                 if(autocvar_g_pickup_items > 0)
 770                         s = strcat(s, ":pickup_items");
 771
 772                 // initialiation stuff, not good in the mutator system
 773                 if(autocvar_g_weaponarena != "0")
 774                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 775
 776                 // TODO to mutator system
 777                 if(autocvar_g_norecoil)
 778                         s = strcat(s, ":norecoil");
 779
 780                 // TODO to mutator system
 781                 if(autocvar_g_powerups == 0)
 782                         s = strcat(s, ":no_powerups");
 783                 if(autocvar_g_powerups > 0)
 784                         s = strcat(s, ":powerups");
 785
 786                 GameLogEcho(s);
 787                 GameLogEcho(":gameinfo:end");
 788         }
 789         else
 790                 matchid = strzone(ftos(random()));
 791
 792         cvar_set("nextmap", "");
 793
 794         SetDefaultAlpha();
 795
 796         if(autocvar_g_campaign)
 797                 CampaignPostInit();
 798
 799         Ban_LoadBans();
 800
 801         MapInfo_Enumerate();
 802         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 803
 804         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 805         {
 806                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 807                 if(fd != -1)
 808                 {
 809                         while((s = fgets(fd)))
 810                         {
 811                                 l = tokenize_console(s);
 812                                 if(l < 2)
 813                                         continue;
 814                                 if(argv(0) == "cd")
 815                                 {
 816                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 817                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 818                                 }
 819                                 else if(argv(0) == "fog")
 820                                 {
 821                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 822                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 823                                 }
 824                                 else if(argv(0) == "set")
 825                                 {
 826                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 827                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 828                                 }
 829                                 else if(argv(0) != "//")
 830                                 {
 831                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 832                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 833                                 }
 834                         }
 835                         fclose(fd);
 836                 }
 837         }
 838
 839         WeaponStats_Init();
 840
 841         Nagger_Init();
 842
 843         next_pingtime = time + 5;
 844
 845         detect_maptype();
 846
 847         // set up information replies for clients and server to use
 848         maplist_reply = strzone(getmaplist());
 849         lsmaps_reply = strzone(getlsmaps());
 850         monsterlist_reply = strzone(getmonsterlist());
 851         for(int i = 0; i < 10; ++i)
 852         {
 853                 s = getrecords(i);
 854                 if (s)
 855                         records_reply[i] = strzone(s);
 856         }
 857         ladder_reply = strzone(getladder());
 858         rankings_reply = strzone(getrankings());
 859
 860         // begin other init
 861         ClientInit_Spawn();
 862         RandomSeed_Spawn();
 863         PingPLReport_Spawn();
 864
 865         CheatInit();
 866
 867         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 868
 869         // fill sv_curl_serverpackages from .serverpackage files
 870         if (autocvar_sv_curl_serverpackages_auto)
 871         {
 872                 s = "csprogs-" WATERMARK ".txt";
 873                 // remove automatically managed files from the list to prevent duplicates
 874                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 875                 {
 876                         string pkg = argv(i);
 877                         if (startsWith(pkg, "csprogs-")) continue;
 878                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 879                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 880                         s = cons(s, pkg);
 881                 }
 882                 // add automatically managed files to the list
 883                 #define X(match) MACRO_BEGIN { \
 884                         fd = search_begin(match, true, false); \
 885                         if (fd >= 0) \
 886                         { \
 887                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 888                                 { \
 889                                         s = cons(s, search_getfilename(fd, i)); \
 890                                 } \
 891                                 search_end(fd); \
 892                         } \
 893                 } MACRO_END
 894                 X("*-serverpackage.txt");
 895                 X("*.serverpackage");
 896                 #undef X
 897                 cvar_set("sv_curl_serverpackages", s);
 898         }
 899
 900         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 901         modname = "Xonotic";
 902         // physics/balance/config changes that count as mod
 903         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 904                 modname = cvar_string("g_mod_physics");
 905         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 906                 modname = cvar_string("g_mod_balance");
 907         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 908                 modname = cvar_string("g_mod_config");
 909         // extra mutators that deserve to count as mod
 910         MUTATOR_CALLHOOK(SetModname);
 911
 912         // save it for later
 913         modname = strzone(modname);
 914
 915         WinningConditionHelper(); // set worldstatus
 916
 917         world_initialized = 1;
 918 }
 919
 920 spawnfunc(light)
 921 {
 922         //makestatic (self); // Who the f___ did that?
 923         remove(self);
 924 }
 925
 926 string GetGametype()
 927 {
 928         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 929 }
 930
 931 string GetMapname()
 932 {
 933         return mapname;
 934 }
 935
 936 float Map_Count, Map_Current;
 937 string Map_Current_Name;
 938
 939 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 940 float GetMaplistPosition()
 941 {
 942         float pos, idx;
 943         string map;
 944
 945         map = GetMapname();
 946         idx = autocvar_g_maplist_index;
 947
 948         if(idx >= 0)
 949                 if(idx < Map_Count)
 950                         if(map == argv(idx))
 951                                 return idx;
 952
 953         for(pos = 0; pos < Map_Count; ++pos)
 954                 if(map == argv(pos))
 955                         return pos;
 956
 957         // resume normal maplist rotation if current map is not in g_maplist
 958         return idx;
 959 }
 960
 961 float MapHasRightSize(string map)
 962 {
 963         float fh;
 964         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 965         if(autocvar_g_maplist_check_waypoints)
 966         {
 967                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 968                 if(!fexists(strcat("maps/", map, ".waypoints")))
 969                 {
 970                         LOG_TRACE(": no waypoints\n");
 971                         return false;
 972                 }
 973                 LOG_TRACE(": has waypoints\n");
 974         }
 975
 976         // open map size restriction file
 977         LOG_TRACE("opensize "); LOG_TRACE(map);
 978         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 979         if(fh >= 0)
 980         {
 981                 float mapmin, mapmax;
 982                 LOG_TRACE(": ok, ");
 983                 mapmin = stof(fgets(fh));
 984                 mapmax = stof(fgets(fh));
 985                 fclose(fh);
 986                 if(player_count < mapmin)
 987                 {
 988                         LOG_TRACE("not enough\n");
 989                         return false;
 990                 }
 991                 if(player_count > mapmax)
 992                 {
 993                         LOG_TRACE("too many\n");
 994                         return false;
 995                 }
 996                 LOG_TRACE("right size\n");
 997                 return true;
 998         }
 999         LOG_TRACE(": not found\n");
1000         return true;
1001 }
1002
1003 string Map_Filename(float position)
1004 {
1005         return strcat("maps/", argv(position), ".bsp");
1006 }
1007
1008 void Map_MarkAsRecent(string m)
1009 {
1010         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1011 }
1012
1013 float Map_IsRecent(string m)
1014 {
1015         return strhasword(autocvar_g_maplist_mostrecent, m);
1016 }
1017
1018 float Map_Check(float position, float pass)
1019 {
1020         string filename;
1021         string map_next;
1022         map_next = argv(position);
1023         if(pass <= 1)
1024         {
1025                 if(Map_IsRecent(map_next))
1026                         return 0;
1027         }
1028         filename = Map_Filename(position);
1029         if(MapInfo_CheckMap(map_next))
1030         {
1031                 if(pass == 2)
1032                         return 1;
1033                 if(MapHasRightSize(map_next))
1034                         return 1;
1035                 return 0;
1036         }
1037         else
1038                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1039
1040         return 0;
1041 }
1042
1043 void Map_Goto_SetStr(string nextmapname)
1044 {
1045         if(getmapname_stored != "")
1046                 strunzone(getmapname_stored);
1047         if(nextmapname == "")
1048                 getmapname_stored = "";
1049         else
1050                 getmapname_stored = strzone(nextmapname);
1051 }
1052
1053 void Map_Goto_SetFloat(float position)
1054 {
1055         cvar_set("g_maplist_index", ftos(position));
1056         Map_Goto_SetStr(argv(position));
1057 }
1058
1059 void Map_Goto(float reinit)
1060 {
1061         MapInfo_LoadMap(getmapname_stored, reinit);
1062 }
1063
1064 // return codes of map selectors:
1065 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1066 //   -2 = permanent failure
1067 float() MaplistMethod_Iterate = // usual method
1068 {
1069         float pass, i;
1070
1071         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1072
1073         for(pass = 1; pass <= 2; ++pass)
1074         {
1075                 for(i = 1; i < Map_Count; ++i)
1076                 {
1077                         float mapindex;
1078                         mapindex = (i + Map_Current) % Map_Count;
1079                         if(Map_Check(mapindex, pass))
1080                                 return mapindex;
1081                 }
1082         }
1083         return -1;
1084 }
1085
1086 float() MaplistMethod_Repeat = // fallback method
1087 {
1088         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1089
1090         if(Map_Check(Map_Current, 2))
1091                 return Map_Current;
1092         return -2;
1093 }
1094
1095 float() MaplistMethod_Random = // random map selection
1096 {
1097         float i, imax;
1098
1099         LOG_TRACE("Trying MaplistMethod_Random\n");
1100
1101         imax = 42;
1102
1103         for(i = 0; i <= imax; ++i)
1104         {
1105                 float mapindex;
1106                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1107                 if(Map_Check(mapindex, 1))
1108                         return mapindex;
1109         }
1110         return -1;
1111 }
1112
1113 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1114 // the exponent sets a bias on the map selection:
1115 // the higher the exponent, the less likely "shortly repeated" same maps are
1116 {
1117         float i, j, imax, insertpos;
1118
1119         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1120
1121         imax = 42;
1122
1123         for(i = 0; i <= imax; ++i)
1124         {
1125                 string newlist;
1126
1127                 // now reinsert this at another position
1128                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1129                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1130                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1131                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1132
1133                 // insert the current map there
1134                 newlist = "";
1135                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1136                         newlist = strcat(newlist, " ", argv(j));
1137                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1138                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1139                         newlist = strcat(newlist, " ", argv(j));
1140                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1141                 cvar_set("g_maplist", newlist);
1142                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1143
1144                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1145                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1146                 if(Map_Check(Map_Current, 1))
1147                         return Map_Current;
1148         }
1149         return -1;
1150 }
1151
1152 void Maplist_Init()
1153 {
1154         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1155         float i;
1156         for (i = 0; i < Map_Count; ++i)
1157                 if (Map_Check(i, 2))
1158                         break;
1159         if (i == Map_Count)
1160         {
1161                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1162                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1163                 if(autocvar_g_maplist_shuffle)
1164                         ShuffleMaplist();
1165                 localcmd("\nmenu_cmd sync\n");
1166                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1167         }
1168         if(Map_Count == 0)
1169                 error("empty maplist, cannot select a new map");
1170         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1171
1172         if(Map_Current_Name)
1173                 strunzone(Map_Current_Name);
1174         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1175         // this may or may not be correct, but who cares, in the worst case a map
1176         // isn't chosen in the first pass that should have been
1177 }
1178
1179 string GetNextMap()
1180 {
1181         float nextMap;
1182
1183         Maplist_Init();
1184         nextMap = -1;
1185
1186         if(nextMap == -1)
1187                 if(autocvar_g_maplist_shuffle > 0)
1188                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1189
1190         if(nextMap == -1)
1191                 if(autocvar_g_maplist_selectrandom)
1192                         nextMap = MaplistMethod_Random();
1193
1194         if(nextMap == -1)
1195                 nextMap = MaplistMethod_Iterate();
1196
1197         if(nextMap == -1)
1198                 nextMap = MaplistMethod_Repeat();
1199
1200         if(nextMap >= 0)
1201         {
1202                 Map_Goto_SetFloat(nextMap);
1203                 return getmapname_stored;
1204         }
1205
1206         return "";
1207 }
1208
1209 float DoNextMapOverride(float reinit)
1210 {
1211         if(autocvar_g_campaign)
1212         {
1213                 CampaignPostIntermission();
1214                 alreadychangedlevel = true;
1215                 return true;
1216         }
1217         if(autocvar_quit_when_empty)
1218         {
1219                 if(player_count <= currentbots)
1220                 {
1221                         localcmd("quit\n");
1222                         alreadychangedlevel = true;
1223                         return true;
1224                 }
1225         }
1226         if(autocvar_quit_and_redirect != "")
1227         {
1228                 redirection_target = strzone(autocvar_quit_and_redirect);
1229                 alreadychangedlevel = true;
1230                 return true;
1231         }
1232         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1233         {
1234                 localcmd("restart\n");
1235                 alreadychangedlevel = true;
1236                 return true;
1237         }
1238         if(autocvar_nextmap != "")
1239         {
1240                 string m;
1241                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1242                 cvar_set("nextmap",m);
1243
1244                 if(!m || gametypevote)
1245                         return false;
1246                 if(autocvar_sv_vote_gametype)
1247                 {
1248                         Map_Goto_SetStr(m);
1249                         return false;
1250                 }
1251
1252                 if(MapInfo_CheckMap(m))
1253                 {
1254                         Map_Goto_SetStr(m);
1255                         Map_Goto(reinit);
1256                         alreadychangedlevel = true;
1257                         return true;
1258                 }
1259         }
1260         if(!reinit && autocvar_lastlevel)
1261         {
1262                 cvar_settemp_restore();
1263                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1264                 alreadychangedlevel = true;
1265                 return true;
1266         }
1267         return false;
1268 }
1269
1270 void GotoNextMap(float reinit)
1271 {
1272         //string nextmap;
1273         //float n, nummaps;
1274         //string s;
1275         if (alreadychangedlevel)
1276                 return;
1277         alreadychangedlevel = true;
1278
1279         string nextMap;
1280
1281         nextMap = GetNextMap();
1282         if(nextMap == "")
1283                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1284         Map_Goto(reinit);
1285 }
1286
1287
1288 /*
1289 ============
1290 IntermissionThink
1291
1292 When the player presses attack or jump, change to the next level
1293 ============
1294 */
1295 .float autoscreenshot;
1296 void IntermissionThink()
1297 {SELFPARAM();
1298         FixIntermissionClient(self);
1299
1300         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1301         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1302
1303         if( (server_screenshot || client_screenshot)
1304                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1305         {
1306                 self.autoscreenshot = -1;
1307                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1308                 return;
1309         }
1310
1311         if (time < intermission_exittime)
1312                 return;
1313
1314         if(!mapvote_initialized)
1315                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(self) || PHYS_INPUT_BUTTON_JUMP(self) || PHYS_INPUT_BUTTON_ATCK2(self) || PHYS_INPUT_BUTTON_HOOK(self) || PHYS_INPUT_BUTTON_USE(self)))
1316                         return;
1317
1318         MapVote_Start();
1319 }
1320
1321 /*
1322 ============
1323 FindIntermission
1324
1325 Returns the entity to view from
1326 ============
1327 */
1328 /*
1329 entity FindIntermission()
1330 {
1331         local   entity spot;
1332         local   float cyc;
1333
1334 // look for info_intermission first
1335         spot = find (world, classname, "info_intermission");
1336         if (spot)
1337         {       // pick a random one
1338                 cyc = random() * 4;
1339                 while (cyc > 1)
1340                 {
1341                         spot = find (spot, classname, "info_intermission");
1342                         if (!spot)
1343                                 spot = find (spot, classname, "info_intermission");
1344                         cyc = cyc - 1;
1345                 }
1346                 return spot;
1347         }
1348
1349 // then look for the start position
1350         spot = find (world, classname, "info_player_start");
1351         if (spot)
1352                 return spot;
1353
1354 // testinfo_player_start is only found in regioned levels
1355         spot = find (world, classname, "testplayerstart");
1356         if (spot)
1357                 return spot;
1358
1359 // then look for the start position
1360         spot = find (world, classname, "info_player_deathmatch");
1361         if (spot)
1362                 return spot;
1363
1364         //objerror ("FindIntermission: no spot");
1365         return world;
1366 }
1367 */
1368
1369 /*
1370 ===============================================================================
1371
1372 RULES
1373
1374 ===============================================================================
1375 */
1376
1377 void DumpStats(float final)
1378 {
1379         float file;
1380         string s;
1381         float to_console;
1382         float to_eventlog;
1383         float to_file;
1384         float i;
1385
1386         to_console = autocvar_sv_logscores_console;
1387         to_eventlog = autocvar_sv_eventlog;
1388         to_file = autocvar_sv_logscores_file;
1389
1390         if(!final)
1391         {
1392                 to_console = true; // always print printstats replies
1393                 to_eventlog = false; // but never print them to the event log
1394         }
1395
1396         if(to_eventlog)
1397                 if(autocvar_sv_eventlog_console)
1398                         to_console = false; // otherwise we get the output twice
1399
1400         if(final)
1401                 s = ":scores:";
1402         else
1403                 s = ":status:";
1404         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1405
1406         if(to_console)
1407                 LOG_INFO(s, "\n");
1408         if(to_eventlog)
1409                 GameLogEcho(s);
1410
1411         file = -1;
1412         if(to_file)
1413         {
1414                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1415                 if(file == -1)
1416                         to_file = false;
1417                 else
1418                         fputs(file, strcat(s, "\n"));
1419         }
1420
1421         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1422         if(to_console)
1423                 LOG_INFO(s, "\n");
1424         if(to_eventlog)
1425                 GameLogEcho(s);
1426         if(to_file)
1427                 fputs(file, strcat(s, "\n"));
1428
1429         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1430                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1431                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1432                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
1433                         s = strcat(s, ftos(it.team), ":");
1434                 else
1435                         s = strcat(s, "spectator:");
1436
1437                 if(to_console)
1438                         LOG_INFO(s, it.netname, "\n");
1439                 if(to_eventlog)
1440                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1441                 if(to_file)
1442                         fputs(file, strcat(s, it.netname, "\n"));
1443         ));
1444
1445         if(teamplay)
1446         {
1447                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1448                 if(to_console)
1449                         LOG_INFO(s, "\n");
1450                 if(to_eventlog)
1451                         GameLogEcho(s);
1452                 if(to_file)
1453                         fputs(file, strcat(s, "\n"));
1454
1455                 for(i = 1; i < 16; ++i)
1456                 {
1457                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1458                         s = strcat(s, ":", ftos(i));
1459                         if(to_console)
1460                                 LOG_INFO(s, "\n");
1461                         if(to_eventlog)
1462                                 GameLogEcho(s);
1463                         if(to_file)
1464                                 fputs(file, strcat(s, "\n"));
1465                 }
1466         }
1467
1468         if(to_console)
1469                 LOG_INFO(":end\n");
1470         if(to_eventlog)
1471                 GameLogEcho(":end");
1472         if(to_file)
1473         {
1474                 fputs(file, ":end\n");
1475                 fclose(file);
1476         }
1477 }
1478
1479 void FixIntermissionClient(entity e)
1480 {
1481         if(!e.autoscreenshot) // initial call
1482         {
1483                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1484                 e.health = -2342;
1485                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1486                 e.solid = SOLID_NOT;
1487                 e.movetype = MOVETYPE_NONE;
1488                 e.takedamage = DAMAGE_NO;
1489                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1490                 {
1491                     .entity weaponentity = weaponentities[slot];
1492                         if(e.(weaponentity))
1493                         {
1494                                 e.(weaponentity).effects = EF_NODRAW;
1495                                 if (e.(weaponentity).weaponchild)
1496                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1497                         }
1498                 }
1499                 if(IS_REAL_CLIENT(e))
1500                 {
1501                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1502                         RandomSelection_Init();
1503                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1504                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1505                         ));
1506                         if (RandomSelection_chosen_string != "")
1507                         {
1508                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1509                         }
1510                         msg_entity = e;
1511                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1512                 }
1513         }
1514 }
1515
1516 /*
1517 go to the next level for deathmatch
1518 only called if a time or frag limit has expired
1519 */
1520 void NextLevel()
1521 {
1522         gameover = true;
1523
1524         intermission_running = 1;
1525
1526 // enforce a wait time before allowing changelevel
1527         if(player_count > 0)
1528                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1529         else
1530                 intermission_exittime = -1;
1531
1532         /*
1533         WriteByte (MSG_ALL, SVC_CDTRACK);
1534         WriteByte (MSG_ALL, 3);
1535         WriteByte (MSG_ALL, 3);
1536         // done in FixIntermission
1537         */
1538
1539         //pos = FindIntermission ();
1540
1541         VoteReset();
1542
1543         DumpStats(true);
1544
1545         // send statistics
1546         PlayerStats_GameReport(true);
1547         WeaponStats_Shutdown();
1548
1549         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_Null); // kill all centerprints now
1550
1551         if(autocvar_sv_eventlog)
1552                 GameLogEcho(":gameover");
1553
1554         GameLogClose();
1555
1556         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1557                 FixIntermissionClient(it);
1558                 if(it.winning)
1559                         bprint(it.netname, " ^7wins.\n");
1560         ));
1561
1562         entity oldself = self;
1563         target_music_kill();
1564         self = oldself;
1565
1566         if(autocvar_g_campaign)
1567                 CampaignPreIntermission();
1568
1569         MUTATOR_CALLHOOK(MatchEnd);
1570
1571         localcmd("\nsv_hook_gameend\n");
1572 }
1573
1574 /*
1575 ============
1576 CheckRules_Player
1577
1578 Exit deathmatch games upon conditions
1579 ============
1580 */
1581 void CheckRules_Player()
1582 {SELFPARAM();
1583         if (gameover)   // someone else quit the game already
1584                 return;
1585
1586         if(!IS_DEAD(self))
1587                 self.play_time += frametime;
1588
1589         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1590         //   (div0: and that in CheckRules_World please)
1591 }
1592
1593
1594 float InitiateSuddenDeath()
1595 {
1596         // Check first whether normal overtimes could be added before initiating suddendeath mode
1597         // - for this timelimit_overtime needs to be >0 of course
1598         // - also check the winning condition calculated in the previous frame and only add normal overtime
1599         //   again, if at the point at which timelimit would be extended again, still no winner was found
1600         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1601         {
1602                 return 1; // need to call InitiateOvertime later
1603         }
1604         else
1605         {
1606                 if(!checkrules_suddendeathend)
1607                 {
1608                         if(autocvar_g_campaign)
1609                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1610                         else
1611                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1612                         if(g_race && !g_race_qualifying)
1613                                 race_StartCompleting();
1614                 }
1615                 return 0;
1616         }
1617 }
1618
1619 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1620 {
1621         ++checkrules_overtimesadded;
1622         //add one more overtime by simply extending the timelimit
1623         float tl;
1624         tl = autocvar_timelimit;
1625         tl += autocvar_timelimit_overtime;
1626         cvar_set("timelimit", ftos(tl));
1627
1628         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1629 }
1630
1631 float GetWinningCode(float fraglimitreached, float equality)
1632 {
1633         if(autocvar_g_campaign == 1)
1634                 if(fraglimitreached)
1635                         return WINNING_YES;
1636                 else
1637                         return WINNING_NO;
1638
1639         else
1640                 if(equality)
1641                         if(fraglimitreached)
1642                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1643                         else
1644                                 return WINNING_NEVER;
1645                 else
1646                         if(fraglimitreached)
1647                                 return WINNING_YES;
1648                         else
1649                                 return WINNING_NO;
1650 }
1651
1652 // set the .winning flag for exactly those players with a given field value
1653 void SetWinners(.float field, float value)
1654 {
1655         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1656 }
1657
1658 // set the .winning flag for those players with a given field value
1659 void AddWinners(.float field, float value)
1660 {
1661         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1662                 if(it.(field) == value)
1663                         it.winning = 1;
1664         ));
1665 }
1666
1667 // clear the .winning flags
1668 void ClearWinners()
1669 {
1670         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1671 }
1672
1673 void ShuffleMaplist()
1674 {
1675         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1676 }
1677
1678 float leaderfrags;
1679 float WinningCondition_Scores(float limit, float leadlimit)
1680 {
1681         float limitreached;
1682
1683         // TODO make everything use THIS winning condition (except LMS)
1684         WinningConditionHelper();
1685
1686         if(teamplay)
1687         {
1688                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1689                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1690                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1691                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1692         }
1693
1694         ClearWinners();
1695         if(WinningConditionHelper_winner)
1696                 WinningConditionHelper_winner.winning = 1;
1697         if(WinningConditionHelper_winnerteam >= 0)
1698                 SetWinners(team, WinningConditionHelper_winnerteam);
1699
1700         if(WinningConditionHelper_lowerisbetter)
1701         {
1702                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1703                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1704                 limit = -limit;
1705         }
1706
1707         if(WinningConditionHelper_zeroisworst)
1708                 leadlimit = 0; // not supported in this mode
1709
1710         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1711         // these modes always score in increments of 1, thus this makes sense
1712         {
1713                 if(leaderfrags != WinningConditionHelper_topscore)
1714                 {
1715                         leaderfrags = WinningConditionHelper_topscore;
1716
1717                         if (limit)
1718                         if (leaderfrags == limit - 1)
1719                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1720                         else if (leaderfrags == limit - 2)
1721                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1722                         else if (leaderfrags == limit - 3)
1723                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1724                 }
1725         }
1726
1727         limitreached = false;
1728         if(limit)
1729                 if(WinningConditionHelper_topscore >= limit)
1730                         limitreached = true;
1731         if(leadlimit)
1732         {
1733                 float leadlimitreached;
1734                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1735                 if(autocvar_leadlimit_and_fraglimit)
1736                         limitreached = (limitreached && leadlimitreached);
1737                 else
1738                         limitreached = (limitreached || leadlimitreached);
1739         }
1740
1741         if(limit)
1742                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1743
1744         return GetWinningCode(
1745                 WinningConditionHelper_topscore && limitreached,
1746                 WinningConditionHelper_equality
1747         );
1748 }
1749
1750 float WinningCondition_RanOutOfSpawns()
1751 {
1752         if(have_team_spawns <= 0)
1753                 return WINNING_NO;
1754
1755         if(!autocvar_g_spawn_useallspawns)
1756                 return WINNING_NO;
1757
1758         if(!some_spawn_has_been_used)
1759                 return WINNING_NO;
1760
1761         team1_score = team2_score = team3_score = team4_score = 0;
1762
1763         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1764                 switch(it.team)
1765                 {
1766                         case NUM_TEAM_1: team1_score = 1; break;
1767                         case NUM_TEAM_2: team2_score = 1; break;
1768                         case NUM_TEAM_3: team3_score = 1; break;
1769                         case NUM_TEAM_4: team4_score = 1; break;
1770                 }
1771         ));
1772
1773         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1774                 switch(it.team)
1775                 {
1776                         case NUM_TEAM_1: team1_score = 1; break;
1777                         case NUM_TEAM_2: team2_score = 1; break;
1778                         case NUM_TEAM_3: team3_score = 1; break;
1779                         case NUM_TEAM_4: team4_score = 1; break;
1780                 }
1781         ));
1782
1783         ClearWinners();
1784         if(team1_score + team2_score + team3_score + team4_score == 0)
1785         {
1786                 checkrules_equality = true;
1787                 return WINNING_YES;
1788         }
1789         else if(team1_score + team2_score + team3_score + team4_score == 1)
1790         {
1791                 float t, i;
1792                 if(team1_score)
1793                         t = NUM_TEAM_1;
1794                 else if(team2_score)
1795                         t = NUM_TEAM_2;
1796                 else if(team3_score)
1797                         t = NUM_TEAM_3;
1798                 else // if(team4_score)
1799                         t = NUM_TEAM_4;
1800                 CheckAllowedTeams(world);
1801                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1802                 {
1803                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1804                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1805                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1806                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1807                 }
1808
1809                 AddWinners(team, t);
1810                 return WINNING_YES;
1811         }
1812         else
1813                 return WINNING_NO;
1814 }
1815
1816 /*
1817 ============
1818 CheckRules_World
1819
1820 Exit deathmatch games upon conditions
1821 ============
1822 */
1823 void CheckRules_World()
1824 {
1825         float timelimit;
1826         float fraglimit;
1827         float leadlimit;
1828
1829         VoteThink();
1830         MapVote_Think();
1831
1832         SetDefaultAlpha();
1833
1834         if (gameover)   // someone else quit the game already
1835         {
1836                 if(player_count == 0) // Nobody there? Then let's go to the next map
1837                         MapVote_Start();
1838                         // this will actually check the player count in the next frame
1839                         // again, but this shouldn't hurt
1840                 return;
1841         }
1842
1843         timelimit = autocvar_timelimit * 60;
1844         fraglimit = autocvar_fraglimit;
1845         leadlimit = autocvar_leadlimit;
1846
1847         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1848         {
1849                 if(timelimit > 0)
1850                         timelimit = 0; // timelimit is not made for warmup
1851                 if(fraglimit > 0)
1852                         fraglimit = 0; // no fraglimit for now
1853                 leadlimit = 0; // no leadlimit for now
1854         }
1855
1856         if(timelimit > 0)
1857         {
1858                 timelimit += game_starttime;
1859         }
1860         else if (timelimit < 0)
1861         {
1862                 // endmatch
1863                 NextLevel();
1864                 return;
1865         }
1866
1867         float wantovertime;
1868         wantovertime = 0;
1869
1870         if(timelimit > game_starttime)
1871                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1872         else
1873                 game_completion_ratio = 0;
1874
1875         if(checkrules_suddendeathend)
1876         {
1877                 if(!checkrules_suddendeathwarning)
1878                 {
1879                         checkrules_suddendeathwarning = true;
1880                         if(g_race && !g_race_qualifying)
1881                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1882                         else
1883                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1884                 }
1885         }
1886         else
1887         {
1888                 if (timelimit && time >= timelimit)
1889                 {
1890                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1891                         {
1892                                 float totalplayers;
1893                                 float playerswithlaps;
1894                                 float readyplayers;
1895                                 totalplayers = playerswithlaps = readyplayers = 0;
1896                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1897                                         ++totalplayers;
1898                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1899                                                 ++playerswithlaps;
1900                                         if(it.ready)
1901                                                 ++readyplayers;
1902                                 ));
1903
1904                                 // at least 2 of the players have completed a lap: start the RACE
1905                                 // otherwise, the players should end the qualifying on their own
1906                                 if(readyplayers || playerswithlaps >= 2)
1907                                 {
1908                                         checkrules_suddendeathend = 0;
1909                                         ReadyRestart(); // go to race
1910                                         return;
1911                                 }
1912                                 else
1913                                         wantovertime |= InitiateSuddenDeath();
1914                         }
1915                         else
1916                                 wantovertime |= InitiateSuddenDeath();
1917                 }
1918         }
1919
1920         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1921         {
1922                 NextLevel();
1923                 return;
1924         }
1925
1926         int checkrules_status = WinningCondition_RanOutOfSpawns();
1927         if(checkrules_status == WINNING_YES)
1928                 bprint("Hey! Someone ran out of spawns!\n");
1929         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1930                 checkrules_status = ret_float;
1931         else
1932                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1933
1934         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1935         {
1936                 checkrules_status = WINNING_NEVER;
1937                 checkrules_overtimesadded = -1;
1938                 wantovertime |= InitiateSuddenDeath();
1939         }
1940
1941         if(checkrules_status == WINNING_NEVER)
1942                 // equality cases! Nobody wins if the overtime ends in a draw.
1943                 ClearWinners();
1944
1945         if(wantovertime)
1946         {
1947                 if(checkrules_status == WINNING_NEVER)
1948                         InitiateOvertime();
1949                 else
1950                         checkrules_status = WINNING_YES;
1951         }
1952
1953         if(checkrules_suddendeathend)
1954                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1955                         checkrules_status = WINNING_YES;
1956
1957         if(checkrules_status == WINNING_YES)
1958         {
1959                 //print("WINNING\n");
1960                 NextLevel();
1961         }
1962 }
1963
1964 string GotoMap(string m)
1965 {
1966         m = GameTypeVote_MapInfo_FixName(m);
1967         if (!m)
1968                 return "The map you suggested is not available on this server.";
1969         if (!autocvar_sv_vote_gametype)
1970         if(!MapInfo_CheckMap(m))
1971                 return "The map you suggested does not support the current game mode.";
1972         cvar_set("nextmap", m);
1973         cvar_set("timelimit", "-1");
1974         if(mapvote_initialized || alreadychangedlevel)
1975         {
1976                 if(DoNextMapOverride(0))
1977                         return "Map switch initiated.";
1978                 else
1979                         return "Hm... no. For some reason I like THIS map more.";
1980         }
1981         else
1982                 return "Map switch will happen after scoreboard.";
1983 }
1984
1985
1986 void EndFrame()
1987 {
1988         anticheat_endframe();
1989
1990         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
1991                 entity e = IS_SPEC(it) ? it.enemy : it;
1992                 if (e.typehitsound) {
1993                         it.typehit_time = time;
1994                 } else if (e.damage_dealt) {
1995                         it.hit_time = time;
1996                         it.damage_dealt_total += ceil(e.damage_dealt);
1997                 }
1998         });
1999         // add 1 frametime because after this, engine SV_Physics
2000         // increases time by a frametime and then networks the frame
2001         // add another frametime because client shows everything with
2002         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2003         // needed!
2004         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2005         FOREACH_CLIENT(true, {
2006                 it.typehitsound = false;
2007                 it.damage_dealt = 0;
2008                 antilag_record(it, CS(it), altime);
2009         });
2010         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, {
2011                 antilag_record(it, it, altime);
2012         });
2013         FOREACH_CLIENT(PS(it), {
2014                 PlayerState s = PS(it);
2015                 s.ps_push(s, it);
2016         });
2017 }
2018
2019
2020 /*
2021  * RedirectionThink:
2022  * returns true if redirecting
2023  */
2024 float redirection_timeout;
2025 float redirection_nextthink;
2026 float RedirectionThink()
2027 {SELFPARAM();
2028         float clients_found;
2029
2030         if(redirection_target == "")
2031                 return false;
2032
2033         if(!redirection_timeout)
2034         {
2035                 cvar_set("sv_public", "-2");
2036                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2037                 if(redirection_target == "self")
2038                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2039                 else
2040                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2041         }
2042
2043         if(time < redirection_nextthink)
2044                 return true;
2045
2046         redirection_nextthink = time + 1;
2047
2048         clients_found = 0;
2049         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2050                 setself(it);
2051                 // TODO add timer
2052                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2053                 if(redirection_target == "self")
2054                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2055                 else
2056                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2057                 ++clients_found;
2058         ));
2059
2060         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2061
2062         if(time > redirection_timeout || clients_found == 0)
2063                 localcmd("\nwait; wait; wait; quit\n");
2064
2065         return true;
2066 }
2067
2068 void TargetMusic_RestoreGame();
2069 void RestoreGame()
2070 {
2071         // Loaded from a save game
2072         // some things then break, so let's work around them...
2073
2074         // Progs DB (capture records)
2075         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2076
2077         // Mapinfo
2078         MapInfo_Shutdown();
2079         MapInfo_Enumerate();
2080         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2081         WeaponStats_Init();
2082
2083         TargetMusic_RestoreGame();
2084 }
2085
2086 void Shutdown()
2087 {
2088         gameover = 2;
2089
2090         if(world_initialized > 0)
2091         {
2092                 world_initialized = 0;
2093                 LOG_TRACE("Saving persistent data...\n");
2094                 Ban_SaveBans();
2095
2096                 // playerstats with unfinished match
2097                 PlayerStats_GameReport(false);
2098
2099                 if(!cheatcount_total)
2100                 {
2101                         if(autocvar_sv_db_saveasdump)
2102                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2103                         else
2104                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2105                 }
2106                 if(autocvar_developer)
2107                 {
2108                         if(autocvar_sv_db_saveasdump)
2109                                 db_dump(TemporaryDB, "server-temp.db");
2110                         else
2111                                 db_save(TemporaryDB, "server-temp.db");
2112                 }
2113                 CheatShutdown(); // must be after cheatcount check
2114                 db_close(ServerProgsDB);
2115                 db_close(TemporaryDB);
2116                 LOG_TRACE("Saving persistent data... done!\n");
2117                 // tell the bot system the game is ending now
2118                 bot_endgame();
2119
2120                 WeaponStats_Shutdown();
2121                 MapInfo_Shutdown();
2122         }
2123         else if(world_initialized == 0)
2124         {
2125                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2126         }
2127         else
2128         {
2129                 __init_dedicated_server_shutdown();
2130         }
2131 }