qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2 void race_deleteTime(string map, float pos);
   3
   4 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   5 {
   6         vector c;
   7         float white, black;
   8
   9         white = 0.001;
  10         black = 0.001;
  11
  12         c = a;
  13
  14         float n, m;
  15         n = m = 0;
  16
  17         while(vlen(c - b) > 1)
  18         {
  19                 ++m;
  20
  21                 tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
  22                 ++n;
  23
  24                 if(!trace_startsolid)
  25                 {
  26                         black += vlen(trace_endpos - c);
  27                         c = trace_endpos;
  28                 }
  29
  30                 n += tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);
  31
  32                 white += vlen(trace_endpos - c);
  33                 c = trace_endpos;
  34         }
  35
  36         if(n > 200)
  37                 dprint("HOLY SHIT! FullTraceFraction: ", ftos(n), " total traces, ", ftos(m), " iterations\n");
  38
  39         return white / (black + white);
  40 }
  41
  42 float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize, float q)
  43 {
  44         vector a, b, mi, ma;
  45
  46         mi = '0 0 0';
  47         ma = '1 0 0' * w + '0 1 0' * h;
  48         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  49         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize + zmin);
  50
  51         return FullTraceFraction(a, mi, ma, b);
  52 }
  53 float RadarMapAtPoint_LineBlock(float x, float y, float w, float h, float zmin, float zsize, float q)
  54 {
  55         vector o, mi, ma;
  56         float i, r;
  57         vector dz;
  58
  59         q = 256 * q - 1;
  60         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
  61
  62         mi = '0 0 0';
  63         dz = (zsize / q) * '0 0 1';
  64         ma = '1 0 0' * w + '0 1 0' * h + dz;
  65         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  66
  67         if(x < world.absmin_x - w)
  68                 return 0;
  69         if(y < world.absmin_y - h)
  70                 return 0;
  71         if(x > world.absmax_x)
  72                 return 0;
  73         if(y > world.absmax_y)
  74                 return 0;
  75
  76         r = 0;
  77         for(i = 0; i < q; ++i)
  78         {
  79                 vector v1, v2;
  80                 v1 = v2 = o + dz * i + mi;
  81                 v1_x += random() * (ma_x - mi_x);
  82                 v1_y += random() * (ma_y - mi_y);
  83                 v1_z += random() * (ma_z - mi_z);
  84                 v2_x += random() * (ma_x - mi_x);
  85                 v2_y += random() * (ma_y - mi_y);
  86                 v2_z += random() * (ma_z - mi_z);
  87                 traceline(v1, v2, MOVE_WORLDONLY, world);
  88                 if(trace_startsolid || trace_fraction < 1)
  89                         ++r;
  90         }
  91         return r / q;
  92 }
  93 float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
  94 {
  95         vector o, mi, ma;
  96         float i, r;
  97         vector dz;
  98
  99         q = 256 * q - 1;
 100         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
 101
 102         mi = '0 0 0';
 103         dz = (zsize / q) * '0 0 1';
 104         ma = '1 0 0' * w + '0 1 0' * h + dz;
 105         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
 106
 107         if(x < world.absmin_x - w)
 108                 return 0;
 109         if(y < world.absmin_y - h)
 110                 return 0;
 111         if(x > world.absmax_x)
 112                 return 0;
 113         if(y > world.absmax_y)
 114                 return 0;
 115
 116         r = 0;
 117         for(i = 0; i < q; ++i)
 118         {
 119                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
 120                 if(trace_startsolid)
 121                         ++r;
 122         }
 123         return r / q;
 124 }
 125 float RadarMapAtPoint_Sample(float x, float y, float w, float h, float zmin, float zsize, float q)
 126 {
 127         vector a, b, mi, ma;
 128
 129         q *= 4; // choose q so it matches the regular algorithm in speed
 130
 131         q = 256 * q - 1;
 132         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
 133
 134         mi = '0 0 0';
 135         ma = '1 0 0' * w + '0 1 0' * h;
 136         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
 137         b = '1 0 0' * w + '0 1 0' * h + '0 0 1' * zsize;
 138
 139         float c, i;
 140         c = 0;
 141
 142         for(i = 0; i < q; ++i)
 143         {
 144                 vector v;
 145                 v_x = a_x + random() * b_x;
 146                 v_y = a_y + random() * b_y;
 147                 v_z = a_z + random() * b_z;
 148                 traceline(v, v, MOVE_WORLDONLY, world);
 149                 if(trace_startsolid)
 150                         ++c;
 151         }
 152
 153         return c / q;
 154 }
 155
 156 // FF is contained twice, to map 256 to FF too
 157 // removes the need to bound()
 158 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFFFF";
 159
 160 float RADAR_WIDTH_MAX = 512;
 161 float RADAR_HEIGHT_MAX = 512;
 162 float sharpen_buffer[RADAR_WIDTH_MAX * 3];
 163
 164 void sharpen_set(float x, float v)
 165 {
 166         sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
 167 }
 168
 169 float sharpen_getpixel(float x, float y)
 170 {
 171         if(x < 0)
 172                 return 0;
 173         if(x >= RADAR_WIDTH_MAX)
 174                 return 0;
 175         if(y < 0)
 176                 return 0;
 177         if(y > 2)
 178                 return 0;
 179         return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
 180 }
 181
 182 float sharpen_get(float x, float a)
 183 {
 184         float sum;
 185         sum = sharpen_getpixel(x, 1);
 186         if(a == 0)
 187                 return sum;
 188         sum *= (8 + 1/a);
 189         sum -= sharpen_getpixel(x - 1, 0);
 190         sum -= sharpen_getpixel(x - 1, 1);
 191         sum -= sharpen_getpixel(x - 1, 2);
 192         sum -= sharpen_getpixel(x + 1, 0);
 193         sum -= sharpen_getpixel(x + 1, 1);
 194         sum -= sharpen_getpixel(x + 1, 2);
 195         sum -= sharpen_getpixel(x, 0);
 196         sum -= sharpen_getpixel(x, 2);
 197         return bound(0, sum * a, 1);
 198 }
 199
 200 void sharpen_shift(float w)
 201 {
 202         float i;
 203         for(i = 0; i < w; ++i)
 204         {
 205                 sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
 206                 sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
 207                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 208         }
 209 }
 210
 211 void sharpen_init(float w)
 212 {
 213         float i;
 214         for(i = 0; i < w; ++i)
 215         {
 216                 sharpen_buffer[i] = 0;
 217                 sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
 218                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 219         }
 220 }
 221
 222 entity radarmapper;
 223 void RadarMap_Next()
 224 {
 225         if(radarmapper.count & 4)
 226         {
 227                 localcmd("quit\n");
 228         }
 229         else if(radarmapper.count & 2)
 230         {
 231                 localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(radarmapper.count), strcat(" --res ", ftos(radarmapper.size_x), " ", ftos(radarmapper.size_y), " --sharpen ", ftos(radarmapper.ltime), " --qual ", ftos(radarmapper.size_z)), "\"\n"));
 232                 GotoNextMap();
 233         }
 234         remove(radarmapper);
 235         radarmapper = world;
 236 }
 237
 238 // rough map entity
 239 //   cnt: current line
 240 //   size: pixel width/height
 241 //   maxs: cell width/height
 242 //   frame: counter
 243 void RadarMap_Think()
 244 {
 245         float i, x, l;
 246         string si;
 247
 248         if(self.frame == 0)
 249         {
 250                 // initialize
 251                 get_mi_min_max_texcoords(1);
 252                 self.mins = mi_picmin;
 253                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
 254                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
 255                 self.maxs_z = mi_max_z - mi_min_z;
 256                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
 257                 self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
 258                 if(!(self.count & 1))
 259                 {
 260                         self.cnt = fopen(self.netname, FILE_READ);
 261                         if(self.cnt < 0)
 262                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.tga"), FILE_READ);
 263                         if(self.cnt < 0)
 264                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.png"), FILE_READ);
 265                         if(self.cnt < 0)
 266                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.jpg"), FILE_READ);
 267                         if(self.cnt < 0)
 268                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.tga"), FILE_READ);
 269                         if(self.cnt < 0)
 270                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.png"), FILE_READ);
 271                         if(self.cnt < 0)
 272                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.jpg"), FILE_READ);
 273                         if(self.cnt >= 0)
 274                         {
 275                                 fclose(self.cnt);
 276
 277                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 278                                 RadarMap_Next();
 279                                 return;
 280                         }
 281                 }
 282                 self.cnt = fopen(self.netname, FILE_WRITE);
 283                 if(self.cnt < 0)
 284                 {
 285                         print("Error writing ", self.netname, "\n");
 286                         remove(self);
 287                         radarmapper = world;
 288                         return;
 289                 }
 290                 print("Writing to ", self.netname, "...\n");
 291                 fputs(self.cnt, "/* XPM */\n");
 292                 fputs(self.cnt, "static char *RadarMap[] = {\n");
 293                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 294                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 295                 for(i = 0; i < 256; ++i)
 296                 {
 297                         si = substring(doublehex, i*2, 2);
 298                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 299                 }
 300                 self.frame += 1;
 301                 self.nextthink = time;
 302                 sharpen_init(self.size_x);
 303         }
 304         else if(self.frame <= self.size_y)
 305         {
 306                 // fill the sharpen buffer with this line
 307                 sharpen_shift(self.size_x);
 308                 i = self.count & 24;
 309
 310                 switch(i)
 311                 {
 312                         case 0:
 313                         default:
 314                                 for(x = 0; x < self.size_x; ++x)
 315                                 {
 316                                         l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 317                                         sharpen_set(x, l);
 318                                 }
 319                                 break;
 320                         case 8:
 321                                 for(x = 0; x < self.size_x; ++x)
 322                                 {
 323                                         l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 324                                         sharpen_set(x, l);
 325                                 }
 326                                 break;
 327                         case 16:
 328                                 for(x = 0; x < self.size_x; ++x)
 329                                 {
 330                                         l = RadarMapAtPoint_Sample(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 331                                         sharpen_set(x, l);
 332                                 }
 333                                 break;
 334                         case 24:
 335                                 for(x = 0; x < self.size_x; ++x)
 336                                 {
 337                                         l = RadarMapAtPoint_LineBlock(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 338                                         sharpen_set(x, l);
 339                                 }
 340                                 break;
 341                 }
 342
 343                 // do we have enough lines?
 344                 if(self.frame >= 2)
 345                 {
 346                         // write a pixel line
 347                         fputs(self.cnt, "\"");
 348                         for(x = 0; x < self.size_x; ++x)
 349                         {
 350                                 l = sharpen_get(x, self.ltime);
 351                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 352                         }
 353                         if(self.frame == self.size_y)
 354                                 fputs(self.cnt, "\"\n");
 355                         else
 356                         {
 357                                 fputs(self.cnt, "\",\n");
 358                                 print(ftos(self.size_y - self.frame), " lines left\n");
 359                         }
 360                 }
 361
 362                 // is this the last line? then write back the missing line
 363                 if(self.frame == self.size_y)
 364                 {
 365                         sharpen_shift(self.size_x);
 366                         // write a pixel line
 367                         fputs(self.cnt, "\"");
 368                         for(x = 0; x < self.size_x; ++x)
 369                         {
 370                                 l = sharpen_get(x, self.ltime);
 371                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 372                         }
 373                         if(self.frame == self.size_y)
 374                                 fputs(self.cnt, "\"\n");
 375                         else
 376                         {
 377                                 fputs(self.cnt, "\",\n");
 378                                 print(ftos(self.size_y - self.frame), " lines left\n");
 379                         }
 380                 }
 381
 382                 self.frame += 1;
 383                 self.nextthink = time;
 384         }
 385         else
 386         {
 387                 // close the file
 388                 fputs(self.cnt, "};\n");
 389                 fclose(self.cnt);
 390                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 391                 RadarMap_Next();
 392         }
 393 }
 394
 395 void RadarMap(float argc)
 396 {
 397         if(radarmapper)
 398                 return;
 399         float i;
 400         radarmapper = spawn();
 401         radarmapper.classname = "radarmapper";
 402         radarmapper.think = RadarMap_Think;
 403         radarmapper.nextthink = time;
 404         radarmapper.count = 8; // default to the --trace method, as it is faster now
 405         radarmapper.ltime = 1;
 406         radarmapper.size_x = 512;
 407         radarmapper.size_y = 512;
 408         radarmapper.size_z = 1;
 409
 410         for(i = 1; i < argc; ++i)
 411         {
 412                 if(argv(i) == "--force")
 413                         radarmapper.count |= 1;
 414                 else if(argv(i) == "--loop")
 415                         radarmapper.count |= 2;
 416                 else if(argv(i) == "--quit")
 417                         radarmapper.count |= 4;
 418                 else if(argv(i) == "--block")
 419                 {
 420                         radarmapper.count &~= 24;
 421                 }
 422                 else if(argv(i) == "--trace")
 423                 {
 424                         radarmapper.count &~= 24;
 425                         radarmapper.count |= 8;
 426                 }
 427                 else if(argv(i) == "--sample")
 428                 {
 429                         radarmapper.count &~= 24;
 430                         radarmapper.count |= 16;
 431                 }
 432                 else if(argv(i) == "--lineblock")
 433                 {
 434                         radarmapper.count |= 24;
 435                 }
 436                 else if(argv(i) == "--flags") // for the recursive call
 437                 {
 438                         ++i;
 439                         radarmapper.count = stof(argv(i));
 440                 }
 441                 else if(argv(i) == "--sharpen") // for the recursive call
 442                 {
 443                         ++i;
 444                         radarmapper.ltime = stof(argv(i));
 445                 }
 446                 else if(argv(i) == "--res") // resolution
 447                 {
 448                         ++i;
 449                         radarmapper.size_x = stof(argv(i));
 450                         ++i;
 451                         radarmapper.size_y = stof(argv(i));
 452                 }
 453                 else if(argv(i) == "--qual") // quality multiplier
 454                 {
 455                         ++i;
 456                         radarmapper.size_z = stof(argv(i));
 457                 }
 458                 else
 459                 {
 460                         remove(radarmapper);
 461                         radarmapper = world;
 462                         print("Usage: sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
 463                         print("The quality factor Q is roughly proportional to the time taken.\n");
 464                         print("--trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
 465                         print("--block \n");
 466                         return;
 467                 }
 468         }
 469
 470         print("Radarmap entity spawned.\n");
 471 }
 472
 473 void make_mapinfo_Think()
 474 {
 475         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 476         {
 477                 print("Done rebuiling mapinfos.\n");
 478                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 479                 remove(self);
 480         }
 481         else
 482         {
 483                 self.think = make_mapinfo_Think;
 484                 self.nextthink = time;
 485         }
 486 }
 487
 488 void changematchtime(float delta, float mi, float ma)
 489 {
 490         float cur;
 491         float new;
 492         float lim;
 493
 494         if(delta == 0)
 495                 return;
 496         if(autocvar_timelimit < 0)
 497                 return;
 498
 499         if(mi <= 10)
 500                 mi = 10; // at least ten sec in the future
 501         cur = time - game_starttime;
 502         if(cur > 0)
 503                 mi += cur; // from current time!
 504
 505         lim = autocvar_timelimit * 60;
 506
 507         if(delta > 0)
 508         {
 509                 if(lim == 0)
 510                         return; // cannot increase any further
 511                 else if(lim < ma)
 512                         new = min(ma, lim + delta);
 513                 else // already above maximum: FAIL
 514                         return;
 515         }
 516         else
 517         {
 518                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
 519                         new = max(mi, ma);
 520                 else if(lim > mi) // above minimum: decrease
 521                         new = max(mi, lim + delta);
 522                 else // already below minimum: FAIL
 523                         return;
 524         }
 525
 526         cvar_set("timelimit", ftos(new / 60));
 527 }
 528
 529 float g_clientmodel_genericsendentity (entity to, float sf);
 530 void modelbug_make_svqc();
 531 void modelbug_make_csqc()
 532 {
 533         Net_LinkEntity(self, TRUE, 0, g_clientmodel_genericsendentity);
 534         self.think = modelbug_make_svqc;
 535         self.nextthink = time + 1;
 536         setorigin(self, self.origin - '0 0 8');
 537 }
 538 void modelbug_make_svqc()
 539 {
 540         self.SendEntity = func_null;
 541         self.think = modelbug_make_csqc;
 542         self.nextthink = time + 1;
 543         setorigin(self, self.origin + '0 0 8');
 544 }
 545
 546 void modelbug()
 547 {
 548         entity e;
 549         e = spawn();
 550         setorigin(e, nextent(world).origin);
 551         precache_model("models_portal.md3");
 552         setmodel(e, "models/portal.md3");
 553         e.think = modelbug_make_svqc;
 554         e.nextthink = time + 1;
 555 }
 556
 557 // ===================
 558 //  Command Functions
 559 // ===================
 560 #define GC_REQUEST_HELP 1
 561 #define GC_REQUEST_COMMAND 2
 562 #define GC_REQUEST_USAGE 3
 563
 564 void GameCommand_adminmsg(float request, string command)
 565 {
 566         entity client;
 567         float argc = tokenize_console(command);
 568         float entno = stof(argv(1));
 569         float n, i;
 570         string s;
 571
 572         switch(request)
 573         {
 574                 case GC_REQUEST_HELP:
 575                         print("  ^2adminmsg^7: Send an admin message to a client directly\n");
 576                         return;
 577
 578                 case GC_REQUEST_COMMAND:
 579                         if(argc >= 3 && argc <= 4) {
 580                                 if((entno < 0) | (entno > maxclients)) {
 581                                         print("Player ", argv(1), " doesn't exist\n");
 582                                         return;
 583                                 }
 584                                 n = 0;
 585                                 for(i = (entno ? entno : 1); i <= (entno ? entno : maxclients); ++i)
 586                                 {
 587                                         client = edict_num(i);
 588                                         if(client.flags & FL_CLIENT)
 589                                         {
 590                                                 if(argc == 4)
 591                                                 {
 592                                                         s = argv(2);
 593                                                         s = strreplace("\n", "", s);
 594                                                         s = strreplace("\\", "\\\\", s);
 595                                                         s = strreplace("$", "$$", s);
 596                                                         s = strreplace("\"", "\\\"", s);
 597                                                         stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", stof(argv(3)), s));
 598                                                 }
 599                                                 else
 600                                                 {
 601                                                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3", admin_name(), ":\n\n^7", argv(2)));
 602                                                         sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", argv(2), "\n"));
 603                                                 }
 604                                                 dprint("Message sent to ", client.netname, "\n");
 605                                                 ++n;
 606                                         }
 607                                 }
 608                                 if(!n) { print("Client not found\n"); }
 609                                 return;
 610                         }
 611
 612                 default:
 613                         print("Incorrect parameters for \"adminmsg\"\n");
 614                 case GC_REQUEST_USAGE:
 615                         print("\nUsage:^3 sv_cmd adminmsg clientnumber \"message\" [infobartime]\n");
 616                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 617                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 618                         print("Examples: adminmsg 4 \"this message will last for ten seconds\" 10\n");
 619                         print("          adminmsg 2 \"this message will be a centerprint\"\n");
 620                         return;
 621         }
 622 }
 623
 624 void GameCommand_allready(float request)
 625 {
 626         switch(request)
 627         {
 628                 case GC_REQUEST_HELP:
 629                         print("  ^2allready^7: Restart the server and reset the players\n");
 630                         return;
 631
 632                 case GC_REQUEST_COMMAND:
 633                         ReadyRestart();
 634                         return;
 635
 636                 default:
 637                 case GC_REQUEST_USAGE:
 638                         print("\nUsage:^3 sv_cmd allready\n");
 639                         print("  No arguments required.\n");
 640                         return;
 641         }
 642 }
 643
 644 void GameCommand_allspec(float request) // todo: Add ability to provide a reason string?
 645 {
 646         entity client;
 647         float i;
 648         switch(request)
 649         {
 650                 case GC_REQUEST_HELP:
 651                         print("  ^2allspec^7: Force all players to spectate\n");
 652                         return;
 653
 654                 case GC_REQUEST_COMMAND:
 655                         FOR_EACH_PLAYER(client)
 656                         {
 657                                 self = client;
 658                                 PutObserverInServer();
 659                                 ++i;
 660                         }
 661                         if(i) { bprint(strcat("Successfully forced all players to spectate (", ftos(i), ")\n")); } // should a message be added if no players were found?
 662                         return;
 663
 664                 default:
 665                 case GC_REQUEST_USAGE:
 666                         print("\nUsage:^3 sv_cmd allspec\n");
 667                         print("  No arguments required.\n");
 668                         print("  See also: ^2moveplayer^7\n");
 669                         return;
 670         }
 671 }
 672
 673 void GameCommand_anticheat(float request, string command) // FIXME: player entity is never found
 674 {
 675         entity client;
 676         float argc = tokenize_console(command);
 677         float entno = stof(argv(1));
 678
 679         switch(request)
 680         {
 681                 case GC_REQUEST_HELP:
 682                         print("  ^2anticheat^7: Create an anticheat report for a client\n");
 683                         return;
 684
 685                 case GC_REQUEST_COMMAND:
 686                         if((entno < 1) | (entno > maxclients)) {
 687                                 print("Player ", argv(1), " doesn't exist\n");
 688                                 return;
 689                         }
 690                         client = edict_num(entno);
 691                         if(clienttype(client) != CLIENTTYPE_REAL && clienttype(client) != CLIENTTYPE_BOT) {
 692                                 print("Player ", client.netname, " is not active\n");
 693                                 return;
 694                         }
 695                         self = client;
 696                         anticheat_report();
 697                         return;
 698
 699                 default:
 700                         print("Incorrect parameters for \"anticheat\"\n");
 701                 case GC_REQUEST_USAGE:
 702                         print("\nUsage:^3 sv_cmd anticheat clientnumber\n");
 703                         print("  where clientnumber is player entity number.\n");
 704                         return;
 705         }
 706 }
 707
 708 void GameCommand_bbox(float request)
 709 {
 710         switch(request)
 711         {
 712                 case GC_REQUEST_HELP:
 713                         print("  ^2bbox^7: Print detailed information about world size\n");
 714                         return;
 715
 716                 case GC_REQUEST_COMMAND:
 717                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 718                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 719                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 720                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 721                         print("Solid bounding box size:");
 722
 723                         tracebox('1 0 0' * world.absmin_x,
 724                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 725                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 726                                                         '1 0 0' * world.absmax_x,
 727                                         MOVE_WORLDONLY,
 728                                         world);
 729                         if(trace_startsolid)
 730                                 print(" ", ftos(world.absmin_x));
 731                         else
 732                                 print(" ", ftos(trace_endpos_x));
 733
 734                         tracebox('0 1 0' * world.absmin_y,
 735                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 736                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 737                                                         '0 1 0' * world.absmax_y,
 738                                         MOVE_WORLDONLY,
 739                                         world);
 740                         if(trace_startsolid)
 741                                 print(" ", ftos(world.absmin_y));
 742                         else
 743                                 print(" ", ftos(trace_endpos_y));
 744
 745                         tracebox('0 0 1' * world.absmin_z,
 746                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 747                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 748                                                         '0 0 1' * world.absmax_z,
 749                                         MOVE_WORLDONLY,
 750                                         world);
 751                         if(trace_startsolid)
 752                                 print(" ", ftos(world.absmin_z));
 753                         else
 754                                 print(" ", ftos(trace_endpos_z));
 755
 756                         tracebox('1 0 0' * world.absmax_x,
 757                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 758                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 759                                                         '1 0 0' * world.absmin_x,
 760                                         MOVE_WORLDONLY,
 761                                         world);
 762                         if(trace_startsolid)
 763                                 print(" ", ftos(world.absmax_x));
 764                         else
 765                                 print(" ", ftos(trace_endpos_x));
 766
 767                         tracebox('0 1 0' * world.absmax_y,
 768                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 769                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 770                                                         '0 1 0' * world.absmin_y,
 771                                         MOVE_WORLDONLY,
 772                                         world);
 773                         if(trace_startsolid)
 774                                 print(" ", ftos(world.absmax_y));
 775                         else
 776                                 print(" ", ftos(trace_endpos_y));
 777
 778                         tracebox('0 0 1' * world.absmax_z,
 779                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 780                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 781                                                         '0 0 1' * world.absmin_z,
 782                                         MOVE_WORLDONLY,
 783                                         world);
 784                         if(trace_startsolid)
 785                                 print(" ", ftos(world.absmax_z));
 786                         else
 787                                 print(" ", ftos(trace_endpos_z));
 788
 789                         print("\n");
 790                         return;
 791
 792                 default:
 793                 case GC_REQUEST_USAGE:
 794                         print("\nUsage:^3 sv_cmd bbox\n");
 795                         print("  No arguments required.\n");
 796                         print("  See also: ^2gettaginfo^7\n");
 797                         return;
 798         }
 799 }
 800
 801 void GameCommand_bot_cmd(float request, string command) // what a mess... old old code.
 802 {
 803         entity bot;
 804         float argc = tokenize_console(command);
 805
 806         switch(request)
 807         {
 808                 case GC_REQUEST_HELP:
 809                         print("  ^2bot_cmd^7: Control and send commands to bots\n");
 810                         return;
 811
 812                 case GC_REQUEST_COMMAND:
 813                         if(argv(1) == "reset")
 814                         {
 815                                 bot_resetqueues();
 816                                 return;
 817                         }
 818                         else if(argv(1) == "load" && argc == 3)
 819                         {
 820                                 float fh, i;
 821                                 string s;
 822                                 fh = fopen(argv(2), FILE_READ);
 823                                 if(fh < 0)
 824                                 {
 825                                         print("cannot open the file\n");
 826                                         return;
 827                                 }
 828
 829                                 i = 0;
 830                                 while((s = fgets(fh)))
 831                                 {
 832                                         argc = tokenize_console(s);
 833
 834                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 835                                         {
 836                                                 // let's start at token 2 so we can skip sv_cmd bot_cmd
 837                                                 bot = find_bot_by_number(stof(argv(2)));
 838                                                 if(bot == world)
 839                                                         bot = find_bot_by_name(argv(2));
 840                                                 if(bot)
 841                                                         bot_queuecommand(bot, strcat(argv(3), " ", argv(4)));
 842                                         }
 843                                         else
 844                                                 localcmd(strcat(s, "\n"));
 845
 846                                         ++i;
 847                                 }
 848                                 print(ftos(i), " commands read\n");
 849                                 fclose(fh);
 850                                 return;
 851                         }
 852                         else if(argv(1) == "help")
 853                         {
 854                                 if(argv(2))
 855                                         bot_cmdhelp(argv(2));
 856                                 else
 857                                         bot_list_commands();
 858                                 return;
 859                         }
 860                         else if(argc >= 3) // this comes last
 861                         {
 862                                 bot = find_bot_by_number(stof(argv(1)));
 863                                 if(bot == world)
 864                                         bot = find_bot_by_name(argv(1));
 865                                 if(bot)
 866                                 {
 867                                         print(strcat("Command '", (argv(2), " ", argv(3)), "' sent to bot ", bot.netname, "\n"));
 868                                         bot_queuecommand(bot, strcat(argv(2), " ", argv(3)));
 869                                         return;
 870                                 }
 871                                 else
 872                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 873                         }
 874
 875                 default:
 876                         print("Incorrect parameters for \"bot_cmd\"\n");
 877                 case GC_REQUEST_USAGE:
 878                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 879                         print("  'client' can be either the name or entity id of the bot\n");
 880                         print("  For full list of commands, see bot_cmd help [command].\n");
 881                         print("Examples: bot_cmd <id> cc \"say something\"\n");
 882                         print("          bot_cmd <id> presskey jump\n");
 883                         return;
 884         }
 885 }
 886
 887 void GameCommand_cointoss(float request) // todo: Perhaps add the ability to give your own arguments to pick between? (Like player names)
 888 {
 889         entity client;
 890         float choice = (random() > 0.5);
 891
 892         switch(request)
 893         {
 894                 case GC_REQUEST_HELP:
 895                         print("  ^2cointoss^7: Flip a virtual coin and give random result\n");
 896                         return;
 897
 898                 case GC_REQUEST_COMMAND:
 899                         FOR_EACH_CLIENT(client)
 900                                 centerprint(client, strcat("^3Throwing coin... Result: ", (choice ? "^1HEADS^3!\n" : "^4TAILS^3!\n")));
 901                         bprint(strcat("^3Throwing coin... Result: ", (choice ? "^1HEADS^3!\n" : "^4TAILS^3!\n")));
 902                         return;
 903
 904                 default:
 905                 case GC_REQUEST_USAGE:
 906                         print("\nUsage:^3 sv_cmd cointoss\n");
 907                         print("  No arguments required.\n");
 908                         return;
 909         }
 910 }
 911
 912 void GameCommand_cvar_changes(float request)
 913 {
 914         switch(request)
 915         {
 916                 case GC_REQUEST_HELP:
 917                         print("  ^2cvar_changes^7: Prints a list of all changed server cvars\n");
 918                         return;
 919
 920                 case GC_REQUEST_COMMAND:
 921                         print(cvar_changes);
 922                         return;
 923
 924                 default:
 925                 case GC_REQUEST_USAGE:
 926                         print("\nUsage:^3 sv_cmd \n");
 927                         print("  No arguments required.\n");
 928                         print("  See also: ^2cvar_purechanges^7\n");
 929                         return;
 930         }
 931 }
 932
 933 void GameCommand_cvar_purechanges(float request)
 934 {
 935         switch(request)
 936         {
 937                 case GC_REQUEST_HELP:
 938                         print("  ^2cvar_purechanges^7: Prints a list of all changed gameplay cvars\n");
 939                         return;
 940
 941                 case GC_REQUEST_COMMAND:
 942                         print(cvar_purechanges);
 943                         return;
 944
 945                 default:
 946                 case GC_REQUEST_USAGE:
 947                         print("\nUsage:^3 sv_cmd cvar_purechanges\n");
 948                         print("  No arguments required.\n");
 949                         print("  See also: ^2cvar_changes^7\n");
 950                         return;
 951         }
 952 }
 953
 954 void GameCommand_database(float request, string command)
 955 {
 956         float argc = tokenize_console(command);
 957
 958         switch(request)
 959         {
 960                 case GC_REQUEST_HELP:
 961                         print("  ^2database^7: Extra controls of the serverprogs database\n");
 962                         return;
 963
 964                 case GC_REQUEST_COMMAND:
 965                         if(argc == 3)
 966                         {
 967                                 if(argv(1) == "save")
 968                                 {
 969                                         db_save(ServerProgsDB, argv(2));
 970                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 971                                         return;
 972                                 }
 973                                 else if(argv(1) == "dump")
 974                                 {
 975                                         db_dump(ServerProgsDB, argv(2));
 976                                         print("DB dumped.\n"); // wtf does this do?
 977                                         return;
 978                                 }
 979                                 else if(argv(1) == "load")
 980                                 {
 981                                         db_close(ServerProgsDB);
 982                                         ServerProgsDB = db_load(argv(2));
 983                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 984                                         return;
 985                                 }
 986                         }
 987
 988                 default:
 989                         print("Incorrect parameters for \"database\"\n");
 990                 case GC_REQUEST_USAGE:
 991                         print("\nUsage:^3 sv_cmd database action filename\n");
 992                         print("  Where 'action' is the command to complete,\n");
 993                         print("  and 'filename' is what it acts upon.\n");
 994                         print("  Full list of commands here: \"save, dump, load.\"\n");
 995                         return;
 996         }
 997 }
 998
 999 void GameCommand_defer_clear(float request, string command)
1000 {
1001         entity client;
1002         float argc = tokenize_console(command);
1003         float entno = stof(argv(1));
1004
1005         switch(request)
1006         {
1007                 case GC_REQUEST_HELP:
1008                         print("  ^2defer_clear^7: Clear all queued defer commands for client\n");
1009                         return;
1010
1011                 case GC_REQUEST_COMMAND:
1012                         if(argc == 2)
1013                         {
1014                                 // player_id is out of range
1015                                 if((entno < 1) | (entno > maxclients)) {
1016                                         print("Player ", argv(1), " doesn't exist\n");
1017                                         return;
1018                                 }
1019                                 client = edict_num(entno);
1020                                 if not(client.flags & FL_CLIENT) {
1021                                         print("Player ", argv(1), " doesn't exist\n");
1022                                         return;
1023                                 }
1024                                 if(clienttype(client) == CLIENTTYPE_BOT) {
1025                                         print("Player ", argv(1), " (", client.netname, ") is a bot\n");
1026                                         return;
1027                                 }
1028                                 stuffcmd(client, "defer clear\n");
1029                                 print("defer clear stuffed to ", argv(1), " (", client.netname, ")\n");
1030                                 return;
1031                         }
1032
1033                 default:
1034                         print("Incorrect parameters for \"defer_clear\"\n");
1035                 case GC_REQUEST_USAGE:
1036                         print("\nUsage:^3 sv_cmd defer_clear clientnumber\n");
1037                         print("  where 'clientnumber' is player entity number.\n");
1038                         print("  See also: ^2defer_clear_all^7\n");
1039                         return;
1040         }
1041 }
1042
1043 void GameCommand_defer_clear_all(float request)
1044 {
1045         entity client;
1046         float i;
1047
1048         switch(request)
1049         {
1050                 case GC_REQUEST_HELP:
1051                         print("  ^2defer_clear_all^7: Clear all queued defer commands for all clients\n");
1052                         return;
1053
1054                 case GC_REQUEST_COMMAND:
1055                         FOR_EACH_CLIENT(client)
1056                         {
1057                                 GameCommand_defer_clear(GC_REQUEST_COMMAND, strcat("defer_clear ", ftos(num_for_edict(client))));
1058                                 ++i;
1059                         }
1060                         if(i) { bprint(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
1061                         return;
1062
1063                 default:
1064                 case GC_REQUEST_USAGE:
1065                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
1066                         print("  No arguments required.\n");
1067                         print("  See also: ^2defer_clear^7\n");
1068                         return;
1069         }
1070 }
1071
1072 void GameCommand_delrec(float request, string command) // UNTESTED
1073 {
1074         float argc = tokenize_console(command);
1075
1076         switch(request)
1077         {
1078                 case GC_REQUEST_HELP:
1079                         print("  ^2delrec^7: Delete race time record for a map\n");
1080                         return;
1081
1082                 case GC_REQUEST_COMMAND:
1083                         if(argv(1))
1084                         {
1085                                 if(argv(2))
1086                                         race_deleteTime(argv(2), stof(argv(1)));
1087                                 else
1088                                         race_deleteTime(GetMapname(), stof(argv(1)));
1089                                 return;
1090                         }
1091
1092                 default:
1093                         print("Incorrect parameters for \"delrec\"\n");
1094                 case GC_REQUEST_USAGE:
1095                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
1096                         print("  'ranking' is which ranking level to clear up to, \n");
1097                         print("  it will clear all records up to nth place.\n");
1098                         print("  if 'map' is not provided it will use current map.\n");
1099                         return;
1100         }
1101 }
1102
1103 void GameCommand_effectindexdump(float request)
1104 {
1105         float fh, d;
1106         string s;
1107
1108         switch(request)
1109         {
1110                 case GC_REQUEST_HELP:
1111                         print("  ^2effectindexdump^7: Dump list of effects from code and effectinfo.txt\n");
1112                         return;
1113
1114                 case GC_REQUEST_COMMAND:
1115                         d = db_create();
1116                         print("begin of effects list\n");
1117                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
1118                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
1119                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
1120                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
1121                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
1122                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
1123                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
1124                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
1125                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
1126                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
1127                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
1128                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
1129                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
1130                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
1131                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
1132                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
1133                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
1134                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
1135                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
1136                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
1137                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
1138                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
1139                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
1140                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
1141                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
1142                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
1143                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
1144                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
1145                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
1146                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
1147                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
1148                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
1149                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
1150                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
1151                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
1152                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
1153
1154                         fh = fopen("effectinfo.txt", FILE_READ);
1155                         while((s = fgets(fh)))
1156                         {
1157                                 tokenize(s); // tokenize_console would hit the loop counter :(
1158                                 if(argv(0) == "effect")
1159                                 {
1160                                         if(db_get(d, argv(1)) != "1")
1161                                         {
1162                                                 if(particleeffectnum(argv(1)) >= 0)
1163                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
1164                                                 db_put(d, argv(1), "1");
1165                                         }
1166                                 }
1167                         }
1168                         print("end of effects list\n");
1169
1170                         db_close(d);
1171                         return;
1172
1173                 default:
1174                 case GC_REQUEST_USAGE:
1175                         print("\nUsage:^3 sv_cmd effectindexdump\n");
1176                         print("  No arguments required.\n");
1177                         return;
1178         }
1179 }
1180
1181 void GameCommand_extendmatchtime(float request) // todo: Perhaps allows the user to send a specific time to extend it.
1182 {
1183         switch(request)
1184         {
1185                 case GC_REQUEST_HELP:
1186                         print("  ^2extendmatchtime^7: Increase the timelimit value incrementally\n");
1187                         return;
1188
1189                 case GC_REQUEST_COMMAND:
1190                         changematchtime(autocvar_timelimit_increment* 60, autocvar_timelimit_min*60, autocvar_timelimit_max*60);
1191                         return;
1192
1193                 default:
1194                 case GC_REQUEST_USAGE:
1195                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
1196                         print("  No arguments required.\n");
1197                         print("  See also: ^2reducematchtime^7\n");
1198                         return;
1199         }
1200 }
1201
1202 void GameCommand_find(float request, string command)
1203 {
1204         entity client;
1205         float argc = tokenize_console(command);
1206
1207         switch(request)
1208         {
1209                 case GC_REQUEST_HELP:
1210                         print("  ^2find^7: Search through entities for matching classname\n");
1211                         return;
1212
1213                 case GC_REQUEST_COMMAND:
1214                         for(client = world; (client = find(client, classname, argv(1))); )
1215                                 print(etos(client), "\n");
1216                         return;
1217
1218                 default:
1219                         print("Incorrect parameters for \"find\"\n");
1220                 case GC_REQUEST_USAGE:
1221                         print("\nUsage:^3 sv_cmd find classname\n");
1222                         print("  Where 'classname' is the classname to search for.\n");
1223                         return;
1224         }
1225 }
1226
1227 void GameCommand_gametype(float request, string command)
1228 {
1229         float argc = tokenize_console(command);
1230         string s = argv(1);
1231         float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
1232
1233         switch(request)
1234         {
1235                 case GC_REQUEST_HELP:
1236                         print("  ^2gametype^7: Simple command to change the active gametype\n");
1237                         return;
1238
1239                 case GC_REQUEST_COMMAND:
1240                         if(t)
1241                         {
1242                                 MapInfo_SwitchGameType(t);
1243                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
1244                                 if(MapInfo_count > 0)
1245                                         bprint("Game type successfully switched to ", s, "\n");
1246                                 else
1247                                 {
1248                                         bprint("Cannot use this game type: no map for it found\n");
1249                                         MapInfo_SwitchGameType(tsave);
1250                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
1251                                 }
1252                         }
1253                         else
1254                                 bprint("Game type switch to ", s, " failed: this type does not exist!\n");
1255                         return;
1256
1257                 default:
1258                         print("Incorrect parameters for \"gametype\"\n");
1259                 case GC_REQUEST_USAGE:
1260                         print("\nUsage:^3 sv_cmd gametype mode\n");
1261                         print("  Where 'mode' is the gametype mode to switch to.\n");
1262                         print("  See also: ^2gotomap^7\n");
1263                         return;
1264         }
1265 }
1266
1267 void GameCommand_gettaginfo(float request, string command) // UNTESTED // todo: finish usage description for it (but, must first learn this shit)
1268 {
1269         entity tmp_entity;
1270         float argc = tokenize_console(command), i;
1271         vector v;
1272         switch(request)
1273         {
1274                 case GC_REQUEST_HELP:
1275                         print("  ^2gettaginfo^7: Get specific information about a weapon model\n");
1276                         return;
1277
1278                 case GC_REQUEST_COMMAND:
1279                         if(argc >= 4)
1280                         {
1281                                 tmp_entity = spawn();
1282                                 if(argv(1) == "w")
1283                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
1284                                 else
1285                                 {
1286                                         precache_model(argv(1));
1287                                         setmodel(tmp_entity, argv(1));
1288                                 }
1289                                 tmp_entity.frame = stof(argv(2));
1290                                 if(substring(argv(3), 0, 1) == "#")
1291                                         i = stof(substring(argv(3), 1, -1));
1292                                 else
1293                                         i = gettagindex(tmp_entity, argv(3));
1294                                 if(i)
1295                                 {
1296                                         v = gettaginfo(tmp_entity, i);
1297                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
1298                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
1299                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
1300                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
1301                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
1302                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
1303                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
1304                                         if(argc >= 6)
1305                                         {
1306                                                 v_y = -v_y;
1307                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
1308                                         }
1309                                 }
1310                                 else
1311                                         print("bone not found\n");
1312
1313                                 remove(tmp_entity);
1314                                 return;
1315                         }
1316
1317                 default:
1318                         print("Incorrect parameters for \"gettaginfo\"\n");
1319                 case GC_REQUEST_USAGE:
1320                         print("\nUsage:^3 sv_cmd gettaginfo\n");
1321                         print("  FIXME: Arguments currently unknown\n");
1322                         print("  See also: ^2bbox^7\n");
1323                         return;
1324         }
1325 }
1326
1327 void GameCommand_gotomap(float request, string command)
1328 {
1329         float argc = tokenize_console(command);
1330
1331         switch(request)
1332         {
1333                 case GC_REQUEST_HELP:
1334                         print("  ^2gotomap^7: Simple command to switch to another map\n");
1335                         return;
1336
1337                 case GC_REQUEST_COMMAND:
1338                         if(argc == 2)
1339                         {
1340                                 print(GotoMap(argv(1)), "\n");
1341                                 return;
1342                         }
1343
1344                 default:
1345                         print("Incorrect parameters for \"gotomap\"\n");
1346                 case GC_REQUEST_USAGE:
1347                         print("\nUsage:^3 sv_cmd gotomap map\n");
1348                         print("  Where 'map' is the *.bsp file to change to.\n");
1349                         print("  See also: ^2gametype^7\n");
1350                         return;
1351         }
1352 }
1353
1354 void GameCommand_ladder(float request)
1355 {
1356         switch(request)
1357         {
1358                 case GC_REQUEST_HELP:
1359                         print("  ^2ladder^7: Get information about top players if supported\n");
1360                         return;
1361
1362                 case GC_REQUEST_COMMAND:
1363                         print(ladder_reply);
1364                         return;
1365
1366                 default:
1367                 case GC_REQUEST_USAGE:
1368                         print("\nUsage:^3 sv_cmd ladder\n");
1369                         print("  No arguments required.\n");
1370                         return;
1371         }
1372 }
1373
1374 void GameCommand_lockteams(float request)
1375 {
1376         switch(request)
1377         {
1378                 case GC_REQUEST_HELP:
1379                         print("  ^2lockteams^7: Disable the ability for players to switch or enter teams\n");
1380                         return;
1381
1382                 case GC_REQUEST_COMMAND:
1383                         if(teamplay)
1384                         {
1385                                 lockteams = 1;
1386                                 bprint("^1The teams are now locked.\n");
1387                         }
1388                         else
1389                                 bprint("That command can only be used in a team-based gamemode.\n");
1390                         return;
1391
1392                 default:
1393                 case GC_REQUEST_USAGE:
1394                         print("\nUsage:^3 sv_cmd lockteams\n");
1395                         print("  No arguments required.\n");
1396                         print("  See also: ^2unlockteams^7\n");
1397                         return;
1398         }
1399 }
1400
1401 void GameCommand_make_mapinfo(float request) // UNTESTED
1402 {
1403         entity tmp_entity;
1404
1405         switch(request)
1406         {
1407                 case GC_REQUEST_HELP:
1408                         print("  ^2make_mapinfo^7: Automatically rebuild mapinfo files\n");
1409                         return;
1410
1411                 case GC_REQUEST_COMMAND:
1412                         tmp_entity = spawn();
1413                         tmp_entity.classname = "make_mapinfo";
1414                         tmp_entity.think = make_mapinfo_Think;
1415                         tmp_entity.nextthink = time; // this sucks... todo: re-write this -- Use initializeentity later
1416                         MapInfo_Enumerate();
1417                         return;
1418
1419                 default:
1420                 case GC_REQUEST_USAGE:
1421                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1422                         print("  No arguments required.\n");
1423                         return;
1424         }
1425 }
1426
1427 void GameCommand_modelbug(float request) // UNTESTED // is this even needed anymore?
1428 {
1429         switch(request)
1430         {
1431                 case GC_REQUEST_HELP:
1432                         print("  ^2modelbug^7: foobar\n");
1433                         return;
1434
1435                 case GC_REQUEST_COMMAND:
1436                         modelbug();
1437                         return;
1438
1439                 default:
1440                 case GC_REQUEST_USAGE:
1441                         print("\nUsage:^3 sv_cmd modelbug\n");
1442                         print("  No arguments required.\n");
1443                         return;
1444         }
1445 }
1446
1447 void GameCommand_moveplayer(float request, string command)
1448 {
1449         entity client;
1450         float argc, i;
1451         argc = tokenize_console(command); // we can only have one argc, so we store the information from it to other strings
1452         string targets = argv(1);
1453         string destination = argv(2);
1454         string notify = argv(3);
1455         argc = tokenizebyseparator(targets, ","); // and re-use it later for the target selection.
1456
1457         switch(request)
1458         {
1459                 case GC_REQUEST_HELP:
1460                         print("  ^2moveplayer^7: Change the team/status of a player\n");
1461                         return;
1462
1463                 case GC_REQUEST_COMMAND:
1464                         // lets see if the target(s) even actually exist.
1465                         if((targets) && (destination))
1466                         {
1467                                 for(i = 0; i < argc; ++i)
1468                                 {
1469                                         // Check to see if the player is a valid target
1470                                         if((stof(argv(i)) < 1) | (stof(argv(i)) > maxclients)) // player_id is out of range
1471                                         {
1472                                                 print(strcat("Player ", argv(i), " doesn't exist", (((i + 1) < argc) ? ", skipping to next player.\n" : ".\n")));
1473                                                 continue;
1474                                         }
1475                                         client = edict_num(stof(argv(i)));
1476                                         if not(client.flags & FL_CLIENT) // player entity is not a client
1477                                         {
1478                                                 print(strcat("Player ", argv(i), " doesn't exist", (((i + 1) < argc) ? ", skipping to next player.\n" : ".\n")));
1479                                                 continue;
1480                                         }
1481
1482                                         // Where are we putting this player?
1483                                         if(destination == "spec" || destination == "spectator")
1484                                         {
1485                                                 if(client.classname != "spectator" && client.classname != "observer")
1486                                                 {
1487                                                         self = client;
1488                                                         PutObserverInServer();
1489                                                 }
1490                                                 else
1491                                                 {
1492                                                         print("Player ", argv(i), " (", client.netname, ") is already spectating.\n");
1493                                                 }
1494                                                 return;
1495                                         }
1496                                         else
1497                                         {
1498                                                 if(client.classname != "spectator" && client.classname != "observer")
1499                                                 {
1500                                                         if(teamplay)
1501                                                         {
1502                                                                 // set up
1503                                                                 float team_color;
1504                                                                 float save = client.team_forced;
1505                                                                 client.team_forced = 0;
1506
1507                                                                 // find the team to move the player to
1508                                                                 team_color = ColourToNumber(destination);
1509                                                                 if(team_color == client.team) // already on the destination team
1510                                                                 {
1511                                                                         // keep the forcing undone
1512                                                                         print("Player ", argv(i), " (", client.netname, ") is already on the ", ColoredTeamName(client.team), ".\n");
1513                                                                         return;
1514                                                                 }
1515                                                                 else if(team_color == 0)  // auto team
1516                                                                 {
1517                                                                         team_color = NumberToTeamNumber(FindSmallestTeam(client, FALSE));
1518                                                                 }
1519                                                                 else
1520                                                                 {
1521                                                                         CheckAllowedTeams(client);
1522                                                                 }
1523                                                                 client.team_forced = save;
1524
1525                                                                 // Check to see if the destination team is even available
1526                                                                 switch(team_color)
1527                                                                 {
1528                                                                         case COLOR_TEAM1:
1529                                                                                 if(c1 == -1) {
1530                                                                                         print("Sorry, can't move player to red team if it doesn't exist.\n");
1531                                                                                         return;
1532                                                                                 }
1533                                                                                 break;
1534
1535                                                                         case COLOR_TEAM2:
1536                                                                                 if(c2 == -1) {
1537                                                                                         print("Sorry, can't move player to blue team if it doesn't exist.\n");
1538                                                                                         return;
1539                                                                                 }
1540                                                                                 break;
1541
1542                                                                         case COLOR_TEAM3:
1543                                                                                 if(c3 == -1) {
1544                                                                                         print("Sorry, can't move player to yellow team if it doesn't exist.\n");
1545                                                                                         return;
1546                                                                                 }
1547                                                                                 break;
1548
1549                                                                         case COLOR_TEAM4:
1550                                                                                 if(c4 == -1) {
1551                                                                                         print("Sorry, can't move player to pink team if it doesn't exist.\n");
1552                                                                                         return;
1553                                                                                 }
1554                                                                                 break;
1555
1556                                                                         default:
1557                                                                                 print("Sorry, can't move player here if team ", destination, " doesn't exist.\n");
1558                                                                                 return;
1559                                                                 }
1560
1561                                                                 // If so, lets continue and finally move the player
1562                                                                 client.team_forced = 0;
1563                                                                 MoveToTeam(client, team_color, 6, stof(notify));
1564                                                                 print("Player ", argv(i), " (", client.netname, ") has been moved to the ", ColoredTeamName(team_color), ".\n");
1565                                                                 return;
1566                                                         }
1567                                                         else
1568                                                         {
1569                                                                 print("Can't change teams when currently not playing a team game.\n");
1570                                                                 return;
1571                                                         }
1572                                                 }
1573                                                 else
1574                                                 {
1575                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1576                                                         return;
1577                                                 }
1578                                         }
1579                                 }
1580                                 print("No acceptable players given, aborting.\n");
1581                                 return; // still correct parameters so return to avoid usage print
1582                         }
1583
1584                 default:
1585                         print("Incorrect parameters for \"moveplayer\"\n");
1586                 case GC_REQUEST_USAGE:
1587                         print("\nUsage:^3 sv_cmd moveplayer clientnumbers destination [notify]\n");
1588                         print("  'clientnumbers' is a list (separated by commas) of player entity ID's\n");
1589                         print("  'destination' is what to send the player to, be it team or spectating\n");
1590                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1591                         print("  'notify' is whether or not to send messages notifying of the move. Detail below.\n");
1592                         print("    0 (00) automove centerprint, admin message; 1 (01) automove centerprint, no admin message\n");
1593                         print("    2 (10) no centerprint, admin message; 3 (11) no centerprint, no admin message\n");
1594                         print("Examples: moveplayer 1,3,5 red 3\n");
1595                         print("          moveplayer 2 spec \n");
1596                         print("  See also: ^2allspec^7\n");
1597                         return;
1598         }
1599 }
1600
1601 void GameCommand_nospectators(float request)
1602 {
1603         switch(request)
1604         {
1605                 case GC_REQUEST_HELP:
1606                         print("  ^2nospectators^7: Automatically remove spectators from a match\n");
1607                         return;
1608
1609                 case GC_REQUEST_COMMAND:
1610                         blockSpectators = 1;
1611                         entity plr;
1612                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1613                         {
1614                                 if(plr.classname == "spectator" || plr.classname == "observer")
1615                                 {
1616                                         plr.spectatortime = time;
1617                                         sprint(plr, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1618                                 }
1619                         }
1620                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1621                         return;
1622
1623                 default:
1624                 case GC_REQUEST_USAGE:
1625                         print("\nUsage:^3 sv_cmd nospectators\n");
1626                         print("  No arguments required.\n");
1627                         return;
1628         }
1629 }
1630
1631 void GameCommand_onslaught_updatelinks(float request) // UNTESTED // should this be here? Perhaps some mutatorhook call instead....
1632 {
1633         switch(request)
1634         {
1635                 case GC_REQUEST_HELP:
1636                         print("  ^2onslaught_updatelinks^7: Refresh link status for onslaught\n");
1637                         return;
1638
1639                 case GC_REQUEST_COMMAND:
1640                         onslaught_updatelinks();
1641                         print("ONS links updated\n");
1642                         return;
1643
1644                 default:
1645                 case GC_REQUEST_USAGE:
1646                         print("\nUsage:^3 sv_cmd onslaught_updatelinks\n");
1647                         print("  No arguments required.\n");
1648                         return;
1649         }
1650 }
1651
1652 void GameCommand_playerdemo(float request, string command) // UNTESTED
1653 {
1654         entity client;
1655         float argc = tokenize_console(command), i, n, entno;
1656         string s;
1657
1658         switch(request)
1659         {
1660                 case GC_REQUEST_HELP:
1661                         print("  ^2playerdemo^7: Control the ability to save demos of players\n");
1662                         return;
1663
1664                 case GC_REQUEST_COMMAND:
1665                         if(argv(1) == "read")
1666                         {
1667                                 // TODO: Create a general command for looking this up, save a lot of space everywhere in this file
1668                                 entno = stof(argv(2));
1669                                 if((entno < 1) | (entno > maxclients)) {
1670                                         print("Player ", argv(2), " doesn't exist\n");
1671                                         return;
1672                                 }
1673                                 client = edict_num(entno);
1674                                 if(clienttype(client) != CLIENTTYPE_BOT) {
1675                                         print("Player ", client.netname, " is not a bot\n");
1676                                         return;
1677                                 }
1678                                 self = client;
1679                                 playerdemo_open_read(argv(3));
1680                                 return;
1681                         }
1682                         else if(argv(1) == "write")
1683                         {
1684                                 entno = stof(argv(2));
1685                                 if((entno < 1) | (entno > maxclients)) {
1686                                         print("Player ", argv(2), " doesn't exist\n");
1687                                         return;
1688                                 }
1689                                 client = edict_num(entno);
1690                                 self = client;
1691                                 playerdemo_open_write(argv(3));
1692                                 return;
1693                         }
1694                         else if(argv(1) == "auto_read_and_write")
1695                         {
1696                                 s = argv(2);
1697                                 n = stof(argv(3));
1698                                 cvar_set("bot_number", ftos(n));
1699                                 localcmd("wait; wait; wait\n");
1700                                 for(i = 0; i < n; ++i)
1701                                         localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", s, ftos(i+1), "\n");
1702                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1703                                 return;
1704                         }
1705                         else if(argv(1) == "auto_read")
1706                         {
1707                                 s = argv(2);
1708                                 n = stof(argv(3));
1709                                 cvar_set("bot_number", ftos(n));
1710                                 localcmd("wait; wait; wait\n");
1711                                 for(i = 0; i < n; ++i)
1712                                         localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", s, ftos(i+1), "\n");
1713                                 return;
1714                         }
1715                         return;
1716
1717                 default:
1718                 case GC_REQUEST_USAGE:
1719                         print("\nUsage:^3 sv_cmd \n");
1720                         print("  No arguments required.\n");
1721                         print("  FIXME: Arguments currently unknown\n");
1722                         return;
1723         }
1724 }
1725
1726 void GameCommand(string command)
1727 {
1728         // ===== TODO list =====
1729
1730         // Finish adding the rest of the commands
1731
1732         // Add ifdef to stuffto so that is can only be used when the game code is compiled for it
1733         //(this way it's more obscure and harder to abuse on normal servers)
1734
1735         float search_request_type;
1736         float argc = tokenize_console(command);
1737
1738         if(argv(0) == "help")
1739         {
1740                 if(argc == 1)
1741                 {
1742                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are:\n");
1743                         GameCommand_adminmsg(GC_REQUEST_HELP, "");
1744                         GameCommand_allready(GC_REQUEST_HELP);
1745                         GameCommand_allspec(GC_REQUEST_HELP);
1746                         GameCommand_anticheat(GC_REQUEST_HELP, "");
1747                         GameCommand_bbox(GC_REQUEST_HELP);
1748                         GameCommand_bot_cmd(GC_REQUEST_HELP, "");
1749                         GameCommand_cointoss(GC_REQUEST_HELP);
1750                         GameCommand_cvar_changes(GC_REQUEST_HELP);
1751                         GameCommand_cvar_purechanges(GC_REQUEST_HELP);
1752                         GameCommand_database(GC_REQUEST_HELP, "");
1753                         GameCommand_defer_clear(GC_REQUEST_HELP, "");
1754                         GameCommand_defer_clear_all(GC_REQUEST_HELP);
1755                         GameCommand_delrec(GC_REQUEST_HELP, "");
1756                         GameCommand_effectindexdump(GC_REQUEST_HELP);
1757                         GameCommand_extendmatchtime(GC_REQUEST_HELP);
1758                         GameCommand_find(GC_REQUEST_HELP, "");
1759                         GameCommand_gametype(GC_REQUEST_HELP, "");
1760                         GameCommand_gettaginfo(GC_REQUEST_HELP, "");
1761                         GameCommand_gotomap(GC_REQUEST_HELP, "");
1762                         GameCommand_ladder(GC_REQUEST_HELP);
1763                         GameCommand_lockteams(GC_REQUEST_HELP);
1764                         GameCommand_make_mapinfo(GC_REQUEST_HELP);
1765                         GameCommand_modelbug(GC_REQUEST_HELP);
1766                         GameCommand_moveplayer(GC_REQUEST_HELP, "");
1767                         GameCommand_nospectators(GC_REQUEST_HELP);
1768                         GameCommand_onslaught_updatelinks(GC_REQUEST_HELP);
1769                         GameCommand_playerdemo(GC_REQUEST_HELP, "");
1770                         GameCommand_Vote("help", world);
1771                         GameCommand_Ban("help");
1772                         GameCommand_Generic("help");
1773                         print("For help about specific commands, type sv_cmd help COMMAND\n");
1774                         return;
1775                 }
1776                 else
1777                         search_request_type = GC_REQUEST_USAGE; // Instead of trying to call a command, we're going to see detailed information about it
1778         }
1779         else if(GameCommand_Vote(command, world))
1780         {
1781                 return; // handled by server/vote.qc
1782         }
1783         else if(GameCommand_Ban(command))
1784         {
1785                 return; // handled by server/ipban.qc
1786         }
1787         else if(GameCommand_Generic(command))
1788         {
1789                 return; // handled by common/gamecommand.qc
1790         }
1791         else
1792                 search_request_type = GC_REQUEST_COMMAND; // continue as usual and scan for normal commands
1793
1794         switch( ((argv(0) == "help") ? argv(1) : argv(0)) ) // if first argument is help, then search for the second argument. Else, search for first.
1795         {
1796                 case "adminmsg": GameCommand_adminmsg(search_request_type, command); break;
1797                 case "allready": GameCommand_allready(search_request_type); break;
1798                 case "allspec": GameCommand_allspec(search_request_type); break;
1799                 case "anticheat": GameCommand_anticheat(search_request_type, command); break;
1800                 case "bbox": GameCommand_bbox(search_request_type); break;
1801                 case "bot_cmd": GameCommand_bot_cmd(search_request_type, command); break;
1802                 case "cointoss": GameCommand_cointoss(search_request_type); break;
1803                 case "cvar_changes": GameCommand_cvar_changes(search_request_type); break;
1804                 case "cvar_purechanges": GameCommand_cvar_purechanges(search_request_type); break;
1805                 case "database": GameCommand_database(search_request_type, command); break;
1806                 case "defer_clear": GameCommand_defer_clear(search_request_type, command); break;
1807                 case "defer_clear_all": GameCommand_defer_clear_all(search_request_type); break;
1808                 case "delrec": GameCommand_delrec(search_request_type, command); break;
1809                 case "effectindexdump": GameCommand_effectindexdump(search_request_type); break;
1810                 case "extendmatchtime": GameCommand_extendmatchtime(search_request_type); break;
1811                 case "find": GameCommand_find(search_request_type, command); break;
1812                 case "gametype": GameCommand_gametype(search_request_type, command); break;
1813                 case "gettaginfo": GameCommand_gettaginfo(search_request_type, command); break;
1814                 case "gotomap": GameCommand_gotomap(search_request_type, command); break;
1815                 case "ladder": GameCommand_ladder(search_request_type); break;
1816                 case "lockteams": GameCommand_lockteams(search_request_type); break;
1817                 case "make_mapinfo": GameCommand_make_mapinfo(search_request_type); break;
1818                 case "modelbug": GameCommand_modelbug(search_request_type); break;
1819                 case "moveplayer": GameCommand_moveplayer(search_request_type, command); break;
1820                 case "nospectators": GameCommand_nospectators(search_request_type); break;
1821                 case "onslaught_updatelinks": GameCommand_onslaught_updatelinks(search_request_type); break;
1822                 case "playerdemo": GameCommand_playerdemo(search_request_type, command); break;
1823
1824                 default:
1825                         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
1826         }
1827 }
1828