qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2 void race_deleteTime(string map, float pos);
   3
   4 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   5 {
   6         vector c;
   7         float white, black;
   8
   9         white = 0.001;
  10         black = 0.001;
  11
  12         c = a;
  13
  14         float n, m;
  15         n = m = 0;
  16
  17         while(vlen(c - b) > 1)
  18         {
  19                 ++m;
  20
  21                 tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
  22                 ++n;
  23
  24                 if(!trace_startsolid)
  25                 {
  26                         black += vlen(trace_endpos - c);
  27                         c = trace_endpos;
  28                 }
  29
  30                 n += tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);
  31
  32                 white += vlen(trace_endpos - c);
  33                 c = trace_endpos;
  34         }
  35
  36         if(n > 200)
  37                 dprint("HOLY SHIT! FullTraceFraction: ", ftos(n), " total traces, ", ftos(m), " iterations\n");
  38
  39         return white / (black + white);
  40 }
  41
  42 float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize, float q)
  43 {
  44         vector a, b, mi, ma;
  45
  46         mi = '0 0 0';
  47         ma = '1 0 0' * w + '0 1 0' * h;
  48         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  49         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize + zmin);
  50
  51         return FullTraceFraction(a, mi, ma, b);
  52 }
  53 float RadarMapAtPoint_LineBlock(float x, float y, float w, float h, float zmin, float zsize, float q)
  54 {
  55         vector o, mi, ma;
  56         float i, r;
  57         vector dz;
  58
  59         q = 256 * q - 1;
  60         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
  61
  62         mi = '0 0 0';
  63         dz = (zsize / q) * '0 0 1';
  64         ma = '1 0 0' * w + '0 1 0' * h + dz;
  65         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  66
  67         if(x < world.absmin_x - w)
  68                 return 0;
  69         if(y < world.absmin_y - h)
  70                 return 0;
  71         if(x > world.absmax_x)
  72                 return 0;
  73         if(y > world.absmax_y)
  74                 return 0;
  75
  76         r = 0;
  77         for(i = 0; i < q; ++i)
  78         {
  79                 vector v1, v2;
  80                 v1 = v2 = o + dz * i + mi;
  81                 v1_x += random() * (ma_x - mi_x);
  82                 v1_y += random() * (ma_y - mi_y);
  83                 v1_z += random() * (ma_z - mi_z);
  84                 v2_x += random() * (ma_x - mi_x);
  85                 v2_y += random() * (ma_y - mi_y);
  86                 v2_z += random() * (ma_z - mi_z);
  87                 traceline(v1, v2, MOVE_WORLDONLY, world);
  88                 if(trace_startsolid || trace_fraction < 1)
  89                         ++r;
  90         }
  91         return r / q;
  92 }
  93 float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
  94 {
  95         vector o, mi, ma;
  96         float i, r;
  97         vector dz;
  98
  99         q = 256 * q - 1;
 100         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
 101
 102         mi = '0 0 0';
 103         dz = (zsize / q) * '0 0 1';
 104         ma = '1 0 0' * w + '0 1 0' * h + dz;
 105         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
 106
 107         if(x < world.absmin_x - w)
 108                 return 0;
 109         if(y < world.absmin_y - h)
 110                 return 0;
 111         if(x > world.absmax_x)
 112                 return 0;
 113         if(y > world.absmax_y)
 114                 return 0;
 115
 116         r = 0;
 117         for(i = 0; i < q; ++i)
 118         {
 119                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
 120                 if(trace_startsolid)
 121                         ++r;
 122         }
 123         return r / q;
 124 }
 125 float RadarMapAtPoint_Sample(float x, float y, float w, float h, float zmin, float zsize, float q)
 126 {
 127         vector a, b, mi, ma;
 128
 129         q *= 4; // choose q so it matches the regular algorithm in speed
 130
 131         q = 256 * q - 1;
 132         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
 133
 134         mi = '0 0 0';
 135         ma = '1 0 0' * w + '0 1 0' * h;
 136         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
 137         b = '1 0 0' * w + '0 1 0' * h + '0 0 1' * zsize;
 138
 139         float c, i;
 140         c = 0;
 141
 142         for(i = 0; i < q; ++i)
 143         {
 144                 vector v;
 145                 v_x = a_x + random() * b_x;
 146                 v_y = a_y + random() * b_y;
 147                 v_z = a_z + random() * b_z;
 148                 traceline(v, v, MOVE_WORLDONLY, world);
 149                 if(trace_startsolid)
 150                         ++c;
 151         }
 152
 153         return c / q;
 154 }
 155
 156 // FF is contained twice, to map 256 to FF too
 157 // removes the need to bound()
 158 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFFFF";
 159
 160 float RADAR_WIDTH_MAX = 512;
 161 float RADAR_HEIGHT_MAX = 512;
 162 float sharpen_buffer[RADAR_WIDTH_MAX * 3];
 163
 164 void sharpen_set(float x, float v)
 165 {
 166         sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
 167 }
 168
 169 float sharpen_getpixel(float x, float y)
 170 {
 171         if(x < 0)
 172                 return 0;
 173         if(x >= RADAR_WIDTH_MAX)
 174                 return 0;
 175         if(y < 0)
 176                 return 0;
 177         if(y > 2)
 178                 return 0;
 179         return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
 180 }
 181
 182 float sharpen_get(float x, float a)
 183 {
 184         float sum;
 185         sum = sharpen_getpixel(x, 1);
 186         if(a == 0)
 187                 return sum;
 188         sum *= (8 + 1/a);
 189         sum -= sharpen_getpixel(x - 1, 0);
 190         sum -= sharpen_getpixel(x - 1, 1);
 191         sum -= sharpen_getpixel(x - 1, 2);
 192         sum -= sharpen_getpixel(x + 1, 0);
 193         sum -= sharpen_getpixel(x + 1, 1);
 194         sum -= sharpen_getpixel(x + 1, 2);
 195         sum -= sharpen_getpixel(x, 0);
 196         sum -= sharpen_getpixel(x, 2);
 197         return bound(0, sum * a, 1);
 198 }
 199
 200 void sharpen_shift(float w)
 201 {
 202         float i;
 203         for(i = 0; i < w; ++i)
 204         {
 205                 sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
 206                 sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
 207                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 208         }
 209 }
 210
 211 void sharpen_init(float w)
 212 {
 213         float i;
 214         for(i = 0; i < w; ++i)
 215         {
 216                 sharpen_buffer[i] = 0;
 217                 sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
 218                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 219         }
 220 }
 221
 222 entity radarmapper;
 223 void RadarMap_Next()
 224 {
 225         if(radarmapper.count & 4)
 226         {
 227                 localcmd("quit\n");
 228         }
 229         else if(radarmapper.count & 2)
 230         {
 231                 localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(radarmapper.count), strcat(" --res ", ftos(radarmapper.size_x), " ", ftos(radarmapper.size_y), " --sharpen ", ftos(radarmapper.ltime), " --qual ", ftos(radarmapper.size_z)), "\"\n"));
 232                 GotoNextMap();
 233         }
 234         remove(radarmapper);
 235         radarmapper = world;
 236 }
 237
 238 // rough map entity
 239 //   cnt: current line
 240 //   size: pixel width/height
 241 //   maxs: cell width/height
 242 //   frame: counter
 243 void RadarMap_Think()
 244 {
 245         float i, x, l;
 246         string si;
 247
 248         if(self.frame == 0)
 249         {
 250                 // initialize
 251                 get_mi_min_max_texcoords(1);
 252                 self.mins = mi_picmin;
 253                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
 254                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
 255                 self.maxs_z = mi_max_z - mi_min_z;
 256                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
 257                 self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
 258                 if(!(self.count & 1))
 259                 {
 260                         self.cnt = fopen(self.netname, FILE_READ);
 261                         if(self.cnt < 0)
 262                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.tga"), FILE_READ);
 263                         if(self.cnt < 0)
 264                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.png"), FILE_READ);
 265                         if(self.cnt < 0)
 266                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.jpg"), FILE_READ);
 267                         if(self.cnt < 0)
 268                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.tga"), FILE_READ);
 269                         if(self.cnt < 0)
 270                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.png"), FILE_READ);
 271                         if(self.cnt < 0)
 272                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.jpg"), FILE_READ);
 273                         if(self.cnt >= 0)
 274                         {
 275                                 fclose(self.cnt);
 276
 277                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 278                                 RadarMap_Next();
 279                                 return;
 280                         }
 281                 }
 282                 self.cnt = fopen(self.netname, FILE_WRITE);
 283                 if(self.cnt < 0)
 284                 {
 285                         print("Error writing ", self.netname, "\n");
 286                         remove(self);
 287                         radarmapper = world;
 288                         return;
 289                 }
 290                 print("Writing to ", self.netname, "...\n");
 291                 fputs(self.cnt, "/* XPM */\n");
 292                 fputs(self.cnt, "static char *RadarMap[] = {\n");
 293                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 294                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 295                 for(i = 0; i < 256; ++i)
 296                 {
 297                         si = substring(doublehex, i*2, 2);
 298                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 299                 }
 300                 self.frame += 1;
 301                 self.nextthink = time;
 302                 sharpen_init(self.size_x);
 303         }
 304         else if(self.frame <= self.size_y)
 305         {
 306                 // fill the sharpen buffer with this line
 307                 sharpen_shift(self.size_x);
 308                 i = self.count & 24;
 309
 310                 switch(i)
 311                 {
 312                         case 0:
 313                         default:
 314                                 for(x = 0; x < self.size_x; ++x)
 315                                 {
 316                                         l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 317                                         sharpen_set(x, l);
 318                                 }
 319                                 break;
 320                         case 8:
 321                                 for(x = 0; x < self.size_x; ++x)
 322                                 {
 323                                         l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 324                                         sharpen_set(x, l);
 325                                 }
 326                                 break;
 327                         case 16:
 328                                 for(x = 0; x < self.size_x; ++x)
 329                                 {
 330                                         l = RadarMapAtPoint_Sample(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 331                                         sharpen_set(x, l);
 332                                 }
 333                                 break;
 334                         case 24:
 335                                 for(x = 0; x < self.size_x; ++x)
 336                                 {
 337                                         l = RadarMapAtPoint_LineBlock(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 338                                         sharpen_set(x, l);
 339                                 }
 340                                 break;
 341                 }
 342
 343                 // do we have enough lines?
 344                 if(self.frame >= 2)
 345                 {
 346                         // write a pixel line
 347                         fputs(self.cnt, "\"");
 348                         for(x = 0; x < self.size_x; ++x)
 349                         {
 350                                 l = sharpen_get(x, self.ltime);
 351                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 352                         }
 353                         if(self.frame == self.size_y)
 354                                 fputs(self.cnt, "\"\n");
 355                         else
 356                         {
 357                                 fputs(self.cnt, "\",\n");
 358                                 print(ftos(self.size_y - self.frame), " lines left\n");
 359                         }
 360                 }
 361
 362                 // is this the last line? then write back the missing line
 363                 if(self.frame == self.size_y)
 364                 {
 365                         sharpen_shift(self.size_x);
 366                         // write a pixel line
 367                         fputs(self.cnt, "\"");
 368                         for(x = 0; x < self.size_x; ++x)
 369                         {
 370                                 l = sharpen_get(x, self.ltime);
 371                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 372                         }
 373                         if(self.frame == self.size_y)
 374                                 fputs(self.cnt, "\"\n");
 375                         else
 376                         {
 377                                 fputs(self.cnt, "\",\n");
 378                                 print(ftos(self.size_y - self.frame), " lines left\n");
 379                         }
 380                 }
 381
 382                 self.frame += 1;
 383                 self.nextthink = time;
 384         }
 385         else
 386         {
 387                 // close the file
 388                 fputs(self.cnt, "};\n");
 389                 fclose(self.cnt);
 390                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 391                 RadarMap_Next();
 392         }
 393 }
 394
 395 void RadarMap(float argc)
 396 {
 397         if(radarmapper)
 398                 return;
 399         float i;
 400         radarmapper = spawn();
 401         radarmapper.classname = "radarmapper";
 402         radarmapper.think = RadarMap_Think;
 403         radarmapper.nextthink = time;
 404         radarmapper.count = 8; // default to the --trace method, as it is faster now
 405         radarmapper.ltime = 1;
 406         radarmapper.size_x = 512;
 407         radarmapper.size_y = 512;
 408         radarmapper.size_z = 1;
 409
 410         for(i = 1; i < argc; ++i)
 411         {
 412                 if(argv(i) == "--force")
 413                         radarmapper.count |= 1;
 414                 else if(argv(i) == "--loop")
 415                         radarmapper.count |= 2;
 416                 else if(argv(i) == "--quit")
 417                         radarmapper.count |= 4;
 418                 else if(argv(i) == "--block")
 419                 {
 420                         radarmapper.count &~= 24;
 421                 }
 422                 else if(argv(i) == "--trace")
 423                 {
 424                         radarmapper.count &~= 24;
 425                         radarmapper.count |= 8;
 426                 }
 427                 else if(argv(i) == "--sample")
 428                 {
 429                         radarmapper.count &~= 24;
 430                         radarmapper.count |= 16;
 431                 }
 432                 else if(argv(i) == "--lineblock")
 433                 {
 434                         radarmapper.count |= 24;
 435                 }
 436                 else if(argv(i) == "--flags") // for the recursive call
 437                 {
 438                         ++i;
 439                         radarmapper.count = stof(argv(i));
 440                 }
 441                 else if(argv(i) == "--sharpen") // for the recursive call
 442                 {
 443                         ++i;
 444                         radarmapper.ltime = stof(argv(i));
 445                 }
 446                 else if(argv(i) == "--res") // resolution
 447                 {
 448                         ++i;
 449                         radarmapper.size_x = stof(argv(i));
 450                         ++i;
 451                         radarmapper.size_y = stof(argv(i));
 452                 }
 453                 else if(argv(i) == "--qual") // quality multiplier
 454                 {
 455                         ++i;
 456                         radarmapper.size_z = stof(argv(i));
 457                 }
 458                 else
 459                 {
 460                         remove(radarmapper);
 461                         radarmapper = world;
 462                         print("Usage: sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
 463                         print("The quality factor Q is roughly proportional to the time taken.\n");
 464                         print("--trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
 465                         print("--block \n");
 466                         return;
 467                 }
 468         }
 469
 470         print("Radarmap entity spawned.\n");
 471 }
 472
 473 void EffectIndexDump()
 474 {
 475         float d;
 476         float fh;
 477         string s;
 478
 479         d = db_create();
 480
 481         print("begin of effects list\n");
 482         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 483         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 484         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 485         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 486         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 487         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 488         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 489         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 490         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 491         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 492         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 493         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 494         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 495         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 496         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 497         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 498         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 499         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 500         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 501         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 502         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 503         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 504         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 505         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 506         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 507         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 508         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 509         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 510         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 511         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 512         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 513         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 514         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 515         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 516         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 517         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 518
 519         fh = fopen("effectinfo.txt", FILE_READ);
 520         while((s = fgets(fh)))
 521         {
 522                 tokenize(s); // tokenize_console would hit the loop counter :(
 523                 if(argv(0) == "effect")
 524                 {
 525                         if(db_get(d, argv(1)) != "1")
 526                         {
 527                                 if(particleeffectnum(argv(1)) >= 0)
 528                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 529                                 db_put(d, argv(1), "1");
 530                         }
 531                 }
 532         }
 533         print("end of effects list\n");
 534
 535         db_close(d);
 536 }
 537
 538 void make_mapinfo_Think()
 539 {
 540         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 541         {
 542                 print("Done rebuiling mapinfos.\n");
 543                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 544                 remove(self);
 545         }
 546         else
 547         {
 548                 self.think = make_mapinfo_Think;
 549                 self.nextthink = time;
 550         }
 551 }
 552
 553 void changematchtime(float delta, float mi, float ma)
 554 {
 555         float cur;
 556         float new;
 557         float lim;
 558
 559         if(delta == 0)
 560                 return;
 561         if(autocvar_timelimit < 0)
 562                 return;
 563
 564         if(mi <= 10)
 565                 mi = 10; // at least ten sec in the future
 566         cur = time - game_starttime;
 567         if(cur > 0)
 568                 mi += cur; // from current time!
 569
 570         lim = autocvar_timelimit * 60;
 571
 572         if(delta > 0)
 573         {
 574                 if(lim == 0)
 575                         return; // cannot increase any further
 576                 else if(lim < ma)
 577                         new = min(ma, lim + delta);
 578                 else // already above maximum: FAIL
 579                         return;
 580         }
 581         else
 582         {
 583                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
 584                         new = max(mi, ma);
 585                 else if(lim > mi) // above minimum: decrease
 586                         new = max(mi, lim + delta);
 587                 else // already below minimum: FAIL
 588                         return;
 589         }
 590
 591         cvar_set("timelimit", ftos(new / 60));
 592 }
 593
 594 float g_clientmodel_genericsendentity (entity to, float sf);
 595 void modelbug_make_svqc();
 596 void modelbug_make_csqc()
 597 {
 598         Net_LinkEntity(self, TRUE, 0, g_clientmodel_genericsendentity);
 599         self.think = modelbug_make_svqc;
 600         self.nextthink = time + 1;
 601         setorigin(self, self.origin - '0 0 8');
 602 }
 603 void modelbug_make_svqc()
 604 {
 605         self.SendEntity = func_null;
 606         self.think = modelbug_make_csqc;
 607         self.nextthink = time + 1;
 608         setorigin(self, self.origin + '0 0 8');
 609 }
 610
 611 void modelbug()
 612 {
 613         entity e;
 614         e = spawn();
 615         setorigin(e, nextent(world).origin);
 616         precache_model("models_portal.md3");
 617         setmodel(e, "models/portal.md3");
 618         e.think = modelbug_make_svqc;
 619         e.nextthink = time + 1;
 620 }
 621
 622 // ===================
 623 //  Command Functions
 624 // ===================
 625 #define GC_REQUEST_HELP 1
 626 #define GC_REQUEST_COMMAND 2
 627 #define GC_REQUEST_USAGE 3
 628
 629 void GameCommand_adminmsg(float request, string command)
 630 {
 631         entity client;
 632         float argc = tokenize_console(command);
 633         float entno = stof(argv(1));
 634         float n, i;
 635         string s;
 636
 637         switch(request)
 638         {
 639                 case GC_REQUEST_HELP:
 640                         print("  adminmsg - Send an admin message to a client directly\n");
 641                         break;
 642
 643                 case GC_REQUEST_COMMAND:
 644                         if(argc >= 3 && argc <= 4) {
 645                                 if((entno < 0) | (entno > maxclients)) {
 646                                         print("Player ", argv(1), " doesn't exist\n");
 647                                         return;
 648                                 }
 649                                 n = 0;
 650                                 for(i = (entno ? entno : 1); i <= (entno ? entno : maxclients); ++i)
 651                                 {
 652                                         client = edict_num(i);
 653                                         if(client.flags & FL_CLIENT)
 654                                         {
 655                                                 if(argc == 4)
 656                                                 {
 657                                                         s = argv(2);
 658                                                         s = strreplace("\n", "", s);
 659                                                         s = strreplace("\\", "\\\\", s);
 660                                                         s = strreplace("$", "$$", s);
 661                                                         s = strreplace("\"", "\\\"", s);
 662                                                         stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", stof(argv(3)), s));
 663                                                 }
 664                                                 else
 665                                                 {
 666                                                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3", admin_name(), ":\n\n^7", argv(2)));
 667                                                         sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", argv(2), "\n"));
 668                                                 }
 669                                                 dprint("Message sent to ", client.netname, "\n");
 670                                                 ++n;
 671                                         }
 672                                 }
 673                                 if(!n) { print("Client not found\n"); }
 674                                 break;
 675                         }
 676
 677                 default:
 678                 case GC_REQUEST_USAGE:
 679                         print("\nUsage: sv_cmd adminmsg clientnumber \"message\" [infobartime]\n");
 680                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 681                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 682                         print("Examples: adminmsg 4 \"this message will last for ten seconds\" 10\n");
 683                         print("          adminmsg 2 \"this message will be a centerprint\"\n");
 684                         return;
 685         }
 686 }
 687
 688 void GameCommand_allready(float request)
 689 {
 690         switch(request)
 691         {
 692                 case GC_REQUEST_HELP:
 693                         print("  allready - Restart the server and reset the players\n");
 694                         break;
 695
 696                 case GC_REQUEST_COMMAND:
 697                         ReadyRestart();
 698                         break;
 699
 700                 default:
 701                 case GC_REQUEST_USAGE:
 702                         print("\nUsage: sv_cmd allready\n");
 703                         print("  No arguments required.\n");
 704                         return;
 705         }
 706 }
 707
 708 void GameCommand_allspec(float request)
 709 {
 710         entity client;
 711         float i;
 712         switch(request)
 713         {
 714                 case GC_REQUEST_HELP:
 715                         print("  allspec - Force all players to spectate\n");
 716                         break;
 717
 718                 case GC_REQUEST_COMMAND:
 719                         FOR_EACH_PLAYER(client)
 720                         {
 721                                 PutObserverInServer();
 722                                 ++i;
 723                         }
 724                         if(i) { bprint(strcat("Successfully forced all players to spectate (", ftos(i), ")\n")); } // should a message be added if no players were found?
 725                         break;
 726
 727                 default:
 728                 case GC_REQUEST_USAGE:
 729                         print("\nUsage: sv_cmd allspec\n");
 730                         print("  No arguments required.\n");
 731                         return;
 732         }
 733 }
 734
 735 void GameCommand_anticheat(float request, string command)
 736 {
 737         entity client;
 738         float argc = tokenize_console(command);
 739         float entno = stof(argv(1));
 740
 741         switch(request)
 742         {
 743                 case GC_REQUEST_HELP:
 744                         print("  anticheat - Create an anticheat report for a client\n");
 745                         break;
 746
 747                 case GC_REQUEST_COMMAND:
 748                         if((entno < 1) | (entno > maxclients)) {
 749                                 print("Player ", argv(1), " doesn't exist\n");
 750                                 return;
 751                         }
 752                         client = edict_num(entno);
 753                         if(clienttype(client) != CLIENTTYPE_REAL && clienttype(client) != CLIENTTYPE_BOT) {
 754                                 print("Player ", client.netname, " is not active\n");
 755                                 return;
 756                         }
 757                         self = client;
 758                         anticheat_report();
 759                         break;
 760
 761                 default:
 762                 case GC_REQUEST_USAGE:
 763                         print("\nUsage: sv_cmd anticheat clientnumber\n");
 764                         print("  Where clientnumber is the entity number\n");
 765                         return;
 766         }
 767 }
 768
 769 void GameCommand_bbox(float request)
 770 {
 771         switch(request)
 772         {
 773                 case GC_REQUEST_HELP:
 774                         print("  bbox - Print large amounts of information about bboxes\n");
 775                         break;
 776
 777                 case GC_REQUEST_COMMAND:
 778                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 779                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 780                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 781                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 782                         print("Solid bounding box size:");
 783
 784                         tracebox('1 0 0' * world.absmin_x,
 785                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 786                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 787                                                         '1 0 0' * world.absmax_x,
 788                                         MOVE_WORLDONLY,
 789                                         world);
 790                         if(trace_startsolid)
 791                                 print(" ", ftos(world.absmin_x));
 792                         else
 793                                 print(" ", ftos(trace_endpos_x));
 794
 795                         tracebox('0 1 0' * world.absmin_y,
 796                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 797                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 798                                                         '0 1 0' * world.absmax_y,
 799                                         MOVE_WORLDONLY,
 800                                         world);
 801                         if(trace_startsolid)
 802                                 print(" ", ftos(world.absmin_y));
 803                         else
 804                                 print(" ", ftos(trace_endpos_y));
 805
 806                         tracebox('0 0 1' * world.absmin_z,
 807                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 808                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 809                                                         '0 0 1' * world.absmax_z,
 810                                         MOVE_WORLDONLY,
 811                                         world);
 812                         if(trace_startsolid)
 813                                 print(" ", ftos(world.absmin_z));
 814                         else
 815                                 print(" ", ftos(trace_endpos_z));
 816
 817                         tracebox('1 0 0' * world.absmax_x,
 818                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 819                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 820                                                         '1 0 0' * world.absmin_x,
 821                                         MOVE_WORLDONLY,
 822                                         world);
 823                         if(trace_startsolid)
 824                                 print(" ", ftos(world.absmax_x));
 825                         else
 826                                 print(" ", ftos(trace_endpos_x));
 827
 828                         tracebox('0 1 0' * world.absmax_y,
 829                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 830                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 831                                                         '0 1 0' * world.absmin_y,
 832                                         MOVE_WORLDONLY,
 833                                         world);
 834                         if(trace_startsolid)
 835                                 print(" ", ftos(world.absmax_y));
 836                         else
 837                                 print(" ", ftos(trace_endpos_y));
 838
 839                         tracebox('0 0 1' * world.absmax_z,
 840                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 841                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 842                                                         '0 0 1' * world.absmin_z,
 843                                         MOVE_WORLDONLY,
 844                                         world);
 845                         if(trace_startsolid)
 846                                 print(" ", ftos(world.absmax_z));
 847                         else
 848                                 print(" ", ftos(trace_endpos_z));
 849
 850                         print("\n");
 851                         break;
 852
 853                 default:
 854                 case GC_REQUEST_USAGE:
 855                         print("\nUsage: sv_cmd bbox\n");
 856                         print("  No arguments required.\n");
 857                         return;
 858         }
 859 }
 860
 861 void GameCommand_bot_cmd(float request, string command)
 862 {
 863         entity bot;
 864         float argc = tokenize_console(command);
 865
 866         switch(request)
 867         {
 868                 case GC_REQUEST_HELP:
 869                         print("  bot_cmd - Control and send commands to bots");
 870                         break;
 871
 872                 case GC_REQUEST_COMMAND:
 873                         if(argv(1) == "reset")
 874                         {
 875                                 bot_resetqueues();
 876                                 return;
 877                         }
 878                         else if(argv(1) == "load" && argc == 3)
 879                         {
 880                                 float fh, i;
 881                                 string s;
 882                                 fh = fopen(argv(2), FILE_READ);
 883                                 if(fh < 0)
 884                                 {
 885                                         print("cannot open the file\n");
 886                                         return;
 887                                 }
 888
 889                                 i = 0;
 890                                 while((s = fgets(fh)))
 891                                 {
 892                                         argc = tokenize_console(s);
 893
 894                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 895                                         {
 896                                                 // let's start at token 2 so we can skip sv_cmd bot_cmd
 897                                                 bot = find_bot_by_number(stof(argv(2)));
 898                                                 if(bot == world)
 899                                                         bot = find_bot_by_name(argv(2));
 900                                                 if(bot)
 901                                                         bot_queuecommand(bot, strcat(argv(3), " ", argv(4)));
 902                                         }
 903                                         else
 904                                                 localcmd(strcat(s, "\n"));
 905
 906                                         ++i;
 907                                 }
 908                                 print(ftos(i), " commands read\n");
 909                                 fclose(fh);
 910                                 return;
 911                         }
 912                         else if(argv(1) == "help")
 913                         {
 914                                 if(argv(2))
 915                                         bot_cmdhelp(argv(2));
 916                                 else
 917                                         bot_list_commands();
 918                                 return;
 919                         }
 920                         else if(argc >= 3) // this comes last
 921                         {
 922                                 bot = find_bot_by_number(stof(argv(1)));
 923                                 if(bot == world)
 924                                         bot = find_bot_by_name(argv(1));
 925                                 if(bot)
 926                                 {
 927                                         print(strcat("Command '", (argv(2), " ", argv(3)), "' sent to bot ", bot.netname, "\n"));
 928                                         bot_queuecommand(bot, strcat(argv(2), " ", argv(3)));
 929                                         return;
 930                                 }
 931                                 else
 932                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 933                         }
 934
 935                 default:
 936                 case GC_REQUEST_USAGE:
 937                         print("\nUsage: sv_cmd bot_cmd client command [argument]\n");
 938                         print("  'client' can be either the name or entity id of the bot\n");
 939                         print("  For full list of commands, see bot_cmd help [command].\n");
 940                         print("Examples: bot_cmd <id> cc \"say something\"\n");
 941                         print("          bot_cmd <id> presskey jump\n");
 942                         return;
 943         }
 944 }
 945
 946 void GameCommand(string command)
 947 {
 948         // ===== TODO list =====
 949         // Finish adding the rest of the commands
 950
 951         // Add ifdef to stuffto so that is can only be used when the game code is compiled for it
 952         //(this way it's more obscure and harder to abuse on normal servers)
 953
 954         entity client, tmp_entity;
 955         vector v;
 956         float search_request_type;
 957         string s;
 958         float argc = tokenize_console(command);
 959
 960         if(argv(0) == "help")
 961         {
 962                 if(argc == 1)
 963                 {
 964                         print("\nUsage: sv_cmd COMMAND..., where possible commands are:\n");
 965                         GameCommand_adminmsg(GC_REQUEST_HELP, command);
 966                         GameCommand_allready(GC_REQUEST_HELP);
 967                         GameCommand_allspec(GC_REQUEST_HELP);
 968                         GameCommand_anticheat(GC_REQUEST_HELP, command);
 969                         GameCommand_bbox(GC_REQUEST_HELP);
 970                         GameCommand_bot_cmd(GC_REQUEST_HELP, command);
 971                         print("  teamstatus\n");
 972                         print("  printstats\n");
 973                         print("  make_mapinfo\n");
 974                         print("  gametype dm|ctf|...\n");
 975                         print("  savedb filename\n");
 976                         print("  dumpdb filename\n");
 977                         print("  loaddb filename\n");
 978                         print("  allready\n");
 979                         print("  effectindexdump\n");
 980                         print("  radarmap [--force] [--quit | --loop] [sharpness]\n");
 981                         print("  bbox\n");
 982                         print("  cvar_changes\n");
 983                         print("  cvar_purechanges\n");
 984                         print("  find classname\n");
 985                         print("  extendmatchtime\n");
 986                         print("  reducematchtime\n");
 987                         GameCommand_Vote("help", world);
 988                         GameCommand_Ban("help");
 989                         GameCommand_Generic("help");
 990                         print("For help about specific commands, type sv_cmd help COMMAND\n");
 991                         return;
 992                 }
 993                 else
 994                         search_request_type = GC_REQUEST_USAGE; // Instead of trying to call a command, we're going to see detailed information about it
 995         }
 996         else if(GameCommand_Vote(command, world))
 997         {
 998                 return; // handled by server/vote.qc
 999         }
1000         else if(GameCommand_Ban(command))
1001         {
1002                 return; // handled by server/ipban.qc
1003         }
1004         else if(GameCommand_Generic(command))
1005         {
1006                 return; // handled by common/gamecommand.qc
1007         }
1008         else
1009                 search_request_type = GC_REQUEST_COMMAND; // continue as usual and scan for normal commands
1010
1011         switch( ((argv(0) == "help") ? argv(1) : argv(0)) ) // if first argument is help, then search for the second argument. Else, search for first.
1012         {
1013                 case "adminmsg": GameCommand_adminmsg(search_request_type, command); break;
1014                 case "allready": GameCommand_allready(search_request_type); break;
1015                 case "allspec": GameCommand_allspec(search_request_type); break;
1016                 case "anticheat": GameCommand_anticheat(search_request_type, command); break;
1017                 case "bbox": GameCommand_bbox(search_request_type); break;
1018                 case "bot_cmd": GameCommand_bot_cmd(search_request_type, command); break;
1019
1020                 default:
1021                         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
1022         }
1023 }
1024