qcsrc/server/ipban.qc

   1 /*
   2  * Protocol of online ban list:
   3  *
   4  * - Reporting a ban:
   5  *     GET g_ban_sync_uri?action=ban&hostname=...&ip=xxx.xxx.xxx&duration=nnnn&reason=...................
   6  *     (IP 1, 2, 3, or 4 octets, 3 octets for example is a /24 mask)
   7  * - Removing a ban:
   8  *     GET g_ban_sync_uri?action=unban&hostname=...&ip=xxx.xxx.xxx
   9  * - Querying the ban list
  10  *     GET g_ban_sync_uri?action=list&hostname=...&servers=xxx.xxx.xxx.xxx;xxx.xxx.xxx.xxx;...
  11  *
  12  *     shows the bans from the listed servers, and possibly others.
  13  *     Format of a ban is ASCII plain text, four lines per ban, delimited by
  14  *     newline ONLY (no carriage return):
  15  *
  16  *     IP address (also 1, 2, 3, or 4 octets, delimited by dot)
  17  *     time left in seconds
  18  *     reason of the ban
  19  *     server IP that registered the ban
  20  */
  21
  22 float Ban_Insert(string ip, float bantime, string reason, float dosync);
  23
  24 void OnlineBanList_SendBan(string ip, float bantime, string reason)
  25 {
  26         string uri;
  27         float i, n;
  28
  29         uri = strcat(     "action=ban&hostname=", uri_escape(cvar_string("hostname")));
  30         uri = strcat(uri, "&ip=", uri_escape(ip));
  31         uri = strcat(uri, "&duration=", ftos(bantime));
  32         uri = strcat(uri, "&reason=", uri_escape(reason));
  33
  34         n = tokenize_console(cvar_string("g_ban_sync_uri"));
  35         if(n >= MAX_IPBAN_URIS)
  36                 n = MAX_IPBAN_URIS;
  37         for(i = 0; i < n; ++i)
  38         {
  39                 if(strstrofs(argv(i), "?", 0) >= 0)
  40                         uri_get(strcat(argv(i), "&", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  41                 else
  42                         uri_get(strcat(argv(i), "?", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  43         }
  44 }
  45
  46 void OnlineBanList_SendUnban(string ip)
  47 {
  48         string uri;
  49         float i, n;
  50
  51         uri = strcat(     "action=unban&hostname=", uri_escape(cvar_string("hostname")));
  52         uri = strcat(uri, "&ip=", uri_escape(ip));
  53
  54         n = tokenize_console(cvar_string("g_ban_sync_uri"));
  55         if(n >= MAX_IPBAN_URIS)
  56                 n = MAX_IPBAN_URIS;
  57         for(i = 0; i < n; ++i)
  58         {
  59                 if(strstrofs(argv(i), "?", 0) >= 0)
  60                         uri_get(strcat(argv(i), "&", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  61                 else
  62                         uri_get(strcat(argv(i), "?", uri), URI_GET_DISCARD); // 0 = "discard" callback target
  63         }
  64 }
  65
  66 string OnlineBanList_Servers;
  67 float OnlineBanList_Timeout;
  68 float OnlineBanList_RequestWaiting[MAX_IPBAN_URIS];
  69
  70 void OnlineBanList_URI_Get_Callback(float id, float status, string data)
  71 {
  72         float n, i, j, l;
  73         string ip;
  74         float timeleft;
  75         string reason;
  76         string serverip;
  77         float syncinterval;
  78         string uri;
  79
  80         id -= URI_GET_IPBAN;
  81
  82         if(id >= MAX_IPBAN_URIS)
  83         {
  84                 print("Received ban list for invalid ID\n");
  85                 return;
  86         }
  87
  88         tokenize_console(cvar_string("g_ban_sync_uri"));
  89         uri = argv(id);
  90
  91         print("Received ban list from ", uri, ": ");
  92
  93         if(OnlineBanList_RequestWaiting[id] == 0)
  94         {
  95                 print("rejected (unexpected)\n");
  96                 return;
  97         }
  98
  99         OnlineBanList_RequestWaiting[id] = 0;
 100
 101         if(time > OnlineBanList_Timeout)
 102         {
 103                 print("rejected (too late)\n");
 104                 return;
 105         }
 106
 107         syncinterval = cvar("g_ban_sync_interval");
 108         if(syncinterval == 0)
 109         {
 110                 print("rejected (syncing disabled)\n");
 111                 return;
 112         }
 113         if(syncinterval > 0)
 114                 syncinterval *= 60;
 115
 116         if(status != 0)
 117         {
 118                 print("error: status is ", ftos(status), "\n");
 119                 return;
 120         }
 121
 122         if(substring(data, 0, 1) == "<")
 123         {
 124                 print("error: received HTML instead of a ban list\n");
 125                 return;
 126         }
 127
 128         if(strstrofs(data, "\r", 0) != -1)
 129         {
 130                 print("error: received carriage returns\n");
 131                 return;
 132         }
 133
 134         if(data == "")
 135                 n = 0;
 136         else
 137                 n = tokenizebyseparator(data, "\n");
 138
 139         if(mod(n, 4) != 0)
 140         {
 141                 print("error: received invalid item count: ", ftos(n), "\n");
 142                 return;
 143         }
 144
 145         print("OK, ", ftos(n / 4), " items\n");
 146
 147         for(i = 0; i < n; i += 4)
 148         {
 149                 ip = argv(i);
 150                 timeleft = stof(argv(i + 1));
 151                 reason = argv(i + 2);
 152                 serverip = argv(i + 3);
 153
 154                 dprint("received ban list item ", ftos(i / 4), ": ip=", ip);
 155                 dprint(" timeleft=", ftos(timeleft), " reason=", reason);
 156                 dprint(" serverip=", serverip, "\n");
 157
 158                 timeleft -= 1.5 * cvar("g_ban_sync_timeout");
 159                 if(timeleft < 0)
 160                         continue;
 161
 162                 l = strlen(ip);
 163                 if(l != 44) // length 44 is a cryptographic ID
 164                 {
 165                         for(j = 0; j < l; ++j)
 166                                 if(strstrofs("0123456789.", substring(ip, j, 1), 0) == -1)
 167                                 {
 168                                         print("Invalid character ", substring(ip, j, 1), " in IP address ", ip, ". Skipping this ban.\n");
 169                                         goto skip;
 170                                 }
 171                 }
 172
 173                 if(cvar("g_ban_sync_trusted_servers_verify"))
 174                         if((strstrofs(strcat(";", OnlineBanList_Servers, ";"), strcat(";", serverip, ";"), 0) == -1))
 175                                 continue;
 176
 177                 if(syncinterval > 0)
 178                         timeleft = min(syncinterval + (OnlineBanList_Timeout - time) + 5, timeleft);
 179                         // the ban will be prolonged on the next sync
 180                         // or expire 5 seconds after the next timeout
 181                 Ban_Insert(ip, timeleft, strcat("ban synced from ", serverip, " at ", uri), 0);
 182                 print("Ban list syncing: accepted ban of ", ip, " by ", serverip, " at ", uri, ": ");
 183                 print(reason, "\n");
 184
 185 :skip
 186         }
 187 }
 188
 189 void OnlineBanList_Think()
 190 {
 191         float argc;
 192         string uri;
 193         float i, n;
 194
 195         if(cvar_string("g_ban_sync_uri") == "")
 196                 goto killme;
 197         if(cvar("g_ban_sync_interval") == 0) // < 0 is okay, it means "sync on level start only"
 198                 goto killme;
 199         argc = tokenize_console(cvar_string("g_ban_sync_trusted_servers"));
 200         if(argc == 0)
 201                 goto killme;
 202
 203         if(OnlineBanList_Servers)
 204                 strunzone(OnlineBanList_Servers);
 205         OnlineBanList_Servers = argv(0);
 206         for(i = 1; i < argc; ++i)
 207                 OnlineBanList_Servers = strcat(OnlineBanList_Servers, ";", argv(i));
 208         OnlineBanList_Servers = strzone(OnlineBanList_Servers);
 209
 210         uri = strcat(     "action=list&hostname=", uri_escape(cvar_string("hostname")));
 211         uri = strcat(uri, "&servers=", uri_escape(OnlineBanList_Servers));
 212
 213         OnlineBanList_Timeout = time + cvar("g_ban_sync_timeout");
 214
 215         n = tokenize_console(cvar_string("g_ban_sync_uri"));
 216         if(n >= MAX_IPBAN_URIS)
 217                 n = MAX_IPBAN_URIS;
 218         for(i = 0; i < n; ++i)
 219         {
 220                 if(OnlineBanList_RequestWaiting[i])
 221                         continue;
 222                 OnlineBanList_RequestWaiting[i] = 1;
 223                 if(strstrofs(argv(i), "?", 0) >= 0)
 224                         uri_get(strcat(argv(i), "&", uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 225                 else
 226                         uri_get(strcat(argv(i), "?", uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 227         }
 228
 229         if(cvar("g_ban_sync_interval") > 0)
 230                 self.nextthink = time + max(60, cvar("g_ban_sync_interval") * 60);
 231         else
 232                 goto killme;
 233         return;
 234
 235 :killme
 236         remove(self);
 237 }
 238
 239 #define BAN_MAX 256
 240 float ban_loaded;
 241 string ban_ip[BAN_MAX];
 242 float ban_expire[BAN_MAX];
 243 float ban_count;
 244
 245 string ban_ip1;
 246 string ban_ip2;
 247 string ban_ip3;
 248 string ban_ip4;
 249 string ban_idfp;
 250
 251 void Ban_SaveBans()
 252 {
 253         string out;
 254         float i;
 255
 256         if(!ban_loaded)
 257                 return;
 258
 259         // version of list
 260         out = "1";
 261         for(i = 0; i < ban_count; ++i)
 262         {
 263                 if(time > ban_expire[i])
 264                         continue;
 265                 out = strcat(out, " ", ban_ip[i]);
 266                 out = strcat(out, " ", ftos(ban_expire[i] - time));
 267         }
 268         if(strlen(out) <= 1) // no real entries
 269                 cvar_set("g_banned_list", "");
 270         else
 271                 cvar_set("g_banned_list", out);
 272 }
 273
 274 float Ban_Delete(float i)
 275 {
 276         if(i < 0)
 277                 return FALSE;
 278         if(i >= ban_count)
 279                 return FALSE;
 280         if(ban_expire[i] == 0)
 281                 return FALSE;
 282         if(ban_expire[i] > 0)
 283         {
 284                 OnlineBanList_SendUnban(ban_ip[i]);
 285                 strunzone(ban_ip[i]);
 286         }
 287         ban_expire[i] = 0;
 288         ban_ip[i] = "";
 289         Ban_SaveBans();
 290         return TRUE;
 291 }
 292
 293 void Ban_LoadBans()
 294 {
 295         float i, n;
 296         for(i = 0; i < ban_count; ++i)
 297                 Ban_Delete(i);
 298         ban_count = 0;
 299         ban_loaded = TRUE;
 300         n = tokenize_console(cvar_string("g_banned_list"));
 301         if(stof(argv(0)) == 1)
 302         {
 303                 ban_count = (n - 1) / 2;
 304                 for(i = 0; i < ban_count; ++i)
 305                 {
 306                         ban_ip[i] = strzone(argv(2*i+1));
 307                         ban_expire[i] = time + stof(argv(2*i+2));
 308                 }
 309         }
 310
 311         entity e;
 312         e = spawn();
 313         e.classname = "bansyncer";
 314         e.think = OnlineBanList_Think;
 315         e.nextthink = time + 1;
 316 }
 317
 318 void Ban_View()
 319 {
 320         float i;
 321         string msg;
 322         for(i = 0; i < ban_count; ++i)
 323         {
 324                 if(time > ban_expire[i])
 325                         continue;
 326                 msg = strcat("#", ftos(i), ": ");
 327                 msg = strcat(msg, ban_ip[i], " is still banned for ");
 328                 msg = strcat(msg, ftos(ban_expire[i] - time), " seconds");
 329                 print(msg, "\n");
 330         }
 331 }
 332
 333 float Ban_GetClientIP(entity client)
 334 {
 335         // we can't use tokenizing here, as this is called during ban list parsing
 336         float i1, i2, i3, i4;
 337         string s;
 338
 339         if(client.crypto_keyfp)
 340                 ban_idfp = client.crypto_idfp;
 341         else
 342                 ban_idfp = string_null;
 343
 344         s = client.netaddress;
 345
 346         i1 = strstrofs(s, ".", 0);
 347         if(i1 < 0)
 348                 i1 = strstrofs(s, ":", 0);
 349         if(i1 < 0)
 350                 return FALSE;
 351         i2 = strstrofs(s, ".", i1 + 1);
 352         if(i2 < 0)
 353                 i2 = strstrofs(s, ":", i1 + 1);
 354         if(i2 < 0)
 355                 return FALSE;
 356         i3 = strstrofs(s, ".", i2 + 1);
 357         if(i3 < 0)
 358                 i3 = strstrofs(s, ":", i2 + 1);
 359         if(i3 < 0)
 360                 return FALSE;
 361         i4 = strstrofs(s, ".", i3 + 1);
 362         if(i4 < 0)
 363                 i4 = strstrofs(s, ":", i3 + 1);
 364         if(i4 >= 0)
 365                 s = substring(s, 0, i4);
 366
 367         ban_ip1 = substring(s, 0, i1);
 368         ban_ip2 = substring(s, 0, i2);
 369         ban_ip3 = substring(s, 0, i3);
 370         ban_ip4 = strcat1(s);
 371
 372         return TRUE;
 373 }
 374
 375 float Ban_IsClientBanned(entity client, float idx)
 376 {
 377         float i, b, e, ipbanned;
 378         if(!ban_loaded)
 379                 Ban_LoadBans();
 380         if(!Ban_GetClientIP(client))
 381                 return FALSE;
 382         if(idx < 0)
 383         {
 384                 b = 0;
 385                 e = ban_count;
 386         }
 387         else
 388         {
 389                 b = idx;
 390                 e = idx + 1;
 391         }
 392         ipbanned = FALSE;
 393         for(i = b; i < e; ++i)
 394         {
 395                 string s;
 396                 if(time > ban_expire[i])
 397                         continue;
 398                 s = ban_ip[i];
 399                 if(ban_ip1 == s) ipbanned = TRUE;
 400                 if(ban_ip2 == s) ipbanned = TRUE;
 401                 if(ban_ip3 == s) ipbanned = TRUE;
 402                 if(ban_ip4 == s) ipbanned = TRUE;
 403                 if(ban_idfp == s) return TRUE;
 404         }
 405         if(ipbanned)
 406                 if(!cvar("g_banned_list_idmode") || !ban_idfp)
 407                         return TRUE;
 408         return FALSE;
 409 }
 410
 411 float Ban_MaybeEnforceBan(entity client)
 412 {
 413         if(Ban_IsClientBanned(client, -1))
 414         {
 415                 string s;
 416                 s = strcat("^1NOTE:^7 banned client ", client.netaddress, " just tried to enter\n");
 417                 dropclient(client);
 418                 bprint(s);
 419                 return TRUE;
 420         }
 421         return FALSE;
 422 }
 423
 424 string Ban_Enforce(float i, string reason)
 425 {
 426         string s;
 427         entity e;
 428
 429         // Enforce our new ban
 430         s = "";
 431         FOR_EACH_REALCLIENT(e)
 432                 if(Ban_IsClientBanned(e, i))
 433                 {
 434                         if(reason != "")
 435                         {
 436                                 if(s == "")
 437                                         reason = strcat(reason, ": affects ");
 438                                 else
 439                                         reason = strcat(reason, ", ");
 440                                 reason = strcat(reason, e.netname);
 441                         }
 442                         s = strcat(s, "^1NOTE:^7 banned client ", e.netname, "^7 has to go\n");
 443                         dropclient(e);
 444                 }
 445         bprint(s);
 446
 447         return reason;
 448 }
 449
 450 float Ban_Insert(string ip, float bantime, string reason, float dosync)
 451 {
 452         float i;
 453         float j;
 454         float bestscore;
 455
 456         // already banned?
 457         for(i = 0; i < ban_count; ++i)
 458                 if(ban_ip[i] == ip)
 459                 {
 460                         // prolong the ban
 461                         if(time + bantime > ban_expire[i])
 462                         {
 463                                 ban_expire[i] = time + bantime;
 464                                 dprint(ip, "'s ban has been prolonged to ", ftos(bantime), " seconds from now\n");
 465                         }
 466                         else
 467                                 dprint(ip, "'s ban is still active until ", ftos(ban_expire[i] - time), " seconds from now\n");
 468
 469                         // and enforce
 470                         reason = Ban_Enforce(i, reason);
 471
 472                         // and abort
 473                         if(dosync)
 474                                 if(reason != "")
 475                                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 476                                                 OnlineBanList_SendBan(ip, bantime, reason);
 477
 478                         return FALSE;
 479                 }
 480
 481         // do we have a free slot?
 482         for(i = 0; i < ban_count; ++i)
 483                 if(time > ban_expire[i])
 484                         break;
 485         // no free slot? Then look for the one who would get unbanned next
 486         if(i >= BAN_MAX)
 487         {
 488                 i = 0;
 489                 bestscore = ban_expire[i];
 490                 for(j = 1; j < ban_count; ++j)
 491                 {
 492                         if(ban_expire[j] < bestscore)
 493                         {
 494                                 i = j;
 495                                 bestscore = ban_expire[i];
 496                         }
 497                 }
 498         }
 499         // if we replace someone, will we be banned longer than him (so long-term
 500         // bans never get overridden by short-term bans)
 501         if(i < ban_count)
 502         if(ban_expire[i] > time + bantime)
 503         {
 504                 print(ip, " could not get banned due to no free ban slot\n");
 505                 return FALSE;
 506         }
 507         // okay, insert our new victim as i
 508         Ban_Delete(i);
 509         dprint(ip, " has been banned for ", ftos(bantime), " seconds\n");
 510         ban_expire[i] = time + bantime;
 511         ban_ip[i] = strzone(ip);
 512         ban_count = max(ban_count, i + 1);
 513
 514         Ban_SaveBans();
 515
 516         reason = Ban_Enforce(i, reason);
 517
 518         // and abort
 519         if(dosync)
 520                 if(reason != "")
 521                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 522                                 OnlineBanList_SendBan(ip, bantime, reason);
 523
 524         return TRUE;
 525 }
 526
 527 void Ban_KickBanClient(entity client, float bantime, float masksize, string reason)
 528 {
 529         if(!Ban_GetClientIP(client))
 530         {
 531                 sprint(client, strcat("Kickbanned: ", reason, "\n"));
 532                 dropclient(client);
 533                 return;
 534         }
 535         // now ban him
 536         switch(masksize)
 537         {
 538                 case 1:
 539                         Ban_Insert(ban_ip1, bantime, reason, 1);
 540                         break;
 541                 case 2:
 542                         Ban_Insert(ban_ip2, bantime, reason, 1);
 543                         break;
 544                 case 3:
 545                         Ban_Insert(ban_ip3, bantime, reason, 1);
 546                         break;
 547                 case 4:
 548                 default:
 549                         Ban_Insert(ban_ip4, bantime, reason, 1);
 550                         break;
 551         }
 552         if(ban_idfp)
 553                 Ban_Insert(ban_idfp, bantime, reason, 1);
 554         /*
 555          * not needed, as we enforce the ban in Ban_Insert anyway
 556         // and kick him
 557         sprint(client, strcat("Kickbanned: ", reason, "\n"));
 558         dropclient(client);
 559          */
 560 }
 561
 562 float GameCommand_Ban(string command)
 563 {
 564         float argc;
 565         float bantime;
 566         entity client;
 567         float entno;
 568         float masksize;
 569         string reason;
 570         float reasonarg;
 571
 572         argc = tokenize_console(command);
 573         if(argv(0) == "help")
 574         {
 575                 print("  kickban # n m p reason - kickban player n for m seconds, using mask size p (1 to 4)\n");
 576                 print("  ban ip m reason - ban an IP or range (incomplete IP, like 1.2.3) for m seconds\n");
 577                 print("  bans - list all existing bans\n");
 578                 print("  unban n - delete the entry #n from the bans list\n");
 579                 return TRUE;
 580         }
 581         if(argv(0) == "kickban")
 582         {
 583 #define INITARG(c) reasonarg = c
 584 #define GETARG(v,d) if((argc > reasonarg) && ((v = stof(argv(reasonarg))) != 0)) ++reasonarg; else v = d
 585 #define RESTARG(v) if(argc > reasonarg) v = substring(command, argv_start_index(reasonarg), strlen(command) - argv_start_index(reasonarg)); else v = ""
 586                 if(argc >= 3)
 587                 {
 588                         entno = stof(argv(2));
 589                         if(entno > maxclients || entno < 1)
 590                                 return TRUE;
 591                         client = edict_num(entno);
 592
 593                         INITARG(3);
 594                         GETARG(bantime, cvar("g_ban_default_bantime"));
 595                         GETARG(masksize, cvar("g_ban_default_masksize"));
 596                         RESTARG(reason);
 597
 598                         Ban_KickBanClient(client, bantime, masksize, reason);
 599                         return TRUE;
 600                 }
 601         }
 602         else if(argv(0) == "ban")
 603         {
 604                 if(argc >= 2)
 605                 {
 606                         string ip;
 607                         ip = argv(1);
 608
 609                         INITARG(2);
 610                         GETARG(bantime, cvar("g_ban_default_bantime"));
 611                         RESTARG(reason);
 612
 613                         Ban_Insert(ip, bantime, reason, 1);
 614                         return TRUE;
 615                 }
 616 #undef INITARG
 617 #undef GETARG
 618 #undef RESTARG
 619         }
 620         else if(argv(0) == "bans")
 621         {
 622                 Ban_View();
 623                 return TRUE;
 624         }
 625         else if(argv(0) == "unban")
 626         {
 627                 if(argc >= 2)
 628                 {
 629                         float who;
 630                         who = stof(argv(1));
 631                         Ban_Delete(who);
 632                         return TRUE;
 633                 }
 634         }
 635         return FALSE;
 636 }