qcsrc/server/main.qc

   1 #include "main.qh"
   2
   3 #include <common/command/generic.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/debug.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/monsters/sv_monsters.qh>
   9 #include <common/util.qh>
  10 #include <common/vehicles/all.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <lib/csqcmodel/sv_model.qh>
  13 #include <lib/warpzone/common.qh>
  14 #include <lib/warpzone/server.qh>
  15 #include <server/anticheat.qh>
  16 #include <server/bot/api.qh>
  17 #include <server/command/common.qh>
  18 #include <server/compat/quake3.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/hook.qh>
  22 #include <server/ipban.qh>
  23 #include <server/mutators/_mod.qh>
  24 #include <server/spawnpoints.qh>
  25 #include <server/weapons/common.qh>
  26 #include <server/weapons/csqcprojectile.qh>
  27 #include <server/world.qh>
  28
  29 void dropclient_do(entity this)
  30 {
  31         if (this.owner)
  32                 dropclient(this.owner);
  33         delete(this);
  34 }
  35 /**
  36  * Schedules dropclient for a player and returns true;
  37  * if dropclient is already scheduled (for that player) it does nothing and returns false.
  38  *
  39  * NOTE: this function exists only to allow sending a message to the kicked player with
  40  * Send_Notification, which doesn't work if called together with dropclient
  41  */
  42 bool dropclient_schedule(entity this)
  43 {
  44         bool scheduled = false;
  45         FOREACH_ENTITY_CLASS("dropclient_handler", true,
  46         {
  47                 if(it.owner == this)
  48                 {
  49                         scheduled = true;
  50                         break; // can't use return here, compiler shows a warning
  51                 }
  52         });
  53         if (scheduled)
  54                 return false;
  55
  56         entity e = new_pure(dropclient_handler);
  57         setthink(e, dropclient_do);
  58         e.owner = this;
  59         e.nextthink = time + 0.1;
  60         return true;
  61 }
  62
  63 void CreatureFrame_hotliquids(entity this)
  64 {
  65         if (this.contents_damagetime >= time)
  66         {
  67                 return;
  68         }
  69
  70         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  71
  72         if (this.flags & FL_PROJECTILE)
  73         {
  74                 if (this.watertype == CONTENT_LAVA)
  75                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  76                 else if (this.watertype == CONTENT_SLIME)
  77                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  78         }
  79         else
  80         {
  81                 if (STAT(FROZEN, this))
  82                 {
  83                         if (this.watertype == CONTENT_LAVA)
  84                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  85                         else if (this.watertype == CONTENT_SLIME)
  86                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  87                 }
  88                 else if (this.watertype == CONTENT_LAVA)
  89                 {
  90                         if (this.watersound_finished < time)
  91                         {
  92                                 this.watersound_finished = time + 0.5;
  93                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  94                         }
  95                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  96                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  97                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  98                 }
  99                 else if (this.watertype == CONTENT_SLIME)
 100                 {
 101                         if (this.watersound_finished < time)
 102                         {
 103                                 this.watersound_finished = time + 0.5;
 104                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
 105                         }
 106                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
 107                 }
 108         }
 109 }
 110
 111 void CreatureFrame_Liquids(entity this)
 112 {
 113         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
 114         {
 115                 if (!(this.flags & FL_INWATER))
 116                 {
 117                         this.flags |= FL_INWATER;
 118                         this.contents_damagetime = 0;
 119                 }
 120
 121                 CreatureFrame_hotliquids(this);
 122         }
 123         else
 124         {
 125                 if (this.flags & FL_INWATER)
 126                 {
 127                         // play leave water sound
 128                         this.flags &= ~FL_INWATER;
 129                         this.contents_damagetime = 0;
 130                 }
 131         }
 132 }
 133
 134 void CreatureFrame_FallDamage(entity this)
 135 {
 136         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 137                 return; // vehicles and projectiles don't receive fall damage
 138         if(!(this.velocity || this.oldvelocity))
 139                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 140
 141         // check for falling damage
 142         bool have_hook = false;
 143         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 144         {
 145             .entity weaponentity = weaponentities[slot];
 146             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 147             {
 148                 have_hook = true;
 149                 break;
 150             }
 151         }
 152         if(!have_hook)
 153         {
 154                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 155                 if(autocvar_g_balance_falldamage_onlyvertical)
 156                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 157                 else
 158                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 159                 if (IS_DEAD(this))
 160                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 161                 else
 162                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 163                 if (dm > 0)
 164                 {
 165                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 166                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 167                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 168                 }
 169         }
 170
 171         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 172                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 173 }
 174
 175 void CreatureFrame_All()
 176 {
 177         if(game_stopped || time < game_starttime)
 178                 return;
 179
 180         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 181         {
 182                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 183                 CreatureFrame_Liquids(it);
 184                 CreatureFrame_FallDamage(it);
 185                 it.oldvelocity = it.velocity;
 186         });
 187 }
 188
 189 void Pause_TryPause(bool ispaused)
 190 {
 191         int n = 0;
 192         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 193                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 194                 ++n;
 195         });
 196         if (!n) return;
 197         setpause(ispaused);
 198 }
 199
 200 void SV_PausedTic(float elapsedtime)
 201 {
 202         if (!server_is_dedicated) Pause_TryPause(false);
 203 }
 204
 205 void dedicated_print(string input)
 206 {
 207         if (server_is_dedicated) print(input);
 208 }
 209
 210 void make_safe_for_remove(entity e)
 211 {
 212     if (e.initialize_entity)
 213     {
 214         entity ent, prev = NULL;
 215         for (ent = initialize_entity_first; ent; )
 216         {
 217             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 218             {
 219                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 220                 // skip it in linked list
 221                 if (prev)
 222                 {
 223                     prev.initialize_entity_next = ent.initialize_entity_next;
 224                     ent = prev.initialize_entity_next;
 225                 }
 226                 else
 227                 {
 228                     initialize_entity_first = ent.initialize_entity_next;
 229                     ent = initialize_entity_first;
 230                 }
 231             }
 232             else
 233             {
 234                 prev = ent;
 235                 ent = ent.initialize_entity_next;
 236             }
 237         }
 238     }
 239 }
 240
 241 void remove_except_protected(entity e)
 242 {
 243         if(e.remove_except_protected_forbidden)
 244                 error("not allowed to remove this at this point");
 245         builtin_remove(e);
 246 }
 247
 248 void remove_unsafely(entity e)
 249 {
 250     if(e.classname == "spike")
 251         error("Removing spikes is forbidden (crylink bug), please report");
 252     builtin_remove(e);
 253 }
 254
 255 void remove_safely(entity e)
 256 {
 257     make_safe_for_remove(e);
 258     builtin_remove(e);
 259 }
 260
 261 /*
 262 =============
 263 StartFrame
 264
 265 Called before each frame by the server
 266 =============
 267 */
 268
 269 bool game_delay_last;
 270
 271 bool autocvar_sv_autopause = false;
 272 void systems_update();
 273 void sys_phys_update(entity this, float dt);
 274 void StartFrame()
 275 {
 276     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 277     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 278     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 279
 280         execute_next_frame();
 281         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 282
 283         delete_fn = remove_unsafely; // not during spawning!
 284         serverprevtime = servertime;
 285         servertime = time;
 286         serverframetime = frametime;
 287
 288 #ifdef PROFILING
 289         if(time > client_cefc_accumulatortime + 1)
 290         {
 291                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 292                 int c_seeing = 0;
 293                 int c_seen = 0;
 294                 FOREACH_CLIENT(true, {
 295                         if(IS_REAL_CLIENT(it))
 296                                 ++c_seeing;
 297                         if(IS_PLAYER(it))
 298                                 ++c_seen;
 299                 });
 300                 LOG_INFO(
 301                     "CEFC time: ", ftos(t * 1000), "ms; ",
 302             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 303             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 304         );
 305                 client_cefc_accumulatortime = time;
 306                 client_cefc_accumulator = 0;
 307         }
 308 #endif
 309
 310         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 311
 312         if (RedirectionThink()) return;
 313
 314         UncustomizeEntitiesRun();
 315         InitializeEntitiesRun();
 316
 317         WarpZone_StartFrame();
 318
 319         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 320         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 321
 322         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 323                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 324
 325         // detect when the pre-game countdown (if any) has ended and the game has started
 326         bool game_delay = (time < game_starttime);
 327         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 328                 GameLogEcho(":startdelay_ended");
 329         game_delay_last = game_delay;
 330
 331         CreatureFrame_All();
 332         CheckRules_World();
 333
 334         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 335                 ReadyRestart();
 336                 return;
 337         }
 338
 339         bot_serverframe();
 340         anticheat_startframe();
 341         MUTATOR_CALLHOOK(SV_StartFrame);
 342
 343         GlobalStats_updateglobal();
 344     FOREACH_CLIENT(true, GlobalStats_update(it));
 345     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 346 }
 347
 348 .vector originjitter;
 349 .vector anglesjitter;
 350 .float anglejitter;
 351 .string gametypefilter;
 352 .string cvarfilter;
 353
 354 void SV_OnEntityPreSpawnFunction(entity this)
 355 {
 356         if (this)
 357         if (this.gametypefilter != "")
 358         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 359         {
 360                 delete(this);
 361                 return;
 362         }
 363         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 364                 delete(this);
 365                 return;
 366         }
 367
 368         if (DoesQ3ARemoveThisEntity(this)) {
 369                 delete(this);
 370                 return;
 371         }
 372
 373         set_movetype(this, this.movetype);
 374
 375         if (this.monster_attack) {
 376                 IL_PUSH(g_monster_targets, this);
 377     }
 378
 379         // support special -1 and -2 angle from radiant
 380         if (this.angles == '0 -1 0') {
 381                 this.angles = '-90 0 0';
 382         } else if (this.angles == '0 -2 0') {
 383                 this.angles = '+90 0 0';
 384     }
 385
 386     #define X(out, in) MACRO_BEGIN \
 387         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 388     MACRO_END
 389     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 390     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 391     X(this.angles.y, this.anglejitter);
 392     #undef X
 393
 394         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 395                 delete(this);
 396                 return;
 397         }
 398 }
 399
 400 void WarpZone_PostInitialize_Callback()
 401 {
 402         // create waypoint links for warpzones
 403         entity tracetest_ent = spawn();
 404         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 405         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 406         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 407         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 408                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 409         delete(tracetest_ent);
 410 }
 411
 412 /** engine callback */
 413 void URI_Get_Callback(float id, float status, string data)
 414 {
 415         if(url_URI_Get_Callback(id, status, data))
 416         {
 417                 // handled
 418         }
 419         else if (id == URI_GET_DISCARD)
 420         {
 421                 // discard
 422         }
 423         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 424         {
 425                 // sv_cmd curl
 426                 Curl_URI_Get_Callback(id, status, data);
 427         }
 428         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
 429         {
 430                 // online ban list
 431                 OnlineBanList_URI_Get_Callback(id, status, data);
 432         }
 433         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
 434         {
 435                 // handled by a mutator
 436         }
 437         else
 438         {
 439                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
 440         }
 441 }
 442
 443 /*
 444 ==================
 445 main
 446
 447 unused but required by the engine
 448 ==================
 449 */
 450 void main ()
 451 {
 452
 453 }