qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include "../common/deathtypes/all.qh"
  20 #include "../common/mapinfo.qh"
  21 #include "../common/notifications/all.qh"
  22 #include "../common/playerstats.qh"
  23 #include "../common/teams.qh"
  24 #include "../common/mapobjects/subs.qh"
  25 #include "../common/util.qh"
  26 #include "../common/turrets/sv_turrets.qh"
  27 #include <common/weapons/_all.qh>
  28 #include "../common/vehicles/sv_vehicles.qh"
  29 #include "../common/vehicles/vehicle.qh"
  30 #include "../common/items/_mod.qh"
  31 #include "../common/state.qh"
  32 #include "../common/effects/qc/globalsound.qh"
  33 #include "../common/wepent.qh"
  34 #include "../lib/csqcmodel/sv_model.qh"
  35 #include "../lib/warpzone/anglestransform.qh"
  36 #include "../lib/warpzone/server.qh"
  37
  38 void crosshair_trace(entity pl)
  39 {
  40         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  41 }
  42 .bool ctrace_solidchanged;
  43 void crosshair_trace_plusvisibletriggers(entity pl)
  44 {
  45         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  46         {
  47                 if(it.model != "")
  48                 {
  49                         it.solid = SOLID_BSP;
  50                         it.ctrace_solidchanged = true;
  51                         IL_PUSH(g_ctrace_changed, it);
  52                 }
  53         });
  54
  55         crosshair_trace(pl);
  56
  57         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  58         {
  59                 it.solid = SOLID_TRIGGER;
  60                 it.ctrace_solidchanged = false;
  61         });
  62
  63         IL_CLEAR(g_ctrace_changed);
  64 }
  65 void WarpZone_crosshair_trace(entity pl)
  66 {
  67         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  68 }
  69
  70
  71 void GameLogEcho(string s)
  72 {
  73     string fn;
  74     int matches;
  75
  76     if (autocvar_sv_eventlog_files)
  77     {
  78         if (!logfile_open)
  79         {
  80             logfile_open = true;
  81             matches = autocvar_sv_eventlog_files_counter + 1;
  82             cvar_set("sv_eventlog_files_counter", itos(matches));
  83             fn = ftos(matches);
  84             if (strlen(fn) < 8)
  85                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  86             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  87             logfile = fopen(fn, FILE_APPEND);
  88             fputs(logfile, ":logversion:3\n");
  89         }
  90         if (logfile >= 0)
  91         {
  92             if (autocvar_sv_eventlog_files_timestamps)
  93                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  94             else
  95                 fputs(logfile, strcat(s, "\n"));
  96         }
  97     }
  98     if (autocvar_sv_eventlog_console)
  99     {
 100         dedicated_print(strcat(s, "\n"));
 101     }
 102 }
 103
 104 void GameLogInit()
 105 {
 106     logfile_open = 0;
 107     // will be opened later
 108 }
 109
 110 void GameLogClose()
 111 {
 112     if (logfile_open && logfile >= 0)
 113     {
 114         fclose(logfile);
 115         logfile = -1;
 116     }
 117 }
 118
 119 entity findnearest(vector point, bool checkitems, vector axismod)
 120 {
 121     vector dist;
 122     int num_nearest = 0;
 123
 124     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 125     {
 126         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 127             dist = it.oldorigin;
 128         else
 129             dist = it.origin;
 130         dist = dist - point;
 131         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 132         float len = vlen2(dist);
 133
 134         int l;
 135         for (l = 0; l < num_nearest; ++l)
 136         {
 137             if (len < nearest_length[l])
 138                 break;
 139         }
 140
 141         // now i tells us where to insert at
 142         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 143         if (l < NUM_NEAREST_ENTITIES)
 144         {
 145             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 146             {
 147                 nearest_length[j + 1] = nearest_length[j];
 148                 nearest_entity[j + 1] = nearest_entity[j];
 149             }
 150             nearest_length[l] = len;
 151             nearest_entity[l] = it;
 152             if (num_nearest < NUM_NEAREST_ENTITIES)
 153                 num_nearest = num_nearest + 1;
 154         }
 155     });
 156
 157     // now use the first one from our list that we can see
 158     for (int j = 0; j < num_nearest; ++j)
 159     {
 160         traceline(point, nearest_entity[j].origin, true, NULL);
 161         if (trace_fraction == 1)
 162         {
 163             if (j != 0)
 164                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 165             return nearest_entity[j];
 166         }
 167     }
 168
 169     if (num_nearest == 0)
 170         return NULL;
 171
 172     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 173     /* DEBUGGING CODE:
 174     dprint("Candidates were: ");
 175     for(j = 0; j < num_nearest; ++j)
 176     {
 177         if(j != 0)
 178                 dprint(", ");
 179         dprint(nearest_entity[j].netname);
 180     }
 181     dprint("\n");
 182     */
 183
 184     return nearest_entity[0];
 185 }
 186
 187 string NearestLocation(vector p)
 188 {
 189     string ret = "somewhere";
 190     entity loc = findnearest(p, false, '1 1 1');
 191     if (loc)
 192         ret = loc.message;
 193     else
 194     {
 195         loc = findnearest(p, true, '1 1 4');
 196         if (loc)
 197             ret = loc.netname;
 198     }
 199     return ret;
 200 }
 201
 202 string AmmoNameFromWeaponentity(Weapon wep)
 203 {
 204         string ammoitems = "batteries";
 205         switch (wep.ammo_type)
 206         {
 207                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 208                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 209                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 210                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 211                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 212                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 213         }
 214         return ammoitems;
 215 }
 216
 217 string formatmessage(entity this, string msg)
 218 {
 219         float p, p1, p2;
 220         float n;
 221         vector cursor;
 222         entity cursor_ent;
 223         string escape;
 224         string replacement;
 225         p = 0;
 226         n = 7;
 227
 228         WarpZone_crosshair_trace(this);
 229         cursor = trace_endpos;
 230         cursor_ent = trace_ent;
 231
 232         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 233         msg = M_ARGV(1, string);
 234
 235         while (1) {
 236                 if (n < 1)
 237                         break; // too many replacements
 238
 239                 n = n - 1;
 240                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 241                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 242
 243                 if (p1 < 0)
 244                         p1 = p2;
 245
 246                 if (p2 < 0)
 247                         p2 = p1;
 248
 249                 p = min(p1, p2);
 250
 251                 if (p < 0)
 252                         break;
 253
 254                 replacement = substring(msg, p, 2);
 255                 escape = substring(msg, p + 1, 1);
 256
 257                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 258
 259                 switch(escape)
 260                 {
 261                         case "%": replacement = "%"; break;
 262                         case "\\":replacement = "\\"; break;
 263                         case "n": replacement = "\n"; break;
 264                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 265                         case "h": replacement = ftos(floor(this.health)); break;
 266                         case "l": replacement = NearestLocation(this.origin); break;
 267                         case "y": replacement = NearestLocation(cursor); break;
 268                         case "d": replacement = NearestLocation(this.death_origin); break;
 269                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 270                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 271                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 272                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 273                         case "S": replacement = ftos(vlen(this.velocity)); break;
 274                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 275                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 276                         default:
 277                         {
 278                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 279                                 replacement = M_ARGV(2, string);
 280                                 break;
 281                         }
 282                 }
 283
 284                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 285                 p = p + strlen(replacement);
 286         }
 287         return msg;
 288 }
 289
 290 /*
 291 =============
 292 GetCvars
 293 =============
 294 Called with:
 295   0:  sends the request
 296   >0: receives a cvar from name=argv(f) value=argv(f+1)
 297 */
 298 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 299 {
 300         if (f < 0)
 301         {
 302                 strfree(store.(field));
 303         }
 304         else if (f > 0)
 305         {
 306                 if (thisname == name)
 307                 {
 308                         strcpy(store.(field), argv(f + 1));
 309                 }
 310         }
 311         else
 312                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 313 }
 314 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 315 {
 316         GetCvars_handleString(this, store, thisname, f, field, name);
 317         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 318                 if (thisname == name)
 319                 {
 320                         string s = func(this, strcat1(store.(field)));
 321                         if (s != store.(field))
 322                         {
 323                                 strcpy(store.(field), s);
 324                         }
 325                 }
 326 }
 327 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 328 {
 329         if (f < 0)
 330         {
 331         }
 332         else if (f > 0)
 333         {
 334                 if (thisname == name)
 335                         store.(field) = stof(argv(f + 1));
 336         }
 337         else
 338                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 339 }
 340 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 341 {
 342         if (f < 0)
 343         {
 344         }
 345         else if (f > 0)
 346         {
 347                 if (thisname == name)
 348                 {
 349                         if (!store.(field))
 350                         {
 351                                 store.(field) = stof(argv(f + 1));
 352                                 if (!store.(field))
 353                                         store.(field) = -1;
 354                         }
 355                 }
 356         }
 357         else
 358         {
 359                 if (!store.(field))
 360                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 361         }
 362 }
 363 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 364 {
 365         string o = W_FixWeaponOrder_ForceComplete(wo);
 366         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 367         return o;
 368 }
 369
 370 REPLICATE(autoswitch, bool, "cl_autoswitch");
 371
 372 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 373
 374 REPLICATE(cvar_cl_allow_uidranking, bool, "cl_allow_uidranking");
 375
 376 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 377
 378 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 379
 380 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 381
 382 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 383
 384 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 385
 386 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 387
 388 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 389
 390 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 391
 392 REPLICATE(cvar_cl_physics, string, "cl_physics");
 393
 394 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 395
 396 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 397
 398 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 399
 400 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 401
 402 /**
 403  * @param f -1: cleanup, 0: request, 1: receive
 404  */
 405 void GetCvars(entity this, entity store, int f)
 406 {
 407         string s = string_null;
 408
 409         if (f > 0)
 410                 s = strcat1(argv(f));
 411
 412         get_cvars_f = f;
 413         get_cvars_s = s;
 414         MUTATOR_CALLHOOK(GetCvars);
 415
 416         Notification_GetCvars(this);
 417
 418         ReplicateVars(this, store, s, f);
 419
 420         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 421         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 422         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 423         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 424         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 425         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 431
 432         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 433
 434         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 435         if (f > 0)
 436         {
 437                 if (s == "cl_weaponpriority")
 438                 {
 439                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 440                         {
 441                                 .entity weaponentity = weaponentities[slot];
 442                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 443                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 444                         }
 445                 }
 446                 if (s == "cl_allow_uidtracking")
 447                         PlayerStats_GameReport_AddPlayer(this);
 448         }
 449 }
 450
 451 // decolorizes and team colors the player name when needed
 452 string playername(entity p, bool team_colorize)
 453 {
 454     string t;
 455     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 456     {
 457         t = Team_ColorCode(p.team);
 458         return strcat(t, strdecolorize(p.netname));
 459     }
 460     else
 461         return p.netname;
 462 }
 463
 464 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 465 {
 466         int i = weaponinfo.m_id;
 467         int d = 0;
 468         bool allow_mutatorblocked = false;
 469
 470         if(!i)
 471                 return 0;
 472
 473         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 474         d = M_ARGV(1, float);
 475         allguns = M_ARGV(2, bool);
 476         allow_mutatorblocked = M_ARGV(3, bool);
 477
 478         if(allguns)
 479         {
 480                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 481                         d = true;
 482                 else
 483                         d = false;
 484         }
 485         else if(!mutator_returnvalue)
 486                 d = !(!weaponinfo.weaponstart);
 487
 488         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 489                 d = 0;
 490
 491         float t = weaponinfo.weaponstartoverride;
 492
 493         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 494
 495         // bit order in t:
 496         // 1: want or not
 497         // 2: is default?
 498         // 4: is set by default?
 499         if(t < 0)
 500                 t = 4 | (3 * d);
 501         else
 502                 t |= (2 * d);
 503
 504         return t;
 505 }
 506
 507 void readplayerstartcvars()
 508 {
 509         float i, t;
 510         string s;
 511
 512         // initialize starting values for players
 513         start_weapons = '0 0 0';
 514         start_weapons_default = '0 0 0';
 515         start_weapons_defaultmask = '0 0 0';
 516         start_items = 0;
 517         start_ammo_shells = 0;
 518         start_ammo_nails = 0;
 519         start_ammo_rockets = 0;
 520         start_ammo_cells = 0;
 521         start_ammo_plasma = 0;
 522         if (random_start_ammo == NULL)
 523         {
 524                 random_start_ammo = spawn();
 525         }
 526         start_health = cvar("g_balance_health_start");
 527         start_armorvalue = cvar("g_balance_armor_start");
 528
 529         g_weaponarena = 0;
 530         g_weaponarena_weapons = '0 0 0';
 531
 532         s = cvar_string("g_weaponarena");
 533
 534         MUTATOR_CALLHOOK(SetWeaponArena, s);
 535         s = M_ARGV(0, string);
 536
 537         if (s == "0" || s == "")
 538         {
 539                 // no arena
 540         }
 541         else if (s == "off")
 542         {
 543                 // forcibly turn off weaponarena
 544         }
 545         else if (s == "all" || s == "1")
 546         {
 547                 g_weaponarena = 1;
 548                 g_weaponarena_list = "All Weapons";
 549                 FOREACH(Weapons, it != WEP_Null, {
 550                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 551                                 g_weaponarena_weapons |= (it.m_wepset);
 552                 });
 553         }
 554         else if (s == "devall")
 555         {
 556                 g_weaponarena = 1;
 557                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 558                 FOREACH(Weapons, it != WEP_Null,
 559                 {
 560                         g_weaponarena_weapons |= (it.m_wepset);
 561                 });
 562         }
 563         else if (s == "most")
 564         {
 565                 g_weaponarena = 1;
 566                 g_weaponarena_list = "Most Weapons";
 567                 FOREACH(Weapons, it != WEP_Null, {
 568                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 569                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 570                                         g_weaponarena_weapons |= (it.m_wepset);
 571                 });
 572         }
 573         else if (s == "none")
 574         {
 575                 g_weaponarena = 1;
 576                 g_weaponarena_list = "No Weapons";
 577         }
 578         else
 579         {
 580                 g_weaponarena = 1;
 581                 t = tokenize_console(s);
 582                 g_weaponarena_list = "";
 583                 for (i = 0; i < t; ++i)
 584                 {
 585                         s = argv(i);
 586                         FOREACH(Weapons, it != WEP_Null, {
 587                                 if(it.netname == s)
 588                                 {
 589                                         g_weaponarena_weapons |= (it.m_wepset);
 590                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 591                                         break;
 592                                 }
 593                         });
 594                 }
 595                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 596         }
 597
 598         if (g_weaponarena)
 599         {
 600                 g_weapon_stay = 0; // incompatible
 601                 start_weapons = g_weaponarena_weapons;
 602                 start_items |= IT_UNLIMITED_AMMO;
 603         }
 604         else
 605         {
 606                 FOREACH(Weapons, it != WEP_Null, {
 607                         int w = want_weapon(it, false);
 608                         WepSet s = it.m_wepset;
 609                         if(w & 1)
 610                                 start_weapons |= s;
 611                         if(w & 2)
 612                                 start_weapons_default |= s;
 613                         if(w & 4)
 614                                 start_weapons_defaultmask |= s;
 615                 });
 616         }
 617
 618         if(!cvar("g_use_ammunition"))
 619                 start_items |= IT_UNLIMITED_AMMO;
 620
 621         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 622         {
 623                 start_ammo_shells = 999;
 624                 start_ammo_nails = 999;
 625                 start_ammo_rockets = 999;
 626                 start_ammo_cells = 999;
 627                 start_ammo_plasma = 999;
 628                 start_ammo_fuel = 999;
 629         }
 630         else
 631         {
 632                 start_ammo_shells = cvar("g_start_ammo_shells");
 633                 start_ammo_nails = cvar("g_start_ammo_nails");
 634                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 635                 start_ammo_cells = cvar("g_start_ammo_cells");
 636                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 637                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 638                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 639                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 640                         "g_random_start_shells"));
 641                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 642                         "g_random_start_bullets"));
 643                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 644                         cvar("g_random_start_rockets"));
 645                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 646                         "g_random_start_cells"));
 647                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 648                         "g_random_start_plasma"));
 649         }
 650
 651         if (warmup_stage)
 652         {
 653                 warmup_start_ammo_shells = start_ammo_shells;
 654                 warmup_start_ammo_nails = start_ammo_nails;
 655                 warmup_start_ammo_rockets = start_ammo_rockets;
 656                 warmup_start_ammo_cells = start_ammo_cells;
 657                 warmup_start_ammo_plasma = start_ammo_plasma;
 658                 warmup_start_ammo_fuel = start_ammo_fuel;
 659                 warmup_start_health = start_health;
 660                 warmup_start_armorvalue = start_armorvalue;
 661                 warmup_start_weapons = start_weapons;
 662                 warmup_start_weapons_default = start_weapons_default;
 663                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 664
 665                 if (!g_weaponarena && !g_ca && !g_freezetag)
 666                 {
 667                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 668                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 669                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 670                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 671                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 672                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 673                         warmup_start_health = cvar("g_warmup_start_health");
 674                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 675                         warmup_start_weapons = '0 0 0';
 676                         warmup_start_weapons_default = '0 0 0';
 677                         warmup_start_weapons_defaultmask = '0 0 0';
 678                         FOREACH(Weapons, it != WEP_Null, {
 679                                 int w = want_weapon(it, g_warmup_allguns);
 680                                 WepSet s = (it.m_wepset);
 681                                 if(w & 1)
 682                                         warmup_start_weapons |= s;
 683                                 if(w & 2)
 684                                         warmup_start_weapons_default |= s;
 685                                 if(w & 4)
 686                                         warmup_start_weapons_defaultmask |= s;
 687                         });
 688                 }
 689         }
 690
 691         if (g_jetpack)
 692                 start_items |= ITEM_Jetpack.m_itemid;
 693
 694         MUTATOR_CALLHOOK(SetStartItems);
 695
 696         if (start_items & ITEM_Jetpack.m_itemid)
 697         {
 698                 start_items |= ITEM_JetpackRegen.m_itemid;
 699                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 700                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 701         }
 702
 703         WepSet precache_weapons = start_weapons;
 704         if (g_warmup_allguns != 1)
 705                 precache_weapons |= warmup_start_weapons;
 706         FOREACH(Weapons, it != WEP_Null, {
 707                 if(precache_weapons & (it.m_wepset))
 708                         it.wr_init(it);
 709         });
 710
 711         start_ammo_shells = max(0, start_ammo_shells);
 712         start_ammo_nails = max(0, start_ammo_nails);
 713         start_ammo_rockets = max(0, start_ammo_rockets);
 714         start_ammo_cells = max(0, start_ammo_cells);
 715         start_ammo_plasma = max(0, start_ammo_plasma);
 716         start_ammo_fuel = max(0, start_ammo_fuel);
 717         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 718                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 719         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 720                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 721         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 722                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 723         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 724                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 725         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 726                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 727
 728         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 729         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 730         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 731         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 732         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 733         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 734 }
 735
 736 void precache_playermodel(string m)
 737 {
 738         float globhandle, i, n;
 739         string f;
 740
 741         if(substring(m, -9,5) == "_lod1")
 742                 return;
 743         if(substring(m, -9,5) == "_lod2")
 744                 return;
 745         precache_model(m);
 746         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 747         if(fexists(f))
 748                 precache_model(f);
 749         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 750         if(fexists(f))
 751                 precache_model(f);
 752
 753         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 754         if (globhandle < 0)
 755                 return;
 756         n = search_getsize(globhandle);
 757         for (i = 0; i < n; ++i)
 758         {
 759                 //print(search_getfilename(globhandle, i), "\n");
 760                 f = search_getfilename(globhandle, i);
 761                 PrecachePlayerSounds(f);
 762         }
 763         search_end(globhandle);
 764 }
 765 void precache_all_playermodels(string pattern)
 766 {
 767         int globhandle = search_begin(pattern, true, false);
 768         if (globhandle < 0) return;
 769         int n = search_getsize(globhandle);
 770         for (int i = 0; i < n; ++i)
 771         {
 772                 string s = search_getfilename(globhandle, i);
 773                 precache_playermodel(s);
 774         }
 775         search_end(globhandle);
 776 }
 777
 778 void precache_playermodels(string s)
 779 {
 780         FOREACH_WORD(s, true, { precache_playermodel(it); });
 781 }
 782
 783 void precache()
 784 {
 785     // gamemode related things
 786
 787     // Precache all player models if desired
 788     if (autocvar_sv_precacheplayermodels)
 789     {
 790         PrecachePlayerSounds("sound/player/default.sounds");
 791         precache_all_playermodels("models/player/*.zym");
 792         precache_all_playermodels("models/player/*.dpm");
 793         precache_all_playermodels("models/player/*.md3");
 794         precache_all_playermodels("models/player/*.psk");
 795         precache_all_playermodels("models/player/*.iqm");
 796     }
 797
 798     if (autocvar_sv_defaultcharacter)
 799     {
 800                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 801                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 802                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 803                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 804                 precache_playermodels(autocvar_sv_defaultplayermodel);
 805     }
 806
 807 #if 0
 808     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 809
 810     if (!this.noise && this.music) // quake 3 uses the music field
 811         this.noise = this.music;
 812
 813     // plays music for the level if there is any
 814     if (this.noise)
 815     {
 816         precache_sound (this.noise);
 817         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 818     }
 819 #endif
 820 }
 821
 822
 823 void make_safe_for_remove(entity e)
 824 {
 825     if (e.initialize_entity)
 826     {
 827         entity ent, prev = NULL;
 828         for (ent = initialize_entity_first; ent; )
 829         {
 830             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 831             {
 832                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 833                 // skip it in linked list
 834                 if (prev)
 835                 {
 836                     prev.initialize_entity_next = ent.initialize_entity_next;
 837                     ent = prev.initialize_entity_next;
 838                 }
 839                 else
 840                 {
 841                     initialize_entity_first = ent.initialize_entity_next;
 842                     ent = initialize_entity_first;
 843                 }
 844             }
 845             else
 846             {
 847                 prev = ent;
 848                 ent = ent.initialize_entity_next;
 849             }
 850         }
 851     }
 852 }
 853
 854 .float remove_except_protected_forbidden;
 855 void remove_except_protected(entity e)
 856 {
 857         if(e.remove_except_protected_forbidden)
 858                 error("not allowed to remove this at this point");
 859         builtin_remove(e);
 860 }
 861
 862 void remove_unsafely(entity e)
 863 {
 864     if(e.classname == "spike")
 865         error("Removing spikes is forbidden (crylink bug), please report");
 866     builtin_remove(e);
 867 }
 868
 869 void remove_safely(entity e)
 870 {
 871     make_safe_for_remove(e);
 872     builtin_remove(e);
 873 }
 874
 875 void InitializeEntity(entity e, void(entity this) func, float order)
 876 {
 877     entity prev, cur;
 878
 879     if (!e || e.initialize_entity)
 880     {
 881         // make a proxy initializer entity
 882         entity e_old = e;
 883         e = new(initialize_entity);
 884         e.enemy = e_old;
 885     }
 886
 887     e.initialize_entity = func;
 888     e.initialize_entity_order = order;
 889
 890     cur = initialize_entity_first;
 891     prev = NULL;
 892     for (;;)
 893     {
 894         if (!cur || cur.initialize_entity_order > order)
 895         {
 896             // insert between prev and cur
 897             if (prev)
 898                 prev.initialize_entity_next = e;
 899             else
 900                 initialize_entity_first = e;
 901             e.initialize_entity_next = cur;
 902             return;
 903         }
 904         prev = cur;
 905         cur = cur.initialize_entity_next;
 906     }
 907 }
 908 void InitializeEntitiesRun()
 909 {
 910     entity startoflist = initialize_entity_first;
 911     initialize_entity_first = NULL;
 912     delete_fn = remove_except_protected;
 913     for (entity e = startoflist; e; e = e.initialize_entity_next)
 914     {
 915                 e.remove_except_protected_forbidden = 1;
 916     }
 917     for (entity e = startoflist; e; )
 918     {
 919                 e.remove_except_protected_forbidden = 0;
 920         e.initialize_entity_order = 0;
 921         entity next = e.initialize_entity_next;
 922         e.initialize_entity_next = NULL;
 923         var void(entity this) func = e.initialize_entity;
 924         e.initialize_entity = func_null;
 925         if (e.classname == "initialize_entity")
 926         {
 927             entity wrappee = e.enemy;
 928             builtin_remove(e);
 929             e = wrappee;
 930         }
 931         //dprint("Delayed initialization: ", e.classname, "\n");
 932         if (func)
 933         {
 934                 func(e);
 935         }
 936         else
 937         {
 938             eprint(e);
 939             backtrace(strcat("Null function in: ", e.classname, "\n"));
 940         }
 941         e = next;
 942     }
 943     delete_fn = remove_unsafely;
 944 }
 945
 946 .float(entity) isEliminated;
 947 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 948 {
 949         Stream out = MSG_ENTITY;
 950         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 951         serialize(byte, out, sendflags);
 952         if (sendflags & 1) {
 953                 for (int i = 1; i <= maxclients; i += 8) {
 954                         int f = 0;
 955                         entity e = edict_num(i);
 956                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 957                                 if (eliminatedPlayers.isEliminated(e)) {
 958                                         f |= BIT(b);
 959                                 }
 960                         }
 961                         serialize(byte, out, f);
 962                 }
 963         }
 964         return true;
 965 }
 966
 967 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 968 {
 969         if(eliminatedPlayers)
 970         {
 971                 backtrace("Can't spawn eliminatedPlayers again!");
 972                 return;
 973         }
 974         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 975         eliminatedPlayers.isEliminated = isEliminated_func;
 976 }
 977
 978
 979
 980
 981 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 982 {
 983         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 984                 this.projectiledeathtype |= HITTYPE_SPLASH;
 985         adaptor_think2use(this);
 986 }
 987
 988 // deferred dropping
 989 void DropToFloor_Handler(entity this)
 990 {
 991     WITHSELF(this, builtin_droptofloor());
 992     this.dropped_origin = this.origin;
 993 }
 994
 995 void droptofloor(entity this)
 996 {
 997     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
 998 }
 999
1000
1001
1002 float trace_hits_box_a0, trace_hits_box_a1;
1003
1004 float trace_hits_box_1d(float end, float thmi, float thma)
1005 {
1006     if (end == 0)
1007     {
1008         // just check if x is in range
1009         if (0 < thmi)
1010             return false;
1011         if (0 > thma)
1012             return false;
1013     }
1014     else
1015     {
1016         // do the trace with respect to x
1017         // 0 -> end has to stay in thmi -> thma
1018         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1019         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1020         if (trace_hits_box_a0 > trace_hits_box_a1)
1021             return false;
1022     }
1023     return true;
1024 }
1025
1026 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1027 {
1028     end -= start;
1029     thmi -= start;
1030     thma -= start;
1031     // now it is a trace from 0 to end
1032
1033     trace_hits_box_a0 = 0;
1034     trace_hits_box_a1 = 1;
1035
1036     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1037         return false;
1038     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1039         return false;
1040     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1041         return false;
1042
1043     return true;
1044 }
1045
1046 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1047 {
1048     return trace_hits_box(start, end, thmi - ma, thma - mi);
1049 }
1050
1051 bool SUB_NoImpactCheck(entity this, entity toucher)
1052 {
1053         // zero hitcontents = this is not the real impact, but either the
1054         // mirror-impact of something hitting the projectile instead of the
1055         // projectile hitting the something, or a touchareagrid one. Neither of
1056         // these stop the projectile from moving, so...
1057         if(trace_dphitcontents == 0)
1058         {
1059                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1060                 checkclient(this);
1061         }
1062     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1063         return true;
1064     if (toucher == NULL && this.size != '0 0 0')
1065     {
1066         vector tic;
1067         tic = this.velocity * sys_frametime;
1068         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1069         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1070         if (trace_fraction >= 1)
1071         {
1072             LOG_TRACE("Odd... did not hit...?");
1073         }
1074         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1075         {
1076             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1077             return true;
1078         }
1079     }
1080
1081     return false;
1082 }
1083
1084 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1085
1086 void W_Crylink_Dequeue(entity e);
1087 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1088 {
1089         if(SUB_OwnerCheck(this, toucher))
1090                 return true;
1091         if(SUB_NoImpactCheck(this, toucher))
1092         {
1093                 if(this.classname == "nade")
1094                         return false; // no checks here
1095                 else if(this.classname == "grapplinghook")
1096                         RemoveHook(this);
1097                 else if(this.classname == "spike")
1098                 {
1099                         W_Crylink_Dequeue(this);
1100                         delete(this);
1101                 }
1102                 else
1103                         delete(this);
1104                 return true;
1105         }
1106         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1107                 UpdateCSQCProjectile(this);
1108         return false;
1109 }
1110
1111 /** engine callback */
1112 void URI_Get_Callback(float id, float status, string data)
1113 {
1114         if(url_URI_Get_Callback(id, status, data))
1115         {
1116                 // handled
1117         }
1118         else if (id == URI_GET_DISCARD)
1119         {
1120                 // discard
1121         }
1122         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1123         {
1124                 // sv_cmd curl
1125                 Curl_URI_Get_Callback(id, status, data);
1126         }
1127         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1128         {
1129                 // online ban list
1130                 OnlineBanList_URI_Get_Callback(id, status, data);
1131         }
1132         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1133         {
1134                 // handled by a mutator
1135         }
1136         else
1137         {
1138                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1139         }
1140 }
1141
1142 string uid2name(string myuid) {
1143         string s;
1144         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1145
1146         // FIXME remove this later after 0.6 release
1147         // convert old style broken records to correct style
1148         if(s == "")
1149         {
1150                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1151                 if(s != "")
1152                 {
1153                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1154                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1155                 }
1156         }
1157
1158         if(s == "")
1159                 s = "^1Unregistered Player";
1160         return s;
1161 }
1162
1163 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1164 {
1165     float m, i;
1166     vector start, org, delta, end, enddown, mstart;
1167
1168     m = e.dphitcontentsmask;
1169     e.dphitcontentsmask = goodcontents | badcontents;
1170
1171     org = boundmin;
1172     delta = boundmax - boundmin;
1173
1174     start = end = org;
1175
1176     for (i = 0; i < attempts; ++i)
1177     {
1178         start.x = org.x + random() * delta.x;
1179         start.y = org.y + random() * delta.y;
1180         start.z = org.z + random() * delta.z;
1181
1182         // rule 1: start inside world bounds, and outside
1183         // solid, and don't start from somewhere where you can
1184         // fall down to evil
1185         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1186         if (trace_fraction >= 1)
1187             continue;
1188         if (trace_startsolid)
1189             continue;
1190         if (trace_dphitcontents & badcontents)
1191             continue;
1192         if (trace_dphitq3surfaceflags & badsurfaceflags)
1193             continue;
1194
1195         // rule 2: if we are too high, lower the point
1196         if (trace_fraction * delta.z > maxaboveground)
1197             start = trace_endpos + '0 0 1' * maxaboveground;
1198         enddown = trace_endpos;
1199
1200         // rule 3: make sure we aren't outside the map. This only works
1201         // for somewhat well formed maps. A good rule of thumb is that
1202         // the map should have a convex outside hull.
1203         // these can be traceLINES as we already verified the starting box
1204         mstart = start + 0.5 * (e.mins + e.maxs);
1205         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1206         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1207             continue;
1208         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1209         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1210             continue;
1211         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1212         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1213             continue;
1214         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1215         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1216             continue;
1217         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220
1221         // rule 4: we must "see" some spawnpoint or item
1222     entity sp = NULL;
1223     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1224     {
1225         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1226         {
1227                 sp = it;
1228                 break;
1229         }
1230     });
1231         if(!sp)
1232         {
1233                 int items_checked = 0;
1234                 IL_EACH(g_items, checkpvs(mstart, it),
1235                 {
1236                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1237                         {
1238                                 sp = it;
1239                                 break;
1240                         }
1241
1242                         ++items_checked;
1243                         if(items_checked >= attempts)
1244                                 break; // sanity
1245                 });
1246
1247                 if(!sp)
1248                         continue;
1249         }
1250
1251         // find a random vector to "look at"
1252         end.x = org.x + random() * delta.x;
1253         end.y = org.y + random() * delta.y;
1254         end.z = org.z + random() * delta.z;
1255         end = start + normalize(end - start) * vlen(delta);
1256
1257         // rule 4: start TO end must not be too short
1258         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1259         if (trace_startsolid)
1260             continue;
1261         if (trace_fraction < minviewdistance / vlen(delta))
1262             continue;
1263
1264         // rule 5: don't want to look at sky
1265         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1266             continue;
1267
1268         // rule 6: we must not end up in trigger_hurt
1269         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1270             continue;
1271
1272         break;
1273     }
1274
1275     e.dphitcontentsmask = m;
1276
1277     if (i < attempts)
1278     {
1279         setorigin(e, start);
1280         e.angles = vectoangles(end - start);
1281         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1282         return true;
1283     }
1284     else
1285         return false;
1286 }
1287
1288 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1289 {
1290         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1291 }
1292
1293 void write_recordmarker(entity pl, float tstart, float dt)
1294 {
1295     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1296
1297     // also write a marker into demo files for demotc-race-record-extractor to find
1298     stuffcmd(pl,
1299              strcat(
1300                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1301                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1302 }
1303
1304 void attach_sameorigin(entity e, entity to, string tag)
1305 {
1306     vector org, t_forward, t_left, t_up, e_forward, e_up;
1307     float tagscale;
1308
1309     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1310     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1311     t_forward = v_forward * tagscale;
1312     t_left = v_right * -tagscale;
1313     t_up = v_up * tagscale;
1314
1315     e.origin_x = org * t_forward;
1316     e.origin_y = org * t_left;
1317     e.origin_z = org * t_up;
1318
1319     // current forward and up directions
1320     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1321                 e.angles = AnglesTransform_FromVAngles(e.angles);
1322         else
1323                 e.angles = AnglesTransform_FromAngles(e.angles);
1324     fixedmakevectors(e.angles);
1325
1326     // untransform forward, up!
1327     e_forward.x = v_forward * t_forward;
1328     e_forward.y = v_forward * t_left;
1329     e_forward.z = v_forward * t_up;
1330     e_up.x = v_up * t_forward;
1331     e_up.y = v_up * t_left;
1332     e_up.z = v_up * t_up;
1333
1334     e.angles = fixedvectoangles2(e_forward, e_up);
1335     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1336                 e.angles = AnglesTransform_ToVAngles(e.angles);
1337         else
1338                 e.angles = AnglesTransform_ToAngles(e.angles);
1339
1340     setattachment(e, to, tag);
1341     setorigin(e, e.origin);
1342 }
1343
1344 void detach_sameorigin(entity e)
1345 {
1346     vector org;
1347     org = gettaginfo(e, 0);
1348     e.angles = fixedvectoangles2(v_forward, v_up);
1349     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1350                 e.angles = AnglesTransform_ToVAngles(e.angles);
1351         else
1352                 e.angles = AnglesTransform_ToAngles(e.angles);
1353     setorigin(e, org);
1354     setattachment(e, NULL, "");
1355     setorigin(e, e.origin);
1356 }
1357
1358 void follow_sameorigin(entity e, entity to)
1359 {
1360     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1361     e.aiment = to; // make the hole follow bmodel
1362     e.punchangle = to.angles; // the original angles of bmodel
1363     e.view_ofs = e.origin - to.origin; // relative origin
1364     e.v_angle = e.angles - to.angles; // relative angles
1365 }
1366
1367 void unfollow_sameorigin(entity e)
1368 {
1369     set_movetype(e, MOVETYPE_NONE);
1370 }
1371
1372 entity gettaginfo_relative_ent;
1373 vector gettaginfo_relative(entity e, float tag)
1374 {
1375     if (!gettaginfo_relative_ent)
1376     {
1377         gettaginfo_relative_ent = spawn();
1378         gettaginfo_relative_ent.effects = EF_NODRAW;
1379     }
1380     gettaginfo_relative_ent.model = e.model;
1381     gettaginfo_relative_ent.modelindex = e.modelindex;
1382     gettaginfo_relative_ent.frame = e.frame;
1383     return gettaginfo(gettaginfo_relative_ent, tag);
1384 }
1385
1386 .string aiment_classname;
1387 .float aiment_deadflag;
1388 void SetMovetypeFollow(entity ent, entity e)
1389 {
1390         // FIXME this may not be warpzone aware
1391         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1392         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1393         ent.aiment = e; // make the hole follow bmodel
1394         ent.punchangle = e.angles; // the original angles of bmodel
1395         ent.view_ofs = ent.origin - e.origin; // relative origin
1396         ent.v_angle = ent.angles - e.angles; // relative angles
1397         ent.aiment_classname = strzone(e.classname);
1398         ent.aiment_deadflag = e.deadflag;
1399 }
1400 void UnsetMovetypeFollow(entity ent)
1401 {
1402         set_movetype(ent, MOVETYPE_FLY);
1403         PROJECTILE_MAKETRIGGER(ent);
1404         ent.aiment = NULL;
1405 }
1406 float LostMovetypeFollow(entity ent)
1407 {
1408 /*
1409         if(ent.move_movetype != MOVETYPE_FOLLOW)
1410                 if(ent.aiment)
1411                         error("???");
1412 */
1413         if(ent.aiment)
1414         {
1415                 if(ent.aiment.classname != ent.aiment_classname)
1416                         return 1;
1417                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1418                         return 1;
1419         }
1420         return 0;
1421 }
1422
1423 .bool pushable;
1424 bool isPushable(entity e)
1425 {
1426         if(e.pushable)
1427                 return true;
1428         if(IS_VEHICLE(e))
1429                 return false;
1430         if(e.iscreature)
1431                 return true;
1432         if (Item_IsLoot(e))
1433         {
1434                 return true;
1435         }
1436         switch(e.classname)
1437         {
1438                 case "body":
1439                         return true;
1440                 case "bullet": // antilagged bullets can't hit this either
1441                         return false;
1442         }
1443         if (e.projectiledeathtype)
1444                 return true;
1445         return false;
1446 }