qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70 float DistributeEvenly_GetRandomized(float weight)
  71 {
  72     float f;
  73     if (weight <= 0)
  74         return 0;
  75     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  76     DistributeEvenly_totalweight -= weight;
  77     DistributeEvenly_amount -= f;
  78     return f;
  79 }
  80
  81 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  82
  83
  84 string STR_PLAYER = "player";
  85 string STR_SPECTATOR = "spectator";
  86 string STR_OBSERVER = "observer";
  87
  88 #if 0
  89 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  90 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  91 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  92 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  93 #else
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  97 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  98 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if(v.classname != STR_PLAYER)
  99 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 100 #endif
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + ((ent.classname == STR_PLAYER) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void bcenterprint(string s)
 111 {
 112     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 113     entity head;
 114     FOR_EACH_PLAYER(head)
 115     if (clienttype(head) == CLIENTTYPE_REAL)
 116         centerprint(head, s);
 117 }
 118
 119 void GameLogEcho(string s)
 120 {
 121     string fn;
 122     float matches;
 123
 124     if (autocvar_sv_eventlog_files)
 125     {
 126         if (!logfile_open)
 127         {
 128             logfile_open = TRUE;
 129             matches = autocvar_sv_eventlog_files_counter + 1;
 130             cvar_set("sv_eventlog_files_counter", ftos(matches));
 131             fn = ftos(matches);
 132             if (strlen(fn) < 8)
 133                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 134             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 135             logfile = fopen(fn, FILE_APPEND);
 136             fputs(logfile, ":logversion:3\n");
 137         }
 138         if (logfile >= 0)
 139         {
 140             if (autocvar_sv_eventlog_files_timestamps)
 141                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 142             else
 143                 fputs(logfile, strcat(s, "\n"));
 144         }
 145     }
 146     if (autocvar_sv_eventlog_console)
 147     {
 148         print(s, "\n");
 149     }
 150 }
 151
 152 void GameLogInit()
 153 {
 154     logfile_open = 0;
 155     // will be opened later
 156 }
 157
 158 void GameLogClose()
 159 {
 160     if (logfile_open && logfile >= 0)
 161     {
 162         fclose(logfile);
 163         logfile = -1;
 164     }
 165 }
 166
 167 float spawnpoint_nag;
 168 void relocate_spawnpoint()
 169 {
 170     // nudge off the floor
 171     setorigin(self, self.origin + '0 0 1');
 172
 173     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 174     if (trace_startsolid)
 175     {
 176         vector o;
 177         o = self.origin;
 178         self.mins = PL_MIN;
 179         self.maxs = PL_MAX;
 180         if (!move_out_of_solid(self))
 181             objerror("could not get out of solid at all!");
 182         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 183         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 184         print(" ", ftos(self.origin_y - o_y));
 185         print(" ", ftos(self.origin_z - o_z), "'\n");
 186         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 187         {
 188             if (!spawnpoint_nag)
 189                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 190             spawnpoint_nag = 1;
 191         }
 192         else
 193         {
 194             setorigin(self, o);
 195             self.mins = self.maxs = '0 0 0';
 196             objerror("player spawn point in solid, mapper sucks!\n");
 197             return;
 198         }
 199     }
 200
 201     self.use = spawnpoint_use;
 202     self.team_saved = self.team;
 203     if (!self.cnt)
 204         self.cnt = 1;
 205
 206     if (have_team_spawns != 0)
 207         if (self.team)
 208             have_team_spawns = 1;
 209     have_team_spawns_forteam[self.team] = 1;
 210
 211     if (autocvar_r_showbboxes)
 212     {
 213         // show where spawnpoints point at too
 214         makevectors(self.angles);
 215         entity e;
 216         e = spawn();
 217         e.classname = "info_player_foo";
 218         setorigin(e, self.origin + v_forward * 24);
 219         setsize(e, '-8 -8 -8', '8 8 8');
 220         e.solid = SOLID_TRIGGER;
 221     }
 222 }
 223
 224 #define strstr strstrofs
 225 /*
 226 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 227 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 228 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 229 // BE CONSTANT OR strzoneD!
 230 float strstr(string haystack, string needle, float offset)
 231 {
 232         float len, endpos;
 233         string found;
 234         len = strlen(needle);
 235         endpos = strlen(haystack) - len;
 236         while(offset <= endpos)
 237         {
 238                 found = substring(haystack, offset, len);
 239                 if(found == needle)
 240                         return offset;
 241                 offset = offset + 1;
 242         }
 243         return -1;
 244 }
 245 */
 246
 247 float NUM_NEAREST_ENTITIES = 4;
 248 entity nearest_entity[NUM_NEAREST_ENTITIES];
 249 float nearest_length[NUM_NEAREST_ENTITIES];
 250 entity findnearest(vector point, .string field, string value, vector axismod)
 251 {
 252     entity localhead;
 253     float i;
 254     float j;
 255     float len;
 256     vector dist;
 257
 258     float num_nearest;
 259     num_nearest = 0;
 260
 261     localhead = find(world, field, value);
 262     while (localhead)
 263     {
 264         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 265             dist = localhead.oldorigin;
 266         else
 267             dist = localhead.origin;
 268         dist = dist - point;
 269         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 270         len = vlen(dist);
 271
 272         for (i = 0; i < num_nearest; ++i)
 273         {
 274             if (len < nearest_length[i])
 275                 break;
 276         }
 277
 278         // now i tells us where to insert at
 279         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 280         if (i < NUM_NEAREST_ENTITIES)
 281         {
 282             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 283             {
 284                 nearest_length[j + 1] = nearest_length[j];
 285                 nearest_entity[j + 1] = nearest_entity[j];
 286             }
 287             nearest_length[i] = len;
 288             nearest_entity[i] = localhead;
 289             if (num_nearest < NUM_NEAREST_ENTITIES)
 290                 num_nearest = num_nearest + 1;
 291         }
 292
 293         localhead = find(localhead, field, value);
 294     }
 295
 296     // now use the first one from our list that we can see
 297     for (i = 0; i < num_nearest; ++i)
 298     {
 299         traceline(point, nearest_entity[i].origin, TRUE, world);
 300         if (trace_fraction == 1)
 301         {
 302             if (i != 0)
 303             {
 304                 dprint("Nearest point (");
 305                 dprint(nearest_entity[0].netname);
 306                 dprint(") is not visible, using a visible one.\n");
 307             }
 308             return nearest_entity[i];
 309         }
 310     }
 311
 312     if (num_nearest == 0)
 313         return world;
 314
 315     dprint("Not seeing any location point, using nearest as fallback.\n");
 316     /* DEBUGGING CODE:
 317     dprint("Candidates were: ");
 318     for(j = 0; j < num_nearest; ++j)
 319     {
 320         if(j != 0)
 321                 dprint(", ");
 322         dprint(nearest_entity[j].netname);
 323     }
 324     dprint("\n");
 325     */
 326
 327     return nearest_entity[0];
 328 }
 329
 330 void spawnfunc_target_location()
 331 {
 332     self.classname = "target_location";
 333     // location name in netname
 334     // eventually support: count, teamgame selectors, line of sight?
 335 }
 336
 337 void spawnfunc_info_location()
 338 {
 339     self.classname = "target_location";
 340     self.message = self.netname;
 341 }
 342
 343 string NearestLocation(vector p)
 344 {
 345     entity loc;
 346     string ret;
 347     ret = "somewhere";
 348     loc = findnearest(p, classname, "target_location", '1 1 1');
 349     if (loc)
 350     {
 351         ret = loc.message;
 352     }
 353     else
 354     {
 355         loc = findnearest(p, target, "###item###", '1 1 4');
 356         if (loc)
 357             ret = loc.netname;
 358     }
 359     return ret;
 360 }
 361
 362 string formatmessage(string msg)
 363 {
 364         float p, p1, p2;
 365         float n;
 366         vector cursor;
 367         entity cursor_ent;
 368         string escape;
 369         string replacement;
 370         p = 0;
 371         n = 7;
 372
 373         WarpZone_crosshair_trace(self);
 374         cursor = trace_endpos;
 375         cursor_ent = trace_ent;
 376
 377         while (1) {
 378                 if (n < 1)
 379                         break; // too many replacements
 380
 381                 n = n - 1;
 382                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 383                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 384
 385                 if (p1 < 0)
 386                         p1 = p2;
 387
 388                 if (p2 < 0)
 389                         p2 = p1;
 390
 391                 p = min(p1, p2);
 392
 393                 if (p < 0)
 394                         break;
 395
 396                 replacement = substring(msg, p, 2);
 397                 escape = substring(msg, p + 1, 1);
 398
 399                 if (escape == "%")
 400                         replacement = "%";
 401                 else if (escape == "\\")
 402                         replacement = "\\";
 403                 else if (escape == "n")
 404                         replacement = "\n";
 405                 else if (escape == "a")
 406                         replacement = ftos(floor(self.armorvalue));
 407                 else if (escape == "h")
 408                         replacement = ftos(floor(self.health));
 409                 else if (escape == "l")
 410                         replacement = NearestLocation(self.origin);
 411                 else if (escape == "y")
 412                         replacement = NearestLocation(cursor);
 413                 else if (escape == "d")
 414                         replacement = NearestLocation(self.death_origin);
 415                 else if (escape == "w") {
 416                         float wep;
 417                         wep = self.weapon;
 418                         if (!wep)
 419                                 wep = self.switchweapon;
 420                         if (!wep)
 421                                 wep = self.cnt;
 422                         replacement = W_Name(wep);
 423                 } else if (escape == "W") {
 424                         if (self.items & IT_SHELLS) replacement = "shells";
 425                         else if (self.items & IT_NAILS) replacement = "bullets";
 426                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 427                         else if (self.items & IT_CELLS) replacement = "cells";
 428                         else replacement = "batteries"; // ;)
 429                 } else if (escape == "x") {
 430                         replacement = cursor_ent.netname;
 431                         if (!replacement || !cursor_ent)
 432                                 replacement = "nothing";
 433                 } else if (escape == "s")
 434                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 435                 else if (escape == "S")
 436                         replacement = ftos(vlen(self.velocity));
 437
 438                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 439                 p = p + strlen(replacement);
 440         }
 441         return msg;
 442 }
 443
 444 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 445         return (value == 0) ? FALSE : TRUE;
 446 }
 447
 448 /*
 449 =============
 450 GetCvars
 451 =============
 452 Called with:
 453   0:  sends the request
 454   >0: receives a cvar from name=argv(f) value=argv(f+1)
 455 */
 456 void GetCvars_handleString(string thisname, float f, .string field, string name)
 457 {
 458         if (f < 0)
 459         {
 460                 if (self.field)
 461                         strunzone(self.field);
 462                 self.field = string_null;
 463         }
 464         else if (f > 0)
 465         {
 466                 if (thisname == name)
 467                 {
 468                         if (self.field)
 469                                 strunzone(self.field);
 470                         self.field = strzone(argv(f + 1));
 471                 }
 472         }
 473         else
 474                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 475 }
 476 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 477 {
 478         GetCvars_handleString(thisname, f, field, name);
 479         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 480                 if (thisname == name)
 481                 {
 482                         string s;
 483                         s = func(strcat1(self.field));
 484                         if (s != self.field)
 485                         {
 486                                 strunzone(self.field);
 487                                 self.field = strzone(s);
 488                         }
 489                 }
 490 }
 491 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                         self.field = stof(argv(f + 1));
 500         }
 501         else
 502                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 503 }
 504 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 505 {
 506         if (f < 0)
 507         {
 508         }
 509         else if (f > 0)
 510         {
 511                 if (thisname == name)
 512                 {
 513                         if(!self.field)
 514                         {
 515                                 self.field = stof(argv(f + 1));
 516                                 if(!self.field)
 517                                         self.field = -1;
 518                         }
 519                 }
 520         }
 521         else
 522         {
 523                 if(!self.field)
 524                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 525         }
 526 }
 527 float w_getbestweapon(entity e);
 528 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 529 {
 530         string o;
 531         o = W_FixWeaponOrder_ForceComplete(wo);
 532         if(self.weaponorder_byimpulse)
 533         {
 534                 strunzone(self.weaponorder_byimpulse);
 535                 self.weaponorder_byimpulse = string_null;
 536         }
 537         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 538         return o;
 539 }
 540 void GetCvars(float f)
 541 {
 542         string s = string_null;
 543
 544         if (f > 0)
 545                 s = strcat1(argv(f));
 546
 547         get_cvars_f = f;
 548         get_cvars_s = s;
 549         MUTATOR_CALLHOOK(GetCvars);
 550         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 551         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 552         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 553         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 554         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 564         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 565         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 566         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 567         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 568         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 569         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 570         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 571         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 572         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 573
 574         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 575         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 576
 577 #ifdef ALLOW_FORCEMODELS
 578         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 579         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 580 #endif
 581         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 582         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 583         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 584         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 585         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 586
 587         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 588         if (f > 0)
 589         {
 590                 if (s == "cl_weaponpriority")
 591                         self.switchweapon = w_getbestweapon(self);
 592                 if (s == "cl_allow_uidtracking")
 593                         PlayerStats_AddPlayer(self);
 594         }
 595 }
 596
 597 void backtrace(string msg)
 598 {
 599     float dev, war;
 600     dev = autocvar_developer;
 601     war = autocvar_prvm_backtraceforwarnings;
 602     cvar_set("developer", "1");
 603     cvar_set("prvm_backtraceforwarnings", "1");
 604     print("\n");
 605     print("--- CUT HERE ---\nWARNING: ");
 606     print(msg);
 607     print("\n");
 608     remove(world); // isn't there any better way to cause a backtrace?
 609     print("\n--- CUT UNTIL HERE ---\n");
 610     cvar_set("developer", ftos(dev));
 611     cvar_set("prvm_backtraceforwarnings", ftos(war));
 612 }
 613
 614 string Team_ColorCode(float teamid)
 615 {
 616     if (teamid == COLOR_TEAM1)
 617         return "^1";
 618     else if (teamid == COLOR_TEAM2)
 619         return "^4";
 620     else if (teamid == COLOR_TEAM3)
 621         return "^3";
 622     else if (teamid == COLOR_TEAM4)
 623         return "^6";
 624     else
 625         return "^7";
 626 }
 627
 628 string Team_ColorName(float t)
 629 {
 630     // fixme: Search for team entities and get their .netname's!
 631     if (t == COLOR_TEAM1)
 632         return "Red";
 633     if (t == COLOR_TEAM2)
 634         return "Blue";
 635     if (t == COLOR_TEAM3)
 636         return "Yellow";
 637     if (t == COLOR_TEAM4)
 638         return "Pink";
 639     return "Neutral";
 640 }
 641
 642 string Team_ColorNameLowerCase(float t)
 643 {
 644     // fixme: Search for team entities and get their .netname's!
 645     if (t == COLOR_TEAM1)
 646         return "red";
 647     if (t == COLOR_TEAM2)
 648         return "blue";
 649     if (t == COLOR_TEAM3)
 650         return "yellow";
 651     if (t == COLOR_TEAM4)
 652         return "pink";
 653     return "neutral";
 654 }
 655
 656 float ColourToNumber(string team_colour)
 657 {
 658         if (team_colour == "red")
 659                 return COLOR_TEAM1;
 660
 661         if (team_colour == "blue")
 662                 return COLOR_TEAM2;
 663
 664         if (team_colour == "yellow")
 665                 return COLOR_TEAM3;
 666
 667         if (team_colour == "pink")
 668                 return COLOR_TEAM4;
 669
 670         if (team_colour == "auto")
 671                 return 0;
 672
 673         return -1;
 674 }
 675
 676 float NumberToTeamNumber(float number)
 677 {
 678         if (number == 1)
 679                 return COLOR_TEAM1;
 680
 681         if (number == 2)
 682                 return COLOR_TEAM2;
 683
 684         if (number == 3)
 685                 return COLOR_TEAM3;
 686
 687         if (number == 4)
 688                 return COLOR_TEAM4;
 689
 690         return -1;
 691 }
 692
 693 // decolorizes and team colors the player name when needed
 694 string playername(entity p)
 695 {
 696     string t;
 697     if (teamplay && !intermission_running && p.classname == "player")
 698     {
 699         t = Team_ColorCode(p.team);
 700         return strcat(t, strdecolorize(p.netname));
 701     }
 702     else
 703         return p.netname;
 704 }
 705
 706 vector randompos(vector m1, vector m2)
 707 {
 708     vector v;
 709     m2 = m2 - m1;
 710     v_x = m2_x * random() + m1_x;
 711     v_y = m2_y * random() + m1_y;
 712     v_z = m2_z * random() + m1_z;
 713     return  v;
 714 }
 715
 716 //#NO AUTOCVARS START
 717
 718 float g_pickup_shells;
 719 float g_pickup_shells_max;
 720 float g_pickup_nails;
 721 float g_pickup_nails_max;
 722 float g_pickup_rockets;
 723 float g_pickup_rockets_max;
 724 float g_pickup_cells;
 725 float g_pickup_cells_max;
 726 float g_pickup_fuel;
 727 float g_pickup_fuel_jetpack;
 728 float g_pickup_fuel_max;
 729 float g_pickup_armorsmall;
 730 float g_pickup_armorsmall_max;
 731 float g_pickup_armorsmall_anyway;
 732 float g_pickup_armormedium;
 733 float g_pickup_armormedium_max;
 734 float g_pickup_armormedium_anyway;
 735 float g_pickup_armorbig;
 736 float g_pickup_armorbig_max;
 737 float g_pickup_armorbig_anyway;
 738 float g_pickup_armorlarge;
 739 float g_pickup_armorlarge_max;
 740 float g_pickup_armorlarge_anyway;
 741 float g_pickup_healthsmall;
 742 float g_pickup_healthsmall_max;
 743 float g_pickup_healthsmall_anyway;
 744 float g_pickup_healthmedium;
 745 float g_pickup_healthmedium_max;
 746 float g_pickup_healthmedium_anyway;
 747 float g_pickup_healthlarge;
 748 float g_pickup_healthlarge_max;
 749 float g_pickup_healthlarge_anyway;
 750 float g_pickup_healthmega;
 751 float g_pickup_healthmega_max;
 752 float g_pickup_healthmega_anyway;
 753 float g_pickup_ammo_anyway;
 754 float g_pickup_weapons_anyway;
 755 float g_weaponarena;
 756 WEPSET_DECLARE_A(g_weaponarena_weapons);
 757 float g_weaponarena_random;
 758 float g_weaponarena_random_with_laser;
 759 string g_weaponarena_list;
 760 float g_weaponspeedfactor;
 761 float g_weaponratefactor;
 762 float g_weapondamagefactor;
 763 float g_weaponforcefactor;
 764 float g_weaponspreadfactor;
 765
 766 WEPSET_DECLARE_A(start_weapons);
 767 WEPSET_DECLARE_A(start_weapons_default);
 768 WEPSET_DECLARE_A(start_weapons_defaultmask);
 769 float start_items;
 770 float start_ammo_shells;
 771 float start_ammo_nails;
 772 float start_ammo_rockets;
 773 float start_ammo_cells;
 774 float start_ammo_fuel;
 775 float start_health;
 776 float start_armorvalue;
 777 WEPSET_DECLARE_A(warmup_start_weapons);
 778 WEPSET_DECLARE_A(warmup_start_weapons_default);
 779 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 780 float warmup_start_ammo_shells;
 781 float warmup_start_ammo_nails;
 782 float warmup_start_ammo_rockets;
 783 float warmup_start_ammo_cells;
 784 float warmup_start_ammo_fuel;
 785 float warmup_start_health;
 786 float warmup_start_armorvalue;
 787 float g_weapon_stay;
 788
 789 entity get_weaponinfo(float w);
 790
 791 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 792 {
 793         var float i = weaponinfo.weapon;
 794         var float d = 0;
 795
 796         if (!i)
 797                 return 0;
 798
 799         if (g_lms || g_ca || allguns)
 800         {
 801                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 802                         d = TRUE;
 803                 else
 804                         d = FALSE;
 805         }
 806         else if (g_cts)
 807                 d = (i == WEP_SHOTGUN);
 808         else if (g_nexball)
 809                 d = 0; // weapon is set a few lines later
 810         else
 811                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 812
 813         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 814                 d |= (i == WEP_HOOK);
 815         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 816                 d = 0;
 817
 818         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 819
 820         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 821
 822         // bit order in t:
 823         // 1: want or not
 824         // 2: is default?
 825         // 4: is set by default?
 826         if(t < 0)
 827                 t = 4 | (3 * d);
 828         else
 829                 t |= (2 * d);
 830
 831         return t;
 832 }
 833
 834 void readplayerstartcvars()
 835 {
 836         entity e;
 837         float i, j, t;
 838         string s;
 839
 840         // initialize starting values for players
 841         WEPSET_CLEAR_A(start_weapons);
 842         WEPSET_CLEAR_A(start_weapons_default);
 843         WEPSET_CLEAR_A(start_weapons_defaultmask);
 844         start_items = 0;
 845         start_ammo_shells = 0;
 846         start_ammo_nails = 0;
 847         start_ammo_rockets = 0;
 848         start_ammo_cells = 0;
 849         start_health = cvar("g_balance_health_start");
 850         start_armorvalue = cvar("g_balance_armor_start");
 851
 852         g_weaponarena = 0;
 853         WEPSET_CLEAR_A(g_weaponarena_weapons);
 854
 855         s = cvar_string("g_weaponarena");
 856         if (s == "0" || s == "")
 857         {
 858                 if(g_lms || g_ca)
 859                         s = "most";
 860         }
 861
 862         if (s == "0" || s == "")
 863         {
 864                 // no arena
 865         }
 866         else if (s == "off")
 867         {
 868                 // forcibly turn off weaponarena
 869         }
 870         else if (s == "all")
 871         {
 872                 g_weaponarena = 1;
 873                 g_weaponarena_list = "All Weapons";
 874                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 875                 {
 876                         e = get_weaponinfo(j);
 877                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 878                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 879                 }
 880         }
 881         else if (s == "most")
 882         {
 883                 g_weaponarena = 1;
 884                 g_weaponarena_list = "Most Weapons";
 885                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 886                 {
 887                         e = get_weaponinfo(j);
 888                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 889                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 890                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 891                 }
 892         }
 893         else if (s == "none")
 894         {
 895                 g_weaponarena = 1;
 896                 g_weaponarena_list = "No Weapons";
 897         }
 898         else
 899         {
 900                 g_weaponarena = 1;
 901                 t = tokenize_console(s);
 902                 g_weaponarena_list = "";
 903                 for (i = 0; i < t; ++i)
 904                 {
 905                         s = argv(i);
 906                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 907                         {
 908                                 e = get_weaponinfo(j);
 909                                 if (e.netname == s)
 910                                 {
 911                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 912                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 913                                         break;
 914                                 }
 915                         }
 916                         if (j > WEP_LAST)
 917                         {
 918                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 919                         }
 920                 }
 921                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 922         }
 923
 924         if(g_weaponarena)
 925                 g_weaponarena_random = cvar("g_weaponarena_random");
 926         else
 927                 g_weaponarena_random = 0;
 928         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 929
 930         if (g_weaponarena)
 931         {
 932                 g_minstagib = 0; // incompatible
 933                 g_pinata = 0; // incompatible
 934                 g_weapon_stay = 0; // incompatible
 935                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 936                 if(!(g_lms || g_ca))
 937                         start_items |= IT_UNLIMITED_AMMO;
 938         }
 939         else
 940         {
 941                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 942                 {
 943                         e = get_weaponinfo(i);
 944                         float w = want_weapon("g_start_weapon_", e, FALSE);
 945                         if(w & 1)
 946                                 WEPSET_OR_AW(start_weapons, i);
 947                         if(w & 2)
 948                                 WEPSET_OR_AW(start_weapons_default, i);
 949                         if(w & 4)
 950                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 951                 }
 952         }
 953
 954         if(!cvar("g_use_ammunition"))
 955                 start_items |= IT_UNLIMITED_AMMO;
 956
 957         if(cvar("g_nexball"))
 958                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 959
 960         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 961         {
 962                 start_ammo_rockets = 999;
 963                 start_ammo_shells = 999;
 964                 start_ammo_cells = 999;
 965                 start_ammo_nails = 999;
 966                 start_ammo_fuel = 999;
 967         }
 968         else
 969         {
 970                 if(g_lms || g_ca)
 971                 {
 972                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 973                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 974                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 975                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 976                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 977                 }
 978                 else
 979                 {
 980                         start_ammo_shells = cvar("g_start_ammo_shells");
 981                         start_ammo_nails = cvar("g_start_ammo_nails");
 982                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 983                         start_ammo_cells = cvar("g_start_ammo_cells");
 984                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 985                 }
 986         }
 987
 988         if (g_lms || g_ca)
 989         {
 990                 start_health = cvar("g_lms_start_health");
 991                 start_armorvalue = cvar("g_lms_start_armor");
 992         }
 993
 994         if (inWarmupStage)
 995         {
 996                 warmup_start_ammo_shells = start_ammo_shells;
 997                 warmup_start_ammo_nails = start_ammo_nails;
 998                 warmup_start_ammo_rockets = start_ammo_rockets;
 999                 warmup_start_ammo_cells = start_ammo_cells;
1000                 warmup_start_ammo_fuel = start_ammo_fuel;
1001                 warmup_start_health = start_health;
1002                 warmup_start_armorvalue = start_armorvalue;
1003                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
1004                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
1005                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
1006
1007                 if (!g_weaponarena && !g_minstagib && !g_ca)
1008                 {
1009                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1010                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1011                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1012                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1013                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1014                         warmup_start_health = cvar("g_warmup_start_health");
1015                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1016                         WEPSET_CLEAR_A(warmup_start_weapons);
1017                         WEPSET_CLEAR_A(warmup_start_weapons_default);
1018                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
1019                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1020                         {
1021                                 e = get_weaponinfo(i);
1022                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
1023                                 if(w & 1)
1024                                         WEPSET_OR_AW(warmup_start_weapons, i);
1025                                 if(w & 2)
1026                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
1027                                 if(w & 4)
1028                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
1029                         }
1030                 }
1031         }
1032
1033         if (g_jetpack)
1034                 start_items |= IT_JETPACK;
1035
1036         MUTATOR_CALLHOOK(SetStartItems);
1037
1038         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
1039         {
1040                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1041                 start_items |= IT_FUEL_REGEN;
1042                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1043                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1044         }
1045
1046         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1047         {
1048                 e = get_weaponinfo(i);
1049                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
1050                         weapon_action(i, WR_PRECACHE);
1051         }
1052
1053         start_ammo_shells = max(0, start_ammo_shells);
1054         start_ammo_nails = max(0, start_ammo_nails);
1055         start_ammo_cells = max(0, start_ammo_cells);
1056         start_ammo_rockets = max(0, start_ammo_rockets);
1057         start_ammo_fuel = max(0, start_ammo_fuel);
1058
1059         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1060         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1061         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1062         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1063         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1064 }
1065
1066 float g_bugrigs;
1067 float g_bugrigs_planar_movement;
1068 float g_bugrigs_planar_movement_car_jumping;
1069 float g_bugrigs_reverse_spinning;
1070 float g_bugrigs_reverse_speeding;
1071 float g_bugrigs_reverse_stopping;
1072 float g_bugrigs_air_steering;
1073 float g_bugrigs_angle_smoothing;
1074 float g_bugrigs_friction_floor;
1075 float g_bugrigs_friction_brake;
1076 float g_bugrigs_friction_air;
1077 float g_bugrigs_accel;
1078 float g_bugrigs_speed_ref;
1079 float g_bugrigs_speed_pow;
1080 float g_bugrigs_steer;
1081
1082 float g_touchexplode;
1083 float g_touchexplode_radius;
1084 float g_touchexplode_damage;
1085 float g_touchexplode_edgedamage;
1086 float g_touchexplode_force;
1087
1088 float sv_autotaunt;
1089 float sv_taunt;
1090
1091 float sv_pitch_min;
1092 float sv_pitch_max;
1093 float sv_pitch_fixyaw;
1094
1095 string GetGametype(); // g_world.qc
1096 void readlevelcvars(void)
1097 {
1098         g_minstagib = cvar("g_minstagib");
1099
1100         // load ALL the mutators
1101         if(cvar("g_dodging"))
1102                 MUTATOR_ADD(mutator_dodging);
1103         if(cvar("g_spawn_near_teammate"))
1104                 MUTATOR_ADD(mutator_spawn_near_teammate);
1105         if(cvar("g_minstagib"))
1106                 MUTATOR_ADD(mutator_minstagib);
1107
1108         if(!g_minstagib)
1109         {
1110                 if(cvar("g_invincible_projectiles"))
1111                         MUTATOR_ADD(mutator_invincibleprojectiles);
1112                 if(cvar("g_new_toys"))
1113                         MUTATOR_ADD(mutator_new_toys);
1114                 if(cvar("g_nix"))
1115                         MUTATOR_ADD(mutator_nix);
1116                 if(cvar("g_rocket_flying"))
1117                         MUTATOR_ADD(mutator_rocketflying);
1118                 if(cvar("g_vampire"))
1119                         MUTATOR_ADD(mutator_vampire);
1120                 if(cvar("g_superspectate"))
1121                         MUTATOR_ADD(mutator_superspec);
1122         }
1123
1124         // is this a mutator? is this a mode?
1125         if(cvar("g_sandbox"))
1126                 MUTATOR_ADD(sandbox);
1127
1128         if(cvar("sv_allow_fullbright"))
1129                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1130
1131     g_bugrigs = cvar("g_bugrigs");
1132     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1133     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1134     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1135     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1136     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1137     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1138     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1139     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1140     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1141     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1142     g_bugrigs_accel = cvar("g_bugrigs_accel");
1143     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1144     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1145     g_bugrigs_steer = cvar("g_bugrigs_steer");
1146
1147     g_touchexplode = cvar("g_touchexplode");
1148     g_touchexplode_radius = cvar("g_touchexplode_radius");
1149     g_touchexplode_damage = cvar("g_touchexplode_damage");
1150     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1151     g_touchexplode_force = cvar("g_touchexplode_force");
1152
1153 #ifdef ALLOW_FORCEMODELS
1154         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1155 #endif
1156
1157         sv_clones = cvar("sv_clones");
1158         sv_gentle = cvar("sv_gentle");
1159         sv_foginterval = cvar("sv_foginterval");
1160         g_cloaked = cvar("g_cloaked");
1161     if(g_cts)
1162         g_cloaked = 1; // always enable cloak in CTS
1163         g_jump_grunt = cvar("g_jump_grunt");
1164         g_footsteps = cvar("g_footsteps");
1165         g_grappling_hook = cvar("g_grappling_hook");
1166         g_jetpack = cvar("g_jetpack");
1167         g_midair = cvar("g_midair");
1168         g_norecoil = cvar("g_norecoil");
1169         g_bloodloss = cvar("g_bloodloss");
1170         sv_maxidle = cvar("sv_maxidle");
1171         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1172         sv_autotaunt = cvar("sv_autotaunt");
1173         sv_taunt = cvar("sv_taunt");
1174
1175         inWarmupStage = cvar("g_warmup");
1176         g_warmup_limit = cvar("g_warmup_limit");
1177         g_warmup_allguns = cvar("g_warmup_allguns");
1178         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1179
1180         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1181                 inWarmupStage = 0; // these modes cannot work together, sorry
1182
1183         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1184         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1185         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1186         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1187         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1188         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1189         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1190         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1191         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1192         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1193         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1194         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1195         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1196         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1197
1198         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1199         g_weaponratefactor = cvar("g_weaponratefactor");
1200         g_weapondamagefactor = cvar("g_weapondamagefactor");
1201         g_weaponforcefactor = cvar("g_weaponforcefactor");
1202         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1203
1204         g_pickup_shells = cvar("g_pickup_shells");
1205         g_pickup_shells_max = cvar("g_pickup_shells_max");
1206         g_pickup_nails = cvar("g_pickup_nails");
1207         g_pickup_nails_max = cvar("g_pickup_nails_max");
1208         g_pickup_rockets = cvar("g_pickup_rockets");
1209         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1210         g_pickup_cells = cvar("g_pickup_cells");
1211         g_pickup_cells_max = cvar("g_pickup_cells_max");
1212         g_pickup_fuel = cvar("g_pickup_fuel");
1213         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1214         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1215         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1216         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1217         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1218         g_pickup_armormedium = cvar("g_pickup_armormedium");
1219         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1220         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1221         g_pickup_armorbig = cvar("g_pickup_armorbig");
1222         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1223         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1224         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1225         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1226         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1227         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1228         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1229         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1230         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1231         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1232         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1233         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1234         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1235         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1236         g_pickup_healthmega = cvar("g_pickup_healthmega");
1237         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1238         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1239
1240         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1241         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1242
1243         g_pinata = cvar("g_pinata");
1244
1245     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1246     if(!g_weapon_stay)
1247         g_weapon_stay = cvar("g_weapon_stay");
1248
1249         if not(inWarmupStage && !g_ca)
1250                 game_starttime = cvar("g_start_delay");
1251
1252         sv_pitch_min = cvar("sv_pitch_min");
1253         sv_pitch_max = cvar("sv_pitch_max");
1254         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1255
1256         readplayerstartcvars();
1257 }
1258
1259 //#NO AUTOCVARS END
1260
1261 // Sound functions
1262 string precache_sound (string s) = #19;
1263 float precache_sound_index (string s) = #19;
1264
1265 #define SND_VOLUME      1
1266 #define SND_ATTENUATION 2
1267 #define SND_LARGEENTITY 8
1268 #define SND_LARGESOUND  16
1269
1270 float sound_allowed(float dest, entity e)
1271 {
1272     // sounds from world may always pass
1273     for (;;)
1274     {
1275         if (e.classname == "body")
1276             e = e.enemy;
1277         else if (e.realowner && e.realowner != e)
1278             e = e.realowner;
1279         else if (e.owner && e.owner != e)
1280             e = e.owner;
1281         else
1282             break;
1283     }
1284     // sounds to self may always pass
1285     if (dest == MSG_ONE)
1286         if (e == msg_entity)
1287             return TRUE;
1288     // sounds by players can be removed
1289     if (autocvar_bot_sound_monopoly)
1290         if (clienttype(e) == CLIENTTYPE_REAL)
1291             return FALSE;
1292     // anything else may pass
1293     return TRUE;
1294 }
1295
1296 #ifdef COMPAT_XON010_CHANNELS
1297 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1298 void sound(entity e, float chan, string samp, float vol, float atten)
1299 {
1300     if (!sound_allowed(MSG_BROADCAST, e))
1301         return;
1302     builtin_sound(e, chan, samp, vol, atten);
1303 }
1304 #else
1305 #undef sound
1306 void sound(entity e, float chan, string samp, float vol, float atten)
1307 {
1308     if (!sound_allowed(MSG_BROADCAST, e))
1309         return;
1310     sound7(e, chan, samp, vol, atten, 0, 0);
1311 }
1312 #endif
1313
1314 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1315 {
1316     float entno, idx;
1317
1318     if (!sound_allowed(dest, e))
1319         return;
1320
1321     entno = num_for_edict(e);
1322     idx = precache_sound_index(samp);
1323
1324     float sflags;
1325     sflags = 0;
1326
1327     atten = floor(atten * 64);
1328     vol = floor(vol * 255);
1329
1330     if (vol != 255)
1331         sflags |= SND_VOLUME;
1332     if (atten != 64)
1333         sflags |= SND_ATTENUATION;
1334     if (entno >= 8192 || chan < 0 || chan > 7)
1335         sflags |= SND_LARGEENTITY;
1336     if (idx >= 256)
1337         sflags |= SND_LARGESOUND;
1338
1339     WriteByte(dest, SVC_SOUND);
1340     WriteByte(dest, sflags);
1341     if (sflags & SND_VOLUME)
1342         WriteByte(dest, vol);
1343     if (sflags & SND_ATTENUATION)
1344         WriteByte(dest, atten);
1345     if (sflags & SND_LARGEENTITY)
1346     {
1347         WriteShort(dest, entno);
1348         WriteByte(dest, chan);
1349     }
1350     else
1351     {
1352         WriteShort(dest, entno * 8 + chan);
1353     }
1354     if (sflags & SND_LARGESOUND)
1355         WriteShort(dest, idx);
1356     else
1357         WriteByte(dest, idx);
1358
1359     WriteCoord(dest, o_x);
1360     WriteCoord(dest, o_y);
1361     WriteCoord(dest, o_z);
1362 }
1363 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1364 {
1365     vector o;
1366
1367     if (!sound_allowed(dest, e))
1368         return;
1369
1370     o = e.origin + 0.5 * (e.mins + e.maxs);
1371     soundtoat(dest, e, o, chan, samp, vol, atten);
1372 }
1373 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1374 {
1375     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1376 }
1377 void stopsoundto(float dest, entity e, float chan)
1378 {
1379     float entno;
1380
1381     if (!sound_allowed(dest, e))
1382         return;
1383
1384     entno = num_for_edict(e);
1385
1386     if (entno >= 8192 || chan < 0 || chan > 7)
1387     {
1388         float idx, sflags;
1389         idx = precache_sound_index("misc/null.wav");
1390         sflags = SND_LARGEENTITY;
1391         if (idx >= 256)
1392             sflags |= SND_LARGESOUND;
1393         WriteByte(dest, SVC_SOUND);
1394         WriteByte(dest, sflags);
1395         WriteShort(dest, entno);
1396         WriteByte(dest, chan);
1397         if (sflags & SND_LARGESOUND)
1398             WriteShort(dest, idx);
1399         else
1400             WriteByte(dest, idx);
1401         WriteCoord(dest, e.origin_x);
1402         WriteCoord(dest, e.origin_y);
1403         WriteCoord(dest, e.origin_z);
1404     }
1405     else
1406     {
1407         WriteByte(dest, SVC_STOPSOUND);
1408         WriteShort(dest, entno * 8 + chan);
1409     }
1410 }
1411 void stopsound(entity e, float chan)
1412 {
1413     if (!sound_allowed(MSG_BROADCAST, e))
1414         return;
1415
1416     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1417     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1418 }
1419
1420 void play2(entity e, string filename)
1421 {
1422     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1423     msg_entity = e;
1424     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1425 }
1426
1427 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1428 .float spamtime;
1429 float spamsound(entity e, float chan, string samp, float vol, float atten)
1430 {
1431     if (!sound_allowed(MSG_BROADCAST, e))
1432         return FALSE;
1433
1434     if (time > e.spamtime)
1435     {
1436         e.spamtime = time;
1437         sound(e, chan, samp, vol, atten);
1438         return TRUE;
1439     }
1440     return FALSE;
1441 }
1442
1443 void play2team(float t, string filename)
1444 {
1445     entity head;
1446
1447     if (autocvar_bot_sound_monopoly)
1448         return;
1449
1450     FOR_EACH_REALPLAYER(head)
1451     {
1452         if (head.team == t)
1453             play2(head, filename);
1454     }
1455 }
1456
1457 void play2all(string samp)
1458 {
1459     if (autocvar_bot_sound_monopoly)
1460         return;
1461
1462     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1463 }
1464
1465 void PrecachePlayerSounds(string f);
1466 void precache_playermodel(string m)
1467 {
1468         float globhandle, i, n;
1469         string f;
1470
1471         if(substring(m, -9,5) == "_lod1")
1472                 return;
1473         if(substring(m, -9,5) == "_lod2")
1474                 return;
1475         precache_model(m);
1476         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1477         if(fexists(f))
1478                 precache_model(f);
1479         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1480         if(fexists(f))
1481                 precache_model(f);
1482
1483         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1484         if (globhandle < 0)
1485                 return;
1486         n = search_getsize(globhandle);
1487         for (i = 0; i < n; ++i)
1488         {
1489                 //print(search_getfilename(globhandle, i), "\n");
1490                 f = search_getfilename(globhandle, i);
1491                 PrecachePlayerSounds(f);
1492         }
1493         search_end(globhandle);
1494 }
1495 void precache_all_playermodels(string pattern)
1496 {
1497         float globhandle, i, n;
1498         string f;
1499
1500         globhandle = search_begin(pattern, TRUE, FALSE);
1501         if (globhandle < 0)
1502                 return;
1503         n = search_getsize(globhandle);
1504         for (i = 0; i < n; ++i)
1505         {
1506                 //print(search_getfilename(globhandle, i), "\n");
1507                 f = search_getfilename(globhandle, i);
1508                 precache_playermodel(f);
1509         }
1510         search_end(globhandle);
1511 }
1512
1513 void precache()
1514 {
1515     // gamemode related things
1516     precache_model ("models/misc/chatbubble.spr");
1517     if (g_runematch)
1518     {
1519         precache_model ("models/runematch/curse.mdl");
1520         precache_model ("models/runematch/rune.mdl");
1521     }
1522
1523 #ifdef TTURRETS_ENABLED
1524     if (autocvar_g_turrets)
1525         turrets_precash();
1526 #endif
1527
1528     // Precache all player models if desired
1529     if (autocvar_sv_precacheplayermodels)
1530     {
1531         PrecachePlayerSounds("sound/player/default.sounds");
1532         precache_all_playermodels("models/player/*.zym");
1533         precache_all_playermodels("models/player/*.dpm");
1534         precache_all_playermodels("models/player/*.md3");
1535         precache_all_playermodels("models/player/*.psk");
1536         precache_all_playermodels("models/player/*.iqm");
1537     }
1538
1539     if (autocvar_sv_defaultcharacter)
1540     {
1541         string s;
1542         s = autocvar_sv_defaultplayermodel_red;
1543         if (s != "")
1544             precache_playermodel(s);
1545         s = autocvar_sv_defaultplayermodel_blue;
1546         if (s != "")
1547             precache_playermodel(s);
1548         s = autocvar_sv_defaultplayermodel_yellow;
1549         if (s != "")
1550             precache_playermodel(s);
1551         s = autocvar_sv_defaultplayermodel_pink;
1552         if (s != "")
1553             precache_playermodel(s);
1554         s = autocvar_sv_defaultplayermodel;
1555         if (s != "")
1556             precache_playermodel(s);
1557     }
1558
1559     if (g_footsteps)
1560     {
1561         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1562         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1563     }
1564
1565     // gore and miscellaneous sounds
1566     //precache_sound ("misc/h2ohit.wav");
1567     precache_model ("models/hook.md3");
1568     precache_sound ("misc/armorimpact.wav");
1569     precache_sound ("misc/bodyimpact1.wav");
1570     precache_sound ("misc/bodyimpact2.wav");
1571     precache_sound ("misc/gib.wav");
1572     precache_sound ("misc/gib_splat01.wav");
1573     precache_sound ("misc/gib_splat02.wav");
1574     precache_sound ("misc/gib_splat03.wav");
1575     precache_sound ("misc/gib_splat04.wav");
1576     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1577     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1578     precache_sound ("misc/null.wav");
1579     precache_sound ("misc/spawn.wav");
1580     precache_sound ("misc/talk.wav");
1581     precache_sound ("misc/teleport.wav");
1582     precache_sound ("misc/poweroff.wav");
1583     precache_sound ("player/lava.wav");
1584     precache_sound ("player/slime.wav");
1585
1586     if (g_jetpack)
1587         precache_sound ("misc/jetpack_fly.wav");
1588
1589     precache_model ("models/sprites/0.spr32");
1590     precache_model ("models/sprites/1.spr32");
1591     precache_model ("models/sprites/2.spr32");
1592     precache_model ("models/sprites/3.spr32");
1593     precache_model ("models/sprites/4.spr32");
1594     precache_model ("models/sprites/5.spr32");
1595     precache_model ("models/sprites/6.spr32");
1596     precache_model ("models/sprites/7.spr32");
1597     precache_model ("models/sprites/8.spr32");
1598     precache_model ("models/sprites/9.spr32");
1599     precache_model ("models/sprites/10.spr32");
1600
1601     // common weapon precaches
1602         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1603     precache_sound ("weapons/weapon_switch.wav");
1604     precache_sound ("weapons/weaponpickup.wav");
1605     precache_sound ("weapons/unavailable.wav");
1606     precache_sound ("weapons/dryfire.wav");
1607     if (g_grappling_hook)
1608     {
1609         precache_sound ("weapons/hook_fire.wav"); // hook
1610         precache_sound ("weapons/hook_impact.wav"); // hook
1611     }
1612
1613     if(autocvar_sv_precacheweapons)
1614     {
1615         //precache weapon models/sounds
1616         float wep;
1617         wep = WEP_FIRST;
1618         while (wep <= WEP_LAST)
1619         {
1620             weapon_action(wep, WR_PRECACHE);
1621             wep = wep + 1;
1622         }
1623     }
1624
1625     precache_model("models/elaser.mdl");
1626     precache_model("models/laser.mdl");
1627     precache_model("models/ebomb.mdl");
1628
1629 #if 0
1630     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1631
1632     if (!self.noise && self.music) // quake 3 uses the music field
1633         self.noise = self.music;
1634
1635     // plays music for the level if there is any
1636     if (self.noise)
1637     {
1638         precache_sound (self.noise);
1639         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1640     }
1641 #endif
1642 }
1643
1644 // sorry, but using \ in macros breaks line numbers
1645 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1646 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1647 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1648
1649
1650 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1651 {
1652         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1653         {
1654                 msg_entity = e;
1655                 WRITESPECTATABLE_MSG_ONE({
1656                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1657                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1658                         WriteByte(MSG_ONE, id);
1659                         WriteString(MSG_ONE, s);
1660                         if (id != 0 && s != "")
1661                         {
1662                                 WriteByte(MSG_ONE, duration);
1663                                 WriteByte(MSG_ONE, countdown_num);
1664                         }
1665                 });
1666         }
1667 }
1668 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1669 {
1670         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1671 }
1672 // WARNING: this kills the trace globals
1673 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1674 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1675
1676 #define INITPRIO_FIRST              0
1677 #define INITPRIO_GAMETYPE           0
1678 #define INITPRIO_GAMETYPE_FALLBACK  1
1679 #define INITPRIO_FINDTARGET        10
1680 #define INITPRIO_DROPTOFLOOR       20
1681 #define INITPRIO_SETLOCATION       90
1682 #define INITPRIO_LINKDOORS         91
1683 #define INITPRIO_LAST              99
1684
1685 .void(void) initialize_entity;
1686 .float initialize_entity_order;
1687 .entity initialize_entity_next;
1688 entity initialize_entity_first;
1689
1690 void make_safe_for_remove(entity e)
1691 {
1692     if (e.initialize_entity)
1693     {
1694         entity ent, prev = world;
1695         for (ent = initialize_entity_first; ent; )
1696         {
1697             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1698             {
1699                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1700                 // skip it in linked list
1701                 if (prev)
1702                 {
1703                     prev.initialize_entity_next = ent.initialize_entity_next;
1704                     ent = prev.initialize_entity_next;
1705                 }
1706                 else
1707                 {
1708                     initialize_entity_first = ent.initialize_entity_next;
1709                     ent = initialize_entity_first;
1710                 }
1711             }
1712             else
1713             {
1714                 prev = ent;
1715                 ent = ent.initialize_entity_next;
1716             }
1717         }
1718     }
1719 }
1720
1721 void objerror(string s)
1722 {
1723     make_safe_for_remove(self);
1724     builtin_objerror(s);
1725 }
1726
1727 .float remove_except_protected_forbidden;
1728 void remove_except_protected(entity e)
1729 {
1730         if(e.remove_except_protected_forbidden)
1731                 error("not allowed to remove this at this point");
1732         builtin_remove(e);
1733 }
1734
1735 void remove_unsafely(entity e)
1736 {
1737     if(e.classname == "spike")
1738         error("Removing spikes is forbidden (crylink bug), please report");
1739     builtin_remove(e);
1740 }
1741
1742 void remove_safely(entity e)
1743 {
1744     make_safe_for_remove(e);
1745     builtin_remove(e);
1746 }
1747
1748 void InitializeEntity(entity e, void(void) func, float order)
1749 {
1750     entity prev, cur;
1751
1752     if (!e || e.initialize_entity)
1753     {
1754         // make a proxy initializer entity
1755         entity e_old;
1756         e_old = e;
1757         e = spawn();
1758         e.classname = "initialize_entity";
1759         e.enemy = e_old;
1760     }
1761
1762     e.initialize_entity = func;
1763     e.initialize_entity_order = order;
1764
1765     cur = initialize_entity_first;
1766     prev = world;
1767     for (;;)
1768     {
1769         if (!cur || cur.initialize_entity_order > order)
1770         {
1771             // insert between prev and cur
1772             if (prev)
1773                 prev.initialize_entity_next = e;
1774             else
1775                 initialize_entity_first = e;
1776             e.initialize_entity_next = cur;
1777             return;
1778         }
1779         prev = cur;
1780         cur = cur.initialize_entity_next;
1781     }
1782 }
1783 void InitializeEntitiesRun()
1784 {
1785     entity startoflist;
1786     startoflist = initialize_entity_first;
1787     initialize_entity_first = world;
1788     remove = remove_except_protected;
1789     for (self = startoflist; self; self = self.initialize_entity_next)
1790     {
1791         self.remove_except_protected_forbidden = 1;
1792     }
1793     for (self = startoflist; self; )
1794     {
1795         entity e;
1796         var void(void) func;
1797         e = self.initialize_entity_next;
1798         func = self.initialize_entity;
1799         self.initialize_entity_order = 0;
1800         self.initialize_entity = func_null;
1801         self.initialize_entity_next = world;
1802         self.remove_except_protected_forbidden = 0;
1803         if (self.classname == "initialize_entity")
1804         {
1805             entity e_old;
1806             e_old = self.enemy;
1807             builtin_remove(self);
1808             self = e_old;
1809         }
1810         //dprint("Delayed initialization: ", self.classname, "\n");
1811         if(func != func_null)
1812             func();
1813         else
1814         {
1815             eprint(self);
1816             backtrace(strcat("Null function in: ", self.classname, "\n"));
1817         }
1818         self = e;
1819     }
1820     remove = remove_unsafely;
1821 }
1822
1823 .float uncustomizeentityforclient_set;
1824 .void(void) uncustomizeentityforclient;
1825 void(void) SUB_Nullpointer = #0;
1826 void UncustomizeEntitiesRun()
1827 {
1828     entity oldself;
1829     oldself = self;
1830     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1831         self.uncustomizeentityforclient();
1832     self = oldself;
1833 }
1834 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1835 {
1836     e.customizeentityforclient = customizer;
1837     e.uncustomizeentityforclient = uncustomizer;
1838     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1839 }
1840
1841 .float nottargeted;
1842 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1843
1844 void() SUB_Remove;
1845 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1846 {
1847     vector mi, ma;
1848
1849     if (e.classname == "")
1850         e.classname = "net_linked";
1851
1852     if (e.model == "" || self.modelindex == 0)
1853     {
1854         mi = e.mins;
1855         ma = e.maxs;
1856         setmodel(e, "null");
1857         setsize(e, mi, ma);
1858     }
1859
1860     e.SendEntity = sendfunc;
1861     e.SendFlags = 0xFFFFFF;
1862
1863     if (!docull)
1864         e.effects |= EF_NODEPTHTEST;
1865
1866     if (dt)
1867     {
1868         e.nextthink = time + dt;
1869         e.think = SUB_Remove;
1870     }
1871 }
1872
1873 void adaptor_think2touch()
1874 {
1875     entity o;
1876     o = other;
1877     other = world;
1878     self.touch();
1879     other = o;
1880 }
1881
1882 void adaptor_think2use()
1883 {
1884     entity o, a;
1885     o = other;
1886     a = activator;
1887     activator = world;
1888     other = world;
1889     self.use();
1890     other = o;
1891     activator = a;
1892 }
1893
1894 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1895 {
1896         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1897                 self.projectiledeathtype |= HITTYPE_SPLASH;
1898         adaptor_think2use();
1899 }
1900
1901 // deferred dropping
1902 void DropToFloor_Handler()
1903 {
1904     builtin_droptofloor();
1905     self.dropped_origin = self.origin;
1906 }
1907
1908 void droptofloor()
1909 {
1910     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1911 }
1912
1913
1914
1915 float trace_hits_box_a0, trace_hits_box_a1;
1916
1917 float trace_hits_box_1d(float end, float thmi, float thma)
1918 {
1919     if (end == 0)
1920     {
1921         // just check if x is in range
1922         if (0 < thmi)
1923             return FALSE;
1924         if (0 > thma)
1925             return FALSE;
1926     }
1927     else
1928     {
1929         // do the trace with respect to x
1930         // 0 -> end has to stay in thmi -> thma
1931         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1932         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1933         if (trace_hits_box_a0 > trace_hits_box_a1)
1934             return FALSE;
1935     }
1936     return TRUE;
1937 }
1938
1939 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1940 {
1941     end -= start;
1942     thmi -= start;
1943     thma -= start;
1944     // now it is a trace from 0 to end
1945
1946     trace_hits_box_a0 = 0;
1947     trace_hits_box_a1 = 1;
1948
1949     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1950         return FALSE;
1951     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1952         return FALSE;
1953     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1954         return FALSE;
1955
1956     return TRUE;
1957 }
1958
1959 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1960 {
1961     return trace_hits_box(start, end, thmi - ma, thma - mi);
1962 }
1963
1964 float SUB_NoImpactCheck()
1965 {
1966         // zero hitcontents = this is not the real impact, but either the
1967         // mirror-impact of something hitting the projectile instead of the
1968         // projectile hitting the something, or a touchareagrid one. Neither of
1969         // these stop the projectile from moving, so...
1970         if(trace_dphitcontents == 0)
1971         {
1972                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1973                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1974                 checkclient();
1975         }
1976     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1977         return 1;
1978     if (other == world && self.size != '0 0 0')
1979     {
1980         vector tic;
1981         tic = self.velocity * sys_frametime;
1982         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1983         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1984         if (trace_fraction >= 1)
1985         {
1986             dprint("Odd... did not hit...?\n");
1987         }
1988         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1989         {
1990             dprint("Detected and prevented the sky-grapple bug.\n");
1991             return 1;
1992         }
1993     }
1994
1995     return 0;
1996 }
1997
1998 #define SUB_OwnerCheck() (other && (other == self.owner))
1999
2000 void RemoveGrapplingHook(entity pl);
2001 void W_Crylink_Dequeue(entity e);
2002 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2003 {
2004         if(SUB_OwnerCheck())
2005                 return TRUE;
2006         if(SUB_NoImpactCheck())
2007         {
2008                 if(self.classname == "grapplinghook")
2009                         RemoveGrapplingHook(self.realowner);
2010                 else if(self.classname == "spike")
2011                 {
2012                         W_Crylink_Dequeue(self);
2013                         remove(self);
2014                 }
2015                 else
2016                         remove(self);
2017                 return TRUE;
2018         }
2019         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2020                 UpdateCSQCProjectile(self);
2021         return FALSE;
2022 }
2023 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2024
2025 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
2026 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
2027
2028 void URI_Get_Callback(float id, float status, string data)
2029 {
2030         if(url_URI_Get_Callback(id, status, data))
2031         {
2032                 // handled
2033         }
2034         else if (id == URI_GET_DISCARD)
2035         {
2036                 // discard
2037         }
2038         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
2039         {
2040                 // sv_cmd curl
2041                 Curl_URI_Get_Callback(id, status, data);
2042         }
2043         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2044         {
2045                 // online ban list
2046                 OnlineBanList_URI_Get_Callback(id, status, data);
2047         }
2048         else
2049         {
2050                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2051         }
2052 }
2053
2054 string uid2name(string myuid) {
2055         string s;
2056         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2057
2058         // FIXME remove this later after 0.6 release
2059         // convert old style broken records to correct style
2060         if(s == "")
2061         {
2062                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2063                 if(s != "")
2064                 {
2065                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2066                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2067                 }
2068         }
2069
2070         if(s == "")
2071                 s = "^1Unregistered Player";
2072         return s;
2073 }
2074
2075 float race_readTime(string map, float pos)
2076 {
2077         string rr;
2078         if(g_cts)
2079                 rr = CTS_RECORD;
2080         else
2081                 rr = RACE_RECORD;
2082
2083         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2084 }
2085
2086 string race_readUID(string map, float pos)
2087 {
2088         string rr;
2089         if(g_cts)
2090                 rr = CTS_RECORD;
2091         else
2092                 rr = RACE_RECORD;
2093
2094         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2095 }
2096
2097 float race_readPos(string map, float t) {
2098         float i;
2099         for (i = 1; i <= RANKINGS_CNT; ++i)
2100                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2101                         return i;
2102
2103         return 0; // pos is zero if unranked
2104 }
2105
2106 void race_writeTime(string map, float t, string myuid)
2107 {
2108         string rr;
2109         if(g_cts)
2110                 rr = CTS_RECORD;
2111         else
2112                 rr = RACE_RECORD;
2113
2114         float newpos;
2115         newpos = race_readPos(map, t);
2116
2117         float i, prevpos = 0;
2118         for(i = 1; i <= RANKINGS_CNT; ++i)
2119         {
2120                 if(race_readUID(map, i) == myuid)
2121                         prevpos = i;
2122         }
2123         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2124                 for (i = prevpos; i > newpos; --i) {
2125                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2126                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2127                 }
2128         } else { // player has no ranked record yet
2129                 for (i = RANKINGS_CNT; i > newpos; --i) {
2130                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2131                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2132                 }
2133         }
2134
2135         // store new time itself
2136         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2137         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2138 }
2139
2140 string race_readName(string map, float pos)
2141 {
2142         string rr;
2143         if(g_cts)
2144                 rr = CTS_RECORD;
2145         else
2146                 rr = RACE_RECORD;
2147
2148         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2149 }
2150
2151 string race_placeName(float pos) {
2152         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2153         {
2154                 if(mod(pos, 10) == 1)
2155                         return strcat(ftos(pos), "st");
2156                 else if(mod(pos, 10) == 2)
2157                         return strcat(ftos(pos), "nd");
2158                 else if(mod(pos, 10) == 3)
2159                         return strcat(ftos(pos), "rd");
2160                 else
2161                         return strcat(ftos(pos), "th");
2162         }
2163         else
2164                 return strcat(ftos(pos), "th");
2165 }
2166
2167 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2168 {
2169     float m, i;
2170     vector start, org, delta, end, enddown, mstart;
2171     entity sp;
2172
2173     m = e.dphitcontentsmask;
2174     e.dphitcontentsmask = goodcontents | badcontents;
2175
2176     org = world.mins;
2177     delta = world.maxs - world.mins;
2178
2179     start = end = org;
2180
2181     for (i = 0; i < attempts; ++i)
2182     {
2183         start_x = org_x + random() * delta_x;
2184         start_y = org_y + random() * delta_y;
2185         start_z = org_z + random() * delta_z;
2186
2187         // rule 1: start inside world bounds, and outside
2188         // solid, and don't start from somewhere where you can
2189         // fall down to evil
2190         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2191         if (trace_fraction >= 1)
2192             continue;
2193         if (trace_startsolid)
2194             continue;
2195         if (trace_dphitcontents & badcontents)
2196             continue;
2197         if (trace_dphitq3surfaceflags & badsurfaceflags)
2198             continue;
2199
2200         // rule 2: if we are too high, lower the point
2201         if (trace_fraction * delta_z > maxaboveground)
2202             start = trace_endpos + '0 0 1' * maxaboveground;
2203         enddown = trace_endpos;
2204
2205         // rule 3: make sure we aren't outside the map. This only works
2206         // for somewhat well formed maps. A good rule of thumb is that
2207         // the map should have a convex outside hull.
2208         // these can be traceLINES as we already verified the starting box
2209         mstart = start + 0.5 * (e.mins + e.maxs);
2210         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2211         if (trace_fraction >= 1)
2212             continue;
2213         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2214         if (trace_fraction >= 1)
2215             continue;
2216         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2217         if (trace_fraction >= 1)
2218             continue;
2219         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2220         if (trace_fraction >= 1)
2221             continue;
2222         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2223         if (trace_fraction >= 1)
2224             continue;
2225
2226         // rule 4: we must "see" some spawnpoint
2227         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2228                 if(checkpvs(mstart, sp))
2229                         break;
2230         if(!sp)
2231         {
2232                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2233                         if(checkpvs(mstart, sp))
2234                                 break;
2235                 if(!sp)
2236                         continue;
2237         }
2238
2239         // find a random vector to "look at"
2240         end_x = org_x + random() * delta_x;
2241         end_y = org_y + random() * delta_y;
2242         end_z = org_z + random() * delta_z;
2243         end = start + normalize(end - start) * vlen(delta);
2244
2245         // rule 4: start TO end must not be too short
2246         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2247         if (trace_startsolid)
2248             continue;
2249         if (trace_fraction < minviewdistance / vlen(delta))
2250             continue;
2251
2252         // rule 5: don't want to look at sky
2253         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2254             continue;
2255
2256         // rule 6: we must not end up in trigger_hurt
2257         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2258             continue;
2259
2260         break;
2261     }
2262
2263     e.dphitcontentsmask = m;
2264
2265     if (i < attempts)
2266     {
2267         setorigin(e, start);
2268         e.angles = vectoangles(end - start);
2269         dprint("Needed ", ftos(i + 1), " attempts\n");
2270         return TRUE;
2271     }
2272     else
2273         return FALSE;
2274 }
2275
2276 float zcurveparticles_effectno;
2277 vector zcurveparticles_start;
2278 float zcurveparticles_spd;
2279
2280 void endzcurveparticles()
2281 {
2282         if(zcurveparticles_effectno)
2283         {
2284                 // terminator
2285                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2286         }
2287         zcurveparticles_effectno = 0;
2288 }
2289
2290 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2291 {
2292         spd = bound(0, floor(spd / 16), 32767);
2293         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2294         {
2295                 endzcurveparticles();
2296                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2297                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2298                 WriteShort(MSG_BROADCAST, effectno);
2299                 WriteCoord(MSG_BROADCAST, start_x);
2300                 WriteCoord(MSG_BROADCAST, start_y);
2301                 WriteCoord(MSG_BROADCAST, start_z);
2302                 zcurveparticles_effectno = effectno;
2303                 zcurveparticles_start = start;
2304         }
2305         else
2306                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2307         WriteCoord(MSG_BROADCAST, end_x);
2308         WriteCoord(MSG_BROADCAST, end_y);
2309         WriteCoord(MSG_BROADCAST, end_z);
2310         WriteCoord(MSG_BROADCAST, end_dz);
2311         zcurveparticles_spd = spd;
2312 }
2313
2314 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2315 {
2316         float end_dz;
2317         vector vecxy, velxy;
2318
2319         vecxy = end - start;
2320         vecxy_z = 0;
2321         velxy = vel;
2322         velxy_z = 0;
2323
2324         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2325         {
2326                 endzcurveparticles();
2327                 trailparticles(world, effectno, start, end);
2328                 return;
2329         }
2330
2331         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2332         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2333 }
2334
2335 void write_recordmarker(entity pl, float tstart, float dt)
2336 {
2337     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2338
2339     // also write a marker into demo files for demotc-race-record-extractor to find
2340     stuffcmd(pl,
2341              strcat(
2342                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2343                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2344 }
2345
2346 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2347 {
2348         switch(algn)
2349         {
2350                 default:
2351                 case 3: // right
2352                         break;
2353
2354                 case 4: // left
2355                         vecs_y = -vecs_y;
2356                         break;
2357
2358                 case 1:
2359                         if(allowcenter) // 2: allow center handedness
2360                         {
2361                                 // center
2362                                 vecs_y = 0;
2363                                 vecs_z -= 2;
2364                         }
2365                         else
2366                         {
2367                                 // right
2368                         }
2369                         break;
2370
2371                 case 2:
2372                         if(allowcenter) // 2: allow center handedness
2373                         {
2374                                 // center
2375                                 vecs_y = 0;
2376                                 vecs_z -= 2;
2377                         }
2378                         else
2379                         {
2380                                 // left
2381                                 vecs_y = -vecs_y;
2382                         }
2383                         break;
2384         }
2385         return vecs;
2386 }
2387
2388 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2389 {
2390         string s;
2391         vector v;
2392
2393         if (autocvar_g_shootfromeye)
2394         {
2395                 if (visual)
2396                 {
2397                         vecs_y = 0;
2398                         vecs_z -= 2;
2399                 }
2400                 else
2401                 {
2402                         vecs_y = 0;
2403                         vecs_z = 0;
2404                 }
2405         }
2406         else if (autocvar_g_shootfromcenter)
2407         {
2408                 vecs_y = 0;
2409                 vecs_z -= 2;
2410         }
2411         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2412         {
2413                 v = stov(s);
2414                 if (y_is_right)
2415                         v_y = -v_y;
2416                 if (v_x != 0)
2417                         vecs_x = v_x;
2418                 vecs_y = v_y;
2419                 vecs_z = v_z;
2420         }
2421         else if (autocvar_g_shootfromclient)
2422         {
2423                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2424         }
2425         return vecs;
2426 }
2427
2428 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2429 {
2430         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2431 }
2432
2433
2434 void attach_sameorigin(entity e, entity to, string tag)
2435 {
2436     vector org, t_forward, t_left, t_up, e_forward, e_up;
2437     float tagscale;
2438
2439     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2440     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2441     t_forward = v_forward * tagscale;
2442     t_left = v_right * -tagscale;
2443     t_up = v_up * tagscale;
2444
2445     e.origin_x = org * t_forward;
2446     e.origin_y = org * t_left;
2447     e.origin_z = org * t_up;
2448
2449     // current forward and up directions
2450     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2451                 e.angles = AnglesTransform_FromVAngles(e.angles);
2452         else
2453                 e.angles = AnglesTransform_FromAngles(e.angles);
2454     fixedmakevectors(e.angles);
2455
2456     // untransform forward, up!
2457     e_forward_x = v_forward * t_forward;
2458     e_forward_y = v_forward * t_left;
2459     e_forward_z = v_forward * t_up;
2460     e_up_x = v_up * t_forward;
2461     e_up_y = v_up * t_left;
2462     e_up_z = v_up * t_up;
2463
2464     e.angles = fixedvectoangles2(e_forward, e_up);
2465     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2466                 e.angles = AnglesTransform_ToVAngles(e.angles);
2467         else
2468                 e.angles = AnglesTransform_ToAngles(e.angles);
2469
2470     setattachment(e, to, tag);
2471     setorigin(e, e.origin);
2472 }
2473
2474 void detach_sameorigin(entity e)
2475 {
2476     vector org;
2477     org = gettaginfo(e, 0);
2478     e.angles = fixedvectoangles2(v_forward, v_up);
2479     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2480                 e.angles = AnglesTransform_ToVAngles(e.angles);
2481         else
2482                 e.angles = AnglesTransform_ToAngles(e.angles);
2483     setorigin(e, org);
2484     setattachment(e, world, "");
2485     setorigin(e, e.origin);
2486 }
2487
2488 void follow_sameorigin(entity e, entity to)
2489 {
2490     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2491     e.aiment = to; // make the hole follow bmodel
2492     e.punchangle = to.angles; // the original angles of bmodel
2493     e.view_ofs = e.origin - to.origin; // relative origin
2494     e.v_angle = e.angles - to.angles; // relative angles
2495 }
2496
2497 void unfollow_sameorigin(entity e)
2498 {
2499     e.movetype = MOVETYPE_NONE;
2500 }
2501
2502 entity gettaginfo_relative_ent;
2503 vector gettaginfo_relative(entity e, float tag)
2504 {
2505     if (!gettaginfo_relative_ent)
2506     {
2507         gettaginfo_relative_ent = spawn();
2508         gettaginfo_relative_ent.effects = EF_NODRAW;
2509     }
2510     gettaginfo_relative_ent.model = e.model;
2511     gettaginfo_relative_ent.modelindex = e.modelindex;
2512     gettaginfo_relative_ent.frame = e.frame;
2513     return gettaginfo(gettaginfo_relative_ent, tag);
2514 }
2515
2516 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2517 {
2518     float p;
2519     p = pow(2, chan);
2520     if (pl.soundentity.cnt & p)
2521         return;
2522     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2523     pl.soundentity.cnt |= p;
2524 }
2525
2526 void SoundEntity_StopSound(entity pl, float chan)
2527 {
2528     float p;
2529     p = pow(2, chan);
2530     if (pl.soundentity.cnt & p)
2531     {
2532         stopsoundto(MSG_ALL, pl.soundentity, chan);
2533         pl.soundentity.cnt &~= p;
2534     }
2535 }
2536
2537 void SoundEntity_Attach(entity pl)
2538 {
2539     pl.soundentity = spawn();
2540     pl.soundentity.classname = "soundentity";
2541     pl.soundentity.owner = pl;
2542     setattachment(pl.soundentity, pl, "");
2543     setmodel(pl.soundentity, "null");
2544 }
2545
2546 void SoundEntity_Detach(entity pl)
2547 {
2548     float i;
2549     for (i = 0; i <= 7; ++i)
2550         SoundEntity_StopSound(pl, i);
2551 }
2552
2553 .float scale2;
2554
2555 float modeleffect_SendEntity(entity to, float sf)
2556 {
2557         float f;
2558         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2559
2560         f = 0;
2561         if(self.velocity != '0 0 0')
2562                 f |= 1;
2563         if(self.angles != '0 0 0')
2564                 f |= 2;
2565         if(self.avelocity != '0 0 0')
2566                 f |= 4;
2567
2568         WriteByte(MSG_ENTITY, f);
2569         WriteShort(MSG_ENTITY, self.modelindex);
2570         WriteByte(MSG_ENTITY, self.skin);
2571         WriteByte(MSG_ENTITY, self.frame);
2572         WriteCoord(MSG_ENTITY, self.origin_x);
2573         WriteCoord(MSG_ENTITY, self.origin_y);
2574         WriteCoord(MSG_ENTITY, self.origin_z);
2575         if(f & 1)
2576         {
2577                 WriteCoord(MSG_ENTITY, self.velocity_x);
2578                 WriteCoord(MSG_ENTITY, self.velocity_y);
2579                 WriteCoord(MSG_ENTITY, self.velocity_z);
2580         }
2581         if(f & 2)
2582         {
2583                 WriteCoord(MSG_ENTITY, self.angles_x);
2584                 WriteCoord(MSG_ENTITY, self.angles_y);
2585                 WriteCoord(MSG_ENTITY, self.angles_z);
2586         }
2587         if(f & 4)
2588         {
2589                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2590                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2591                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2592         }
2593         WriteShort(MSG_ENTITY, self.scale * 256.0);
2594         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2595         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2596         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2597         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2598
2599         return TRUE;
2600 }
2601
2602 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2603 {
2604         entity e;
2605         float sz;
2606         e = spawn();
2607         e.classname = "modeleffect";
2608         setmodel(e, m);
2609         e.frame = f;
2610         setorigin(e, o);
2611         e.velocity = v;
2612         e.angles = ang;
2613         e.avelocity = angv;
2614         e.alpha = a;
2615         e.teleport_time = t1;
2616         e.fade_time = t2;
2617         e.skin = s;
2618         if(s0 >= 0)
2619                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2620         else
2621                 e.scale = -s0;
2622         if(s2 >= 0)
2623                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2624         else
2625                 e.scale2 = -s2;
2626         sz = max(e.scale, e.scale2);
2627         setsize(e, e.mins * sz, e.maxs * sz);
2628         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2629 }
2630
2631 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2632 {
2633         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2634 }
2635
2636 float randombit(float bits)
2637 {
2638         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2639                 return bits;
2640
2641         float n, f, b, r;
2642
2643         r = random();
2644         b = 0;
2645         n = 0;
2646
2647         for(f = 1; f <= bits; f *= 2)
2648         {
2649                 if(bits & f)
2650                 {
2651                         ++n;
2652                         r *= n;
2653                         if(r <= 1)
2654                                 b = f;
2655                         else
2656                                 r = (r - 1) / (n - 1);
2657                 }
2658         }
2659
2660         return b;
2661 }
2662
2663 float randombits(float bits, float k, float error_return)
2664 {
2665         float r;
2666         r = 0;
2667         while(k > 0 && bits != r)
2668         {
2669                 r += randombit(bits - r);
2670                 --k;
2671         }
2672         if(error_return)
2673                 if(k > 0)
2674                         return -1; // all
2675         return r;
2676 }
2677
2678 void randombit_test(float bits, float iter)
2679 {
2680         while(iter > 0)
2681         {
2682                 print(ftos(randombit(bits)), "\n");
2683                 --iter;
2684         }
2685 }
2686
2687 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2688 {
2689         if(halflifedist > 0)
2690                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2691         else if(halflifedist < 0)
2692                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2693         else
2694                 return 1;
2695 }
2696
2697
2698
2699
2700 #ifdef RELEASE
2701 #define cvar_string_normal builtin_cvar_string
2702 #define cvar_normal builtin_cvar
2703 #else
2704 string cvar_string_normal(string n)
2705 {
2706         if not(cvar_type(n) & 1)
2707                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2708         return builtin_cvar_string(n);
2709 }
2710
2711 float cvar_normal(string n)
2712 {
2713         return stof(cvar_string_normal(n));
2714 }
2715 #endif
2716 #define cvar_set_normal builtin_cvar_set
2717
2718 void defer_think()
2719 {
2720     entity oself;
2721
2722     oself           = self;
2723     self            = self.owner;
2724     oself.think     = SUB_Remove;
2725     oself.nextthink = time;
2726
2727     oself.use();
2728 }
2729
2730 /*
2731     Execute func() after time + fdelay.
2732     self when func is executed = self when defer is called
2733 */
2734 void defer(float fdelay, void() func)
2735 {
2736     entity e;
2737
2738     e           = spawn();
2739     e.owner     = self;
2740     e.use       = func;
2741     e.think     = defer_think;
2742     e.nextthink = time + fdelay;
2743 }
2744
2745 .string aiment_classname;
2746 .float aiment_deadflag;
2747 void SetMovetypeFollow(entity ent, entity e)
2748 {
2749         // FIXME this may not be warpzone aware
2750         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2751         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2752         ent.aiment = e; // make the hole follow bmodel
2753         ent.punchangle = e.angles; // the original angles of bmodel
2754         ent.view_ofs = ent.origin - e.origin; // relative origin
2755         ent.v_angle = ent.angles - e.angles; // relative angles
2756         ent.aiment_classname = strzone(e.classname);
2757         ent.aiment_deadflag = e.deadflag;
2758 }
2759 void UnsetMovetypeFollow(entity ent)
2760 {
2761         ent.movetype = MOVETYPE_FLY;
2762         PROJECTILE_MAKETRIGGER(ent);
2763         ent.aiment = world;
2764 }
2765 float LostMovetypeFollow(entity ent)
2766 {
2767 /*
2768         if(ent.movetype != MOVETYPE_FOLLOW)
2769                 if(ent.aiment)
2770                         error("???");
2771 */
2772         if(ent.aiment)
2773         {
2774                 if(ent.aiment.classname != ent.aiment_classname)
2775                         return 1;
2776                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2777                         return 1;
2778         }
2779         return 0;
2780 }
2781
2782 float isPushable(entity e)
2783 {
2784         if(e.iscreature)
2785                 return TRUE;
2786         if(e.pushable)
2787                 return TRUE;
2788         switch(e.classname)
2789         {
2790                 case "body":
2791                 case "droppedweapon":
2792                 case "keepawayball":
2793                 case "nexball_basketball":
2794                 case "nexball_football":
2795                         return TRUE;
2796                 case "bullet": // antilagged bullets can't hit this either
2797                         return FALSE;
2798         }
2799         if (e.projectiledeathtype)
2800                 return TRUE;
2801         return FALSE;
2802 }