qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 422
 423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 424
 425 /**
 426  * @param f -1: cleanup, 0: request, 1: receive
 427  */
 428 void GetCvars(entity this, entity store, int f)
 429 {
 430         string s = string_null;
 431
 432         if (f == 0)
 433                 LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
 434
 435         if (f > 0)
 436                 s = strcat1(argv(f));
 437
 438         get_cvars_f = f;
 439         get_cvars_s = s;
 440         MUTATOR_CALLHOOK(GetCvars);
 441
 442         Notification_GetCvars(this);
 443
 444         ReplicateVars(this, store, s, f);
 445
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 454         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 455         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 456         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 457
 458         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 459
 460         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 461         if (f > 0)
 462         {
 463                 if (s == "cl_weaponpriority")
 464                 {
 465                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 466                         {
 467                                 .entity weaponentity = weaponentities[slot];
 468                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 469                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 470                         }
 471                 }
 472                 if (s == "cl_allow_uidtracking")
 473                         PlayerStats_GameReport_AddPlayer(this);
 474         }
 475 }
 476
 477 // decolorizes and team colors the player name when needed
 478 string playername(entity p, bool team_colorize)
 479 {
 480     string t;
 481     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 482     {
 483         t = Team_ColorCode(p.team);
 484         return strcat(t, strdecolorize(p.netname));
 485     }
 486     else
 487         return p.netname;
 488 }
 489
 490 float want_weapon(entity weaponinfo, float allguns)
 491 {
 492         int d = 0;
 493         bool allow_mutatorblocked = false;
 494
 495         if(!weaponinfo.m_id)
 496                 return 0;
 497
 498         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 499         d = M_ARGV(1, float);
 500         allguns = M_ARGV(2, bool);
 501         allow_mutatorblocked = M_ARGV(3, bool);
 502
 503         if(allguns)
 504                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
 505         else if(!mutator_returnvalue)
 506                 d = !(!weaponinfo.weaponstart);
 507
 508         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 509                 d = 0;
 510
 511         float t = weaponinfo.weaponstartoverride;
 512
 513         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
 514
 515         // bit order in t:
 516         // 1: want or not
 517         // 2: is default?
 518         // 4: is set by default?
 519         if(t < 0)
 520                 t = 4 | (3 * d);
 521         else
 522                 t |= (2 * d);
 523
 524         return t;
 525 }
 526
 527 /// Weapons the player normally starts with outside weapon arena.
 528 WepSet weapons_start()
 529 {
 530         WepSet ret = '0 0 0';
 531         FOREACH(Weapons, it != WEP_Null, {
 532                 int w = want_weapon(it, false);
 533                 if (w & 1)
 534                         ret |= it.m_wepset;
 535         });
 536         return ret;
 537 }
 538
 539 WepSet weapons_all()
 540 {
 541         WepSet ret = '0 0 0';
 542         FOREACH(Weapons, it != WEP_Null, {
 543                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
 544                         ret |= it.m_wepset;
 545         });
 546         return ret;
 547 }
 548
 549 WepSet weapons_devall()
 550 {
 551         WepSet ret = '0 0 0';
 552         FOREACH(Weapons, it != WEP_Null,
 553         {
 554                 ret |= it.m_wepset;
 555         });
 556         return ret;
 557 }
 558
 559 WepSet weapons_most()
 560 {
 561         WepSet ret = '0 0 0';
 562         FOREACH(Weapons, it != WEP_Null, {
 563                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
 564                         ret |= it.m_wepset;
 565         });
 566         return ret;
 567 }
 568
 569 void weaponarena_available_all_update(entity this)
 570 {
 571         if (weaponsInMapAll)
 572         {
 573                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
 574         }
 575         else
 576         {
 577                 // if no weapons are available on the map, just fall back to all weapons arena
 578                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
 579         }
 580 }
 581
 582 void weaponarena_available_devall_update(entity this)
 583 {
 584         if (weaponsInMapAll)
 585         {
 586                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
 587         }
 588         else
 589         {
 590                 // if no weapons are available on the map, just fall back to devall weapons arena
 591                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
 592         }
 593 }
 594
 595 void weaponarena_available_most_update(entity this)
 596 {
 597         if (weaponsInMapAll)
 598         {
 599                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
 600         }
 601         else
 602         {
 603                 // if no weapons are available on the map, just fall back to most weapons arena
 604                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
 605         }
 606 }
 607
 608 void readplayerstartcvars()
 609 {
 610         float i, t;
 611
 612         // initialize starting values for players
 613         start_weapons = '0 0 0';
 614         start_weapons_default = '0 0 0';
 615         start_weapons_defaultmask = '0 0 0';
 616         start_items = 0;
 617         start_ammo_shells = 0;
 618         start_ammo_nails = 0;
 619         start_ammo_rockets = 0;
 620         start_ammo_cells = 0;
 621         start_ammo_plasma = 0;
 622         if (random_start_ammo == NULL)
 623         {
 624                 random_start_ammo = spawn();
 625         }
 626         start_health = cvar("g_balance_health_start");
 627         start_armorvalue = cvar("g_balance_armor_start");
 628
 629         g_weaponarena = 0;
 630         g_weaponarena_weapons = '0 0 0';
 631
 632         string s = cvar_string("g_weaponarena");
 633
 634         MUTATOR_CALLHOOK(SetWeaponArena, s);
 635         s = M_ARGV(0, string);
 636
 637         if (s == "0" || s == "")
 638         {
 639                 // no arena
 640         }
 641         else if (s == "off")
 642         {
 643                 // forcibly turn off weaponarena
 644         }
 645         else if (s == "all" || s == "1")
 646         {
 647                 g_weaponarena = 1;
 648                 g_weaponarena_list = "All Weapons";
 649                 g_weaponarena_weapons = weapons_all();
 650         }
 651         else if (s == "devall")
 652         {
 653                 g_weaponarena = 1;
 654                 g_weaponarena_list = "Dev All Weapons";
 655                 g_weaponarena_weapons = weapons_devall();
 656         }
 657         else if (s == "most")
 658         {
 659                 g_weaponarena = 1;
 660                 g_weaponarena_list = "Most Weapons";
 661                 g_weaponarena_weapons = weapons_most();
 662         }
 663         else if (s == "all_available")
 664         {
 665                 g_weaponarena = 1;
 666                 g_weaponarena_list = "All Available Weapons";
 667
 668                 // this needs to run after weaponsInMapAll is initialized
 669                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
 670         }
 671         else if (s == "devall_available")
 672         {
 673                 g_weaponarena = 1;
 674                 g_weaponarena_list = "Dev All Available Weapons";
 675
 676                 // this needs to run after weaponsInMapAll is initialized
 677                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
 678         }
 679         else if (s == "most_available")
 680         {
 681                 g_weaponarena = 1;
 682                 g_weaponarena_list = "Most Available Weapons";
 683
 684                 // this needs to run after weaponsInMapAll is initialized
 685                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
 686         }
 687         else if (s == "none")
 688         {
 689                 g_weaponarena = 1;
 690                 g_weaponarena_list = "No Weapons";
 691         }
 692         else
 693         {
 694                 g_weaponarena = 1;
 695                 t = tokenize_console(s);
 696                 g_weaponarena_list = "";
 697                 for (i = 0; i < t; ++i)
 698                 {
 699                         s = argv(i);
 700                         Weapon wep = Weapons_fromstr(s);
 701                         if(wep != WEP_Null)
 702                         {
 703                                 g_weaponarena_weapons |= (wep.m_wepset);
 704                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 705                         }
 706                 }
 707                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 708         }
 709
 710         if (g_weaponarena)
 711         {
 712                 g_weapon_stay = 0; // incompatible
 713                 start_weapons = g_weaponarena_weapons;
 714                 start_items |= IT_UNLIMITED_AMMO;
 715         }
 716         else
 717         {
 718                 FOREACH(Weapons, it != WEP_Null, {
 719                         int w = want_weapon(it, false);
 720                         WepSet s = it.m_wepset;
 721                         if(w & 1)
 722                                 start_weapons |= s;
 723                         if(w & 2)
 724                                 start_weapons_default |= s;
 725                         if(w & 4)
 726                                 start_weapons_defaultmask |= s;
 727                 });
 728         }
 729
 730         if(cvar("g_balance_superweapons_time") < 0)
 731                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 732
 733         if(!cvar("g_use_ammunition"))
 734                 start_items |= IT_UNLIMITED_AMMO;
 735
 736         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 737         {
 738                 start_ammo_shells = 999;
 739                 start_ammo_nails = 999;
 740                 start_ammo_rockets = 999;
 741                 start_ammo_cells = 999;
 742                 start_ammo_plasma = 999;
 743                 start_ammo_fuel = 999;
 744         }
 745         else
 746         {
 747                 start_ammo_shells = cvar("g_start_ammo_shells");
 748                 start_ammo_nails = cvar("g_start_ammo_nails");
 749                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 750                 start_ammo_cells = cvar("g_start_ammo_cells");
 751                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 752                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 753                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 754                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
 755                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
 756                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
 757                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
 758                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
 759         }
 760
 761         warmup_start_ammo_shells = start_ammo_shells;
 762         warmup_start_ammo_nails = start_ammo_nails;
 763         warmup_start_ammo_rockets = start_ammo_rockets;
 764         warmup_start_ammo_cells = start_ammo_cells;
 765         warmup_start_ammo_plasma = start_ammo_plasma;
 766         warmup_start_ammo_fuel = start_ammo_fuel;
 767         warmup_start_health = start_health;
 768         warmup_start_armorvalue = start_armorvalue;
 769         warmup_start_weapons = start_weapons;
 770         warmup_start_weapons_default = start_weapons_default;
 771         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 772
 773         if (!g_weaponarena)
 774         {
 775                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 776                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 777                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 778                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 779                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 780                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 781                 warmup_start_health = cvar("g_warmup_start_health");
 782                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
 783                 warmup_start_weapons = '0 0 0';
 784                 warmup_start_weapons_default = '0 0 0';
 785                 warmup_start_weapons_defaultmask = '0 0 0';
 786                 FOREACH(Weapons, it != WEP_Null, {
 787                         int w = want_weapon(it, g_warmup_allguns);
 788                         WepSet s = it.m_wepset;
 789                         if(w & 1)
 790                                 warmup_start_weapons |= s;
 791                         if(w & 2)
 792                                 warmup_start_weapons_default |= s;
 793                         if(w & 4)
 794                                 warmup_start_weapons_defaultmask |= s;
 795                 });
 796         }
 797
 798         if (g_jetpack)
 799                 start_items |= ITEM_Jetpack.m_itemid;
 800
 801         MUTATOR_CALLHOOK(SetStartItems);
 802
 803         if (start_items & ITEM_Jetpack.m_itemid)
 804         {
 805                 start_items |= ITEM_JetpackRegen.m_itemid;
 806                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 807                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 808         }
 809
 810         start_ammo_shells = max(0, start_ammo_shells);
 811         start_ammo_nails = max(0, start_ammo_nails);
 812         start_ammo_rockets = max(0, start_ammo_rockets);
 813         start_ammo_cells = max(0, start_ammo_cells);
 814         start_ammo_plasma = max(0, start_ammo_plasma);
 815         start_ammo_fuel = max(0, start_ammo_fuel);
 816         SetResource(random_start_ammo, RES_SHELLS,
 817                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
 818         SetResource(random_start_ammo, RES_BULLETS,
 819                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
 820         SetResource(random_start_ammo, RES_ROCKETS,
 821                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
 822         SetResource(random_start_ammo, RES_CELLS,
 823                 max(0, GetResource(random_start_ammo, RES_CELLS)));
 824         SetResource(random_start_ammo, RES_PLASMA,
 825                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
 826
 827         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 828         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 829         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 830         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 831         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 832         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 833 }
 834
 835 void precache_playermodel(string m)
 836 {
 837         float globhandle, i, n;
 838         string f;
 839
 840         if(substring(m, -9, 5) == "_lod1")
 841                 return;
 842         if(substring(m, -9, 5) == "_lod2")
 843                 return;
 844         precache_model(m);
 845         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 846         if(fexists(f))
 847                 precache_model(f);
 848         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 849         if(fexists(f))
 850                 precache_model(f);
 851
 852         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 853         if (globhandle < 0)
 854                 return;
 855         n = search_getsize(globhandle);
 856         for (i = 0; i < n; ++i)
 857         {
 858                 //print(search_getfilename(globhandle, i), "\n");
 859                 f = search_getfilename(globhandle, i);
 860                 PrecachePlayerSounds(f);
 861         }
 862         search_end(globhandle);
 863 }
 864 void precache_all_playermodels(string pattern)
 865 {
 866         int globhandle = search_begin(pattern, true, false);
 867         if (globhandle < 0) return;
 868         int n = search_getsize(globhandle);
 869         for (int i = 0; i < n; ++i)
 870         {
 871                 string s = search_getfilename(globhandle, i);
 872                 precache_playermodel(s);
 873         }
 874         search_end(globhandle);
 875 }
 876
 877 void precache_playermodels(string s)
 878 {
 879         FOREACH_WORD(s, true, { precache_playermodel(it); });
 880 }
 881
 882 void precache()
 883 {
 884     // gamemode related things
 885
 886     // Precache all player models if desired
 887     if (autocvar_sv_precacheplayermodels)
 888     {
 889         PrecachePlayerSounds("sound/player/default.sounds");
 890         precache_all_playermodels("models/player/*.zym");
 891         precache_all_playermodels("models/player/*.dpm");
 892         precache_all_playermodels("models/player/*.md3");
 893         precache_all_playermodels("models/player/*.psk");
 894         precache_all_playermodels("models/player/*.iqm");
 895     }
 896
 897     if (autocvar_sv_defaultcharacter)
 898     {
 899                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 900                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 901                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 902                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 903                 precache_playermodels(autocvar_sv_defaultplayermodel);
 904     }
 905
 906 #if 0
 907     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 908
 909     if (!this.noise && this.music) // quake 3 uses the music field
 910         this.noise = this.music;
 911
 912     // plays music for the level if there is any
 913     if (this.noise)
 914     {
 915         precache_sound (this.noise);
 916         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 917     }
 918 #endif
 919 }
 920
 921
 922 void make_safe_for_remove(entity e)
 923 {
 924     if (e.initialize_entity)
 925     {
 926         entity ent, prev = NULL;
 927         for (ent = initialize_entity_first; ent; )
 928         {
 929             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 930             {
 931                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 932                 // skip it in linked list
 933                 if (prev)
 934                 {
 935                     prev.initialize_entity_next = ent.initialize_entity_next;
 936                     ent = prev.initialize_entity_next;
 937                 }
 938                 else
 939                 {
 940                     initialize_entity_first = ent.initialize_entity_next;
 941                     ent = initialize_entity_first;
 942                 }
 943             }
 944             else
 945             {
 946                 prev = ent;
 947                 ent = ent.initialize_entity_next;
 948             }
 949         }
 950     }
 951 }
 952
 953 .float remove_except_protected_forbidden;
 954 void remove_except_protected(entity e)
 955 {
 956         if(e.remove_except_protected_forbidden)
 957                 error("not allowed to remove this at this point");
 958         builtin_remove(e);
 959 }
 960
 961 void remove_unsafely(entity e)
 962 {
 963     if(e.classname == "spike")
 964         error("Removing spikes is forbidden (crylink bug), please report");
 965     builtin_remove(e);
 966 }
 967
 968 void remove_safely(entity e)
 969 {
 970     make_safe_for_remove(e);
 971     builtin_remove(e);
 972 }
 973
 974 void InitializeEntity(entity e, void(entity this) func, int order)
 975 {
 976     entity prev, cur;
 977
 978     if (!e || e.initialize_entity)
 979     {
 980         // make a proxy initializer entity
 981         entity e_old = e;
 982         e = new(initialize_entity);
 983         e.enemy = e_old;
 984     }
 985
 986     e.initialize_entity = func;
 987     e.initialize_entity_order = order;
 988
 989     cur = initialize_entity_first;
 990     prev = NULL;
 991     for (;;)
 992     {
 993         if (!cur || cur.initialize_entity_order > order)
 994         {
 995             // insert between prev and cur
 996             if (prev)
 997                 prev.initialize_entity_next = e;
 998             else
 999                 initialize_entity_first = e;
1000             e.initialize_entity_next = cur;
1001             return;
1002         }
1003         prev = cur;
1004         cur = cur.initialize_entity_next;
1005     }
1006 }
1007 void InitializeEntitiesRun()
1008 {
1009     entity startoflist = initialize_entity_first;
1010     initialize_entity_first = NULL;
1011     delete_fn = remove_except_protected;
1012     for (entity e = startoflist; e; e = e.initialize_entity_next)
1013     {
1014                 e.remove_except_protected_forbidden = 1;
1015     }
1016     for (entity e = startoflist; e; )
1017     {
1018                 e.remove_except_protected_forbidden = 0;
1019         e.initialize_entity_order = 0;
1020         entity next = e.initialize_entity_next;
1021         e.initialize_entity_next = NULL;
1022         var void(entity this) func = e.initialize_entity;
1023         e.initialize_entity = func_null;
1024         if (e.classname == "initialize_entity")
1025         {
1026             entity wrappee = e.enemy;
1027             builtin_remove(e);
1028             e = wrappee;
1029         }
1030         //dprint("Delayed initialization: ", e.classname, "\n");
1031         if (func)
1032         {
1033                 func(e);
1034         }
1035         else
1036         {
1037             eprint(e);
1038             backtrace(strcat("Null function in: ", e.classname, "\n"));
1039         }
1040         e = next;
1041     }
1042     delete_fn = remove_unsafely;
1043 }
1044
1045 .float(entity) isEliminated;
1046 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1047 {
1048         Stream out = MSG_ENTITY;
1049         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1050         serialize(byte, out, sendflags);
1051         if (sendflags & 1) {
1052                 for (int i = 1; i <= maxclients; i += 8) {
1053                         int f = 0;
1054                         entity e = edict_num(i);
1055                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1056                                 if (eliminatedPlayers.isEliminated(e)) {
1057                                         f |= BIT(b);
1058                                 }
1059                         }
1060                         serialize(byte, out, f);
1061                 }
1062         }
1063         return true;
1064 }
1065
1066 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1067 {
1068         if(eliminatedPlayers)
1069         {
1070                 backtrace("Can't spawn eliminatedPlayers again!");
1071                 return;
1072         }
1073         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1074         eliminatedPlayers.isEliminated = isEliminated_func;
1075 }
1076
1077
1078
1079
1080 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1081 {
1082         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1083                 this.projectiledeathtype |= HITTYPE_SPLASH;
1084         adaptor_think2use(this);
1085 }
1086
1087 // deferred dropping
1088 void DropToFloor_Handler(entity this)
1089 {
1090     WITHSELF(this, builtin_droptofloor());
1091     this.dropped_origin = this.origin;
1092 }
1093
1094 void droptofloor(entity this)
1095 {
1096     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1097 }
1098
1099
1100
1101 float trace_hits_box_a0, trace_hits_box_a1;
1102
1103 float trace_hits_box_1d(float end, float thmi, float thma)
1104 {
1105     if (end == 0)
1106     {
1107         // just check if x is in range
1108         if (0 < thmi)
1109             return false;
1110         if (0 > thma)
1111             return false;
1112     }
1113     else
1114     {
1115         // do the trace with respect to x
1116         // 0 -> end has to stay in thmi -> thma
1117         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1118         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1119         if (trace_hits_box_a0 > trace_hits_box_a1)
1120             return false;
1121     }
1122     return true;
1123 }
1124
1125 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1126 {
1127     end -= start;
1128     thmi -= start;
1129     thma -= start;
1130     // now it is a trace from 0 to end
1131
1132     trace_hits_box_a0 = 0;
1133     trace_hits_box_a1 = 1;
1134
1135     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1136         return false;
1137     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1138         return false;
1139     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1140         return false;
1141
1142     return true;
1143 }
1144
1145 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1146 {
1147     return trace_hits_box(start, end, thmi - ma, thma - mi);
1148 }
1149
1150 bool SUB_NoImpactCheck(entity this, entity toucher)
1151 {
1152         // zero hitcontents = this is not the real impact, but either the
1153         // mirror-impact of something hitting the projectile instead of the
1154         // projectile hitting the something, or a touchareagrid one. Neither of
1155         // these stop the projectile from moving, so...
1156         if(trace_dphitcontents == 0)
1157         {
1158                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1159                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1160         }
1161     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1162         return true;
1163     if (toucher == NULL && this.size != '0 0 0')
1164     {
1165         vector tic;
1166         tic = this.velocity * sys_frametime;
1167         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1168         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1169         if (trace_fraction >= 1)
1170         {
1171             LOG_TRACE("Odd... did not hit...?");
1172         }
1173         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1174         {
1175             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1176             return true;
1177         }
1178     }
1179
1180     return false;
1181 }
1182
1183 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1184
1185 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1186 {
1187         if(SUB_OwnerCheck(this, toucher))
1188                 return true;
1189         if(SUB_NoImpactCheck(this, toucher))
1190         {
1191                 if(this.classname == "nade")
1192                         return false; // no checks here
1193                 else if(this.classname == "grapplinghook")
1194                         RemoveHook(this);
1195                 else if(this.classname == "spike")
1196                 {
1197                         W_Crylink_Dequeue(this);
1198                         delete(this);
1199                 }
1200                 else
1201                         delete(this);
1202                 return true;
1203         }
1204         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1205                 UpdateCSQCProjectile(this);
1206         return false;
1207 }
1208
1209 /** engine callback */
1210 void URI_Get_Callback(float id, float status, string data)
1211 {
1212         if(url_URI_Get_Callback(id, status, data))
1213         {
1214                 // handled
1215         }
1216         else if (id == URI_GET_DISCARD)
1217         {
1218                 // discard
1219         }
1220         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1221         {
1222                 // sv_cmd curl
1223                 Curl_URI_Get_Callback(id, status, data);
1224         }
1225         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1226         {
1227                 // online ban list
1228                 OnlineBanList_URI_Get_Callback(id, status, data);
1229         }
1230         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1231         {
1232                 // handled by a mutator
1233         }
1234         else
1235         {
1236                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1237         }
1238 }
1239
1240 string uid2name(string myuid) {
1241         string s;
1242         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1243
1244         // FIXME remove this later after 0.6 release
1245         // convert old style broken records to correct style
1246         if(s == "")
1247         {
1248                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1249                 if(s != "")
1250                 {
1251                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1252                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1253                 }
1254         }
1255
1256         if(s == "")
1257                 s = "^1Unregistered Player";
1258         return s;
1259 }
1260
1261 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1262 {
1263     float m, i;
1264     vector start, org, delta, end, enddown, mstart;
1265
1266     m = e.dphitcontentsmask;
1267     e.dphitcontentsmask = goodcontents | badcontents;
1268
1269     org = boundmin;
1270     delta = boundmax - boundmin;
1271
1272     start = end = org;
1273
1274     for (i = 0; i < attempts; ++i)
1275     {
1276         start.x = org.x + random() * delta.x;
1277         start.y = org.y + random() * delta.y;
1278         start.z = org.z + random() * delta.z;
1279
1280         // rule 1: start inside world bounds, and outside
1281         // solid, and don't start from somewhere where you can
1282         // fall down to evil
1283         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1284         if (trace_fraction >= 1)
1285             continue;
1286         if (trace_startsolid)
1287             continue;
1288         if (trace_dphitcontents & badcontents)
1289             continue;
1290         if (trace_dphitq3surfaceflags & badsurfaceflags)
1291             continue;
1292
1293         // rule 2: if we are too high, lower the point
1294         if (trace_fraction * delta.z > maxaboveground)
1295             start = trace_endpos + '0 0 1' * maxaboveground;
1296         enddown = trace_endpos;
1297
1298         // rule 3: make sure we aren't outside the map. This only works
1299         // for somewhat well formed maps. A good rule of thumb is that
1300         // the map should have a convex outside hull.
1301         // these can be traceLINES as we already verified the starting box
1302         mstart = start + 0.5 * (e.mins + e.maxs);
1303         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1304         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1305             continue;
1306         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1307         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1308             continue;
1309         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1310         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1311             continue;
1312         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1313         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1314             continue;
1315         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1316         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1317             continue;
1318
1319         // rule 4: we must "see" some spawnpoint or item
1320     entity sp = NULL;
1321     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1322     {
1323         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1324         {
1325                 sp = it;
1326                 break;
1327         }
1328     });
1329         if(!sp)
1330         {
1331                 int items_checked = 0;
1332                 IL_EACH(g_items, checkpvs(mstart, it),
1333                 {
1334                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1335                         {
1336                                 sp = it;
1337                                 break;
1338                         }
1339
1340                         ++items_checked;
1341                         if(items_checked >= attempts)
1342                                 break; // sanity
1343                 });
1344
1345                 if(!sp)
1346                         continue;
1347         }
1348
1349         // find a random vector to "look at"
1350         end.x = org.x + random() * delta.x;
1351         end.y = org.y + random() * delta.y;
1352         end.z = org.z + random() * delta.z;
1353         end = start + normalize(end - start) * vlen(delta);
1354
1355         // rule 4: start TO end must not be too short
1356         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1357         if (trace_startsolid)
1358             continue;
1359         if (trace_fraction < minviewdistance / vlen(delta))
1360             continue;
1361
1362         // rule 5: don't want to look at sky
1363         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1364             continue;
1365
1366         // rule 6: we must not end up in trigger_hurt
1367         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1368             continue;
1369
1370         break;
1371     }
1372
1373     e.dphitcontentsmask = m;
1374
1375     if (i < attempts)
1376     {
1377         setorigin(e, start);
1378         e.angles = vectoangles(end - start);
1379         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1380         return true;
1381     }
1382     else
1383         return false;
1384 }
1385
1386 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1387 {
1388         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1389 }
1390
1391 void write_recordmarker(entity pl, float tstart, float dt)
1392 {
1393     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1394
1395     // also write a marker into demo files for demotc-race-record-extractor to find
1396     stuffcmd(pl,
1397              strcat(
1398                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1399                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1400 }
1401
1402 void attach_sameorigin(entity e, entity to, string tag)
1403 {
1404     vector org, t_forward, t_left, t_up, e_forward, e_up;
1405     float tagscale;
1406
1407     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1408     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1409     t_forward = v_forward * tagscale;
1410     t_left = v_right * -tagscale;
1411     t_up = v_up * tagscale;
1412
1413     e.origin_x = org * t_forward;
1414     e.origin_y = org * t_left;
1415     e.origin_z = org * t_up;
1416
1417     // current forward and up directions
1418     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1419                 e.angles = AnglesTransform_FromVAngles(e.angles);
1420         else
1421                 e.angles = AnglesTransform_FromAngles(e.angles);
1422     fixedmakevectors(e.angles);
1423
1424     // untransform forward, up!
1425     e_forward.x = v_forward * t_forward;
1426     e_forward.y = v_forward * t_left;
1427     e_forward.z = v_forward * t_up;
1428     e_up.x = v_up * t_forward;
1429     e_up.y = v_up * t_left;
1430     e_up.z = v_up * t_up;
1431
1432     e.angles = fixedvectoangles2(e_forward, e_up);
1433     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1434                 e.angles = AnglesTransform_ToVAngles(e.angles);
1435         else
1436                 e.angles = AnglesTransform_ToAngles(e.angles);
1437
1438     setattachment(e, to, tag);
1439     setorigin(e, e.origin);
1440 }
1441
1442 void detach_sameorigin(entity e)
1443 {
1444     vector org;
1445     org = gettaginfo(e, 0);
1446     e.angles = fixedvectoangles2(v_forward, v_up);
1447     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1448                 e.angles = AnglesTransform_ToVAngles(e.angles);
1449         else
1450                 e.angles = AnglesTransform_ToAngles(e.angles);
1451     setorigin(e, org);
1452     setattachment(e, NULL, "");
1453     setorigin(e, e.origin);
1454 }
1455
1456 void follow_sameorigin(entity e, entity to)
1457 {
1458     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1459     e.aiment = to; // make the hole follow bmodel
1460     e.punchangle = to.angles; // the original angles of bmodel
1461     e.view_ofs = e.origin - to.origin; // relative origin
1462     e.v_angle = e.angles - to.angles; // relative angles
1463 }
1464
1465 void unfollow_sameorigin(entity e)
1466 {
1467     set_movetype(e, MOVETYPE_NONE);
1468 }
1469
1470 entity gettaginfo_relative_ent;
1471 vector gettaginfo_relative(entity e, float tag)
1472 {
1473     if (!gettaginfo_relative_ent)
1474     {
1475         gettaginfo_relative_ent = spawn();
1476         gettaginfo_relative_ent.effects = EF_NODRAW;
1477     }
1478     gettaginfo_relative_ent.model = e.model;
1479     gettaginfo_relative_ent.modelindex = e.modelindex;
1480     gettaginfo_relative_ent.frame = e.frame;
1481     return gettaginfo(gettaginfo_relative_ent, tag);
1482 }
1483
1484 .string aiment_classname;
1485 .float aiment_deadflag;
1486 void SetMovetypeFollow(entity ent, entity e)
1487 {
1488         // FIXME this may not be warpzone aware
1489         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1490         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1491         ent.aiment = e; // make the hole follow bmodel
1492         ent.punchangle = e.angles; // the original angles of bmodel
1493         ent.view_ofs = ent.origin - e.origin; // relative origin
1494         ent.v_angle = ent.angles - e.angles; // relative angles
1495         ent.aiment_classname = strzone(e.classname);
1496         ent.aiment_deadflag = e.deadflag;
1497 }
1498 void UnsetMovetypeFollow(entity ent)
1499 {
1500         set_movetype(ent, MOVETYPE_FLY);
1501         PROJECTILE_MAKETRIGGER(ent);
1502         ent.aiment = NULL;
1503 }
1504 float LostMovetypeFollow(entity ent)
1505 {
1506 /*
1507         if(ent.move_movetype != MOVETYPE_FOLLOW)
1508                 if(ent.aiment)
1509                         error("???");
1510 */
1511         if(ent.aiment)
1512         {
1513                 if(ent.aiment.classname != ent.aiment_classname)
1514                         return 1;
1515                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1516                         return 1;
1517         }
1518         return 0;
1519 }
1520
1521 .bool pushable;
1522 bool isPushable(entity e)
1523 {
1524         if(e.pushable)
1525                 return true;
1526         if(IS_VEHICLE(e))
1527                 return false;
1528         if(e.iscreature)
1529                 return true;
1530         if (Item_IsLoot(e))
1531         {
1532                 return true;
1533         }
1534         switch(e.classname)
1535         {
1536                 case "body":
1537                         return true;
1538                 case "bullet": // antilagged bullets can't hit this either
1539                         return false;
1540         }
1541         if (e.projectiledeathtype)
1542                 return true;
1543         return false;
1544 }