qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 float spawnpoint_nag;
 155 void relocate_spawnpoint()
 156 {
 157     // nudge off the floor
 158     setorigin(self, self.origin + '0 0 1');
 159
 160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 161     if (trace_startsolid)
 162     {
 163         vector o;
 164         o = self.origin;
 165         self.mins = PL_MIN;
 166         self.maxs = PL_MAX;
 167         if (!move_out_of_solid(self))
 168             objerror("could not get out of solid at all!");
 169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 171         print(" ", ftos(self.origin_y - o_y));
 172         print(" ", ftos(self.origin_z - o_z), "'\n");
 173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 174         {
 175             if (!spawnpoint_nag)
 176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 177             spawnpoint_nag = 1;
 178         }
 179         else
 180         {
 181             setorigin(self, o);
 182             self.mins = self.maxs = '0 0 0';
 183             objerror("player spawn point in solid, mapper sucks!\n");
 184             return;
 185         }
 186     }
 187
 188     self.use = spawnpoint_use;
 189     self.team_saved = self.team;
 190     if (!self.cnt)
 191         self.cnt = 1;
 192
 193     if (have_team_spawns != 0)
 194         if (self.team)
 195             have_team_spawns = 1;
 196     have_team_spawns_forteam[self.team] = 1;
 197
 198     if (autocvar_r_showbboxes)
 199     {
 200         // show where spawnpoints point at too
 201         makevectors(self.angles);
 202         entity e;
 203         e = spawn();
 204         e.classname = "info_player_foo";
 205         setorigin(e, self.origin + v_forward * 24);
 206         setsize(e, '-8 -8 -8', '8 8 8');
 207         e.solid = SOLID_TRIGGER;
 208     }
 209 }
 210
 211 #define strstr strstrofs
 212 /*
 213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 216 // BE CONSTANT OR strzoneD!
 217 float strstr(string haystack, string needle, float offset)
 218 {
 219         float len, endpos;
 220         string found;
 221         len = strlen(needle);
 222         endpos = strlen(haystack) - len;
 223         while(offset <= endpos)
 224         {
 225                 found = substring(haystack, offset, len);
 226                 if(found == needle)
 227                         return offset;
 228                 offset = offset + 1;
 229         }
 230         return -1;
 231 }
 232 */
 233
 234 float NUM_NEAREST_ENTITIES = 4;
 235 entity nearest_entity[NUM_NEAREST_ENTITIES];
 236 float nearest_length[NUM_NEAREST_ENTITIES];
 237 entity findnearest(vector point, .string field, string value, vector axismod)
 238 {
 239     entity localhead;
 240     float i;
 241     float j;
 242     float len;
 243     vector dist;
 244
 245     float num_nearest;
 246     num_nearest = 0;
 247
 248     localhead = find(world, field, value);
 249     while (localhead)
 250     {
 251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 252             dist = localhead.oldorigin;
 253         else
 254             dist = localhead.origin;
 255         dist = dist - point;
 256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 257         len = vlen(dist);
 258
 259         for (i = 0; i < num_nearest; ++i)
 260         {
 261             if (len < nearest_length[i])
 262                 break;
 263         }
 264
 265         // now i tells us where to insert at
 266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 267         if (i < NUM_NEAREST_ENTITIES)
 268         {
 269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 270             {
 271                 nearest_length[j + 1] = nearest_length[j];
 272                 nearest_entity[j + 1] = nearest_entity[j];
 273             }
 274             nearest_length[i] = len;
 275             nearest_entity[i] = localhead;
 276             if (num_nearest < NUM_NEAREST_ENTITIES)
 277                 num_nearest = num_nearest + 1;
 278         }
 279
 280         localhead = find(localhead, field, value);
 281     }
 282
 283     // now use the first one from our list that we can see
 284     for (i = 0; i < num_nearest; ++i)
 285     {
 286         traceline(point, nearest_entity[i].origin, TRUE, world);
 287         if (trace_fraction == 1)
 288         {
 289             if (i != 0)
 290             {
 291                 dprint("Nearest point (");
 292                 dprint(nearest_entity[0].netname);
 293                 dprint(") is not visible, using a visible one.\n");
 294             }
 295             return nearest_entity[i];
 296         }
 297     }
 298
 299     if (num_nearest == 0)
 300         return world;
 301
 302     dprint("Not seeing any location point, using nearest as fallback.\n");
 303     /* DEBUGGING CODE:
 304     dprint("Candidates were: ");
 305     for(j = 0; j < num_nearest; ++j)
 306     {
 307         if(j != 0)
 308                 dprint(", ");
 309         dprint(nearest_entity[j].netname);
 310     }
 311     dprint("\n");
 312     */
 313
 314     return nearest_entity[0];
 315 }
 316
 317 void spawnfunc_target_location()
 318 {
 319     self.classname = "target_location";
 320     // location name in netname
 321     // eventually support: count, teamgame selectors, line of sight?
 322 }
 323
 324 void spawnfunc_info_location()
 325 {
 326     self.classname = "target_location";
 327     self.message = self.netname;
 328 }
 329
 330 string NearestLocation(vector p)
 331 {
 332     entity loc;
 333     string ret;
 334     ret = "somewhere";
 335     loc = findnearest(p, classname, "target_location", '1 1 1');
 336     if (loc)
 337     {
 338         ret = loc.message;
 339     }
 340     else
 341     {
 342         loc = findnearest(p, target, "###item###", '1 1 4');
 343         if (loc)
 344             ret = loc.netname;
 345     }
 346     return ret;
 347 }
 348
 349 string formatmessage(string msg)
 350 {
 351         float p, p1, p2;
 352         float n;
 353         vector cursor;
 354         entity cursor_ent;
 355         string escape;
 356         string replacement;
 357         p = 0;
 358         n = 7;
 359
 360         WarpZone_crosshair_trace(self);
 361         cursor = trace_endpos;
 362         cursor_ent = trace_ent;
 363
 364         while (1) {
 365                 if (n < 1)
 366                         break; // too many replacements
 367
 368                 n = n - 1;
 369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 371
 372                 if (p1 < 0)
 373                         p1 = p2;
 374
 375                 if (p2 < 0)
 376                         p2 = p1;
 377
 378                 p = min(p1, p2);
 379
 380                 if (p < 0)
 381                         break;
 382
 383                 replacement = substring(msg, p, 2);
 384                 escape = substring(msg, p + 1, 1);
 385
 386                 if (escape == "%")
 387                         replacement = "%";
 388                 else if (escape == "\\")
 389                         replacement = "\\";
 390                 else if (escape == "n")
 391                         replacement = "\n";
 392                 else if (escape == "a")
 393                         replacement = ftos(floor(self.armorvalue));
 394                 else if (escape == "h")
 395                         replacement = ftos(floor(self.health));
 396                 else if (escape == "l")
 397                         replacement = NearestLocation(self.origin);
 398                 else if (escape == "y")
 399                         replacement = NearestLocation(cursor);
 400                 else if (escape == "d")
 401                         replacement = NearestLocation(self.death_origin);
 402                 else if (escape == "w") {
 403                         float wep;
 404                         wep = self.weapon;
 405                         if (!wep)
 406                                 wep = self.switchweapon;
 407                         if (!wep)
 408                                 wep = self.cnt;
 409                         replacement = W_Name(wep);
 410                 } else if (escape == "W") {
 411                         if (self.items & IT_SHELLS) replacement = "shells";
 412                         else if (self.items & IT_NAILS) replacement = "bullets";
 413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 414                         else if (self.items & IT_CELLS) replacement = "cells";
 415                         else replacement = "batteries"; // ;)
 416                 } else if (escape == "x") {
 417                         replacement = cursor_ent.netname;
 418                         if (!replacement || !cursor_ent)
 419                                 replacement = "nothing";
 420                 } else if (escape == "s")
 421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 422                 else if (escape == "S")
 423                         replacement = ftos(vlen(self.velocity));
 424
 425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 426                 p = p + strlen(replacement);
 427         }
 428         return msg;
 429 }
 430
 431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 432         return (value == 0) ? FALSE : TRUE;
 433 }
 434
 435 /*
 436 =============
 437 GetCvars
 438 =============
 439 Called with:
 440   0:  sends the request
 441   >0: receives a cvar from name=argv(f) value=argv(f+1)
 442 */
 443 void GetCvars_handleString(string thisname, float f, .string field, string name)
 444 {
 445         if (f < 0)
 446         {
 447                 if (self.field)
 448                         strunzone(self.field);
 449                 self.field = string_null;
 450         }
 451         else if (f > 0)
 452         {
 453                 if (thisname == name)
 454                 {
 455                         if (self.field)
 456                                 strunzone(self.field);
 457                         self.field = strzone(argv(f + 1));
 458                 }
 459         }
 460         else
 461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462 }
 463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 464 {
 465         GetCvars_handleString(thisname, f, field, name);
 466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 467                 if (thisname == name)
 468                 {
 469                         string s;
 470                         s = func(strcat1(self.field));
 471                         if (s != self.field)
 472                         {
 473                                 strunzone(self.field);
 474                                 self.field = strzone(s);
 475                         }
 476                 }
 477 }
 478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 479 {
 480         if (f < 0)
 481         {
 482         }
 483         else if (f > 0)
 484         {
 485                 if (thisname == name)
 486                         self.field = stof(argv(f + 1));
 487         }
 488         else
 489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 490 }
 491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                 {
 500                         if(!self.field)
 501                         {
 502                                 self.field = stof(argv(f + 1));
 503                                 if(!self.field)
 504                                         self.field = -1;
 505                         }
 506                 }
 507         }
 508         else
 509         {
 510                 if(!self.field)
 511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 512         }
 513 }
 514 float w_getbestweapon(entity e);
 515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 516 {
 517         string o;
 518         o = W_FixWeaponOrder_ForceComplete(wo);
 519         if(self.weaponorder_byimpulse)
 520         {
 521                 strunzone(self.weaponorder_byimpulse);
 522                 self.weaponorder_byimpulse = string_null;
 523         }
 524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 525         return o;
 526 }
 527 void GetCvars(float f)
 528 {
 529         string s;
 530
 531         if (f > 0)
 532                 s = strcat1(argv(f));
 533
 534         get_cvars_f = f;
 535         get_cvars_s = s;
 536         MUTATOR_CALLHOOK(GetCvars);
 537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 560
 561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 563
 564 #ifdef ALLOW_FORCEMODELS
 565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 567 #endif
 568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 573
 574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 575         if (f > 0)
 576         {
 577                 if (s == "cl_weaponpriority")
 578                         self.switchweapon = w_getbestweapon(self);
 579                 if (s == "cl_allow_uidtracking")
 580                         PlayerStats_AddPlayer(self);
 581         }
 582 }
 583
 584 void backtrace(string msg)
 585 {
 586     float dev, war;
 587     dev = autocvar_developer;
 588     war = autocvar_prvm_backtraceforwarnings;
 589     cvar_set("developer", "1");
 590     cvar_set("prvm_backtraceforwarnings", "1");
 591     print("\n");
 592     print("--- CUT HERE ---\nWARNING: ");
 593     print(msg);
 594     print("\n");
 595     remove(world); // isn't there any better way to cause a backtrace?
 596     print("\n--- CUT UNTIL HERE ---\n");
 597     cvar_set("developer", ftos(dev));
 598     cvar_set("prvm_backtraceforwarnings", ftos(war));
 599 }
 600
 601 string Team_ColorCode(float teamid)
 602 {
 603     if (teamid == COLOR_TEAM1)
 604         return "^1";
 605     else if (teamid == COLOR_TEAM2)
 606         return "^4";
 607     else if (teamid == COLOR_TEAM3)
 608         return "^3";
 609     else if (teamid == COLOR_TEAM4)
 610         return "^6";
 611     else
 612         return "^7";
 613 }
 614
 615 string Team_ColorName(float t)
 616 {
 617     // fixme: Search for team entities and get their .netname's!
 618     if (t == COLOR_TEAM1)
 619         return "Red";
 620     if (t == COLOR_TEAM2)
 621         return "Blue";
 622     if (t == COLOR_TEAM3)
 623         return "Yellow";
 624     if (t == COLOR_TEAM4)
 625         return "Pink";
 626     return "Neutral";
 627 }
 628
 629 string Team_ColorNameLowerCase(float t)
 630 {
 631     // fixme: Search for team entities and get their .netname's!
 632     if (t == COLOR_TEAM1)
 633         return "red";
 634     if (t == COLOR_TEAM2)
 635         return "blue";
 636     if (t == COLOR_TEAM3)
 637         return "yellow";
 638     if (t == COLOR_TEAM4)
 639         return "pink";
 640     return "neutral";
 641 }
 642
 643 float ColourToNumber(string team_colour)
 644 {
 645         if (team_colour == "red")
 646                 return COLOR_TEAM1;
 647
 648         if (team_colour == "blue")
 649                 return COLOR_TEAM2;
 650
 651         if (team_colour == "yellow")
 652                 return COLOR_TEAM3;
 653
 654         if (team_colour == "pink")
 655                 return COLOR_TEAM4;
 656
 657         if (team_colour == "auto")
 658                 return 0;
 659
 660         return -1;
 661 }
 662
 663 float NumberToTeamNumber(float number)
 664 {
 665         if (number == 1)
 666                 return COLOR_TEAM1;
 667
 668         if (number == 2)
 669                 return COLOR_TEAM2;
 670
 671         if (number == 3)
 672                 return COLOR_TEAM3;
 673
 674         if (number == 4)
 675                 return COLOR_TEAM4;
 676
 677         return -1;
 678 }
 679
 680 // decolorizes and team colors the player name when needed
 681 string playername(entity p)
 682 {
 683     string t;
 684     if (teamplay && !intermission_running && p.classname == "player")
 685     {
 686         t = Team_ColorCode(p.team);
 687         return strcat(t, strdecolorize(p.netname));
 688     }
 689     else
 690         return p.netname;
 691 }
 692
 693 vector randompos(vector m1, vector m2)
 694 {
 695     vector v;
 696     m2 = m2 - m1;
 697     v_x = m2_x * random() + m1_x;
 698     v_y = m2_y * random() + m1_y;
 699     v_z = m2_z * random() + m1_z;
 700     return  v;
 701 }
 702
 703 //#NO AUTOCVARS START
 704
 705 float g_pickup_shells;
 706 float g_pickup_shells_max;
 707 float g_pickup_nails;
 708 float g_pickup_nails_max;
 709 float g_pickup_rockets;
 710 float g_pickup_rockets_max;
 711 float g_pickup_cells;
 712 float g_pickup_cells_max;
 713 float g_pickup_fuel;
 714 float g_pickup_fuel_jetpack;
 715 float g_pickup_fuel_max;
 716 float g_pickup_armorsmall;
 717 float g_pickup_armorsmall_max;
 718 float g_pickup_armorsmall_anyway;
 719 float g_pickup_armormedium;
 720 float g_pickup_armormedium_max;
 721 float g_pickup_armormedium_anyway;
 722 float g_pickup_armorbig;
 723 float g_pickup_armorbig_max;
 724 float g_pickup_armorbig_anyway;
 725 float g_pickup_armorlarge;
 726 float g_pickup_armorlarge_max;
 727 float g_pickup_armorlarge_anyway;
 728 float g_pickup_healthsmall;
 729 float g_pickup_healthsmall_max;
 730 float g_pickup_healthsmall_anyway;
 731 float g_pickup_healthmedium;
 732 float g_pickup_healthmedium_max;
 733 float g_pickup_healthmedium_anyway;
 734 float g_pickup_healthlarge;
 735 float g_pickup_healthlarge_max;
 736 float g_pickup_healthlarge_anyway;
 737 float g_pickup_healthmega;
 738 float g_pickup_healthmega_max;
 739 float g_pickup_healthmega_anyway;
 740 float g_pickup_ammo_anyway;
 741 float g_pickup_weapons_anyway;
 742 float g_weaponarena;
 743 float g_weaponarena_random;
 744 float g_weaponarena_random_with_laser;
 745 string g_weaponarena_list;
 746 float g_weaponspeedfactor;
 747 float g_weaponratefactor;
 748 float g_weapondamagefactor;
 749 float g_weaponforcefactor;
 750 float g_weaponspreadfactor;
 751
 752 float start_weapons;
 753 float start_items;
 754 float start_ammo_shells;
 755 float start_ammo_nails;
 756 float start_ammo_rockets;
 757 float start_ammo_cells;
 758 float start_ammo_fuel;
 759 float start_health;
 760 float start_armorvalue;
 761 float warmup_start_weapons;
 762 float warmup_start_ammo_shells;
 763 float warmup_start_ammo_nails;
 764 float warmup_start_ammo_rockets;
 765 float warmup_start_ammo_cells;
 766 float warmup_start_ammo_fuel;
 767 float warmup_start_health;
 768 float warmup_start_armorvalue;
 769 float g_weapon_stay;
 770 float g_ghost_items;
 771
 772 entity get_weaponinfo(float w);
 773
 774 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 775 {
 776         var float i = weaponinfo.weapon;
 777
 778         if (!i)
 779                 return 0;
 780
 781         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 782
 783         if (t < 0) // "default" weapon selection
 784         {
 785                 if (g_lms || g_ca || allguns)
 786                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 787                 else if(t < -1)
 788                         t = 0;
 789                 else if (g_cts)
 790                         t = (i == WEP_SHOTGUN);
 791                 else if (g_nexball)
 792                         t = 0; // weapon is set a few lines later
 793                 else
 794                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 795                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 796                         t |= (i == WEP_HOOK);
 797         }
 798
 799         // we cannot disable porto in Nexball, we must force it
 800         if(g_nexball && i == WEP_PORTO)
 801                 t = 1;
 802
 803         return t;
 804 }
 805
 806 void readplayerstartcvars()
 807 {
 808         entity e;
 809         float i, j, t;
 810         string s;
 811
 812         // initialize starting values for players
 813         start_weapons = 0;
 814         start_items = 0;
 815         start_ammo_shells = 0;
 816         start_ammo_nails = 0;
 817         start_ammo_rockets = 0;
 818         start_ammo_cells = 0;
 819         start_health = cvar("g_balance_health_start");
 820         start_armorvalue = cvar("g_balance_armor_start");
 821
 822         g_weaponarena = 0;
 823         s = cvar_string("g_weaponarena");
 824         if (s == "0" || s == "")
 825         {
 826                 if(g_lms || g_ca)
 827                         s = "most";
 828         }
 829
 830         if (s == "0" || s == "")
 831         {
 832                 // no arena
 833         }
 834         else if (s == "off")
 835         {
 836                 // forcibly turn off weaponarena
 837         }
 838         else if (s == "all")
 839         {
 840                 g_weaponarena_list = "All Weapons";
 841                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 842                 {
 843                         e = get_weaponinfo(j);
 844                         g_weaponarena |= e.weapons;
 845                         weapon_action(e.weapon, WR_PRECACHE);
 846                 }
 847         }
 848         else if (s == "most")
 849         {
 850                 g_weaponarena_list = "Most Weapons";
 851                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 852                 {
 853                         e = get_weaponinfo(j);
 854                         if (e.spawnflags & WEP_FLAG_NORMAL)
 855                         {
 856                                 g_weaponarena |= e.weapons;
 857                                 weapon_action(e.weapon, WR_PRECACHE);
 858                         }
 859                 }
 860         }
 861         else if (s == "none")
 862         {
 863                 g_weaponarena_list = "No Weapons";
 864                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 865         }
 866         else
 867         {
 868                 t = tokenize_console(s);
 869                 g_weaponarena_list = "";
 870                 for (i = 0; i < t; ++i)
 871                 {
 872                         s = argv(i);
 873                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 874                         {
 875                                 e = get_weaponinfo(j);
 876                                 if (e.netname == s)
 877                                 {
 878                                         g_weaponarena |= e.weapons;
 879                                         weapon_action(e.weapon, WR_PRECACHE);
 880                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 881                                         break;
 882                                 }
 883                         }
 884                         if (j > WEP_LAST)
 885                         {
 886                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 887                         }
 888                 }
 889                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 890         }
 891
 892         if(g_weaponarena)
 893                 g_weaponarena_random = cvar("g_weaponarena_random");
 894         else
 895                 g_weaponarena_random = 0;
 896         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 897
 898         if (g_weaponarena)
 899         {
 900                 start_weapons = g_weaponarena;
 901                 if(!(g_lms || g_ca))
 902                         start_items |= IT_UNLIMITED_AMMO;
 903         }
 904         else if (g_minstagib)
 905         {
 906                 start_health = 100;
 907                 start_armorvalue = 0;
 908                 start_weapons = WEPBIT_MINSTANEX;
 909                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 910                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 911                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 912
 913                 if (g_minstagib_invis_alpha <= 0)
 914                         g_minstagib_invis_alpha = -1;
 915         }
 916         else
 917         {
 918                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 919                 {
 920                         e = get_weaponinfo(i);
 921                         if(want_weapon("g_start_weapon_", e, FALSE))
 922                                 start_weapons |= e.weapons;
 923                 }
 924         }
 925
 926         if(!cvar("g_use_ammunition"))
 927                 start_items |= IT_UNLIMITED_AMMO;
 928
 929         if(cvar("g_nexball"))
 930                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 931
 932         if(g_minstagib)
 933         {
 934                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 935                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 936         }
 937         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 938         {
 939                 start_ammo_rockets = 999;
 940                 start_ammo_shells = 999;
 941                 start_ammo_cells = 999;
 942                 start_ammo_nails = 999;
 943                 start_ammo_fuel = 999;
 944         }
 945         else
 946         {
 947                 if(g_lms || g_ca)
 948                 {
 949                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 950                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 951                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 952                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 953                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 954                 }
 955                 else
 956                 {
 957                         start_ammo_shells = cvar("g_start_ammo_shells");
 958                         start_ammo_nails = cvar("g_start_ammo_nails");
 959                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 960                         start_ammo_cells = cvar("g_start_ammo_cells");
 961                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 962                 }
 963         }
 964
 965         if (g_lms || g_ca)
 966         {
 967                 start_health = cvar("g_lms_start_health");
 968                 start_armorvalue = cvar("g_lms_start_armor");
 969         }
 970
 971         if (inWarmupStage)
 972         {
 973                 warmup_start_ammo_shells = start_ammo_shells;
 974                 warmup_start_ammo_nails = start_ammo_nails;
 975                 warmup_start_ammo_rockets = start_ammo_rockets;
 976                 warmup_start_ammo_cells = start_ammo_cells;
 977                 warmup_start_ammo_fuel = start_ammo_fuel;
 978                 warmup_start_health = start_health;
 979                 warmup_start_armorvalue = start_armorvalue;
 980                 warmup_start_weapons = start_weapons;
 981
 982                 if (!g_weaponarena && !g_minstagib && !g_ca)
 983                 {
 984                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 985                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 986                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 987                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 988                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 989                         warmup_start_health = cvar("g_warmup_start_health");
 990                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 991                         warmup_start_weapons = 0;
 992                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 993                         {
 994                                 e = get_weaponinfo(i);
 995                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 996                                         warmup_start_weapons |= e.weapons;
 997                         }
 998                 }
 999         }
1000
1001         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1002         {
1003                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1004                 start_items |= IT_FUEL_REGEN;
1005                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1006                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1007         }
1008
1009         if (g_jetpack)
1010                 start_items |= IT_JETPACK;
1011
1012         MUTATOR_CALLHOOK(SetStartItems);
1013
1014         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1015         {
1016                 e = get_weaponinfo(i);
1017                 if(e.weapons & (start_weapons | warmup_start_weapons))
1018                         weapon_action(e.weapon, WR_PRECACHE);
1019         }
1020
1021         start_ammo_shells = max(0, start_ammo_shells);
1022         start_ammo_nails = max(0, start_ammo_nails);
1023         start_ammo_cells = max(0, start_ammo_cells);
1024         start_ammo_rockets = max(0, start_ammo_rockets);
1025         start_ammo_fuel = max(0, start_ammo_fuel);
1026
1027         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1028         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1029         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1030         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1031         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1032 }
1033
1034 float g_bugrigs;
1035 float g_bugrigs_planar_movement;
1036 float g_bugrigs_planar_movement_car_jumping;
1037 float g_bugrigs_reverse_spinning;
1038 float g_bugrigs_reverse_speeding;
1039 float g_bugrigs_reverse_stopping;
1040 float g_bugrigs_air_steering;
1041 float g_bugrigs_angle_smoothing;
1042 float g_bugrigs_friction_floor;
1043 float g_bugrigs_friction_brake;
1044 float g_bugrigs_friction_air;
1045 float g_bugrigs_accel;
1046 float g_bugrigs_speed_ref;
1047 float g_bugrigs_speed_pow;
1048 float g_bugrigs_steer;
1049
1050 float g_touchexplode;
1051 float g_touchexplode_radius;
1052 float g_touchexplode_damage;
1053 float g_touchexplode_edgedamage;
1054 float g_touchexplode_force;
1055
1056 float sv_autotaunt;
1057 float sv_taunt;
1058
1059 float sv_pitch_min;
1060 float sv_pitch_max;
1061 float sv_pitch_fixyaw;
1062
1063 string GetGametype(); // g_world.qc
1064 void readlevelcvars(void)
1065 {
1066         // first load all the mutators
1067         if(cvar("g_invincible_projectiles"))
1068                 MUTATOR_ADD(mutator_invincibleprojectiles);
1069         if(cvar("g_nix"))
1070                 MUTATOR_ADD(mutator_nix);
1071         if(cvar("g_dodging"))
1072                 MUTATOR_ADD(mutator_dodging);
1073         if(cvar("g_rocket_flying"))
1074                 MUTATOR_ADD(mutator_rocketflying);
1075         if(cvar("g_vampire"))
1076                 MUTATOR_ADD(mutator_vampire);
1077         if(cvar("g_spawn_near_teammate"))
1078                 MUTATOR_ADD(mutator_spawn_near_teammate);
1079
1080         // is this a mutator? is this a mode?
1081         if(cvar("g_sandbox"))
1082                 MUTATOR_ADD(sandbox);
1083
1084         if(cvar("sv_allow_fullbright"))
1085                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1086
1087     g_bugrigs = cvar("g_bugrigs");
1088     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1089     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1090     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1091     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1092     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1093     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1094     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1095     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1096     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1097     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1098     g_bugrigs_accel = cvar("g_bugrigs_accel");
1099     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1100     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1101     g_bugrigs_steer = cvar("g_bugrigs_steer");
1102
1103     g_touchexplode = cvar("g_touchexplode");
1104     g_touchexplode_radius = cvar("g_touchexplode_radius");
1105     g_touchexplode_damage = cvar("g_touchexplode_damage");
1106     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1107     g_touchexplode_force = cvar("g_touchexplode_force");
1108
1109 #ifdef ALLOW_FORCEMODELS
1110         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1111 #endif
1112
1113         sv_clones = cvar("sv_clones");
1114         sv_gentle = cvar("sv_gentle");
1115         sv_foginterval = cvar("sv_foginterval");
1116         g_cloaked = cvar("g_cloaked");
1117     if(g_cts)
1118         g_cloaked = 1; // always enable cloak in CTS
1119         g_jump_grunt = cvar("g_jump_grunt");
1120         g_footsteps = cvar("g_footsteps");
1121         g_grappling_hook = cvar("g_grappling_hook");
1122         g_jetpack = cvar("g_jetpack");
1123         g_midair = cvar("g_midair");
1124         g_minstagib = cvar("g_minstagib");
1125         g_norecoil = cvar("g_norecoil");
1126         g_bloodloss = cvar("g_bloodloss");
1127         sv_maxidle = cvar("sv_maxidle");
1128         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1129         g_ctf_reverse = cvar("g_ctf_reverse");
1130         sv_autotaunt = cvar("sv_autotaunt");
1131         sv_taunt = cvar("sv_taunt");
1132
1133         inWarmupStage = cvar("g_warmup");
1134         g_warmup_limit = cvar("g_warmup_limit");
1135         g_warmup_allguns = cvar("g_warmup_allguns");
1136         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1137
1138         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1139                 inWarmupStage = 0; // these modes cannot work together, sorry
1140
1141         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1142         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1143         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1144         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1145         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1146         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1147         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1148         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1149         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1150         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1151         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1152         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1153         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1154         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1155
1156         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1157         g_weaponratefactor = cvar("g_weaponratefactor");
1158         g_weapondamagefactor = cvar("g_weapondamagefactor");
1159         g_weaponforcefactor = cvar("g_weaponforcefactor");
1160         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1161
1162         g_pickup_shells = cvar("g_pickup_shells");
1163         g_pickup_shells_max = cvar("g_pickup_shells_max");
1164         g_pickup_nails = cvar("g_pickup_nails");
1165         g_pickup_nails_max = cvar("g_pickup_nails_max");
1166         g_pickup_rockets = cvar("g_pickup_rockets");
1167         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1168         g_pickup_cells = cvar("g_pickup_cells");
1169         g_pickup_cells_max = cvar("g_pickup_cells_max");
1170         g_pickup_fuel = cvar("g_pickup_fuel");
1171         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1172         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1173         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1174         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1175         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1176         g_pickup_armormedium = cvar("g_pickup_armormedium");
1177         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1178         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1179         g_pickup_armorbig = cvar("g_pickup_armorbig");
1180         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1181         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1182         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1183         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1184         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1185         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1186         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1187         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1188         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1189         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1190         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1191         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1192         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1193         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1194         g_pickup_healthmega = cvar("g_pickup_healthmega");
1195         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1196         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1197
1198         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1199         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1200
1201         g_pinata = cvar("g_pinata");
1202
1203     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1204     if(!g_weapon_stay)
1205         g_weapon_stay = cvar("g_weapon_stay");
1206
1207         g_ghost_items = cvar("g_ghost_items");
1208
1209         if(g_ghost_items >= 1)
1210                 g_ghost_items = 0.25; // default alpha value
1211
1212         if not(inWarmupStage && !g_ca)
1213                 game_starttime = cvar("g_start_delay");
1214
1215         sv_pitch_min = cvar("sv_pitch_min");
1216         sv_pitch_max = cvar("sv_pitch_max");
1217         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1218
1219         readplayerstartcvars();
1220 }
1221
1222 //#NO AUTOCVARS END
1223
1224 // Sound functions
1225 string precache_sound (string s) = #19;
1226 float precache_sound_index (string s) = #19;
1227
1228 #define SND_VOLUME      1
1229 #define SND_ATTENUATION 2
1230 #define SND_LARGEENTITY 8
1231 #define SND_LARGESOUND  16
1232
1233 float sound_allowed(float dest, entity e)
1234 {
1235     // sounds from world may always pass
1236     for (;;)
1237     {
1238         if (e.classname == "body")
1239             e = e.enemy;
1240         else if (e.realowner && e.realowner != e)
1241             e = e.realowner;
1242         else if (e.owner && e.owner != e)
1243             e = e.owner;
1244         else
1245             break;
1246     }
1247     // sounds to self may always pass
1248     if (dest == MSG_ONE)
1249         if (e == msg_entity)
1250             return TRUE;
1251     // sounds by players can be removed
1252     if (autocvar_bot_sound_monopoly)
1253         if (clienttype(e) == CLIENTTYPE_REAL)
1254             return FALSE;
1255     // anything else may pass
1256     return TRUE;
1257 }
1258
1259 #ifdef COMPAT_XON010_CHANNELS
1260 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1261 void sound(entity e, float chan, string samp, float vol, float atten)
1262 {
1263     if (!sound_allowed(MSG_BROADCAST, e))
1264         return;
1265     builtin_sound(e, chan, samp, vol, atten);
1266 }
1267 #else
1268 #undef sound
1269 void sound(entity e, float chan, string samp, float vol, float atten)
1270 {
1271     if (!sound_allowed(MSG_BROADCAST, e))
1272         return;
1273     sound7(e, chan, samp, vol, atten, 0, 0);
1274 }
1275 #endif
1276
1277 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1278 {
1279     float entno, idx;
1280
1281     if (!sound_allowed(dest, e))
1282         return;
1283
1284     entno = num_for_edict(e);
1285     idx = precache_sound_index(samp);
1286
1287     float sflags;
1288     sflags = 0;
1289
1290     atten = floor(atten * 64);
1291     vol = floor(vol * 255);
1292
1293     if (vol != 255)
1294         sflags |= SND_VOLUME;
1295     if (atten != 64)
1296         sflags |= SND_ATTENUATION;
1297     if (entno >= 8192 || chan < 0 || chan > 7)
1298         sflags |= SND_LARGEENTITY;
1299     if (idx >= 256)
1300         sflags |= SND_LARGESOUND;
1301
1302     WriteByte(dest, SVC_SOUND);
1303     WriteByte(dest, sflags);
1304     if (sflags & SND_VOLUME)
1305         WriteByte(dest, vol);
1306     if (sflags & SND_ATTENUATION)
1307         WriteByte(dest, atten);
1308     if (sflags & SND_LARGEENTITY)
1309     {
1310         WriteShort(dest, entno);
1311         WriteByte(dest, chan);
1312     }
1313     else
1314     {
1315         WriteShort(dest, entno * 8 + chan);
1316     }
1317     if (sflags & SND_LARGESOUND)
1318         WriteShort(dest, idx);
1319     else
1320         WriteByte(dest, idx);
1321
1322     WriteCoord(dest, o_x);
1323     WriteCoord(dest, o_y);
1324     WriteCoord(dest, o_z);
1325 }
1326 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1327 {
1328     vector o;
1329
1330     if (!sound_allowed(dest, e))
1331         return;
1332
1333     o = e.origin + 0.5 * (e.mins + e.maxs);
1334     soundtoat(dest, e, o, chan, samp, vol, atten);
1335 }
1336 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1337 {
1338     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1339 }
1340 void stopsoundto(float dest, entity e, float chan)
1341 {
1342     float entno;
1343
1344     if (!sound_allowed(dest, e))
1345         return;
1346
1347     entno = num_for_edict(e);
1348
1349     if (entno >= 8192 || chan < 0 || chan > 7)
1350     {
1351         float idx, sflags;
1352         idx = precache_sound_index("misc/null.wav");
1353         sflags = SND_LARGEENTITY;
1354         if (idx >= 256)
1355             sflags |= SND_LARGESOUND;
1356         WriteByte(dest, SVC_SOUND);
1357         WriteByte(dest, sflags);
1358         WriteShort(dest, entno);
1359         WriteByte(dest, chan);
1360         if (sflags & SND_LARGESOUND)
1361             WriteShort(dest, idx);
1362         else
1363             WriteByte(dest, idx);
1364         WriteCoord(dest, e.origin_x);
1365         WriteCoord(dest, e.origin_y);
1366         WriteCoord(dest, e.origin_z);
1367     }
1368     else
1369     {
1370         WriteByte(dest, SVC_STOPSOUND);
1371         WriteShort(dest, entno * 8 + chan);
1372     }
1373 }
1374 void stopsound(entity e, float chan)
1375 {
1376     if (!sound_allowed(MSG_BROADCAST, e))
1377         return;
1378
1379     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1380     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1381 }
1382
1383 void play2(entity e, string filename)
1384 {
1385     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1386     msg_entity = e;
1387     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1388 }
1389
1390 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1391 .float spamtime;
1392 float spamsound(entity e, float chan, string samp, float vol, float atten)
1393 {
1394     if (!sound_allowed(MSG_BROADCAST, e))
1395         return FALSE;
1396
1397     if (time > e.spamtime)
1398     {
1399         e.spamtime = time;
1400         sound(e, chan, samp, vol, atten);
1401         return TRUE;
1402     }
1403     return FALSE;
1404 }
1405
1406 void play2team(float t, string filename)
1407 {
1408     entity head;
1409
1410     if (autocvar_bot_sound_monopoly)
1411         return;
1412
1413     FOR_EACH_REALPLAYER(head)
1414     {
1415         if (head.team == t)
1416             play2(head, filename);
1417     }
1418 }
1419
1420 void play2all(string samp)
1421 {
1422     if (autocvar_bot_sound_monopoly)
1423         return;
1424
1425     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1426 }
1427
1428 void PrecachePlayerSounds(string f);
1429 void precache_playermodel(string m)
1430 {
1431         float globhandle, i, n;
1432         string f;
1433
1434         if(substring(m, -9,5) == "_lod1")
1435                 return;
1436         if(substring(m, -9,5) == "_lod2")
1437                 return;
1438         precache_model(m);
1439         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1440         if(fexists(f))
1441                 precache_model(f);
1442         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1443         if(fexists(f))
1444                 precache_model(f);
1445
1446         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1447         if (globhandle < 0)
1448                 return;
1449         n = search_getsize(globhandle);
1450         for (i = 0; i < n; ++i)
1451         {
1452                 //print(search_getfilename(globhandle, i), "\n");
1453                 f = search_getfilename(globhandle, i);
1454                 PrecachePlayerSounds(f);
1455         }
1456         search_end(globhandle);
1457 }
1458 void precache_all_playermodels(string pattern)
1459 {
1460         float globhandle, i, n;
1461         string f;
1462
1463         globhandle = search_begin(pattern, TRUE, FALSE);
1464         if (globhandle < 0)
1465                 return;
1466         n = search_getsize(globhandle);
1467         for (i = 0; i < n; ++i)
1468         {
1469                 //print(search_getfilename(globhandle, i), "\n");
1470                 f = search_getfilename(globhandle, i);
1471                 precache_playermodel(f);
1472         }
1473         search_end(globhandle);
1474 }
1475
1476 void precache()
1477 {
1478     // gamemode related things
1479     precache_model ("models/misc/chatbubble.spr");
1480     if (g_runematch)
1481     {
1482         precache_model ("models/runematch/curse.mdl");
1483         precache_model ("models/runematch/rune.mdl");
1484     }
1485
1486 #ifdef TTURRETS_ENABLED
1487     if (autocvar_g_turrets)
1488         turrets_precash();
1489 #endif
1490
1491     // Precache all player models if desired
1492     if (autocvar_sv_precacheplayermodels)
1493     {
1494         PrecachePlayerSounds("sound/player/default.sounds");
1495         precache_all_playermodels("models/player/*.zym");
1496         precache_all_playermodels("models/player/*.dpm");
1497         precache_all_playermodels("models/player/*.md3");
1498         precache_all_playermodels("models/player/*.psk");
1499         precache_all_playermodels("models/player/*.iqm");
1500     }
1501
1502     if (autocvar_sv_defaultcharacter)
1503     {
1504         string s;
1505         s = autocvar_sv_defaultplayermodel_red;
1506         if (s != "")
1507             precache_playermodel(s);
1508         s = autocvar_sv_defaultplayermodel_blue;
1509         if (s != "")
1510             precache_playermodel(s);
1511         s = autocvar_sv_defaultplayermodel_yellow;
1512         if (s != "")
1513             precache_playermodel(s);
1514         s = autocvar_sv_defaultplayermodel_pink;
1515         if (s != "")
1516             precache_playermodel(s);
1517         s = autocvar_sv_defaultplayermodel;
1518         if (s != "")
1519             precache_playermodel(s);
1520     }
1521
1522     if (g_footsteps)
1523     {
1524         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1525         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1526     }
1527
1528     // gore and miscellaneous sounds
1529     //precache_sound ("misc/h2ohit.wav");
1530     precache_model ("models/hook.md3");
1531     precache_sound ("misc/armorimpact.wav");
1532     precache_sound ("misc/bodyimpact1.wav");
1533     precache_sound ("misc/bodyimpact2.wav");
1534     precache_sound ("misc/gib.wav");
1535     precache_sound ("misc/gib_splat01.wav");
1536     precache_sound ("misc/gib_splat02.wav");
1537     precache_sound ("misc/gib_splat03.wav");
1538     precache_sound ("misc/gib_splat04.wav");
1539     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1540     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1541     precache_sound ("misc/null.wav");
1542     precache_sound ("misc/spawn.wav");
1543     precache_sound ("misc/talk.wav");
1544     precache_sound ("misc/teleport.wav");
1545     precache_sound ("misc/poweroff.wav");
1546     precache_sound ("player/lava.wav");
1547     precache_sound ("player/slime.wav");
1548
1549     if (g_jetpack)
1550         precache_sound ("misc/jetpack_fly.wav");
1551
1552     precache_model ("models/sprites/0.spr32");
1553     precache_model ("models/sprites/1.spr32");
1554     precache_model ("models/sprites/2.spr32");
1555     precache_model ("models/sprites/3.spr32");
1556     precache_model ("models/sprites/4.spr32");
1557     precache_model ("models/sprites/5.spr32");
1558     precache_model ("models/sprites/6.spr32");
1559     precache_model ("models/sprites/7.spr32");
1560     precache_model ("models/sprites/8.spr32");
1561     precache_model ("models/sprites/9.spr32");
1562     precache_model ("models/sprites/10.spr32");
1563
1564     // common weapon precaches
1565         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1566     precache_sound ("weapons/weapon_switch.wav");
1567     precache_sound ("weapons/weaponpickup.wav");
1568     precache_sound ("weapons/unavailable.wav");
1569     precache_sound ("weapons/dryfire.wav");
1570     if (g_grappling_hook)
1571     {
1572         precache_sound ("weapons/hook_fire.wav"); // hook
1573         precache_sound ("weapons/hook_impact.wav"); // hook
1574     }
1575
1576     if(autocvar_sv_precacheweapons)
1577     {
1578         //precache weapon models/sounds
1579         float wep;
1580         wep = WEP_FIRST;
1581         while (wep <= WEP_LAST)
1582         {
1583             weapon_action(wep, WR_PRECACHE);
1584             wep = wep + 1;
1585         }
1586     }
1587
1588     precache_model("models/elaser.mdl");
1589     precache_model("models/laser.mdl");
1590     precache_model("models/ebomb.mdl");
1591
1592 #if 0
1593     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1594
1595     if (!self.noise && self.music) // quake 3 uses the music field
1596         self.noise = self.music;
1597
1598     // plays music for the level if there is any
1599     if (self.noise)
1600     {
1601         precache_sound (self.noise);
1602         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1603     }
1604 #endif
1605 }
1606
1607 // sorry, but using \ in macros breaks line numbers
1608 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1609 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1610 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1611
1612
1613 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1614 {
1615         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1616         {
1617                 msg_entity = e;
1618                 WRITESPECTATABLE_MSG_ONE({
1619                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1620                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1621                         WriteByte(MSG_ONE, id);
1622                         WriteString(MSG_ONE, s);
1623                         if (id != 0 && s != "")
1624                         {
1625                                 WriteByte(MSG_ONE, duration);
1626                                 WriteByte(MSG_ONE, countdown_num);
1627                         }
1628                 });
1629         }
1630 }
1631 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1632 {
1633         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1634 }
1635 // WARNING: this kills the trace globals
1636 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1637 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1638
1639 #define INITPRIO_FIRST              0
1640 #define INITPRIO_GAMETYPE           0
1641 #define INITPRIO_GAMETYPE_FALLBACK  1
1642 #define INITPRIO_FINDTARGET        10
1643 #define INITPRIO_DROPTOFLOOR       20
1644 #define INITPRIO_SETLOCATION       90
1645 #define INITPRIO_LINKDOORS         91
1646 #define INITPRIO_LAST              99
1647
1648 .void(void) initialize_entity;
1649 .float initialize_entity_order;
1650 .entity initialize_entity_next;
1651 entity initialize_entity_first;
1652
1653 void make_safe_for_remove(entity e)
1654 {
1655     if (e.initialize_entity)
1656     {
1657         entity ent, prev;
1658         for (ent = initialize_entity_first; ent; )
1659         {
1660             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1661             {
1662                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1663                 // skip it in linked list
1664                 if (prev)
1665                 {
1666                     prev.initialize_entity_next = ent.initialize_entity_next;
1667                     ent = prev.initialize_entity_next;
1668                 }
1669                 else
1670                 {
1671                     initialize_entity_first = ent.initialize_entity_next;
1672                     ent = initialize_entity_first;
1673                 }
1674             }
1675             else
1676             {
1677                 prev = ent;
1678                 ent = ent.initialize_entity_next;
1679             }
1680         }
1681     }
1682 }
1683
1684 void objerror(string s)
1685 {
1686     make_safe_for_remove(self);
1687     builtin_objerror(s);
1688 }
1689
1690 .float remove_except_protected_forbidden;
1691 void remove_except_protected(entity e)
1692 {
1693         if(e.remove_except_protected_forbidden)
1694                 error("not allowed to remove this at this point");
1695         builtin_remove(e);
1696 }
1697
1698 void remove_unsafely(entity e)
1699 {
1700     if(e.classname == "spike")
1701         error("Removing spikes is forbidden (crylink bug), please report");
1702     builtin_remove(e);
1703 }
1704
1705 void remove_safely(entity e)
1706 {
1707     make_safe_for_remove(e);
1708     builtin_remove(e);
1709 }
1710
1711 void InitializeEntity(entity e, void(void) func, float order)
1712 {
1713     entity prev, cur;
1714
1715     if (!e || e.initialize_entity)
1716     {
1717         // make a proxy initializer entity
1718         entity e_old;
1719         e_old = e;
1720         e = spawn();
1721         e.classname = "initialize_entity";
1722         e.enemy = e_old;
1723     }
1724
1725     e.initialize_entity = func;
1726     e.initialize_entity_order = order;
1727
1728     cur = initialize_entity_first;
1729     for (;;)
1730     {
1731         if (!cur || cur.initialize_entity_order > order)
1732         {
1733             // insert between prev and cur
1734             if (prev)
1735                 prev.initialize_entity_next = e;
1736             else
1737                 initialize_entity_first = e;
1738             e.initialize_entity_next = cur;
1739             return;
1740         }
1741         prev = cur;
1742         cur = cur.initialize_entity_next;
1743     }
1744 }
1745 void InitializeEntitiesRun()
1746 {
1747     entity startoflist;
1748     startoflist = initialize_entity_first;
1749     initialize_entity_first = world;
1750     remove = remove_except_protected;
1751     for (self = startoflist; self; self = self.initialize_entity_next)
1752     {
1753         self.remove_except_protected_forbidden = 1;
1754     }
1755     for (self = startoflist; self; )
1756     {
1757         entity e;
1758         var void(void) func;
1759         e = self.initialize_entity_next;
1760         func = self.initialize_entity;
1761         self.initialize_entity_order = 0;
1762         self.initialize_entity = func_null;
1763         self.initialize_entity_next = world;
1764         self.remove_except_protected_forbidden = 0;
1765         if (self.classname == "initialize_entity")
1766         {
1767             entity e_old;
1768             e_old = self.enemy;
1769             builtin_remove(self);
1770             self = e_old;
1771         }
1772         //dprint("Delayed initialization: ", self.classname, "\n");
1773         if(func != func_null)
1774             func();
1775         else
1776         {
1777             eprint(self);
1778             backtrace(strcat("Null function in: ", self.classname, "\n"));
1779         }
1780         self = e;
1781     }
1782     remove = remove_unsafely;
1783 }
1784
1785 .float uncustomizeentityforclient_set;
1786 .void(void) uncustomizeentityforclient;
1787 void(void) SUB_Nullpointer = #0;
1788 void UncustomizeEntitiesRun()
1789 {
1790     entity oldself;
1791     oldself = self;
1792     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1793         self.uncustomizeentityforclient();
1794     self = oldself;
1795 }
1796 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1797 {
1798     e.customizeentityforclient = customizer;
1799     e.uncustomizeentityforclient = uncustomizer;
1800     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1801 }
1802
1803 .float nottargeted;
1804 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1805
1806 void() SUB_Remove;
1807 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1808 {
1809     vector mi, ma;
1810
1811     if (e.classname == "")
1812         e.classname = "net_linked";
1813
1814     if (e.model == "" || self.modelindex == 0)
1815     {
1816         mi = e.mins;
1817         ma = e.maxs;
1818         setmodel(e, "null");
1819         setsize(e, mi, ma);
1820     }
1821
1822     e.SendEntity = sendfunc;
1823     e.SendFlags = 0xFFFFFF;
1824
1825     if (!docull)
1826         e.effects |= EF_NODEPTHTEST;
1827
1828     if (dt)
1829     {
1830         e.nextthink = time + dt;
1831         e.think = SUB_Remove;
1832     }
1833 }
1834
1835 void adaptor_think2touch()
1836 {
1837     entity o;
1838     o = other;
1839     other = world;
1840     self.touch();
1841     other = o;
1842 }
1843
1844 void adaptor_think2use()
1845 {
1846     entity o, a;
1847     o = other;
1848     a = activator;
1849     activator = world;
1850     other = world;
1851     self.use();
1852     other = o;
1853     activator = a;
1854 }
1855
1856 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1857 {
1858         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1859                 self.projectiledeathtype |= HITTYPE_SPLASH;
1860         adaptor_think2use();
1861 }
1862
1863 // deferred dropping
1864 void DropToFloor_Handler()
1865 {
1866     builtin_droptofloor();
1867     self.dropped_origin = self.origin;
1868 }
1869
1870 void droptofloor()
1871 {
1872     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1873 }
1874
1875
1876
1877 float trace_hits_box_a0, trace_hits_box_a1;
1878
1879 float trace_hits_box_1d(float end, float thmi, float thma)
1880 {
1881     if (end == 0)
1882     {
1883         // just check if x is in range
1884         if (0 < thmi)
1885             return FALSE;
1886         if (0 > thma)
1887             return FALSE;
1888     }
1889     else
1890     {
1891         // do the trace with respect to x
1892         // 0 -> end has to stay in thmi -> thma
1893         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1894         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1895         if (trace_hits_box_a0 > trace_hits_box_a1)
1896             return FALSE;
1897     }
1898     return TRUE;
1899 }
1900
1901 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1902 {
1903     end -= start;
1904     thmi -= start;
1905     thma -= start;
1906     // now it is a trace from 0 to end
1907
1908     trace_hits_box_a0 = 0;
1909     trace_hits_box_a1 = 1;
1910
1911     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1912         return FALSE;
1913     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1914         return FALSE;
1915     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1916         return FALSE;
1917
1918     return TRUE;
1919 }
1920
1921 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1922 {
1923     return trace_hits_box(start, end, thmi - ma, thma - mi);
1924 }
1925
1926 float SUB_NoImpactCheck()
1927 {
1928         // zero hitcontents = this is not the real impact, but either the
1929         // mirror-impact of something hitting the projectile instead of the
1930         // projectile hitting the something, or a touchareagrid one. Neither of
1931         // these stop the projectile from moving, so...
1932         if(trace_dphitcontents == 0)
1933         {
1934                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1935                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1936                 checkclient();
1937         }
1938     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1939         return 1;
1940     if (other == world && self.size != '0 0 0')
1941     {
1942         vector tic;
1943         tic = self.velocity * sys_frametime;
1944         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1945         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1946         if (trace_fraction >= 1)
1947         {
1948             dprint("Odd... did not hit...?\n");
1949         }
1950         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1951         {
1952             dprint("Detected and prevented the sky-grapple bug.\n");
1953             return 1;
1954         }
1955     }
1956
1957     return 0;
1958 }
1959
1960 #define SUB_OwnerCheck() (other && (other == self.owner))
1961
1962 void RemoveGrapplingHook(entity pl);
1963 void W_Crylink_Dequeue(entity e);
1964 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1965 {
1966         if(SUB_OwnerCheck())
1967                 return TRUE;
1968         if(SUB_NoImpactCheck())
1969         {
1970                 if(self.classname == "grapplinghook")
1971                         RemoveGrapplingHook(self.realowner);
1972                 else if(self.classname == "spike")
1973                 {
1974                         W_Crylink_Dequeue(self);
1975                         remove(self);
1976                 }
1977                 else
1978                         remove(self);
1979                 return TRUE;
1980         }
1981         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1982                 UpdateCSQCProjectile(self);
1983         return FALSE;
1984 }
1985 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1986
1987 float MAX_IPBAN_URIS           = 16;
1988
1989 float URI_GET_DISCARD          = 0;
1990 float URI_GET_IPBAN            = 1;
1991 float URI_GET_IPBAN_END        = 16;
1992
1993 void URI_Get_Callback(float id, float status, string data)
1994 {
1995     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
1996     dprint(data);
1997     dprint("\nEnd of data.\n");
1998
1999     if(url_URI_Get_Callback(id, status, data))
2000     {
2001         // handled
2002     }
2003     else if (id == URI_GET_DISCARD)
2004     {
2005         // discard
2006     }
2007     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2008     {
2009         // online ban list
2010         OnlineBanList_URI_Get_Callback(id, status, data);
2011     }
2012     else
2013     {
2014         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2015     }
2016 }
2017
2018 string uid2name(string myuid) {
2019         string s;
2020         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2021
2022         // FIXME remove this later after 0.6 release
2023         // convert old style broken records to correct style
2024         if(s == "")
2025         {
2026                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2027                 if(s != "")
2028                 {
2029                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2030                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2031                 }
2032         }
2033
2034         if(s == "")
2035                 s = "^1Unregistered Player";
2036         return s;
2037 }
2038
2039 float race_readTime(string map, float pos)
2040 {
2041         string rr;
2042         if(g_cts)
2043                 rr = CTS_RECORD;
2044         else
2045                 rr = RACE_RECORD;
2046
2047         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2048 }
2049
2050 string race_readUID(string map, float pos)
2051 {
2052         string rr;
2053         if(g_cts)
2054                 rr = CTS_RECORD;
2055         else
2056                 rr = RACE_RECORD;
2057
2058         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2059 }
2060
2061 float race_readPos(string map, float t) {
2062         float i;
2063         for (i = 1; i <= RANKINGS_CNT; ++i)
2064                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2065                         return i;
2066
2067         return 0; // pos is zero if unranked
2068 }
2069
2070 void race_writeTime(string map, float t, string myuid)
2071 {
2072         string rr;
2073         if(g_cts)
2074                 rr = CTS_RECORD;
2075         else
2076                 rr = RACE_RECORD;
2077
2078         float newpos;
2079         newpos = race_readPos(map, t);
2080
2081         float i, prevpos;
2082         for(i = 1; i <= RANKINGS_CNT; ++i)
2083         {
2084                 if(race_readUID(map, i) == myuid)
2085                         prevpos = i;
2086         }
2087         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2088                 for (i = prevpos; i > newpos; --i) {
2089                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2090                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2091                 }
2092         } else { // player has no ranked record yet
2093                 for (i = RANKINGS_CNT; i > newpos; --i) {
2094                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2095                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2096                 }
2097         }
2098
2099         // store new time itself
2100         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2101         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2102 }
2103
2104 string race_readName(string map, float pos)
2105 {
2106         string rr;
2107         if(g_cts)
2108                 rr = CTS_RECORD;
2109         else
2110                 rr = RACE_RECORD;
2111
2112         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2113 }
2114
2115 string race_placeName(float pos) {
2116         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2117         {
2118                 if(mod(pos, 10) == 1)
2119                         return strcat(ftos(pos), "st");
2120                 else if(mod(pos, 10) == 2)
2121                         return strcat(ftos(pos), "nd");
2122                 else if(mod(pos, 10) == 3)
2123                         return strcat(ftos(pos), "rd");
2124                 else
2125                         return strcat(ftos(pos), "th");
2126         }
2127         else
2128                 return strcat(ftos(pos), "th");
2129 }
2130
2131 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2132 {
2133     float m, i;
2134     vector start, org, delta, end, enddown, mstart;
2135     entity sp;
2136
2137     m = e.dphitcontentsmask;
2138     e.dphitcontentsmask = goodcontents | badcontents;
2139
2140     org = world.mins;
2141     delta = world.maxs - world.mins;
2142
2143     for (i = 0; i < attempts; ++i)
2144     {
2145         start_x = org_x + random() * delta_x;
2146         start_y = org_y + random() * delta_y;
2147         start_z = org_z + random() * delta_z;
2148
2149         // rule 1: start inside world bounds, and outside
2150         // solid, and don't start from somewhere where you can
2151         // fall down to evil
2152         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2153         if (trace_fraction >= 1)
2154             continue;
2155         if (trace_startsolid)
2156             continue;
2157         if (trace_dphitcontents & badcontents)
2158             continue;
2159         if (trace_dphitq3surfaceflags & badsurfaceflags)
2160             continue;
2161
2162         // rule 2: if we are too high, lower the point
2163         if (trace_fraction * delta_z > maxaboveground)
2164             start = trace_endpos + '0 0 1' * maxaboveground;
2165         enddown = trace_endpos;
2166
2167         // rule 3: make sure we aren't outside the map. This only works
2168         // for somewhat well formed maps. A good rule of thumb is that
2169         // the map should have a convex outside hull.
2170         // these can be traceLINES as we already verified the starting box
2171         mstart = start + 0.5 * (e.mins + e.maxs);
2172         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2173         if (trace_fraction >= 1)
2174             continue;
2175         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2176         if (trace_fraction >= 1)
2177             continue;
2178         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2179         if (trace_fraction >= 1)
2180             continue;
2181         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2182         if (trace_fraction >= 1)
2183             continue;
2184         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2185         if (trace_fraction >= 1)
2186             continue;
2187
2188         // rule 4: we must "see" some spawnpoint
2189         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2190                 if(checkpvs(mstart, sp))
2191                         break;
2192         if(!sp)
2193         {
2194                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2195                         if(checkpvs(mstart, sp))
2196                                 break;
2197                 if(!sp)
2198                         continue;
2199         }
2200
2201         // find a random vector to "look at"
2202         end_x = org_x + random() * delta_x;
2203         end_y = org_y + random() * delta_y;
2204         end_z = org_z + random() * delta_z;
2205         end = start + normalize(end - start) * vlen(delta);
2206
2207         // rule 4: start TO end must not be too short
2208         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2209         if (trace_startsolid)
2210             continue;
2211         if (trace_fraction < minviewdistance / vlen(delta))
2212             continue;
2213
2214         // rule 5: don't want to look at sky
2215         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2216             continue;
2217
2218         // rule 6: we must not end up in trigger_hurt
2219         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2220             continue;
2221
2222         break;
2223     }
2224
2225     e.dphitcontentsmask = m;
2226
2227     if (i < attempts)
2228     {
2229         setorigin(e, start);
2230         e.angles = vectoangles(end - start);
2231         dprint("Needed ", ftos(i + 1), " attempts\n");
2232         return TRUE;
2233     }
2234     else
2235         return FALSE;
2236 }
2237
2238 float zcurveparticles_effectno;
2239 vector zcurveparticles_start;
2240 float zcurveparticles_spd;
2241
2242 void endzcurveparticles()
2243 {
2244         if(zcurveparticles_effectno)
2245         {
2246                 // terminator
2247                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2248         }
2249         zcurveparticles_effectno = 0;
2250 }
2251
2252 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2253 {
2254         spd = bound(0, floor(spd / 16), 32767);
2255         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2256         {
2257                 endzcurveparticles();
2258                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2259                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2260                 WriteShort(MSG_BROADCAST, effectno);
2261                 WriteCoord(MSG_BROADCAST, start_x);
2262                 WriteCoord(MSG_BROADCAST, start_y);
2263                 WriteCoord(MSG_BROADCAST, start_z);
2264                 zcurveparticles_effectno = effectno;
2265                 zcurveparticles_start = start;
2266         }
2267         else
2268                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2269         WriteCoord(MSG_BROADCAST, end_x);
2270         WriteCoord(MSG_BROADCAST, end_y);
2271         WriteCoord(MSG_BROADCAST, end_z);
2272         WriteCoord(MSG_BROADCAST, end_dz);
2273         zcurveparticles_spd = spd;
2274 }
2275
2276 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2277 {
2278         float end_dz;
2279         vector vecxy, velxy;
2280
2281         vecxy = end - start;
2282         vecxy_z = 0;
2283         velxy = vel;
2284         velxy_z = 0;
2285
2286         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2287         {
2288                 endzcurveparticles();
2289                 trailparticles(world, effectno, start, end);
2290                 return;
2291         }
2292
2293         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2294         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2295 }
2296
2297 void write_recordmarker(entity pl, float tstart, float dt)
2298 {
2299     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2300
2301     // also write a marker into demo files for demotc-race-record-extractor to find
2302     stuffcmd(pl,
2303              strcat(
2304                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2305                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2306 }
2307
2308 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2309 {
2310         switch(algn)
2311         {
2312                 default:
2313                 case 3: // right
2314                         break;
2315
2316                 case 4: // left
2317                         vecs_y = -vecs_y;
2318                         break;
2319
2320                 case 1:
2321                         if(allowcenter) // 2: allow center handedness
2322                         {
2323                                 // center
2324                                 vecs_y = 0;
2325                                 vecs_z -= 2;
2326                         }
2327                         else
2328                         {
2329                                 // right
2330                         }
2331                         break;
2332
2333                 case 2:
2334                         if(allowcenter) // 2: allow center handedness
2335                         {
2336                                 // center
2337                                 vecs_y = 0;
2338                                 vecs_z -= 2;
2339                         }
2340                         else
2341                         {
2342                                 // left
2343                                 vecs_y = -vecs_y;
2344                         }
2345                         break;
2346         }
2347         return vecs;
2348 }
2349
2350 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2351 {
2352         string s;
2353         vector v;
2354
2355         if (autocvar_g_shootfromeye)
2356         {
2357                 if (visual)
2358                 {
2359                         vecs_y = 0;
2360                         vecs_z -= 2;
2361                 }
2362                 else
2363                 {
2364                         vecs_y = 0;
2365                         vecs_z = 0;
2366                 }
2367         }
2368         else if (autocvar_g_shootfromcenter)
2369         {
2370                 vecs_y = 0;
2371                 vecs_z -= 2;
2372         }
2373         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2374         {
2375                 v = stov(s);
2376                 if (y_is_right)
2377                         v_y = -v_y;
2378                 if (v_x != 0)
2379                         vecs_x = v_x;
2380                 vecs_y = v_y;
2381                 vecs_z = v_z;
2382         }
2383         else if (autocvar_g_shootfromclient)
2384         {
2385                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2386         }
2387         return vecs;
2388 }
2389
2390 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2391 {
2392         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2393 }
2394
2395
2396 void attach_sameorigin(entity e, entity to, string tag)
2397 {
2398     vector org, t_forward, t_left, t_up, e_forward, e_up;
2399     vector org0, ang0;
2400     float tagscale;
2401
2402     ang0 = e.angles;
2403     org0 = e.origin;
2404
2405     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2406     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2407     t_forward = v_forward * tagscale;
2408     t_left = v_right * -tagscale;
2409     t_up = v_up * tagscale;
2410
2411     e.origin_x = org * t_forward;
2412     e.origin_y = org * t_left;
2413     e.origin_z = org * t_up;
2414
2415     // current forward and up directions
2416     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2417                 e.angles = AnglesTransform_FromVAngles(e.angles);
2418         else
2419                 e.angles = AnglesTransform_FromAngles(e.angles);
2420     fixedmakevectors(e.angles);
2421
2422     // untransform forward, up!
2423     e_forward_x = v_forward * t_forward;
2424     e_forward_y = v_forward * t_left;
2425     e_forward_z = v_forward * t_up;
2426     e_up_x = v_up * t_forward;
2427     e_up_y = v_up * t_left;
2428     e_up_z = v_up * t_up;
2429
2430     e.angles = fixedvectoangles2(e_forward, e_up);
2431     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2432                 e.angles = AnglesTransform_ToVAngles(e.angles);
2433         else
2434                 e.angles = AnglesTransform_ToAngles(e.angles);
2435
2436     setattachment(e, to, tag);
2437     setorigin(e, e.origin);
2438 }
2439
2440 void detach_sameorigin(entity e)
2441 {
2442     vector org;
2443     org = gettaginfo(e, 0);
2444     e.angles = fixedvectoangles2(v_forward, v_up);
2445     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2446                 e.angles = AnglesTransform_ToVAngles(e.angles);
2447         else
2448                 e.angles = AnglesTransform_ToAngles(e.angles);
2449     setorigin(e, org);
2450     setattachment(e, world, "");
2451     setorigin(e, e.origin);
2452 }
2453
2454 void follow_sameorigin(entity e, entity to)
2455 {
2456     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2457     e.aiment = to; // make the hole follow bmodel
2458     e.punchangle = to.angles; // the original angles of bmodel
2459     e.view_ofs = e.origin - to.origin; // relative origin
2460     e.v_angle = e.angles - to.angles; // relative angles
2461 }
2462
2463 void unfollow_sameorigin(entity e)
2464 {
2465     e.movetype = MOVETYPE_NONE;
2466 }
2467
2468 entity gettaginfo_relative_ent;
2469 vector gettaginfo_relative(entity e, float tag)
2470 {
2471     if (!gettaginfo_relative_ent)
2472     {
2473         gettaginfo_relative_ent = spawn();
2474         gettaginfo_relative_ent.effects = EF_NODRAW;
2475     }
2476     gettaginfo_relative_ent.model = e.model;
2477     gettaginfo_relative_ent.modelindex = e.modelindex;
2478     gettaginfo_relative_ent.frame = e.frame;
2479     return gettaginfo(gettaginfo_relative_ent, tag);
2480 }
2481
2482 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2483 {
2484     float p;
2485     p = pow(2, chan);
2486     if (pl.soundentity.cnt & p)
2487         return;
2488     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2489     pl.soundentity.cnt |= p;
2490 }
2491
2492 void SoundEntity_StopSound(entity pl, float chan)
2493 {
2494     float p;
2495     p = pow(2, chan);
2496     if (pl.soundentity.cnt & p)
2497     {
2498         stopsoundto(MSG_ALL, pl.soundentity, chan);
2499         pl.soundentity.cnt &~= p;
2500     }
2501 }
2502
2503 void SoundEntity_Attach(entity pl)
2504 {
2505     pl.soundentity = spawn();
2506     pl.soundentity.classname = "soundentity";
2507     pl.soundentity.owner = pl;
2508     setattachment(pl.soundentity, pl, "");
2509     setmodel(pl.soundentity, "null");
2510 }
2511
2512 void SoundEntity_Detach(entity pl)
2513 {
2514     float i;
2515     for (i = 0; i <= 7; ++i)
2516         SoundEntity_StopSound(pl, i);
2517 }
2518
2519 .float scale2;
2520
2521 float modeleffect_SendEntity(entity to, float sf)
2522 {
2523         float f;
2524         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2525
2526         f = 0;
2527         if(self.velocity != '0 0 0')
2528                 f |= 1;
2529         if(self.angles != '0 0 0')
2530                 f |= 2;
2531         if(self.avelocity != '0 0 0')
2532                 f |= 4;
2533
2534         WriteByte(MSG_ENTITY, f);
2535         WriteShort(MSG_ENTITY, self.modelindex);
2536         WriteByte(MSG_ENTITY, self.skin);
2537         WriteByte(MSG_ENTITY, self.frame);
2538         WriteCoord(MSG_ENTITY, self.origin_x);
2539         WriteCoord(MSG_ENTITY, self.origin_y);
2540         WriteCoord(MSG_ENTITY, self.origin_z);
2541         if(f & 1)
2542         {
2543                 WriteCoord(MSG_ENTITY, self.velocity_x);
2544                 WriteCoord(MSG_ENTITY, self.velocity_y);
2545                 WriteCoord(MSG_ENTITY, self.velocity_z);
2546         }
2547         if(f & 2)
2548         {
2549                 WriteCoord(MSG_ENTITY, self.angles_x);
2550                 WriteCoord(MSG_ENTITY, self.angles_y);
2551                 WriteCoord(MSG_ENTITY, self.angles_z);
2552         }
2553         if(f & 4)
2554         {
2555                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2556                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2557                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2558         }
2559         WriteShort(MSG_ENTITY, self.scale * 256.0);
2560         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2561         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2562         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2563         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2564
2565         return TRUE;
2566 }
2567
2568 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2569 {
2570         entity e;
2571         float sz;
2572         e = spawn();
2573         e.classname = "modeleffect";
2574         setmodel(e, m);
2575         e.frame = f;
2576         setorigin(e, o);
2577         e.velocity = v;
2578         e.angles = ang;
2579         e.avelocity = angv;
2580         e.alpha = a;
2581         e.teleport_time = t1;
2582         e.fade_time = t2;
2583         e.skin = s;
2584         if(s0 >= 0)
2585                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2586         else
2587                 e.scale = -s0;
2588         if(s2 >= 0)
2589                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2590         else
2591                 e.scale2 = -s2;
2592         sz = max(e.scale, e.scale2);
2593         setsize(e, e.mins * sz, e.maxs * sz);
2594         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2595 }
2596
2597 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2598 {
2599         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2600 }
2601
2602 float randombit(float bits)
2603 {
2604         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2605                 return bits;
2606
2607         float n, f, b, r;
2608
2609         r = random();
2610         b = 0;
2611         n = 0;
2612
2613         for(f = 1; f <= bits; f *= 2)
2614         {
2615                 if(bits & f)
2616                 {
2617                         ++n;
2618                         r *= n;
2619                         if(r <= 1)
2620                                 b = f;
2621                         else
2622                                 r = (r - 1) / (n - 1);
2623                 }
2624         }
2625
2626         return b;
2627 }
2628
2629 float randombits(float bits, float k, float error_return)
2630 {
2631         float r;
2632         r = 0;
2633         while(k > 0 && bits != r)
2634         {
2635                 r += randombit(bits - r);
2636                 --k;
2637         }
2638         if(error_return)
2639                 if(k > 0)
2640                         return -1; // all
2641         return r;
2642 }
2643
2644 void randombit_test(float bits, float iter)
2645 {
2646         while(iter > 0)
2647         {
2648                 print(ftos(randombit(bits)), "\n");
2649                 --iter;
2650         }
2651 }
2652
2653 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2654 {
2655         if(halflifedist > 0)
2656                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2657         else if(halflifedist < 0)
2658                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2659         else
2660                 return 1;
2661 }
2662
2663
2664
2665
2666 #ifdef RELEASE
2667 #define cvar_string_normal builtin_cvar_string
2668 #define cvar_normal builtin_cvar
2669 #else
2670 string cvar_string_normal(string n)
2671 {
2672         if not(cvar_type(n) & 1)
2673                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2674         return builtin_cvar_string(n);
2675 }
2676
2677 float cvar_normal(string n)
2678 {
2679         return stof(cvar_string_normal(n));
2680 }
2681 #endif
2682 #define cvar_set_normal builtin_cvar_set
2683
2684 void defer_think()
2685 {
2686     entity oself;
2687
2688     oself           = self;
2689     self            = self.owner;
2690     oself.think     = SUB_Remove;
2691     oself.nextthink = time;
2692
2693     oself.use();
2694 }
2695
2696 /*
2697     Execute func() after time + fdelay.
2698     self when func is executed = self when defer is called
2699 */
2700 void defer(float fdelay, void() func)
2701 {
2702     entity e;
2703
2704     e           = spawn();
2705     e.owner     = self;
2706     e.use       = func;
2707     e.think     = defer_think;
2708     e.nextthink = time + fdelay;
2709 }
2710
2711 .string aiment_classname;
2712 .float aiment_deadflag;
2713 void SetMovetypeFollow(entity ent, entity e)
2714 {
2715         // FIXME this may not be warpzone aware
2716         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2717         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2718         ent.aiment = e; // make the hole follow bmodel
2719         ent.punchangle = e.angles; // the original angles of bmodel
2720         ent.view_ofs = ent.origin - e.origin; // relative origin
2721         ent.v_angle = ent.angles - e.angles; // relative angles
2722         ent.aiment_classname = strzone(e.classname);
2723         ent.aiment_deadflag = e.deadflag;
2724 }
2725 void UnsetMovetypeFollow(entity ent)
2726 {
2727         ent.movetype = MOVETYPE_FLY;
2728         PROJECTILE_MAKETRIGGER(ent);
2729         ent.aiment = world;
2730 }
2731 float LostMovetypeFollow(entity ent)
2732 {
2733 /*
2734         if(ent.movetype != MOVETYPE_FOLLOW)
2735                 if(ent.aiment)
2736                         error("???");
2737 */
2738         if(ent.aiment)
2739         {
2740                 if(ent.aiment.classname != ent.aiment_classname)
2741                         return 1;
2742                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2743                         return 1;
2744         }
2745         return 0;
2746 }
2747
2748 float isPushable(entity e)
2749 {
2750         if(e.iscreature)
2751                 return TRUE;
2752         switch(e.classname)
2753         {
2754                 case "body":
2755                 case "droppedweapon":
2756                 case "keepawayball":
2757                 case "nexball_basketball":
2758                 case "nexball_football":
2759                         return TRUE;
2760                 case "bullet": // antilagged bullets can't hit this either
2761                         return FALSE;
2762         }
2763         if (e.projectiledeathtype)
2764                 return TRUE;
2765         return FALSE;
2766 }