qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239     have_team_spawns_forteam[self.team] = 1;
 240
 241     if (autocvar_r_showbboxes)
 242     {
 243         // show where spawnpoints point at too
 244         makevectors(self.angles);
 245         entity e;
 246         e = spawn();
 247         e.classname = "info_player_foo";
 248         setorigin(e, self.origin + v_forward * 24);
 249         setsize(e, '-8 -8 -8', '8 8 8');
 250         e.solid = SOLID_TRIGGER;
 251     }
 252 }
 253
 254 #define strstr strstrofs
 255 /*
 256 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 257 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 258 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 259 // BE CONSTANT OR strzoneD!
 260 float strstr(string haystack, string needle, float offset)
 261 {
 262         float len, endpos;
 263         string found;
 264         len = strlen(needle);
 265         endpos = strlen(haystack) - len;
 266         while(offset <= endpos)
 267         {
 268                 found = substring(haystack, offset, len);
 269                 if(found == needle)
 270                         return offset;
 271                 offset = offset + 1;
 272         }
 273         return -1;
 274 }
 275 */
 276
 277 float NUM_NEAREST_ENTITIES = 4;
 278 entity nearest_entity[NUM_NEAREST_ENTITIES];
 279 float nearest_length[NUM_NEAREST_ENTITIES];
 280 entity findnearest(vector point, .string field, string value, vector axismod)
 281 {
 282     entity localhead;
 283     float i;
 284     float j;
 285     float len;
 286     vector dist;
 287
 288     float num_nearest;
 289     num_nearest = 0;
 290
 291     localhead = find(world, field, value);
 292     while (localhead)
 293     {
 294         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 295             dist = localhead.oldorigin;
 296         else
 297             dist = localhead.origin;
 298         dist = dist - point;
 299         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 300         len = vlen(dist);
 301
 302         for (i = 0; i < num_nearest; ++i)
 303         {
 304             if (len < nearest_length[i])
 305                 break;
 306         }
 307
 308         // now i tells us where to insert at
 309         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 310         if (i < NUM_NEAREST_ENTITIES)
 311         {
 312             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 313             {
 314                 nearest_length[j + 1] = nearest_length[j];
 315                 nearest_entity[j + 1] = nearest_entity[j];
 316             }
 317             nearest_length[i] = len;
 318             nearest_entity[i] = localhead;
 319             if (num_nearest < NUM_NEAREST_ENTITIES)
 320                 num_nearest = num_nearest + 1;
 321         }
 322
 323         localhead = find(localhead, field, value);
 324     }
 325
 326     // now use the first one from our list that we can see
 327     for (i = 0; i < num_nearest; ++i)
 328     {
 329         traceline(point, nearest_entity[i].origin, TRUE, world);
 330         if (trace_fraction == 1)
 331         {
 332             if (i != 0)
 333             {
 334                 dprint("Nearest point (");
 335                 dprint(nearest_entity[0].netname);
 336                 dprint(") is not visible, using a visible one.\n");
 337             }
 338             return nearest_entity[i];
 339         }
 340     }
 341
 342     if (num_nearest == 0)
 343         return world;
 344
 345     dprint("Not seeing any location point, using nearest as fallback.\n");
 346     /* DEBUGGING CODE:
 347     dprint("Candidates were: ");
 348     for(j = 0; j < num_nearest; ++j)
 349     {
 350         if(j != 0)
 351                 dprint(", ");
 352         dprint(nearest_entity[j].netname);
 353     }
 354     dprint("\n");
 355     */
 356
 357     return nearest_entity[0];
 358 }
 359
 360 void spawnfunc_target_location()
 361 {
 362     self.classname = "target_location";
 363     // location name in netname
 364     // eventually support: count, teamgame selectors, line of sight?
 365 };
 366
 367 void spawnfunc_info_location()
 368 {
 369     self.classname = "target_location";
 370     self.message = self.netname;
 371 };
 372
 373 string NearestLocation(vector p)
 374 {
 375     entity loc;
 376     string ret;
 377     ret = "somewhere";
 378     loc = findnearest(p, classname, "target_location", '1 1 1');
 379     if (loc)
 380     {
 381         ret = loc.message;
 382     }
 383     else
 384     {
 385         loc = findnearest(p, target, "###item###", '1 1 4');
 386         if (loc)
 387             ret = loc.netname;
 388     }
 389     return ret;
 390 }
 391
 392 string formatmessage(string msg)
 393 {
 394         float p, p1, p2;
 395         float n;
 396         vector cursor;
 397         entity cursor_ent;
 398         string escape;
 399         string replacement;
 400         p = 0;
 401         n = 7;
 402
 403         WarpZone_crosshair_trace(self);
 404         cursor = trace_endpos;
 405         cursor_ent = trace_ent;
 406
 407         while (1) {
 408                 if (n < 1)
 409                         break; // too many replacements
 410
 411                 n = n - 1;
 412                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 413                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 414
 415                 if (p1 < 0)
 416                         p1 = p2;
 417
 418                 if (p2 < 0)
 419                         p2 = p1;
 420
 421                 p = min(p1, p2);
 422
 423                 if (p < 0)
 424                         break;
 425
 426                 replacement = substring(msg, p, 2);
 427                 escape = substring(msg, p + 1, 1);
 428
 429                 if (escape == "%")
 430                         replacement = "%";
 431                 else if (escape == "\\")
 432                         replacement = "\\";
 433                 else if (escape == "n")
 434                         replacement = "\n";
 435                 else if (escape == "a")
 436                         replacement = ftos(floor(self.armorvalue));
 437                 else if (escape == "h")
 438                         replacement = ftos(floor(self.health));
 439                 else if (escape == "l")
 440                         replacement = NearestLocation(self.origin);
 441                 else if (escape == "y")
 442                         replacement = NearestLocation(cursor);
 443                 else if (escape == "d")
 444                         replacement = NearestLocation(self.death_origin);
 445                 else if (escape == "w") {
 446                         float wep;
 447                         wep = self.weapon;
 448                         if (!wep)
 449                                 wep = self.switchweapon;
 450                         if (!wep)
 451                                 wep = self.cnt;
 452                         replacement = W_Name(wep);
 453                 } else if (escape == "W") {
 454                         if (self.items & IT_SHELLS) replacement = "shells";
 455                         else if (self.items & IT_NAILS) replacement = "bullets";
 456                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 457                         else if (self.items & IT_CELLS) replacement = "cells";
 458                         else replacement = "batteries"; // ;)
 459                 } else if (escape == "x") {
 460                         replacement = cursor_ent.netname;
 461                         if (!replacement || !cursor_ent)
 462                                 replacement = "nothing";
 463                 } else if (escape == "s")
 464                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 465                 else if (escape == "S")
 466                         replacement = ftos(vlen(self.velocity));
 467
 468                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 469                 p = p + strlen(replacement);
 470         }
 471         return msg;
 472 }
 473
 474 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 475         return (value == 0) ? FALSE : TRUE;
 476 }
 477
 478 /*
 479 =============
 480 GetCvars
 481 =============
 482 Called with:
 483   0:  sends the request
 484   >0: receives a cvar from name=argv(f) value=argv(f+1)
 485 */
 486 void GetCvars_handleString(string thisname, float f, .string field, string name)
 487 {
 488         if (f < 0)
 489         {
 490                 if (self.field)
 491                         strunzone(self.field);
 492                 self.field = string_null;
 493         }
 494         else if (f > 0)
 495         {
 496                 if (thisname == name)
 497                 {
 498                         if (self.field)
 499                                 strunzone(self.field);
 500                         self.field = strzone(argv(f + 1));
 501                 }
 502         }
 503         else
 504                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 505 }
 506 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 507 {
 508         GetCvars_handleString(thisname, f, field, name);
 509         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 510                 if (thisname == name)
 511                 {
 512                         string s;
 513                         s = func(strcat1(self.field));
 514                         if (s != self.field)
 515                         {
 516                                 strunzone(self.field);
 517                                 self.field = strzone(s);
 518                         }
 519                 }
 520 }
 521 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 522 {
 523         if (f < 0)
 524         {
 525         }
 526         else if (f > 0)
 527         {
 528                 if (thisname == name)
 529                         self.field = stof(argv(f + 1));
 530         }
 531         else
 532                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 533 }
 534 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 535 {
 536         if (f < 0)
 537         {
 538         }
 539         else if (f > 0)
 540         {
 541                 if (thisname == name)
 542                 {
 543                         if(!self.field)
 544                         {
 545                                 self.field = stof(argv(f + 1));
 546                                 if(!self.field)
 547                                         self.field = -1;
 548                         }
 549                 }
 550         }
 551         else
 552         {
 553                 if(!self.field)
 554                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 555         }
 556 }
 557 float w_getbestweapon(entity e);
 558 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 559 {
 560         string o;
 561         o = W_FixWeaponOrder_ForceComplete(wo);
 562         if(self.weaponorder_byimpulse)
 563         {
 564                 strunzone(self.weaponorder_byimpulse);
 565                 self.weaponorder_byimpulse = string_null;
 566         }
 567         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 568         return o;
 569 }
 570 void GetCvars(float f)
 571 {
 572         string s;
 573
 574         if (f > 0)
 575                 s = strcat1(argv(f));
 576
 577         get_cvars_f = f;
 578         get_cvars_s = s;
 579         MUTATOR_CALLHOOK(GetCvars);
 580         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 581         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 582         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 583         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 584         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 585         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 586         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 587         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 588         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 589         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 597         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 598         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 599         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 600         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 601         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 602         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 603
 604         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 605         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 606
 607 #ifdef ALLOW_FORCEMODELS
 608         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 609         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 610 #endif
 611         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 612         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 613         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 614
 615         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 616         if (f > 0)
 617         {
 618                 if (s == "cl_weaponpriority")
 619                         self.switchweapon = w_getbestweapon(self);
 620                 if (s == "cl_allow_uidtracking")
 621                         PlayerStats_AddPlayer(self);
 622         }
 623 }
 624
 625 void backtrace(string msg)
 626 {
 627     float dev, war;
 628     dev = autocvar_developer;
 629     war = autocvar_prvm_backtraceforwarnings;
 630     cvar_set("developer", "1");
 631     cvar_set("prvm_backtraceforwarnings", "1");
 632     print("\n");
 633     print("--- CUT HERE ---\nWARNING: ");
 634     print(msg);
 635     print("\n");
 636     remove(world); // isn't there any better way to cause a backtrace?
 637     print("\n--- CUT UNTIL HERE ---\n");
 638     cvar_set("developer", ftos(dev));
 639     cvar_set("prvm_backtraceforwarnings", ftos(war));
 640 }
 641
 642 string Team_ColorCode(float teamid)
 643 {
 644     if (teamid == COLOR_TEAM1)
 645         return "^1";
 646     else if (teamid == COLOR_TEAM2)
 647         return "^4";
 648     else if (teamid == COLOR_TEAM3)
 649         return "^3";
 650     else if (teamid == COLOR_TEAM4)
 651         return "^6";
 652     else
 653         return "^7";
 654 }
 655
 656 string Team_ColorName(float t)
 657 {
 658     // fixme: Search for team entities and get their .netname's!
 659     if (t == COLOR_TEAM1)
 660         return "Red";
 661     if (t == COLOR_TEAM2)
 662         return "Blue";
 663     if (t == COLOR_TEAM3)
 664         return "Yellow";
 665     if (t == COLOR_TEAM4)
 666         return "Pink";
 667     return "Neutral";
 668 }
 669
 670 string Team_ColorNameLowerCase(float t)
 671 {
 672     // fixme: Search for team entities and get their .netname's!
 673     if (t == COLOR_TEAM1)
 674         return "red";
 675     if (t == COLOR_TEAM2)
 676         return "blue";
 677     if (t == COLOR_TEAM3)
 678         return "yellow";
 679     if (t == COLOR_TEAM4)
 680         return "pink";
 681     return "neutral";
 682 }
 683
 684 float ColourToNumber(string team_colour)
 685 {
 686         if (team_colour == "red")
 687                 return COLOR_TEAM1;
 688
 689         if (team_colour == "blue")
 690                 return COLOR_TEAM2;
 691
 692         if (team_colour == "yellow")
 693                 return COLOR_TEAM3;
 694
 695         if (team_colour == "pink")
 696                 return COLOR_TEAM4;
 697
 698         if (team_colour == "auto")
 699                 return 0;
 700
 701         return -1;
 702 }
 703
 704 float NumberToTeamNumber(float number)
 705 {
 706         if (number == 1)
 707                 return COLOR_TEAM1;
 708
 709         if (number == 2)
 710                 return COLOR_TEAM2;
 711
 712         if (number == 3)
 713                 return COLOR_TEAM3;
 714
 715         if (number == 4)
 716                 return COLOR_TEAM4;
 717
 718         return -1;
 719 }
 720
 721 #define CENTERPRIO_POINT 1
 722 #define CENTERPRIO_SPAM 2
 723 #define CENTERPRIO_VOTE 4
 724 #define CENTERPRIO_NORMAL 5
 725 #define CENTERPRIO_SHIELDING 7
 726 #define CENTERPRIO_MAPVOTE 9
 727 #define CENTERPRIO_IDLEKICK 50
 728 #define CENTERPRIO_ADMIN 99
 729 .float centerprint_priority;
 730 .float centerprint_expires;
 731 void centerprint_atprio(entity e, float prio, string s)
 732 {
 733     if (intermission_running)
 734         if (prio < CENTERPRIO_MAPVOTE)
 735             return;
 736     if (time > e.centerprint_expires)
 737         e.centerprint_priority = 0;
 738     if (prio >= e.centerprint_priority)
 739     {
 740         e.centerprint_priority = prio;
 741         if (timeoutStatus == 2)
 742             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 743         else
 744             e.centerprint_expires = time + e.cvar_scr_centertime;
 745         centerprint_builtin(e, s);
 746     }
 747 }
 748 void centerprint_expire(entity e, float prio)
 749 {
 750     if (prio == e.centerprint_priority)
 751     {
 752         e.centerprint_priority = 0;
 753         centerprint_builtin(e, "");
 754     }
 755 }
 756 void centerprint(entity e, string s)
 757 {
 758     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 759 }
 760
 761 // decolorizes and team colors the player name when needed
 762 string playername(entity p)
 763 {
 764     string t;
 765     if (teamplay && !intermission_running && p.classname == "player")
 766     {
 767         t = Team_ColorCode(p.team);
 768         return strcat(t, strdecolorize(p.netname));
 769     }
 770     else
 771         return p.netname;
 772 }
 773
 774 vector randompos(vector m1, vector m2)
 775 {
 776     local vector v;
 777     m2 = m2 - m1;
 778     v_x = m2_x * random() + m1_x;
 779     v_y = m2_y * random() + m1_y;
 780     v_z = m2_z * random() + m1_z;
 781     return  v;
 782 };
 783
 784 //#NO AUTOCVARS START
 785
 786 float g_pickup_shells;
 787 float g_pickup_shells_max;
 788 float g_pickup_nails;
 789 float g_pickup_nails_max;
 790 float g_pickup_rockets;
 791 float g_pickup_rockets_max;
 792 float g_pickup_cells;
 793 float g_pickup_cells_max;
 794 float g_pickup_fuel;
 795 float g_pickup_fuel_jetpack;
 796 float g_pickup_fuel_max;
 797 float g_pickup_armorsmall;
 798 float g_pickup_armorsmall_max;
 799 float g_pickup_armorsmall_anyway;
 800 float g_pickup_armormedium;
 801 float g_pickup_armormedium_max;
 802 float g_pickup_armormedium_anyway;
 803 float g_pickup_armorbig;
 804 float g_pickup_armorbig_max;
 805 float g_pickup_armorbig_anyway;
 806 float g_pickup_armorlarge;
 807 float g_pickup_armorlarge_max;
 808 float g_pickup_armorlarge_anyway;
 809 float g_pickup_healthsmall;
 810 float g_pickup_healthsmall_max;
 811 float g_pickup_healthsmall_anyway;
 812 float g_pickup_healthmedium;
 813 float g_pickup_healthmedium_max;
 814 float g_pickup_healthmedium_anyway;
 815 float g_pickup_healthlarge;
 816 float g_pickup_healthlarge_max;
 817 float g_pickup_healthlarge_anyway;
 818 float g_pickup_healthmega;
 819 float g_pickup_healthmega_max;
 820 float g_pickup_healthmega_anyway;
 821 float g_pickup_ammo_anyway;
 822 float g_pickup_weapons_anyway;
 823 float g_weaponarena;
 824 float g_weaponarena_random;
 825 float g_weaponarena_random_with_laser;
 826 string g_weaponarena_list;
 827 float g_weaponspeedfactor;
 828 float g_weaponratefactor;
 829 float g_weapondamagefactor;
 830 float g_weaponforcefactor;
 831 float g_weaponspreadfactor;
 832
 833 float start_weapons;
 834 float start_items;
 835 float start_ammo_shells;
 836 float start_ammo_nails;
 837 float start_ammo_rockets;
 838 float start_ammo_cells;
 839 float start_ammo_fuel;
 840 float start_health;
 841 float start_armorvalue;
 842 float warmup_start_weapons;
 843 float warmup_start_ammo_shells;
 844 float warmup_start_ammo_nails;
 845 float warmup_start_ammo_rockets;
 846 float warmup_start_ammo_cells;
 847 float warmup_start_ammo_fuel;
 848 float warmup_start_health;
 849 float warmup_start_armorvalue;
 850 float g_weapon_stay;
 851 float g_ghost_items;
 852
 853 entity get_weaponinfo(float w);
 854
 855 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 856 {
 857         var float i = weaponinfo.weapon;
 858
 859         if (!i)
 860                 return 0;
 861
 862         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 863
 864         if (t < 0) // "default" weapon selection
 865         {
 866                 if (g_lms || g_ca || allguns)
 867                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 868                 else if(t < -1)
 869                         t = 0;
 870                 else if (g_cts)
 871                         t = (i == WEP_SHOTGUN);
 872                 else if (g_nexball)
 873                         t = 0; // weapon is set a few lines later
 874                 else
 875                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 876                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 877                         t |= (i == WEP_HOOK);
 878         }
 879
 880         // we cannot disable porto in Nexball, we must force it
 881         if(g_nexball && i == WEP_PORTO)
 882                 t = 1;
 883
 884         return t;
 885 }
 886
 887 void readplayerstartcvars()
 888 {
 889         entity e;
 890         float i, j, t;
 891         string s;
 892
 893         // initialize starting values for players
 894         start_weapons = 0;
 895         start_items = 0;
 896         start_ammo_shells = 0;
 897         start_ammo_nails = 0;
 898         start_ammo_rockets = 0;
 899         start_ammo_cells = 0;
 900         start_health = cvar("g_balance_health_start");
 901         start_armorvalue = cvar("g_balance_armor_start");
 902
 903         g_weaponarena = 0;
 904         s = cvar_string("g_weaponarena");
 905         if (s == "0" || s == "")
 906         {
 907                 if(g_lms || g_ca)
 908                         s = "most";
 909         }
 910
 911         if (s == "0" || s == "")
 912         {
 913                 // no arena
 914         }
 915         else if (s == "off")
 916         {
 917                 // forcibly turn off weaponarena
 918         }
 919         else if (s == "all")
 920         {
 921                 g_weaponarena_list = "All Weapons";
 922                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 923                 {
 924                         e = get_weaponinfo(j);
 925                         g_weaponarena |= e.weapons;
 926                         weapon_action(e.weapon, WR_PRECACHE);
 927                 }
 928         }
 929         else if (s == "most")
 930         {
 931                 g_weaponarena_list = "Most Weapons";
 932                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 933                 {
 934                         e = get_weaponinfo(j);
 935                         if (e.spawnflags & WEP_FLAG_NORMAL)
 936                         {
 937                                 g_weaponarena |= e.weapons;
 938                                 weapon_action(e.weapon, WR_PRECACHE);
 939                         }
 940                 }
 941         }
 942         else if (s == "none")
 943         {
 944                 g_weaponarena_list = "No Weapons";
 945                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 946         }
 947         else
 948         {
 949                 t = tokenize_console(s);
 950                 g_weaponarena_list = "";
 951                 for (i = 0; i < t; ++i)
 952                 {
 953                         s = argv(i);
 954                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 955                         {
 956                                 e = get_weaponinfo(j);
 957                                 if (e.netname == s)
 958                                 {
 959                                         g_weaponarena |= e.weapons;
 960                                         weapon_action(e.weapon, WR_PRECACHE);
 961                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 962                                         break;
 963                                 }
 964                         }
 965                         if (j > WEP_LAST)
 966                         {
 967                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 968                         }
 969                 }
 970                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 971         }
 972
 973         if(g_weaponarena)
 974                 g_weaponarena_random = cvar("g_weaponarena_random");
 975         else
 976                 g_weaponarena_random = 0;
 977         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 978
 979         if (g_weaponarena)
 980         {
 981                 start_weapons = g_weaponarena;
 982                 if(!(g_lms || g_ca))
 983                         start_items |= IT_UNLIMITED_AMMO;
 984         }
 985         else if (g_minstagib)
 986         {
 987                 start_health = 100;
 988                 start_armorvalue = 0;
 989                 start_weapons = WEPBIT_MINSTANEX;
 990                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 991                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 992
 993                 if (g_minstagib_invis_alpha <= 0)
 994                         g_minstagib_invis_alpha = -1;
 995         }
 996         else
 997         {
 998                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 999                 {
1000                         e = get_weaponinfo(i);
1001                         if(want_weapon("g_start_weapon_", e, FALSE))
1002                                 start_weapons |= e.weapons;
1003                 }
1004         }
1005
1006         if(!cvar("g_use_ammunition"))
1007                 start_items |= IT_UNLIMITED_AMMO;
1008
1009         if(g_minstagib)
1010         {
1011                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1012                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1013         }
1014         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
1015         {
1016                 start_ammo_rockets = 999;
1017                 start_ammo_shells = 999;
1018                 start_ammo_cells = 999;
1019                 start_ammo_nails = 999;
1020                 start_ammo_fuel = 999;
1021         }
1022         else
1023         {
1024                 if(g_lms || g_ca)
1025                 {
1026                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1027                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1028                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1029                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1030                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1031                 }
1032                 else
1033                 {
1034                         start_ammo_shells = cvar("g_start_ammo_shells");
1035                         start_ammo_nails = cvar("g_start_ammo_nails");
1036                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1037                         start_ammo_cells = cvar("g_start_ammo_cells");
1038                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1039                 }
1040         }
1041
1042         if (g_lms || g_ca)
1043         {
1044                 start_health = cvar("g_lms_start_health");
1045                 start_armorvalue = cvar("g_lms_start_armor");
1046         }
1047
1048         if (inWarmupStage)
1049         {
1050                 warmup_start_ammo_shells = start_ammo_shells;
1051                 warmup_start_ammo_nails = start_ammo_nails;
1052                 warmup_start_ammo_rockets = start_ammo_rockets;
1053                 warmup_start_ammo_cells = start_ammo_cells;
1054                 warmup_start_ammo_fuel = start_ammo_fuel;
1055                 warmup_start_health = start_health;
1056                 warmup_start_armorvalue = start_armorvalue;
1057                 warmup_start_weapons = start_weapons;
1058
1059                 if (!g_weaponarena && !g_minstagib && !g_ca)
1060                 {
1061                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1062                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1063                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1064                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1065                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1066                         warmup_start_health = cvar("g_warmup_start_health");
1067                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1068                         warmup_start_weapons = 0;
1069                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1070                         {
1071                                 e = get_weaponinfo(i);
1072                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1073                                         warmup_start_weapons |= e.weapons;
1074                         }
1075                 }
1076         }
1077
1078         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1079         {
1080                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1081                 start_items |= IT_FUEL_REGEN;
1082                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1083                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1084         }
1085
1086         if (g_jetpack)
1087                 start_items |= IT_JETPACK;
1088
1089         if (g_weapon_stay == 2)
1090         {
1091                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1092                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1093                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1094                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1095                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1096                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1097                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1098                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1099                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1100                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1101         }
1102
1103         MUTATOR_CALLHOOK(SetStartItems);
1104
1105         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1106         {
1107                 e = get_weaponinfo(i);
1108                 if(e.weapons & (start_weapons | warmup_start_weapons))
1109                         weapon_action(e.weapon, WR_PRECACHE);
1110         }
1111
1112         start_ammo_shells = max(0, start_ammo_shells);
1113         start_ammo_nails = max(0, start_ammo_nails);
1114         start_ammo_cells = max(0, start_ammo_cells);
1115         start_ammo_rockets = max(0, start_ammo_rockets);
1116         start_ammo_fuel = max(0, start_ammo_fuel);
1117
1118         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1119         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1120         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1121         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1122         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1123 }
1124
1125 float g_bugrigs;
1126 float g_bugrigs_planar_movement;
1127 float g_bugrigs_planar_movement_car_jumping;
1128 float g_bugrigs_reverse_spinning;
1129 float g_bugrigs_reverse_speeding;
1130 float g_bugrigs_reverse_stopping;
1131 float g_bugrigs_air_steering;
1132 float g_bugrigs_angle_smoothing;
1133 float g_bugrigs_friction_floor;
1134 float g_bugrigs_friction_brake;
1135 float g_bugrigs_friction_air;
1136 float g_bugrigs_accel;
1137 float g_bugrigs_speed_ref;
1138 float g_bugrigs_speed_pow;
1139 float g_bugrigs_steer;
1140
1141 float g_touchexplode;
1142 float g_touchexplode_radius;
1143 float g_touchexplode_damage;
1144 float g_touchexplode_edgedamage;
1145 float g_touchexplode_force;
1146
1147 float sv_autotaunt;
1148 float sv_taunt;
1149
1150 float sv_pitch_min;
1151 float sv_pitch_max;
1152 float sv_pitch_fixyaw;
1153
1154 string GetGametype(); // g_world.qc
1155 void readlevelcvars(void)
1156 {
1157         // first load all the mutators
1158         if(cvar("g_nix"))
1159                 MUTATOR_ADD(mutator_nix);
1160         if(cvar("g_dodging"))
1161                 MUTATOR_ADD(mutator_dodging);
1162         if(cvar("g_rocket_flying"))
1163                 MUTATOR_ADD(mutator_rocketflying);
1164         if(cvar("g_vampire"))
1165                 MUTATOR_ADD(mutator_vampire);
1166
1167         if(cvar("sv_allow_fullbright"))
1168                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1169
1170     g_bugrigs = cvar("g_bugrigs");
1171     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1172     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1173     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1174     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1175     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1176     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1177     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1178     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1179     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1180     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1181     g_bugrigs_accel = cvar("g_bugrigs_accel");
1182     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1183     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1184     g_bugrigs_steer = cvar("g_bugrigs_steer");
1185
1186     g_touchexplode = cvar("g_touchexplode");
1187     g_touchexplode_radius = cvar("g_touchexplode_radius");
1188     g_touchexplode_damage = cvar("g_touchexplode_damage");
1189     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1190     g_touchexplode_force = cvar("g_touchexplode_force");
1191
1192 #ifdef ALLOW_FORCEMODELS
1193         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1194 #endif
1195         sv_loddistance1 = cvar("sv_loddistance1");
1196         sv_loddistance2 = cvar("sv_loddistance2");
1197
1198         if(sv_loddistance2 <= sv_loddistance1)
1199                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1200
1201         sv_clones = cvar("sv_clones");
1202         sv_gentle = cvar("sv_gentle");
1203         sv_foginterval = cvar("sv_foginterval");
1204         g_cloaked = cvar("g_cloaked");
1205     if(g_cts)
1206         g_cloaked = 1; // always enable cloak in CTS
1207         g_jump_grunt = cvar("g_jump_grunt");
1208         g_footsteps = cvar("g_footsteps");
1209         g_grappling_hook = cvar("g_grappling_hook");
1210         g_jetpack = cvar("g_jetpack");
1211         g_midair = cvar("g_midair");
1212         g_minstagib = cvar("g_minstagib");
1213         g_norecoil = cvar("g_norecoil");
1214         g_bloodloss = cvar("g_bloodloss");
1215         sv_maxidle = cvar("sv_maxidle");
1216         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1217         sv_pogostick = cvar("sv_pogostick");
1218         g_ctf_reverse = cvar("g_ctf_reverse");
1219         sv_autotaunt = cvar("sv_autotaunt");
1220         sv_taunt = cvar("sv_taunt");
1221
1222         inWarmupStage = cvar("g_warmup");
1223         g_warmup_limit = cvar("g_warmup_limit");
1224         g_warmup_allguns = cvar("g_warmup_allguns");
1225         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1226
1227         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1228                 inWarmupStage = 0; // these modes cannot work together, sorry
1229
1230         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1231         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1232         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1233         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1234         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1235         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1236         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1237         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1238         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1239         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1240         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1241         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1242
1243         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1244         g_weaponratefactor = cvar("g_weaponratefactor");
1245         g_weapondamagefactor = cvar("g_weapondamagefactor");
1246         g_weaponforcefactor = cvar("g_weaponforcefactor");
1247         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1248
1249         g_pickup_shells = cvar("g_pickup_shells");
1250         g_pickup_shells_max = cvar("g_pickup_shells_max");
1251         g_pickup_nails = cvar("g_pickup_nails");
1252         g_pickup_nails_max = cvar("g_pickup_nails_max");
1253         g_pickup_rockets = cvar("g_pickup_rockets");
1254         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1255         g_pickup_cells = cvar("g_pickup_cells");
1256         g_pickup_cells_max = cvar("g_pickup_cells_max");
1257         g_pickup_fuel = cvar("g_pickup_fuel");
1258         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1259         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1260         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1261         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1262         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1263         g_pickup_armormedium = cvar("g_pickup_armormedium");
1264         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1265         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1266         g_pickup_armorbig = cvar("g_pickup_armorbig");
1267         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1268         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1269         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1270         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1271         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1272         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1273         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1274         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1275         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1276         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1277         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1278         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1279         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1280         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1281         g_pickup_healthmega = cvar("g_pickup_healthmega");
1282         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1283         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1284
1285         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1286         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1287
1288         g_pinata = cvar("g_pinata");
1289
1290     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1291     if(!g_weapon_stay)
1292         g_weapon_stay = cvar("g_weapon_stay");
1293
1294         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1295                 g_weapon_stay = 1;
1296
1297         g_ghost_items = cvar("g_ghost_items");
1298
1299         if(g_ghost_items >= 1)
1300                 g_ghost_items = 0.25; // default alpha value
1301
1302         if not(inWarmupStage && !g_ca)
1303                 game_starttime = cvar("g_start_delay");
1304
1305         sv_pitch_min = cvar("sv_pitch_min");
1306         sv_pitch_max = cvar("sv_pitch_max");
1307         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1308
1309         readplayerstartcvars();
1310 }
1311
1312 //#NO AUTOCVARS END
1313
1314 // Sound functions
1315 string precache_sound (string s) = #19;
1316 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1317 float precache_sound_index (string s) = #19;
1318
1319 #define SND_VOLUME      1
1320 #define SND_ATTENUATION 2
1321 #define SND_LARGEENTITY 8
1322 #define SND_LARGESOUND  16
1323
1324 float sound_allowed(float dest, entity e)
1325 {
1326     // sounds from world may always pass
1327     for (;;)
1328     {
1329         if (e.classname == "body")
1330             e = e.enemy;
1331         if (e.owner && e.owner != e)
1332             e = e.owner;
1333         else
1334             break;
1335     }
1336     // sounds to self may always pass
1337     if (dest == MSG_ONE)
1338         if (e == msg_entity)
1339             return TRUE;
1340     // sounds by players can be removed
1341     if (autocvar_bot_sound_monopoly)
1342         if (clienttype(e) == CLIENTTYPE_REAL)
1343             return FALSE;
1344     // anything else may pass
1345     return TRUE;
1346 }
1347
1348 void sound(entity e, float chan, string samp, float vol, float atten)
1349 {
1350     if (!sound_allowed(MSG_BROADCAST, e))
1351         return;
1352     sound_builtin(e, chan, samp, vol, atten);
1353 }
1354 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1355 {
1356     float entno, idx;
1357
1358     if (!sound_allowed(dest, e))
1359         return;
1360
1361     entno = num_for_edict(e);
1362     idx = precache_sound_index(samp);
1363
1364     float sflags;
1365     sflags = 0;
1366
1367     atten = floor(atten * 64);
1368     vol = floor(vol * 255);
1369
1370     if (vol != 255)
1371         sflags |= SND_VOLUME;
1372     if (atten != 64)
1373         sflags |= SND_ATTENUATION;
1374     if (entno >= 8192 || chan < 0 || chan > 7)
1375         sflags |= SND_LARGEENTITY;
1376     if (idx >= 256)
1377         sflags |= SND_LARGESOUND;
1378
1379     WriteByte(dest, SVC_SOUND);
1380     WriteByte(dest, sflags);
1381     if (sflags & SND_VOLUME)
1382         WriteByte(dest, vol);
1383     if (sflags & SND_ATTENUATION)
1384         WriteByte(dest, atten);
1385     if (sflags & SND_LARGEENTITY)
1386     {
1387         WriteShort(dest, entno);
1388         WriteByte(dest, chan & 0xFF);
1389     }
1390     else
1391     {
1392         WriteShort(dest, entno * 8 + chan);
1393     }
1394     if (sflags & SND_LARGESOUND)
1395         WriteShort(dest, idx);
1396     else
1397         WriteByte(dest, idx);
1398
1399     WriteCoord(dest, o_x);
1400     WriteCoord(dest, o_y);
1401     WriteCoord(dest, o_z);
1402 }
1403 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1404 {
1405     vector o;
1406
1407     if (!sound_allowed(dest, e))
1408         return;
1409
1410     o = e.origin + 0.5 * (e.mins + e.maxs);
1411     soundtoat(dest, e, o, chan, samp, vol, atten);
1412 }
1413 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1414 {
1415     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1416 }
1417 void stopsoundto(float dest, entity e, float chan)
1418 {
1419     float entno;
1420
1421     if (!sound_allowed(dest, e))
1422         return;
1423
1424     entno = num_for_edict(e);
1425
1426     if (entno >= 8192)
1427     {
1428         float idx, sflags;
1429         idx = precache_sound_index("misc/null.wav");
1430         sflags = SND_LARGEENTITY;
1431         if (idx >= 256)
1432             sflags |= SND_LARGESOUND;
1433         WriteByte(dest, SVC_SOUND);
1434         WriteByte(dest, sflags);
1435         WriteShort(dest, entno);
1436         WriteByte(dest, chan);
1437         if (sflags & SND_LARGESOUND)
1438             WriteShort(dest, idx);
1439         else
1440             WriteByte(dest, idx);
1441         WriteCoord(dest, e.origin_x);
1442         WriteCoord(dest, e.origin_y);
1443         WriteCoord(dest, e.origin_z);
1444     }
1445     else
1446     {
1447         WriteByte(dest, SVC_STOPSOUND);
1448         WriteShort(dest, entno * 8 + chan);
1449     }
1450 }
1451 void stopsound(entity e, float chan)
1452 {
1453     if (!sound_allowed(MSG_BROADCAST, e))
1454         return;
1455
1456     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1457     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1458 }
1459
1460 void play2(entity e, string filename)
1461 {
1462     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1463     msg_entity = e;
1464     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1465 }
1466
1467 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1468 .float spamtime;
1469 float spamsound(entity e, float chan, string samp, float vol, float atten)
1470 {
1471     if (!sound_allowed(MSG_BROADCAST, e))
1472         return FALSE;
1473
1474     if (time > e.spamtime)
1475     {
1476         e.spamtime = time;
1477         sound(e, chan, samp, vol, atten);
1478         return TRUE;
1479     }
1480     return FALSE;
1481 }
1482
1483 void play2team(float t, string filename)
1484 {
1485     local entity head;
1486
1487     if (autocvar_bot_sound_monopoly)
1488         return;
1489
1490     FOR_EACH_REALPLAYER(head)
1491     {
1492         if (head.team == t)
1493             play2(head, filename);
1494     }
1495 }
1496
1497 void play2all(string samp)
1498 {
1499     if (autocvar_bot_sound_monopoly)
1500         return;
1501
1502     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1503 }
1504
1505 void PrecachePlayerSounds(string f);
1506 void precache_playermodel(string m)
1507 {
1508         float globhandle, i, n;
1509         string f;
1510
1511         if(substring(m, -9,5) == "_lod1")
1512                 return;
1513         if(substring(m, -9,5) == "_lod2")
1514                 return;
1515         precache_model(m);
1516         if(sv_loddistance1)
1517         {
1518                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1519                 if(fexists(f))
1520                         precache_model(f);
1521                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1522                 if(fexists(f))
1523                         precache_model(f);
1524         }
1525
1526         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1527         if (globhandle < 0)
1528                 return;
1529         n = search_getsize(globhandle);
1530         for (i = 0; i < n; ++i)
1531         {
1532                 //print(search_getfilename(globhandle, i), "\n");
1533                 f = search_getfilename(globhandle, i);
1534                 PrecachePlayerSounds(f);
1535         }
1536         search_end(globhandle);
1537 }
1538 void precache_all_playermodels(string pattern)
1539 {
1540         float globhandle, i, n;
1541         string f;
1542
1543         globhandle = search_begin(pattern, TRUE, FALSE);
1544         if (globhandle < 0)
1545                 return;
1546         n = search_getsize(globhandle);
1547         for (i = 0; i < n; ++i)
1548         {
1549                 //print(search_getfilename(globhandle, i), "\n");
1550                 f = search_getfilename(globhandle, i);
1551                 precache_playermodel(f);
1552         }
1553         search_end(globhandle);
1554 }
1555
1556 void precache()
1557 {
1558     // gamemode related things
1559     precache_model ("models/misc/chatbubble.spr");
1560     if (g_runematch)
1561     {
1562         precache_model ("models/runematch/curse.mdl");
1563         precache_model ("models/runematch/rune.mdl");
1564     }
1565
1566 #ifdef TTURRETS_ENABLED
1567     if (autocvar_g_turrets)
1568         turrets_precash();
1569 #endif
1570
1571     // Precache all player models if desired
1572     if (autocvar_sv_precacheplayermodels)
1573     {
1574         PrecachePlayerSounds("sound/player/default.sounds");
1575         precache_all_playermodels("models/player/*.zym");
1576         precache_all_playermodels("models/player/*.dpm");
1577         precache_all_playermodels("models/player/*.md3");
1578         precache_all_playermodels("models/player/*.psk");
1579         precache_all_playermodels("models/player/*.iqm");
1580     }
1581
1582     if (autocvar_sv_defaultcharacter)
1583     {
1584         string s;
1585         s = autocvar_sv_defaultplayermodel_red;
1586         if (s != "")
1587             precache_playermodel(s);
1588         s = autocvar_sv_defaultplayermodel_blue;
1589         if (s != "")
1590             precache_playermodel(s);
1591         s = autocvar_sv_defaultplayermodel_yellow;
1592         if (s != "")
1593             precache_playermodel(s);
1594         s = autocvar_sv_defaultplayermodel_pink;
1595         if (s != "")
1596             precache_playermodel(s);
1597         s = autocvar_sv_defaultplayermodel;
1598         if (s != "")
1599             precache_playermodel(s);
1600     }
1601
1602     if (g_footsteps)
1603     {
1604         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1605         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1606     }
1607
1608     // gore and miscellaneous sounds
1609     //precache_sound ("misc/h2ohit.wav");
1610     precache_model ("models/hook.md3");
1611     precache_sound ("misc/armorimpact.wav");
1612     precache_sound ("misc/bodyimpact1.wav");
1613     precache_sound ("misc/bodyimpact2.wav");
1614     precache_sound ("misc/gib.wav");
1615     precache_sound ("misc/gib_splat01.wav");
1616     precache_sound ("misc/gib_splat02.wav");
1617     precache_sound ("misc/gib_splat03.wav");
1618     precache_sound ("misc/gib_splat04.wav");
1619     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1620     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1621     precache_sound ("misc/null.wav");
1622     precache_sound ("misc/spawn.wav");
1623     precache_sound ("misc/talk.wav");
1624     precache_sound ("misc/teleport.wav");
1625     precache_sound ("misc/poweroff.wav");
1626     precache_sound ("player/lava.wav");
1627     precache_sound ("player/slime.wav");
1628
1629     if (g_jetpack)
1630         precache_sound ("misc/jetpack_fly.wav");
1631
1632     precache_model ("models/sprites/0.spr32");
1633     precache_model ("models/sprites/1.spr32");
1634     precache_model ("models/sprites/2.spr32");
1635     precache_model ("models/sprites/3.spr32");
1636     precache_model ("models/sprites/4.spr32");
1637     precache_model ("models/sprites/5.spr32");
1638     precache_model ("models/sprites/6.spr32");
1639     precache_model ("models/sprites/7.spr32");
1640     precache_model ("models/sprites/8.spr32");
1641     precache_model ("models/sprites/9.spr32");
1642     precache_model ("models/sprites/10.spr32");
1643
1644     // common weapon precaches
1645         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1646     precache_sound ("weapons/weapon_switch.wav");
1647     precache_sound ("weapons/weaponpickup.wav");
1648     precache_sound ("weapons/unavailable.wav");
1649     precache_sound ("weapons/dryfire.wav");
1650     if (g_grappling_hook)
1651     {
1652         precache_sound ("weapons/hook_fire.wav"); // hook
1653         precache_sound ("weapons/hook_impact.wav"); // hook
1654     }
1655
1656     if(autocvar_sv_precacheweapons)
1657     {
1658         //precache weapon models/sounds
1659         local float wep;
1660         wep = WEP_FIRST;
1661         while (wep <= WEP_LAST)
1662         {
1663             weapon_action(wep, WR_PRECACHE);
1664             wep = wep + 1;
1665         }
1666     }
1667
1668     precache_model("models/elaser.mdl");
1669     precache_model("models/laser.mdl");
1670     precache_model("models/ebomb.mdl");
1671
1672 #if 0
1673     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1674
1675     if (!self.noise && self.music) // quake 3 uses the music field
1676         self.noise = self.music;
1677
1678     // plays music for the level if there is any
1679     if (self.noise)
1680     {
1681         precache_sound (self.noise);
1682         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1683     }
1684 #endif
1685 }
1686
1687 // sorry, but using \ in macros breaks line numbers
1688 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1689 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1690 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1691
1692 // WARNING: this kills the trace globals
1693 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1694 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1695
1696 #define INITPRIO_FIRST              0
1697 #define INITPRIO_GAMETYPE           0
1698 #define INITPRIO_GAMETYPE_FALLBACK  1
1699 #define INITPRIO_FINDTARGET        10
1700 #define INITPRIO_DROPTOFLOOR       20
1701 #define INITPRIO_SETLOCATION       90
1702 #define INITPRIO_LINKDOORS         91
1703 #define INITPRIO_LAST              99
1704
1705 .void(void) initialize_entity;
1706 .float initialize_entity_order;
1707 .entity initialize_entity_next;
1708 entity initialize_entity_first;
1709
1710 void make_safe_for_remove(entity e)
1711 {
1712     if (e.initialize_entity)
1713     {
1714         entity ent, prev;
1715         for (ent = initialize_entity_first; ent; )
1716         {
1717             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1718             {
1719                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1720                 // skip it in linked list
1721                 if (prev)
1722                 {
1723                     prev.initialize_entity_next = ent.initialize_entity_next;
1724                     ent = prev.initialize_entity_next;
1725                 }
1726                 else
1727                 {
1728                     initialize_entity_first = ent.initialize_entity_next;
1729                     ent = initialize_entity_first;
1730                 }
1731             }
1732             else
1733             {
1734                 prev = ent;
1735                 ent = ent.initialize_entity_next;
1736             }
1737         }
1738     }
1739 }
1740
1741 void objerror(string s)
1742 {
1743     make_safe_for_remove(self);
1744     objerror_builtin(s);
1745 }
1746
1747 .float remove_except_protected_forbidden;
1748 void remove_except_protected(entity e)
1749 {
1750         if(e.remove_except_protected_forbidden)
1751                 error("not allowed to remove this at this point");
1752         remove_builtin(e);
1753 }
1754
1755 void remove_unsafely(entity e)
1756 {
1757     remove_builtin(e);
1758 }
1759
1760 void remove_safely(entity e)
1761 {
1762     make_safe_for_remove(e);
1763     remove_builtin(e);
1764 }
1765
1766 void InitializeEntity(entity e, void(void) func, float order)
1767 {
1768     entity prev, cur;
1769
1770     if (!e || e.initialize_entity)
1771     {
1772         // make a proxy initializer entity
1773         entity e_old;
1774         e_old = e;
1775         e = spawn();
1776         e.classname = "initialize_entity";
1777         e.enemy = e_old;
1778     }
1779
1780     e.initialize_entity = func;
1781     e.initialize_entity_order = order;
1782
1783     cur = initialize_entity_first;
1784     for (;;)
1785     {
1786         if (!cur || cur.initialize_entity_order > order)
1787         {
1788             // insert between prev and cur
1789             if (prev)
1790                 prev.initialize_entity_next = e;
1791             else
1792                 initialize_entity_first = e;
1793             e.initialize_entity_next = cur;
1794             return;
1795         }
1796         prev = cur;
1797         cur = cur.initialize_entity_next;
1798     }
1799 }
1800 void InitializeEntitiesRun()
1801 {
1802     entity startoflist;
1803     startoflist = initialize_entity_first;
1804     initialize_entity_first = world;
1805     remove = remove_except_protected;
1806     for (self = startoflist; self; self = self.initialize_entity_next)
1807     {
1808         self.remove_except_protected_forbidden = 1;
1809     }
1810     for (self = startoflist; self; )
1811     {
1812         entity e;
1813         var void(void) func;
1814         e = self.initialize_entity_next;
1815         func = self.initialize_entity;
1816         self.initialize_entity_order = 0;
1817         self.initialize_entity = func_null;
1818         self.initialize_entity_next = world;
1819         self.remove_except_protected_forbidden = 0;
1820         if (self.classname == "initialize_entity")
1821         {
1822             entity e_old;
1823             e_old = self.enemy;
1824             remove_builtin(self);
1825             self = e_old;
1826         }
1827         //dprint("Delayed initialization: ", self.classname, "\n");
1828         if(func != func_null)
1829             func();
1830         else
1831         {
1832             eprint(self);
1833             backtrace(strcat("Null function in: ", self.classname, "\n"));
1834         }
1835         self = e;
1836     }
1837     remove = remove_unsafely;
1838 }
1839
1840 .float uncustomizeentityforclient_set;
1841 .void(void) uncustomizeentityforclient;
1842 void(void) SUB_Nullpointer = #0;
1843 void UncustomizeEntitiesRun()
1844 {
1845     entity oldself;
1846     oldself = self;
1847     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1848         self.uncustomizeentityforclient();
1849     self = oldself;
1850 }
1851 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1852 {
1853     e.customizeentityforclient = customizer;
1854     e.uncustomizeentityforclient = uncustomizer;
1855     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1856 }
1857
1858 .float nottargeted;
1859 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1860
1861 void() SUB_Remove;
1862 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1863 {
1864     vector mi, ma;
1865
1866     if (e.classname == "")
1867         e.classname = "net_linked";
1868
1869     if (e.model == "" || self.modelindex == 0)
1870     {
1871         mi = e.mins;
1872         ma = e.maxs;
1873         setmodel(e, "null");
1874         setsize(e, mi, ma);
1875     }
1876
1877     e.SendEntity = sendfunc;
1878     e.SendFlags = 0xFFFFFF;
1879
1880     if (!docull)
1881         e.effects |= EF_NODEPTHTEST;
1882
1883     if (dt)
1884     {
1885         e.nextthink = time + dt;
1886         e.think = SUB_Remove;
1887     }
1888 }
1889
1890 void adaptor_think2touch()
1891 {
1892     entity o;
1893     o = other;
1894     other = world;
1895     self.touch();
1896     other = o;
1897 }
1898
1899 void adaptor_think2use()
1900 {
1901     entity o, a;
1902     o = other;
1903     a = activator;
1904     activator = world;
1905     other = world;
1906     self.use();
1907     other = o;
1908     activator = a;
1909 }
1910
1911 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1912 {
1913         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1914                 self.projectiledeathtype |= HITTYPE_SPLASH;
1915         adaptor_think2use();
1916 }
1917
1918 // deferred dropping
1919 void DropToFloor_Handler()
1920 {
1921     droptofloor_builtin();
1922     self.dropped_origin = self.origin;
1923 }
1924
1925 void droptofloor()
1926 {
1927     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1928 }
1929
1930
1931
1932 float trace_hits_box_a0, trace_hits_box_a1;
1933
1934 float trace_hits_box_1d(float end, float thmi, float thma)
1935 {
1936     if (end == 0)
1937     {
1938         // just check if x is in range
1939         if (0 < thmi)
1940             return FALSE;
1941         if (0 > thma)
1942             return FALSE;
1943     }
1944     else
1945     {
1946         // do the trace with respect to x
1947         // 0 -> end has to stay in thmi -> thma
1948         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1949         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1950         if (trace_hits_box_a0 > trace_hits_box_a1)
1951             return FALSE;
1952     }
1953     return TRUE;
1954 }
1955
1956 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1957 {
1958     end -= start;
1959     thmi -= start;
1960     thma -= start;
1961     // now it is a trace from 0 to end
1962
1963     trace_hits_box_a0 = 0;
1964     trace_hits_box_a1 = 1;
1965
1966     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1967         return FALSE;
1968     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1969         return FALSE;
1970     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1971         return FALSE;
1972
1973     return TRUE;
1974 }
1975
1976 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1977 {
1978     return trace_hits_box(start, end, thmi - ma, thma - mi);
1979 }
1980
1981 float SUB_NoImpactCheck()
1982 {
1983         // zero hitcontents = this is not the real impact, but either the
1984         // mirror-impact of something hitting the projectile instead of the
1985         // projectile hitting the something, or a touchareagrid one. Neither of
1986         // these stop the projectile from moving, so...
1987         if(trace_dphitcontents == 0)
1988         {
1989                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1990                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1991                 checkclient();
1992         }
1993     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1994         return 1;
1995     if (other == world && self.size != '0 0 0')
1996     {
1997         vector tic;
1998         tic = self.velocity * sys_frametime;
1999         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2000         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2001         if (trace_fraction >= 1)
2002         {
2003             dprint("Odd... did not hit...?\n");
2004         }
2005         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2006         {
2007             dprint("Detected and prevented the sky-grapple bug.\n");
2008             return 1;
2009         }
2010     }
2011
2012     return 0;
2013 }
2014
2015 #define SUB_OwnerCheck() (other && (other == self.owner))
2016
2017 void RemoveGrapplingHook(entity pl);
2018 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2019 {
2020         if(SUB_OwnerCheck())
2021                 return TRUE;
2022         if(SUB_NoImpactCheck())
2023         {
2024                 if(self.classname == "grapplinghook")
2025                         RemoveGrapplingHook(self.realowner);
2026                 else
2027                         remove(self);
2028                 return TRUE;
2029         }
2030         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2031                 UpdateCSQCProjectileNextFrame(self);
2032         return FALSE;
2033 }
2034 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2035
2036 float MAX_IPBAN_URIS           = 16;
2037
2038 float URI_GET_DISCARD          = 0;
2039 float URI_GET_IPBAN            = 1;
2040 float URI_GET_IPBAN_END        = 16;
2041 float URI_GET_PLAYERSTATS_SENT = 17;
2042
2043 void URI_Get_Callback(float id, float status, string data)
2044 {
2045     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2046     dprint(data);
2047     dprint("\nEnd of data.\n");
2048
2049     if (id == URI_GET_DISCARD)
2050     {
2051         // discard
2052     }
2053     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2054     {
2055         // online ban list
2056         OnlineBanList_URI_Get_Callback(id, status, data);
2057     }
2058     else if (id == URI_GET_PLAYERSTATS_SENT)
2059     {
2060         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2061     }
2062     else
2063     {
2064         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2065     }
2066 }
2067
2068 void print_to(entity e, string s)
2069 {
2070     if (e)
2071         sprint(e, strcat(s, "\n"));
2072     else
2073         print(s, "\n");
2074 }
2075
2076 string uid2name(string myuid) {
2077         string s;
2078         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2079
2080         if(s == "")
2081                 s = "^1Unregistered Player";
2082         return s;
2083 }
2084
2085 float race_readTime(string map, float pos)
2086 {
2087         string rr;
2088         if(g_cts)
2089                 rr = CTS_RECORD;
2090         else
2091                 rr = RACE_RECORD;
2092
2093         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2094 }
2095
2096 string race_readUID(string map, float pos)
2097 {
2098         string rr;
2099         if(g_cts)
2100                 rr = CTS_RECORD;
2101         else
2102                 rr = RACE_RECORD;
2103
2104         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2105 }
2106
2107 float race_readPos(string map, float t) {
2108         float i;
2109         for (i = 1; i <= RANKINGS_CNT; ++i)
2110                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2111                         return i;
2112
2113         return 0; // pos is zero if unranked
2114 }
2115
2116 void race_writeTime(string map, float t, string myuid)
2117 {
2118         string rr;
2119         if(g_cts)
2120                 rr = CTS_RECORD;
2121         else
2122                 rr = RACE_RECORD;
2123
2124         float newpos;
2125         newpos = race_readPos(map, t);
2126
2127         float i, prevpos;
2128         for(i = 1; i <= RANKINGS_CNT; ++i)
2129         {
2130                 if(race_readUID(map, i) == myuid)
2131                         prevpos = i;
2132         }
2133         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2134                 for (i = prevpos; i > newpos; --i) {
2135                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2136                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2137                 }
2138         } else { // player has no ranked record yet
2139                 for (i = RANKINGS_CNT; i > newpos; --i) {
2140                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2141                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2142                 }
2143         }
2144
2145         // store new time itself
2146         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2147         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2148 }
2149
2150 string race_readName(string map, float pos)
2151 {
2152         string rr;
2153         if(g_cts)
2154                 rr = CTS_RECORD;
2155         else
2156                 rr = RACE_RECORD;
2157
2158         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2159 }
2160
2161 string race_placeName(float pos) {
2162         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2163         {
2164                 if(mod(pos, 10) == 1)
2165                         return strcat(ftos(pos), "st");
2166                 else if(mod(pos, 10) == 2)
2167                         return strcat(ftos(pos), "nd");
2168                 else if(mod(pos, 10) == 3)
2169                         return strcat(ftos(pos), "rd");
2170                 else
2171                         return strcat(ftos(pos), "th");
2172         }
2173         else
2174                 return strcat(ftos(pos), "th");
2175 }
2176 string getrecords(float page) // 50 records per page
2177 {
2178     float rec;
2179     string h;
2180     float r;
2181     float i;
2182     string s;
2183
2184     rec = 0;
2185
2186     s = "";
2187
2188     if (g_ctf)
2189     {
2190         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2191         {
2192             if (MapInfo_Get_ByID(i))
2193             {
2194                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2195                 if (r == 0)
2196                     continue;
2197                 // TODO: uid2name
2198                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2199                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2200                 ++rec;
2201             }
2202         }
2203     }
2204
2205     if (g_race)
2206     {
2207         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2208         {
2209             if (MapInfo_Get_ByID(i))
2210             {
2211                 r = race_readTime(MapInfo_Map_bspname, 1);
2212                 if (r == 0)
2213                     continue;
2214                 h = race_readName(MapInfo_Map_bspname, 1);
2215                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2216                 ++rec;
2217             }
2218         }
2219     }
2220
2221     if (g_cts)
2222     {
2223         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2224         {
2225             if (MapInfo_Get_ByID(i))
2226             {
2227                 r = race_readTime(MapInfo_Map_bspname, 1);
2228                 if (r == 0)
2229                     continue;
2230                 h = race_readName(MapInfo_Map_bspname, 1);
2231                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2232                 ++rec;
2233             }
2234         }
2235     }
2236
2237     MapInfo_ClearTemps();
2238
2239     if (s == "" && page == 0)
2240         return "No records are available on this server.\n";
2241     else
2242         return s;
2243 }
2244
2245 string getrankings()
2246 {
2247     string n;
2248     float t;
2249     float i;
2250     string s;
2251     string p;
2252     string map;
2253
2254     s = "";
2255
2256     map = GetMapname();
2257
2258     for (i = 1; i <= RANKINGS_CNT; ++i)
2259     {
2260         t = race_readTime(map, i);
2261         if (t == 0)
2262             continue;
2263         n = race_readName(map, i);
2264         p = race_placeName(i);
2265         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2266     }
2267
2268     MapInfo_ClearTemps();
2269
2270     if (s == "")
2271         return strcat("No records are available for the map: ", map, "\n");
2272     else
2273         return strcat("Records for ", map, ":\n", s);
2274 }
2275
2276 #define LADDER_FIRSTPOINT 100
2277 #define LADDER_CNT 10
2278         // position X still gives LADDER_FIRSTPOINT/X points
2279 #define LADDER_SIZE 30
2280         // ladder shows the top X players
2281 string top_uids[LADDER_SIZE];
2282 float top_scores[LADDER_SIZE];
2283 string getladder()
2284 {
2285     float i, j, k, uidcnt;
2286     string s, temp_s;
2287
2288     s = "";
2289     temp_s = "";
2290
2291     string rr;
2292     if(g_cts)
2293         rr = CTS_RECORD;
2294     else
2295         rr = RACE_RECORD;
2296
2297     string myuid;
2298
2299     for (k = 0; k < MapInfo_count; ++k)
2300     {
2301         if (MapInfo_Get_ByID(k))
2302         {
2303                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2304                         if(i == 0) // speed award
2305                         {
2306                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2307                                         continue;
2308
2309                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2310                         }
2311                         else // normal record, if it exists (else break)
2312                         {
2313                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2314                                         continue;
2315
2316                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2317                         }
2318
2319                         // string s contains:
2320                         // arg 0 = # of speed recs
2321                         // arg 1 = # of 1st place recs
2322                         // arg 2 = # of 2nd place recs
2323                         // ... etc
2324                         // LADDER_CNT+1 = total points
2325
2326                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2327                         if (temp_s == "")
2328                         {
2329                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2330                             ++uidcnt;
2331                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2332                             {
2333                                 if(j != LADDER_CNT + 1)
2334                                     temp_s = strcat(temp_s, "0 ");
2335                                 else
2336                                     temp_s = strcat(temp_s, "0");
2337                             }
2338                         }
2339
2340                         tokenize_console(temp_s);
2341                         s = "";
2342
2343                         if(i == 0) // speed award
2344                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2345                             {
2346                                 if(j == 0) // speed award
2347                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2348                                 else
2349                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2350                             }
2351                         else // record
2352                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2353                             {
2354                                 if(j == 0)
2355                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2356                                 else if(j == i) // wanted rec!
2357                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2358                                 else
2359                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2360                             }
2361
2362                         // total points are (by default) calculated like this:
2363                         // speedrec = floor(100 / 10) = 10 points
2364                         // 1st place = floor(100 / 1) = 100 points
2365                         // 2nd place = floor(100 / 2) = 50 points
2366                         // 3rd place = floor(100 / 3) = 33 points
2367                         // 4th place = floor(100 / 4) = 25 points
2368                         // 5th place = floor(100 / 5) = 20 points
2369                         // ... etc
2370
2371                         if(i == 0)
2372                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2373                         else
2374                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2375
2376                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2377                 }
2378         }
2379     }
2380
2381     float thiscnt;
2382     string thisuid;
2383     for (i = 0; i <= uidcnt; ++i) // for each known uid
2384     {
2385         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2386         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2387         tokenize_console(temp_s);
2388         thiscnt = stof(argv(LADDER_CNT+1));
2389
2390         if(thiscnt > top_scores[LADDER_SIZE-1])
2391         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2392         {
2393             if(thiscnt > top_scores[j])
2394             {
2395                 for (k = LADDER_SIZE-1; k >= j; --k)
2396                 {
2397                     top_uids[k] = top_uids[k-1];
2398                     top_scores[k] = top_scores[k-1];
2399                 }
2400                 top_uids[j] = thisuid;
2401                 top_scores[j] = thiscnt;
2402                 break;
2403             }
2404         }
2405     }
2406
2407     s = "^3-----------------------\n\n";
2408
2409     s = strcat(s, "Pos ^3|");
2410     s = strcat(s, " ^7Total  ^3|");
2411     for (i = 1; i <= LADDER_CNT; ++i)
2412     {
2413         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2414     }
2415     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2416
2417     s = strcat(s, "\n^3----+--------");
2418     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2419     {
2420         s = strcat(s, "+-----");
2421     }
2422 #if LADDER_CNT > 9
2423     for (i = 1; i <= LADDER_CNT - 9; ++i)
2424     {
2425         s = strcat(s, "+------");
2426     }
2427 #endif
2428
2429     s = strcat(s, "+--------------+--------------------\n");
2430
2431     for (i = 0; i < LADDER_SIZE; ++i)
2432     {
2433         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2434         tokenize_console(temp_s);
2435         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2436             continue;
2437         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2438         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2439         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2440         {
2441             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2442         }
2443 #if LADDER_CNT > 9
2444         for (j = 10; j <= LADDER_CNT; ++j)
2445         {
2446             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2447         }
2448 #endif
2449
2450         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2451         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2452     }
2453
2454     MapInfo_ClearTemps();
2455
2456     if (s == "")
2457         return "No ladder on this server!\n";
2458     else
2459         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2460 }
2461
2462
2463 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2464 {
2465     float m, i;
2466     vector start, org, delta, end, enddown, mstart;
2467
2468     m = e.dphitcontentsmask;
2469     e.dphitcontentsmask = goodcontents | badcontents;
2470
2471     org = world.mins;
2472     delta = world.maxs - world.mins;
2473
2474     for (i = 0; i < attempts; ++i)
2475     {
2476         start_x = org_x + random() * delta_x;
2477         start_y = org_y + random() * delta_y;
2478         start_z = org_z + random() * delta_z;
2479
2480         // rule 1: start inside world bounds, and outside
2481         // solid, and don't start from somewhere where you can
2482         // fall down to evil
2483         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2484         if (trace_fraction >= 1)
2485             continue;
2486         if (trace_startsolid)
2487             continue;
2488         if (trace_dphitcontents & badcontents)
2489             continue;
2490         if (trace_dphitq3surfaceflags & badsurfaceflags)
2491             continue;
2492
2493         // rule 2: if we are too high, lower the point
2494         if (trace_fraction * delta_z > maxaboveground)
2495             start = trace_endpos + '0 0 1' * maxaboveground;
2496         enddown = trace_endpos;
2497
2498         // rule 3: make sure we aren't outside the map. This only works
2499         // for somewhat well formed maps. A good rule of thumb is that
2500         // the map should have a convex outside hull.
2501         // these can be traceLINES as we already verified the starting box
2502         mstart = start + 0.5 * (e.mins + e.maxs);
2503         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2504         if (trace_fraction >= 1)
2505             continue;
2506         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2507         if (trace_fraction >= 1)
2508             continue;
2509         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2510         if (trace_fraction >= 1)
2511             continue;
2512         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2513         if (trace_fraction >= 1)
2514             continue;
2515         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2516         if (trace_fraction >= 1)
2517             continue;
2518
2519         // find a random vector to "look at"
2520         end_x = org_x + random() * delta_x;
2521         end_y = org_y + random() * delta_y;
2522         end_z = org_z + random() * delta_z;
2523         end = start + normalize(end - start) * vlen(delta);
2524
2525         // rule 4: start TO end must not be too short
2526         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2527         if (trace_startsolid)
2528             continue;
2529         if (trace_fraction < minviewdistance / vlen(delta))
2530             continue;
2531
2532         // rule 5: don't want to look at sky
2533         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2534             continue;
2535
2536         // rule 6: we must not end up in trigger_hurt
2537         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2538             continue;
2539
2540         break;
2541     }
2542
2543     e.dphitcontentsmask = m;
2544
2545     if (i < attempts)
2546     {
2547         setorigin(e, start);
2548         e.angles = vectoangles(end - start);
2549         dprint("Needed ", ftos(i + 1), " attempts\n");
2550         return TRUE;
2551     }
2552     else
2553         return FALSE;
2554 }
2555
2556 float zcurveparticles_effectno;
2557 vector zcurveparticles_start;
2558 float zcurveparticles_spd;
2559
2560 void endzcurveparticles()
2561 {
2562         if(zcurveparticles_effectno)
2563         {
2564                 // terminator
2565                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2566         }
2567         zcurveparticles_effectno = 0;
2568 }
2569
2570 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2571 {
2572         spd = bound(0, floor(spd / 16), 32767);
2573         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2574         {
2575                 endzcurveparticles();
2576                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2577                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2578                 WriteShort(MSG_BROADCAST, effectno);
2579                 WriteCoord(MSG_BROADCAST, start_x);
2580                 WriteCoord(MSG_BROADCAST, start_y);
2581                 WriteCoord(MSG_BROADCAST, start_z);
2582                 zcurveparticles_effectno = effectno;
2583                 zcurveparticles_start = start;
2584         }
2585         else
2586                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2587         WriteCoord(MSG_BROADCAST, end_x);
2588         WriteCoord(MSG_BROADCAST, end_y);
2589         WriteCoord(MSG_BROADCAST, end_z);
2590         WriteCoord(MSG_BROADCAST, end_dz);
2591         zcurveparticles_spd = spd;
2592 }
2593
2594 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2595 {
2596         float end_dz;
2597         vector vecxy, velxy;
2598
2599         vecxy = end - start;
2600         vecxy_z = 0;
2601         velxy = vel;
2602         velxy_z = 0;
2603
2604         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2605         {
2606                 endzcurveparticles();
2607                 trailparticles(world, effectno, start, end);
2608                 return;
2609         }
2610
2611         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2612         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2613 }
2614
2615 void write_recordmarker(entity pl, float tstart, float dt)
2616 {
2617     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2618
2619     // also write a marker into demo files for demotc-race-record-extractor to find
2620     stuffcmd(pl,
2621              strcat(
2622                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2623                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2624 }
2625
2626 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2627 {
2628         switch(algn)
2629         {
2630                 default:
2631                 case 3: // right
2632                         break;
2633
2634                 case 4: // left
2635                         vecs_y = -vecs_y;
2636                         break;
2637
2638                 case 1:
2639                         if(allowcenter) // 2: allow center handedness
2640                         {
2641                                 // center
2642                                 vecs_y = 0;
2643                                 vecs_z -= 2;
2644                         }
2645                         else
2646                         {
2647                                 // right
2648                         }
2649                         break;
2650
2651                 case 2:
2652                         if(allowcenter) // 2: allow center handedness
2653                         {
2654                                 // center
2655                                 vecs_y = 0;
2656                                 vecs_z -= 2;
2657                         }
2658                         else
2659                         {
2660                                 // left
2661                                 vecs_y = -vecs_y;
2662                         }
2663                         break;
2664         }
2665         return vecs;
2666 }
2667
2668 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2669 {
2670         string s;
2671         vector v;
2672
2673         if (autocvar_g_shootfromeye)
2674         {
2675                 if (visual)
2676                 {
2677                         vecs_y = 0;
2678                         vecs_z -= 2;
2679                 }
2680                 else
2681                 {
2682                         vecs_y = 0;
2683                         vecs_z = 0;
2684                 }
2685         }
2686         else if (autocvar_g_shootfromcenter)
2687         {
2688                 vecs_y = 0;
2689                 vecs_z -= 2;
2690         }
2691         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2692         {
2693                 v = stov(s);
2694                 if (y_is_right)
2695                         v_y = -v_y;
2696                 if (v_x != 0)
2697                         vecs_x = v_x;
2698                 vecs_y = v_y;
2699                 vecs_z = v_z;
2700         }
2701         else if (autocvar_g_shootfromclient)
2702         {
2703                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2704         }
2705         return vecs;
2706 }
2707
2708 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2709 {
2710         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2711 }
2712
2713
2714 void attach_sameorigin(entity e, entity to, string tag)
2715 {
2716     vector org, t_forward, t_left, t_up, e_forward, e_up;
2717     vector org0, ang0;
2718     float tagscale;
2719
2720     ang0 = e.angles;
2721     org0 = e.origin;
2722
2723     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2724     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2725     t_forward = v_forward * tagscale;
2726     t_left = v_right * -tagscale;
2727     t_up = v_up * tagscale;
2728
2729     e.origin_x = org * t_forward;
2730     e.origin_y = org * t_left;
2731     e.origin_z = org * t_up;
2732
2733     // current forward and up directions
2734     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2735                 e.angles = AnglesTransform_FromVAngles(e.angles);
2736         else
2737                 e.angles = AnglesTransform_FromAngles(e.angles);
2738     fixedmakevectors(e.angles);
2739
2740     // untransform forward, up!
2741     e_forward_x = v_forward * t_forward;
2742     e_forward_y = v_forward * t_left;
2743     e_forward_z = v_forward * t_up;
2744     e_up_x = v_up * t_forward;
2745     e_up_y = v_up * t_left;
2746     e_up_z = v_up * t_up;
2747
2748     e.angles = fixedvectoangles2(e_forward, e_up);
2749     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2750                 e.angles = AnglesTransform_ToVAngles(e.angles);
2751         else
2752                 e.angles = AnglesTransform_ToAngles(e.angles);
2753
2754     setattachment(e, to, tag);
2755     setorigin(e, e.origin);
2756 }
2757
2758 void detach_sameorigin(entity e)
2759 {
2760     vector org;
2761     org = gettaginfo(e, 0);
2762     e.angles = fixedvectoangles2(v_forward, v_up);
2763     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2764                 e.angles = AnglesTransform_ToVAngles(e.angles);
2765         else
2766                 e.angles = AnglesTransform_ToAngles(e.angles);
2767     setorigin(e, org);
2768     setattachment(e, world, "");
2769     setorigin(e, e.origin);
2770 }
2771
2772 void follow_sameorigin(entity e, entity to)
2773 {
2774     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2775     e.aiment = to; // make the hole follow bmodel
2776     e.punchangle = to.angles; // the original angles of bmodel
2777     e.view_ofs = e.origin - to.origin; // relative origin
2778     e.v_angle = e.angles - to.angles; // relative angles
2779 }
2780
2781 void unfollow_sameorigin(entity e)
2782 {
2783     e.movetype = MOVETYPE_NONE;
2784 }
2785
2786 entity gettaginfo_relative_ent;
2787 vector gettaginfo_relative(entity e, float tag)
2788 {
2789     if (!gettaginfo_relative_ent)
2790     {
2791         gettaginfo_relative_ent = spawn();
2792         gettaginfo_relative_ent.effects = EF_NODRAW;
2793     }
2794     gettaginfo_relative_ent.model = e.model;
2795     gettaginfo_relative_ent.modelindex = e.modelindex;
2796     gettaginfo_relative_ent.frame = e.frame;
2797     return gettaginfo(gettaginfo_relative_ent, tag);
2798 }
2799
2800 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2801 {
2802     float p;
2803     p = pow(2, chan);
2804     if (pl.soundentity.cnt & p)
2805         return;
2806     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2807     pl.soundentity.cnt |= p;
2808 }
2809
2810 void SoundEntity_StopSound(entity pl, float chan)
2811 {
2812     float p;
2813     p = pow(2, chan);
2814     if (pl.soundentity.cnt & p)
2815     {
2816         stopsoundto(MSG_ALL, pl.soundentity, chan);
2817         pl.soundentity.cnt &~= p;
2818     }
2819 }
2820
2821 void SoundEntity_Attach(entity pl)
2822 {
2823     pl.soundentity = spawn();
2824     pl.soundentity.classname = "soundentity";
2825     pl.soundentity.owner = pl;
2826     setattachment(pl.soundentity, pl, "");
2827     setmodel(pl.soundentity, "null");
2828 }
2829
2830 void SoundEntity_Detach(entity pl)
2831 {
2832     float i;
2833     for (i = 0; i <= 7; ++i)
2834         SoundEntity_StopSound(pl, i);
2835 }
2836
2837
2838 float ParseCommandPlayerSlotTarget_firsttoken;
2839 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2840 {
2841         string s;
2842         entity e, head;
2843         float n;
2844
2845         s = string_null;
2846
2847         ParseCommandPlayerSlotTarget_firsttoken = -1;
2848
2849         if (tokens > idx)
2850         {
2851                 if (substring(argv(idx), 0, 1) == "#")
2852                 {
2853                         s = substring(argv(idx), 1, -1);
2854                         ++idx;
2855                         if (s == "") if (tokens > idx)
2856                         {
2857                                 s = argv(idx);
2858                                 ++idx;
2859                         }
2860                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2861                         n = stof(s);
2862                         if (s == ftos(n) && n > 0 && n <= maxclients)
2863                         {
2864                                 e = edict_num(n);
2865                                 if (e.flags & FL_CLIENT)
2866                                         return e;
2867                         }
2868                 }
2869                 else
2870                 {
2871                         // it must be a nick name
2872                         s = argv(idx);
2873                         ++idx;
2874                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2875
2876                         n = 0;
2877                         FOR_EACH_CLIENT(head)
2878                                 if (head.netname == s)
2879                                 {
2880                                         e = head;
2881                                         ++n;
2882                                 }
2883                         if (n == 1)
2884                                 return e;
2885
2886                         s = strdecolorize(s);
2887                         n = 0;
2888                         FOR_EACH_CLIENT(head)
2889                                 if (strdecolorize(head.netname) == s)
2890                                 {
2891                                         e = head;
2892                                         ++n;
2893                                 }
2894                         if (n == 1)
2895                                 return e;
2896                 }
2897         }
2898
2899         return world;
2900 }
2901
2902 .float scale2;
2903
2904 float modeleffect_SendEntity(entity to, float sf)
2905 {
2906         float f;
2907         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2908
2909         f = 0;
2910         if(self.velocity != '0 0 0')
2911                 f |= 1;
2912         if(self.angles != '0 0 0')
2913                 f |= 2;
2914         if(self.avelocity != '0 0 0')
2915                 f |= 4;
2916
2917         WriteByte(MSG_ENTITY, f);
2918         WriteShort(MSG_ENTITY, self.modelindex);
2919         WriteByte(MSG_ENTITY, self.skin);
2920         WriteByte(MSG_ENTITY, self.frame);
2921         WriteCoord(MSG_ENTITY, self.origin_x);
2922         WriteCoord(MSG_ENTITY, self.origin_y);
2923         WriteCoord(MSG_ENTITY, self.origin_z);
2924         if(f & 1)
2925         {
2926                 WriteCoord(MSG_ENTITY, self.velocity_x);
2927                 WriteCoord(MSG_ENTITY, self.velocity_y);
2928                 WriteCoord(MSG_ENTITY, self.velocity_z);
2929         }
2930         if(f & 2)
2931         {
2932                 WriteCoord(MSG_ENTITY, self.angles_x);
2933                 WriteCoord(MSG_ENTITY, self.angles_y);
2934                 WriteCoord(MSG_ENTITY, self.angles_z);
2935         }
2936         if(f & 4)
2937         {
2938                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2939                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2940                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2941         }
2942         WriteShort(MSG_ENTITY, self.scale * 256.0);
2943         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2944         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2945         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2946         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2947
2948         return TRUE;
2949 }
2950
2951 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2952 {
2953         entity e;
2954         float sz;
2955         e = spawn();
2956         e.classname = "modeleffect";
2957         setmodel(e, m);
2958         e.frame = f;
2959         setorigin(e, o);
2960         e.velocity = v;
2961         e.angles = ang;
2962         e.avelocity = angv;
2963         e.alpha = a;
2964         e.teleport_time = t1;
2965         e.fade_time = t2;
2966         e.skin = s;
2967         if(s0 >= 0)
2968                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2969         else
2970                 e.scale = -s0;
2971         if(s2 >= 0)
2972                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2973         else
2974                 e.scale2 = -s2;
2975         sz = max(e.scale, e.scale2);
2976         setsize(e, e.mins * sz, e.maxs * sz);
2977         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2978 }
2979
2980 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2981 {
2982         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2983 }
2984
2985 float randombit(float bits)
2986 {
2987         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2988                 return bits;
2989
2990         float n, f, b, r;
2991
2992         r = random();
2993         b = 0;
2994         n = 0;
2995
2996         for(f = 1; f <= bits; f *= 2)
2997         {
2998                 if(bits & f)
2999                 {
3000                         ++n;
3001                         r *= n;
3002                         if(r <= 1)
3003                                 b = f;
3004                         else
3005                                 r = (r - 1) / (n - 1);
3006                 }
3007         }
3008
3009         return b;
3010 }
3011
3012 float randombits(float bits, float k, float error_return)
3013 {
3014         float r;
3015         r = 0;
3016         while(k > 0 && bits != r)
3017         {
3018                 r += randombit(bits - r);
3019                 --k;
3020         }
3021         if(error_return)
3022                 if(k > 0)
3023                         return -1; // all
3024         return r;
3025 }
3026
3027 void randombit_test(float bits, float iter)
3028 {
3029         while(iter > 0)
3030         {
3031                 print(ftos(randombit(bits)), "\n");
3032                 --iter;
3033         }
3034 }
3035
3036 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3037 {
3038         if(halflifedist > 0)
3039                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3040         else if(halflifedist < 0)
3041                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3042         else
3043                 return 1;
3044 }
3045
3046
3047
3048
3049 #ifdef RELEASE
3050 #define cvar_string_normal cvar_string_builtin
3051 #define cvar_normal cvar_builtin
3052 #else
3053 string cvar_string_normal(string n)
3054 {
3055         if not(cvar_type(n) & 1)
3056                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3057         return cvar_string_builtin(n);
3058 }
3059
3060 float cvar_normal(string n)
3061 {
3062         return stof(cvar_string_normal(n));
3063 }
3064 #endif
3065 #define cvar_set_normal cvar_set_builtin
3066
3067 void defer_think()
3068 {
3069     entity oself;
3070
3071     oself           = self;
3072     self            = self.owner;
3073     oself.think     = SUB_Remove;
3074     oself.nextthink = time;
3075
3076     oself.use();
3077 }
3078
3079 /*
3080     Execute func() after time + fdelay.
3081     self when func is executed = self when defer is called
3082 */
3083 void defer(float fdelay, void() func)
3084 {
3085     entity e;
3086
3087     e           = spawn();
3088     e.owner     = self;
3089     e.use       = func;
3090     e.think     = defer_think;
3091     e.nextthink = time + fdelay;
3092 }
3093
3094 .string aiment_classname;
3095 .float aiment_deadflag;
3096 void SetMovetypeFollow(entity ent, entity e)
3097 {
3098         // FIXME this may not be warpzone aware
3099         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3100         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3101         ent.aiment = e; // make the hole follow bmodel
3102         ent.punchangle = e.angles; // the original angles of bmodel
3103         ent.view_ofs = ent.origin - e.origin; // relative origin
3104         ent.v_angle = ent.angles - e.angles; // relative angles
3105         ent.aiment_classname = strzone(e.classname);
3106         ent.aiment_deadflag = e.deadflag;
3107 }
3108 void UnsetMovetypeFollow(entity ent)
3109 {
3110         ent.movetype = MOVETYPE_FLY;
3111         PROJECTILE_MAKETRIGGER(ent);
3112         ent.aiment = world;
3113 }
3114 float LostMovetypeFollow(entity ent)
3115 {
3116 /*
3117         if(ent.movetype != MOVETYPE_FOLLOW)
3118                 if(ent.aiment)
3119                         error("???");
3120 */
3121         if(ent.aiment)
3122         {
3123                 if(ent.aiment.classname != ent.aiment_classname)
3124                         return 1;
3125                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3126                         return 1;
3127         }
3128         return 0;
3129 }
3130
3131 float isPushable(entity e)
3132 {
3133         if(e.iscreature)
3134                 return TRUE;
3135         switch(e.classname)
3136         {
3137                 case "body":
3138                 case "droppedweapon":
3139                 case "keepawayball":
3140                 case "nexball_basketball":
3141                 case "nexball_football":
3142                         return TRUE;
3143                 case "bullet": // antilagged bullets can't hit this either
3144                         return FALSE;
3145         }
3146         if (e.projectiledeathtype)
3147                 return TRUE;
3148         return FALSE;
3149 }