Merge remote-tracking branch 'origin/master' into samual/respawn_improvements
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / miscfunctions.qc
1 var void remove(entity e);
2 void objerror(string s);
3 void droptofloor();
4 .vector dropped_origin;
5
6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
7 void crosshair_trace(entity pl)
8 {
9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
10 }
11 void crosshair_trace_plusvisibletriggers(entity pl)
12 {
13         entity first;
14         entity e;
15         first = findchainfloat(solid, SOLID_TRIGGER);
16
17         for (e = first; e; e = e.chain)
18                 if (e.model != "")
19                         e.solid = SOLID_BSP;
20
21         crosshair_trace(pl);
22
23         for (e = first; e; e = e.chain)
24                 e.solid = SOLID_TRIGGER;
25 }
26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
27 void WarpZone_crosshair_trace(entity pl)
28 {
29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
30 }
31
32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
33 void() spawnpoint_use;
34 string GetMapname();
35
36 string admin_name(void)
37 {
38         if(autocvar_sv_adminnick != "")
39                 return autocvar_sv_adminnick;
40         else
41                 return "SERVER ADMIN";
42 }
43
44 float DistributeEvenly_amount;
45 float DistributeEvenly_totalweight;
46 void DistributeEvenly_Init(float amount, float totalweight)
47 {
48     if (DistributeEvenly_amount)
49     {
50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
52     }
53     if (totalweight == 0)
54         DistributeEvenly_amount = 0;
55     else
56         DistributeEvenly_amount = amount;
57     DistributeEvenly_totalweight = totalweight;
58 }
59 float DistributeEvenly_Get(float weight)
60 {
61     float f;
62     if (weight <= 0)
63         return 0;
64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
65     DistributeEvenly_totalweight -= weight;
66     DistributeEvenly_amount -= f;
67     return f;
68 }
69 float DistributeEvenly_GetRandomized(float weight)
70 {
71     float f;
72     if (weight <= 0)
73         return 0;
74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
75     DistributeEvenly_totalweight -= weight;
76     DistributeEvenly_amount -= f;
77     return f;
78 }
79
80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
81
82 string STR_PLAYER = "player";
83 string STR_SPECTATOR = "spectator";
84 string STR_OBSERVER = "observer";
85
86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
93
94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
97
98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
101
102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
103
104 // copies a string to a tempstring (so one can strunzone it)
105 string strcat1(string s) = #115; // FRIK_FILE
106
107 float logfile_open;
108 float logfile;
109
110 void GameLogEcho(string s)
111 {
112     string fn;
113     float matches;
114
115     if (autocvar_sv_eventlog_files)
116     {
117         if (!logfile_open)
118         {
119             logfile_open = TRUE;
120             matches = autocvar_sv_eventlog_files_counter + 1;
121             cvar_set("sv_eventlog_files_counter", ftos(matches));
122             fn = ftos(matches);
123             if (strlen(fn) < 8)
124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
126             logfile = fopen(fn, FILE_APPEND);
127             fputs(logfile, ":logversion:3\n");
128         }
129         if (logfile >= 0)
130         {
131             if (autocvar_sv_eventlog_files_timestamps)
132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
133             else
134                 fputs(logfile, strcat(s, "\n"));
135         }
136     }
137     if (autocvar_sv_eventlog_console)
138     {
139         print(s, "\n");
140     }
141 }
142
143 void GameLogInit()
144 {
145     logfile_open = 0;
146     // will be opened later
147 }
148
149 void GameLogClose()
150 {
151     if (logfile_open && logfile >= 0)
152     {
153         fclose(logfile);
154         logfile = -1;
155     }
156 }
157
158 #define strstr strstrofs
159 /*
160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
163 // BE CONSTANT OR strzoneD!
164 float strstr(string haystack, string needle, float offset)
165 {
166         float len, endpos;
167         string found;
168         len = strlen(needle);
169         endpos = strlen(haystack) - len;
170         while(offset <= endpos)
171         {
172                 found = substring(haystack, offset, len);
173                 if(found == needle)
174                         return offset;
175                 offset = offset + 1;
176         }
177         return -1;
178 }
179 */
180
181 float NUM_NEAREST_ENTITIES = 4;
182 entity nearest_entity[NUM_NEAREST_ENTITIES];
183 float nearest_length[NUM_NEAREST_ENTITIES];
184 entity findnearest(vector point, .string field, string value, vector axismod)
185 {
186     entity localhead;
187     float i;
188     float j;
189     float len;
190     vector dist;
191
192     float num_nearest;
193     num_nearest = 0;
194
195     localhead = find(world, field, value);
196     while (localhead)
197     {
198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
199             dist = localhead.oldorigin;
200         else
201             dist = localhead.origin;
202         dist = dist - point;
203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
204         len = vlen(dist);
205
206         for (i = 0; i < num_nearest; ++i)
207         {
208             if (len < nearest_length[i])
209                 break;
210         }
211
212         // now i tells us where to insert at
213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
214         if (i < NUM_NEAREST_ENTITIES)
215         {
216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
217             {
218                 nearest_length[j + 1] = nearest_length[j];
219                 nearest_entity[j + 1] = nearest_entity[j];
220             }
221             nearest_length[i] = len;
222             nearest_entity[i] = localhead;
223             if (num_nearest < NUM_NEAREST_ENTITIES)
224                 num_nearest = num_nearest + 1;
225         }
226
227         localhead = find(localhead, field, value);
228     }
229
230     // now use the first one from our list that we can see
231     for (i = 0; i < num_nearest; ++i)
232     {
233         traceline(point, nearest_entity[i].origin, TRUE, world);
234         if (trace_fraction == 1)
235         {
236             if (i != 0)
237             {
238                 dprint("Nearest point (");
239                 dprint(nearest_entity[0].netname);
240                 dprint(") is not visible, using a visible one.\n");
241             }
242             return nearest_entity[i];
243         }
244     }
245
246     if (num_nearest == 0)
247         return world;
248
249     dprint("Not seeing any location point, using nearest as fallback.\n");
250     /* DEBUGGING CODE:
251     dprint("Candidates were: ");
252     for(j = 0; j < num_nearest; ++j)
253     {
254         if(j != 0)
255                 dprint(", ");
256         dprint(nearest_entity[j].netname);
257     }
258     dprint("\n");
259     */
260
261     return nearest_entity[0];
262 }
263
264 void spawnfunc_target_location()
265 {
266     self.classname = "target_location";
267     // location name in netname
268     // eventually support: count, teamgame selectors, line of sight?
269 }
270
271 void spawnfunc_info_location()
272 {
273     self.classname = "target_location";
274     self.message = self.netname;
275 }
276
277 string NearestLocation(vector p)
278 {
279     entity loc;
280     string ret;
281     ret = "somewhere";
282     loc = findnearest(p, classname, "target_location", '1 1 1');
283     if (loc)
284     {
285         ret = loc.message;
286     }
287     else
288     {
289         loc = findnearest(p, target, "###item###", '1 1 4');
290         if (loc)
291             ret = loc.netname;
292     }
293     return ret;
294 }
295
296 string formatmessage(string msg)
297 {
298         float p, p1, p2;
299         float n;
300         vector cursor;
301         entity cursor_ent;
302         string escape;
303         string replacement;
304         p = 0;
305         n = 7;
306
307         WarpZone_crosshair_trace(self);
308         cursor = trace_endpos;
309         cursor_ent = trace_ent;
310
311         while (1) {
312                 if (n < 1)
313                         break; // too many replacements
314
315                 n = n - 1;
316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
318
319                 if (p1 < 0)
320                         p1 = p2;
321
322                 if (p2 < 0)
323                         p2 = p1;
324
325                 p = min(p1, p2);
326
327                 if (p < 0)
328                         break;
329
330                 replacement = substring(msg, p, 2);
331                 escape = substring(msg, p + 1, 1);
332
333                 if (escape == "%")
334                         replacement = "%";
335                 else if (escape == "\\")
336                         replacement = "\\";
337                 else if (escape == "n")
338                         replacement = "\n";
339                 else if (escape == "a")
340                         replacement = ftos(floor(self.armorvalue));
341                 else if (escape == "h")
342                         replacement = ftos(floor(self.health));
343                 else if (escape == "l")
344                         replacement = NearestLocation(self.origin);
345                 else if (escape == "y")
346                         replacement = NearestLocation(cursor);
347                 else if (escape == "d")
348                         replacement = NearestLocation(self.death_origin);
349                 else if (escape == "w") {
350                         float wep;
351                         wep = self.weapon;
352                         if (!wep)
353                                 wep = self.switchweapon;
354                         if (!wep)
355                                 wep = self.cnt;
356                         replacement = W_Name(wep);
357                 } else if (escape == "W") {
358                         if (self.items & IT_SHELLS) replacement = "shells";
359                         else if (self.items & IT_NAILS) replacement = "bullets";
360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
361                         else if (self.items & IT_CELLS) replacement = "cells";
362                         else replacement = "batteries"; // ;)
363                 } else if (escape == "x") {
364                         replacement = cursor_ent.netname;
365                         if (replacement == "" || !cursor_ent)
366                                 replacement = "nothing";
367                 } else if (escape == "s")
368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
369                 else if (escape == "S")
370                         replacement = ftos(vlen(self.velocity));
371
372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
373                 p = p + strlen(replacement);
374         }
375         return msg;
376 }
377
378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
379         return (value == 0) ? FALSE : TRUE;
380 }
381
382 /*
383 =============
384 GetCvars
385 =============
386 Called with:
387   0:  sends the request
388   >0: receives a cvar from name=argv(f) value=argv(f+1)
389 */
390 void GetCvars_handleString(string thisname, float f, .string field, string name)
391 {
392         if (f < 0)
393         {
394                 if (self.field)
395                         strunzone(self.field);
396                 self.field = string_null;
397         }
398         else if (f > 0)
399         {
400                 if (thisname == name)
401                 {
402                         if (self.field)
403                                 strunzone(self.field);
404                         self.field = strzone(argv(f + 1));
405                 }
406         }
407         else
408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
409 }
410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
411 {
412         GetCvars_handleString(thisname, f, field, name);
413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
414                 if (thisname == name)
415                 {
416                         string s;
417                         s = func(strcat1(self.field));
418                         if (s != self.field)
419                         {
420                                 strunzone(self.field);
421                                 self.field = strzone(s);
422                         }
423                 }
424 }
425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
426 {
427         if (f < 0)
428         {
429         }
430         else if (f > 0)
431         {
432                 if (thisname == name)
433                         self.field = stof(argv(f + 1));
434         }
435         else
436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
437 }
438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
439 {
440         if (f < 0)
441         {
442         }
443         else if (f > 0)
444         {
445                 if (thisname == name)
446                 {
447                         if(!self.field)
448                         {
449                                 self.field = stof(argv(f + 1));
450                                 if(!self.field)
451                                         self.field = -1;
452                         }
453                 }
454         }
455         else
456         {
457                 if(!self.field)
458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
459         }
460 }
461 float w_getbestweapon(entity e);
462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
463 {
464         string o;
465         o = W_FixWeaponOrder_ForceComplete(wo);
466         if(self.weaponorder_byimpulse)
467         {
468                 strunzone(self.weaponorder_byimpulse);
469                 self.weaponorder_byimpulse = string_null;
470         }
471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
472         return o;
473 }
474 void GetCvars(float f)
475 {
476         string s = string_null;
477
478         if (f > 0)
479                 s = strcat1(argv(f));
480
481         get_cvars_f = f;
482         get_cvars_s = s;
483
484         MUTATOR_CALLHOOK(GetCvars);
485
486         Notification_GetCvars();
487
488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
490         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
491         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
492         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
504         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
505         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
506         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
511
512         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
513         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
514
515         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
516         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
517         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
518         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
519         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
520
521         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
522         if (f > 0)
523         {
524                 if (s == "cl_weaponpriority")
525                         self.switchweapon = w_getbestweapon(self);
526                 if (s == "cl_allow_uidtracking")
527                         PlayerStats_AddPlayer(self);
528         }
529 }
530
531 // decolorizes and team colors the player name when needed
532 string playername(entity p)
533 {
534     string t;
535     if (teamplay && !intermission_running && p.classname == "player")
536     {
537         t = Team_ColorCode(p.team);
538         return strcat(t, strdecolorize(p.netname));
539     }
540     else
541         return p.netname;
542 }
543
544 vector randompos(vector m1, vector m2)
545 {
546     vector v;
547     m2 = m2 - m1;
548     v_x = m2_x * random() + m1_x;
549     v_y = m2_y * random() + m1_y;
550     v_z = m2_z * random() + m1_z;
551     return  v;
552 }
553
554 //#NO AUTOCVARS START
555
556 float g_pickup_shells;
557 float g_pickup_shells_max;
558 float g_pickup_nails;
559 float g_pickup_nails_max;
560 float g_pickup_rockets;
561 float g_pickup_rockets_max;
562 float g_pickup_cells;
563 float g_pickup_cells_max;
564 float g_pickup_fuel;
565 float g_pickup_fuel_jetpack;
566 float g_pickup_fuel_max;
567 float g_pickup_armorsmall;
568 float g_pickup_armorsmall_max;
569 float g_pickup_armorsmall_anyway;
570 float g_pickup_armormedium;
571 float g_pickup_armormedium_max;
572 float g_pickup_armormedium_anyway;
573 float g_pickup_armorbig;
574 float g_pickup_armorbig_max;
575 float g_pickup_armorbig_anyway;
576 float g_pickup_armorlarge;
577 float g_pickup_armorlarge_max;
578 float g_pickup_armorlarge_anyway;
579 float g_pickup_healthsmall;
580 float g_pickup_healthsmall_max;
581 float g_pickup_healthsmall_anyway;
582 float g_pickup_healthmedium;
583 float g_pickup_healthmedium_max;
584 float g_pickup_healthmedium_anyway;
585 float g_pickup_healthlarge;
586 float g_pickup_healthlarge_max;
587 float g_pickup_healthlarge_anyway;
588 float g_pickup_healthmega;
589 float g_pickup_healthmega_max;
590 float g_pickup_healthmega_anyway;
591 float g_pickup_ammo_anyway;
592 float g_pickup_weapons_anyway;
593 float g_weaponarena;
594 WEPSET_DECLARE_A(g_weaponarena_weapons);
595 float g_weaponarena_random;
596 float g_weaponarena_random_with_laser;
597 string g_weaponarena_list;
598 float g_weaponspeedfactor;
599 float g_weaponratefactor;
600 float g_weapondamagefactor;
601 float g_weaponforcefactor;
602 float g_weaponspreadfactor;
603
604 WEPSET_DECLARE_A(start_weapons);
605 WEPSET_DECLARE_A(start_weapons_default);
606 WEPSET_DECLARE_A(start_weapons_defaultmask);
607 float start_items;
608 float start_ammo_shells;
609 float start_ammo_nails;
610 float start_ammo_rockets;
611 float start_ammo_cells;
612 float start_ammo_fuel;
613 float start_health;
614 float start_armorvalue;
615 WEPSET_DECLARE_A(warmup_start_weapons);
616 WEPSET_DECLARE_A(warmup_start_weapons_default);
617 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
618 float warmup_start_ammo_shells;
619 float warmup_start_ammo_nails;
620 float warmup_start_ammo_rockets;
621 float warmup_start_ammo_cells;
622 float warmup_start_ammo_fuel;
623 float warmup_start_health;
624 float warmup_start_armorvalue;
625 float g_weapon_stay;
626
627 entity get_weaponinfo(float w);
628
629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
630 {
631         var float i = weaponinfo.weapon;
632         var float d = 0;
633
634         if (!i)
635                 return 0;
636
637         if (g_lms || g_ca || allguns)
638         {
639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
640                         d = TRUE;
641                 else
642                         d = FALSE;
643         }
644         else if (g_cts)
645                 d = (i == WEP_SHOTGUN);
646         else if (g_nexball)
647                 d = 0; // weapon is set a few lines later
648         else
649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
650                 
651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
652                 d |= (i == WEP_HOOK);
653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
654                 d = 0;
655
656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
657         
658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
659         
660         // bit order in t:
661         // 1: want or not
662         // 2: is default?
663         // 4: is set by default?
664         if(t < 0)
665                 t = 4 | (3 * d);
666         else
667                 t |= (2 * d);
668
669         return t;
670 }
671
672 void readplayerstartcvars()
673 {
674         entity e;
675         float i, j, t;
676         string s;
677
678         // initialize starting values for players
679         WEPSET_CLEAR_A(start_weapons);
680         WEPSET_CLEAR_A(start_weapons_default);
681         WEPSET_CLEAR_A(start_weapons_defaultmask);
682         start_items = 0;
683         start_ammo_shells = 0;
684         start_ammo_nails = 0;
685         start_ammo_rockets = 0;
686         start_ammo_cells = 0;
687         start_health = cvar("g_balance_health_start");
688         start_armorvalue = cvar("g_balance_armor_start");
689
690         g_weaponarena = 0;
691         WEPSET_CLEAR_A(g_weaponarena_weapons);
692
693         s = cvar_string("g_weaponarena");
694         if (s == "0" || s == "")
695         {
696                 if(g_lms || g_ca)
697                         s = "most";
698         }
699
700         if (s == "0" || s == "")
701         {
702                 // no arena
703         }
704         else if (s == "off")
705         {
706                 // forcibly turn off weaponarena
707         }
708         else if (s == "all")
709         {
710                 g_weaponarena = 1;
711                 g_weaponarena_list = "All Weapons";
712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
713                 {
714                         e = get_weaponinfo(j);
715                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
716                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
717                 }
718         }
719         else if (s == "most")
720         {
721                 g_weaponarena = 1;
722                 g_weaponarena_list = "Most Weapons";
723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
724                 {
725                         e = get_weaponinfo(j);
726                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
728                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
729                 }
730         }
731         else if (s == "none")
732         {
733                 g_weaponarena = 1;
734                 g_weaponarena_list = "No Weapons";
735         }
736         else
737         {
738                 g_weaponarena = 1;
739                 t = tokenize_console(s);
740                 g_weaponarena_list = "";
741                 for (i = 0; i < t; ++i)
742                 {
743                         s = argv(i);
744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
745                         {
746                                 e = get_weaponinfo(j);
747                                 if (e.netname == s)
748                                 {
749                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
751                                         break;
752                                 }
753                         }
754                         if (j > WEP_LAST)
755                         {
756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
757                         }
758                 }
759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
760         }
761
762         if(g_weaponarena)
763                 g_weaponarena_random = cvar("g_weaponarena_random");
764         else
765                 g_weaponarena_random = 0;
766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
767
768         if (g_weaponarena)
769         {
770                 g_minstagib = 0; // incompatible
771                 g_pinata = 0; // incompatible
772                 g_weapon_stay = 0; // incompatible
773                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
774                 if(!(g_lms || g_ca))
775                         start_items |= IT_UNLIMITED_AMMO;
776         }
777         else if (g_minstagib)
778         {
779                 g_pinata = 0; // incompatible
780                 g_weapon_stay = 0; // incompatible
781                 g_bloodloss = 0; // incompatible
782                 start_health = 100;
783                 start_armorvalue = 0;
784                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
785                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
786                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
787
788                 if (g_minstagib_invis_alpha <= 0)
789                         g_minstagib_invis_alpha = -1;
790         }
791         else
792         {
793                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
794                 {
795                         e = get_weaponinfo(i);
796                         float w = want_weapon("g_start_weapon_", e, FALSE);
797                         if(w & 1)
798                                 WEPSET_OR_AW(start_weapons, i);
799                         if(w & 2)
800                                 WEPSET_OR_AW(start_weapons_default, i);
801                         if(w & 4)
802                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
803                 }
804         }
805
806         if(!cvar("g_use_ammunition"))
807                 start_items |= IT_UNLIMITED_AMMO;
808
809         if(cvar("g_nexball"))
810                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
811
812         if(g_minstagib)
813         {
814                 start_ammo_cells = cvar("g_minstagib_ammo_start");
815                 start_ammo_fuel = cvar("g_start_ammo_fuel");
816         }
817         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
818         {
819                 start_ammo_rockets = 999;
820                 start_ammo_shells = 999;
821                 start_ammo_cells = 999;
822                 start_ammo_nails = 999;
823                 start_ammo_fuel = 999;
824         }
825         else
826         {
827                 if(g_lms || g_ca)
828                 {
829                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
830                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
831                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
832                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
833                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
834                 }
835                 else
836                 {
837                         start_ammo_shells = cvar("g_start_ammo_shells");
838                         start_ammo_nails = cvar("g_start_ammo_nails");
839                         start_ammo_rockets = cvar("g_start_ammo_rockets");
840                         start_ammo_cells = cvar("g_start_ammo_cells");
841                         start_ammo_fuel = cvar("g_start_ammo_fuel");
842                 }
843         }
844
845         if (g_lms || g_ca)
846         {
847                 start_health = cvar("g_lms_start_health");
848                 start_armorvalue = cvar("g_lms_start_armor");
849         }
850
851         if (inWarmupStage)
852         {
853                 warmup_start_ammo_shells = start_ammo_shells;
854                 warmup_start_ammo_nails = start_ammo_nails;
855                 warmup_start_ammo_rockets = start_ammo_rockets;
856                 warmup_start_ammo_cells = start_ammo_cells;
857                 warmup_start_ammo_fuel = start_ammo_fuel;
858                 warmup_start_health = start_health;
859                 warmup_start_armorvalue = start_armorvalue;
860                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
861                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
862                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
863
864                 if (!g_weaponarena && !g_minstagib && !g_ca)
865                 {
866                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
867                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
868                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
869                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
870                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
871                         warmup_start_health = cvar("g_warmup_start_health");
872                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
873                         WEPSET_CLEAR_A(warmup_start_weapons);
874                         WEPSET_CLEAR_A(warmup_start_weapons_default);
875                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
876                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
877                         {
878                                 e = get_weaponinfo(i);
879                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
880                                 if(w & 1)
881                                         WEPSET_OR_AW(warmup_start_weapons, i);
882                                 if(w & 2)
883                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
884                                 if(w & 4)
885                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
886                         }
887                 }
888         }
889
890         if (g_jetpack)
891                 start_items |= IT_JETPACK;
892
893         MUTATOR_CALLHOOK(SetStartItems);
894
895         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
896         {
897                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
898                 start_items |= IT_FUEL_REGEN;
899                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
900                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
901         }
902
903         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
904         {
905                 e = get_weaponinfo(i);
906                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
907                         weapon_action(i, WR_PRECACHE);
908         }
909
910         start_ammo_shells = max(0, start_ammo_shells);
911         start_ammo_nails = max(0, start_ammo_nails);
912         start_ammo_cells = max(0, start_ammo_cells);
913         start_ammo_rockets = max(0, start_ammo_rockets);
914         start_ammo_fuel = max(0, start_ammo_fuel);
915
916         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
917         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
918         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
919         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
920         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
921 }
922
923 float g_bugrigs;
924 float g_bugrigs_planar_movement;
925 float g_bugrigs_planar_movement_car_jumping;
926 float g_bugrigs_reverse_spinning;
927 float g_bugrigs_reverse_speeding;
928 float g_bugrigs_reverse_stopping;
929 float g_bugrigs_air_steering;
930 float g_bugrigs_angle_smoothing;
931 float g_bugrigs_friction_floor;
932 float g_bugrigs_friction_brake;
933 float g_bugrigs_friction_air;
934 float g_bugrigs_accel;
935 float g_bugrigs_speed_ref;
936 float g_bugrigs_speed_pow;
937 float g_bugrigs_steer;
938
939 float sv_autotaunt;
940 float sv_taunt;
941
942 string GetGametype(); // g_world.qc
943 void readlevelcvars(void)
944 {
945         g_minstagib = cvar("g_minstagib");
946
947         // load ALL the mutators
948         if(cvar("g_dodging"))
949                 MUTATOR_ADD(mutator_dodging);
950         if(cvar("g_spawn_near_teammate"))
951                 MUTATOR_ADD(mutator_spawn_near_teammate);
952         if(cvar("g_physical_items"))
953                 MUTATOR_ADD(mutator_physical_items);
954         if(cvar("g_touchexplode"))
955                 MUTATOR_ADD(mutator_touchexplode);
956         if(!g_minstagib)
957         {
958                 if(cvar("g_invincible_projectiles"))
959                         MUTATOR_ADD(mutator_invincibleprojectiles);
960                 if(cvar("g_new_toys"))
961                         MUTATOR_ADD(mutator_new_toys);
962                 if(cvar("g_nix"))
963                         MUTATOR_ADD(mutator_nix);
964                 if(cvar("g_rocket_flying"))
965                         MUTATOR_ADD(mutator_rocketflying);
966                 if(cvar("g_vampire"))
967                         MUTATOR_ADD(mutator_vampire);           
968                 if(cvar("g_superspectate"))
969                         MUTATOR_ADD(mutator_superspec);
970         }
971
972         // is this a mutator? is this a mode?
973         if(cvar("g_sandbox"))
974                 MUTATOR_ADD(sandbox);
975
976         if(cvar("sv_allow_fullbright"))
977                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
978
979     g_bugrigs = cvar("g_bugrigs");
980     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
981     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
982     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
983     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
984     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
985     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
986     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
987     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
988     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
989     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
990     g_bugrigs_accel = cvar("g_bugrigs_accel");
991     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
992     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
993     g_bugrigs_steer = cvar("g_bugrigs_steer");
994
995         sv_clones = cvar("sv_clones");
996         sv_foginterval = cvar("sv_foginterval");
997         g_cloaked = cvar("g_cloaked");
998     if(g_cts)
999         g_cloaked = 1; // always enable cloak in CTS
1000         g_jump_grunt = cvar("g_jump_grunt");
1001         g_footsteps = cvar("g_footsteps");
1002         g_grappling_hook = cvar("g_grappling_hook");
1003         g_jetpack = cvar("g_jetpack");
1004         g_midair = cvar("g_midair");
1005         g_norecoil = cvar("g_norecoil");
1006         g_bloodloss = cvar("g_bloodloss");
1007         sv_maxidle = cvar("sv_maxidle");
1008         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1009         sv_autotaunt = cvar("sv_autotaunt");
1010         sv_taunt = cvar("sv_taunt");
1011
1012         inWarmupStage = cvar("g_warmup");
1013         g_warmup_limit = cvar("g_warmup_limit");
1014         g_warmup_allguns = cvar("g_warmup_allguns");
1015         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1016
1017         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1018                 inWarmupStage = 0; // these modes cannot work together, sorry
1019
1020         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1021         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1022         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1023         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1024         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1025         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1026         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1027         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1028         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1029         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1030         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1031         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1032         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1033         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1034
1035         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1036         g_weaponratefactor = cvar("g_weaponratefactor");
1037         g_weapondamagefactor = cvar("g_weapondamagefactor");
1038         g_weaponforcefactor = cvar("g_weaponforcefactor");
1039         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1040
1041         g_pickup_shells = cvar("g_pickup_shells");
1042         g_pickup_shells_max = cvar("g_pickup_shells_max");
1043         g_pickup_nails = cvar("g_pickup_nails");
1044         g_pickup_nails_max = cvar("g_pickup_nails_max");
1045         g_pickup_rockets = cvar("g_pickup_rockets");
1046         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1047         g_pickup_cells = cvar("g_pickup_cells");
1048         g_pickup_cells_max = cvar("g_pickup_cells_max");
1049         g_pickup_fuel = cvar("g_pickup_fuel");
1050         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1051         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1052         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1053         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1054         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1055         g_pickup_armormedium = cvar("g_pickup_armormedium");
1056         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1057         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1058         g_pickup_armorbig = cvar("g_pickup_armorbig");
1059         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1060         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1061         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1062         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1063         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1064         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1065         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1066         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1067         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1068         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1069         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1070         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1071         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1072         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1073         g_pickup_healthmega = cvar("g_pickup_healthmega");
1074         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1075         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1076
1077         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1078         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1079
1080         g_pinata = cvar("g_pinata");
1081
1082     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1083     if(!g_weapon_stay)
1084         g_weapon_stay = cvar("g_weapon_stay");
1085
1086         if not(inWarmupStage && !g_ca)
1087                 game_starttime = cvar("g_start_delay");
1088
1089         readplayerstartcvars();
1090 }
1091
1092 //#NO AUTOCVARS END
1093
1094 // Sound functions
1095 string precache_sound (string s) = #19;
1096 float precache_sound_index (string s) = #19;
1097
1098 #define SND_VOLUME      1
1099 #define SND_ATTENUATION 2
1100 #define SND_LARGEENTITY 8
1101 #define SND_LARGESOUND  16
1102
1103 float sound_allowed(float dest, entity e)
1104 {
1105     // sounds from world may always pass
1106     for (;;)
1107     {
1108         if (e.classname == "body")
1109             e = e.enemy;
1110         else if (e.realowner && e.realowner != e)
1111             e = e.realowner;
1112         else if (e.owner && e.owner != e)
1113             e = e.owner;
1114         else
1115             break;
1116     }
1117     // sounds to self may always pass
1118     if (dest == MSG_ONE)
1119         if (e == msg_entity)
1120             return TRUE;
1121     // sounds by players can be removed
1122     if (autocvar_bot_sound_monopoly)
1123         if (clienttype(e) == CLIENTTYPE_REAL)
1124             return FALSE;
1125     // anything else may pass
1126     return TRUE;
1127 }
1128
1129 #ifdef COMPAT_XON010_CHANNELS
1130 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1131 void sound(entity e, float chan, string samp, float vol, float atten)
1132 {
1133     if (!sound_allowed(MSG_BROADCAST, e))
1134         return;
1135     builtin_sound(e, chan, samp, vol, atten);
1136 }
1137 #else
1138 #undef sound
1139 void sound(entity e, float chan, string samp, float vol, float atten)
1140 {
1141     if (!sound_allowed(MSG_BROADCAST, e))
1142         return;
1143     sound7(e, chan, samp, vol, atten, 0, 0);
1144 }
1145 #endif
1146
1147 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1148 {
1149     float entno, idx;
1150
1151     if (!sound_allowed(dest, e))
1152         return;
1153
1154     entno = num_for_edict(e);
1155     idx = precache_sound_index(samp);
1156
1157     float sflags;
1158     sflags = 0;
1159
1160     atten = floor(atten * 64);
1161     vol = floor(vol * 255);
1162
1163     if (vol != 255)
1164         sflags |= SND_VOLUME;
1165     if (atten != 64)
1166         sflags |= SND_ATTENUATION;
1167     if (entno >= 8192 || chan < 0 || chan > 7)
1168         sflags |= SND_LARGEENTITY;
1169     if (idx >= 256)
1170         sflags |= SND_LARGESOUND;
1171
1172     WriteByte(dest, SVC_SOUND);
1173     WriteByte(dest, sflags);
1174     if (sflags & SND_VOLUME)
1175         WriteByte(dest, vol);
1176     if (sflags & SND_ATTENUATION)
1177         WriteByte(dest, atten);
1178     if (sflags & SND_LARGEENTITY)
1179     {
1180         WriteShort(dest, entno);
1181         WriteByte(dest, chan);
1182     }
1183     else
1184     {
1185         WriteShort(dest, entno * 8 + chan);
1186     }
1187     if (sflags & SND_LARGESOUND)
1188         WriteShort(dest, idx);
1189     else
1190         WriteByte(dest, idx);
1191
1192     WriteCoord(dest, o_x);
1193     WriteCoord(dest, o_y);
1194     WriteCoord(dest, o_z);
1195 }
1196 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1197 {
1198     vector o;
1199
1200     if (!sound_allowed(dest, e))
1201         return;
1202
1203     o = e.origin + 0.5 * (e.mins + e.maxs);
1204     soundtoat(dest, e, o, chan, samp, vol, atten);
1205 }
1206 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1207 {
1208     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1209 }
1210 void stopsoundto(float dest, entity e, float chan)
1211 {
1212     float entno;
1213
1214     if (!sound_allowed(dest, e))
1215         return;
1216
1217     entno = num_for_edict(e);
1218
1219     if (entno >= 8192 || chan < 0 || chan > 7)
1220     {
1221         float idx, sflags;
1222         idx = precache_sound_index("misc/null.wav");
1223         sflags = SND_LARGEENTITY;
1224         if (idx >= 256)
1225             sflags |= SND_LARGESOUND;
1226         WriteByte(dest, SVC_SOUND);
1227         WriteByte(dest, sflags);
1228         WriteShort(dest, entno);
1229         WriteByte(dest, chan);
1230         if (sflags & SND_LARGESOUND)
1231             WriteShort(dest, idx);
1232         else
1233             WriteByte(dest, idx);
1234         WriteCoord(dest, e.origin_x);
1235         WriteCoord(dest, e.origin_y);
1236         WriteCoord(dest, e.origin_z);
1237     }
1238     else
1239     {
1240         WriteByte(dest, SVC_STOPSOUND);
1241         WriteShort(dest, entno * 8 + chan);
1242     }
1243 }
1244 void stopsound(entity e, float chan)
1245 {
1246     if (!sound_allowed(MSG_BROADCAST, e))
1247         return;
1248
1249     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1250     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1251 }
1252
1253 void play2(entity e, string filename)
1254 {
1255     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1256     msg_entity = e;
1257     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1258 }
1259
1260 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1261 .float spamtime;
1262 float spamsound(entity e, float chan, string samp, float vol, float atten)
1263 {
1264     if (!sound_allowed(MSG_BROADCAST, e))
1265         return FALSE;
1266
1267     if (time > e.spamtime)
1268     {
1269         e.spamtime = time;
1270         sound(e, chan, samp, vol, atten);
1271         return TRUE;
1272     }
1273     return FALSE;
1274 }
1275
1276 void play2team(float t, string filename)
1277 {
1278     entity head;
1279
1280     if (autocvar_bot_sound_monopoly)
1281         return;
1282
1283     FOR_EACH_REALPLAYER(head)
1284     {
1285         if (head.team == t)
1286             play2(head, filename);
1287     }
1288 }
1289
1290 void play2all(string samp)
1291 {
1292     if (autocvar_bot_sound_monopoly)
1293         return;
1294
1295     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1296 }
1297
1298 void PrecachePlayerSounds(string f);
1299 void precache_playermodel(string m)
1300 {
1301         float globhandle, i, n;
1302         string f;
1303
1304         if(substring(m, -9,5) == "_lod1")
1305                 return;
1306         if(substring(m, -9,5) == "_lod2")
1307                 return;
1308         precache_model(m);
1309         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1310         if(fexists(f))
1311                 precache_model(f);
1312         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1313         if(fexists(f))
1314                 precache_model(f);
1315
1316         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1317         if (globhandle < 0)
1318                 return;
1319         n = search_getsize(globhandle);
1320         for (i = 0; i < n; ++i)
1321         {
1322                 //print(search_getfilename(globhandle, i), "\n");
1323                 f = search_getfilename(globhandle, i);
1324                 PrecachePlayerSounds(f);
1325         }
1326         search_end(globhandle);
1327 }
1328 void precache_all_playermodels(string pattern)
1329 {
1330         float globhandle, i, n;
1331         string f;
1332
1333         globhandle = search_begin(pattern, TRUE, FALSE);
1334         if (globhandle < 0)
1335                 return;
1336         n = search_getsize(globhandle);
1337         for (i = 0; i < n; ++i)
1338         {
1339                 //print(search_getfilename(globhandle, i), "\n");
1340                 f = search_getfilename(globhandle, i);
1341                 precache_playermodel(f);
1342         }
1343         search_end(globhandle);
1344 }
1345
1346 void precache()
1347 {
1348     // gamemode related things
1349     precache_model ("models/misc/chatbubble.spr");
1350
1351 #ifdef TTURRETS_ENABLED
1352     if (autocvar_g_turrets)
1353         turrets_precash();
1354 #endif
1355
1356     // Precache all player models if desired
1357     if (autocvar_sv_precacheplayermodels)
1358     {
1359         PrecachePlayerSounds("sound/player/default.sounds");
1360         precache_all_playermodels("models/player/*.zym");
1361         precache_all_playermodels("models/player/*.dpm");
1362         precache_all_playermodels("models/player/*.md3");
1363         precache_all_playermodels("models/player/*.psk");
1364         precache_all_playermodels("models/player/*.iqm");
1365     }
1366
1367     if (autocvar_sv_defaultcharacter)
1368     {
1369         string s;
1370         s = autocvar_sv_defaultplayermodel_red;
1371         if (s != "")
1372             precache_playermodel(s);
1373         s = autocvar_sv_defaultplayermodel_blue;
1374         if (s != "")
1375             precache_playermodel(s);
1376         s = autocvar_sv_defaultplayermodel_yellow;
1377         if (s != "")
1378             precache_playermodel(s);
1379         s = autocvar_sv_defaultplayermodel_pink;
1380         if (s != "")
1381             precache_playermodel(s);
1382         s = autocvar_sv_defaultplayermodel;
1383         if (s != "")
1384             precache_playermodel(s);
1385     }
1386
1387     if (g_footsteps)
1388     {
1389         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1390         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1391     }
1392
1393     // gore and miscellaneous sounds
1394     //precache_sound ("misc/h2ohit.wav");
1395     precache_model ("models/hook.md3");
1396     precache_sound ("misc/armorimpact.wav");
1397     precache_sound ("misc/bodyimpact1.wav");
1398     precache_sound ("misc/bodyimpact2.wav");
1399     precache_sound ("misc/gib.wav");
1400     precache_sound ("misc/gib_splat01.wav");
1401     precache_sound ("misc/gib_splat02.wav");
1402     precache_sound ("misc/gib_splat03.wav");
1403     precache_sound ("misc/gib_splat04.wav");
1404     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1405     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1406     precache_sound ("misc/null.wav");
1407     precache_sound ("misc/spawn.wav");
1408     precache_sound ("misc/talk.wav");
1409     precache_sound ("misc/teleport.wav");
1410     precache_sound ("misc/poweroff.wav");
1411     precache_sound ("player/lava.wav");
1412     precache_sound ("player/slime.wav");
1413
1414     precache_model ("models/sprites/0.spr32");
1415     precache_model ("models/sprites/1.spr32");
1416     precache_model ("models/sprites/2.spr32");
1417     precache_model ("models/sprites/3.spr32");
1418     precache_model ("models/sprites/4.spr32");
1419     precache_model ("models/sprites/5.spr32");
1420     precache_model ("models/sprites/6.spr32");
1421     precache_model ("models/sprites/7.spr32");
1422     precache_model ("models/sprites/8.spr32");
1423     precache_model ("models/sprites/9.spr32");
1424     precache_model ("models/sprites/10.spr32");
1425
1426     // common weapon precaches
1427         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1428     precache_sound ("weapons/weapon_switch.wav");
1429     precache_sound ("weapons/weaponpickup.wav");
1430     precache_sound ("weapons/unavailable.wav");
1431     precache_sound ("weapons/dryfire.wav");
1432     if (g_grappling_hook)
1433     {
1434         precache_sound ("weapons/hook_fire.wav"); // hook
1435         precache_sound ("weapons/hook_impact.wav"); // hook
1436     }
1437
1438     if(autocvar_sv_precacheweapons)
1439     {
1440         //precache weapon models/sounds
1441         float wep;
1442         wep = WEP_FIRST;
1443         while (wep <= WEP_LAST)
1444         {
1445             weapon_action(wep, WR_PRECACHE);
1446             wep = wep + 1;
1447         }
1448     }
1449
1450     precache_model("models/elaser.mdl");
1451     precache_model("models/laser.mdl");
1452     precache_model("models/ebomb.mdl");
1453
1454 #if 0
1455     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1456
1457     if (!self.noise && self.music) // quake 3 uses the music field
1458         self.noise = self.music;
1459
1460     // plays music for the level if there is any
1461     if (self.noise)
1462     {
1463         precache_sound (self.noise);
1464         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1465     }
1466 #endif
1467 }
1468
1469 // WARNING: this kills the trace globals
1470 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1471 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1472
1473 #define INITPRIO_FIRST              0
1474 #define INITPRIO_GAMETYPE           0
1475 #define INITPRIO_GAMETYPE_FALLBACK  1
1476 #define INITPRIO_FINDTARGET        10
1477 #define INITPRIO_DROPTOFLOOR       20
1478 #define INITPRIO_SETLOCATION       90
1479 #define INITPRIO_LINKDOORS         91
1480 #define INITPRIO_LAST              99
1481
1482 .void(void) initialize_entity;
1483 .float initialize_entity_order;
1484 .entity initialize_entity_next;
1485 entity initialize_entity_first;
1486
1487 void make_safe_for_remove(entity e)
1488 {
1489     if (e.initialize_entity)
1490     {
1491         entity ent, prev = world;
1492         for (ent = initialize_entity_first; ent; )
1493         {
1494             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1495             {
1496                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1497                 // skip it in linked list
1498                 if (prev)
1499                 {
1500                     prev.initialize_entity_next = ent.initialize_entity_next;
1501                     ent = prev.initialize_entity_next;
1502                 }
1503                 else
1504                 {
1505                     initialize_entity_first = ent.initialize_entity_next;
1506                     ent = initialize_entity_first;
1507                 }
1508             }
1509             else
1510             {
1511                 prev = ent;
1512                 ent = ent.initialize_entity_next;
1513             }
1514         }
1515     }
1516 }
1517
1518 void objerror(string s)
1519 {
1520     make_safe_for_remove(self);
1521     builtin_objerror(s);
1522 }
1523
1524 .float remove_except_protected_forbidden;
1525 void remove_except_protected(entity e)
1526 {
1527         if(e.remove_except_protected_forbidden)
1528                 error("not allowed to remove this at this point");
1529         builtin_remove(e);
1530 }
1531
1532 void remove_unsafely(entity e)
1533 {
1534     if(e.classname == "spike")
1535         error("Removing spikes is forbidden (crylink bug), please report");
1536     builtin_remove(e);
1537 }
1538
1539 void remove_safely(entity e)
1540 {
1541     make_safe_for_remove(e);
1542     builtin_remove(e);
1543 }
1544
1545 void InitializeEntity(entity e, void(void) func, float order)
1546 {
1547     entity prev, cur;
1548
1549     if (!e || e.initialize_entity)
1550     {
1551         // make a proxy initializer entity
1552         entity e_old;
1553         e_old = e;
1554         e = spawn();
1555         e.classname = "initialize_entity";
1556         e.enemy = e_old;
1557     }
1558
1559     e.initialize_entity = func;
1560     e.initialize_entity_order = order;
1561
1562     cur = initialize_entity_first;
1563     prev = world;
1564     for (;;)
1565     {
1566         if (!cur || cur.initialize_entity_order > order)
1567         {
1568             // insert between prev and cur
1569             if (prev)
1570                 prev.initialize_entity_next = e;
1571             else
1572                 initialize_entity_first = e;
1573             e.initialize_entity_next = cur;
1574             return;
1575         }
1576         prev = cur;
1577         cur = cur.initialize_entity_next;
1578     }
1579 }
1580 void InitializeEntitiesRun()
1581 {
1582     entity startoflist;
1583     startoflist = initialize_entity_first;
1584     initialize_entity_first = world;
1585     remove = remove_except_protected;
1586     for (self = startoflist; self; self = self.initialize_entity_next)
1587     {
1588         self.remove_except_protected_forbidden = 1;
1589     }
1590     for (self = startoflist; self; )
1591     {
1592         entity e;
1593         var void(void) func;
1594         e = self.initialize_entity_next;
1595         func = self.initialize_entity;
1596         self.initialize_entity_order = 0;
1597         self.initialize_entity = func_null;
1598         self.initialize_entity_next = world;
1599         self.remove_except_protected_forbidden = 0;
1600         if (self.classname == "initialize_entity")
1601         {
1602             entity e_old;
1603             e_old = self.enemy;
1604             builtin_remove(self);
1605             self = e_old;
1606         }
1607         //dprint("Delayed initialization: ", self.classname, "\n");
1608         if(func)
1609             func();
1610         else
1611         {
1612             eprint(self);
1613             backtrace(strcat("Null function in: ", self.classname, "\n"));
1614         }
1615         self = e;
1616     }
1617     remove = remove_unsafely;
1618 }
1619
1620 .float uncustomizeentityforclient_set;
1621 .void(void) uncustomizeentityforclient;
1622 void UncustomizeEntitiesRun()
1623 {
1624     entity oldself;
1625     oldself = self;
1626     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1627         self.uncustomizeentityforclient();
1628     self = oldself;
1629 }
1630 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1631 {
1632     e.customizeentityforclient = customizer;
1633     e.uncustomizeentityforclient = uncustomizer;
1634     e.uncustomizeentityforclient_set = !!uncustomizer;
1635 }
1636
1637 .float nottargeted;
1638 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1639
1640 void() SUB_Remove;
1641 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1642 {
1643     vector mi, ma;
1644
1645     if (e.classname == "")
1646         e.classname = "net_linked";
1647
1648     if (e.model == "" || self.modelindex == 0)
1649     {
1650         mi = e.mins;
1651         ma = e.maxs;
1652         setmodel(e, "null");
1653         setsize(e, mi, ma);
1654     }
1655
1656     e.SendEntity = sendfunc;
1657     e.SendFlags = 0xFFFFFF;
1658
1659     if (!docull)
1660         e.effects |= EF_NODEPTHTEST;
1661
1662     if (dt)
1663     {
1664         e.nextthink = time + dt;
1665         e.think = SUB_Remove;
1666     }
1667 }
1668
1669 void adaptor_think2touch()
1670 {
1671     entity o;
1672     o = other;
1673     other = world;
1674     self.touch();
1675     other = o;
1676 }
1677
1678 void adaptor_think2use()
1679 {
1680     entity o, a;
1681     o = other;
1682     a = activator;
1683     activator = world;
1684     other = world;
1685     self.use();
1686     other = o;
1687     activator = a;
1688 }
1689
1690 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1691 {
1692         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1693                 self.projectiledeathtype |= HITTYPE_SPLASH;
1694         adaptor_think2use();
1695 }
1696
1697 // deferred dropping
1698 void DropToFloor_Handler()
1699 {
1700     builtin_droptofloor();
1701     self.dropped_origin = self.origin;
1702 }
1703
1704 void droptofloor()
1705 {
1706     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1707 }
1708
1709
1710
1711 float trace_hits_box_a0, trace_hits_box_a1;
1712
1713 float trace_hits_box_1d(float end, float thmi, float thma)
1714 {
1715     if (end == 0)
1716     {
1717         // just check if x is in range
1718         if (0 < thmi)
1719             return FALSE;
1720         if (0 > thma)
1721             return FALSE;
1722     }
1723     else
1724     {
1725         // do the trace with respect to x
1726         // 0 -> end has to stay in thmi -> thma
1727         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1728         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1729         if (trace_hits_box_a0 > trace_hits_box_a1)
1730             return FALSE;
1731     }
1732     return TRUE;
1733 }
1734
1735 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1736 {
1737     end -= start;
1738     thmi -= start;
1739     thma -= start;
1740     // now it is a trace from 0 to end
1741
1742     trace_hits_box_a0 = 0;
1743     trace_hits_box_a1 = 1;
1744
1745     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1746         return FALSE;
1747     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1748         return FALSE;
1749     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1750         return FALSE;
1751
1752     return TRUE;
1753 }
1754
1755 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1756 {
1757     return trace_hits_box(start, end, thmi - ma, thma - mi);
1758 }
1759
1760 float SUB_NoImpactCheck()
1761 {
1762         // zero hitcontents = this is not the real impact, but either the
1763         // mirror-impact of something hitting the projectile instead of the
1764         // projectile hitting the something, or a touchareagrid one. Neither of
1765         // these stop the projectile from moving, so...
1766         if(trace_dphitcontents == 0)
1767         {
1768                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1769                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1770                 checkclient();
1771         }
1772     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1773         return 1;
1774     if (other == world && self.size != '0 0 0')
1775     {
1776         vector tic;
1777         tic = self.velocity * sys_frametime;
1778         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1779         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1780         if (trace_fraction >= 1)
1781         {
1782             dprint("Odd... did not hit...?\n");
1783         }
1784         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1785         {
1786             dprint("Detected and prevented the sky-grapple bug.\n");
1787             return 1;
1788         }
1789     }
1790
1791     return 0;
1792 }
1793
1794 #define SUB_OwnerCheck() (other && (other == self.owner))
1795
1796 void RemoveGrapplingHook(entity pl);
1797 void W_Crylink_Dequeue(entity e);
1798 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1799 {
1800         if(SUB_OwnerCheck())
1801                 return TRUE;
1802         if(SUB_NoImpactCheck())
1803         {
1804                 if(self.classname == "grapplinghook")
1805                         RemoveGrapplingHook(self.realowner);
1806                 else if(self.classname == "spike")
1807                 {
1808                         W_Crylink_Dequeue(self);
1809                         remove(self);
1810                 }
1811                 else
1812                         remove(self);
1813                 return TRUE;
1814         }
1815         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1816                 UpdateCSQCProjectile(self);
1817         return FALSE;
1818 }
1819 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1820
1821 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1822 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1823
1824 void URI_Get_Callback(float id, float status, string data)
1825 {
1826         if(url_URI_Get_Callback(id, status, data))
1827         {
1828                 // handled
1829         }
1830         else if (id == URI_GET_DISCARD)
1831         {
1832                 // discard
1833         }
1834         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1835         {
1836                 // sv_cmd curl
1837                 Curl_URI_Get_Callback(id, status, data);
1838         }
1839         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1840         {
1841                 // online ban list
1842                 OnlineBanList_URI_Get_Callback(id, status, data);
1843         }
1844         else
1845         {
1846                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1847         }
1848 }
1849
1850 string uid2name(string myuid) {
1851         string s;
1852         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1853
1854         // FIXME remove this later after 0.6 release
1855         // convert old style broken records to correct style
1856         if(s == "")
1857         {
1858                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1859                 if(s != "")
1860                 {
1861                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1862                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1863                 }
1864         }
1865         
1866         if(s == "")
1867                 s = "^1Unregistered Player";
1868         return s;
1869 }
1870
1871 float race_readTime(string map, float pos)
1872 {
1873         string rr;
1874         if(g_cts)
1875                 rr = CTS_RECORD;
1876         else
1877                 rr = RACE_RECORD;
1878
1879         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1880 }
1881
1882 string race_readUID(string map, float pos)
1883 {
1884         string rr;
1885         if(g_cts)
1886                 rr = CTS_RECORD;
1887         else
1888                 rr = RACE_RECORD;
1889
1890         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1891 }
1892
1893 float race_readPos(string map, float t) {
1894         float i;
1895         for (i = 1; i <= RANKINGS_CNT; ++i)
1896                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1897                         return i;
1898
1899         return 0; // pos is zero if unranked
1900 }
1901
1902 void race_writeTime(string map, float t, string myuid)
1903 {
1904         string rr;
1905         if(g_cts)
1906                 rr = CTS_RECORD;
1907         else
1908                 rr = RACE_RECORD;
1909
1910         float newpos;
1911         newpos = race_readPos(map, t);
1912
1913         float i, prevpos = 0;
1914         for(i = 1; i <= RANKINGS_CNT; ++i)
1915         {
1916                 if(race_readUID(map, i) == myuid)
1917                         prevpos = i;
1918         }
1919         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1920                 for (i = prevpos; i > newpos; --i) {
1921                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1922                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1923                 }
1924         } else { // player has no ranked record yet
1925                 for (i = RANKINGS_CNT; i > newpos; --i) {
1926                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1927                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1928                 }
1929         }
1930
1931         // store new time itself
1932         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1933         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1934 }
1935
1936 string race_readName(string map, float pos)
1937 {
1938         string rr;
1939         if(g_cts)
1940                 rr = CTS_RECORD;
1941         else
1942                 rr = RACE_RECORD;
1943
1944         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1945 }
1946
1947 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1948 {
1949     float m, i;
1950     vector start, org, delta, end, enddown, mstart;
1951     entity sp;
1952
1953     m = e.dphitcontentsmask;
1954     e.dphitcontentsmask = goodcontents | badcontents;
1955
1956     org = world.mins;
1957     delta = world.maxs - world.mins;
1958
1959     start = end = org;
1960
1961     for (i = 0; i < attempts; ++i)
1962     {
1963         start_x = org_x + random() * delta_x;
1964         start_y = org_y + random() * delta_y;
1965         start_z = org_z + random() * delta_z;
1966
1967         // rule 1: start inside world bounds, and outside
1968         // solid, and don't start from somewhere where you can
1969         // fall down to evil
1970         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1971         if (trace_fraction >= 1)
1972             continue;
1973         if (trace_startsolid)
1974             continue;
1975         if (trace_dphitcontents & badcontents)
1976             continue;
1977         if (trace_dphitq3surfaceflags & badsurfaceflags)
1978             continue;
1979
1980         // rule 2: if we are too high, lower the point
1981         if (trace_fraction * delta_z > maxaboveground)
1982             start = trace_endpos + '0 0 1' * maxaboveground;
1983         enddown = trace_endpos;
1984
1985         // rule 3: make sure we aren't outside the map. This only works
1986         // for somewhat well formed maps. A good rule of thumb is that
1987         // the map should have a convex outside hull.
1988         // these can be traceLINES as we already verified the starting box
1989         mstart = start + 0.5 * (e.mins + e.maxs);
1990         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1991         if (trace_fraction >= 1)
1992             continue;
1993         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1994         if (trace_fraction >= 1)
1995             continue;
1996         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1997         if (trace_fraction >= 1)
1998             continue;
1999         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2000         if (trace_fraction >= 1)
2001             continue;
2002         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2003         if (trace_fraction >= 1)
2004             continue;
2005
2006         // rule 4: we must "see" some spawnpoint
2007         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2008                 if(checkpvs(mstart, sp))
2009                         break;
2010         if(!sp)
2011         {
2012                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2013                         if(checkpvs(mstart, sp))
2014                                 break;
2015                 if(!sp)
2016                         continue;
2017         }
2018
2019         // find a random vector to "look at"
2020         end_x = org_x + random() * delta_x;
2021         end_y = org_y + random() * delta_y;
2022         end_z = org_z + random() * delta_z;
2023         end = start + normalize(end - start) * vlen(delta);
2024
2025         // rule 4: start TO end must not be too short
2026         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2027         if (trace_startsolid)
2028             continue;
2029         if (trace_fraction < minviewdistance / vlen(delta))
2030             continue;
2031
2032         // rule 5: don't want to look at sky
2033         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2034             continue;
2035
2036         // rule 6: we must not end up in trigger_hurt
2037         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2038             continue;
2039
2040         break;
2041     }
2042
2043     e.dphitcontentsmask = m;
2044
2045     if (i < attempts)
2046     {
2047         setorigin(e, start);
2048         e.angles = vectoangles(end - start);
2049         dprint("Needed ", ftos(i + 1), " attempts\n");
2050         return TRUE;
2051     }
2052     else
2053         return FALSE;
2054 }
2055
2056 float zcurveparticles_effectno;
2057 vector zcurveparticles_start;
2058 float zcurveparticles_spd;
2059
2060 void endzcurveparticles()
2061 {
2062         if(zcurveparticles_effectno)
2063         {
2064                 // terminator
2065                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2066         }
2067         zcurveparticles_effectno = 0;
2068 }
2069
2070 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2071 {
2072         spd = bound(0, floor(spd / 16), 32767);
2073         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2074         {
2075                 endzcurveparticles();
2076                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2077                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2078                 WriteShort(MSG_BROADCAST, effectno);
2079                 WriteCoord(MSG_BROADCAST, start_x);
2080                 WriteCoord(MSG_BROADCAST, start_y);
2081                 WriteCoord(MSG_BROADCAST, start_z);
2082                 zcurveparticles_effectno = effectno;
2083                 zcurveparticles_start = start;
2084         }
2085         else
2086                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2087         WriteCoord(MSG_BROADCAST, end_x);
2088         WriteCoord(MSG_BROADCAST, end_y);
2089         WriteCoord(MSG_BROADCAST, end_z);
2090         WriteCoord(MSG_BROADCAST, end_dz);
2091         zcurveparticles_spd = spd;
2092 }
2093
2094 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2095 {
2096         float end_dz;
2097         vector vecxy, velxy;
2098
2099         vecxy = end - start;
2100         vecxy_z = 0;
2101         velxy = vel;
2102         velxy_z = 0;
2103
2104         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2105         {
2106                 endzcurveparticles();
2107                 trailparticles(world, effectno, start, end);
2108                 return;
2109         }
2110
2111         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2112         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2113 }
2114
2115 void write_recordmarker(entity pl, float tstart, float dt)
2116 {
2117     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2118
2119     // also write a marker into demo files for demotc-race-record-extractor to find
2120     stuffcmd(pl,
2121              strcat(
2122                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2123                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2124 }
2125
2126 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2127 {
2128         switch(algn)
2129         {
2130                 default:
2131                 case 3: // right
2132                         break;
2133
2134                 case 4: // left
2135                         vecs_y = -vecs_y;
2136                         break;
2137
2138                 case 1:
2139                         if(allowcenter) // 2: allow center handedness
2140                         {
2141                                 // center
2142                                 vecs_y = 0;
2143                                 vecs_z -= 2;
2144                         }
2145                         else
2146                         {
2147                                 // right
2148                         }
2149                         break;
2150
2151                 case 2:
2152                         if(allowcenter) // 2: allow center handedness
2153                         {
2154                                 // center
2155                                 vecs_y = 0;
2156                                 vecs_z -= 2;
2157                         }
2158                         else
2159                         {
2160                                 // left
2161                                 vecs_y = -vecs_y;
2162                         }
2163                         break;
2164         }
2165         return vecs;
2166 }
2167
2168 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2169 {
2170         string s;
2171         vector v;
2172
2173         if (autocvar_g_shootfromeye)
2174         {
2175                 if (visual)
2176                 {
2177                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2178                         else { vecs_y = 0; vecs_z -= 2; }
2179                 }
2180                 else
2181                 {
2182                         vecs_y = 0;
2183                         vecs_z = 0;
2184                 }
2185         }
2186         else if (autocvar_g_shootfromcenter)
2187         {
2188                 vecs_y = 0;
2189                 vecs_z -= 2;
2190         }
2191         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2192         {
2193                 v = stov(s);
2194                 if (y_is_right)
2195                         v_y = -v_y;
2196                 if (v_x != 0)
2197                         vecs_x = v_x;
2198                 vecs_y = v_y;
2199                 vecs_z = v_z;
2200         }
2201         else if (autocvar_g_shootfromclient)
2202         {
2203                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2204         }
2205         return vecs;
2206 }
2207
2208 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2209 {
2210         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2211 }
2212
2213
2214 void attach_sameorigin(entity e, entity to, string tag)
2215 {
2216     vector org, t_forward, t_left, t_up, e_forward, e_up;
2217     float tagscale;
2218
2219     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2220     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2221     t_forward = v_forward * tagscale;
2222     t_left = v_right * -tagscale;
2223     t_up = v_up * tagscale;
2224
2225     e.origin_x = org * t_forward;
2226     e.origin_y = org * t_left;
2227     e.origin_z = org * t_up;
2228
2229     // current forward and up directions
2230     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2231                 e.angles = AnglesTransform_FromVAngles(e.angles);
2232         else
2233                 e.angles = AnglesTransform_FromAngles(e.angles);
2234     fixedmakevectors(e.angles);
2235
2236     // untransform forward, up!
2237     e_forward_x = v_forward * t_forward;
2238     e_forward_y = v_forward * t_left;
2239     e_forward_z = v_forward * t_up;
2240     e_up_x = v_up * t_forward;
2241     e_up_y = v_up * t_left;
2242     e_up_z = v_up * t_up;
2243
2244     e.angles = fixedvectoangles2(e_forward, e_up);
2245     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2246                 e.angles = AnglesTransform_ToVAngles(e.angles);
2247         else
2248                 e.angles = AnglesTransform_ToAngles(e.angles);
2249
2250     setattachment(e, to, tag);
2251     setorigin(e, e.origin);
2252 }
2253
2254 void detach_sameorigin(entity e)
2255 {
2256     vector org;
2257     org = gettaginfo(e, 0);
2258     e.angles = fixedvectoangles2(v_forward, v_up);
2259     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2260                 e.angles = AnglesTransform_ToVAngles(e.angles);
2261         else
2262                 e.angles = AnglesTransform_ToAngles(e.angles);
2263     setorigin(e, org);
2264     setattachment(e, world, "");
2265     setorigin(e, e.origin);
2266 }
2267
2268 void follow_sameorigin(entity e, entity to)
2269 {
2270     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2271     e.aiment = to; // make the hole follow bmodel
2272     e.punchangle = to.angles; // the original angles of bmodel
2273     e.view_ofs = e.origin - to.origin; // relative origin
2274     e.v_angle = e.angles - to.angles; // relative angles
2275 }
2276
2277 void unfollow_sameorigin(entity e)
2278 {
2279     e.movetype = MOVETYPE_NONE;
2280 }
2281
2282 entity gettaginfo_relative_ent;
2283 vector gettaginfo_relative(entity e, float tag)
2284 {
2285     if (!gettaginfo_relative_ent)
2286     {
2287         gettaginfo_relative_ent = spawn();
2288         gettaginfo_relative_ent.effects = EF_NODRAW;
2289     }
2290     gettaginfo_relative_ent.model = e.model;
2291     gettaginfo_relative_ent.modelindex = e.modelindex;
2292     gettaginfo_relative_ent.frame = e.frame;
2293     return gettaginfo(gettaginfo_relative_ent, tag);
2294 }
2295
2296 .float scale2;
2297
2298 float modeleffect_SendEntity(entity to, float sf)
2299 {
2300         float f;
2301         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2302
2303         f = 0;
2304         if(self.velocity != '0 0 0')
2305                 f |= 1;
2306         if(self.angles != '0 0 0')
2307                 f |= 2;
2308         if(self.avelocity != '0 0 0')
2309                 f |= 4;
2310
2311         WriteByte(MSG_ENTITY, f);
2312         WriteShort(MSG_ENTITY, self.modelindex);
2313         WriteByte(MSG_ENTITY, self.skin);
2314         WriteByte(MSG_ENTITY, self.frame);
2315         WriteCoord(MSG_ENTITY, self.origin_x);
2316         WriteCoord(MSG_ENTITY, self.origin_y);
2317         WriteCoord(MSG_ENTITY, self.origin_z);
2318         if(f & 1)
2319         {
2320                 WriteCoord(MSG_ENTITY, self.velocity_x);
2321                 WriteCoord(MSG_ENTITY, self.velocity_y);
2322                 WriteCoord(MSG_ENTITY, self.velocity_z);
2323         }
2324         if(f & 2)
2325         {
2326                 WriteCoord(MSG_ENTITY, self.angles_x);
2327                 WriteCoord(MSG_ENTITY, self.angles_y);
2328                 WriteCoord(MSG_ENTITY, self.angles_z);
2329         }
2330         if(f & 4)
2331         {
2332                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2333                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2334                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2335         }
2336         WriteShort(MSG_ENTITY, self.scale * 256.0);
2337         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2338         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2339         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2340         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2341
2342         return TRUE;
2343 }
2344
2345 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2346 {
2347         entity e;
2348         float sz;
2349         e = spawn();
2350         e.classname = "modeleffect";
2351         setmodel(e, m);
2352         e.frame = f;
2353         setorigin(e, o);
2354         e.velocity = v;
2355         e.angles = ang;
2356         e.avelocity = angv;
2357         e.alpha = a;
2358         e.teleport_time = t1;
2359         e.fade_time = t2;
2360         e.skin = s;
2361         if(s0 >= 0)
2362                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2363         else
2364                 e.scale = -s0;
2365         if(s2 >= 0)
2366                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2367         else
2368                 e.scale2 = -s2;
2369         sz = max(e.scale, e.scale2);
2370         setsize(e, e.mins * sz, e.maxs * sz);
2371         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2372 }
2373
2374 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2375 {
2376         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2377 }
2378
2379 float randombit(float bits)
2380 {
2381         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2382                 return bits;
2383
2384         float n, f, b, r;
2385
2386         r = random();
2387         b = 0;
2388         n = 0;
2389
2390         for(f = 1; f <= bits; f *= 2)
2391         {
2392                 if(bits & f)
2393                 {
2394                         ++n;
2395                         r *= n;
2396                         if(r <= 1)
2397                                 b = f;
2398                         else
2399                                 r = (r - 1) / (n - 1);
2400                 }
2401         }
2402
2403         return b;
2404 }
2405
2406 float randombits(float bits, float k, float error_return)
2407 {
2408         float r;
2409         r = 0;
2410         while(k > 0 && bits != r)
2411         {
2412                 r += randombit(bits - r);
2413                 --k;
2414         }
2415         if(error_return)
2416                 if(k > 0)
2417                         return -1; // all
2418         return r;
2419 }
2420
2421 void randombit_test(float bits, float iter)
2422 {
2423         while(iter > 0)
2424         {
2425                 print(ftos(randombit(bits)), "\n");
2426                 --iter;
2427         }
2428 }
2429
2430 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2431 {
2432         if(halflifedist > 0)
2433                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2434         else if(halflifedist < 0)
2435                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2436         else
2437                 return 1;
2438 }
2439
2440
2441
2442
2443 #ifdef RELEASE
2444 #define cvar_string_normal builtin_cvar_string
2445 #define cvar_normal builtin_cvar
2446 #else
2447 string cvar_string_normal(string n)
2448 {
2449         if not(cvar_type(n) & 1)
2450                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2451         return builtin_cvar_string(n);
2452 }
2453
2454 float cvar_normal(string n)
2455 {
2456         return stof(cvar_string_normal(n));
2457 }
2458 #endif
2459 #define cvar_set_normal builtin_cvar_set
2460
2461 void defer_think()
2462 {
2463     entity oself;
2464
2465     oself           = self;
2466     self            = self.owner;
2467     oself.think     = SUB_Remove;
2468     oself.nextthink = time;
2469
2470     oself.use();
2471 }
2472
2473 /*
2474     Execute func() after time + fdelay.
2475     self when func is executed = self when defer is called
2476 */
2477 void defer(float fdelay, void() func)
2478 {
2479     entity e;
2480
2481     e           = spawn();
2482     e.owner     = self;
2483     e.use       = func;
2484     e.think     = defer_think;
2485     e.nextthink = time + fdelay;
2486 }
2487
2488 .string aiment_classname;
2489 .float aiment_deadflag;
2490 void SetMovetypeFollow(entity ent, entity e)
2491 {
2492         // FIXME this may not be warpzone aware
2493         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2494         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2495         ent.aiment = e; // make the hole follow bmodel
2496         ent.punchangle = e.angles; // the original angles of bmodel
2497         ent.view_ofs = ent.origin - e.origin; // relative origin
2498         ent.v_angle = ent.angles - e.angles; // relative angles
2499         ent.aiment_classname = strzone(e.classname);
2500         ent.aiment_deadflag = e.deadflag;
2501 }
2502 void UnsetMovetypeFollow(entity ent)
2503 {
2504         ent.movetype = MOVETYPE_FLY;
2505         PROJECTILE_MAKETRIGGER(ent);
2506         ent.aiment = world;
2507 }
2508 float LostMovetypeFollow(entity ent)
2509 {
2510 /*
2511         if(ent.movetype != MOVETYPE_FOLLOW)
2512                 if(ent.aiment)
2513                         error("???");
2514 */
2515         if(ent.aiment)
2516         {
2517                 if(ent.aiment.classname != ent.aiment_classname)
2518                         return 1;
2519                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2520                         return 1;
2521         }
2522         return 0;
2523 }
2524
2525 float isPushable(entity e)
2526 {
2527         if(e.iscreature)
2528                 return TRUE;
2529         if(e.pushable)
2530                 return TRUE;
2531         switch(e.classname)
2532         {
2533                 case "body":
2534                 case "droppedweapon":
2535                 case "keepawayball":
2536                 case "nexball_basketball":
2537                 case "nexball_football":
2538                         return TRUE;
2539                 case "bullet": // antilagged bullets can't hit this either
2540                         return FALSE;
2541         }
2542         if (e.projectiledeathtype)
2543                 return TRUE;
2544         return FALSE;
2545 }