qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625         }
 626 }
 627
 628 float fexists(string f)
 629 {
 630     float fh;
 631     fh = fopen(f, FILE_READ);
 632     if (fh < 0)
 633         return FALSE;
 634     fclose(fh);
 635     return TRUE;
 636 }
 637
 638 void backtrace(string msg)
 639 {
 640     float dev, war;
 641     dev = autocvar_developer;
 642     war = autocvar_prvm_backtraceforwarnings;
 643     cvar_set("developer", "1");
 644     cvar_set("prvm_backtraceforwarnings", "1");
 645     print("\n");
 646     print("--- CUT HERE ---\nWARNING: ");
 647     print(msg);
 648     print("\n");
 649     remove(world); // isn't there any better way to cause a backtrace?
 650     print("\n--- CUT UNTIL HERE ---\n");
 651     cvar_set("developer", ftos(dev));
 652     cvar_set("prvm_backtraceforwarnings", ftos(war));
 653 }
 654
 655 string Team_ColorCode(float teamid)
 656 {
 657     if (teamid == COLOR_TEAM1)
 658         return "^1";
 659     else if (teamid == COLOR_TEAM2)
 660         return "^4";
 661     else if (teamid == COLOR_TEAM3)
 662         return "^3";
 663     else if (teamid == COLOR_TEAM4)
 664         return "^6";
 665     else
 666         return "^7";
 667 }
 668
 669 string Team_ColorName(float t)
 670 {
 671     // fixme: Search for team entities and get their .netname's!
 672     if (t == COLOR_TEAM1)
 673         return "Red";
 674     if (t == COLOR_TEAM2)
 675         return "Blue";
 676     if (t == COLOR_TEAM3)
 677         return "Yellow";
 678     if (t == COLOR_TEAM4)
 679         return "Pink";
 680     return "Neutral";
 681 }
 682
 683 string Team_ColorNameLowerCase(float t)
 684 {
 685     // fixme: Search for team entities and get their .netname's!
 686     if (t == COLOR_TEAM1)
 687         return "red";
 688     if (t == COLOR_TEAM2)
 689         return "blue";
 690     if (t == COLOR_TEAM3)
 691         return "yellow";
 692     if (t == COLOR_TEAM4)
 693         return "pink";
 694     return "neutral";
 695 }
 696
 697 float ColourToNumber(string team_colour)
 698 {
 699         if (team_colour == "red")
 700                 return COLOR_TEAM1;
 701
 702         if (team_colour == "blue")
 703                 return COLOR_TEAM2;
 704
 705         if (team_colour == "yellow")
 706                 return COLOR_TEAM3;
 707
 708         if (team_colour == "pink")
 709                 return COLOR_TEAM4;
 710
 711         if (team_colour == "auto")
 712                 return 0;
 713
 714         return -1;
 715 }
 716
 717 float NumberToTeamNumber(float number)
 718 {
 719         if (number == 1)
 720                 return COLOR_TEAM1;
 721
 722         if (number == 2)
 723                 return COLOR_TEAM2;
 724
 725         if (number == 3)
 726                 return COLOR_TEAM3;
 727
 728         if (number == 4)
 729                 return COLOR_TEAM4;
 730
 731         return -1;
 732 }
 733
 734 #define CENTERPRIO_POINT 1
 735 #define CENTERPRIO_SPAM 2
 736 #define CENTERPRIO_VOTE 4
 737 #define CENTERPRIO_NORMAL 5
 738 #define CENTERPRIO_SHIELDING 7
 739 #define CENTERPRIO_MAPVOTE 9
 740 #define CENTERPRIO_IDLEKICK 50
 741 #define CENTERPRIO_ADMIN 99
 742 .float centerprint_priority;
 743 .float centerprint_expires;
 744 void centerprint_atprio(entity e, float prio, string s)
 745 {
 746     if (intermission_running)
 747         if (prio < CENTERPRIO_MAPVOTE)
 748             return;
 749     if (time > e.centerprint_expires)
 750         e.centerprint_priority = 0;
 751     if (prio >= e.centerprint_priority)
 752     {
 753         e.centerprint_priority = prio;
 754         if (timeoutStatus == 2)
 755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 756         else
 757             e.centerprint_expires = time + e.cvar_scr_centertime;
 758         centerprint_builtin(e, s);
 759     }
 760 }
 761 void centerprint_expire(entity e, float prio)
 762 {
 763     if (prio == e.centerprint_priority)
 764     {
 765         e.centerprint_priority = 0;
 766         centerprint_builtin(e, "");
 767     }
 768 }
 769 void centerprint(entity e, string s)
 770 {
 771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 772 }
 773
 774 // decolorizes and team colors the player name when needed
 775 string playername(entity p)
 776 {
 777     string t;
 778     if (teams_matter && !intermission_running && p.classname == "player")
 779     {
 780         t = Team_ColorCode(p.team);
 781         return strcat(t, strdecolorize(p.netname));
 782     }
 783     else
 784         return p.netname;
 785 }
 786
 787 vector randompos(vector m1, vector m2)
 788 {
 789     local vector v;
 790     m2 = m2 - m1;
 791     v_x = m2_x * random() + m1_x;
 792     v_y = m2_y * random() + m1_y;
 793     v_z = m2_z * random() + m1_z;
 794     return  v;
 795 };
 796
 797 //#NO AUTOCVARS START
 798
 799 float g_pickup_shells;
 800 float g_pickup_shells_max;
 801 float g_pickup_nails;
 802 float g_pickup_nails_max;
 803 float g_pickup_rockets;
 804 float g_pickup_rockets_max;
 805 float g_pickup_cells;
 806 float g_pickup_cells_max;
 807 float g_pickup_fuel;
 808 float g_pickup_fuel_jetpack;
 809 float g_pickup_fuel_max;
 810 float g_pickup_armorsmall;
 811 float g_pickup_armorsmall_max;
 812 float g_pickup_armorsmall_anyway;
 813 float g_pickup_armormedium;
 814 float g_pickup_armormedium_max;
 815 float g_pickup_armormedium_anyway;
 816 float g_pickup_armorbig;
 817 float g_pickup_armorbig_max;
 818 float g_pickup_armorbig_anyway;
 819 float g_pickup_armorlarge;
 820 float g_pickup_armorlarge_max;
 821 float g_pickup_armorlarge_anyway;
 822 float g_pickup_healthsmall;
 823 float g_pickup_healthsmall_max;
 824 float g_pickup_healthsmall_anyway;
 825 float g_pickup_healthmedium;
 826 float g_pickup_healthmedium_max;
 827 float g_pickup_healthmedium_anyway;
 828 float g_pickup_healthlarge;
 829 float g_pickup_healthlarge_max;
 830 float g_pickup_healthlarge_anyway;
 831 float g_pickup_healthmega;
 832 float g_pickup_healthmega_max;
 833 float g_pickup_healthmega_anyway;
 834 float g_pickup_ammo_anyway;
 835 float g_pickup_weapons_anyway;
 836 float g_weaponarena;
 837 float g_weaponarena_random;
 838 float g_weaponarena_random_with_laser;
 839 string g_weaponarena_list;
 840 float g_weaponspeedfactor;
 841 float g_weaponratefactor;
 842 float g_weapondamagefactor;
 843 float g_weaponforcefactor;
 844 float g_weaponspreadfactor;
 845
 846 float start_weapons;
 847 float start_items;
 848 float start_ammo_shells;
 849 float start_ammo_nails;
 850 float start_ammo_rockets;
 851 float start_ammo_cells;
 852 float start_ammo_fuel;
 853 float start_health;
 854 float start_armorvalue;
 855 float warmup_start_weapons;
 856 float warmup_start_ammo_shells;
 857 float warmup_start_ammo_nails;
 858 float warmup_start_ammo_rockets;
 859 float warmup_start_ammo_cells;
 860 float warmup_start_ammo_fuel;
 861 float warmup_start_health;
 862 float warmup_start_armorvalue;
 863 float g_weapon_stay;
 864 float g_ghost_items;
 865
 866 entity get_weaponinfo(float w);
 867
 868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 869 {
 870         var float i = weaponinfo.weapon;
 871
 872         if (!i)
 873                 return 0;
 874
 875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 876
 877         if (t < 0) // "default" weapon selection
 878         {
 879                 if (g_lms || g_ca || allguns)
 880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 881                 else if(t < -1)
 882                         t = 0;
 883                 else if (g_race || g_cts)
 884                         t = (i == WEP_LASER);
 885                 else if (g_nexball)
 886                         t = 0; // weapon is set a few lines later
 887                 else
 888                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 889                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 890                         t |= (i == WEP_HOOK);
 891         }
 892
 893         // we cannot disable porto in Nexball, we must force it
 894         if(g_nexball && i == WEP_PORTO)
 895                 t = 1;
 896
 897         return t;
 898 }
 899
 900 void readplayerstartcvars()
 901 {
 902         entity e;
 903         float i, j, t;
 904         string s;
 905
 906         // initialize starting values for players
 907         start_weapons = 0;
 908         start_items = 0;
 909         start_ammo_shells = 0;
 910         start_ammo_nails = 0;
 911         start_ammo_rockets = 0;
 912         start_ammo_cells = 0;
 913         start_health = cvar("g_balance_health_start");
 914         start_armorvalue = cvar("g_balance_armor_start");
 915
 916         g_weaponarena = 0;
 917         s = cvar_string("g_weaponarena");
 918         if (s == "0")
 919         {
 920         }
 921         else if (s == "all")
 922         {
 923                 g_weaponarena_list = "All Weapons";
 924                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 925                 {
 926                         e = get_weaponinfo(j);
 927                         g_weaponarena |= e.weapons;
 928                         weapon_action(e.weapon, WR_PRECACHE);
 929                 }
 930         }
 931         else if (s == "most")
 932         {
 933                 g_weaponarena_list = "Most Weapons";
 934                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 935                 {
 936                         e = get_weaponinfo(j);
 937                         if (e.spawnflags & WEP_FLAG_NORMAL)
 938                         {
 939                                 g_weaponarena |= e.weapons;
 940                                 weapon_action(e.weapon, WR_PRECACHE);
 941                         }
 942                 }
 943         }
 944         else if (s == "none")
 945         {
 946                 g_weaponarena_list = "No Weapons";
 947                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 948         }
 949         else
 950         {
 951                 t = tokenize_console(s);
 952                 g_weaponarena_list = "";
 953                 for (i = 0; i < t; ++i)
 954                 {
 955                         s = argv(i);
 956                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 957                         {
 958                                 e = get_weaponinfo(j);
 959                                 if (e.netname == s)
 960                                 {
 961                                         g_weaponarena |= e.weapons;
 962                                         weapon_action(e.weapon, WR_PRECACHE);
 963                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 964                                         break;
 965                                 }
 966                         }
 967                         if (j > WEP_LAST)
 968                         {
 969                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 970                         }
 971                 }
 972                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 973         }
 974
 975         if(g_weaponarena)
 976                 g_weaponarena_random = cvar("g_weaponarena_random");
 977         else
 978                 g_weaponarena_random = 0;
 979         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 980
 981         if (g_weaponarena)
 982         {
 983                 start_weapons = g_weaponarena;
 984                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 985                 {
 986                         e = get_weaponinfo(j);
 987                         if(start_weapons & e.weapons)
 988                         {
 989                                 if(e.items & IT_ROCKETS)
 990                                         start_ammo_rockets = 999;
 991                                 if(e.items & IT_SHELLS)
 992                                         start_ammo_shells = 999;
 993                                 if(e.items & IT_CELLS)
 994                                         start_ammo_cells = 999;
 995                                 if(e.items & IT_NAILS)
 996                                         start_ammo_nails = 999;
 997                                 if(e.items & IT_FUEL)
 998                                         start_ammo_fuel = 999;
 999                         }
1000                 }
1001                 start_items |= IT_UNLIMITED_AMMO;
1002         }
1003         else if (g_minstagib)
1004         {
1005                 start_health = 100;
1006                 start_armorvalue = 0;
1007                 start_weapons = WEPBIT_MINSTANEX;
1008                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1009                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1010                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1011                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1012
1013                 if (g_minstagib_invis_alpha <= 0)
1014                         g_minstagib_invis_alpha = -1;
1015         }
1016         else
1017         {
1018                 if (g_lms || g_ca)
1019                 {
1020                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1021                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1022                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1023                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1024                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1025                         start_health = cvar("g_lms_start_health");
1026                         start_armorvalue = cvar("g_lms_start_armor");
1027                 }
1028                 else
1029                 {
1030                         start_ammo_shells = cvar("g_start_ammo_shells");
1031                         start_ammo_nails = cvar("g_start_ammo_nails");
1032                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1033                         start_ammo_cells = cvar("g_start_ammo_cells");
1034                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1035                 }
1036
1037                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1038                 {
1039                         e = get_weaponinfo(i);
1040                         if(want_weapon("g_start_weapon_", e, FALSE))
1041                                 start_weapons |= e.weapons;
1042                 }
1043         }
1044
1045         if (inWarmupStage)
1046         {
1047                 warmup_start_ammo_shells = start_ammo_shells;
1048                 warmup_start_ammo_nails = start_ammo_nails;
1049                 warmup_start_ammo_rockets = start_ammo_rockets;
1050                 warmup_start_ammo_cells = start_ammo_cells;
1051                 warmup_start_ammo_fuel = start_ammo_fuel;
1052                 warmup_start_health = start_health;
1053                 warmup_start_armorvalue = start_armorvalue;
1054                 warmup_start_weapons = start_weapons;
1055
1056                 if (!g_weaponarena && !g_minstagib && !g_ca)
1057                 {
1058                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1059                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1060                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1061                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1062                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1063                         warmup_start_health = cvar("g_warmup_start_health");
1064                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1065                         warmup_start_weapons = 0;
1066                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1067                         {
1068                                 e = get_weaponinfo(i);
1069                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1070                                         warmup_start_weapons |= e.weapons;
1071                         }
1072                 }
1073         }
1074
1075         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1076         {
1077                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1078                 start_items |= IT_FUEL_REGEN;
1079                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1080                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1081         }
1082
1083         if(!cvar("g_use_ammunition"))
1084         {
1085                 start_ammo_shells = cvar("g_pickup_shells_max");
1086                 start_ammo_nails = cvar("g_pickup_nails_max");
1087                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1088                 start_ammo_cells = cvar("g_pickup_cells_max");
1089                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1090                 start_items |= IT_UNLIMITED_AMMO;
1091                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1092                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1093                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1094                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1095                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1096                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1097         }
1098
1099         if (g_jetpack)
1100                 start_items |= IT_JETPACK;
1101
1102         if (g_weapon_stay == 2)
1103         {
1104                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1105                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1106                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1107                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1108                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1109                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1110                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1111                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1112                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1113                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1114         }
1115
1116         MUTATOR_CALLHOOK(SetStartItems);
1117
1118         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1119         {
1120                 e = get_weaponinfo(i);
1121                 if(e.weapons & (start_weapons | warmup_start_weapons))
1122                         weapon_action(e.weapon, WR_PRECACHE);
1123         }
1124
1125         start_ammo_shells = max(0, start_ammo_shells);
1126         start_ammo_nails = max(0, start_ammo_nails);
1127         start_ammo_cells = max(0, start_ammo_cells);
1128         start_ammo_rockets = max(0, start_ammo_rockets);
1129         start_ammo_fuel = max(0, start_ammo_fuel);
1130
1131         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1132         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1133         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1134         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1135         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1136 }
1137
1138 float g_bugrigs;
1139 float g_bugrigs_planar_movement;
1140 float g_bugrigs_planar_movement_car_jumping;
1141 float g_bugrigs_reverse_spinning;
1142 float g_bugrigs_reverse_speeding;
1143 float g_bugrigs_reverse_stopping;
1144 float g_bugrigs_air_steering;
1145 float g_bugrigs_angle_smoothing;
1146 float g_bugrigs_friction_floor;
1147 float g_bugrigs_friction_brake;
1148 float g_bugrigs_friction_air;
1149 float g_bugrigs_accel;
1150 float g_bugrigs_speed_ref;
1151 float g_bugrigs_speed_pow;
1152 float g_bugrigs_steer;
1153
1154 float g_touchexplode;
1155 float g_touchexplode_radius;
1156 float g_touchexplode_damage;
1157 float g_touchexplode_edgedamage;
1158 float g_touchexplode_force;
1159
1160 float sv_autotaunt;
1161 float sv_taunt;
1162
1163 float sv_pitch_min;
1164 float sv_pitch_max;
1165 float sv_pitch_fixyaw;
1166
1167 void readlevelcvars(void)
1168 {
1169         // first load all the mutators
1170         if(cvar("g_nix"))
1171                 MUTATOR_ADD(mutator_nix);
1172         if(cvar("g_dodging"))
1173                 MUTATOR_ADD(mutator_dodging);
1174         if(cvar("g_rocket_flying"))
1175                 MUTATOR_ADD(mutator_rocketflying);
1176         if(cvar("g_vampire"))
1177                 MUTATOR_ADD(mutator_vampire);
1178
1179         if(cvar("sv_allow_fullbright"))
1180                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1181
1182     g_bugrigs = cvar("g_bugrigs");
1183     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1184     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1185     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1186     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1187     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1188     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1189     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1190     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1191     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1192     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1193     g_bugrigs_accel = cvar("g_bugrigs_accel");
1194     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1195     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1196     g_bugrigs_steer = cvar("g_bugrigs_steer");
1197
1198     g_touchexplode = cvar("g_touchexplode");
1199     g_touchexplode_radius = cvar("g_touchexplode_radius");
1200     g_touchexplode_damage = cvar("g_touchexplode_damage");
1201     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1202     g_touchexplode_force = cvar("g_touchexplode_force");
1203
1204 #ifdef ALLOW_FORCEMODELS
1205         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1206 #endif
1207         sv_loddistance1 = cvar("sv_loddistance1");
1208         sv_loddistance2 = cvar("sv_loddistance2");
1209
1210         if(sv_loddistance2 <= sv_loddistance1)
1211                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1212
1213         sv_clones = cvar("sv_clones");
1214         sv_gentle = cvar("sv_gentle");
1215         sv_foginterval = cvar("sv_foginterval");
1216         g_cloaked = cvar("g_cloaked");
1217         g_jump_grunt = cvar("g_jump_grunt");
1218         g_footsteps = cvar("g_footsteps");
1219         g_grappling_hook = cvar("g_grappling_hook");
1220         g_jetpack = cvar("g_jetpack");
1221         g_midair = cvar("g_midair");
1222         g_minstagib = cvar("g_minstagib");
1223         g_norecoil = cvar("g_norecoil");
1224         g_bloodloss = cvar("g_bloodloss");
1225         sv_maxidle = cvar("sv_maxidle");
1226         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1227         sv_pogostick = cvar("sv_pogostick");
1228         g_ctf_reverse = cvar("g_ctf_reverse");
1229         sv_autotaunt = cvar("sv_autotaunt");
1230         sv_taunt = cvar("sv_taunt");
1231
1232         inWarmupStage = cvar("g_warmup");
1233         g_warmup_limit = cvar("g_warmup_limit");
1234         g_warmup_allguns = cvar("g_warmup_allguns");
1235         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1236
1237         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1238                 inWarmupStage = 0; // these modes cannot work together, sorry
1239
1240         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1241         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1242         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1243         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1244         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1245         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1246         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1247         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1248         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1249         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1250         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1251         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1252
1253         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1254         g_weaponratefactor = cvar("g_weaponratefactor");
1255         g_weapondamagefactor = cvar("g_weapondamagefactor");
1256         g_weaponforcefactor = cvar("g_weaponforcefactor");
1257         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1258
1259         g_pickup_shells = cvar("g_pickup_shells");
1260         g_pickup_shells_max = cvar("g_pickup_shells_max");
1261         g_pickup_nails = cvar("g_pickup_nails");
1262         g_pickup_nails_max = cvar("g_pickup_nails_max");
1263         g_pickup_rockets = cvar("g_pickup_rockets");
1264         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1265         g_pickup_cells = cvar("g_pickup_cells");
1266         g_pickup_cells_max = cvar("g_pickup_cells_max");
1267         g_pickup_fuel = cvar("g_pickup_fuel");
1268         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1269         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1270         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1271         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1272         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1273         g_pickup_armormedium = cvar("g_pickup_armormedium");
1274         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1275         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1276         g_pickup_armorbig = cvar("g_pickup_armorbig");
1277         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1278         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1279         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1280         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1281         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1282         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1283         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1284         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1285         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1286         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1287         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1288         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1289         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1290         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1291         g_pickup_healthmega = cvar("g_pickup_healthmega");
1292         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1293         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1294
1295         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1296         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1297
1298         g_pinata = cvar("g_pinata");
1299
1300     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1301     if(!g_weapon_stay)
1302         g_weapon_stay = cvar("g_weapon_stay");
1303
1304         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1305                 g_weapon_stay = 1;
1306
1307         g_ghost_items = cvar("g_ghost_items");
1308
1309         if(g_ghost_items >= 1)
1310                 g_ghost_items = 0.25; // default alpha value
1311
1312         if not(inWarmupStage && !g_ca)
1313                 game_starttime = cvar("g_start_delay");
1314
1315         sv_pitch_min = cvar("sv_pitch_min");
1316         sv_pitch_max = cvar("sv_pitch_max");
1317         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1318
1319         readplayerstartcvars();
1320 }
1321
1322 //#NO AUTOCVARS END
1323
1324 // Sound functions
1325 string precache_sound (string s) = #19;
1326 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1327 float precache_sound_index (string s) = #19;
1328
1329 #define SND_VOLUME      1
1330 #define SND_ATTENUATION 2
1331 #define SND_LARGEENTITY 8
1332 #define SND_LARGESOUND  16
1333
1334 float sound_allowed(float dest, entity e)
1335 {
1336     // sounds from world may always pass
1337     for (;;)
1338     {
1339         if (e.classname == "body")
1340             e = e.enemy;
1341         if (e.owner && e.owner != e)
1342             e = e.owner;
1343         else
1344             break;
1345     }
1346     // sounds to self may always pass
1347     if (dest == MSG_ONE)
1348         if (e == msg_entity)
1349             return TRUE;
1350     // sounds by players can be removed
1351     if (autocvar_bot_sound_monopoly)
1352         if (clienttype(e) == CLIENTTYPE_REAL)
1353             return FALSE;
1354     // anything else may pass
1355     return TRUE;
1356 }
1357
1358 void sound(entity e, float chan, string samp, float vol, float atten)
1359 {
1360     if (!sound_allowed(MSG_BROADCAST, e))
1361         return;
1362     sound_builtin(e, chan, samp, vol, atten);
1363 }
1364 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1365 {
1366     float entno, idx;
1367
1368     if (!sound_allowed(dest, e))
1369         return;
1370
1371     entno = num_for_edict(e);
1372     idx = precache_sound_index(samp);
1373
1374     float sflags;
1375     sflags = 0;
1376
1377     atten = floor(atten * 64);
1378     vol = floor(vol * 255);
1379
1380     if (vol != 255)
1381         sflags |= SND_VOLUME;
1382     if (atten != 64)
1383         sflags |= SND_ATTENUATION;
1384     if (entno >= 8192)
1385         sflags |= SND_LARGEENTITY;
1386     if (idx >= 256)
1387         sflags |= SND_LARGESOUND;
1388
1389     WriteByte(dest, SVC_SOUND);
1390     WriteByte(dest, sflags);
1391     if (sflags & SND_VOLUME)
1392         WriteByte(dest, vol);
1393     if (sflags & SND_ATTENUATION)
1394         WriteByte(dest, atten);
1395     if (sflags & SND_LARGEENTITY)
1396     {
1397         WriteShort(dest, entno);
1398         WriteByte(dest, chan);
1399     }
1400     else
1401     {
1402         WriteShort(dest, entno * 8 + chan);
1403     }
1404     if (sflags & SND_LARGESOUND)
1405         WriteShort(dest, idx);
1406     else
1407         WriteByte(dest, idx);
1408
1409     WriteCoord(dest, o_x);
1410     WriteCoord(dest, o_y);
1411     WriteCoord(dest, o_z);
1412 }
1413 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1414 {
1415     vector o;
1416
1417     if (!sound_allowed(dest, e))
1418         return;
1419
1420     o = e.origin + 0.5 * (e.mins + e.maxs);
1421     soundtoat(dest, e, o, chan, samp, vol, atten);
1422 }
1423 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1424 {
1425     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1426 }
1427 void stopsoundto(float dest, entity e, float chan)
1428 {
1429     float entno;
1430
1431     if (!sound_allowed(dest, e))
1432         return;
1433
1434     entno = num_for_edict(e);
1435
1436     if (entno >= 8192)
1437     {
1438         float idx, sflags;
1439         idx = precache_sound_index("misc/null.wav");
1440         sflags = SND_LARGEENTITY;
1441         if (idx >= 256)
1442             sflags |= SND_LARGESOUND;
1443         WriteByte(dest, SVC_SOUND);
1444         WriteByte(dest, sflags);
1445         WriteShort(dest, entno);
1446         WriteByte(dest, chan);
1447         if (sflags & SND_LARGESOUND)
1448             WriteShort(dest, idx);
1449         else
1450             WriteByte(dest, idx);
1451         WriteCoord(dest, e.origin_x);
1452         WriteCoord(dest, e.origin_y);
1453         WriteCoord(dest, e.origin_z);
1454     }
1455     else
1456     {
1457         WriteByte(dest, SVC_STOPSOUND);
1458         WriteShort(dest, entno * 8 + chan);
1459     }
1460 }
1461 void stopsound(entity e, float chan)
1462 {
1463     if (!sound_allowed(MSG_BROADCAST, e))
1464         return;
1465
1466     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1467     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1468 }
1469
1470 void play2(entity e, string filename)
1471 {
1472     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1473     msg_entity = e;
1474     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1475 }
1476
1477 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1478 .float spamtime;
1479 float spamsound(entity e, float chan, string samp, float vol, float atten)
1480 {
1481     if (!sound_allowed(MSG_BROADCAST, e))
1482         return FALSE;
1483
1484     if (time > e.spamtime)
1485     {
1486         e.spamtime = time;
1487         sound(e, chan, samp, vol, atten);
1488         return TRUE;
1489     }
1490     return FALSE;
1491 }
1492
1493 void play2team(float t, string filename)
1494 {
1495     local entity head;
1496
1497     if (autocvar_bot_sound_monopoly)
1498         return;
1499
1500     FOR_EACH_REALPLAYER(head)
1501     {
1502         if (head.team == t)
1503             play2(head, filename);
1504     }
1505 }
1506
1507 void play2all(string samp)
1508 {
1509     if (autocvar_bot_sound_monopoly)
1510         return;
1511
1512     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1513 }
1514
1515 void PrecachePlayerSounds(string f);
1516 void precache_playermodel(string m)
1517 {
1518         float globhandle, i, n;
1519         string f;
1520
1521         if(substring(m, -9,5) == "_lod1")
1522                 return;
1523         if(substring(m, -9,5) == "_lod2")
1524                 return;
1525         precache_model(m);
1526         if(sv_loddistance1)
1527         {
1528                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1529                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1530         }
1531
1532         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1533         if (globhandle < 0)
1534                 return;
1535         n = search_getsize(globhandle);
1536         for (i = 0; i < n; ++i)
1537         {
1538                 //print(search_getfilename(globhandle, i), "\n");
1539                 f = search_getfilename(globhandle, i);
1540                 PrecachePlayerSounds(f);
1541         }
1542         search_end(globhandle);
1543 }
1544 void precache_all_playermodels(string pattern)
1545 {
1546         float globhandle, i, n;
1547         string f;
1548
1549         globhandle = search_begin(pattern, TRUE, FALSE);
1550         if (globhandle < 0)
1551                 return;
1552         n = search_getsize(globhandle);
1553         for (i = 0; i < n; ++i)
1554         {
1555                 //print(search_getfilename(globhandle, i), "\n");
1556                 f = search_getfilename(globhandle, i);
1557                 precache_playermodel(f);
1558         }
1559         search_end(globhandle);
1560 }
1561
1562 void precache()
1563 {
1564     // gamemode related things
1565     precache_model ("models/misc/chatbubble.spr");
1566     precache_model ("models/misc/teambubble.spr");
1567     if (g_runematch)
1568     {
1569         precache_model ("models/runematch/curse.mdl");
1570         precache_model ("models/runematch/rune.mdl");
1571     }
1572
1573 #ifdef TTURRETS_ENABLED
1574     if (autocvar_g_turrets)
1575         turrets_precash();
1576 #endif
1577
1578     // Precache all player models if desired
1579     if (autocvar_sv_precacheplayermodels)
1580     {
1581         PrecachePlayerSounds("sound/player/default.sounds");
1582         precache_all_playermodels("models/player/*.zym");
1583         precache_all_playermodels("models/player/*.dpm");
1584         precache_all_playermodels("models/player/*.md3");
1585         precache_all_playermodels("models/player/*.psk");
1586         precache_all_playermodels("models/player/*.iqm");
1587     }
1588
1589     if (autocvar_sv_defaultcharacter)
1590     {
1591         string s;
1592         s = autocvar_sv_defaultplayermodel_red;
1593         if (s != "")
1594             precache_playermodel(s);
1595         s = autocvar_sv_defaultplayermodel_blue;
1596         if (s != "")
1597             precache_playermodel(s);
1598         s = autocvar_sv_defaultplayermodel_yellow;
1599         if (s != "")
1600             precache_playermodel(s);
1601         s = autocvar_sv_defaultplayermodel_pink;
1602         if (s != "")
1603             precache_playermodel(s);
1604         s = autocvar_sv_defaultplayermodel;
1605         if (s != "")
1606             precache_playermodel(s);
1607     }
1608
1609     if (g_footsteps)
1610     {
1611         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1612         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1613     }
1614
1615     // gore and miscellaneous sounds
1616     //precache_sound ("misc/h2ohit.wav");
1617     precache_model ("models/hook.md3");
1618     precache_sound ("misc/armorimpact.wav");
1619     precache_sound ("misc/bodyimpact1.wav");
1620     precache_sound ("misc/bodyimpact2.wav");
1621     precache_sound ("misc/gib.wav");
1622     precache_sound ("misc/gib_splat01.wav");
1623     precache_sound ("misc/gib_splat02.wav");
1624     precache_sound ("misc/gib_splat03.wav");
1625     precache_sound ("misc/gib_splat04.wav");
1626     precache_sound ("misc/hit.wav");
1627         precache_sound ("misc/typehit.wav");
1628     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1629     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1630     precache_sound ("misc/null.wav");
1631     precache_sound ("misc/spawn.wav");
1632     precache_sound ("misc/talk.wav");
1633     precache_sound ("misc/teleport.wav");
1634     precache_sound ("misc/poweroff.wav");
1635     precache_sound ("player/lava.wav");
1636     precache_sound ("player/slime.wav");
1637
1638     if (g_jetpack)
1639         precache_sound ("misc/jetpack_fly.wav");
1640
1641     precache_model ("models/sprites/0.spr32");
1642     precache_model ("models/sprites/1.spr32");
1643     precache_model ("models/sprites/2.spr32");
1644     precache_model ("models/sprites/3.spr32");
1645     precache_model ("models/sprites/4.spr32");
1646     precache_model ("models/sprites/5.spr32");
1647     precache_model ("models/sprites/6.spr32");
1648     precache_model ("models/sprites/7.spr32");
1649     precache_model ("models/sprites/8.spr32");
1650     precache_model ("models/sprites/9.spr32");
1651     precache_model ("models/sprites/10.spr32");
1652
1653     // common weapon precaches
1654     precache_sound ("weapons/weapon_switch.wav");
1655     precache_sound ("weapons/weaponpickup.wav");
1656     precache_sound ("weapons/unavailable.wav");
1657     precache_sound ("weapons/dryfire.wav");
1658     if (g_grappling_hook)
1659     {
1660         precache_sound ("weapons/hook_fire.wav"); // hook
1661         precache_sound ("weapons/hook_impact.wav"); // hook
1662     }
1663
1664     if(autocvar_sv_precacheweapons)
1665     {
1666         //precache weapon models/sounds
1667         local float wep;
1668         wep = WEP_FIRST;
1669         while (wep <= WEP_LAST)
1670         {
1671             weapon_action(wep, WR_PRECACHE);
1672             wep = wep + 1;
1673         }
1674     }
1675
1676     precache_model("models/elaser.mdl");
1677     precache_model("models/laser.mdl");
1678     precache_model("models/ebomb.mdl");
1679
1680 #if 0
1681     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1682
1683     if (!self.noise && self.music) // quake 3 uses the music field
1684         self.noise = self.music;
1685
1686     // plays music for the level if there is any
1687     if (self.noise)
1688     {
1689         precache_sound (self.noise);
1690         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1691     }
1692 #endif
1693 }
1694
1695 // sorry, but using \ in macros breaks line numbers
1696 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1697 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1698 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1699
1700 // WARNING: this kills the trace globals
1701 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1702 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1703
1704 #define INITPRIO_FIRST              0
1705 #define INITPRIO_GAMETYPE           0
1706 #define INITPRIO_GAMETYPE_FALLBACK  1
1707 #define INITPRIO_FINDTARGET        10
1708 #define INITPRIO_DROPTOFLOOR       20
1709 #define INITPRIO_SETLOCATION       90
1710 #define INITPRIO_LINKDOORS         91
1711 #define INITPRIO_LAST              99
1712
1713 .void(void) initialize_entity;
1714 .float initialize_entity_order;
1715 .entity initialize_entity_next;
1716 entity initialize_entity_first;
1717
1718 void make_safe_for_remove(entity e)
1719 {
1720     if (e.initialize_entity)
1721     {
1722         entity ent, prev;
1723         for (ent = initialize_entity_first; ent; )
1724         {
1725             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1726             {
1727                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1728                 // skip it in linked list
1729                 if (prev)
1730                 {
1731                     prev.initialize_entity_next = ent.initialize_entity_next;
1732                     ent = prev.initialize_entity_next;
1733                 }
1734                 else
1735                 {
1736                     initialize_entity_first = ent.initialize_entity_next;
1737                     ent = initialize_entity_first;
1738                 }
1739             }
1740             else
1741             {
1742                 prev = ent;
1743                 ent = ent.initialize_entity_next;
1744             }
1745         }
1746     }
1747 }
1748
1749 void objerror(string s)
1750 {
1751     make_safe_for_remove(self);
1752     objerror_builtin(s);
1753 }
1754
1755 void remove_unsafely(entity e)
1756 {
1757     remove_builtin(e);
1758 }
1759
1760 void remove_safely(entity e)
1761 {
1762     make_safe_for_remove(e);
1763     remove_builtin(e);
1764 }
1765
1766 void InitializeEntity(entity e, void(void) func, float order)
1767 {
1768     entity prev, cur;
1769
1770     if (!e || e.initialize_entity)
1771     {
1772         // make a proxy initializer entity
1773         entity e_old;
1774         e_old = e;
1775         e = spawn();
1776         e.classname = "initialize_entity";
1777         e.enemy = e_old;
1778     }
1779
1780     e.initialize_entity = func;
1781     e.initialize_entity_order = order;
1782
1783     cur = initialize_entity_first;
1784     for (;;)
1785     {
1786         if (!cur || cur.initialize_entity_order > order)
1787         {
1788             // insert between prev and cur
1789             if (prev)
1790                 prev.initialize_entity_next = e;
1791             else
1792                 initialize_entity_first = e;
1793             e.initialize_entity_next = cur;
1794             return;
1795         }
1796         prev = cur;
1797         cur = cur.initialize_entity_next;
1798     }
1799 }
1800 void InitializeEntitiesRun()
1801 {
1802     entity startoflist;
1803     startoflist = initialize_entity_first;
1804     initialize_entity_first = world;
1805     for (self = startoflist; self; )
1806     {
1807         entity e;
1808         var void(void) func;
1809         e = self.initialize_entity_next;
1810         func = self.initialize_entity;
1811         self.initialize_entity_order = 0;
1812         self.initialize_entity = func_null;
1813         self.initialize_entity_next = world;
1814         if (self.classname == "initialize_entity")
1815         {
1816             entity e_old;
1817             e_old = self.enemy;
1818             remove_builtin(self);
1819             self = e_old;
1820         }
1821         //dprint("Delayed initialization: ", self.classname, "\n");
1822         func();
1823         self = e;
1824     }
1825 }
1826
1827 .float uncustomizeentityforclient_set;
1828 .void(void) uncustomizeentityforclient;
1829 void(void) SUB_Nullpointer = #0;
1830 void UncustomizeEntitiesRun()
1831 {
1832     entity oldself;
1833     oldself = self;
1834     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1835         self.uncustomizeentityforclient();
1836     self = oldself;
1837 }
1838 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1839 {
1840     e.customizeentityforclient = customizer;
1841     e.uncustomizeentityforclient = uncustomizer;
1842     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1843 }
1844
1845 .float nottargeted;
1846 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1847
1848 void() SUB_Remove;
1849 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1850 {
1851     vector mi, ma;
1852
1853     if (e.classname == "")
1854         e.classname = "net_linked";
1855
1856     if (e.model == "" || self.modelindex == 0)
1857     {
1858         mi = e.mins;
1859         ma = e.maxs;
1860         setmodel(e, "null");
1861         setsize(e, mi, ma);
1862     }
1863
1864     e.SendEntity = sendfunc;
1865     e.SendFlags = 0xFFFFFF;
1866
1867     if (!docull)
1868         e.effects |= EF_NODEPTHTEST;
1869
1870     if (dt)
1871     {
1872         e.nextthink = time + dt;
1873         e.think = SUB_Remove;
1874     }
1875 }
1876
1877 void adaptor_think2touch()
1878 {
1879     entity o;
1880     o = other;
1881     other = world;
1882     self.touch();
1883     other = o;
1884 }
1885
1886 void adaptor_think2use()
1887 {
1888     entity o, a;
1889     o = other;
1890     a = activator;
1891     activator = world;
1892     other = world;
1893     self.use();
1894     other = o;
1895     activator = a;
1896 }
1897
1898 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1899 {
1900         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1901                 self.projectiledeathtype |= HITTYPE_SPLASH;
1902         adaptor_think2use();
1903 }
1904
1905 // deferred dropping
1906 void DropToFloor_Handler()
1907 {
1908     droptofloor_builtin();
1909     self.dropped_origin = self.origin;
1910 }
1911
1912 void droptofloor()
1913 {
1914     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1915 }
1916
1917
1918
1919 float trace_hits_box_a0, trace_hits_box_a1;
1920
1921 float trace_hits_box_1d(float end, float thmi, float thma)
1922 {
1923     if (end == 0)
1924     {
1925         // just check if x is in range
1926         if (0 < thmi)
1927             return FALSE;
1928         if (0 > thma)
1929             return FALSE;
1930     }
1931     else
1932     {
1933         // do the trace with respect to x
1934         // 0 -> end has to stay in thmi -> thma
1935         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1936         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1937         if (trace_hits_box_a0 > trace_hits_box_a1)
1938             return FALSE;
1939     }
1940     return TRUE;
1941 }
1942
1943 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1944 {
1945     end -= start;
1946     thmi -= start;
1947     thma -= start;
1948     // now it is a trace from 0 to end
1949
1950     trace_hits_box_a0 = 0;
1951     trace_hits_box_a1 = 1;
1952
1953     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1954         return FALSE;
1955     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1956         return FALSE;
1957     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1958         return FALSE;
1959
1960     return TRUE;
1961 }
1962
1963 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1964 {
1965     return trace_hits_box(start, end, thmi - ma, thma - mi);
1966 }
1967
1968 float SUB_NoImpactCheck()
1969 {
1970         // zero hitcontents = this is not the real impact, but either the
1971         // mirror-impact of something hitting the projectile instead of the
1972         // projectile hitting the something, or a touchareagrid one. Neither of
1973         // these stop the projectile from moving, so...
1974         if(trace_dphitcontents == 0)
1975         {
1976                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1977                 checkclient();
1978         }
1979     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1980         return 1;
1981     if (other == world && self.size != '0 0 0')
1982     {
1983         vector tic;
1984         tic = self.velocity * sys_frametime;
1985         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1986         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1987         if (trace_fraction >= 1)
1988         {
1989             dprint("Odd... did not hit...?\n");
1990         }
1991         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1992         {
1993             dprint("Detected and prevented the sky-grapple bug.\n");
1994             return 1;
1995         }
1996     }
1997
1998     return 0;
1999 }
2000
2001 #define SUB_OwnerCheck() (other && (other == self.owner))
2002
2003 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2004 {
2005         if(SUB_OwnerCheck())
2006                 return TRUE;
2007         if(SUB_NoImpactCheck())
2008         {
2009                 remove(self);
2010                 return TRUE;
2011         }
2012         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2013                 UpdateCSQCProjectileNextFrame(self);
2014         return FALSE;
2015 }
2016 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2017
2018 float MAX_IPBAN_URIS           = 16;
2019
2020 float URI_GET_DISCARD          = 0;
2021 float URI_GET_IPBAN            = 1;
2022 float URI_GET_IPBAN_END        = 16;
2023 float URI_GET_PLAYERSTATS_SENT = 17;
2024
2025 void URI_Get_Callback(float id, float status, string data)
2026 {
2027     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2028     dprint(data);
2029     dprint("\nEnd of data.\n");
2030
2031     if (id == URI_GET_DISCARD)
2032     {
2033         // discard
2034     }
2035     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2036     {
2037         // online ban list
2038         OnlineBanList_URI_Get_Callback(id, status, data);
2039     }
2040     else if (id == URI_GET_PLAYERSTATS_SENT)
2041     {
2042         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2043     }
2044     else
2045     {
2046         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2047     }
2048 }
2049
2050 void print_to(entity e, string s)
2051 {
2052     if (e)
2053         sprint(e, strcat(s, "\n"));
2054     else
2055         print(s, "\n");
2056 }
2057
2058 string uid2name(string myuid) {
2059         string s;
2060         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2061
2062         if(s == "")
2063                 s = "^1Unregistered Player";
2064         return s;
2065 }
2066
2067 float race_readTime(string map, float pos)
2068 {
2069         string rr;
2070         if(g_cts)
2071                 rr = CTS_RECORD;
2072         else
2073                 rr = RACE_RECORD;
2074
2075         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2076 }
2077
2078 string race_readUID(string map, float pos)
2079 {
2080         string rr;
2081         if(g_cts)
2082                 rr = CTS_RECORD;
2083         else
2084                 rr = RACE_RECORD;
2085
2086         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2087 }
2088
2089 float race_readPos(string map, float t) {
2090         float i;
2091         for (i = 1; i <= RANKINGS_CNT; ++i)
2092                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2093                         return i;
2094
2095         return 0; // pos is zero if unranked
2096 }
2097
2098 void race_writeTime(string map, float t, string myuid)
2099 {
2100         string rr;
2101         if(g_cts)
2102                 rr = CTS_RECORD;
2103         else
2104                 rr = RACE_RECORD;
2105
2106         float newpos;
2107         newpos = race_readPos(map, t);
2108
2109         float i, prevpos;
2110         for(i = 1; i <= RANKINGS_CNT; ++i)
2111         {
2112                 if(race_readUID(map, i) == myuid)
2113                         prevpos = i;
2114         }
2115         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2116                 for (i = prevpos; i > newpos; --i) {
2117                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2118                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2119                 }
2120         } else { // player has no ranked record yet
2121                 for (i = RANKINGS_CNT; i > newpos; --i) {
2122                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2123                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2124                 }
2125         }
2126
2127         // store new time itself
2128         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2129         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2130 }
2131
2132 string race_readName(string map, float pos)
2133 {
2134         string rr;
2135         if(g_cts)
2136                 rr = CTS_RECORD;
2137         else
2138                 rr = RACE_RECORD;
2139
2140         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2141 }
2142
2143 string race_placeName(float pos) {
2144         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2145         {
2146                 if(mod(pos, 10) == 1)
2147                         return strcat(ftos(pos), "st");
2148                 else if(mod(pos, 10) == 2)
2149                         return strcat(ftos(pos), "nd");
2150                 else if(mod(pos, 10) == 3)
2151                         return strcat(ftos(pos), "rd");
2152                 else
2153                         return strcat(ftos(pos), "th");
2154         }
2155         else
2156                 return strcat(ftos(pos), "th");
2157 }
2158 string getrecords(float page) // 50 records per page
2159 {
2160     float rec;
2161     string h;
2162     float r;
2163     float i;
2164     string s;
2165
2166     rec = 0;
2167
2168     s = "";
2169
2170     if (g_ctf)
2171     {
2172         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2173         {
2174             if (MapInfo_Get_ByID(i))
2175             {
2176                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2177                 if (r == 0)
2178                     continue;
2179                 // TODO: uid2name
2180                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2181                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2182                 ++rec;
2183             }
2184         }
2185     }
2186
2187     if (g_race)
2188     {
2189         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2190         {
2191             if (MapInfo_Get_ByID(i))
2192             {
2193                 r = race_readTime(MapInfo_Map_bspname, 1);
2194                 if (r == 0)
2195                     continue;
2196                 h = race_readName(MapInfo_Map_bspname, 1);
2197                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2198                 ++rec;
2199             }
2200         }
2201     }
2202
2203     if (g_cts)
2204     {
2205         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2206         {
2207             if (MapInfo_Get_ByID(i))
2208             {
2209                 r = race_readTime(MapInfo_Map_bspname, 1);
2210                 if (r == 0)
2211                     continue;
2212                 h = race_readName(MapInfo_Map_bspname, 1);
2213                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2214                 ++rec;
2215             }
2216         }
2217     }
2218
2219     MapInfo_ClearTemps();
2220
2221     if (s == "" && page == 0)
2222         return "No records are available on this server.\n";
2223     else
2224         return s;
2225 }
2226
2227 string getrankings()
2228 {
2229     string n;
2230     float t;
2231     float i;
2232     string s;
2233     string p;
2234     string map;
2235
2236     s = "";
2237
2238     map = GetMapname();
2239
2240     for (i = 1; i <= RANKINGS_CNT; ++i)
2241     {
2242         t = race_readTime(map, i);
2243         if (t == 0)
2244             continue;
2245         n = race_readName(map, i);
2246         p = race_placeName(i);
2247         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2248     }
2249
2250     MapInfo_ClearTemps();
2251
2252     if (s == "")
2253         return strcat("No records are available for the map: ", map, "\n");
2254     else
2255         return strcat("Records for ", map, ":\n", s);
2256 }
2257
2258 #define LADDER_FIRSTPOINT 100
2259 #define LADDER_CNT 10
2260         // position X still gives LADDER_FIRSTPOINT/X points
2261 #define LADDER_SIZE 30
2262         // ladder shows the top X players
2263 string top_uids[LADDER_SIZE];
2264 float top_scores[LADDER_SIZE];
2265 string getladder()
2266 {
2267     float i, j, k, uidcnt;
2268     string s, temp_s;
2269
2270     s = "";
2271     temp_s = "";
2272
2273     string rr;
2274     if(g_cts)
2275         rr = CTS_RECORD;
2276     else
2277         rr = RACE_RECORD;
2278
2279     string myuid;
2280
2281     for (k = 0; k < MapInfo_count; ++k)
2282     {
2283         if (MapInfo_Get_ByID(k))
2284         {
2285                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2286                         if(i == 0) // speed award
2287                         {
2288                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2289                                         continue;
2290
2291                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2292                         }
2293                         else // normal record, if it exists (else break)
2294                         {
2295                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2296                                         continue;
2297
2298                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2299                         }
2300
2301                         // string s contains:
2302                         // arg 0 = # of speed recs
2303                         // arg 1 = # of 1st place recs
2304                         // arg 2 = # of 2nd place recs
2305                         // ... etc
2306                         // LADDER_CNT+1 = total points
2307
2308                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2309                         if (temp_s == "")
2310                         {
2311                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2312                             ++uidcnt;
2313                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2314                             {
2315                                 if(j != LADDER_CNT + 1)
2316                                     temp_s = strcat(temp_s, "0 ");
2317                                 else
2318                                     temp_s = strcat(temp_s, "0");
2319                             }
2320                         }
2321
2322                         tokenize_console(temp_s);
2323                         s = "";
2324
2325                         if(i == 0) // speed award
2326                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2327                             {
2328                                 if(j == 0) // speed award
2329                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2330                                 else
2331                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2332                             }
2333                         else // record
2334                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2335                             {
2336                                 if(j == 0)
2337                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2338                                 else if(j == i) // wanted rec!
2339                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2340                                 else
2341                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2342                             }
2343
2344                         // total points are (by default) calculated like this:
2345                         // speedrec = floor(100 / 10) = 10 points
2346                         // 1st place = floor(100 / 1) = 100 points
2347                         // 2nd place = floor(100 / 2) = 50 points
2348                         // 3rd place = floor(100 / 3) = 33 points
2349                         // 4th place = floor(100 / 4) = 25 points
2350                         // 5th place = floor(100 / 5) = 20 points
2351                         // ... etc
2352
2353                         if(i == 0)
2354                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2355                         else
2356                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2357
2358                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2359                 }
2360         }
2361     }
2362
2363     float thiscnt;
2364     string thisuid;
2365     for (i = 0; i <= uidcnt; ++i) // for each known uid
2366     {
2367         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2368         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2369         tokenize_console(temp_s);
2370         thiscnt = stof(argv(LADDER_CNT+1));
2371
2372         if(thiscnt > top_scores[LADDER_SIZE-1])
2373         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2374         {
2375             if(thiscnt > top_scores[j])
2376             {
2377                 for (k = LADDER_SIZE-1; k >= j; --k)
2378                 {
2379                     top_uids[k] = top_uids[k-1];
2380                     top_scores[k] = top_scores[k-1];
2381                 }
2382                 top_uids[j] = thisuid;
2383                 top_scores[j] = thiscnt;
2384                 break;
2385             }
2386         }
2387     }
2388
2389     s = "^3-----------------------\n\n";
2390
2391     s = strcat(s, "Pos ^3|");
2392     s = strcat(s, " ^7Total  ^3|");
2393     for (i = 1; i <= LADDER_CNT; ++i)
2394     {
2395         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2396     }
2397     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2398
2399     s = strcat(s, "\n^3----+--------");
2400     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2401     {
2402         s = strcat(s, "+-----");
2403     }
2404 #if LADDER_CNT > 9
2405     for (i = 1; i <= LADDER_CNT - 9; ++i)
2406     {
2407         s = strcat(s, "+------");
2408     }
2409 #endif
2410
2411     s = strcat(s, "+--------------+--------------------\n");
2412
2413     for (i = 0; i < LADDER_SIZE; ++i)
2414     {
2415         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2416         tokenize_console(temp_s);
2417         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2418             continue;
2419         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2420         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2421         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2422         {
2423             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2424         }
2425 #if LADDER_CNT > 9
2426         for (j = 10; j <= LADDER_CNT; ++j)
2427         {
2428             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2429         }
2430 #endif
2431
2432         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2433         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2434     }
2435
2436     MapInfo_ClearTemps();
2437
2438     if (s == "")
2439         return "No ladder on this server!\n";
2440     else
2441         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2442 }
2443
2444
2445 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2446 {
2447     float m, i;
2448     vector start, org, delta, end, enddown, mstart;
2449
2450     m = e.dphitcontentsmask;
2451     e.dphitcontentsmask = goodcontents | badcontents;
2452
2453     org = world.mins;
2454     delta = world.maxs - world.mins;
2455
2456     for (i = 0; i < attempts; ++i)
2457     {
2458         start_x = org_x + random() * delta_x;
2459         start_y = org_y + random() * delta_y;
2460         start_z = org_z + random() * delta_z;
2461
2462         // rule 1: start inside world bounds, and outside
2463         // solid, and don't start from somewhere where you can
2464         // fall down to evil
2465         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2466         if (trace_fraction >= 1)
2467             continue;
2468         if (trace_startsolid)
2469             continue;
2470         if (trace_dphitcontents & badcontents)
2471             continue;
2472         if (trace_dphitq3surfaceflags & badsurfaceflags)
2473             continue;
2474
2475         // rule 2: if we are too high, lower the point
2476         if (trace_fraction * delta_z > maxaboveground)
2477             start = trace_endpos + '0 0 1' * maxaboveground;
2478         enddown = trace_endpos;
2479
2480         // rule 3: make sure we aren't outside the map. This only works
2481         // for somewhat well formed maps. A good rule of thumb is that
2482         // the map should have a convex outside hull.
2483         // these can be traceLINES as we already verified the starting box
2484         mstart = start + 0.5 * (e.mins + e.maxs);
2485         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2486         if (trace_fraction >= 1)
2487             continue;
2488         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2489         if (trace_fraction >= 1)
2490             continue;
2491         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2492         if (trace_fraction >= 1)
2493             continue;
2494         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2495         if (trace_fraction >= 1)
2496             continue;
2497         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2498         if (trace_fraction >= 1)
2499             continue;
2500
2501         // find a random vector to "look at"
2502         end_x = org_x + random() * delta_x;
2503         end_y = org_y + random() * delta_y;
2504         end_z = org_z + random() * delta_z;
2505         end = start + normalize(end - start) * vlen(delta);
2506
2507         // rule 4: start TO end must not be too short
2508         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2509         if (trace_startsolid)
2510             continue;
2511         if (trace_fraction < minviewdistance / vlen(delta))
2512             continue;
2513
2514         // rule 5: don't want to look at sky
2515         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2516             continue;
2517
2518         // rule 6: we must not end up in trigger_hurt
2519         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2520         {
2521             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2522             continue;
2523         }
2524
2525         break;
2526     }
2527
2528     e.dphitcontentsmask = m;
2529
2530     if (i < attempts)
2531     {
2532         setorigin(e, start);
2533         e.angles = vectoangles(end - start);
2534         dprint("Needed ", ftos(i + 1), " attempts\n");
2535         return TRUE;
2536     }
2537     else
2538         return FALSE;
2539 }
2540
2541 float zcurveparticles_effectno;
2542 vector zcurveparticles_start;
2543 float zcurveparticles_spd;
2544
2545 void endzcurveparticles()
2546 {
2547         if(zcurveparticles_effectno)
2548         {
2549                 // terminator
2550                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2551         }
2552         zcurveparticles_effectno = 0;
2553 }
2554
2555 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2556 {
2557         spd = bound(0, floor(spd / 16), 32767);
2558         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2559         {
2560                 endzcurveparticles();
2561                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2562                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2563                 WriteShort(MSG_BROADCAST, effectno);
2564                 WriteCoord(MSG_BROADCAST, start_x);
2565                 WriteCoord(MSG_BROADCAST, start_y);
2566                 WriteCoord(MSG_BROADCAST, start_z);
2567                 zcurveparticles_effectno = effectno;
2568                 zcurveparticles_start = start;
2569         }
2570         else
2571                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2572         WriteCoord(MSG_BROADCAST, end_x);
2573         WriteCoord(MSG_BROADCAST, end_y);
2574         WriteCoord(MSG_BROADCAST, end_z);
2575         WriteCoord(MSG_BROADCAST, end_dz);
2576         zcurveparticles_spd = spd;
2577 }
2578
2579 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2580 {
2581         float end_dz;
2582         vector vecxy, velxy;
2583
2584         vecxy = end - start;
2585         vecxy_z = 0;
2586         velxy = vel;
2587         velxy_z = 0;
2588
2589         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2590         {
2591                 endzcurveparticles();
2592                 trailparticles(world, effectno, start, end);
2593                 return;
2594         }
2595
2596         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2597         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2598 }
2599
2600 string GetGametype(); // g_world.qc
2601 void write_recordmarker(entity pl, float tstart, float dt)
2602 {
2603     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2604
2605     // also write a marker into demo files for demotc-race-record-extractor to find
2606     stuffcmd(pl,
2607              strcat(
2608                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2609                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2610 }
2611
2612 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2613 {
2614         switch(algn)
2615         {
2616                 case 1: // right
2617                         break;
2618
2619                 case 2: // left
2620                         vecs_y = -vecs_y;
2621                         break;
2622
2623                 default:
2624                 case 3:
2625                         if(allowcenter) // 2: allow center handedness
2626                         {
2627                                 // center
2628                                 vecs_y = 0;
2629                                 vecs_z -= 2;
2630                         }
2631                         else
2632                         {
2633                                 // right
2634                         }
2635                         break;
2636
2637                 case 4:
2638                         if(allowcenter) // 2: allow center handedness
2639                         {
2640                                 // center
2641                                 vecs_y = 0;
2642                                 vecs_z -= 2;
2643                         }
2644                         else
2645                         {
2646                                 // left
2647                                 vecs_y = -vecs_y;
2648                         }
2649                         break;
2650         }
2651         return vecs;
2652 }
2653
2654 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2655 {
2656         string s;
2657         vector v;
2658
2659         if (autocvar_g_shootfromeye)
2660         {
2661                 if (visual)
2662                 {
2663                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2664                 }
2665                 else
2666                 {
2667                         vecs_y = 0;
2668                         vecs_z = 0;
2669                 }
2670         }
2671         else if (autocvar_g_shootfromcenter)
2672         {
2673                 if (visual)
2674                 {
2675                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2676                 }
2677                 else
2678                 {
2679                         vecs_y = 0;
2680                         vecs_z -= 2;
2681                 }
2682         }
2683         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2684         {
2685                 v = stov(s);
2686                 if (y_is_right)
2687                         v_y = -v_y;
2688                 if (v_x != 0)
2689                         vecs_x = v_x;
2690                 vecs_y = v_y;
2691                 vecs_z = v_z;
2692         }
2693         else if (autocvar_g_shootfromclient)
2694         {
2695                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2696         }
2697         return vecs;
2698 }
2699
2700 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2701 {
2702         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2703 }
2704
2705
2706 void attach_sameorigin(entity e, entity to, string tag)
2707 {
2708     vector org, t_forward, t_left, t_up, e_forward, e_up;
2709     vector org0, ang0;
2710     float tagscale;
2711
2712     ang0 = e.angles;
2713     org0 = e.origin;
2714
2715     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2716     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2717     t_forward = v_forward * tagscale;
2718     t_left = v_right * -tagscale;
2719     t_up = v_up * tagscale;
2720
2721     e.origin_x = org * t_forward;
2722     e.origin_y = org * t_left;
2723     e.origin_z = org * t_up;
2724
2725     // current forward and up directions
2726     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2727                 e.angles = AnglesTransform_FromVAngles(e.angles);
2728         else
2729                 e.angles = AnglesTransform_FromAngles(e.angles);
2730     fixedmakevectors(e.angles);
2731
2732     // untransform forward, up!
2733     e_forward_x = v_forward * t_forward;
2734     e_forward_y = v_forward * t_left;
2735     e_forward_z = v_forward * t_up;
2736     e_up_x = v_up * t_forward;
2737     e_up_y = v_up * t_left;
2738     e_up_z = v_up * t_up;
2739
2740     e.angles = fixedvectoangles2(e_forward, e_up);
2741     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2742                 e.angles = AnglesTransform_ToVAngles(e.angles);
2743         else
2744                 e.angles = AnglesTransform_ToAngles(e.angles);
2745
2746     setattachment(e, to, tag);
2747     setorigin(e, e.origin);
2748 }
2749
2750 void detach_sameorigin(entity e)
2751 {
2752     vector org;
2753     org = gettaginfo(e, 0);
2754     e.angles = fixedvectoangles2(v_forward, v_up);
2755     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2756                 e.angles = AnglesTransform_ToVAngles(e.angles);
2757         else
2758                 e.angles = AnglesTransform_ToAngles(e.angles);
2759     setorigin(e, org);
2760     setattachment(e, world, "");
2761     setorigin(e, e.origin);
2762 }
2763
2764 void follow_sameorigin(entity e, entity to)
2765 {
2766     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2767     e.aiment = to; // make the hole follow bmodel
2768     e.punchangle = to.angles; // the original angles of bmodel
2769     e.view_ofs = e.origin - to.origin; // relative origin
2770     e.v_angle = e.angles - to.angles; // relative angles
2771 }
2772
2773 void unfollow_sameorigin(entity e)
2774 {
2775     e.movetype = MOVETYPE_NONE;
2776 }
2777
2778 entity gettaginfo_relative_ent;
2779 vector gettaginfo_relative(entity e, float tag)
2780 {
2781     if (!gettaginfo_relative_ent)
2782     {
2783         gettaginfo_relative_ent = spawn();
2784         gettaginfo_relative_ent.effects = EF_NODRAW;
2785     }
2786     gettaginfo_relative_ent.model = e.model;
2787     gettaginfo_relative_ent.modelindex = e.modelindex;
2788     gettaginfo_relative_ent.frame = e.frame;
2789     return gettaginfo(gettaginfo_relative_ent, tag);
2790 }
2791
2792 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2793 {
2794     float p;
2795     p = pow(2, chan);
2796     if (pl.soundentity.cnt & p)
2797         return;
2798     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2799     pl.soundentity.cnt |= p;
2800 }
2801
2802 void SoundEntity_StopSound(entity pl, float chan)
2803 {
2804     float p;
2805     p = pow(2, chan);
2806     if (pl.soundentity.cnt & p)
2807     {
2808         stopsoundto(MSG_ALL, pl.soundentity, chan);
2809         pl.soundentity.cnt &~= p;
2810     }
2811 }
2812
2813 void SoundEntity_Attach(entity pl)
2814 {
2815     pl.soundentity = spawn();
2816     pl.soundentity.classname = "soundentity";
2817     pl.soundentity.owner = pl;
2818     setattachment(pl.soundentity, pl, "");
2819     setmodel(pl.soundentity, "null");
2820 }
2821
2822 void SoundEntity_Detach(entity pl)
2823 {
2824     float i;
2825     for (i = 0; i <= 7; ++i)
2826         SoundEntity_StopSound(pl, i);
2827 }
2828
2829
2830 float ParseCommandPlayerSlotTarget_firsttoken;
2831 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2832 {
2833     string s;
2834     entity e, head;
2835     float n;
2836
2837     s = string_null;
2838
2839     ParseCommandPlayerSlotTarget_firsttoken = -1;
2840
2841     if (tokens > idx)
2842     {
2843         if (substring(argv(idx), 0, 1) == "#")
2844         {
2845             s = substring(argv(idx), 1, -1);
2846             ++idx;
2847             if (s == "")
2848                 if (tokens > idx)
2849                 {
2850                     s = argv(idx);
2851                     ++idx;
2852                 }
2853                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2854             if (s == ftos(stof(s)))
2855             {
2856                 e = edict_num(stof(s));
2857                 if (e.flags & FL_CLIENT)
2858                     return e;
2859             }
2860         }
2861         else
2862         {
2863             // it must be a nick name
2864             s = argv(idx);
2865             ++idx;
2866                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2867
2868             n = 0;
2869             FOR_EACH_CLIENT(head)
2870             if (head.netname == s)
2871             {
2872                 e = head;
2873                 ++n;
2874             }
2875             if (n == 1)
2876                 return e;
2877
2878             s = strdecolorize(s);
2879             n = 0;
2880             FOR_EACH_CLIENT(head)
2881             if (strdecolorize(head.netname) == s)
2882             {
2883                 e = head;
2884                 ++n;
2885             }
2886             if (n == 1)
2887                 return e;
2888         }
2889     }
2890
2891     return world;
2892 }
2893
2894 .float scale2;
2895
2896 float modeleffect_SendEntity(entity to, float sf)
2897 {
2898         float f;
2899         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2900
2901         f = 0;
2902         if(self.velocity != '0 0 0')
2903                 f |= 1;
2904         if(self.angles != '0 0 0')
2905                 f |= 2;
2906         if(self.avelocity != '0 0 0')
2907                 f |= 4;
2908
2909         WriteByte(MSG_ENTITY, f);
2910         WriteShort(MSG_ENTITY, self.modelindex);
2911         WriteByte(MSG_ENTITY, self.skin);
2912         WriteByte(MSG_ENTITY, self.frame);
2913         WriteCoord(MSG_ENTITY, self.origin_x);
2914         WriteCoord(MSG_ENTITY, self.origin_y);
2915         WriteCoord(MSG_ENTITY, self.origin_z);
2916         if(f & 1)
2917         {
2918                 WriteCoord(MSG_ENTITY, self.velocity_x);
2919                 WriteCoord(MSG_ENTITY, self.velocity_y);
2920                 WriteCoord(MSG_ENTITY, self.velocity_z);
2921         }
2922         if(f & 2)
2923         {
2924                 WriteCoord(MSG_ENTITY, self.angles_x);
2925                 WriteCoord(MSG_ENTITY, self.angles_y);
2926                 WriteCoord(MSG_ENTITY, self.angles_z);
2927         }
2928         if(f & 4)
2929         {
2930                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2931                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2932                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2933         }
2934         WriteShort(MSG_ENTITY, self.scale * 256.0);
2935         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2936         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2937         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2938         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2939
2940         return TRUE;
2941 }
2942
2943 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2944 {
2945         entity e;
2946         float sz;
2947         e = spawn();
2948         e.classname = "modeleffect";
2949         setmodel(e, m);
2950         e.frame = f;
2951         setorigin(e, o);
2952         e.velocity = v;
2953         e.angles = ang;
2954         e.avelocity = angv;
2955         e.alpha = a;
2956         e.teleport_time = t1;
2957         e.fade_time = t2;
2958         e.skin = s;
2959         if(s0 >= 0)
2960                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2961         else
2962                 e.scale = -s0;
2963         if(s2 >= 0)
2964                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2965         else
2966                 e.scale2 = -s2;
2967         sz = max(e.scale, e.scale2);
2968         setsize(e, e.mins * sz, e.maxs * sz);
2969         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2970 }
2971
2972 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2973 {
2974         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2975 }
2976
2977 float randombit(float bits)
2978 {
2979         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2980                 return bits;
2981
2982         float n, f, b, r;
2983
2984         r = random();
2985         b = 0;
2986         n = 0;
2987
2988         for(f = 1; f <= bits; f *= 2)
2989         {
2990                 if(bits & f)
2991                 {
2992                         ++n;
2993                         r *= n;
2994                         if(r <= 1)
2995                                 b = f;
2996                         else
2997                                 r = (r - 1) / (n - 1);
2998                 }
2999         }
3000
3001         return b;
3002 }
3003
3004 float randombits(float bits, float k, float error_return)
3005 {
3006         float r;
3007         r = 0;
3008         while(k > 0 && bits != r)
3009         {
3010                 r += randombit(bits - r);
3011                 --k;
3012         }
3013         if(error_return)
3014                 if(k > 0)
3015                         return -1; // all
3016         return r;
3017 }
3018
3019 void randombit_test(float bits, float iter)
3020 {
3021         while(iter > 0)
3022         {
3023                 print(ftos(randombit(bits)), "\n");
3024                 --iter;
3025         }
3026 }
3027
3028 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3029 {
3030         if(halflifedist > 0)
3031                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3032         else if(halflifedist < 0)
3033                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3034         else
3035                 return 1;
3036 }
3037
3038
3039
3040
3041 #ifdef RELEASE
3042 #define cvar_string_normal cvar_string_builtin
3043 #define cvar_normal cvar_builtin
3044 #else
3045 string cvar_string_normal(string n)
3046 {
3047         if not(cvar_type(n) & 1)
3048                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3049         return cvar_string_builtin(n);
3050 }
3051
3052 float cvar_normal(string n)
3053 {
3054         return stof(cvar_string_normal(n));
3055 }
3056 #endif
3057 #define cvar_set_normal cvar_set_builtin
3058
3059 void defer_think()
3060 {
3061     entity oself;
3062
3063     oself           = self;
3064     self            = self.owner;
3065     oself.think     = SUB_Remove;
3066     oself.nextthink = time;
3067
3068     oself.use();
3069 }
3070
3071 /*
3072     Execute func() after time + fdelay.
3073     self when func is executed = self when defer is called
3074 */
3075 void defer(float fdelay, void() func)
3076 {
3077     entity e;
3078
3079     e           = spawn();
3080     e.owner     = self;
3081     e.use       = func;
3082     e.think     = defer_think;
3083     e.nextthink = time + fdelay;
3084 }