qcsrc/server/mode_onslaught.qc

   1 void onslaught_generator_updatesprite(entity e);
   2 void onslaught_controlpoint_updatesprite(entity e);
   3 void onslaught_link_checkupdate();
   4
   5 .entity sprite;
   6 .string target2;
   7 .float iscaptured;
   8 .float islinked;
   9 .float isgenneighbor_red;
  10 .float isgenneighbor_blue;
  11 .float iscpneighbor_red;
  12 .float iscpneighbor_blue;
  13 .float isshielded;
  14 .float lasthealth;
  15 .float lastteam;
  16 .float lastshielded;
  17 .float lastcaptured;
  18
  19 .string model1, model2, model3;
  20
  21 void ons_gib_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector vforce)
  22 {
  23         self.velocity = self.velocity + vforce;
  24 }
  25
  26 .float giblifetime;
  27 void ons_throwgib_think()
  28 {
  29         float d;
  30
  31         self.nextthink = time + 0.05;
  32
  33         d = self.giblifetime - time;
  34
  35         if(d<0)
  36         {
  37                 self.think = SUB_Remove;
  38                 return;
  39         }
  40         if(d<1)
  41                 self.alpha = d;
  42
  43         if(d>2)
  44         if(random()<0.6)
  45                 pointparticles(particleeffectnum("onslaught_generator_gib_flame"), self.origin, '0 0 0', 1);
  46 };
  47
  48 void ons_throwgib(vector v_from, vector v_to, string smodel, float f_lifetime, float b_burn)
  49 {
  50         local entity gib;
  51
  52         gib = spawn();
  53
  54         setmodel(gib, smodel);
  55         setorigin(gib, v_from);
  56         gib.solid = SOLID_BBOX;
  57         gib.movetype = MOVETYPE_BOUNCE;
  58         gib.takedamage = DAMAGE_YES;
  59         gib.event_damage = ons_gib_damage;
  60         gib.health = -1;
  61         gib.effects = EF_LOWPRECISION;
  62         gib.flags = FL_NOTARGET;
  63         gib.velocity = v_to;
  64         gib.giblifetime = time + f_lifetime;
  65
  66         if (b_burn)
  67         {
  68                 gib.think = ons_throwgib_think;
  69                 gib.nextthink = time + 0.05;
  70         }
  71         else
  72                 SUB_SetFade(gib, gib.giblifetime, 2);
  73 };
  74
  75 void onslaught_updatelinks()
  76 {
  77         local entity l, links;
  78         local float stop, t1, t2, t3, t4;
  79         // first check if the game has ended
  80         dprint("--- updatelinks ---\n");
  81         links = findchain(classname, "onslaught_link");
  82         // mark generators as being shielded and networked
  83         l = findchain(classname, "onslaught_generator");
  84         while (l)
  85         {
  86                 if (l.iscaptured)
  87                         dprint(etos(l), " (generator) belongs to team ", ftos(l.team), "\n");
  88                 else
  89                         dprint(etos(l), " (generator) is destroyed\n");
  90                 l.islinked = l.iscaptured;
  91                 l.isshielded = l.iscaptured;
  92                 l = l.chain;
  93         }
  94         // mark points as shielded and not networked
  95         l = findchain(classname, "onslaught_controlpoint");
  96         while (l)
  97         {
  98                 l.islinked = FALSE;
  99                 l.isshielded = TRUE;
 100                 l.isgenneighbor_red = FALSE;
 101                 l.isgenneighbor_blue = FALSE;
 102                 l.iscpneighbor_red = FALSE;
 103                 l.iscpneighbor_blue = FALSE;
 104                 dprint(etos(l), " (point) belongs to team ", ftos(l.team), "\n");
 105                 l = l.chain;
 106         }
 107         // flow power outward from the generators through the network
 108         l = links;
 109         while (l)
 110         {
 111                 dprint(etos(l), " (link) connects ", etos(l.goalentity), " with ", etos(l.enemy), "\n");
 112                 l = l.chain;
 113         }
 114         stop = FALSE;
 115         while (!stop)
 116         {
 117                 stop = TRUE;
 118                 l = links;
 119                 while (l)
 120                 {
 121                         // if both points are captured by the same team, and only one of
 122                         // them is powered, mark the other one as powered as well
 123                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 124                                 if (l.enemy.islinked != l.goalentity.islinked)
 125                                         if (l.enemy.team == l.goalentity.team)
 126                                         {
 127                                                 if (!l.goalentity.islinked)
 128                                                 {
 129                                                         stop = FALSE;
 130                                                         l.goalentity.islinked = TRUE;
 131                                                         dprint(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)\n");
 132                                                 }
 133                                                 else if (!l.enemy.islinked)
 134                                                 {
 135                                                         stop = FALSE;
 136                                                         l.enemy.islinked = TRUE;
 137                                                         dprint(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)\n");
 138                                                 }
 139                                         }
 140                         l = l.chain;
 141                 }
 142         }
 143         // now that we know which points are powered we can mark their neighbors
 144         // as unshielded if team differs
 145         l = links;
 146         while (l)
 147         {
 148                 if (l.goalentity.islinked)
 149                 {
 150                         if (l.goalentity.team != l.enemy.team)
 151                         {
 152                                 dprint(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)\n");
 153                                 l.enemy.isshielded = FALSE;
 154                         }
 155                         if(l.goalentity.classname == "onslaught_generator")
 156                         {
 157                                 if(l.goalentity.team == COLOR_TEAM1)
 158                                         l.enemy.isgenneighbor_red = TRUE;
 159                                 else if(l.goalentity.team == COLOR_TEAM2)
 160                                         l.enemy.isgenneighbor_blue = TRUE;
 161                         }
 162                         else
 163                         {
 164                                 if(l.goalentity.team == COLOR_TEAM1)
 165                                         l.enemy.iscpneighbor_red = TRUE;
 166                                 else if(l.goalentity.team == COLOR_TEAM2)
 167                                         l.enemy.iscpneighbor_blue = TRUE;
 168                         }
 169                 }
 170                 if (l.enemy.islinked)
 171                 {
 172                         if (l.goalentity.team != l.enemy.team)
 173                         {
 174                                 dprint(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)\n");
 175                                 l.goalentity.isshielded = FALSE;
 176                         }
 177                         if(l.enemy.classname == "onslaught_generator")
 178                         {
 179                                 if(l.enemy.team == COLOR_TEAM1)
 180                                         l.goalentity.isgenneighbor_red = TRUE;
 181                                 else if(l.enemy.team == COLOR_TEAM2)
 182                                         l.goalentity.isgenneighbor_blue = TRUE;
 183                         }
 184                         else
 185                         {
 186                                 if(l.enemy.team == COLOR_TEAM1)
 187                                         l.goalentity.iscpneighbor_red = TRUE;
 188                                 else if(l.enemy.team == COLOR_TEAM2)
 189                                         l.goalentity.iscpneighbor_blue = TRUE;
 190                         }
 191                 }
 192                 l = l.chain;
 193         }
 194         // now update the takedamage and alpha variables on generator shields
 195         l = findchain(classname, "onslaught_generator");
 196         while (l)
 197         {
 198                 if (l.isshielded)
 199                 {
 200                         dprint(etos(l), " (generator) is shielded\n");
 201                         l.enemy.alpha = 1;
 202                         l.takedamage = DAMAGE_NO;
 203                         l.bot_attack = FALSE;
 204                 }
 205                 else
 206                 {
 207                         dprint(etos(l), " (generator) is not shielded\n");
 208                         l.enemy.alpha = -1;
 209                         l.takedamage = DAMAGE_AIM;
 210                         l.bot_attack = TRUE;
 211                 }
 212                 l = l.chain;
 213         }
 214         // now update the takedamage and alpha variables on control point icons
 215         l = findchain(classname, "onslaught_controlpoint");
 216         while (l)
 217         {
 218                 if (l.isshielded)
 219                 {
 220                         dprint(etos(l), " (point) is shielded\n");
 221                         l.enemy.alpha = 1;
 222                         if (l.goalentity)
 223                         {
 224                                 l.goalentity.takedamage = DAMAGE_NO;
 225                                 l.goalentity.bot_attack = FALSE;
 226                         }
 227                 }
 228                 else
 229                 {
 230                         dprint(etos(l), " (point) is not shielded\n");
 231                         l.enemy.alpha = -1;
 232                         if (l.goalentity)
 233                         {
 234                                 l.goalentity.takedamage = DAMAGE_AIM;
 235                                 l.goalentity.bot_attack = TRUE;
 236                         }
 237                 }
 238                 onslaught_controlpoint_updatesprite(l);
 239                 l = l.chain;
 240         }
 241         // count generators owned by each team
 242         t1 = t2 = t3 = t4 = 0;
 243         l = findchain(classname, "onslaught_generator");
 244         while (l)
 245         {
 246                 if (l.iscaptured)
 247                 {
 248                         if (l.team == COLOR_TEAM1) t1 = 1;
 249                         if (l.team == COLOR_TEAM2) t2 = 1;
 250                         if (l.team == COLOR_TEAM3) t3 = 1;
 251                         if (l.team == COLOR_TEAM4) t4 = 1;
 252                 }
 253                 onslaught_generator_updatesprite(l);
 254                 l = l.chain;
 255         }
 256         // see if multiple teams remain (if not, it's game over)
 257         if (t1 + t2 + t3 + t4 < 2)
 258                 dprint("--- game over ---\n");
 259         else
 260                 dprint("--- done updating links ---\n");
 261 };
 262
 263 float onslaught_controlpoint_can_be_linked(entity cp, float t)
 264 {
 265         if(t == COLOR_TEAM1)
 266         {
 267                 if(cp.isgenneighbor_red)
 268                         return 2;
 269                 if(cp.iscpneighbor_red)
 270                         return 1;
 271         }
 272         else if(t == COLOR_TEAM2)
 273         {
 274                 if(cp.isgenneighbor_blue)
 275                         return 2;
 276                 if(cp.iscpneighbor_blue)
 277                         return 1;
 278         }
 279         return 0;
 280         /*
 281            entity e;
 282         // check to see if this player has a legitimate claim to capture this
 283         // control point - more specifically that there is a captured path of
 284         // points leading back to the team generator
 285         e = findchain(classname, "onslaught_link");
 286         while (e)
 287         {
 288         if (e.goalentity == cp)
 289         {
 290         dprint(etos(e), " (link) connects to ", etos(e.enemy), " (point)");
 291         if (e.enemy.islinked)
 292         {
 293         dprint(" which is linked");
 294         if (e.enemy.team == t)
 295         {
 296         dprint(" and has the correct team!\n");
 297         return 1;
 298         }
 299         else
 300         dprint(" but has the wrong team\n");
 301         }
 302         else
 303         dprint("\n");
 304         }
 305         else if (e.enemy == cp)
 306         {
 307         dprint(etos(e), " (link) connects to ", etos(e.goalentity), " (point)");
 308         if (e.goalentity.islinked)
 309         {
 310         dprint(" which is linked");
 311         if (e.goalentity.team == t)
 312         {
 313         dprint(" and has a team!\n");
 314         return 1;
 315         }
 316         else
 317         dprint(" but has the wrong team\n");
 318         }
 319         else
 320         dprint("\n");
 321         }
 322         e = e.chain;
 323         }
 324         return 0;
 325          */
 326 }
 327
 328 float onslaught_controlpoint_attackable(entity cp, float t)
 329         // -2: SAME TEAM, attackable by enemy!
 330         // -1: SAME TEAM!
 331         // 0: off limits
 332         // 1: attack it
 333         // 2: touch it
 334         // 3: attack it (HIGH PRIO)
 335         // 4: touch it (HIGH PRIO)
 336 {
 337         float a;
 338
 339         if(cp.isshielded)
 340         {
 341                 return 0;
 342         }
 343         else if(cp.goalentity)
 344         {
 345                 // if there's already an icon built, nothing happens
 346                 if(cp.team == t)
 347                 {
 348                         a = onslaught_controlpoint_can_be_linked(cp, COLOR_TEAM1 + COLOR_TEAM2 - t);
 349                         if(a) // attackable by enemy?
 350                                 return -2; // EMERGENCY!
 351                         return -1;
 352                 }
 353                 // we know it can be linked, so no need to check
 354                 // but...
 355                 a = onslaught_controlpoint_can_be_linked(cp, t);
 356                 if(a == 2) // near our generator?
 357                         return 3; // EMERGENCY!
 358                 return 1;
 359         }
 360         else
 361         {
 362                 // free point
 363                 if(onslaught_controlpoint_can_be_linked(cp, t))
 364                 {
 365                         a = onslaught_controlpoint_can_be_linked(cp, COLOR_TEAM1 + COLOR_TEAM2 - t);
 366                         if(a == 2)
 367                                 return 4; // GET THIS ONE NOW!
 368                         else
 369                                 return 2; // TOUCH ME
 370                 }
 371         }
 372         return 0;
 373 }
 374
 375 void onslaught_generator_think()
 376 {
 377         local float d;
 378         local entity e;
 379         self.nextthink = ceil(time + 1);
 380         if (!gameover)
 381         {
 382                 if (autocvar_timelimit)
 383                 if (time > game_starttime + autocvar_timelimit * 60)
 384                 {
 385                         // self.max_health / 300 gives 5 minutes of overtime.
 386                         // control points reduce the overtime duration.
 387                         sound(self, CH_TRIGGER, "onslaught/generator_decay.wav", VOL_BASE, ATTN_NORM);
 388                         d = 1;
 389                         e = findchain(classname, "onslaught_controlpoint");
 390                         while (e)
 391                         {
 392                                 if (e.team != self.team)
 393                                         if (e.islinked)
 394                                                 d = d + 1;
 395                                 e = e.chain;
 396                         }
 397                         d = d * self.max_health / 300;
 398                         Damage(self, self, self, d, DEATH_HURTTRIGGER, self.origin, '0 0 0');
 399                 }
 400         }
 401 };
 402
 403 void onslaught_generator_ring_spawn(vector org)
 404 {
 405         modeleffect_spawn("models/onslaught/shockwavetransring.md3", 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, -16, 0.1, 1.25, 0.25);
 406 };
 407
 408 void onslaught_generator_ray_think()
 409 {
 410         self.nextthink = time + 0.05;
 411         if(self.count > 10)
 412         {
 413                 self.think = SUB_Remove;
 414                 return;
 415         }
 416
 417         if(self.count > 5)
 418                 self.alpha -= 0.1;
 419         else
 420                 self.alpha += 0.1;
 421
 422         self.scale += 0.2;
 423         self.count +=1;
 424 };
 425
 426 void onslaught_generator_ray_spawn(vector org)
 427 {
 428         entity e;
 429         e = spawn();
 430         setmodel(e, "models/onslaught/ons_ray.md3");
 431         setorigin(e, org);
 432         e.angles = randomvec() * 360;
 433         e.alpha = 0;
 434         e.scale = random() * 5 + 8;
 435         e.think = onslaught_generator_ray_think;
 436         e.nextthink = time + 0.05;
 437 };
 438
 439 void onslaught_generator_shockwave_spawn(vector org)
 440 {
 441         shockwave_spawn("models/onslaught/shockwave.md3", org, -64, 0.75, 0.5);
 442 };
 443
 444 void onslaught_generator_damage_think()
 445 {
 446         if(self.owner.health < 0)
 447         {
 448                 self.think = SUB_Remove;
 449                 return;
 450         }
 451         self.nextthink = time+0.1;
 452
 453         // damaged fx (less probable the more damaged is the generator)
 454         if(random() < 0.9 - self.owner.health / self.owner.max_health)
 455                 if(random() < 0.01)
 456                 {
 457                         pointparticles(particleeffectnum("electro_ballexplode"), self.origin + randompos('-50 -50 -20', '50 50 50'), '0 0 0', 1);
 458                         sound(self, CH_TRIGGER, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);
 459                 }
 460                 else
 461                         pointparticles(particleeffectnum("torch_small"), self.origin + randompos('-60 -60 -20', '60 60 60'), '0 0 0', 1);
 462 };
 463
 464 void onslaught_generator_damage_spawn(entity gd_owner)
 465 {
 466         entity e;
 467         e = spawn();
 468         e.owner = gd_owner;
 469         e.health = self.owner.health;
 470         setorigin(e, gd_owner.origin);
 471         e.think = onslaught_generator_damage_think;
 472         e.nextthink = time+1;
 473 };
 474
 475 void onslaught_generator_deaththink()
 476 {
 477         local vector org;
 478         local float i;
 479
 480         if not (self.count)
 481                 self.count = 40;
 482
 483         // White shockwave
 484         if(self.count==40||self.count==20)
 485         {
 486                 onslaught_generator_ring_spawn(self.origin);
 487                 sound(self, CH_TRIGGER, "onslaught/shockwave.wav", VOL_BASE, ATTN_NORM);
 488         }
 489
 490         // Throw some gibs
 491         if(random() < 0.3)
 492         {
 493                 i = random();
 494                 if(i < 0.3)
 495                         ons_throwgib(self.origin + '0 0 40', (100 * randomvec() - '1 1 1') * 11 + '0 0 20', "models/onslaught/gen_gib1.md3", 6, TRUE);
 496                 else if(i > 0.7)
 497                         ons_throwgib(self.origin + '0 0 40', (100 * randomvec() - '1 1 1') * 12 + '0 0 20', "models/onslaught/gen_gib2.md3", 6, TRUE);
 498                 else
 499                         ons_throwgib(self.origin + '0 0 40', (100 * randomvec() - '1 1 1') * 13 + '0 0 20', "models/onslaught/gen_gib3.md3", 6, TRUE);
 500         }
 501
 502         // Spawn fire balls
 503         for(i=0;i < 10;++i)
 504         {
 505                 org = self.origin + randompos('-30 -30 -30' * i + '0 0 -20', '30 30 30' * i + '0 0 20');
 506                 pointparticles(particleeffectnum("onslaught_generator_gib_explode"), org, '0 0 0', 1);
 507         }
 508
 509         // Short explosion sound + small explosion
 510         if(random() < 0.25)
 511         {
 512                 te_explosion(self.origin);
 513                 sound(self, CH_TRIGGER, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 514         }
 515
 516         // Particles
 517         org = self.origin + randompos(self.mins + '8 8 8', self.maxs + '-8 -8 -8');
 518         pointparticles(particleeffectnum("onslaught_generator_smallexplosion"), org, '0 0 0', 1);
 519
 520         // rays
 521         if(random() > 0.25 )
 522         {
 523                 onslaught_generator_ray_spawn(self.origin);
 524         }
 525
 526         // Final explosion
 527         if(self.count==1)
 528         {
 529                 org = self.origin;
 530                 te_explosion(org);
 531                 onslaught_generator_shockwave_spawn(org);
 532                 pointparticles(particleeffectnum("onslaught_generator_finalexplosion"), org, '0 0 0', 1);
 533                 sound(self, CH_TRIGGER, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 534         }
 535         else
 536                 self.nextthink = time + 0.05;
 537
 538         self.count = self.count - 1;
 539 };
 540
 541 void onslaught_generator_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 542 {
 543         local float i;
 544         if (damage <= 0)
 545                 return;
 546         if(inWarmupStage)
 547                 return;
 548         if (attacker != self)
 549         {
 550                 if (self.isshielded)
 551                 {
 552                         // this is protected by a shield, so ignore the damage
 553                         if (time > self.pain_finished)
 554                                 if (attacker.classname == "player")
 555                                 {
 556                                         play2(attacker, "onslaught/damageblockedbyshield.wav");
 557                                         self.pain_finished = time + 1;
 558                                 }
 559                         return;
 560                 }
 561                 if (time > self.pain_finished)
 562                 {
 563                         self.pain_finished = time + 10;
 564                         bprint(ColoredTeamName(self.team), " generator under attack!\n");
 565                         play2team(self.team, "onslaught/generator_underattack.wav");
 566                 }
 567         }
 568         self.health = self.health - damage;
 569         WaypointSprite_UpdateHealth(self.sprite, self.health);
 570         // choose an animation frame based on health
 571         self.frame = 10 * bound(0, (1 - self.health / self.max_health), 1);
 572         // see if the generator is still functional, or dying
 573         if (self.health > 0)
 574         {
 575 #ifdef ONSLAUGHT_SPAM
 576                 float h, lh;
 577                 lh = ceil(self.lasthealth / 100) * 100;
 578                 h = ceil(self.health / 100) * 100;
 579                 if(lh != h)
 580                         bprint(ColoredTeamName(self.team), " generator has less than ", ftos(h), " health remaining\n");
 581 #endif
 582                 self.lasthealth = self.health;
 583         }
 584         else if not(inWarmupStage)
 585         {
 586                 if (attacker == self)
 587                         bprint(ColoredTeamName(self.team), " generator spontaneously exploded due to overtime!\n");
 588                 else
 589                 {
 590                         string t;
 591                         t = ColoredTeamName(attacker.team);
 592                         bprint(ColoredTeamName(self.team), " generator destroyed by ", t, "!\n");
 593                 }
 594                 self.iscaptured = FALSE;
 595                 self.islinked = FALSE;
 596                 self.isshielded = FALSE;
 597                 self.takedamage = DAMAGE_NO; // can't be hurt anymore
 598                 self.event_damage = SUB_Null; // won't do anything if hurt
 599                 self.count = 0; // reset counter
 600                 self.think = onslaught_generator_deaththink; // explosion sequence
 601                 self.nextthink = time; // start exploding immediately
 602                 self.think(); // do the first explosion now
 603
 604                 WaypointSprite_UpdateMaxHealth(self.sprite, 0);
 605
 606                 onslaught_updatelinks();
 607         }
 608
 609         if(self.health <= 0)
 610                 setmodel(self, "models/onslaught/generator_dead.md3");
 611         else if(self.health < self.max_health * 0.10)
 612                 setmodel(self, "models/onslaught/generator_dmg9.md3");
 613         else if(self.health < self.max_health * 0.20)
 614                 setmodel(self, "models/onslaught/generator_dmg8.md3");
 615         else if(self.health < self.max_health * 0.30)
 616                 setmodel(self, "models/onslaught/generator_dmg7.md3");
 617         else if(self.health < self.max_health * 0.40)
 618                 setmodel(self, "models/onslaught/generator_dmg6.md3");
 619         else if(self.health < self.max_health * 0.50)
 620                 setmodel(self, "models/onslaught/generator_dmg5.md3");
 621         else if(self.health < self.max_health * 0.60)
 622                 setmodel(self, "models/onslaught/generator_dmg4.md3");
 623         else if(self.health < self.max_health * 0.70)
 624                 setmodel(self, "models/onslaught/generator_dmg3.md3");
 625         else if(self.health < self.max_health * 0.80)
 626                 setmodel(self, "models/onslaught/generator_dmg2.md3");
 627         else if(self.health < self.max_health * 0.90)
 628                 setmodel(self, "models/onslaught/generator_dmg1.md3");
 629         setsize(self, '-52 -52 -14', '52 52 75');
 630
 631         // Throw some flaming gibs on damage, more damage = more chance for gib
 632         if(random() < damage/220)
 633         {
 634                 sound(self, CH_TRIGGER, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 635                 i = random();
 636                 if(i < 0.3)
 637                         ons_throwgib(hitloc + '0 0 20', force * -1, "models/onslaught/gen_gib1.md3", 5, TRUE);
 638                 else if(i > 0.7)
 639                         ons_throwgib(hitloc + '0 0 20', force * -1, "models/onslaught/gen_gib2.md3", 5, TRUE);
 640                 else
 641                         ons_throwgib(hitloc + '0 0 20', force * -1, "models/onslaught/gen_gib3.md3", 5, TRUE);
 642         }
 643         else
 644         {
 645                 // particles on every hit
 646                 pointparticles(particleeffectnum("sparks"), hitloc, force * -1, 1);
 647
 648                 //sound on every hit
 649                 if (random() < 0.5)
 650                         sound(self, CH_TRIGGER, "onslaught/ons_hit1.wav", VOL_BASE, ATTN_NORM);
 651                 else
 652                         sound(self, CH_TRIGGER, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);
 653         }
 654
 655         //throw some gibs on damage
 656         if(random() < damage/200+0.2)
 657                 if(random() < 0.5)
 658                         ons_throwgib(hitloc + '0 0 20', randomvec()*360, "models/onslaught/gen_gib1.md3", 5, FALSE);
 659 };
 660
 661 // update links after a delay
 662 void onslaught_generator_delayed()
 663 {
 664         onslaught_updatelinks();
 665         // now begin normal thinking
 666         self.think = onslaught_generator_think;
 667         self.nextthink = time;
 668 };
 669
 670 string onslaught_generator_waypointsprite_for_team(entity e, float t)
 671 {
 672         if(t == e.team)
 673         {
 674                 if(e.team == COLOR_TEAM1)
 675                         return "ons-gen-red";
 676                 else if(e.team == COLOR_TEAM2)
 677                         return "ons-gen-blue";
 678         }
 679         if(e.isshielded)
 680                 return "ons-gen-shielded";
 681         if(e.team == COLOR_TEAM1)
 682                 return "ons-gen-red";
 683         else if(e.team == COLOR_TEAM2)
 684                 return "ons-gen-blue";
 685         return "";
 686 }
 687
 688 void onslaught_generator_updatesprite(entity e)
 689 {
 690         string s1, s2, s3;
 691         s1 = onslaught_generator_waypointsprite_for_team(e, COLOR_TEAM1);
 692         s2 = onslaught_generator_waypointsprite_for_team(e, COLOR_TEAM2);
 693         s3 = onslaught_generator_waypointsprite_for_team(e, -1);
 694         WaypointSprite_UpdateSprites(e.sprite, s1, s2, s3);
 695
 696         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 697         {
 698                 e.lastteam = e.team + 2;
 699                 e.lastshielded = e.isshielded;
 700                 if(e.lastshielded)
 701                 {
 702                         if(e.team == COLOR_TEAM1 || e.team == COLOR_TEAM2)
 703                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, FALSE));
 704                         else
 705                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 706                 }
 707                 else
 708                 {
 709                         if(e.team == COLOR_TEAM1 || e.team == COLOR_TEAM2)
 710                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, FALSE));
 711                         else
 712                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 713                 }
 714                 WaypointSprite_Ping(e.sprite);
 715         }
 716 }
 717
 718 string onslaught_controlpoint_waypointsprite_for_team(entity e, float t)
 719 {
 720         float a;
 721         if(t != -1)
 722         {
 723                 a = onslaught_controlpoint_attackable(e, t);
 724                 if(a == 3 || a == 4) // ATTACK/TOUCH THIS ONE NOW
 725                 {
 726                         if(e.team == COLOR_TEAM1)
 727                                 return "ons-cp-atck-red";
 728                         else if(e.team == COLOR_TEAM2)
 729                                 return "ons-cp-atck-blue";
 730                         else
 731                                 return "ons-cp-atck-neut";
 732                 }
 733                 else if(a == -2) // DEFEND THIS ONE NOW
 734                 {
 735                         if(e.team == COLOR_TEAM1)
 736                                 return "ons-cp-dfnd-red";
 737                         else if(e.team == COLOR_TEAM2)
 738                                 return "ons-cp-dfnd-blue";
 739                 }
 740                 else if(e.team == t || a == -1 || a == 1) // own point, or fire at it
 741                 {
 742                         if(e.team == COLOR_TEAM1)
 743                                 return "ons-cp-red";
 744                         else if(e.team == COLOR_TEAM2)
 745                                 return "ons-cp-blue";
 746                 }
 747                 else if(a == 2) // touch it
 748                         return "ons-cp-neut";
 749         }
 750         else
 751         {
 752                 if(e.team == COLOR_TEAM1)
 753                         return "ons-cp-red";
 754                 else if(e.team == COLOR_TEAM2)
 755                         return "ons-cp-blue";
 756                 else
 757                         return "ons-cp-neut";
 758         }
 759         return "";
 760 }
 761
 762 void onslaught_controlpoint_updatesprite(entity e)
 763 {
 764         string s1, s2, s3;
 765         s1 = onslaught_controlpoint_waypointsprite_for_team(e, COLOR_TEAM1);
 766         s2 = onslaught_controlpoint_waypointsprite_for_team(e, COLOR_TEAM2);
 767         s3 = onslaught_controlpoint_waypointsprite_for_team(e, -1);
 768         WaypointSprite_UpdateSprites(e.sprite, s1, s2, s3);
 769
 770         float sh;
 771         sh = !(onslaught_controlpoint_can_be_linked(e, COLOR_TEAM1) || onslaught_controlpoint_can_be_linked(e, COLOR_TEAM2));
 772
 773         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 774         {
 775                 if(e.iscaptured) // don't mess up build bars!
 776                 {
 777                         if(sh)
 778                         {
 779                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 780                         }
 781                         else
 782                         {
 783                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 784                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
 785                         }
 786                 }
 787                 if(e.lastshielded)
 788                 {
 789                         if(e.team == COLOR_TEAM1 || e.team == COLOR_TEAM2)
 790                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, FALSE));
 791                         else
 792                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 793                 }
 794                 else
 795                 {
 796                         if(e.team == COLOR_TEAM1 || e.team == COLOR_TEAM2)
 797                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, FALSE));
 798                         else
 799                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 800                 }
 801                 WaypointSprite_Ping(e.sprite);
 802
 803                 e.lastteam = e.team + 2;
 804                 e.lastshielded = sh;
 805                 e.lastcaptured = e.iscaptured;
 806         }
 807 }
 808
 809 void onslaught_generator_reset()
 810 {
 811         self.team = self.team_saved;
 812         self.lasthealth = self.max_health = self.health = autocvar_g_onslaught_gen_health;
 813         self.takedamage = DAMAGE_AIM;
 814         self.bot_attack = TRUE;
 815         self.iscaptured = TRUE;
 816         self.islinked = TRUE;
 817         self.isshielded = TRUE;
 818         self.enemy.solid = SOLID_NOT;
 819         self.think = onslaught_generator_delayed;
 820         self.nextthink = time + 0.2;
 821         setmodel(self, "models/onslaught/generator.md3");
 822         setsize(self, '-52 -52 -14', '52 52 75');
 823
 824         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 825         WaypointSprite_UpdateHealth(self.sprite, self.health);
 826 }
 827
 828 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
 829   Base generator.
 830
 831   spawnfunc_onslaught_link entities can target this.
 832
 833 keys:
 834 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
 835 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
 836  */
 837 void spawnfunc_onslaught_generator()
 838 {
 839         if (!g_onslaught)
 840         {
 841                 remove(self);
 842                 return;
 843         }
 844
 845         local entity e;
 846         precache_model("models/onslaught/generator.md3");
 847         precache_model("models/onslaught/generator_shield.md3");
 848         precache_model("models/onslaught/generator_dmg1.md3");
 849         precache_model("models/onslaught/generator_dmg2.md3");
 850         precache_model("models/onslaught/generator_dmg3.md3");
 851         precache_model("models/onslaught/generator_dmg4.md3");
 852         precache_model("models/onslaught/generator_dmg5.md3");
 853         precache_model("models/onslaught/generator_dmg6.md3");
 854         precache_model("models/onslaught/generator_dmg7.md3");
 855         precache_model("models/onslaught/generator_dmg8.md3");
 856         precache_model("models/onslaught/generator_dmg9.md3");
 857         precache_model("models/onslaught/generator_dead.md3");
 858         precache_model("models/onslaught/shockwave.md3");
 859         precache_model("models/onslaught/shockwavetransring.md3");
 860         precache_model("models/onslaught/gen_gib1.md3");
 861         precache_model("models/onslaught/gen_gib2.md3");
 862         precache_model("models/onslaught/gen_gib3.md3");
 863         precache_model("models/onslaught/ons_ray.md3");
 864         precache_sound("onslaught/generator_decay.wav");
 865         precache_sound("weapons/grenade_impact.wav");
 866         precache_sound("weapons/rocket_impact.wav");
 867         precache_sound("onslaught/generator_underattack.wav");
 868         precache_sound("onslaught/shockwave.wav");
 869         precache_sound("onslaught/ons_hit1.wav");
 870         precache_sound("onslaught/ons_hit2.wav");
 871         precache_sound("onslaught/electricity_explode.wav");
 872         if (!self.team)
 873                 objerror("team must be set");
 874         self.team_saved = self.team;
 875         self.colormap = 1024 + (self.team - 1) * 17;
 876         self.solid = SOLID_BBOX;
 877         self.movetype = MOVETYPE_NONE;
 878         self.lasthealth = self.max_health = self.health = autocvar_g_onslaught_gen_health;
 879         setmodel(self, "models/onslaught/generator.md3");
 880         setsize(self, '-52 -52 -14', '52 52 75');
 881         setorigin(self, self.origin);
 882         self.takedamage = DAMAGE_AIM;
 883         self.bot_attack = TRUE;
 884         self.event_damage = onslaught_generator_damage;
 885         self.iscaptured = TRUE;
 886         self.islinked = TRUE;
 887         self.isshielded = TRUE;
 888         // helper entity that create fx when generator is damaged
 889         onslaught_generator_damage_spawn(self);
 890         // spawn shield model which indicates whether this can be damaged
 891         self.enemy = e = spawn();
 892         e.classname = "onslaught_generator_shield";
 893         e.solid = SOLID_NOT;
 894         e.movetype = MOVETYPE_NONE;
 895         e.effects = EF_ADDITIVE;
 896         setmodel(e, "models/onslaught/generator_shield.md3");
 897         setorigin(e, self.origin);
 898         e.colormap = self.colormap;
 899         e.team = self.team;
 900         self.think = onslaught_generator_delayed;
 901         self.nextthink = time + 0.2;
 902         InitializeEntity(self, onslaught_generator_delayed, INITPRIO_LAST);
 903
 904         WaypointSprite_SpawnFixed(string_null, e.origin + '0 0 1' * e.maxs_z, self, sprite, RADARICON_NONE, '0 0 0');
 905         WaypointSprite_UpdateRule(self.sprite, COLOR_TEAM2, SPRITERULE_TEAMPLAY);
 906         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 907         WaypointSprite_UpdateHealth(self.sprite, self.health);
 908
 909         waypoint_spawnforitem(self);
 910
 911         onslaught_updatelinks();
 912
 913         self.reset = onslaught_generator_reset;
 914 };
 915
 916 .float waslinked;
 917 .float cp_bob_spd;
 918 .vector cp_origin, cp_bob_origin, cp_bob_dmg;
 919
 920 float ons_notification_time_team1;
 921 float ons_notification_time_team2;
 922
 923 void onslaught_controlpoint_icon_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 924 {
 925         entity oself;
 926         float nag;
 927
 928         if (damage <= 0)
 929                 return;
 930         if (self.owner.isshielded)
 931         {
 932                 // this is protected by a shield, so ignore the damage
 933                 if (time > self.pain_finished)
 934                         if (attacker.classname == "player")
 935                         {
 936                                 play2(attacker, "onslaught/damageblockedbyshield.wav");
 937                                 self.pain_finished = time + 1;
 938                         }
 939                 return;
 940         }
 941
 942         if (attacker.classname == "player")
 943         {
 944                 if(self.team == COLOR_TEAM1)
 945                 {
 946                         if(time - ons_notification_time_team1 > 10)
 947                         {
 948                                 nag = TRUE;
 949                                 ons_notification_time_team1 = time;
 950                         }
 951                 }
 952                 else if(self.team == COLOR_TEAM2)
 953                 {
 954                         if(time - ons_notification_time_team2 > 10)
 955                         {
 956                                 nag = TRUE;
 957                                 ons_notification_time_team2 = time;
 958                         }
 959                 }
 960                 else
 961                         nag = TRUE;
 962
 963                 if(nag)
 964                         play2team(self.team, "onslaught/controlpoint_underattack.wav");
 965         }
 966
 967         self.health = self.health - damage;
 968         if(self.owner.iscaptured)
 969                 WaypointSprite_UpdateHealth(self.owner.sprite, self.health);
 970         else
 971                 WaypointSprite_UpdateBuildFinished(self.owner.sprite, time + (self.max_health - self.health) / (self.count / sys_frametime));
 972         self.pain_finished = time + 1;
 973         self.punchangle = (2 * randomvec() - '1 1 1') * 45;
 974         self.cp_bob_dmg_z = (2 * random() - 1) * 15;
 975         // colormod flash when shot
 976         self.colormod = '2 2 2';
 977         // particles on every hit
 978         pointparticles(particleeffectnum("sparks"), hitloc, force*-1, 1);
 979         //sound on every hit
 980         if (random() < 0.5)
 981                 sound(self, CH_TRIGGER, "onslaught/ons_hit1.wav", VOL_BASE+0.3, ATTN_NORM);
 982         else
 983                 sound(self, CH_TRIGGER, "onslaught/ons_hit2.wav", VOL_BASE+0.3, ATTN_NORM);
 984
 985         if (self.health < 0)
 986         {
 987                 sound(self, CH_TRIGGER, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 988                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 989                 {
 990                         string t;
 991                         t = ColoredTeamName(attacker.team);
 992                         bprint(ColoredTeamName(self.team), " ", self.message, " control point destroyed by ", t, "\n");
 993                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 25, "models/onslaught/controlpoint_icon_gib1.md3", 3, FALSE);
 994                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 45, "models/onslaught/controlpoint_icon_gib2.md3", 3, FALSE);
 995                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 45, "models/onslaught/controlpoint_icon_gib2.md3", 3, FALSE);
 996                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 75, "models/onslaught/controlpoint_icon_gib4.md3", 3, FALSE);
 997                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 75, "models/onslaught/controlpoint_icon_gib4.md3", 3, FALSE);
 998                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 75, "models/onslaught/controlpoint_icon_gib4.md3", 3, FALSE);
 999                         ons_throwgib(self.origin, (2 * randomvec() - '1 1 1') * 75, "models/onslaught/controlpoint_icon_gib4.md3", 3, FALSE);
1000                 }
1001                 self.owner.goalentity = world;
1002                 self.owner.islinked = FALSE;
1003                 self.owner.iscaptured = FALSE;
1004                 self.owner.team = 0;
1005                 self.owner.colormap = 1024;
1006
1007                 WaypointSprite_UpdateMaxHealth(self.owner.sprite, 0);
1008
1009                 onslaught_updatelinks();
1010
1011                 // Use targets now (somebody make sure this is in the right place..)
1012                 oself = self;
1013                 self = self.owner;
1014                 activator = self;
1015                 SUB_UseTargets ();
1016                 self = oself;
1017
1018
1019                 self.owner.waslinked = self.owner.islinked;
1020                 if(self.owner.model != "models/onslaught/controlpoint_pad.md3")
1021                         setmodel(self.owner, "models/onslaught/controlpoint_pad.md3");
1022                 //setsize(self, '-32 -32 0', '32 32 8');
1023
1024                 remove(self);
1025         }
1026 };
1027
1028 void onslaught_controlpoint_icon_think()
1029 {
1030         entity oself;
1031         self.nextthink = time + sys_frametime;
1032         if (time > self.pain_finished + 5)
1033         {
1034                 if(self.health < self.max_health)
1035                 {
1036                         self.health = self.health + self.count;
1037                         if (self.health >= self.max_health)
1038                                 self.health = self.max_health;
1039                         WaypointSprite_UpdateHealth(self.owner.sprite, self.health);
1040                 }
1041         }
1042         if (self.health < self.max_health * 0.25)
1043                 setmodel(self, "models/onslaught/controlpoint_icon_dmg3.md3");
1044         else if (self.health < self.max_health * 0.50)
1045                 setmodel(self, "models/onslaught/controlpoint_icon_dmg2.md3");
1046         else if (self.health < self.max_health * 0.75)
1047                 setmodel(self, "models/onslaught/controlpoint_icon_dmg1.md3");
1048         else if (self.health < self.max_health * 0.90)
1049                 setmodel(self, "models/onslaught/controlpoint_icon.md3");
1050         // colormod flash when shot
1051         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
1052
1053         if(self.owner.islinked != self.owner.waslinked)
1054         {
1055                 // unteam the spawnpoint if needed
1056                 float t;
1057                 t = self.owner.team;
1058                 if(!self.owner.islinked)
1059                         self.owner.team = 0;
1060
1061                 oself = self;
1062                 self = self.owner;
1063                 activator = self;
1064                 SUB_UseTargets ();
1065                 self = oself;
1066
1067                 self.owner.team = t;
1068
1069                 self.owner.waslinked = self.owner.islinked;
1070         }
1071
1072         if (self.punchangle_x > 0)
1073         {
1074                 self.punchangle_x = self.punchangle_x - 60 * sys_frametime;
1075                 if (self.punchangle_x < 0)
1076                         self.punchangle_x = 0;
1077         }
1078         else if (self.punchangle_x < 0)
1079         {
1080                 self.punchangle_x = self.punchangle_x + 60 * sys_frametime;
1081                 if (self.punchangle_x > 0)
1082                         self.punchangle_x = 0;
1083         }
1084
1085         if (self.punchangle_y > 0)
1086         {
1087                 self.punchangle_y = self.punchangle_y - 60 * sys_frametime;
1088                 if (self.punchangle_y < 0)
1089                         self.punchangle_y = 0;
1090         }
1091         else if (self.punchangle_y < 0)
1092         {
1093                 self.punchangle_y = self.punchangle_y + 60 * sys_frametime;
1094                 if (self.punchangle_y > 0)
1095                         self.punchangle_y = 0;
1096         }
1097
1098         if (self.punchangle_z > 0)
1099         {
1100                 self.punchangle_z = self.punchangle_z - 60 * sys_frametime;
1101                 if (self.punchangle_z < 0)
1102                         self.punchangle_z = 0;
1103         }
1104         else if (self.punchangle_z < 0)
1105         {
1106                 self.punchangle_z = self.punchangle_z + 60 * sys_frametime;
1107                 if (self.punchangle_z > 0)
1108                         self.punchangle_z = 0;
1109         }
1110
1111         self.angles_x = self.punchangle_x;
1112         self.angles_y = self.punchangle_y + self.mangle_y;
1113         self.angles_z = self.punchangle_z;
1114         self.mangle_y = self.mangle_y + 45 * sys_frametime;
1115
1116         self.cp_bob_origin_z = 4 * PI * (1 - cos(self.cp_bob_spd));
1117         self.cp_bob_spd = self.cp_bob_spd + 1.875 * sys_frametime;
1118         if(self.cp_bob_dmg_z > 0)
1119                 self.cp_bob_dmg_z = self.cp_bob_dmg_z - 3 * sys_frametime;
1120         else
1121                 self.cp_bob_dmg_z = 0;
1122         setorigin(self,self.cp_origin + self.cp_bob_origin + self.cp_bob_dmg);
1123
1124         // damaged fx
1125         if(random() < 0.6 - self.health / self.max_health)
1126         {
1127                 pointparticles(particleeffectnum("electricity_sparks"), self.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
1128
1129                 if(random() > 0.8)
1130                         sound(self, CH_PAIN, "onslaught/ons_spark1.wav", VOL_BASE, ATTN_NORM);
1131                 else if (random() > 0.5)
1132                         sound(self, CH_PAIN, "onslaught/ons_spark2.wav", VOL_BASE, ATTN_NORM);
1133         }
1134 };
1135
1136 void onslaught_controlpoint_icon_buildthink()
1137 {
1138         local entity oself;
1139         float a;
1140
1141         self.nextthink = time + sys_frametime;
1142
1143         // only do this if there is power
1144         a = onslaught_controlpoint_can_be_linked(self.owner, self.owner.team);
1145         if(!a)
1146                 return;
1147
1148         self.health = self.health + self.count;
1149
1150         if (self.health >= self.max_health)
1151         {
1152                 self.health = self.max_health;
1153                 self.count = autocvar_g_onslaught_cp_regen * sys_frametime; // slow repair rate from now on
1154                 self.think = onslaught_controlpoint_icon_think;
1155                 sound(self, CH_TRIGGER, "onslaught/controlpoint_built.wav", VOL_BASE, ATTN_NORM);
1156                 bprint(ColoredTeamName(self.team), " captured ", self.owner.message, " control point\n");
1157                 self.owner.iscaptured = TRUE;
1158
1159                 WaypointSprite_UpdateMaxHealth(self.owner.sprite, self.max_health);
1160                 WaypointSprite_UpdateHealth(self.owner.sprite, self.health);
1161
1162                 onslaught_updatelinks();
1163
1164                 // Use targets now (somebody make sure this is in the right place..)
1165                 oself = self;
1166                 self = self.owner;
1167                 activator = self;
1168                 SUB_UseTargets ();
1169                 self = oself;
1170                 self.cp_origin = self.origin;
1171                 self.cp_bob_origin = '0 0 0.1';
1172                 self.cp_bob_spd = 0;
1173         }
1174         self.alpha = self.health / self.max_health;
1175         // colormod flash when shot
1176         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
1177         if(self.owner.model != "models/onslaught/controlpoint_pad2.md3")
1178                 setmodel(self.owner, "models/onslaught/controlpoint_pad2.md3");
1179         //setsize(self, '-32 -32 0', '32 32 8');
1180
1181         if(random() < 0.9 - self.health / self.max_health)
1182                 pointparticles(particleeffectnum("rage"), self.origin + 10 * randomvec(), '0 0 -1', 1);
1183 };
1184
1185
1186
1187
1188 void onslaught_controlpoint_touch()
1189 {
1190         local entity e;
1191         float a;
1192         if (other.classname != "player")
1193                 return;
1194         a = onslaught_controlpoint_attackable(self, other.team);
1195         if(a != 2 && a != 4)
1196                 return;
1197         // we've verified that this player has a legitimate claim to this point,
1198         // so start building the captured point icon (which only captures this
1199         // point if it successfully builds without being destroyed first)
1200         self.goalentity = e = spawn();
1201         e.classname = "onslaught_controlpoint_icon";
1202         e.owner = self;
1203         e.max_health = autocvar_g_onslaught_cp_health;
1204         e.health = autocvar_g_onslaught_cp_buildhealth;
1205         e.solid = SOLID_BBOX;
1206         e.movetype = MOVETYPE_NONE;
1207         setmodel(e, "models/onslaught/controlpoint_icon.md3");
1208         setsize(e, '-32 -32 -32', '32 32 32');
1209         setorigin(e, self.origin + '0 0 96');
1210         e.takedamage = DAMAGE_AIM;
1211         e.bot_attack = TRUE;
1212         e.event_damage = onslaught_controlpoint_icon_damage;
1213         e.team = other.team;
1214         e.colormap = 1024 + (e.team - 1) * 17;
1215         e.think = onslaught_controlpoint_icon_buildthink;
1216         e.nextthink = time + sys_frametime;
1217         e.count = (e.max_health - e.health) * sys_frametime / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
1218         sound(e, CH_TRIGGER, "onslaught/controlpoint_build.wav", VOL_BASE, ATTN_NORM);
1219         self.team = e.team;
1220         self.colormap = e.colormap;
1221         WaypointSprite_UpdateBuildFinished(self.sprite, time + (e.max_health - e.health) / (e.count / sys_frametime));
1222         onslaught_updatelinks();
1223 };
1224
1225 void onslaught_controlpoint_reset()
1226 {
1227         if(self.goalentity && self.goalentity != world)
1228                 remove(self.goalentity);
1229         self.goalentity = world;
1230         self.team = 0;
1231         self.colormap = 1024;
1232         self.iscaptured = FALSE;
1233         self.islinked = FALSE;
1234         self.isshielded = TRUE;
1235         self.enemy.solid = SOLID_NOT;
1236         self.enemy.colormap = self.colormap;
1237         self.think = self.enemy.think = SUB_Null;
1238         self.nextthink = 0; // don't like SUB_Null :P
1239         setmodel(self, "models/onslaught/controlpoint_pad.md3");
1240         //setsize(self, '-32 -32 0', '32 32 8');
1241
1242         WaypointSprite_UpdateMaxHealth(self.sprite, 0);
1243
1244         onslaught_updatelinks();
1245
1246         activator = self;
1247         SUB_UseTargets(); // to reset the structures, playerspawns etc.
1248 }
1249
1250 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
1251   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
1252
1253   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
1254
1255 keys:
1256 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
1257 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
1258 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
1259  */
1260 void spawnfunc_onslaught_controlpoint()
1261 {
1262         local entity e;
1263         if (!g_onslaught)
1264         {
1265                 remove(self);
1266                 return;
1267         }
1268         precache_model("models/onslaught/controlpoint_pad.md3");
1269         precache_model("models/onslaught/controlpoint_pad2.md3");
1270         precache_model("models/onslaught/controlpoint_shield.md3");
1271         precache_model("models/onslaught/controlpoint_icon.md3");
1272         precache_model("models/onslaught/controlpoint_icon_dmg1.md3");
1273         precache_model("models/onslaught/controlpoint_icon_dmg2.md3");
1274         precache_model("models/onslaught/controlpoint_icon_dmg3.md3");
1275         precache_model("models/onslaught/controlpoint_icon_gib1.md3");
1276         precache_model("models/onslaught/controlpoint_icon_gib2.md3");
1277         precache_model("models/onslaught/controlpoint_icon_gib4.md3");
1278         precache_sound("onslaught/controlpoint_build.wav");
1279         precache_sound("onslaught/controlpoint_built.wav");
1280         precache_sound("weapons/grenade_impact.wav");
1281         precache_sound("onslaught/damageblockedbyshield.wav");
1282         precache_sound("onslaught/controlpoint_underattack.wav");
1283         precache_sound("onslaught/ons_spark1.wav");
1284         precache_sound("onslaught/ons_spark2.wav");
1285         self.solid = SOLID_BBOX;
1286         self.movetype = MOVETYPE_NONE;
1287         setmodel(self, "models/onslaught/controlpoint_pad.md3");
1288         //setsize(self, '-32 -32 0', '32 32 8');
1289         setorigin(self, self.origin);
1290         self.touch = onslaught_controlpoint_touch;
1291         self.team = 0;
1292         self.colormap = 1024;
1293         self.iscaptured = FALSE;
1294         self.islinked = FALSE;
1295         self.isshielded = TRUE;
1296         // spawn shield model which indicates whether this can be damaged
1297         self.enemy = e = spawn();
1298         e.classname = "onslaught_controlpoint_shield";
1299         e.solid = SOLID_NOT;
1300         e.movetype = MOVETYPE_NONE;
1301         e.effects = EF_ADDITIVE;
1302         setmodel(e, "models/onslaught/controlpoint_shield.md3");
1303         //setsize(e, '-32 -32 0', '32 32 128');
1304         setorigin(e, self.origin);
1305         e.colormap = self.colormap;
1306
1307         waypoint_spawnforitem(self);
1308
1309         WaypointSprite_SpawnFixed(string_null, e.origin + '0 0 1' * e.maxs_z, self, sprite, RADARICON_NONE, '0 0 0');
1310         WaypointSprite_UpdateRule(self.sprite, COLOR_TEAM2, SPRITERULE_TEAMPLAY);
1311
1312         onslaught_updatelinks();
1313
1314         self.reset = onslaught_controlpoint_reset;
1315 };
1316
1317 float onslaught_link_send(entity to, float sendflags)
1318 {
1319         WriteByte(MSG_ENTITY, ENT_CLIENT_RADARLINK);
1320         WriteByte(MSG_ENTITY, sendflags);
1321         if(sendflags & 1)
1322         {
1323                 WriteCoord(MSG_ENTITY, self.goalentity.origin_x);
1324                 WriteCoord(MSG_ENTITY, self.goalentity.origin_y);
1325                 WriteCoord(MSG_ENTITY, self.goalentity.origin_z);
1326         }
1327         if(sendflags & 2)
1328         {
1329                 WriteCoord(MSG_ENTITY, self.enemy.origin_x);
1330                 WriteCoord(MSG_ENTITY, self.enemy.origin_y);
1331                 WriteCoord(MSG_ENTITY, self.enemy.origin_z);
1332         }
1333         if(sendflags & 4)
1334         {
1335                 WriteByte(MSG_ENTITY, self.clientcolors); // which is goalentity's color + enemy's color * 16
1336         }
1337         return TRUE;
1338 }
1339
1340 void onslaught_link_checkupdate()
1341 {
1342         // TODO check if the two sides have moved (currently they won't move anyway)
1343         float redpower, bluepower;
1344
1345         redpower = bluepower = 0;
1346         if(self.goalentity.islinked)
1347         {
1348                 if(self.goalentity.team == COLOR_TEAM1)
1349                         redpower = 1;
1350                 else if(self.goalentity.team == COLOR_TEAM2)
1351                         bluepower = 1;
1352         }
1353         if(self.enemy.islinked)
1354         {
1355                 if(self.enemy.team == COLOR_TEAM1)
1356                         redpower = 2;
1357                 else if(self.enemy.team == COLOR_TEAM2)
1358                         bluepower = 2;
1359         }
1360
1361         float cc;
1362         if(redpower == 1 && bluepower == 2)
1363                 cc = (COLOR_TEAM1 - 1) * 0x01 + (COLOR_TEAM2 - 1) * 0x10;
1364         else if(redpower == 2 && bluepower == 1)
1365                 cc = (COLOR_TEAM1 - 1) * 0x10 + (COLOR_TEAM2 - 1) * 0x01;
1366         else if(redpower)
1367                 cc = (COLOR_TEAM1 - 1) * 0x11;
1368         else if(bluepower)
1369                 cc = (COLOR_TEAM2 - 1) * 0x11;
1370         else
1371                 cc = 0;
1372
1373         //print(etos(self), " rp=", ftos(redpower), " bp=", ftos(bluepower), " ");
1374         //print("cc=", ftos(cc), "\n");
1375
1376         if(cc != self.clientcolors)
1377         {
1378                 self.clientcolors = cc;
1379                 self.SendFlags |= 4;
1380         }
1381
1382         self.nextthink = time;
1383 }
1384
1385 void onslaught_link_delayed()
1386 {
1387         self.goalentity = find(world, targetname, self.target);
1388         self.enemy = find(world, targetname, self.target2);
1389         if (!self.goalentity)
1390                 objerror("can not find target\n");
1391         if (!self.enemy)
1392                 objerror("can not find target2\n");
1393         dprint(etos(self.goalentity), " linked with ", etos(self.enemy), "\n");
1394         self.SendFlags |= 3;
1395         self.think = onslaught_link_checkupdate;
1396         self.nextthink = time;
1397 }
1398
1399 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
1400   Link between control points.
1401
1402   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
1403
1404 keys:
1405 "target" - first control point.
1406 "target2" - second control point.
1407  */
1408 void spawnfunc_onslaught_link()
1409 {
1410         if (!g_onslaught)
1411         {
1412                 remove(self);
1413                 return;
1414         }
1415         if (self.target == "" || self.target2 == "")
1416                 objerror("target and target2 must be set\n");
1417         InitializeEntity(self, onslaught_link_delayed, INITPRIO_FINDTARGET);
1418         Net_LinkEntity(self, FALSE, 0, onslaught_link_send);
1419 };