qcsrc/server/mutators/gamemode_keepaway.qc

   1 void ka_SpawnBall(void);
   2 void ka_TouchEvent(void);
   3 void ka_RespawnBall(void);
   4 void ka_DropEvent(entity);
   5 void ka_TimeScoring(void);
   6
   7 entity ka_ball;
   8
   9 float ka_ballcarrier_waypointsprite_visible_for_player(entity);
  10
  11 void ka_Initialize() // run at the start of a match, initiates game mode
  12 {
  13         if(!g_keepaway)
  14                 return;
  15
  16         precache_sound("keepaway/pickedup.wav");
  17         precache_sound("keepaway/dropped.wav");
  18         precache_sound("keepaway/respawn.wav");
  19         precache_sound("keepaway/touch.wav");
  20
  21         ScoreRules_keepaway();
  22         ka_SpawnBall();
  23 }
  24
  25 void ka_Reset() // used to clear the ballcarrier whenever the match switches from warmup to normal
  26 {
  27         if(self.owner)
  28                 if(self.owner.classname == "player")
  29                         ka_DropEvent(self.owner);
  30
  31         ka_RespawnBall();
  32 }
  33
  34 void ka_SpawnBall() // loads various values for the ball, runs only once at start of match
  35 {
  36         if(!g_keepaway) { return; }
  37
  38         entity e;
  39         e = spawn();
  40         e.model = "models/orbs/orbblue.md3";
  41         precache_model(e.model);
  42         setmodel(e, e.model);
  43         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
  44         e.classname = "keepawayball";
  45         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
  46         e.takedamage = DAMAGE_YES;
  47         e.solid = SOLID_TRIGGER;
  48         e.movetype = MOVETYPE_BOUNCE;
  49         e.glow_color = autocvar_g_keepawayball_trail_color;
  50         e.glow_trail = TRUE;
  51         e.flags = FL_ITEM;
  52         e.reset = ka_Reset;
  53         e.touch = ka_TouchEvent;
  54         e.owner = world;
  55         ka_ball = e;
  56
  57         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
  58 }
  59
  60 void ka_RespawnBall() // runs whenever the ball needs to be relocated
  61 {
  62         if(gameover) { return; }
  63         vector oldballorigin = self.origin;
  64
  65         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  66         {
  67                 makevectors(self.angles);
  68                 self.movetype = MOVETYPE_BOUNCE;
  69                 self.velocity = '0 0 200';
  70                 self.angles = '0 0 0';
  71                 self.effects = autocvar_g_keepawayball_effects;
  72                 self.think = ka_RespawnBall;
  73                 self.nextthink = time + autocvar_g_keepawayball_respawntime;
  74
  75                 pointparticles(particleeffectnum("electro_combo"), oldballorigin, '0 0 0', 1);
  76                 pointparticles(particleeffectnum("electro_combo"), self.origin, '0 0 0', 1);
  77
  78                 WaypointSprite_Spawn("ka-ball", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attachedforcarrier, FALSE);
  79                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '0 1 1');
  80                 WaypointSprite_Ping(self.waypointsprite_attachedforcarrier);
  81
  82                 sound(self, CHAN_AUTO, "keepaway/respawn.wav", VOL_BASE, ATTN_NONE); // ATTN_NONE (it's a sound intended to be heard anywhere)
  83         }
  84         else
  85         {
  86                 ka_RespawnBall(); // finding a location failed, retry
  87         }
  88 }
  89
  90 void ka_TouchEvent() // runs any time that the ball comes in contact with something
  91 {
  92         if(gameover) { return; }
  93         if(!self) { return; }
  94         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  95         { // The ball fell off the map, respawn it since players can't get to it
  96                 ka_RespawnBall();
  97                 return;
  98         }
  99         if(other.deadflag != DEAD_NO) { return; }
 100         if(other.classname != "player")
 101         {  // The ball just touched an object, most likely the world
 102                 pointparticles(particleeffectnum("kaball_sparks"), self.origin, '0 0 0', 1);
 103                 sound(self, CHAN_AUTO, "keepaway/touch.wav", VOL_BASE, ATTN_NORM);
 104                 return;
 105         }
 106         else if(self.wait > time) { return; }
 107
 108         // attach the ball to the player
 109         self.owner = other;
 110         other.ballcarried = self;
 111         setattachment(self, other, "");
 112         setorigin(self, '0 0 0');
 113
 114         // make the ball invisible/unable to do anything/set up time scoring
 115         self.velocity = '0 0 0';
 116         self.movetype = MOVETYPE_NONE;
 117         self.effects |= EF_NODRAW;
 118         self.touch = SUB_Null;
 119         self.think = ka_TimeScoring;
 120         self.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 121         self.takedamage = DAMAGE_NO;
 122
 123         // apply effects to player
 124         other.glow_color = autocvar_g_keepawayball_trail_color;
 125         other.glow_trail = TRUE;
 126         other.effects |= autocvar_g_keepaway_ballcarrier_effects;
 127
 128         // messages and sounds
 129         Send_KillNotification(other.netname, "", "", KA_PICKUPBALL, MSG_KA);
 130         WriteByte(MSG_BROADCAST, SVC_CENTERPRINT);
 131         WriteString(MSG_BROADCAST, strcat("\n\n", other.netname, "^7 has picked up the ball!\n"));
 132         sound(self.owner, CHAN_AUTO, "keepaway/pickedup.wav", VOL_BASE, ATTN_NONE); // ATTN_NONE (it's a sound intended to be heard anywhere)
 133
 134         // scoring
 135         PlayerScore_Add(other, SP_KEEPAWAY_PICKUPS, 1);
 136
 137         // waypoints
 138         WaypointSprite_AttachCarrier("ka-ballcarrier", other);
 139         other.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 140         WaypointSprite_UpdateRule(other.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 141         WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 0 0');
 142         WaypointSprite_Ping(other.waypointsprite_attachedforcarrier);
 143         WaypointSprite_Kill(self.waypointsprite_attachedforcarrier);
 144 }
 145
 146 void ka_DropEvent(entity plyr) // runs any time that a player is supposed to lose the ball
 147 {
 148         entity ball;
 149         ball = plyr.ballcarried;
 150
 151         if(!ball) { return; }
 152
 153         // reset the ball
 154         setattachment(ball, world, "");
 155         ball.movetype = MOVETYPE_BOUNCE;
 156         ball.wait = time + 1;
 157         ball.touch = ka_TouchEvent;
 158         ball.think = ka_RespawnBall;
 159         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 160         ball.takedamage = DAMAGE_YES;
 161         ball.effects &~= EF_NODRAW;
 162         setorigin(ball, plyr.origin + '0 0 10');
 163         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 164         ball.owner.ballcarried = world; // I hope nothing checks to see if the world has the ball in the rest of my code :P
 165         ball.owner = world;
 166
 167         // reset the player effects
 168         plyr.glow_trail = FALSE;
 169         plyr.effects &~= autocvar_g_keepaway_ballcarrier_effects;
 170
 171         // messages and sounds
 172         Send_KillNotification(plyr.netname, "", "", KA_DROPBALL, MSG_KA);
 173         WriteByte(MSG_BROADCAST, SVC_CENTERPRINT);
 174         WriteString(MSG_BROADCAST, strcat("\n\n", plyr.netname, "^7 has dropped the ball!\n"));
 175         sound(other, CHAN_AUTO, "keepaway/dropped.wav", VOL_BASE, ATTN_NONE);   // ATTN_NONE (it's a sound intended to be heard anywhere)
 176
 177         // scoring
 178         // PlayerScore_Add(plyr, SP_KEEPAWAY_DROPS, 1); Not anymore, this is 100% the same as pickups and is useless.
 179
 180         // waypoints
 181         WaypointSprite_Spawn("ka-ball", 0, 0, ball, '0 0 64', world, ball.team, ball, waypointsprite_attachedforcarrier, FALSE);
 182         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 183         WaypointSprite_UpdateTeamRadar(ball.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '0 1 1');
 184         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 185         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 186 }
 187
 188 float ka_ballcarrier_waypointsprite_visible_for_player(entity e) // runs on waypoints which are attached to ballcarriers, updates once per frame
 189 {
 190         if(e.ballcarried)
 191                 if(other.classname == "spectator")
 192                         return FALSE; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
 193
 194         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
 195
 196         return TRUE;
 197 }
 198
 199 void ka_TimeScoring()
 200 {
 201         if(self.owner.ballcarried)
 202         { // add points for holding the ball after a certain amount of time
 203                 if(autocvar_g_keepaway_score_timepoints)
 204                         PlayerScore_Add(self.owner, SP_SCORE, autocvar_g_keepaway_score_timepoints);
 205
 206                 PlayerScore_Add(self.owner, SP_KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
 207                 self.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 208         }
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(ka_Scoring)
 212 {
 213         if((frag_attacker != frag_target) && (frag_attacker.classname == "player"))
 214         {
 215                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 216                         PlayerScore_Add(frag_attacker, SP_KEEPAWAY_CARRIERKILLS, 1);
 217                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 218                                 PlayerScore_Add(frag_attacker, SP_SCORE, autocvar_g_keepaway_score_bckill);
 219                 }
 220                 else if(!frag_attacker.ballcarried)
 221                         if(autocvar_g_keepaway_noncarrier_warn)
 222                                 centerprint_atprio(frag_attacker, (CENTERPRIO_SPAM + 5), "Killing people while you don't have the ball gives no points!");
 223
 224                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 225                         PlayerScore_Add(frag_attacker, SP_SCORE, autocvar_g_keepaway_score_killac);
 226         }
 227
 228         if(self.ballcarried) { ka_DropEvent(self); } // a player with the ball has died, drop it
 229         return 0;
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(ka_GiveFragsForKill)
 233 {
 234         frag_score = 0; // no frags counted in keepaway
 235         return 1; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(ka_PlayerPreThink)
 239 {
 240         // clear the item used for the ball in keepaway
 241         self.items &~= IT_KEY1;
 242
 243         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 244         if(self.ballcarried)
 245                 self.items |= IT_KEY1;
 246
 247         return 0;
 248 }
 249
 250 MUTATOR_HOOKFUNCTION(ka_PlayerUseKey)
 251 {
 252         if(MUTATOR_RETURNVALUE == 0)
 253         if(self.ballcarried)
 254         {
 255                 ka_DropEvent(self);
 256                 return 1;
 257         }
 258         return 0;
 259 }
 260
 261 MUTATOR_HOOKFUNCTION(ka_PlayerDamage) // for changing damage and force values that are applied to players in g_damage.qc
 262 {
 263         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 264         {
 265                 if(frag_target == frag_attacker) // damage done to yourself
 266                 {
 267                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 268                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 269                 }
 270                 else // damage done to noncarriers
 271                 {
 272                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 273                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 274                 }
 275         }
 276         else if not(frag_target.ballcarried) // if the target is a noncarrier
 277         {
 278                 if(frag_target == frag_attacker) // damage done to yourself
 279                 {
 280                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 281                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 282                 }
 283                 else // damage done to other noncarriers
 284                 {
 285                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 286                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 287                 }
 288         }
 289         return 0;
 290 }
 291
 292 MUTATOR_HOOKFUNCTION(ka_RemovePlayer)
 293 {
 294         if(self.ballcarried) { ka_DropEvent(self); } // a player with the ball has left the match, drop it
 295         return 0;
 296 }
 297
 298 MUTATOR_HOOKFUNCTION(ka_PlayerPowerups)
 299 {
 300         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 301         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 302
 303         self.effects &~= autocvar_g_keepaway_ballcarrier_effects;
 304
 305         if(self.ballcarried)
 306                 self.effects |= autocvar_g_keepaway_ballcarrier_effects;
 307
 308         return 0;
 309 }
 310
 311 MUTATOR_DEFINITION(gamemode_keepaway)
 312 {
 313         MUTATOR_HOOK(MakePlayerObserver, ka_RemovePlayer, CBC_ORDER_ANY);
 314         MUTATOR_HOOK(ClientDisconnect, ka_RemovePlayer, CBC_ORDER_ANY);
 315         MUTATOR_HOOK(PlayerDies, ka_Scoring, CBC_ORDER_ANY);
 316         MUTATOR_HOOK(GiveFragsForKill, ka_GiveFragsForKill, CBC_ORDER_ANY);
 317         MUTATOR_HOOK(PlayerPreThink, ka_PlayerPreThink, CBC_ORDER_ANY);
 318         MUTATOR_HOOK(PlayerDamage_Calculate, ka_PlayerDamage, CBC_ORDER_ANY);
 319         MUTATOR_HOOK(PlayerPowerups, ka_PlayerPowerups, CBC_ORDER_ANY);
 320         MUTATOR_HOOK(PlayerUseKey, ka_PlayerUseKey, CBC_ORDER_ANY);
 321
 322         MUTATOR_ONADD
 323         {
 324                 if(time > 1) // game loads at time 1
 325                         error("This is a game type and it cannot be added at runtime.");
 326                 g_keepaway = 1;
 327                 ka_Initialize();
 328         }
 329
 330         MUTATOR_ONREMOVE
 331         {
 332                 g_keepaway = 0;
 333                 error("This is a game type and it cannot be removed at runtime.");
 334         }
 335
 336         return 0;
 337 }