qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5
   6 #ifdef KH_PLAYER_USE_ATTACHMENT
   7 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   8 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
   9 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  10 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  11 string KH_PLAYER_ATTACHMENT_BONE = "";
  12 #else
  13 float KH_KEY_ZSHIFT = 22;
  14 float KH_KEY_XYDIST = 24;
  15 float KH_KEY_XYSPEED = 45;
  16 #endif
  17 float KH_KEY_WP_ZSHIFT = 20;
  18
  19 vector KH_KEY_MIN = '-10 -10 -46';
  20 vector KH_KEY_MAX = '10 10 3';
  21 float KH_KEY_BRIGHTNESS = 2;
  22
  23 string kh_Controller_Waitmsg;
  24 float kh_no_radar_circles;
  25
  26 // kh_state
  27 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  28 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  30 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  31 .float kh_state;
  32 .float siren_time;  //  time delay the siren
  33 //.float stuff_time;  //  time delay to stuffcmd a cvar
  34
  35 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  36 //test[0] = status of dropped keys, test[1 - 16] = player #
  37 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  38 //for(i = 0; i < maxplayers; ++i)
  39 //      test[i] = "0";
  40
  41 float kh_Team_ByID(float t)
  42 {
  43         if(t == 0) return COLOR_TEAM1;
  44         if(t == 1) return COLOR_TEAM2;
  45         if(t == 2) return COLOR_TEAM3;
  46         if(t == 3) return COLOR_TEAM4;
  47         return 0;
  48 }
  49
  50 entity kh_worldkeylist;
  51 .entity kh_worldkeynext;
  52 entity kh_controller;
  53 float kh_tracking_enabled;
  54 float kh_teams;
  55 float kh_interferemsg_time, kh_interferemsg_team;
  56 .entity kh_next, kh_prev; // linked list
  57 .float kh_droptime;
  58 .float kh_dropperteam;
  59 .entity kh_previous_owner;
  60 .float kh_previous_owner_playerid;
  61
  62 string kh_sound_capture = "kh/capture.wav";
  63 string kh_sound_destroy = "kh/destroy.wav";
  64 string kh_sound_drop = "kh/drop.wav";
  65 string kh_sound_collect = "kh/collect.wav";
  66 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  67
  68 float kh_key_dropped, kh_key_carried;
  69
  70 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  71 {
  72         if(e.classname != "player" || self.team != e.team)
  73                 if(!kh_tracking_enabled)
  74                         return FALSE;
  75
  76         return TRUE;
  77 }
  78
  79 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
  80 {
  81         if(!kh_tracking_enabled)
  82                 return FALSE;
  83         if(!self.owner)
  84                 return TRUE;
  85         if(!self.owner.owner)
  86                 return TRUE;
  87         return FALSE;  // draw only when key is not owned
  88 }
  89
  90 void kh_update_state()
  91 {
  92         entity player;
  93         entity key;
  94         float s;
  95         float f;
  96
  97         s = 0;
  98         FOR_EACH_KH_KEY(key)
  99         {
 100                 if(key.owner)
 101                         f = key.team;
 102                 else
 103                         f = 30;
 104                 s |= pow(32, key.count) * f;
 105         }
 106
 107         FOR_EACH_CLIENT(player)
 108         {
 109                 player.kh_state = s;
 110         }
 111
 112         FOR_EACH_KH_KEY(key)
 113         {
 114                 if(key.owner)
 115                         key.owner.kh_state |= pow(32, key.count) * 31;
 116         }
 117         //print(ftos((nextent(world)).kh_state), "\n");
 118 }
 119
 120
 121
 122
 123 var kh_Think_t kh_Controller_Thinkfunc;
 124 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
 125 {
 126         kh_Controller_Thinkfunc = func;
 127         kh_controller.cnt = ceil(t);
 128         if(kh_Controller_Waitmsg != "")
 129                 strunzone(kh_Controller_Waitmsg);
 130         if(msg == "")
 131                 kh_Controller_Waitmsg = "";
 132         else
 133                 kh_Controller_Waitmsg = strzone(msg);
 134         if(t == 0)
 135                 kh_controller.nextthink = time; // force
 136 }
 137
 138 void kh_Controller_Think()  // called a lot
 139 {
 140         entity e;
 141         if(intermission_running)
 142                 return;
 143         if(self.cnt > 0)
 144         {
 145                 if(kh_Controller_Waitmsg != "")
 146                 {
 147                         string s;
 148                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 149                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 150                         else
 151                                 s = kh_Controller_Waitmsg;
 152
 153                         //dprint(s, "\n");
 154
 155                         FOR_EACH_PLAYER(e)
 156                                 if(clienttype(e) == CLIENTTYPE_REAL)
 157                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 158                 }
 159                 self.cnt -= 1;
 160         }
 161         else if(self.cnt == 0)
 162         {
 163                 self.cnt -= 1;
 164                 kh_Controller_Thinkfunc();
 165         }
 166         self.nextthink = time + 1;
 167 }
 168
 169 // frags f: take from cvar * f
 170 // frags 0: no frags
 171 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 172 {
 173         string s;
 174         if(intermission_running)
 175                 return;
 176
 177         if(frags_player)
 178                 UpdateFrags(player, frags_player);
 179
 180         if(key && key.owner && frags_owner)
 181                 UpdateFrags(key.owner, frags_owner);
 182
 183         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 184                 return;
 185
 186         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 187
 188         if(key && key.owner)
 189                 s = strcat(s, ":", ftos(key.owner.playerid));
 190         else
 191                 s = strcat(s, ":0");
 192
 193         s = strcat(s, ":", ftos(frags_owner), ":");
 194
 195         if(key)
 196                 s = strcat(s, key.netname);
 197
 198         GameLogEcho(s);
 199 }
 200
 201 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 202 {
 203         if(e.tag_entity)
 204         {
 205                 makevectors(e.tag_entity.angles);
 206                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 207         }
 208         else
 209                 return e.origin;
 210 }
 211
 212 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 213 {
 214 #ifdef KH_PLAYER_USE_ATTACHMENT
 215         entity first;
 216         first = key.owner.kh_next;
 217         if(key == first)
 218         {
 219                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 220                 if(key.kh_next)
 221                 {
 222                         setattachment(key.kh_next, key, "");
 223                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 224                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 225                         key.kh_next.angles = '0 0 0';
 226                 }
 227                 else
 228                         setorigin(key, KH_PLAYER_ATTACHMENT);
 229                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 230         }
 231         else
 232         {
 233                 setattachment(key, key.kh_prev, "");
 234                 if(key.kh_next)
 235                         setattachment(key.kh_next, key, "");
 236                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 237                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 238                 key.angles = '0 0 0';
 239         }
 240 #else
 241         setattachment(key, key.owner, "");
 242         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 243         key.angles_y -= key.owner.angles_y;
 244 #endif
 245         key.flags = 0;
 246         key.solid = SOLID_NOT;
 247         key.movetype = MOVETYPE_NONE;
 248         key.team = key.owner.team;
 249         key.nextthink = time;
 250         key.damageforcescale = 0;
 251         key.takedamage = DAMAGE_NO;
 252         key.modelindex = kh_key_carried;
 253 }
 254
 255 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 256 {
 257 #ifdef KH_PLAYER_USE_ATTACHMENT
 258         entity first;
 259         first = key.owner.kh_next;
 260         if(key == first)
 261         {
 262                 if(key.kh_next)
 263                 {
 264                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 265                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 266                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 267                 }
 268         }
 269         else
 270         {
 271                 if(key.kh_next)
 272                         setattachment(key.kh_next, key.kh_prev, "");
 273                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 274         }
 275         // in any case:
 276         setattachment(key, world, "");
 277         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 278         key.angles = key.owner.angles;
 279 #else
 280         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 281         setattachment(key, world, "");
 282         key.angles_y += key.owner.angles_y;
 283 #endif
 284         key.flags = FL_ITEM;
 285         key.solid = SOLID_TRIGGER;
 286         key.movetype = MOVETYPE_TOSS;
 287         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 288         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 289         key.takedamage = DAMAGE_YES;
 290         // let key.team stay
 291         key.modelindex = kh_key_dropped;
 292         key.kh_previous_owner = key.owner;
 293         key.kh_previous_owner_playerid = key.owner.playerid;
 294 }
 295
 296 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 297 {
 298         entity k;
 299         float ownerteam0, ownerteam;
 300         if(key.owner == player)
 301                 return;
 302
 303         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 304
 305         if(key.owner)
 306         {
 307                 kh_Key_Detach(key);
 308
 309                 // remove from linked list
 310                 if(key.kh_next)
 311                         key.kh_next.kh_prev = key.kh_prev;
 312                 key.kh_prev.kh_next = key.kh_next;
 313                 key.kh_next = world;
 314                 key.kh_prev = world;
 315
 316                 if(key.owner.kh_next == world)
 317                 {
 318                         // No longer a key carrier
 319                         if(!kh_no_radar_circles)
 320                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 321                         WaypointSprite_DetachCarrier(key.owner);
 322                 }
 323         }
 324
 325         key.owner = player;
 326
 327         if(player)
 328         {
 329                 // insert into linked list
 330                 key.kh_next = player.kh_next;
 331                 key.kh_prev = player;
 332                 player.kh_next = key;
 333                 if(key.kh_next)
 334                         key.kh_next.kh_prev = key;
 335
 336                 float i;
 337                 i = test[key.owner.playerid];
 338                         if(key.netname == "^1red key")
 339                                 i += 1;
 340                         if(key.netname == "^4blue key")
 341                                 i += 2;
 342                         if(key.netname == "^3yellow key")
 343                                 i += 4;
 344                         if(key.netname == "^6pink key")
 345                                 i += 8;
 346                 test[key.owner.playerid] = i;
 347
 348                 kh_Key_Attach(key);
 349
 350                 if(key.kh_next == world)
 351                 {
 352                         // player is now a key carrier
 353                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 354                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 355                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 356                         if(player.team == COLOR_TEAM1)
 357                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 358                         else if(player.team == COLOR_TEAM2)
 359                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 360                         else if(player.team == COLOR_TEAM3)
 361                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 362                         else if(player.team == COLOR_TEAM4)
 363                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 364                         if(!kh_no_radar_circles)
 365                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 366                 }
 367         }
 368
 369         // moved that here, also update if there's no player
 370         kh_update_state();
 371
 372         key.pusher = world;
 373
 374         ownerteam = kh_Key_AllOwnedByWhichTeam();
 375         if(ownerteam != ownerteam0)
 376         {
 377                 if(ownerteam != -1)
 378                 {
 379                         kh_interferemsg_time = time + 0.2;
 380                         kh_interferemsg_team = player.team;
 381
 382                         // audit all key carrier sprites, update them to RUN HERE
 383                         FOR_EACH_KH_KEY(k)
 384                         {
 385                                 if(k.owner)
 386                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 387                         }
 388                 }
 389                 else
 390                 {
 391                         kh_interferemsg_time = 0;
 392
 393                         // audit all key carrier sprites, update them to RUN HERE
 394                         FOR_EACH_KH_KEY(k)
 395                         {
 396                                 if(k.owner)
 397                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 398                         }
 399                 }
 400         }
 401 }
 402
 403 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 404 {
 405         if(self.owner)
 406                 return;
 407         if(vlen(force) <= 0)
 408                 return;
 409         if(time > self.pushltime)
 410                 if(attacker.classname == "player")
 411                         self.team = attacker.team;
 412 }
 413
 414 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 415 {
 416         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTN_NORM);
 417
 418         if(key.kh_dropperteam != player.team)
 419         {
 420                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 421                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 422         }
 423         key.kh_dropperteam = 0;
 424         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 425
 426         kh_Key_AssignTo(key, player); // this also updates .kh_state
 427 }
 428
 429 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 430 {
 431         if(intermission_running)
 432                 return;
 433
 434         if(self.owner) // already carried
 435                 return;
 436         if(other.classname != "player")
 437                 return;
 438         if(other.deadflag != DEAD_NO)
 439                 return;
 440         if(other == self.enemy)
 441                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 442                         return;  // you just dropped it!
 443         kh_Key_Collect(self, other);
 444 }
 445
 446 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 447 {
 448         entity o;
 449         o = key.owner;
 450         kh_Key_AssignTo(key, world);
 451         if(o) // it was attached
 452                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 453         else // it was dropped
 454                 WaypointSprite_DetachCarrier(key);
 455
 456         // remove key from key list
 457         if (kh_worldkeylist == key)
 458                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 459         else
 460         {
 461                 o = kh_worldkeylist;
 462                 while (o)
 463                 {
 464                         if (o.kh_worldkeynext == key)
 465                         {
 466                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 467                                 break;
 468                         }
 469                         o = o.kh_worldkeynext;
 470                 }
 471         }
 472
 473         remove(key);
 474
 475         kh_update_state();
 476 }
 477
 478 void kh_FinishRound()  // runs when a team captures the keys
 479 {
 480         // prepare next round
 481         kh_interferemsg_time = 0;
 482         entity key;
 483
 484         kh_no_radar_circles = TRUE;
 485         FOR_EACH_KH_KEY(key)
 486                 kh_Key_Remove(key);
 487         kh_no_radar_circles = FALSE;
 488
 489         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", kh_StartRound);
 490 }
 491
 492 void kh_WinnerTeam(float teem)  // runs when a team wins
 493 {
 494         // all key carriers get some points
 495         vector firstorigin, lastorigin, midpoint;
 496         float first;
 497         entity key;
 498         float score;
 499         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 500         DistributeEvenly_Init(score, kh_teams);
 501         // twice the score for 3 team games, three times the score for 4 team games!
 502         // note: for a win by destroying the key, this should NOT be applied
 503         FOR_EACH_KH_KEY(key)
 504         {
 505                 float f;
 506                 f = DistributeEvenly_Get(1);
 507                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 508                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 509         }
 510
 511         first = TRUE;
 512         FOR_EACH_KH_KEY(key)
 513                 if(key.owner.kh_next == key)
 514                 {
 515                         if(!first)
 516                                 bprint("^7, ");
 517                         bprint(key.owner.netname);
 518                         first = FALSE;
 519                 }
 520         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 521
 522         first = TRUE;
 523         midpoint = '0 0 0';
 524         FOR_EACH_KH_KEY(key)
 525         {
 526                 vector thisorigin;
 527
 528                 thisorigin = kh_AttachedOrigin(key);
 529                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 530                 midpoint += thisorigin;
 531
 532                 if(!first)
 533                         te_lightning2(world, lastorigin, thisorigin);
 534                 lastorigin = thisorigin;
 535                 if(first)
 536                         firstorigin = thisorigin;
 537                 first = FALSE;
 538         }
 539         if(kh_teams > 2)
 540         {
 541                 te_lightning2(world, lastorigin, firstorigin);
 542         }
 543         midpoint = midpoint * (1 / kh_teams);
 544         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 545
 546         play2all(kh_sound_capture);
 547         kh_FinishRound();
 548 }
 549
 550 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 551 {
 552         entity player, key, attacker;
 553         float players;
 554         float keys;
 555         float f;
 556
 557         attacker = world;
 558         if(lostkey.pusher)
 559                 if(lostkey.pusher.team != teem)
 560                         if(lostkey.pusher.classname == "player")
 561                                 attacker = lostkey.pusher;
 562
 563         players = keys = 0;
 564
 565         if(attacker)
 566         {
 567                 if(lostkey.kh_previous_owner)
 568                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 569                         // don't actually GIVE him the -nn points, just log
 570                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 571                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 572                 centerprint(attacker, "Your push is the best!");
 573                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 574         }
 575         else
 576         {
 577                 float of, fragsleft, i, j, thisteam;
 578                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 579
 580                 FOR_EACH_PLAYER(player)
 581                         if(player.team != teem)
 582                                 ++players;
 583
 584                 FOR_EACH_KH_KEY(key)
 585                         if(key.owner && key.team != teem)
 586                                 ++keys;
 587
 588                 if(lostkey.kh_previous_owner)
 589                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 590                         // don't actually GIVE him the -nn points, just log
 591
 592                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 593                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 594
 595                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 596
 597                 FOR_EACH_KH_KEY(key)
 598                         if(key.owner && key.team != teem)
 599                         {
 600                                 f = DistributeEvenly_Get(of);
 601                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 602                         }
 603
 604                 fragsleft = DistributeEvenly_Get(players);
 605
 606                 // Now distribute these among all other teams...
 607                 j = kh_teams - 1;
 608                 for(i = 0; i < kh_teams; ++i)
 609                 {
 610                         thisteam = kh_Team_ByID(i);
 611                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 612                                 continue;
 613
 614                         players = 0;
 615                         FOR_EACH_PLAYER(player)
 616                                 if(player.team == thisteam)
 617                                         ++players;
 618
 619                         DistributeEvenly_Init(fragsleft, j);
 620                         fragsleft = DistributeEvenly_Get(j - 1);
 621                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 622
 623                         FOR_EACH_PLAYER(player)
 624                                 if(player.team == thisteam)
 625                                 {
 626                                         f = DistributeEvenly_Get(1);
 627                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 628                                 }
 629
 630                         --j;
 631                 }
 632
 633                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 634         }
 635         play2all(kh_sound_destroy);
 636         te_tarexplosion(lostkey.origin);
 637
 638         kh_FinishRound();
 639 }
 640
 641 void kh_Key_Think()  // runs all the time
 642 {
 643         entity head;
 644         //entity player;  // needed by FOR_EACH_PLAYER
 645
 646         if(intermission_running)
 647                 return;
 648
 649         if(self.owner)
 650         {
 651 #ifndef KH_PLAYER_USE_ATTACHMENT
 652                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 653                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 654 #endif
 655         }
 656
 657         // if in nodrop or time over, end the round
 658         if(!self.owner)
 659                 if(time > self.pain_finished)
 660                         kh_LoserTeam(self.team, self);
 661
 662         if(self.owner)
 663         if(kh_Key_AllOwnedByWhichTeam() != -1)
 664         {
 665                 if(self.siren_time < time)
 666                 {
 667                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 668                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 669                 }
 670
 671                 entity key;
 672                 vector p;
 673                 p = self.owner.origin;
 674                 FOR_EACH_KH_KEY(key)
 675                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 676                                 goto not_winning;
 677                 kh_WinnerTeam(self.team);
 678 :not_winning
 679         }
 680
 681         if(kh_interferemsg_time && time > kh_interferemsg_time)
 682         {
 683                 kh_interferemsg_time = 0;
 684                 FOR_EACH_PLAYER(head)
 685                 {
 686                         if(head.team == kh_interferemsg_team)
 687                                 if(head.kh_next)
 688                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!");
 689                                 else
 690                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!");
 691                         else
 692                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!"));
 693                 }
 694         }
 695
 696         self.nextthink = time + 0.05;
 697 }
 698
 699 void key_reset()
 700 {
 701         kh_Key_AssignTo(self, world);
 702         kh_Key_Remove(self);
 703 }
 704
 705 string STR_ITEM_KH_KEY = "item_kh_key";
 706 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 707 {
 708         entity key;
 709         key = spawn();
 710         key.count = i;
 711         key.classname = STR_ITEM_KH_KEY;
 712         key.touch = kh_Key_Touch;
 713         key.think = kh_Key_Think;
 714         key.nextthink = time;
 715         key.items = IT_KEY1 | IT_KEY2;
 716         key.cnt = angle;
 717         key.angles = '0 360 0' * random();
 718         key.event_damage = kh_Key_Damage;
 719         key.takedamage = DAMAGE_YES;
 720         key.modelindex = kh_key_dropped;
 721         key.model = "key";
 722         key.kh_dropperteam = 0;
 723         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 724         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 725         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 726         key.reset = key_reset;
 727
 728         switch(initial_owner.team)
 729         {
 730                 case COLOR_TEAM1:
 731                         key.netname = "^1red key";
 732                         break;
 733                 case COLOR_TEAM2:
 734                         key.netname = "^4blue key";
 735                         break;
 736                 case COLOR_TEAM3:
 737                         key.netname = "^3yellow key";
 738                         break;
 739                 case COLOR_TEAM4:
 740                         key.netname = "^6pink key";
 741                         break;
 742                 default:
 743                         key.netname = "NETGIER key";
 744                         break;
 745         }
 746
 747         // link into key list
 748         key.kh_worldkeynext = kh_worldkeylist;
 749         kh_worldkeylist = key;
 750
 751         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 752
 753         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAG, '0 1 1');
 754         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 755
 756         kh_Key_AssignTo(key, initial_owner);
 757 }
 758
 759 // -1 when no team completely owns all keys yet
 760 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 761 {
 762         entity key;
 763         float teem;
 764         float keys;
 765
 766         teem = -1;
 767         keys = kh_teams;
 768         FOR_EACH_KH_KEY(key)
 769         {
 770                 if(!key.owner)
 771                         return -1;
 772                 if(teem == -1)
 773                         teem = key.team;
 774                 else if(teem != key.team)
 775                         return -1;
 776                 --keys;
 777         }
 778         if(keys != 0)
 779                 return -1;
 780         return teem;
 781 }
 782
 783 void kh_Key_DropOne(entity key)
 784 {
 785         // prevent collecting this one for some time
 786         entity player;
 787         player = key.owner;
 788
 789         key.kh_droptime = time;
 790         key.enemy = player;
 791
 792         kh_Scores_Event(player, key, "dropkey", 0, 0);
 793         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 794         bprint(player.netname, "^7 dropped the ", key.netname, "\n");
 795         kh_Key_AssignTo(key, world);
 796         makevectors(player.v_angle);
 797         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, FALSE);
 798         key.pusher = world;
 799         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 800         key.kh_dropperteam = key.team;
 801
 802         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 803 }
 804
 805 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 806 {
 807         entity key;
 808         entity mypusher;
 809         if(player.kh_next)
 810         {
 811                 mypusher = world;
 812                 if(player.pusher)
 813                         if(time < player.pushltime)
 814                                 mypusher = player.pusher;
 815                 while((key = player.kh_next))
 816                 {
 817                         kh_Scores_Event(player, key, "losekey", 0, 0);
 818                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 819                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 820                         kh_Key_AssignTo(key, world);
 821                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 822                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, FALSE);
 823                         key.pusher = mypusher;
 824                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 825                         if(suicide)
 826                                 key.kh_dropperteam = player.team;
 827                 }
 828                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 829         }
 830 }
 831
 832 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 833 {
 834         float i, players, teem;
 835         entity player;
 836         string result;
 837         result = "";
 838
 839         // find a random player per team
 840         for(i = 0; i < kh_teams; ++i)
 841         {
 842                 teem = kh_Team_ByID(i);
 843                 players = 0;
 844                 FOR_EACH_PLAYER(player)
 845                         if(player.deadflag == DEAD_NO)
 846                                 if(!player.BUTTON_CHAT)
 847                                         if(player.team == teem)
 848                                                 ++players;
 849                 if(players == 0)
 850                 {
 851                         if(result != "")
 852                                 result = strcat(result, ", ");
 853                         result = strcat(result, ColoredTeamName(teem));
 854                 }
 855         }
 856         return result;
 857 }
 858
 859 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 860 {
 861         string teams_missing;
 862
 863         if(time < game_starttime)
 864         {
 865                 kh_Controller_SetThink(game_starttime - time + 0.1, "", kh_WaitForPlayers);
 866                 return;
 867         }
 868
 869         teams_missing = kh_CheckEnoughPlayers();
 870         if(teams_missing == "")
 871                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", kh_StartRound);
 872         else
 873                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 874 }
 875
 876 void kh_EnableTrackingDevice()  // runs after each round
 877 {
 878         entity player;
 879
 880         FOR_EACH_PLAYER(player)
 881                 if(clienttype(player) == CLIENTTYPE_REAL)
 882                         centerprint_expire(player, CENTERPRIO_SPAM);
 883
 884         kh_tracking_enabled = TRUE;
 885 }
 886
 887 void kh_StartRound()  // runs at the start of each round
 888 {
 889         string teams_missing;
 890         float i, players, teem;
 891         entity player;
 892
 893         if(time < game_starttime)
 894         {
 895                 kh_Controller_SetThink(game_starttime - time + 0.1, "", kh_WaitForPlayers);
 896                 return;
 897         }
 898
 899         teams_missing = kh_CheckEnoughPlayers();
 900         if(teams_missing != "")
 901         {
 902                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 903                 return;
 904         }
 905
 906         FOR_EACH_PLAYER(player)
 907                 if(clienttype(player) == CLIENTTYPE_REAL)
 908                         centerprint_expire(player, CENTERPRIO_SPAM);
 909
 910         for(i = 0; i < kh_teams; ++i)
 911         {
 912                 teem = kh_Team_ByID(i);
 913                 players = 0;
 914                 entity my_player;
 915                 FOR_EACH_PLAYER(player)
 916                         if(player.deadflag == DEAD_NO)
 917                                 if(!player.BUTTON_CHAT)
 918                                         if(player.team == teem)
 919                                         {
 920                                                 ++players;
 921                                                 if(random() * players <= 1)
 922                                                         my_player = player;
 923                                         }
 924                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 925         }
 926
 927         kh_tracking_enabled = FALSE;
 928         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, "Scanning frequency range...", kh_EnableTrackingDevice);
 929 }
 930
 931 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 932 {
 933         if(attacker == targ)
 934                 return f;
 935
 936         if(targ.kh_next)
 937         {
 938                 if(attacker.team == targ.team)
 939                 {
 940                         entity k;
 941                         float nk;
 942                         nk = 0;
 943                         for(k = targ.kh_next; k != world; k = k.kh_next)
 944                                 ++nk;
 945                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 946                 }
 947                 else
 948                 {
 949                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 950                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 951                         // the frag gets added later
 952                 }
 953         }
 954
 955         return f;
 956 }
 957
 958 void kh_Initialize()  // sets up th KH environment
 959 {
 960         precache_sound(kh_sound_capture);
 961         precache_sound(kh_sound_destroy);
 962         precache_sound(kh_sound_drop);
 963         precache_sound(kh_sound_collect);
 964         precache_sound(kh_sound_alarm);  // the new siren
 965
 966 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 967         precache_model("models/keyhunt/key-carried.md3");
 968 #endif
 969         precache_model("models/keyhunt/key.md3");
 970
 971         // setup variables
 972         kh_teams = autocvar_g_keyhunt_teams_override;
 973         if(kh_teams < 2)
 974                 kh_teams = autocvar_g_keyhunt_teams;
 975         kh_teams = bound(2, kh_teams, 4);
 976
 977         // make a KH entity for controlling the game
 978         kh_controller = spawn();
 979         kh_controller.think = kh_Controller_Think;
 980         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 981
 982         setmodel(kh_controller, "models/keyhunt/key.md3");
 983         kh_key_dropped = kh_controller.modelindex;
 984         /*
 985         dprint(vtos(kh_controller.mins));
 986         dprint(vtos(kh_controller.maxs));
 987         dprint("\n");
 988         */
 989 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 990         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 991         kh_key_carried = kh_controller.modelindex;
 992 #else
 993         kh_key_carried = kh_key_dropped;
 994 #endif
 995
 996         kh_controller.model = "";
 997         kh_controller.modelindex = 0;
 998
 999         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1000
1001         ScoreRules_kh(kh_teams);
1002 }
1003
1004 void kh_finalize()
1005 {
1006         // to be called before intermission
1007         kh_FinishRound();
1008         remove(kh_controller);
1009         kh_controller = world;
1010 }
1011
1012 // register this as a mutator
1013
1014 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1015 {
1016         kh_Key_DropAll(self, TRUE);
1017         return 0;
1018 }
1019
1020 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1021 {
1022         if(self == other)
1023                 kh_Key_DropAll(self, TRUE);
1024         else if(other.classname == "player")
1025                 kh_Key_DropAll(self, FALSE);
1026         else
1027                 kh_Key_DropAll(self, TRUE);
1028         return 0;
1029 }
1030
1031 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1032 {
1033         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1034         return 0;
1035 }
1036
1037 MUTATOR_HOOKFUNCTION(kh_finalize)
1038 {
1039         kh_finalize();
1040         return 0;
1041 }
1042
1043 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1044 {
1045         ret_float = kh_teams;
1046         return 0;
1047 }
1048
1049 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1050 {
1051         self.kh_state = other.kh_state;
1052         return 0;
1053 }
1054
1055 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1056 {
1057         if(MUTATOR_RETURNVALUE == 0)
1058         {
1059                 entity k;
1060                 k = self.kh_next;
1061                 if(k)
1062                 {
1063                         kh_Key_DropOne(k);
1064                         return 1;
1065                 }
1066         }
1067         return 0;
1068 }
1069
1070 MUTATOR_DEFINITION(gamemode_keyhunt)
1071 {
1072         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1073         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1074         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1075         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1076         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1077         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1078         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1079         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1080
1081         MUTATOR_ONADD
1082         {
1083                 if(time > 1) // game loads at time 1
1084                         error("This is a game type and it cannot be added at runtime.");
1085                 g_keyhunt = 1;
1086                 kh_Initialize();
1087         }
1088
1089         MUTATOR_ONREMOVE
1090         {
1091                 g_keyhunt = 0;
1092                 error("This is a game type and it cannot be removed at runtime.");
1093         }
1094
1095         return 0;
1096 }