qcsrc/server/mutators/mutator_multijump.qc

   1 #ifdef SVQC
   2         #include "../_all.qh"
   3         #include "mutator.qh"
   4         #include "../antilag.qh"
   5 #endif
   6
   7 .float multijump_count;
   8 .float multijump_ready;
   9
  10 #ifdef CSQC
  11
  12 #define PHYS_MULTIJUMP                          getstati(STAT_MULTIJUMP)
  13 #define PHYS_MULTIJUMP_SPEED            getstatf(STAT_MULTIJUMP_SPEED)
  14 #define PHYS_MULTIJUMP_ADD                      getstati(STAT_MULTIJUMP_ADD)
  15
  16 #elif defined(SVQC)
  17
  18 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  19 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  20 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  21
  22
  23 .float stat_multijump;
  24 .float stat_multijump_speed;
  25 .float stat_multijump_add;
  26
  27 void multijump_UpdateStats()
  28 {
  29         self.stat_multijump = PHYS_MULTIJUMP;
  30         self.stat_multijump_speed = PHYS_MULTIJUMP_SPEED;
  31         self.stat_multijump_add = PHYS_MULTIJUMP_ADD;
  32 }
  33
  34 void multijump_AddStats()
  35 {
  36         addstat(STAT_MULTIJUMP, AS_INT, stat_multijump);
  37         addstat(STAT_MULTIJUMP_SPEED, AS_FLOAT, stat_multijump_speed);
  38         addstat(STAT_MULTIJUMP_ADD, AS_INT, stat_multijump_add);
  39 }
  40
  41 #endif
  42
  43 void PM_multijump()
  44 {
  45         if(!PHYS_MULTIJUMP) { return; }
  46
  47         if(IS_ONGROUND(self))
  48         {
  49                 self.multijump_count = 0;
  50         }
  51 }
  52
  53 float PM_multijump_checkjump()
  54 {
  55         if(!PHYS_MULTIJUMP) { return false; }
  56
  57         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self)) // jump button pressed this frame and we are in midair
  58                 self.multijump_ready = true;  // this is necessary to check that we released the jump button and pressed it again
  59         else
  60                 self.multijump_ready = false;
  61
  62         if(!player_multijump && self.multijump_ready && (self.multijump_count < PHYS_MULTIJUMP || PHYS_MULTIJUMP == -1) && self.velocity_z > PHYS_MULTIJUMP_SPEED)
  63         {
  64                 if (PHYS_MULTIJUMP)
  65                 {
  66                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  67                         {
  68                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
  69                                 {
  70                                         player_multijump = true;
  71                                         self.velocity_z = 0;
  72                                 }
  73                         }
  74                         else
  75                                 player_multijump = true;
  76
  77                         if(player_multijump)
  78                         {
  79                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
  80                                 {
  81                                         float curspeed;
  82                                         vector wishvel, wishdir;
  83
  84 #ifdef SVQC
  85                                         curspeed = max(
  86                                                 vlen(vec2(self.velocity)), // current xy speed
  87                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  88                                         );
  89 #elif defined(CSQC)
  90                                         curspeed = vlen(vec2(self.velocity));
  91 #endif
  92
  93                                         makevectors(self.v_angle_y * '0 1 0');
  94                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
  95                                         wishdir = normalize(wishvel);
  96
  97                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  98                                         self.velocity_y = wishdir_y * curspeed;
  99                                         // keep velocity_z unchanged!
 100                                 }
 101                                 self.multijump_count += 1;
 102                         }
 103                 }
 104                 self.multijump_ready = false; // require releasing and pressing the jump button again for the next jump
 105         }
 106
 107         return false;
 108 }
 109
 110 #ifdef SVQC
 111 MUTATOR_HOOKFUNCTION(multijump_PlayerPhysics)
 112 {
 113         multijump_UpdateStats();
 114         PM_multijump();
 115
 116         return false;
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(multijump_PlayerJump)
 120 {
 121         return PM_multijump_checkjump();
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsString)
 125 {
 126         ret_string = strcat(ret_string, ":multijump");
 127         return false;
 128 }
 129
 130 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsPrettyString)
 131 {
 132         ret_string = strcat(ret_string, ", Multi jump");
 133         return false;
 134 }
 135
 136 MUTATOR_DEFINITION(mutator_multijump)
 137 {
 138         MUTATOR_HOOK(PlayerPhysics, multijump_PlayerPhysics, CBC_ORDER_ANY);
 139         MUTATOR_HOOK(PlayerJump, multijump_PlayerJump, CBC_ORDER_ANY);
 140         MUTATOR_HOOK(BuildMutatorsString, multijump_BuildMutatorsString, CBC_ORDER_ANY);
 141         MUTATOR_HOOK(BuildMutatorsPrettyString, multijump_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 142
 143         MUTATOR_ONADD
 144         {
 145                 multijump_AddStats();
 146         }
 147
 148         return false;
 149 }
 150 #endif