qcsrc/server/mutators/mutator_multijump.qc

   1 .float multijump_count;
   2 .float multijump_ready;
   3
   4 #ifdef CSQC
   5
   6 #define PHYS_MULTIJUMP                          getstati(STAT_MULTIJUMP)
   7 #define PHYS_MULTIJUMP_SPEED            getstatf(STAT_MULTIJUMP_SPEED)
   8 #define PHYS_MULTIJUMP_ADD                      getstati(STAT_MULTIJUMP_ADD)
   9
  10 #elif defined(SVQC)
  11
  12 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  13 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  14 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  15
  16
  17 .float stat_multijump;
  18 .float stat_multijump_speed;
  19 .float stat_multijump_add;
  20
  21 void multijump_UpdateStats()
  22 {
  23         self.stat_multijump = PHYS_MULTIJUMP;
  24         self.stat_multijump_speed = PHYS_MULTIJUMP_SPEED;
  25         self.stat_multijump_add = PHYS_MULTIJUMP_ADD;
  26 }
  27
  28 void multijump_AddStats()
  29 {
  30         addstat(STAT_MULTIJUMP, AS_INT, stat_multijump);
  31         addstat(STAT_MULTIJUMP_SPEED, AS_FLOAT, stat_multijump_speed);
  32         addstat(STAT_MULTIJUMP_ADD, AS_INT, stat_multijump_add);
  33 }
  34
  35 #endif
  36
  37 void PM_multijump()
  38 {
  39         if(!PHYS_MULTIJUMP) { return; }
  40
  41         if(IS_ONGROUND(self))
  42         {
  43                 self.multijump_count = 0;
  44         }
  45 }
  46
  47 float PM_multijump_checkjump()
  48 {
  49         if(!PHYS_MULTIJUMP) { return FALSE; }
  50
  51         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self)) // jump button pressed this frame and we are in midair
  52                 self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  53         else
  54                 self.multijump_ready = FALSE;
  55
  56         if(!player_multijump && self.multijump_ready && (self.multijump_count < PHYS_MULTIJUMP || PHYS_MULTIJUMP == -1) && self.velocity_z > PHYS_MULTIJUMP_SPEED)
  57         {
  58                 if (PHYS_MULTIJUMP)
  59                 {
  60                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  61                         {
  62                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
  63                                 {
  64                                         player_multijump = TRUE;
  65                                         self.velocity_z = 0;
  66                                 }
  67                         }
  68                         else
  69                                 player_multijump = TRUE;
  70
  71                         if(player_multijump)
  72                         {
  73                                 if(PHYS_INPUT_MOVEVALUES(self)_x != 0 || PHYS_INPUT_MOVEVALUES(self)_y != 0) // don't remove all speed if player isnt pressing any movement keys
  74                                 {
  75                                         float curspeed;
  76                                         vector wishvel, wishdir;
  77
  78                                         curspeed = max(
  79                                                 vlen(vec2(self.velocity)) // current xy speed
  80 #ifdef SVQC
  81                                                 ,vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  82 #endif
  83                                         );
  84                                         makevectors(PHYS_INPUT_ANGLES(self)_y * '0 1 0');
  85                                         wishvel = v_forward * PHYS_INPUT_MOVEVALUES(self)_x + v_right * PHYS_INPUT_MOVEVALUES(self)_y;
  86                                         wishdir = normalize(wishvel);
  87
  88                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  89                                         self.velocity_y = wishdir_y * curspeed;
  90                                         // keep velocity_z unchanged!
  91                                 }
  92                                 self.multijump_count += 1;
  93                         }
  94                 }
  95                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
  96         }
  97
  98         return FALSE;
  99 }
 100
 101 #ifdef SVQC
 102 MUTATOR_HOOKFUNCTION(multijump_PlayerPhysics)
 103 {
 104         multijump_UpdateStats();
 105         PM_multijump();
 106
 107         return FALSE;
 108 }
 109
 110 MUTATOR_HOOKFUNCTION(multijump_PlayerJump)
 111 {
 112         return PM_multijump_checkjump();
 113 }
 114
 115 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsString)
 116 {
 117         ret_string = strcat(ret_string, ":multijump");
 118         return FALSE;
 119 }
 120
 121 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsPrettyString)
 122 {
 123         ret_string = strcat(ret_string, ", Multi jump");
 124         return FALSE;
 125 }
 126
 127 MUTATOR_DEFINITION(mutator_multijump)
 128 {
 129         MUTATOR_HOOK(PlayerPhysics, multijump_PlayerPhysics, CBC_ORDER_ANY);
 130         MUTATOR_HOOK(PlayerJump, multijump_PlayerJump, CBC_ORDER_ANY);
 131         MUTATOR_HOOK(BuildMutatorsString, multijump_BuildMutatorsString, CBC_ORDER_ANY);
 132         MUTATOR_HOOK(BuildMutatorsPrettyString, multijump_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 133
 134         MUTATOR_ONADD
 135         {
 136                 multijump_AddStats();
 137         }
 138
 139         return FALSE;
 140 }
 141 #endif