qcsrc/server/mutators/mutator_nades.qc

   1 #include "mutator_nades.qh"
   2
   3 #include "mutator.qh"
   4
   5 #include "gamemode_keyhunt.qh"
   6 #include "gamemode_freezetag.qh"
   7 #include "../../common/nades/all.qh"
   8 #include "../../common/gamemodes/all.qh"
   9 #include "../../common/monsters/spawn.qh"
  10 #include "../../common/monsters/sv_monsters.qh"
  11 #include "../g_subs.qh"
  12
  13 .float nade_time_primed;
  14
  15 .entity nade_spawnloc;
  16
  17 void nade_timer_think()
  18 {SELFPARAM();
  19         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
  20         self.nextthink = time;
  21         if(!self.owner || wasfreed(self.owner))
  22                 remove(self);
  23 }
  24
  25 void nade_burn_spawn(entity _nade)
  26 {
  27         CSQCProjectile(_nade, true, Nades[_nade.nade_type].m_projectile[true], true);
  28 }
  29
  30 void nade_spawn(entity _nade)
  31 {
  32         entity timer = spawn();
  33         setmodel(timer, MDL_NADE_TIMER);
  34         setattachment(timer, _nade, "");
  35         timer.classname = "nade_timer";
  36         timer.colormap = _nade.colormap;
  37         timer.glowmod = _nade.glowmod;
  38         timer.think = nade_timer_think;
  39         timer.nextthink = time;
  40         timer.wait = _nade.wait;
  41         timer.owner = _nade;
  42         timer.skin = 10;
  43
  44         _nade.effects |= EF_LOWPRECISION;
  45
  46         CSQCProjectile(_nade, true, Nades[_nade.nade_type].m_projectile[false], true);
  47 }
  48
  49 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  50 {SELFPARAM();
  51         entity e;
  52         float d;
  53         vector p;
  54
  55         if ( damage < 0 )
  56                 return;
  57
  58         RandomSelection_Init();
  59         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
  60                 if(e.takedamage == DAMAGE_AIM)
  61                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  62                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  63                 if(!e.frozen)
  64                 {
  65                         p = e.origin;
  66                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
  67                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
  68                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
  69                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  70                         if(d < dist)
  71                         {
  72                                 e.fireball_impactvec = p;
  73                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  74                         }
  75                 }
  76         if(RandomSelection_chosen_ent)
  77         {
  78                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  79                 d = damage + (edgedamage - damage) * (d / dist);
  80                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  81                 //trailparticles(self, particleeffectnum(EFFECT_FIREBALL_LASER), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  82                 Send_Effect(EFFECT_FIREBALL_LASER, self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  83         }
  84 }
  85
  86
  87 void napalm_ball_think()
  88 {SELFPARAM();
  89         if(round_handler_IsActive())
  90         if(!round_handler_IsRoundStarted())
  91         {
  92                 remove(self);
  93                 return;
  94         }
  95
  96         if(time > self.pushltime)
  97         {
  98                 remove(self);
  99                 return;
 100         }
 101
 102         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 103         if(pointcontents(midpoint) == CONTENT_WATER)
 104         {
 105                 self.velocity = self.velocity * 0.5;
 106
 107                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 108                         { self.velocity_z = 200; }
 109         }
 110
 111         self.angles = vectoangles(self.velocity);
 112
 113         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 114                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 115
 116         self.nextthink = time + 0.1;
 117 }
 118
 119
 120 void nade_napalm_ball()
 121 {SELFPARAM();
 122         entity proj;
 123         vector kick;
 124
 125         spamsound(self, CH_SHOTS, SND(FIREBALL_FIRE), VOL_BASE, ATTEN_NORM);
 126
 127         proj = spawn ();
 128         proj.owner = self.owner;
 129         proj.realowner = self.realowner;
 130         proj.team = self.owner.team;
 131         proj.classname = "grenade";
 132         proj.bot_dodge = true;
 133         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 134         proj.movetype = MOVETYPE_BOUNCE;
 135         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 136         PROJECTILE_MAKETRIGGER(proj);
 137         setmodel(proj, MDL_Null);
 138         proj.scale = 1;//0.5;
 139         setsize(proj, '-4 -4 -4', '4 4 4');
 140         setorigin(proj, self.origin);
 141         proj.think = napalm_ball_think;
 142         proj.nextthink = time;
 143         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 144         proj.effects = EF_LOWPRECISION | EF_FLAME;
 145
 146         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 147         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 148         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 149         proj.velocity = kick;
 150
 151         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 152
 153         proj.angles = vectoangles(proj.velocity);
 154         proj.flags = FL_PROJECTILE;
 155         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 156
 157         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 158 }
 159
 160
 161 void napalm_fountain_think()
 162 {SELFPARAM();
 163
 164         if(round_handler_IsActive())
 165         if(!round_handler_IsRoundStarted())
 166         {
 167                 remove(self);
 168                 return;
 169         }
 170
 171         if(time >= self.ltime)
 172         {
 173                 remove(self);
 174                 return;
 175         }
 176
 177         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 178         if(pointcontents(midpoint) == CONTENT_WATER)
 179         {
 180                 self.velocity = self.velocity * 0.5;
 181
 182                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 183                         { self.velocity_z = 200; }
 184
 185                 UpdateCSQCProjectile(self);
 186         }
 187
 188         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 189                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 190
 191         self.nextthink = time + 0.1;
 192         if(time >= self.nade_special_time)
 193         {
 194                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 195                 nade_napalm_ball();
 196         }
 197 }
 198
 199 void nade_napalm_boom()
 200 {SELFPARAM();
 201         entity fountain;
 202         int c;
 203         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 204                 nade_napalm_ball();
 205
 206
 207         fountain = spawn();
 208         fountain.owner = self.owner;
 209         fountain.realowner = self.realowner;
 210         fountain.origin = self.origin;
 211         setorigin(fountain, fountain.origin);
 212         fountain.think = napalm_fountain_think;
 213         fountain.nextthink = time;
 214         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 215         fountain.pushltime = fountain.ltime;
 216         fountain.team = self.team;
 217         fountain.movetype = MOVETYPE_TOSS;
 218         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 219         fountain.bot_dodge = true;
 220         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 221         fountain.nade_special_time = time;
 222         setsize(fountain, '-16 -16 -16', '16 16 16');
 223         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 224 }
 225
 226 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 227 {
 228         frost_target.frozen_by = freezefield.realowner;
 229         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 230         Freeze(frost_target, 1/freeze_time, 3, false);
 231         if(frost_target.ballcarried)
 232         if(g_keepaway) { ka_DropEvent(frost_target); }
 233         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 234         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 235         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 236
 237         kh_Key_DropAll(frost_target, false);
 238 }
 239
 240 void nade_ice_think()
 241 {SELFPARAM();
 242
 243         if(round_handler_IsActive())
 244         if(!round_handler_IsRoundStarted())
 245         {
 246                 remove(self);
 247                 return;
 248         }
 249
 250         if(time >= self.ltime)
 251         {
 252                 if ( autocvar_g_nades_ice_explode )
 253                 {
 254                         entity expef = EFFECT_NADE_EXPLODE(self.realowner.team);
 255                         Send_Effect(expef, self.origin + '0 0 1', '0 0 0', 1);
 256                         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 257
 258                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 259                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 260                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 261                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 262                 }
 263                 remove(self);
 264                 return;
 265         }
 266
 267
 268         self.nextthink = time+0.1;
 269
 270         // gaussian
 271         float randomr;
 272         randomr = random();
 273         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 274         float randomw;
 275         randomw = random()*M_PI*2;
 276         vector randomp;
 277         randomp.x = randomr*cos(randomw);
 278         randomp.y = randomr*sin(randomw);
 279         randomp.z = 1;
 280         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, self.origin + randomp, '0 0 0', 1);
 281
 282         if(time >= self.nade_special_time)
 283         {
 284                 self.nade_special_time = time+0.7;
 285
 286                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
 287                 Send_Effect(EFFECT_ICEFIELD, self.origin, '0 0 0', 1);
 288         }
 289
 290
 291         float current_freeze_time = self.ltime - time - 0.1;
 292
 293         entity e;
 294         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 295         if(e != self)
 296         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 297         if(e.takedamage && e.deadflag == DEAD_NO)
 298         if(e.health > 0)
 299         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 300         if(!e.frozen)
 301         if(current_freeze_time > 0)
 302                 nade_ice_freeze(self, e, current_freeze_time);
 303 }
 304
 305 void nade_ice_boom()
 306 {SELFPARAM();
 307         entity fountain;
 308         fountain = spawn();
 309         fountain.owner = self.owner;
 310         fountain.realowner = self.realowner;
 311         fountain.origin = self.origin;
 312         setorigin(fountain, fountain.origin);
 313         fountain.think = nade_ice_think;
 314         fountain.nextthink = time;
 315         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 316         fountain.pushltime = fountain.wait = fountain.ltime;
 317         fountain.team = self.team;
 318         fountain.movetype = MOVETYPE_TOSS;
 319         fountain.projectiledeathtype = DEATH_NADE_ICE;
 320         fountain.bot_dodge = false;
 321         setsize(fountain, '-16 -16 -16', '16 16 16');
 322         fountain.nade_special_time = time+0.3;
 323         fountain.angles = self.angles;
 324
 325         if ( autocvar_g_nades_ice_explode )
 326         {
 327                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 328                 entity timer = spawn();
 329                 setmodel(timer, MDL_NADE_TIMER);
 330                 setattachment(timer, fountain, "");
 331                 timer.classname = "nade_timer";
 332                 timer.colormap = self.colormap;
 333                 timer.glowmod = self.glowmod;
 334                 timer.think = nade_timer_think;
 335                 timer.nextthink = time;
 336                 timer.wait = fountain.ltime;
 337                 timer.owner = fountain;
 338                 timer.skin = 10;
 339         }
 340         else
 341                 setmodel(fountain, MDL_Null);
 342 }
 343
 344 void nade_translocate_boom()
 345 {SELFPARAM();
 346         if(self.realowner.vehicle)
 347                 return;
 348
 349         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
 350         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 351         locout = trace_endpos;
 352
 353         makevectors(self.realowner.angles);
 354
 355         MUTATOR_CALLHOOK(PortalTeleport, self.realowner);
 356
 357         TeleportPlayer(self, self.realowner, locout, self.realowner.angles, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 358 }
 359
 360 void nade_spawn_boom()
 361 {SELFPARAM();
 362         entity spawnloc = spawn();
 363         setorigin(spawnloc, self.origin);
 364         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 365         spawnloc.movetype = MOVETYPE_NONE;
 366         spawnloc.solid = SOLID_NOT;
 367         spawnloc.drawonlytoclient = self.realowner;
 368         spawnloc.effects = EF_STARDUST;
 369         spawnloc.cnt = autocvar_g_nades_spawn_count;
 370
 371         if(self.realowner.nade_spawnloc)
 372         {
 373                 remove(self.realowner.nade_spawnloc);
 374                 self.realowner.nade_spawnloc = world;
 375         }
 376
 377         self.realowner.nade_spawnloc = spawnloc;
 378 }
 379
 380 void nade_heal_think()
 381 {SELFPARAM();
 382         if(time >= self.ltime)
 383         {
 384                 remove(self);
 385                 return;
 386         }
 387
 388         self.nextthink = time;
 389
 390         if(time >= self.nade_special_time)
 391         {
 392                 self.nade_special_time = time+0.25;
 393                 self.nade_show_particles = 1;
 394         }
 395         else
 396                 self.nade_show_particles = 0;
 397 }
 398
 399 void nade_heal_touch()
 400 {SELFPARAM();
 401         float maxhealth;
 402         float health_factor;
 403         if(IS_PLAYER(other) || IS_MONSTER(other))
 404         if(other.deadflag == DEAD_NO)
 405         if(!other.frozen)
 406         {
 407                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 408                 if ( other != self.realowner )
 409                 {
 410                         if ( SAME_TEAM(other,self) )
 411                                 health_factor *= autocvar_g_nades_heal_friend;
 412                         else
 413                                 health_factor *= autocvar_g_nades_heal_foe;
 414                 }
 415                 if ( health_factor > 0 )
 416                 {
 417                         maxhealth = (IS_MONSTER(other)) ? other.max_health : g_pickup_healthmega_max;
 418                         if ( other.health < maxhealth )
 419                         {
 420                                 if ( self.nade_show_particles )
 421                                         Send_Effect(EFFECT_HEALING, other.origin, '0 0 0', 1);
 422                                 other.health = min(other.health+health_factor, maxhealth);
 423                         }
 424                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 425                 }
 426                 else if ( health_factor < 0 )
 427                 {
 428                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 429                 }
 430
 431         }
 432
 433         if ( IS_REAL_CLIENT(other) || IS_VEHICLE(other) )
 434         {
 435                 entity show_red = (IS_VEHICLE(other)) ? other.owner : other;
 436                 show_red.stat_healing_orb = time+0.1;
 437                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 438         }
 439 }
 440
 441 void nade_heal_boom()
 442 {SELFPARAM();
 443         entity healer;
 444         healer = spawn();
 445         healer.owner = self.owner;
 446         healer.realowner = self.realowner;
 447         setorigin(healer, self.origin);
 448         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 449         healer.ltime = time + healer.healer_lifetime;
 450         healer.team = self.realowner.team;
 451         healer.bot_dodge = false;
 452         healer.solid = SOLID_TRIGGER;
 453         healer.touch = nade_heal_touch;
 454
 455         setmodel(healer, MDL_NADE_HEAL);
 456         healer.healer_radius = autocvar_g_nades_nade_radius;
 457         vector size = '1 1 1' * healer.healer_radius / 2;
 458         setsize(healer,-size,size);
 459
 460         Net_LinkEntity(healer, true, 0, healer_send);
 461
 462         healer.think = nade_heal_think;
 463         healer.nextthink = time;
 464         healer.SendFlags |= 1;
 465 }
 466
 467 void nade_monster_boom()
 468 {SELFPARAM();
 469         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
 470
 471         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 472                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 473         e.monster_skill = MONSTER_SKILL_INSANE;
 474 }
 475
 476 void nade_boom()
 477 {SELFPARAM();
 478         entity expef = NULL;
 479         bool nade_blast = true;
 480
 481         switch ( Nades[self.nade_type] )
 482         {
 483                 case NADE_TYPE_NAPALM:
 484                         nade_blast = autocvar_g_nades_napalm_blast;
 485                         expef = EFFECT_EXPLOSION_MEDIUM;
 486                         break;
 487                 case NADE_TYPE_ICE:
 488                         nade_blast = false;
 489                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 490                         break;
 491                 case NADE_TYPE_TRANSLOCATE:
 492                         nade_blast = false;
 493                         break;
 494                 case NADE_TYPE_MONSTER:
 495                 case NADE_TYPE_SPAWN:
 496                         nade_blast = false;
 497                         switch(self.realowner.team)
 498                         {
 499                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 500                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 501                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 502                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 503                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 504                         }
 505                         break;
 506                 case NADE_TYPE_HEAL:
 507                         nade_blast = false;
 508                         expef = EFFECT_SPAWN_RED;
 509                         break;
 510
 511                 default:
 512                 case NADE_TYPE_NORMAL:
 513                         expef = EFFECT_NADE_EXPLODE(self.realowner.team);
 514                         break;
 515         }
 516
 517         if(expef)
 518                 Send_Effect(expef, findbetterlocation(self.origin, 8), '0 0 0', 1);
 519
 520         sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 521         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 522
 523         self.event_damage = func_null; // prevent somehow calling damage in the next call
 524
 525         if(nade_blast)
 526         {
 527                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 528                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 529                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 530         }
 531
 532         if(self.takedamage)
 533         switch ( Nades[self.nade_type] )
 534         {
 535                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 536                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 537                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 538                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 539                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 540                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 541         }
 542
 543         entity head;
 544         for(head = world; (head = find(head, classname, "grapplinghook")); )
 545         if(head.aiment == self)
 546                 RemoveGrapplingHook(head.realowner);
 547
 548         remove(self);
 549 }
 550
 551 void nade_touch()
 552 {SELFPARAM();
 553         /*float is_weapclip = 0;
 554         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 555         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 556         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 557                 is_weapclip = 1;*/
 558         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 559         {
 560                 entity head;
 561                 for(head = world; (head = find(head, classname, "grapplinghook")); )
 562                 if(head.aiment == self)
 563                         RemoveGrapplingHook(head.realowner);
 564                 remove(self);
 565                 return;
 566         }
 567
 568         PROJECTILE_TOUCH;
 569
 570         //setsize(self, '-2 -2 -2', '2 2 2');
 571         //UpdateCSQCProjectile(self);
 572         if(self.health == self.max_health)
 573         {
 574                 spamsound(self, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTEN_NORM);
 575                 return;
 576         }
 577
 578         self.enemy = other;
 579         nade_boom();
 580 }
 581
 582 void nade_beep()
 583 {SELFPARAM();
 584         sound(self, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 585         self.think = nade_boom;
 586         self.nextthink = max(self.wait, time);
 587 }
 588
 589 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 590 {SELFPARAM();
 591         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 592         {
 593                 self.takedamage = DAMAGE_NO;
 594                 nade_boom();
 595                 return;
 596         }
 597
 598         if(self.nade_type == NADE_TYPE_TRANSLOCATE.m_id || self.nade_type == NADE_TYPE_SPAWN.m_id)
 599                 return;
 600
 601         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER.m_id))
 602         {
 603                 force *= 1.5;
 604                 damage = 0;
 605         }
 606
 607         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id) && (deathtype & HITTYPE_SECONDARY))
 608         {
 609                 force *= 0.5; // too much
 610                 frag_damage = 0;
 611         }
 612
 613         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX.m_id) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id))
 614         {
 615                 force *= 6;
 616                 damage = self.max_health * 0.55;
 617         }
 618
 619         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN.m_id) || DEATH_ISWEAPON(deathtype, WEP_HMG.m_id))
 620                 damage = self.max_health * 0.1;
 621
 622         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE.m_id) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN.m_id)) // WEAPONTODO
 623         if(deathtype & HITTYPE_SECONDARY)
 624         {
 625                 damage = self.max_health * 0.1;
 626                 force *= 10;
 627         }
 628         else
 629                 damage = self.max_health * 1.15;
 630
 631         self.velocity += force;
 632         UpdateCSQCProjectile(self);
 633
 634         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
 635                 return;
 636
 637         if(self.health == self.max_health)
 638         {
 639                 sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 640                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 641                 self.think = nade_beep;
 642         }
 643
 644         self.health -= damage;
 645
 646         if ( self.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 647                 self.realowner = attacker;
 648
 649         if(self.health <= 0)
 650                 W_PrepareExplosionByDamage(attacker, nade_boom);
 651         else
 652                 nade_burn_spawn(self);
 653 }
 654
 655 void toss_nade(entity e, vector _velocity, float _time)
 656 {SELFPARAM();
 657         if(e.nade == world)
 658                 return;
 659
 660         entity _nade = e.nade;
 661         e.nade = world;
 662
 663         remove(e.fake_nade);
 664         e.fake_nade = world;
 665
 666         makevectors(e.v_angle);
 667
 668         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
 669
 670         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 671
 672         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 673                                   + (v_right * autocvar_g_nades_throw_offset.y)
 674                                   + (v_up * autocvar_g_nades_throw_offset.z);
 675         if(autocvar_g_nades_throw_offset == '0 0 0')
 676                 offset = '0 0 0';
 677
 678         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 679         //setmodel(_nade, MDL_PROJECTILE_NADE);
 680         //setattachment(_nade, world, "");
 681         PROJECTILE_MAKETRIGGER(_nade);
 682         setsize(_nade, '-16 -16 -16', '16 16 16');
 683         _nade.movetype = MOVETYPE_BOUNCE;
 684
 685         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 686         if (trace_startsolid)
 687                 setorigin(_nade, e.origin);
 688
 689         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
 690                 _nade.velocity = '0 0 100';
 691         else if(autocvar_g_nades_nade_newton_style == 1)
 692                 _nade.velocity = e.velocity + _velocity;
 693         else if(autocvar_g_nades_nade_newton_style == 2)
 694                 _nade.velocity = _velocity;
 695         else
 696                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
 697
 698         _nade.touch = nade_touch;
 699         _nade.health = autocvar_g_nades_nade_health;
 700         _nade.max_health = _nade.health;
 701         _nade.takedamage = DAMAGE_AIM;
 702         _nade.event_damage = nade_damage;
 703         _nade.customizeentityforclient = func_null;
 704         _nade.exteriormodeltoclient = world;
 705         _nade.traileffectnum = 0;
 706         _nade.teleportable = true;
 707         _nade.pushable = true;
 708         _nade.gravity = 1;
 709         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 710         _nade.damagedbycontents = true;
 711         _nade.angles = vectoangles(_nade.velocity);
 712         _nade.flags = FL_PROJECTILE;
 713         _nade.projectiledeathtype = DEATH_NADE;
 714         _nade.toss_time = time;
 715         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 716
 717         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
 718                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 719         else
 720                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 721
 722         nade_spawn(_nade);
 723
 724         if(_time)
 725         {
 726                 _nade.think = nade_boom;
 727                 _nade.nextthink = _time;
 728         }
 729
 730         e.nade_refire = time + autocvar_g_nades_nade_refire;
 731         e.nade_timer = 0;
 732 }
 733
 734 void nades_GiveBonus(entity player, float score)
 735 {
 736         if (autocvar_g_nades)
 737         if (autocvar_g_nades_bonus)
 738         if (IS_REAL_CLIENT(player))
 739         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 740         if (player.frozen == 0)
 741         if (player.deadflag == DEAD_NO)
 742         {
 743                 if ( player.bonus_nade_score < 1 )
 744                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 745
 746                 if ( player.bonus_nade_score >= 1 )
 747                 {
 748                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 749                         play2(player, SND(KH_ALARM));
 750                         player.bonus_nades++;
 751                         player.bonus_nade_score -= 1;
 752                 }
 753         }
 754 }
 755
 756 void nades_RemoveBonus(entity player)
 757 {
 758         player.bonus_nades = player.bonus_nade_score = 0;
 759 }
 760
 761 float nade_customize()
 762 {SELFPARAM();
 763         //if(IS_SPEC(other)) { return false; }
 764         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 765         {
 766                 // somewhat hide the model, but keep the glow
 767                 //self.effects = 0;
 768                 if(self.traileffectnum)
 769                         self.traileffectnum = 0;
 770                 self.alpha = -1;
 771         }
 772         else
 773         {
 774                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 775                 if(!self.traileffectnum)
 776                         self.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades[self.nade_type].m_projectile[false], self.team).eent_eff_name);
 777                 self.alpha = 1;
 778         }
 779
 780         return true;
 781 }
 782
 783 void nade_prime()
 784 {SELFPARAM();
 785         if(autocvar_g_nades_bonus_only)
 786         if(!self.bonus_nades)
 787                 return; // only allow bonus nades
 788
 789         if(self.nade)
 790                 remove(self.nade);
 791
 792         if(self.fake_nade)
 793                 remove(self.fake_nade);
 794
 795         entity n = spawn(), fn = spawn();
 796
 797         n.classname = "nade";
 798         fn.classname = "fake_nade";
 799
 800         if(self.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
 801                 n.nade_type = self.nade_type;
 802         else if (self.bonus_nades >= 1)
 803         {
 804                 n.nade_type = self.nade_type;
 805                 n.pokenade_type = self.pokenade_type;
 806                 self.bonus_nades -= 1;
 807         }
 808         else
 809         {
 810                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 811                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 812         }
 813
 814         n.nade_type = bound(1, n.nade_type, Nades_COUNT);
 815
 816         setmodel(n, MDL_PROJECTILE_NADE);
 817         //setattachment(n, self, "bip01 l hand");
 818         n.exteriormodeltoclient = self;
 819         n.customizeentityforclient = nade_customize;
 820         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades[n.nade_type].m_projectile[false], self.team).eent_eff_name);
 821         n.colormod = Nades[n.nade_type].m_color;
 822         n.realowner = self;
 823         n.colormap = self.colormap;
 824         n.glowmod = self.glowmod;
 825         n.wait = time + autocvar_g_nades_nade_lifetime;
 826         n.nade_time_primed = time;
 827         n.think = nade_beep;
 828         n.nextthink = max(n.wait - 3, time);
 829         n.projectiledeathtype = DEATH_NADE;
 830
 831         setmodel(fn, MDL_NADE_VIEW);
 832         setattachment(fn, self.weaponentity, "");
 833         fn.realowner = fn.owner = self;
 834         fn.colormod = Nades[n.nade_type].m_color;
 835         fn.colormap = self.colormap;
 836         fn.glowmod = self.glowmod;
 837         fn.think = SUB_Remove;
 838         fn.nextthink = n.wait;
 839
 840         self.nade = n;
 841         self.fake_nade = fn;
 842 }
 843
 844 float CanThrowNade()
 845 {SELFPARAM();
 846         if(self.vehicle)
 847                 return false;
 848
 849         if(gameover)
 850                 return false;
 851
 852         if(self.deadflag != DEAD_NO)
 853                 return false;
 854
 855         if (!autocvar_g_nades)
 856                 return false; // allow turning them off mid match
 857
 858         if(forbidWeaponUse(self))
 859                 return false;
 860
 861         if (!IS_PLAYER(self))
 862                 return false;
 863
 864         return true;
 865 }
 866
 867 .bool nade_altbutton;
 868
 869 void nades_CheckThrow()
 870 {SELFPARAM();
 871         if(!CanThrowNade())
 872                 return;
 873
 874         entity held_nade = self.nade;
 875         if (!held_nade)
 876         {
 877                 self.nade_altbutton = true;
 878                 if(time > self.nade_refire)
 879                 {
 880                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 881                         nade_prime();
 882                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 883                 }
 884         }
 885         else
 886         {
 887                 self.nade_altbutton = false;
 888                 if (time >= held_nade.nade_time_primed + 1) {
 889                         makevectors(self.v_angle);
 890                         float _force = time - held_nade.nade_time_primed;
 891                         _force /= autocvar_g_nades_nade_lifetime;
 892                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 893                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 894                 }
 895         }
 896 }
 897
 898 void nades_Clear(entity player)
 899 {
 900         if(player.nade)
 901                 remove(player.nade);
 902         if(player.fake_nade)
 903                 remove(player.fake_nade);
 904
 905         player.nade = player.fake_nade = world;
 906         player.nade_timer = 0;
 907 }
 908
 909 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 910 {
 911         if(vh_player.nade)
 912                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 913
 914         return false;
 915 }
 916
 917 CLASS(NadeOffhand, OffhandWeapon)
 918     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
 919     {
 920         entity held_nade = player.nade;
 921                 if (held_nade)
 922                 {
 923                         player.nade_timer = bound(0, (time - held_nade.nade_time_primed) / autocvar_g_nades_nade_lifetime, 1);
 924                         // LOG_TRACEF("%d %d\n", player.nade_timer, time - held_nade.nade_time_primed);
 925                         makevectors(player.angles);
 926                         held_nade.velocity = player.velocity;
 927                         setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 928                         held_nade.angles_y = player.angles.y;
 929
 930                         if (time + 0.1 >= held_nade.wait)
 931                                 toss_nade(player, '0 0 0', time + 0.05);
 932                 }
 933
 934         if (!CanThrowNade()) return;
 935         if (!(time > player.nade_refire)) return;
 936                 if (key_pressed) {
 937                         if (!held_nade) {
 938                                 nade_prime();
 939                                 held_nade = player.nade;
 940                         }
 941                 } else if (time >= held_nade.nade_time_primed + 1) {
 942                         if (held_nade) {
 943                                 makevectors(player.v_angle);
 944                                 float _force = time - held_nade.nade_time_primed;
 945                                 _force /= autocvar_g_nades_nade_lifetime;
 946                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 947                                 toss_nade(player, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 948                         }
 949                 }
 950     }
 951 ENDCLASS(NadeOffhand)
 952 NadeOffhand OFFHAND_NADE; STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
 953
 954 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 955 {
 956         if (self.offhand != OFFHAND_NADE || (self.weapons & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
 957                 nades_CheckThrow();
 958                 return true;
 959         }
 960         return false;
 961 }
 962
 963 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 964 {SELFPARAM();
 965         if (!IS_PLAYER(self)) { return false; }
 966
 967         if (self.nade && self.offhand != OFFHAND_NADE) OFFHAND_NADE.offhand_think(OFFHAND_NADE, self, self.nade_altbutton);
 968
 969         if(IS_PLAYER(self))
 970         {
 971                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 972                 {
 973                         entity key;
 974                         float key_count = 0;
 975                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 976
 977                         float time_score;
 978                         if(self.flagcarried || self.ballcarried) // this player is important
 979                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 980                         else
 981                                 time_score = autocvar_g_nades_bonus_score_time;
 982
 983                         if(key_count)
 984                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 985
 986                         if(autocvar_g_nades_bonus_client_select)
 987                         {
 988                                 self.nade_type = self.cvar_cl_nade_type;
 989                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 990                         }
 991                         else
 992                         {
 993                                 self.nade_type = autocvar_g_nades_bonus_type;
 994                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 995                         }
 996
 997                         self.nade_type = bound(1, self.nade_type, Nades_COUNT);
 998
 999                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1000                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
1001                 }
1002                 else
1003                 {
1004                         self.bonus_nades = self.bonus_nade_score = 0;
1005                 }
1006         }
1007
1008         float n = 0;
1009         entity o = world;
1010         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1011                 n = -1;
1012         else
1013         {
1014                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1015                 n = 0;
1016                 FOR_EACH_PLAYER(other) if(self != other)
1017                 {
1018                         if(other.deadflag == DEAD_NO)
1019                         if(other.frozen == 0)
1020                         if(SAME_TEAM(other, self))
1021                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1022                         {
1023                                 if(!o)
1024                                         o = other;
1025                                 if(self.frozen == 1)
1026                                         other.reviving = true;
1027                                 ++n;
1028                         }
1029                 }
1030         }
1031
1032         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1033         {
1034                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1035                 self.health = max(1, self.revive_progress * start_health);
1036
1037                 if(self.revive_progress >= 1)
1038                 {
1039                         Unfreeze(self);
1040
1041                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1042                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1043                 }
1044
1045                 FOR_EACH_PLAYER(other) if(other.reviving)
1046                 {
1047                         other.revive_progress = self.revive_progress;
1048                         other.reviving = false;
1049                 }
1050         }
1051
1052         return false;
1053 }
1054
1055 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1056 {SELFPARAM();
1057         if(autocvar_g_nades_spawn)
1058                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1059         else
1060                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1061
1062         if(autocvar_g_nades_bonus_client_select)
1063                 self.nade_type = self.cvar_cl_nade_type;
1064
1065         self.nade_timer = 0;
1066
1067         if (!self.offhand) self.offhand = OFFHAND_NADE;
1068
1069         if(self.nade_spawnloc)
1070         {
1071                 setorigin(self, self.nade_spawnloc.origin);
1072                 self.nade_spawnloc.cnt -= 1;
1073
1074                 if(self.nade_spawnloc.cnt <= 0)
1075                 {
1076                         remove(self.nade_spawnloc);
1077                         self.nade_spawnloc = world;
1078                 }
1079         }
1080
1081         return false;
1082 }
1083
1084 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1085 {
1086         if(frag_target.nade)
1087         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1088                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1089
1090         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1091
1092         if(IS_PLAYER(frag_attacker))
1093         {
1094                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1095                         nades_RemoveBonus(frag_attacker);
1096                 else if(frag_target.flagcarried)
1097                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1098                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1099                 {
1100                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1101                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1102                         switch(frag_attacker.killcount)
1103                         {
1104                                 KILL_SPREE_LIST
1105                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1106                         }
1107                         #undef SPREE_ITEM
1108                 }
1109                 else
1110                         nades_GiveBonus(frag_attacker, killcount_bonus);
1111         }
1112
1113         nades_RemoveBonus(frag_target);
1114
1115         return false;
1116 }
1117
1118 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1119 {
1120         if(frag_target.frozen)
1121         if(autocvar_g_freezetag_revive_nade)
1122         if(frag_attacker == frag_target)
1123         if(frag_deathtype == DEATH_NADE)
1124         if(time - frag_inflictor.toss_time <= 0.1)
1125         {
1126                 Unfreeze(frag_target);
1127                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1128                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1129                 frag_damage = 0;
1130                 frag_force = '0 0 0';
1131                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1132                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1133         }
1134
1135         return false;
1136 }
1137
1138 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1139 {SELFPARAM();
1140         if(IS_PLAYER(frag_attacker))
1141         if(DIFF_TEAM(frag_attacker, self))
1142         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1143                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1144
1145         return false;
1146 }
1147
1148 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1149 {SELFPARAM();
1150         nades_Clear(self);
1151         nades_RemoveBonus(self);
1152         return false;
1153 }
1154
1155 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1156 {SELFPARAM();
1157         self.nade_timer = other.nade_timer;
1158         self.nade_type = other.nade_type;
1159         self.pokenade_type = other.pokenade_type;
1160         self.bonus_nades = other.bonus_nades;
1161         self.bonus_nade_score = other.bonus_nade_score;
1162         self.stat_healing_orb = other.stat_healing_orb;
1163         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1164         return false;
1165 }
1166
1167 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1168 {
1169         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1170         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1171
1172         return false;
1173 }
1174
1175 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1176 {
1177         ret_string = strcat(ret_string, ":Nades");
1178         return false;
1179 }
1180
1181 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1182 {
1183         ret_string = strcat(ret_string, ", Nades");
1184         return false;
1185 }
1186
1187 void nades_Initialize()
1188 {
1189         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1190         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1191         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1192         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1193         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1194         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1195 }
1196
1197 MUTATOR_DEFINITION(mutator_nades)
1198 {
1199         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1200         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1201         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1202         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1203         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1204         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1205         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1206         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1207         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1208         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1209         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1210         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1211         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1212         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1213
1214         MUTATOR_ONADD
1215         {
1216                 nades_Initialize();
1217         }
1218
1219         return false;
1220 }