qcsrc/server/mutators/mutator_superspec.qc

   1 #define _SSMAGIX "SUPERSPEC_OPTIONSFILE_V1"
   2 #define _ISLOCAL ((edict_num(1) == self) ? TRUE : FALSE)
   3
   4 #define ASF_STRENGTH        1
   5 #define ASF_SHIELD          2
   6 #define ASF_MEGA_AR         4
   7 #define ASF_MEGA_HP         8
   8 #define ASF_FLAG_GRAB       16
   9 #define ASF_OBSERVER_ONLY   32
  10 #define ASF_SHOWWHAT        64
  11 #define ASF_SSIM            128
  12 #define ASF_ALL             0xFFFFFF
  13 .float autospec_flags;
  14
  15 #define SSF_SILENT          1
  16 #define SSF_VERBOSE         2
  17 #define SSF_ITEMMSG         4
  18 .float superspec_flags;
  19
  20 .string superspec_itemfilter; //"classname1 classname2 ..."
  21
  22 float _spectate(entity _player)
  23 {
  24         if(Spectate(_player) == 1)
  25         {
  26                 PutObserverInServer();
  27                 self.classname = "spectator";
  28         }
  29
  30         return TRUE;
  31 }
  32
  33 void superspec_save_client_conf()
  34 {
  35         string fn = "superspec-local.options";
  36         float fh;
  37
  38         if not(_ISLOCAL)
  39         {
  40                 if(self.crypto_idfp == "")
  41                         return;
  42
  43                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
  44         }
  45
  46         fh = fopen(fn, FILE_WRITE);
  47         if(fh < 0)
  48         {
  49                 dprint("^1ERROR: ^7 superspec can not open ", fn, " for writing.\n");
  50         }
  51         else
  52         {
  53                 fputs(fh, _SSMAGIX);
  54                 fputs(fh, "\n");
  55                 fputs(fh, ftos(self.autospec_flags));
  56                 fputs(fh, "\n");
  57                 fputs(fh, ftos(self.superspec_flags));
  58                 fputs(fh, "\n");
  59                 fputs(fh, self.superspec_itemfilter);
  60                 fputs(fh, "\n");
  61                 fclose(fh);
  62         }
  63 }
  64
  65 void superspec_msg(string _center_title, string _con_title, entity _to, string _msg, float _spamlevel)
  66 {
  67         sprint(_to, strcat(_con_title, _msg));
  68
  69         if(_to.superspec_flags & SSF_SILENT)
  70                 return;
  71
  72         if(_spamlevel > 1)
  73                 if not(_to.superspec_flags & SSF_VERBOSE)
  74                         return;
  75
  76         centerprint(_to, strcat(_center_title, _msg));
  77 }
  78
  79 float superspec_filteritem(entity _for, entity _item)
  80 {
  81         float i;
  82
  83         if(_for.superspec_itemfilter == "")
  84                 return TRUE;
  85
  86         if(_for.superspec_itemfilter == "")
  87                 return TRUE;
  88
  89         float l = tokenize_console(_for.superspec_itemfilter);
  90         for(i = 0; i < l; ++i)
  91         {
  92                 if(argv(i) == _item.classname)
  93                         return TRUE;
  94         }
  95
  96         return FALSE;
  97 }
  98
  99 MUTATOR_HOOKFUNCTION(superspec_ItemTouch)
 100 {
 101         entity _oldself = self;
 102         entity _item = self;
 103
 104         FOR_EACH_SPEC(self)
 105         {
 106                 if(self.superspec_flags & SSF_ITEMMSG)
 107                         if(superspec_filteritem(self, _item))
 108                         {
 109                                 if(self.superspec_flags & SSF_VERBOSE)
 110                                         superspec_msg("", "", self, sprintf("Player %s^7 just picked up ^3%s\n", other.netname, _item.netname), 1);
 111                                 else
 112                                         superspec_msg("", "", self, sprintf("Player %s^7 just picked up ^3%s\n^8(%s^8)\n", other.netname, _item.netname, _item.classname), 1);
 113                                 if(self.autospec_flags& ASF_SSIM && self.enemy != other)
 114                                 {
 115                                         _spectate(other);
 116
 117                                         self = _oldself;
 118                                         return MUT_ITEMTOUCH_CONTINUE;
 119                                 }
 120                         }
 121
 122                 if((self.autospec_flags & ASF_SHIELD && _item.invincible_finished) ||
 123                                 (self.autospec_flags & ASF_STRENGTH && _item.strength_finished) ||
 124                                 (self.autospec_flags& ASF_MEGA_AR && _item.classname == "item_armor_large") ||
 125                                 (self.autospec_flags& ASF_MEGA_HP && _item.classname == "item_health_mega") ||
 126                                 (self.autospec_flags& ASF_FLAG_GRAB && _item.classname == "item_flag_team"))
 127                 {
 128
 129                         if((self.enemy != other) || IS_OBSERVER(self))
 130                         {
 131                                 if(self.autospec_flags & ASF_OBSERVER_ONLY && !IS_OBSERVER(self))
 132                                 {
 133                                         if(self.superspec_flags & SSF_VERBOSE)
 134                                                 superspec_msg("", "", self, sprintf("^8Ignored that ^7%s^8 grabbed %s^8 since the observer_only option is ON\n", other.netname, _item.netname), 2);
 135                                 }
 136                                 else
 137                                 {
 138                                         if(self.autospec_flags & ASF_SHOWWHAT)
 139                                                 superspec_msg("", "", self, sprintf("^7Following %s^7 due to picking up %s\n", other.netname, _item.netname), 2);
 140
 141                                         _spectate(other);
 142                                 }
 143                         }
 144                 }
 145         }
 146
 147         self = _oldself;
 148
 149         return MUT_ITEMTOUCH_CONTINUE;
 150 }
 151
 152 MUTATOR_HOOKFUNCTION(superspec_SV_ParseClientCommand)
 153 {
 154 #define OPTIONINFO(flag,var,test,text,long,short) \
 155     var = strcat(var, ((flag & test) ? "^2[ON]  ^7" : "^1[OFF] ^7")); \
 156     var = strcat(var, text," ^7(^3 ", long, "^7 | ^3", short, " ^7)\n")
 157
 158         if(MUTATOR_RETURNVALUE) // command was already handled?
 159                 return FALSE;
 160
 161         if(IS_PLAYER(self))
 162                 return FALSE;
 163
 164         if(cmd_name == "superspec_itemfilter")
 165         {
 166                 if(argv(1) == "help")
 167                 {
 168                         string _aspeco;
 169                         _aspeco = "^7 superspec_itemfilter ^3\"item_classname1 item_classname2\"^7 only show thise items when ^2superspec ^3item_message^7 is on\n";
 170                         _aspeco = strcat(_aspeco, "^3 clear^7 Remove the filter (show all pickups)\n");
 171                         _aspeco = strcat(_aspeco, "^3 show ^7 Display current filter\n");
 172                         superspec_msg("^3superspec_itemfilter help:\n\n\n", "\n^3superspec_itemfilter help:\n", self, _aspeco, 1);
 173                 }
 174                 else if(argv(1) == "clear")
 175                 {
 176                         if(self.superspec_itemfilter != "")
 177                                 strunzone(self.superspec_itemfilter);
 178
 179                         self.superspec_itemfilter = "";
 180                 }
 181                 else if(argv(1) == "show" || argv(1) == "")
 182                 {
 183                         if(self.superspec_itemfilter == "")
 184                         {
 185                                 superspec_msg("^3superspec_itemfilter^7 is ^1not^7 set", "\n^3superspec_itemfilter^7 is ^1not^7 set\n", self, "", 1);
 186                                 return TRUE;
 187                         }
 188                         float i;
 189                         float l = tokenize_console(self.superspec_itemfilter);
 190                         string _msg = "";
 191                         for(i = 0; i < l; ++i)
 192                                 _msg = strcat(_msg, "^3#", ftos(i), " ^7", argv(i), "\n");
 193                                 //_msg = sprintf("^3#%d^7 %s\n%s", i, _msg, argv(i));
 194
 195                         _msg = strcat(_msg,"\n");
 196
 197                         superspec_msg("^3superspec_itemfilter is:\n\n\n", "\n^3superspec_itemfilter is:\n", self, _msg, 1);
 198                 }
 199                 else
 200                 {
 201                         if(self.superspec_itemfilter != "")
 202                                 strunzone(self.superspec_itemfilter);
 203
 204                         self.superspec_itemfilter = strzone(argv(1));
 205                 }
 206
 207                 return TRUE;
 208         }
 209
 210         if(cmd_name == "superspec")
 211         {
 212                 string _aspeco;
 213
 214                 if(cmd_argc > 1)
 215                 {
 216                         float i, _bits = 0, _start = 1;
 217                         if(argv(1) == "help")
 218                         {
 219                                 _aspeco = "use cmd superspec [option] [on|off] to set options\n\n";
 220                                 _aspeco = strcat(_aspeco, "^3 silent ^7(short^5 si^7) supresses ALL messages from superspectate.\n");
 221                                 _aspeco = strcat(_aspeco, "^3 verbose ^7(short^5 ve^7) makes superspectate print some additional information.\n");
 222                                 _aspeco = strcat(_aspeco, "^3 item_message ^7(short^5 im^7) makes superspectate print items that were picked up.\n");
 223                                 _aspeco = strcat(_aspeco, "^7    Use cmd superspec_itemfilter \"item_class1 item_class2\" to set up a filter of what to show with ^3item_message.\n");
 224                                 superspec_msg("^2Available Super Spectate ^3options:\n\n\n", "\n^2Available Super Spectate ^3options:\n", self, _aspeco, 1);
 225                                 return TRUE;
 226                         }
 227
 228                         if(argv(1) == "clear")
 229                         {
 230                                 self.superspec_flags = 0;
 231                                 _start = 2;
 232                         }
 233
 234                         for(i = _start; i < cmd_argc; ++i)
 235                         {
 236                                 if(argv(i) == "on" || argv(i) == "1")
 237                                 {
 238                                         self.superspec_flags |= _bits;
 239                                         _bits = 0;
 240                                 }
 241                                 else if(argv(i) == "off" || argv(i) == "0")
 242                                 {
 243                                         if(_start == 1)
 244                                                 self.superspec_flags &~= _bits;
 245
 246                                         _bits = 0;
 247                                 }
 248                                 else
 249                                 {
 250                                         if((argv(i) == "silent") || (argv(i) == "si")) _bits |= SSF_SILENT ;
 251                                         if((argv(i) == "verbose") || (argv(i) == "ve")) _bits |= SSF_VERBOSE;
 252                                         if((argv(i) == "item_message") || (argv(i) == "im")) _bits |= SSF_ITEMMSG;
 253                                 }
 254                         }
 255                 }
 256
 257                 _aspeco = "";
 258                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_SILENT, "Silent", "silent", "si");
 259                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_VERBOSE, "Verbose", "verbose", "ve");
 260                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_ITEMMSG, "Item pickup messages", "item_message", "im");
 261
 262                 superspec_msg("^3Current Super Spectate options are:\n\n\n\n\n", "\n^3Current Super Spectate options are:\n", self, _aspeco, 1);
 263
 264                 return TRUE;
 265         }
 266
 267 /////////////////////
 268
 269         if(cmd_name == "autospec")
 270         {
 271                 string _aspeco;
 272                 if(cmd_argc > 1)
 273                 {
 274                         if(argv(1) == "help")
 275                         {
 276                                 _aspeco = "use cmd autospec [option] [on|off] to set options\n\n";
 277                                 _aspeco = strcat(_aspeco, "^3 strength ^7(short^5 st^7) for automatic spectate on strength powerup\n");
 278                                 _aspeco = strcat(_aspeco, "^3 shield ^7(short^5 sh^7) for automatic spectate on shield powerup\n");
 279                                 _aspeco = strcat(_aspeco, "^3 mega_health ^7(short^5 mh^7) for automatic spectate on mega health\n");
 280                                 _aspeco = strcat(_aspeco, "^3 mega_armor ^7(short^5 ma^7) for automatic spectate on mega armor\n");
 281                                 _aspeco = strcat(_aspeco, "^3 flag_grab ^7(short^5 fg^7) for automatic spectate on CTF flag grab\n");
 282                                 _aspeco = strcat(_aspeco, "^3 observer_only ^7(short^5 oo^7) for automatic spectate only if in observer mode\n");
 283                                 _aspeco = strcat(_aspeco, "^3 show_what ^7(short^5 sw^7) to display what event triggered autospectate\n");
 284                                 _aspeco = strcat(_aspeco, "^3 item_msg ^7(short^5 im^7) to autospec when item_message in superspectate is triggered\n");
 285                                 _aspeco = strcat(_aspeco, "^3 all ^7(short ^5aa^7) to turn everything on/off\n");
 286                                 superspec_msg("^2Available Auto Spectate ^3options:\n\n\n", "\n^2Available Auto Spectate ^3options:\n", self, _aspeco, 1);
 287                                 return TRUE;
 288                         }
 289
 290                         float i, _bits = 0, _start = 1;
 291                         if(argv(1) == "clear")
 292                         {
 293                                 self.autospec_flags = 0;
 294                                 _start = 2;
 295                         }
 296
 297                         for(i = _start; i < cmd_argc; ++i)
 298                         {
 299                                 if(argv(i) == "on" || argv(i) == "1")
 300                                 {
 301                                         self.autospec_flags |= _bits;
 302                                         _bits = 0;
 303                                 }
 304                                 else if(argv(i) == "off" || argv(i) == "0")
 305                                 {
 306                                         if(_start == 1)
 307                                                 self.autospec_flags &~= _bits;
 308
 309                                         _bits = 0;
 310                                 }
 311                                 else
 312                                 {
 313                                         if((argv(i) == "strength") || (argv(i) == "st")) _bits |= ASF_STRENGTH;
 314                                         if((argv(i) == "shield") || (argv(i) == "sh")) _bits |= ASF_SHIELD;
 315                                         if((argv(i) == "mega_health") || (argv(i) == "mh")) _bits |= ASF_MEGA_HP;
 316                                         if((argv(i) == "mega_armor") || (argv(i) == "ma")) _bits |= ASF_MEGA_AR;
 317                                         if((argv(i) == "flag_grab") || (argv(i) == "fg")) _bits |= ASF_FLAG_GRAB;
 318                                         if((argv(i) == "observer_only") || (argv(i) == "oo")) _bits |= ASF_OBSERVER_ONLY;
 319                                         if((argv(i) == "show_what") || (argv(i) == "sw")) _bits |= ASF_SHOWWHAT;
 320                                         if((argv(i) == "item_msg") || (argv(i) == "im")) _bits |= ASF_SSIM;
 321                                         if((argv(i) == "all") || (argv(i) == "aa")) _bits |= ASF_ALL;
 322                                 }
 323                         }
 324                 }
 325
 326                 _aspeco = "";
 327                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_STRENGTH, "Strength", "strength", "st");
 328                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHIELD, "Shield", "shield", "sh");
 329                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_HP, "Mega Health", "mega_health", "mh");
 330                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_AR, "Mega Armor", "mega_armor", "ma");
 331                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_FLAG_GRAB, "Flag grab", "flag_grab","fg");
 332                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_OBSERVER_ONLY, "Only switch if observer", "observer_only", "oo");
 333                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHOWWHAT, "Show what item triggered spectate", "show_what", "sw");
 334                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SSIM, "Switch on superspec item message", "item_msg", "im");
 335
 336                 superspec_msg("^3Current auto spectate options are:\n\n\n\n\n", "\n^3Current auto spectate options are:\n", self, _aspeco, 1);
 337                 return TRUE;
 338         }
 339
 340         if(cmd_name == "followpowerup")
 341         {
 342                 entity _player;
 343                 FOR_EACH_PLAYER(_player)
 344                 {
 345                         if(_player.strength_finished > time || _player.invincible_finished > time)
 346                                 return _spectate(_player);
 347                 }
 348
 349                 superspec_msg("", "", self, "No active powerup\n", 1);
 350                 return TRUE;
 351         }
 352
 353         if(cmd_name == "followstrength")
 354         {
 355                 entity _player;
 356                 FOR_EACH_PLAYER(_player)
 357                 {
 358                         if(_player.strength_finished > time)
 359                                 return _spectate(_player);
 360                 }
 361
 362                 superspec_msg("", "", self, "No active Strength\n", 1);
 363                 return TRUE;
 364         }
 365
 366         if(cmd_name == "followshield")
 367         {
 368                 entity _player;
 369                 FOR_EACH_PLAYER(_player)
 370                 {
 371                         if(_player.invincible_finished > time)
 372                                 return _spectate(_player);
 373                 }
 374
 375                 superspec_msg("", "", self, "No active Shield\n", 1);
 376                 return TRUE;
 377         }
 378
 379         if(cmd_name == "followfc")
 380         {
 381                 if(!g_ctf)
 382                         return TRUE;
 383
 384                 entity _player;
 385                 float _team = 0;
 386
 387                 if(cmd_argc == 2)
 388                 {
 389                         if(argv(1) == "red")
 390                                 _team = NUM_TEAM_1;
 391                         else
 392                                 _team = NUM_TEAM_2;
 393                 }
 394
 395                 FOR_EACH_PLAYER(_player)
 396                 {
 397                         if(_player.flagcarried && (_player.team == _team || _team == 0))
 398                                 return _spectate(_player);
 399                 }
 400
 401                 superspec_msg("", "", self, "No active flag carrier\n", 1);
 402                 return TRUE;
 403         }
 404
 405         return FALSE;
 406 #undef OPTIONINFO
 407 }
 408
 409 MUTATOR_HOOKFUNCTION(superspec_BuildMutatorsString)
 410 {
 411         ret_string = strcat(ret_string, ":SS");
 412         return 0;
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(superspec_BuildMutatorsPrettyString)
 416 {
 417         ret_string = strcat(ret_string, ", Super Spectators");
 418         return 0;
 419 }
 420
 421 void superspec_hello()
 422 {
 423         if(self.enemy.crypto_idfp == "")
 424                 centerprint(self.enemy, "Your client have/allow no crypto id, superspec options will not be saved/restored.");
 425         else
 426                 centerprint(self.enemy, sprintf("Hello %s\nSince your client has a Crypto ID, your superspec preferences will be persisted on this server.", self.enemy.netname));
 427
 428         remove(self);
 429 }
 430
 431 MUTATOR_HOOKFUNCTION(superspec_ClientConnect)
 432 {
 433         if(!IS_REAL_CLIENT(self))
 434                 return FALSE;
 435
 436         string fn = "superspec-local.options";
 437         float fh;
 438
 439         self.superspec_flags = SSF_VERBOSE;
 440         self.superspec_itemfilter = "";
 441
 442         entity _hello = spawn();
 443         _hello.enemy = self;
 444         _hello.think = superspec_hello;
 445         _hello.nextthink = time + 5;
 446
 447         if not(_ISLOCAL)
 448         {
 449                 if(self.crypto_idfp == "")
 450                         return FALSE;
 451
 452                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
 453         }
 454
 455         fh = fopen(fn, FILE_READ);
 456         if(fh < 0)
 457         {
 458                 dprint("^1ERROR: ^7 superspec can not open ", fn, " for reading.\n");
 459         }
 460         else
 461         {
 462                 string _magic = fgets(fh);
 463                 if(_magic != _SSMAGIX)
 464                 {
 465                         dprint("^1ERROR^7 While reading superspec options file: unknown magic\n");
 466                 }
 467                 else
 468                 {
 469                         self.autospec_flags = stof(fgets(fh));
 470                         self.superspec_flags = stof(fgets(fh));
 471                         self.superspec_itemfilter = strzone(fgets(fh));
 472                 }
 473                 fclose(fh);
 474         }
 475
 476         return FALSE;
 477 }
 478
 479 MUTATOR_HOOKFUNCTION(superspec_ClientDisconnect)
 480 {
 481         superspec_save_client_conf();
 482         return FALSE;
 483 }
 484
 485 MUTATOR_DEFINITION(mutator_superspec)
 486 {
 487
 488         MUTATOR_HOOK(BuildMutatorsString, superspec_BuildMutatorsString, CBC_ORDER_ANY);
 489         MUTATOR_HOOK(BuildMutatorsPrettyString, superspec_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 490         MUTATOR_HOOK(SV_ParseClientCommand, superspec_SV_ParseClientCommand, CBC_ORDER_ANY);
 491         MUTATOR_HOOK(ItemTouch, superspec_ItemTouch, CBC_ORDER_ANY);
 492         MUTATOR_HOOK(ClientConnect, superspec_ClientConnect, CBC_ORDER_ANY);
 493         MUTATOR_HOOK(ClientDisconnect, superspec_ClientDisconnect, CBC_ORDER_ANY);
 494
 495         return 0;
 496 }