qcsrc/server/mutators/sandbox.qc

   1
   2 #include "mutator.qh"
   3
   4 const float MAX_STORAGE_ATTACHMENTS = 16;
   5 float object_count;
   6 .float object_flood;
   7 .entity object_attach;
   8 .string material;
   9
  10 .float touch_timer;
  11 void sandbox_ObjectFunction_Touch()
  12 {SELFPARAM();
  13         // apply material impact effects
  14
  15         if(!self.material)
  16                 return;
  17         if(self.touch_timer > time)
  18                 return; // don't execute each frame
  19         self.touch_timer = time + 0.1;
  20
  21         // make particle count and sound volume depend on impact speed
  22         float intensity;
  23         intensity = vlen(self.velocity) + vlen(other.velocity);
  24         if(intensity) // avoid divisions by 0
  25                 intensity /= 2; // average the two velocities
  26         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  27                 return; // impact not strong enough to do anything
  28         // now offset intensity and apply it to the effects
  29         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  30         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  31
  32         _sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  33         Send_Effect_(strcat("impact_", self.material), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  34 }
  35
  36 void sandbox_ObjectFunction_Think()
  37 {SELFPARAM();
  38         entity e;
  39
  40         // decide if and how this object can be grabbed
  41         if(autocvar_g_sandbox_readonly)
  42                 self.grab = 0; // no grabbing
  43         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  44                 self.grab = 1; // owner only
  45         else
  46                 self.grab = 3; // anyone
  47
  48         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  49         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  50         // since if the owning player disconnects, the object's owner should also be reset.
  51         FOR_EACH_REALPLAYER(e) // bots can't have objects
  52         {
  53                 if(self.crypto_idfp == e.crypto_idfp)
  54                 {
  55                         self.realowner = e;
  56                         break;
  57                 }
  58                 self.realowner = world;
  59         }
  60
  61         self.nextthink = time;
  62
  63         CSQCMODEL_AUTOUPDATE(self);
  64 }
  65
  66 .float old_solid, old_movetype;
  67 entity sandbox_ObjectEdit_Get(float permissions)
  68 {SELFPARAM();
  69         // Returns the traced entity if the player can edit it, and world if not.
  70         // If permissions if false, the object is returned regardless of editing rights.
  71         // Attached objects are SOLID_NOT and do not get traced.
  72
  73         crosshair_trace_plusvisibletriggers(self);
  74         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  75                 return world; // out of trace range
  76         if(trace_ent.classname != "object")
  77                 return world; // entity is not an object
  78         if(!permissions)
  79                 return trace_ent; // don't check permissions, anyone can edit this object
  80         if(trace_ent.crypto_idfp == "")
  81                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  82         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
  83                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  84         return world;
  85 }
  86
  87 void sandbox_ObjectEdit_Scale(entity e, float f)
  88 {
  89         e.scale = f;
  90         if(e.scale)
  91         {
  92                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  93                 _setmodel(e, e.model); // reset mins and maxs based on mesh
  94                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  95         }
  96 }
  97
  98 void sandbox_ObjectAttach_Remove(entity e);
  99 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 100 {
 101         // attaches e to parent on string s
 102
 103         // we can't attach to an attachment, for obvious reasons
 104         sandbox_ObjectAttach_Remove(e);
 105
 106         e.old_solid = e.solid; // persist solidity
 107         e.old_movetype = e.movetype; // persist physics
 108         e.movetype = MOVETYPE_FOLLOW;
 109         e.solid = SOLID_NOT;
 110         e.takedamage = DAMAGE_NO;
 111
 112         setattachment(e, parent, s);
 113         e.owner = parent;
 114 }
 115
 116 void sandbox_ObjectAttach_Remove(entity e)
 117 {
 118         // detaches any object attached to e
 119
 120         entity head;
 121         for(head = world; (head = find(head, classname, "object")); )
 122         {
 123                 if(head.owner == e)
 124                 {
 125                         vector org;
 126                         org = gettaginfo(head, 0);
 127                         setattachment(head, world, "");
 128                         head.owner = world;
 129
 130                         // objects change origin and angles when detached, so apply previous position
 131                         setorigin(head, org);
 132                         head.angles = e.angles; // don't allow detached objects to spin or roll
 133
 134                         head.solid = head.old_solid; // restore persisted solidity
 135                         head.movetype = head.old_movetype; // restore persisted physics
 136                         head.takedamage = DAMAGE_AIM;
 137                 }
 138         }
 139 }
 140
 141 entity sandbox_ObjectSpawn(float database)
 142 {SELFPARAM();
 143         // spawn a new object with default properties
 144
 145         entity e = spawn();
 146         e.classname = "object";
 147         e.takedamage = DAMAGE_AIM;
 148         e.damageforcescale = 1;
 149         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 150         e.movetype = MOVETYPE_TOSS;
 151         e.frame = 0;
 152         e.skin = 0;
 153         e.material = string_null;
 154         e.touch = sandbox_ObjectFunction_Touch;
 155         e.think = sandbox_ObjectFunction_Think;
 156         e.nextthink = time;
 157         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 158
 159         if(!database)
 160         {
 161                 // set the object's owner via player UID
 162                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 163                 if(self.crypto_idfp != "")
 164                         e.crypto_idfp = strzone(self.crypto_idfp);
 165                 else
 166                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 167
 168                 // set public object information
 169                 e.netname = strzone(self.netname); // name of the owner
 170                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 171                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 172
 173                 // set origin and direction based on player position and view angle
 174                 makevectors(self.v_angle);
 175                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 176                 setorigin(e, trace_endpos);
 177                 e.angles_y = self.v_angle.y;
 178         }
 179
 180         WITH(entity, self, e, CSQCMODEL_AUTOINIT(e));
 181
 182         object_count += 1;
 183         return e;
 184 }
 185
 186 void sandbox_ObjectRemove(entity e)
 187 {
 188         sandbox_ObjectAttach_Remove(e); // detach child objects
 189
 190         // if the object being removed has been selected for attachment by a player, unset it
 191         entity head;
 192         FOR_EACH_REALPLAYER(head) // bots can't have objects
 193         {
 194                 if(head.object_attach == e)
 195                         head.object_attach = world;
 196         }
 197
 198         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 199         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 200         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 201         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 202         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 203         remove(e);
 204         e = world;
 205
 206         object_count -= 1;
 207 }
 208
 209 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 210
 211 string sandbox_ObjectPort_Save(entity e, float database)
 212 {
 213         // save object properties, and return them as a string
 214         float i = 0;
 215         string s;
 216         entity head;
 217
 218         for(head = world; (head = find(head, classname, "object")); )
 219         {
 220                 // the main object needs to be first in the array [0] with attached objects following
 221                 float slot, physics, solidity;
 222                 if(head == e) // this is the main object, place it first
 223                 {
 224                         slot = 0;
 225                         solidity = head.solid; // applied solidity is normal solidity for children
 226                         physics = head.movetype; // applied physics are normal physics for parents
 227                 }
 228                 else if(head.owner == e) // child object, list them in order
 229                 {
 230                         i += 1; // children start from 1
 231                         slot = i;
 232                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 233                         physics = head.old_movetype; // persisted physics are normal physics for children
 234                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 235                 }
 236                 else
 237                         continue;
 238
 239                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 240                 if(slot)
 241                 {
 242                         // properties stored only for child objects
 243                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 244                 }
 245                 else
 246                 {
 247                         // properties stored only for parent objects
 248                         if(database)
 249                         {
 250                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 251                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 252                         }
 253                 }
 254                 // properties stored for all objects
 255                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 256                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 257                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 258                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 259                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 260                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 261                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 262                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 263                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 264                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 265                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 266                 if(database)
 267                 {
 268                         // properties stored only for the database
 269                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 270                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 271                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 272                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 273                 }
 274         }
 275
 276         // now apply the array to a simple string, with the ; symbol separating objects
 277         s = "";
 278         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 279         {
 280                 if(port_string[i])
 281                         s = strcat(s, port_string[i], "; ");
 282                 port_string[i] = string_null; // fully clear the string
 283         }
 284
 285         return s;
 286 }
 287
 288 entity sandbox_ObjectPort_Load(string s, float database)
 289 {
 290         // load object properties, and spawn a new object with them
 291         float n, i;
 292         entity e = world, parent = world;
 293
 294         // separate objects between the ; symbols
 295         n = tokenizebyseparator(s, "; ");
 296         for(i = 0; i < n; ++i)
 297                 port_string[i] = argv(i);
 298
 299         // now separate and apply the properties of each object
 300         for(i = 0; i < n; ++i)
 301         {
 302                 float argv_num;
 303                 string tagname = string_null;
 304                 argv_num = 0;
 305                 tokenize_console(port_string[i]);
 306                 e = sandbox_ObjectSpawn(database);
 307
 308                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 309                 if(i)
 310                 {
 311                         // properties stored only for child objects
 312                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 313                 }
 314                 else
 315                 {
 316                         // properties stored only for parent objects
 317                         if(database)
 318                         {
 319                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 320                                 e.angles = stov(argv(argv_num));        ++argv_num;
 321                         }
 322                         parent = e; // mark parent objects as such
 323                 }
 324                 // properties stored for all objects
 325                 _setmodel(e, argv(argv_num));   ++argv_num;
 326                 e.skin = stof(argv(argv_num));  ++argv_num;
 327                 e.alpha = stof(argv(argv_num)); ++argv_num;
 328                 e.colormod = stov(argv(argv_num));      ++argv_num;
 329                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 330                 e.frame = stof(argv(argv_num)); ++argv_num;
 331                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 332                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 333                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 334                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 335                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 336                 if(database)
 337                 {
 338                         // properties stored only for the database
 339                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 340                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 341                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 342                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 343                 }
 344
 345                 // attach last
 346                 if(i)
 347                         sandbox_ObjectAttach_Set(e, parent, tagname);
 348         }
 349
 350         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 351                 port_string[i] = string_null; // fully clear the string
 352
 353         return e;
 354 }
 355
 356 void sandbox_Database_Save()
 357 {
 358         // saves all objects to the database file
 359         entity head;
 360         string file_name;
 361         float file_get;
 362
 363         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 364         file_get = fopen(file_name, FILE_WRITE);
 365         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 366         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 367
 368         for(head = world; (head = find(head, classname, "object")); )
 369         {
 370                 // attached objects are persisted separately, ignore them here
 371                 if(head.owner != world)
 372                         continue;
 373
 374                 // use a line of text for each object, listing all properties
 375                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
 376         }
 377         fclose(file_get);
 378 }
 379
 380 void sandbox_Database_Load()
 381 {
 382         // loads all objects from the database file
 383         string file_read, file_name;
 384         float file_get, i;
 385
 386         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 387         file_get = fopen(file_name, FILE_READ);
 388         if(file_get < 0)
 389         {
 390                 if(autocvar_g_sandbox_info > 0)
 391                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 392         }
 393         else
 394         {
 395                 for (;;)
 396                 {
 397                         file_read = fgets(file_get);
 398                         if(file_read == "")
 399                                 break;
 400                         if(substring(file_read, 0, 2) == "//")
 401                                 continue;
 402                         if(substring(file_read, 0, 1) == "#")
 403                                 continue;
 404
 405                         entity e;
 406                         e = sandbox_ObjectPort_Load(file_read, true);
 407
 408                         if(e.material)
 409                         {
 410                                 // since objects are being loaded for the first time, precache material sounds for each
 411                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 412                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 413                         }
 414                 }
 415                 if(autocvar_g_sandbox_info > 0)
 416                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 417         }
 418         fclose(file_get);
 419 }
 420
 421 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 422 {SELFPARAM();
 423         if(MUTATOR_RETURNVALUE) // command was already handled?
 424                 return false;
 425         if(cmd_name == "g_sandbox")
 426         {
 427                 if(autocvar_g_sandbox_readonly)
 428                 {
 429                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 430                         return true;
 431                 }
 432                 if(cmd_argc < 2)
 433                 {
 434                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 435                         return true;
 436                 }
 437
 438                 switch(argv(1))
 439                 {
 440                         entity e;
 441                         float i;
 442                         string s;
 443
 444                         // ---------------- COMMAND: HELP ----------------
 445                         case "help":
 446                                 print_to(self, "You can use the following sandbox commands:");
 447                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 448                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 449                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 450                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 451                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 452                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 453                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 454                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 455                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 456                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 457                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 458                                 print_to(self, "^3alpha value ^7- sets object transparency");
 459                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 460                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 461                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 462                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 463                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 464                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 465                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 466                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 467                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 468                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 469                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 470                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 471                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 472                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 473                                 return true;
 474
 475                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 476                         case "object_spawn":
 477                                 if(time < self.object_flood)
 478                                 {
 479                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 480                                         return true;
 481                                 }
 482                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 483                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 484                                 {
 485                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 486                                         return true;
 487                                 }
 488                                 if(cmd_argc < 3)
 489                                 {
 490                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 491                                         return true;
 492                                 }
 493                                 if (!(fexists(argv(2))))
 494                                 {
 495                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 496                                         return true;
 497                                 }
 498
 499                                 e = sandbox_ObjectSpawn(false);
 500                                 _setmodel(e, argv(2));
 501
 502                                 if(autocvar_g_sandbox_info > 0)
 503                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 504                                 return true;
 505
 506                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 507                         case "object_remove":
 508                                 e = sandbox_ObjectEdit_Get(true);
 509                                 if(e != world)
 510                                 {
 511                                         if(autocvar_g_sandbox_info > 0)
 512                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 513                                         sandbox_ObjectRemove(e);
 514                                         return true;
 515                                 }
 516
 517                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 518                                 return true;
 519
 520                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 521                         case "object_duplicate":
 522                                 switch(argv(2))
 523                                 {
 524                                         case "copy":
 525                                                 // copies customizable properties of the selected object to the clipboard cvar
 526                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 527                                                 if(e != world)
 528                                                 {
 529                                                         s = sandbox_ObjectPort_Save(e, false);
 530                                                         s = strreplace("\"", "\\\"", s);
 531                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 532
 533                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 534                                                         return true;
 535                                                 }
 536                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 537                                                 return true;
 538
 539                                         case "paste":
 540                                                 // spawns a new object using the properties in the player's clipboard cvar
 541                                                 if(time < self.object_flood)
 542                                                 {
 543                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 544                                                         return true;
 545                                                 }
 546                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 547                                                 if(argv(3) == "") // no object in clipboard
 548                                                 {
 549                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 550                                                         return true;
 551                                                 }
 552                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 553                                                 {
 554                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 555                                                         return true;
 556                                                 }
 557                                                 e = sandbox_ObjectPort_Load(argv(3), false);
 558
 559                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 560                                                 if(autocvar_g_sandbox_info > 0)
 561                                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 562                                                 return true;
 563                                 }
 564                                 return true;
 565
 566                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 567                         case "object_attach":
 568                                 switch(argv(2))
 569                                 {
 570                                         case "get":
 571                                                 // select e as the object as meant to be attached
 572                                                 e = sandbox_ObjectEdit_Get(true);
 573                                                 if(e != world)
 574                                                 {
 575                                                         self.object_attach = e;
 576                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 577                                                         return true;
 578                                                 }
 579                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 580                                                 return true;
 581                                         case "set":
 582                                                 if(self.object_attach == world)
 583                                                 {
 584                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 585                                                         return true;
 586                                                 }
 587
 588                                                 // attaches the previously selected object to e
 589                                                 e = sandbox_ObjectEdit_Get(true);
 590                                                 if(e != world)
 591                                                 {
 592                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 593                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 594                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 595                                                         if(autocvar_g_sandbox_info > 1)
 596                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 597                                                         return true;
 598                                                 }
 599                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 600                                                 return true;
 601                                         case "remove":
 602                                                 // removes e if it was attached
 603                                                 e = sandbox_ObjectEdit_Get(true);
 604                                                 if(e != world)
 605                                                 {
 606                                                         sandbox_ObjectAttach_Remove(e);
 607                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 608                                                         if(autocvar_g_sandbox_info > 1)
 609                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 610                                                         return true;
 611                                                 }
 612                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 613                                                 return true;
 614                                 }
 615                                 return true;
 616
 617                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 618                         case "object_edit":
 619                                 if(argv(2) == "")
 620                                 {
 621                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 622                                         return true;
 623                                 }
 624
 625                                 e = sandbox_ObjectEdit_Get(true);
 626                                 if(e != world)
 627                                 {
 628                                         switch(argv(2))
 629                                         {
 630                                                 case "skin":
 631                                                         e.skin = stof(argv(3));
 632                                                         break;
 633                                                 case "alpha":
 634                                                         e.alpha = stof(argv(3));
 635                                                         break;
 636                                                 case "color_main":
 637                                                         e.colormod = stov(argv(3));
 638                                                         break;
 639                                                 case "color_glow":
 640                                                         e.glowmod = stov(argv(3));
 641                                                         break;
 642                                                 case "frame":
 643                                                         e.frame = stof(argv(3));
 644                                                         break;
 645                                                 case "scale":
 646                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 647                                                         break;
 648                                                 case "solidity":
 649                                                         switch(argv(3))
 650                                                         {
 651                                                                 case "0": // non-solid
 652                                                                         e.solid = SOLID_TRIGGER;
 653                                                                         break;
 654                                                                 case "1": // solid
 655                                                                         e.solid = SOLID_BBOX;
 656                                                                         break;
 657                                                                 default:
 658                                                                         break;
 659                                                         }
 660                                                 case "physics":
 661                                                         switch(argv(3))
 662                                                         {
 663                                                                 case "0": // static
 664                                                                         e.movetype = MOVETYPE_NONE;
 665                                                                         break;
 666                                                                 case "1": // movable
 667                                                                         e.movetype = MOVETYPE_TOSS;
 668                                                                         break;
 669                                                                 case "2": // physical
 670                                                                         e.movetype = MOVETYPE_PHYSICS;
 671                                                                         break;
 672                                                                 default:
 673                                                                         break;
 674                                                         }
 675                                                         break;
 676                                                 case "force":
 677                                                         e.damageforcescale = stof(argv(3));
 678                                                         break;
 679                                                 case "material":
 680                                                         if(e.material)  strunzone(e.material);
 681                                                         if(argv(3))
 682                                                         {
 683                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 684                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
 685                                                                 e.material = strzone(argv(3));
 686                                                         }
 687                                                         else
 688                                                                 e.material = string_null; // no material
 689                                                         break;
 690                                                 default:
 691                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 692                                                         return true;
 693                                         }
 694
 695                                         // update last editing time
 696                                         if(e.message2)  strunzone(e.message2);
 697                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
 698
 699                                         if(autocvar_g_sandbox_info > 1)
 700                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 701                                         return true;
 702                                 }
 703
 704                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 705                                 return true;
 706
 707                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 708                         case "object_claim":
 709                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 710                                 if(self.crypto_idfp == "")
 711                                 {
 712                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 713                                         return true;
 714                                 }
 715                                 e = sandbox_ObjectEdit_Get(true);
 716                                 if(e != world)
 717                                 {
 718                                         // update the owner's name
 719                                         // Do this before checking if you're already the owner and skipping if such, so we
 720                                         // also update the player's nickname if he changed it (but has the same player UID)
 721                                         if(e.netname != self.netname)
 722                                         {
 723                                                 if(e.netname)   strunzone(e.netname);
 724                                                 e.netname = strzone(self.netname);
 725                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 726                                         }
 727
 728                                         if(e.crypto_idfp == self.crypto_idfp)
 729                                         {
 730                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 731                                                 return true;
 732                                         }
 733
 734                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 735                                         e.crypto_idfp = strzone(self.crypto_idfp);
 736
 737                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 738                                 }
 739                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 740                                 return true;
 741
 742                         // ---------------- COMMAND: OBJECT, INFO ----------------
 743                         case "object_info":
 744                                 // prints public information about the object to the player
 745                                 e = sandbox_ObjectEdit_Get(false);
 746                                 if(e != world)
 747                                 {
 748                                         switch(argv(2))
 749                                         {
 750                                                 case "object":
 751                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 752                                                         return true;
 753                                                 case "mesh":
 754                                                         s = "";
 755                                                         FOR_EACH_TAG(e)
 756                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 757                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 758                                                         return true;
 759                                                 case "attachments":
 760                                                         // this should show the same info as 'mesh' but for attachments
 761                                                         s = "";
 762                                                         entity head;
 763                                                         i = 0;
 764                                                         for(head = world; (head = find(head, classname, "object")); )
 765                                                         {
 766                                                                 if(head.owner == e)
 767                                                                 {
 768                                                                         ++i; // start from 1
 769                                                                         gettaginfo(e, head.tag_index);
 770                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 771                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 772                                                                 }
 773                                                         }
 774                                                         if(i) // object contains attachments
 775                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 776                                                         else
 777                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 778                                                         return true;
 779                                         }
 780                                 }
 781                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 782                                 return true;
 783
 784                         // ---------------- COMMAND: DEFAULT ----------------
 785                         default:
 786                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 787                                 return true;
 788                 }
 789         }
 790         return false;
 791 }
 792
 793 float autosave_time;
 794 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 795 {
 796         if(!autocvar_g_sandbox_storage_autosave)
 797                 return false;
 798         if(time < autosave_time)
 799                 return false;
 800         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 801
 802         sandbox_Database_Save();
 803
 804         return true;
 805 }
 806
 807 MUTATOR_HOOKFUNCTION(sandbox_SetModname)
 808 {
 809         modname = "Sandbox";
 810         return true;
 811 }
 812
 813 MUTATOR_DEFINITION(sandbox)
 814 {
 815         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 816         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 817         MUTATOR_HOOK(SetModname, sandbox_SetModname, CBC_ORDER_ANY);
 818
 819         MUTATOR_ONADD
 820         {
 821                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 822                 if(autocvar_g_sandbox_storage_autoload)
 823                         sandbox_Database_Load();
 824         }
 825
 826         MUTATOR_ONROLLBACK_OR_REMOVE
 827         {
 828                 // nothing to roll back
 829         }
 830
 831         MUTATOR_ONREMOVE
 832         {
 833                 // nothing to remove
 834         }
 835
 836         return false;
 837 }
 838