qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.movetype = MOVETYPE_FOLLOW;
  72         e.solid = SOLID_NOT;
  73         e.takedamage = DAMAGE_NO;
  74
  75         setattachment(e, parent, s);
  76         e.owner = parent;
  77 }
  78
  79 void sandbox_ObjectAttach_Remove(entity e)
  80 {
  81         // detaches any object attached to e
  82
  83         entity head;
  84         for(head = world; (head = find(head, classname, "object")); )
  85         {
  86                 if(head.owner == e)
  87                 {
  88                         vector org;
  89                         head.movetype = MOVETYPE_TOSS; // default
  90                         head.solid = SOLID_BBOX;
  91                         head.takedamage = DAMAGE_AIM;
  92
  93                         org = gettaginfo(head, 0);
  94                         setattachment(head, world, "");
  95                         head.owner = world;
  96
  97                         // objects change origin and angles when detached, so apply previous position
  98                         setorigin(head, org);
  99                         head.angles = e.angles; // don't allow detached objects to spin or roll
 100                 }
 101         }
 102 }
 103
 104 entity sandbox_ObjectSpawn(float database)
 105 {
 106         // spawn a new object with default properties
 107
 108         entity e;
 109         e = spawn();
 110         e.classname = "object";
 111         e.takedamage = DAMAGE_AIM;
 112         e.damageforcescale = 1;
 113         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 114         e.movetype = MOVETYPE_TOSS;
 115         e.frame = 0;
 116         e.skin = 0;
 117         e.material = string_null;
 118         e.touch = sandbox_ObjectFunction_Touch;
 119
 120         if(!database)
 121         {
 122                 // set the object's owner via player UID
 123                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 124                 if(self.crypto_idfp != "")
 125                         e.crypto_idfp = strzone(self.crypto_idfp);
 126                 else
 127                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 128
 129                 // set origin and direction based on player position and view angle
 130                 makevectors(self.v_angle);
 131                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 132                 setorigin(e, trace_endpos);
 133                 e.angles_y = self.v_angle_y;
 134         }
 135
 136         object_count += 1;
 137         return e;
 138 }
 139
 140 void sandbox_ObjectRemove(entity e)
 141 {
 142         sandbox_ObjectAttach_Remove(e); // detach child objects
 143         if(e.material)
 144         {
 145                 strunzone(e.material);
 146                 e.material = string_null;
 147         }
 148         if(e.crypto_idfp)
 149         {
 150                 strunzone(e.crypto_idfp);
 151                 e.crypto_idfp = string_null;
 152         }
 153         remove(e);
 154         e = world;
 155
 156         object_count -= 1;
 157 }
 158
 159 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 160
 161 string sandbox_ObjectPort_Save(entity e, float database)
 162 {
 163         // save object properties, and return them as a string
 164         float i;
 165         string s;
 166         entity head;
 167
 168         for(head = world; (head = find(head, classname, "object")); )
 169         {
 170                 // the main object needs to be first in the array [0], with attached objects following
 171                 float slot;
 172                 if(head == e) // this is the main object, make it first
 173                         slot = 0;
 174                 else if(head.owner == e) // child object, list them in order
 175                 {
 176                         i += 1; // children start from 1
 177                         slot = i;
 178                 }
 179                 else
 180                         continue;
 181
 182                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 183                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 184                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 185                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 186                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 187                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 188                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 189                 port_string[slot] = strcat(port_string[slot], ftos(head.movetype), " ");
 190                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 191                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 192                 gettaginfo(head, 0); if(gettaginfo_name)        port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 193                 if(database)
 194                 {
 195                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 196                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 197                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 198                 }
 199         }
 200
 201         // now apply the array to a simple string, with the ; symbol separating objects
 202         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 203         {
 204                 if(port_string[i])
 205                         s = strcat(s, port_string[i], "; ");
 206                 port_string[i] = string_null; // fully clear the string
 207         }
 208
 209         return s;
 210 }
 211
 212 entity sandbox_ObjectPort_Load(string s, float database)
 213 {
 214         // load object properties, and spawn a new object with them
 215         float n, i;
 216         entity e, parent;
 217
 218         // separate objects between the ; symbols
 219         n = tokenizebyseparator(s, "; ");
 220         for(i = 0; i < n; ++i)
 221                 port_string[i] = argv(i);
 222
 223         // now separate and apply the properties of each object
 224         for(i = 0; i < n; ++i)
 225         {
 226                 string taginfo;
 227                 tokenize_console(port_string[i]);
 228                 e = sandbox_ObjectSpawn(database);
 229
 230                 setmodel(e, argv(0));
 231                 e.skin = stof(argv(1));
 232                 e.alpha = stof(argv(2));
 233                 e.colormod = stov(argv(3));
 234                 e.glowmod = stov(argv(4));
 235                 e.frame = stof(argv(5));
 236                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 237                 e.movetype = stof(argv(7));
 238                 e.damageforcescale = stof(argv(8));
 239                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 240                 if(argv(10) != "-")     taginfo = argv(10);     else    taginfo = string_null;
 241                 if(database)
 242                 {
 243                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(11) != "-")     e.crypto_idfp = strzone(argv(11));      else    e.crypto_idfp = string_null;
 244                         setorigin(e, stov(argv(12)));
 245                         e.angles = stov(argv(13));
 246                 }
 247
 248                 if(!i) // parent object, set it as such and leave it be
 249                         parent = e;
 250                 else // child object, attach it to the parent
 251                         sandbox_ObjectAttach_Set(e, parent, taginfo);
 252         }
 253
 254         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 255                 port_string[i] = string_null; // fully clear the string
 256
 257         return e;
 258 }
 259
 260 void sandbox_Database_Save()
 261 {
 262         // saves all objects to the database file
 263         entity head;
 264         string file_name;
 265         float file_get;
 266
 267         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 268         file_get = fopen(file_name, FILE_WRITE);
 269         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 270         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 271
 272         for(head = world; (head = find(head, classname, "object")); )
 273         {
 274                 // attached objects are persisted separately, ignore them here
 275                 if(head.owner != world)
 276                         continue;
 277
 278                 // use a line of text for each object, listing all properties
 279                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 280         }
 281         fclose(file_get);
 282 }
 283
 284 void sandbox_Database_Load()
 285 {
 286         // loads all objects from the database file
 287         string file_read, file_name;
 288         float file_get, i;
 289
 290         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 291         file_get = fopen(file_name, FILE_READ);
 292         if(file_get < 0)
 293         {
 294                 if(autocvar_g_sandbox_info > 0)
 295                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 296         }
 297         else
 298         {
 299                 for(;;)
 300                 {
 301                         file_read = fgets(file_get);
 302                         if(!file_read)
 303                                 break;
 304                         if(substring(file_read, 0, 2) == "//")
 305                                 continue;
 306                         if(substring(file_read, 0, 1) == "#")
 307                                 continue;
 308
 309                         entity e;
 310                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 311
 312                         if(e.material)
 313                         {
 314                                 // since objects are being loaded for the first time, precache material sounds for each
 315                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 316                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 317                         }
 318                 }
 319                 if(autocvar_g_sandbox_info > 0)
 320                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 321         }
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 325 {
 326         if(MUTATOR_RETURNVALUE) // command was already handled?
 327                 return FALSE;
 328         if(cmd_name == "g_sandbox")
 329         {
 330                 if(cmd_argc < 2)
 331                 {
 332                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 333                         return TRUE;
 334                 }
 335
 336                 switch(argv(1))
 337                 {
 338                         entity e;
 339                         float i;
 340
 341                         // ---------------- COMMAND: HELP ----------------
 342                         case "help":
 343                                 print_to(self, "You can use the following sandbox commands:");
 344                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 345                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 346                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 347                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 348                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 349                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 350                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 351                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 352                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 353                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 354                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 355                                 print_to(self, "^3alpha value ^7- sets object transparency");
 356                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 357                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 358                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 359                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 360                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 361                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 362                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 363                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 364                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 365                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 366                                 return TRUE;
 367
 368                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 369                         case "object_spawn":
 370                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 371                                 {
 372                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 373                                         return TRUE;
 374                                 }
 375                                 if(cmd_argc < 3)
 376                                 {
 377                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 378                                         return TRUE;
 379                                 }
 380                                 else if not(fexists(argv(2)))
 381                                 {
 382                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 383                                         return TRUE;
 384                                 }
 385
 386                                 e = sandbox_ObjectSpawn(FALSE);
 387                                 setmodel(e, argv(2));
 388
 389                                 if(autocvar_g_sandbox_info > 0)
 390                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 391                                 return TRUE;
 392
 393                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 394                         case "object_remove":
 395                                 e = sandbox_ObjectEdit_Get(TRUE);
 396                                 if(e != world)
 397                                 {
 398                                         if(autocvar_g_sandbox_info > 0)
 399                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 400                                         sandbox_ObjectRemove(e);
 401                                         return TRUE;
 402                                 }
 403
 404                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 405                                 return TRUE;
 406
 407                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 408                         case "object_duplicate":
 409                                 switch(argv(2))
 410                                 {
 411                                         case "copy":
 412                                                 // copies customizable properties of the selected object to the clipboard
 413                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 414                                                 if(e != world)
 415                                                 {
 416                                                         if(self.object_clipboard)
 417                                                                 strunzone(self.object_clipboard);
 418                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 419
 420                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 421                                                         return TRUE;
 422                                                 }
 423                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 424                                                 return TRUE;
 425
 426                                         case "paste":
 427                                                 // spawns a new object using the properties in the player's clipboard
 428                                                 if(!self.object_clipboard) // no object in clipboard
 429                                                 {
 430                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 431                                                         return TRUE;
 432                                                 }
 433                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 434                                                 {
 435                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 436                                                         return TRUE;
 437                                                 }
 438
 439                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 440
 441                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 442                                                 if(autocvar_g_sandbox_info > 0)
 443                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 444                                                 return TRUE;
 445                                 }
 446                                 return TRUE;
 447
 448                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 449                         case "object_attach":
 450                                 switch(argv(2))
 451                                 {
 452                                         case "get":
 453                                                 // select e as the object as meant to be attached
 454                                                 e = sandbox_ObjectEdit_Get(TRUE);
 455                                                 if(e != world)
 456                                                 {
 457                                                         self.object_attach = e;
 458                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 459                                                         return TRUE;
 460                                                 }
 461                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 462                                                 return TRUE;
 463                                         case "set":
 464                                                 if(self.object_attach == world)
 465                                                 {
 466                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 467                                                         return TRUE;
 468                                                 }
 469
 470                                                 // attaches the previously selected object to e
 471                                                 e = sandbox_ObjectEdit_Get(TRUE);
 472                                                 if(e != world)
 473                                                 {
 474                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 475                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 476                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 477                                                         if(autocvar_g_sandbox_info > 1)
 478                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 479                                                         return TRUE;
 480                                                 }
 481                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 482                                                 return TRUE;
 483                                         case "remove":
 484                                                 // removes e if it was attached
 485                                                 e = sandbox_ObjectEdit_Get(TRUE);
 486                                                 if(e != world)
 487                                                 {
 488                                                         sandbox_ObjectAttach_Remove(e);
 489                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 490                                                         if(autocvar_g_sandbox_info > 1)
 491                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 492                                                         return TRUE;
 493                                                 }
 494                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 495                                                 return TRUE;
 496                                 }
 497                                 return TRUE;
 498
 499                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 500                         case "object_edit":
 501                                 if(!argv(2))
 502                                 {
 503                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 504                                         return TRUE;
 505                                 }
 506
 507                                 e = sandbox_ObjectEdit_Get(TRUE);
 508                                 if(e != world)
 509                                 {
 510                                         switch(argv(2))
 511                                         {
 512                                                 case "skin":
 513                                                         e.skin = stof(argv(3));
 514                                                         break;
 515                                                 case "alpha":
 516                                                         e.alpha = stof(argv(3));
 517                                                         break;
 518                                                 case "color_main":
 519                                                         e.colormod = stov(argv(3));
 520                                                         break;
 521                                                 case "color_glow":
 522                                                         e.glowmod = stov(argv(3));
 523                                                         break;
 524                                                 case "frame":
 525                                                         e.frame = stof(argv(3));
 526                                                         break;
 527                                                 case "scale":
 528                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 529                                                         break;
 530                                                 case "physics":
 531                                                         switch(argv(3))
 532                                                         {
 533                                                                 case "0": // static
 534                                                                         e.movetype = MOVETYPE_NONE;
 535                                                                         break;
 536                                                                 case "1": // movable
 537                                                                         e.movetype = MOVETYPE_TOSS;
 538                                                                         break;
 539                                                                 case "2": // physical
 540                                                                         e.movetype = MOVETYPE_PHYSICS;
 541                                                                         break;
 542                                                                 default:
 543                                                                         break;
 544                                                         }
 545                                                         break;
 546                                                 case "force":
 547                                                         e.damageforcescale = stof(argv(3));
 548                                                         break;
 549                                                 case "material":
 550                                                         if(e.material)
 551                                                                 strunzone(e.material);
 552                                                         if(argv(3))
 553                                                         {
 554                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 555                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 556                                                                 e.material = strzone(argv(3));
 557                                                         }
 558                                                         else
 559                                                                 e.material = string_null; // no material
 560                                                         break;
 561                                                 default:
 562                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 563                                                         break;
 564                                         }
 565                                         if(autocvar_g_sandbox_info > 1)
 566                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 567                                         return TRUE;
 568                                 }
 569
 570                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 571                                 return TRUE;
 572
 573                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 574                         case "object_claim":
 575                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 576                                 if(self.crypto_idfp == "")
 577                                 {
 578                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 579                                         return TRUE;
 580                                 }
 581                                 e = sandbox_ObjectEdit_Get(TRUE);
 582                                 if(e != world)
 583                                 {
 584                                         if(e.crypto_idfp == self.crypto_idfp)
 585                                         {
 586                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 587                                                 return TRUE;
 588                                         }
 589
 590                                         if(e.crypto_idfp)
 591                                                 strunzone(e.crypto_idfp);
 592                                         e.crypto_idfp = self.crypto_idfp;
 593                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 594                                 }
 595                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 596                                 return TRUE;
 597
 598                         // ---------------- COMMAND: OBJECT, INFO ----------------
 599                         case "object_info":
 600                                 // prints public information about the object to the player
 601                                 e = sandbox_ObjectEdit_Get(FALSE);
 602                                 if(e != world)
 603                                 {
 604                                         switch(argv(2))
 605                                         {
 606                                                 case "mesh":
 607                                                         string tags;
 608                                                         for(i = 1; gettaginfo(e, i); i++)
 609                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 610                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 611                                                         return TRUE;
 612                                         }
 613                                 }
 614                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 615                                 return TRUE;
 616
 617                         // ---------------- COMMAND: DEFAULT ----------------
 618                         default:
 619                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 620                                 return TRUE;
 621                 }
 622         }
 623         return FALSE;
 624 }
 625
 626 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 627 {
 628         // if the player is close enough to their object, they can drag it
 629
 630         if(autocvar_sv_cheats)
 631                 return FALSE; // cheat dragging is used instead
 632
 633         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 634         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 635         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 636         // it goes out of range while slinging it around.
 637
 638         entity e;
 639         float grab;
 640
 641         e = sandbox_ObjectEdit_Get(TRUE);
 642         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 643                 grab = TRUE;
 644
 645         if(Drag(e, grab)) // execute dragging
 646                 return TRUE;
 647
 648         return FALSE;
 649 }
 650
 651 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 652 {
 653         // unzone the player's clipboard if it's not empty
 654         if(self.object_clipboard)
 655         {
 656                 strunzone(self.object_clipboard);
 657                 self.object_clipboard = string_null;
 658         }
 659
 660         return FALSE;
 661 }
 662
 663 float autosave_time;
 664 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 665 {
 666         if(!autocvar_g_sandbox_storage_autosave)
 667                 return FALSE;
 668         if(time < autosave_time)
 669                 return FALSE;
 670         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 671
 672         sandbox_Database_Save();
 673
 674         return TRUE;
 675 }
 676
 677 MUTATOR_DEFINITION(sandbox)
 678 {
 679         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 680         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 681         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 682         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 683
 684         MUTATOR_ONADD
 685         {
 686                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 687                 if(autocvar_g_sandbox_storage_autoload)
 688                         sandbox_Database_Load();
 689         }
 690
 691         return FALSE;
 692 }
 693