qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_ObjectFunction_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_ObjectEdit_Get(float permissions)
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // if permissions if FALSE, the object is returned regardless of editing rights
  36         // attached objects are SOLID_NOT and don't risk getting traced
  37
  38         makevectors(self.v_angle);
  39         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  40
  41         if(trace_ent.classname != "object")
  42                 return world; // entity is not an object
  43         if(!permissions)
  44                 return trace_ent; // don't check permissions, anyone can edit this object
  45         if(!trace_ent.crypto_idfp)
  46                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  47         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  48                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  49         return world;
  50 }
  51
  52 void sandbox_ObjectEdit_Scale(entity e, float f)
  53 {
  54         e.scale = f;
  55         if(e.scale)
  56         {
  57                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  58                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  59         }
  60 }
  61
  62 .float old_movetype;
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.old_movetype = e.movetype; // persist physics
  72         e.movetype = MOVETYPE_FOLLOW;
  73         e.solid = SOLID_NOT;
  74         e.takedamage = DAMAGE_NO;
  75
  76         setattachment(e, parent, s);
  77         e.owner = parent;
  78 }
  79
  80 void sandbox_ObjectAttach_Remove(entity e)
  81 {
  82         // detaches any object attached to e
  83
  84         entity head;
  85         for(head = world; (head = find(head, classname, "object")); )
  86         {
  87                 if(head.owner == e)
  88                 {
  89                         vector org;
  90                         head.movetype = head.old_movetype; // restore persisted physics
  91                         head.solid = SOLID_BBOX;
  92                         head.takedamage = DAMAGE_AIM;
  93
  94                         org = gettaginfo(head, 0);
  95                         setattachment(head, world, "");
  96                         head.owner = world;
  97
  98                         // objects change origin and angles when detached, so apply previous position
  99                         setorigin(head, org);
 100                         head.angles = e.angles; // don't allow detached objects to spin or roll
 101                 }
 102         }
 103 }
 104
 105 entity sandbox_ObjectSpawn(float database)
 106 {
 107         // spawn a new object with default properties
 108
 109         entity e;
 110         e = spawn();
 111         e.classname = "object";
 112         e.takedamage = DAMAGE_AIM;
 113         e.damageforcescale = 1;
 114         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 115         e.movetype = MOVETYPE_TOSS;
 116         e.frame = 0;
 117         e.skin = 0;
 118         e.material = string_null;
 119         e.touch = sandbox_ObjectFunction_Touch;
 120
 121         if(!database)
 122         {
 123                 // set the object's owner via player UID
 124                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 125                 if(self.crypto_idfp != "")
 126                         e.crypto_idfp = strzone(self.crypto_idfp);
 127                 else
 128                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 129
 130                 // set origin and direction based on player position and view angle
 131                 makevectors(self.v_angle);
 132                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 133                 setorigin(e, trace_endpos);
 134                 e.angles_y = self.v_angle_y;
 135         }
 136
 137         object_count += 1;
 138         return e;
 139 }
 140
 141 void sandbox_ObjectRemove(entity e)
 142 {
 143         sandbox_ObjectAttach_Remove(e); // detach child objects
 144         if(e.material)
 145         {
 146                 strunzone(e.material);
 147                 e.material = string_null;
 148         }
 149         if(e.crypto_idfp)
 150         {
 151                 strunzone(e.crypto_idfp);
 152                 e.crypto_idfp = string_null;
 153         }
 154         remove(e);
 155         e = world;
 156
 157         object_count -= 1;
 158 }
 159
 160 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 161
 162 string sandbox_ObjectPort_Save(entity e, float database)
 163 {
 164         // save object properties, and return them as a string
 165         float i;
 166         string s;
 167         entity head;
 168
 169         for(head = world; (head = find(head, classname, "object")); )
 170         {
 171                 // the main object needs to be first in the array [0] with attached objects following
 172                 float slot, physics;
 173                 if(head == e) // this is the main object, place it first
 174                 {
 175                         slot = 0;
 176                         physics = head.movetype; // applied physics are normal physics for parents
 177                 }
 178                 else if(head.owner == e) // child object, list them in order
 179                 {
 180                         i += 1; // children start from 1
 181                         slot = i;
 182                         physics = head.old_movetype; // persisted physics are normal physics for children
 183                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 184                 }
 185                 else
 186                         continue;
 187
 188                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 189                 if(slot)
 190                 {
 191                         // properties stored only for child objects
 192                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 193                 }
 194                 else
 195                 {
 196                         // properties stored only for parent objects
 197                         if(database)
 198                         {
 199                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 200                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 201                         }
 202                 }
 203                 // properties stored for all objects
 204                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 205                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 206                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 207                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 208                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 209                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 210                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 212                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 213                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 214                 if(database)
 215                 {
 216                         // properties stored only for the database
 217                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 218                 }
 219         }
 220
 221         // now apply the array to a simple string, with the ; symbol separating objects
 222         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 223         {
 224                 if(port_string[i])
 225                         s = strcat(s, port_string[i], "; ");
 226                 port_string[i] = string_null; // fully clear the string
 227         }
 228
 229         return s;
 230 }
 231
 232 entity sandbox_ObjectPort_Load(string s, float database)
 233 {
 234         // load object properties, and spawn a new object with them
 235         float n, i;
 236         entity e, parent;
 237
 238         // separate objects between the ; symbols
 239         n = tokenizebyseparator(s, "; ");
 240         for(i = 0; i < n; ++i)
 241                 port_string[i] = argv(i);
 242
 243         // now separate and apply the properties of each object
 244         for(i = 0; i < n; ++i)
 245         {
 246                 float argv_num;
 247                 string tagname;
 248                 argv_num = 0;
 249                 tokenize_console(port_string[i]);
 250                 e = sandbox_ObjectSpawn(database);
 251
 252                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 253                 if(i)
 254                 {
 255                         // properties stored only for child objects
 256                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 257                 }
 258                 else
 259                 {
 260                         // properties stored only for parent objects
 261                         if(database)
 262                         {
 263                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 264                                 e.angles = stov(argv(argv_num));        ++argv_num;
 265                         }
 266                         parent = e; // mark parent objects as such
 267                 }
 268                 // properties stored for all objects
 269                 setmodel(e, argv(argv_num));    ++argv_num;
 270                 e.skin = stof(argv(argv_num));  ++argv_num;
 271                 e.alpha = stof(argv(argv_num)); ++argv_num;
 272                 e.colormod = stov(argv(argv_num));      ++argv_num;
 273                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 274                 e.frame = stof(argv(argv_num)); ++argv_num;
 275                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 276                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 277                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 278                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 279                 if(database)
 280                 {
 281                         // properties stored only for the database
 282                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 283                 }
 284
 285                 // attach last
 286                 if(i)
 287                         sandbox_ObjectAttach_Set(e, parent, tagname);
 288         }
 289
 290         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 291                 port_string[i] = string_null; // fully clear the string
 292
 293         return e;
 294 }
 295
 296 void sandbox_Database_Save()
 297 {
 298         // saves all objects to the database file
 299         entity head;
 300         string file_name;
 301         float file_get;
 302
 303         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 304         file_get = fopen(file_name, FILE_WRITE);
 305         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 306         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 307
 308         for(head = world; (head = find(head, classname, "object")); )
 309         {
 310                 // attached objects are persisted separately, ignore them here
 311                 if(head.owner != world)
 312                         continue;
 313
 314                 // use a line of text for each object, listing all properties
 315                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 316         }
 317         fclose(file_get);
 318 }
 319
 320 void sandbox_Database_Load()
 321 {
 322         // loads all objects from the database file
 323         string file_read, file_name;
 324         float file_get, i;
 325
 326         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 327         file_get = fopen(file_name, FILE_READ);
 328         if(file_get < 0)
 329         {
 330                 if(autocvar_g_sandbox_info > 0)
 331                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 332         }
 333         else
 334         {
 335                 for(;;)
 336                 {
 337                         file_read = fgets(file_get);
 338                         if(!file_read)
 339                                 break;
 340                         if(substring(file_read, 0, 2) == "//")
 341                                 continue;
 342                         if(substring(file_read, 0, 1) == "#")
 343                                 continue;
 344
 345                         entity e;
 346                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 347
 348                         if(e.material)
 349                         {
 350                                 // since objects are being loaded for the first time, precache material sounds for each
 351                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 352                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 353                         }
 354                 }
 355                 if(autocvar_g_sandbox_info > 0)
 356                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 357         }
 358 }
 359
 360 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 361 {
 362         if(MUTATOR_RETURNVALUE) // command was already handled?
 363                 return FALSE;
 364         if(cmd_name == "g_sandbox")
 365         {
 366                 if(cmd_argc < 2)
 367                 {
 368                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 369                         return TRUE;
 370                 }
 371
 372                 switch(argv(1))
 373                 {
 374                         entity e;
 375                         float i;
 376                         string s;
 377
 378                         // ---------------- COMMAND: HELP ----------------
 379                         case "help":
 380                                 print_to(self, "You can use the following sandbox commands:");
 381                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 382                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 383                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 384                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 385                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 386                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 387                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 388                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 389                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 390                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 391                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 392                                 print_to(self, "^3alpha value ^7- sets object transparency");
 393                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 394                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 395                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 396                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 397                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 398                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 399                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 400                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 401                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 402                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 403                                 return TRUE;
 404
 405                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 406                         case "object_spawn":
 407                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 408                                 {
 409                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 410                                         return TRUE;
 411                                 }
 412                                 if(cmd_argc < 3)
 413                                 {
 414                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 415                                         return TRUE;
 416                                 }
 417                                 else if not(fexists(argv(2)))
 418                                 {
 419                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 420                                         return TRUE;
 421                                 }
 422
 423                                 e = sandbox_ObjectSpawn(FALSE);
 424                                 setmodel(e, argv(2));
 425
 426                                 if(autocvar_g_sandbox_info > 0)
 427                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 428                                 return TRUE;
 429
 430                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 431                         case "object_remove":
 432                                 e = sandbox_ObjectEdit_Get(TRUE);
 433                                 if(e != world)
 434                                 {
 435                                         if(autocvar_g_sandbox_info > 0)
 436                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 437                                         sandbox_ObjectRemove(e);
 438                                         return TRUE;
 439                                 }
 440
 441                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 442                                 return TRUE;
 443
 444                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 445                         case "object_duplicate":
 446                                 switch(argv(2))
 447                                 {
 448                                         case "copy":
 449                                                 // copies customizable properties of the selected object to the clipboard
 450                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 451                                                 if(e != world)
 452                                                 {
 453                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 454                                                         s = strreplace("\"", "\\\"", s);
 455                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 456
 457                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 458                                                         return TRUE;
 459                                                 }
 460                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 461                                                 return TRUE;
 462
 463                                         case "paste":
 464                                                 // spawns a new object using the properties in the player's clipboard
 465                                                 if(!argv(3)) // no object in clipboard
 466                                                 {
 467                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 468                                                         return TRUE;
 469                                                 }
 470                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 471                                                 {
 472                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 473                                                         return TRUE;
 474                                                 }
 475
 476                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 477
 478                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 479                                                 if(autocvar_g_sandbox_info > 0)
 480                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 481                                                 return TRUE;
 482                                 }
 483                                 return TRUE;
 484
 485                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 486                         case "object_attach":
 487                                 switch(argv(2))
 488                                 {
 489                                         case "get":
 490                                                 // select e as the object as meant to be attached
 491                                                 e = sandbox_ObjectEdit_Get(TRUE);
 492                                                 if(e != world)
 493                                                 {
 494                                                         self.object_attach = e;
 495                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 496                                                         return TRUE;
 497                                                 }
 498                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 499                                                 return TRUE;
 500                                         case "set":
 501                                                 if(self.object_attach == world)
 502                                                 {
 503                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 504                                                         return TRUE;
 505                                                 }
 506
 507                                                 // attaches the previously selected object to e
 508                                                 e = sandbox_ObjectEdit_Get(TRUE);
 509                                                 if(e != world)
 510                                                 {
 511                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 512                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 513                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 514                                                         if(autocvar_g_sandbox_info > 1)
 515                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 516                                                         return TRUE;
 517                                                 }
 518                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 519                                                 return TRUE;
 520                                         case "remove":
 521                                                 // removes e if it was attached
 522                                                 e = sandbox_ObjectEdit_Get(TRUE);
 523                                                 if(e != world)
 524                                                 {
 525                                                         sandbox_ObjectAttach_Remove(e);
 526                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 527                                                         if(autocvar_g_sandbox_info > 1)
 528                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 529                                                         return TRUE;
 530                                                 }
 531                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 532                                                 return TRUE;
 533                                 }
 534                                 return TRUE;
 535
 536                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 537                         case "object_edit":
 538                                 if(!argv(2))
 539                                 {
 540                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 541                                         return TRUE;
 542                                 }
 543
 544                                 e = sandbox_ObjectEdit_Get(TRUE);
 545                                 if(e != world)
 546                                 {
 547                                         switch(argv(2))
 548                                         {
 549                                                 case "skin":
 550                                                         e.skin = stof(argv(3));
 551                                                         break;
 552                                                 case "alpha":
 553                                                         e.alpha = stof(argv(3));
 554                                                         break;
 555                                                 case "color_main":
 556                                                         e.colormod = stov(argv(3));
 557                                                         break;
 558                                                 case "color_glow":
 559                                                         e.glowmod = stov(argv(3));
 560                                                         break;
 561                                                 case "frame":
 562                                                         e.frame = stof(argv(3));
 563                                                         break;
 564                                                 case "scale":
 565                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 566                                                         break;
 567                                                 case "physics":
 568                                                         switch(argv(3))
 569                                                         {
 570                                                                 case "0": // static
 571                                                                         e.movetype = MOVETYPE_NONE;
 572                                                                         break;
 573                                                                 case "1": // movable
 574                                                                         e.movetype = MOVETYPE_TOSS;
 575                                                                         break;
 576                                                                 case "2": // physical
 577                                                                         e.movetype = MOVETYPE_PHYSICS;
 578                                                                         break;
 579                                                                 default:
 580                                                                         break;
 581                                                         }
 582                                                         break;
 583                                                 case "force":
 584                                                         e.damageforcescale = stof(argv(3));
 585                                                         break;
 586                                                 case "material":
 587                                                         if(e.material)
 588                                                                 strunzone(e.material);
 589                                                         if(argv(3))
 590                                                         {
 591                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 592                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 593                                                                 e.material = strzone(argv(3));
 594                                                         }
 595                                                         else
 596                                                                 e.material = string_null; // no material
 597                                                         break;
 598                                                 default:
 599                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 600                                                         break;
 601                                         }
 602                                         if(autocvar_g_sandbox_info > 1)
 603                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 604                                         return TRUE;
 605                                 }
 606
 607                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 608                                 return TRUE;
 609
 610                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 611                         case "object_claim":
 612                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 613                                 if(self.crypto_idfp == "")
 614                                 {
 615                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 616                                         return TRUE;
 617                                 }
 618                                 e = sandbox_ObjectEdit_Get(TRUE);
 619                                 if(e != world)
 620                                 {
 621                                         if(e.crypto_idfp == self.crypto_idfp)
 622                                         {
 623                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 624                                                 return TRUE;
 625                                         }
 626
 627                                         if(e.crypto_idfp)
 628                                                 strunzone(e.crypto_idfp);
 629                                         e.crypto_idfp = self.crypto_idfp;
 630                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 631                                 }
 632                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 633                                 return TRUE;
 634
 635                         // ---------------- COMMAND: OBJECT, INFO ----------------
 636                         case "object_info":
 637                                 // prints public information about the object to the player
 638                                 e = sandbox_ObjectEdit_Get(FALSE);
 639                                 if(e != world)
 640                                 {
 641                                         switch(argv(2))
 642                                         {
 643                                                 case "mesh":
 644                                                         string tags;
 645                                                         for(i = 1; gettaginfo(e, i); i++)
 646                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 647                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 648                                                         return TRUE;
 649                                         }
 650                                 }
 651                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 652                                 return TRUE;
 653
 654                         // ---------------- COMMAND: DEFAULT ----------------
 655                         default:
 656                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 657                                 return TRUE;
 658                 }
 659         }
 660         return FALSE;
 661 }
 662
 663 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 664 {
 665         // if the player is close enough to their object, they can drag it
 666
 667         if(autocvar_sv_cheats)
 668                 return FALSE; // cheat dragging is used instead
 669
 670         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 671         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 672         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 673         // it goes out of range while slinging it around.
 674
 675         entity e;
 676         float grab;
 677
 678         e = sandbox_ObjectEdit_Get(TRUE);
 679         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 680                 grab = TRUE;
 681
 682         if(Drag(e, grab)) // execute dragging
 683                 return TRUE;
 684
 685         return FALSE;
 686 }
 687
 688 float autosave_time;
 689 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 690 {
 691         if(!autocvar_g_sandbox_storage_autosave)
 692                 return FALSE;
 693         if(time < autosave_time)
 694                 return FALSE;
 695         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 696
 697         sandbox_Database_Save();
 698
 699         return TRUE;
 700 }
 701
 702 MUTATOR_DEFINITION(sandbox)
 703 {
 704         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 705         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 706         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 707
 708         MUTATOR_ONADD
 709         {
 710                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 711                 if(autocvar_g_sandbox_storage_autoload)
 712                         sandbox_Database_Load();
 713         }
 714
 715         return FALSE;
 716 }
 717