qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.movetype = MOVETYPE_FOLLOW;
  72         e.solid = SOLID_NOT;
  73         e.takedamage = DAMAGE_NO;
  74
  75         setattachment(e, parent, s);
  76         e.owner = parent;
  77 }
  78
  79 void sandbox_ObjectAttach_Remove(entity e)
  80 {
  81         // detaches any object attached to e
  82
  83         entity head;
  84         for(head = world; (head = find(head, classname, "object")); )
  85         {
  86                 if(head.owner == e)
  87                 {
  88                         vector org;
  89                         head.movetype = MOVETYPE_TOSS; // default
  90                         head.solid = SOLID_BBOX;
  91                         head.takedamage = DAMAGE_AIM;
  92
  93                         org = gettaginfo(head, 0);
  94                         setattachment(head, world, "");
  95                         head.owner = world;
  96
  97                         // objects change origin and angles when detached, so apply previous position
  98                         setorigin(head, org);
  99                         head.angles = e.angles; // don't allow detached objects to spin or roll
 100                 }
 101         }
 102 }
 103
 104 entity sandbox_ObjectSpawn(float database)
 105 {
 106         // spawn a new object with default properties
 107
 108         entity e;
 109         e = spawn();
 110         e.classname = "object";
 111         e.takedamage = DAMAGE_AIM;
 112         e.damageforcescale = 1;
 113         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 114         e.movetype = MOVETYPE_TOSS;
 115         e.frame = 0;
 116         e.skin = 0;
 117         e.material = string_null;
 118         e.touch = sandbox_ObjectFunction_Touch;
 119
 120         if(!database)
 121         {
 122                 // set the object's owner via player UID
 123                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 124                 if(self.crypto_idfp != "")
 125                         e.crypto_idfp = strzone(self.crypto_idfp);
 126                 else
 127                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 128
 129                 // set origin and direction based on player position and view angle
 130                 makevectors(self.v_angle);
 131                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 132                 setorigin(e, trace_endpos);
 133                 e.angles_y = self.v_angle_y;
 134         }
 135
 136         object_count += 1;
 137         return e;
 138 }
 139
 140 void sandbox_ObjectRemove(entity e)
 141 {
 142         sandbox_ObjectAttach_Remove(e); // detach child objects
 143         if(e.material)
 144         {
 145                 strunzone(e.material);
 146                 e.material = string_null;
 147         }
 148         if(e.crypto_idfp)
 149         {
 150                 strunzone(e.crypto_idfp);
 151                 e.crypto_idfp = string_null;
 152         }
 153         remove(e);
 154         e = world;
 155
 156         object_count -= 1;
 157 }
 158
 159 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 160
 161 string sandbox_ObjectPort_Save(entity e, float database)
 162 {
 163         // save object properties, and return them as a string
 164         float i;
 165         string s;
 166         entity head;
 167
 168         for(head = world; (head = find(head, classname, "object")); )
 169         {
 170                 // the main object needs to be first in the array [0] with attached objects following
 171                 float slot;
 172                 string tagindex;
 173                 if(head == e) // this is the main object, place it first
 174                 {
 175                         slot = 0;
 176                         tagindex = string_null; // the main object is not attached to anything
 177                 }
 178                 else if(head.owner == e) // child object, list them in order
 179                 {
 180                         i += 1; // children start from 1
 181                         slot = i;
 182
 183                         // get the name of the tag our object is attached to
 184                         gettaginfo(head.owner, head.tag_index);
 185                         tagindex = gettaginfo_name;
 186                 }
 187                 else
 188                         continue;
 189
 190                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 191                 if(slot)
 192                 {
 193                         // properties stored only for child objects
 194                         if(tagindex)    port_string[slot] = strcat(port_string[slot], "\"", tagindex, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 195                 }
 196                 else
 197                 {
 198                         // properties stored only for parent objects
 199                         if(database)
 200                         {
 201                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 202                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 203                         }
 204                 }
 205                 // properties stored for all objects
 206                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 207                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 208                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 209                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 210                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 212                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 213                 port_string[slot] = strcat(port_string[slot], ftos(head.movetype), " ");
 214                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 215                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 216                 if(database)
 217                 {
 218                         // properties stored only for the database
 219                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 220                 }
 221         }
 222
 223         // now apply the array to a simple string, with the ; symbol separating objects
 224         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 225         {
 226                 if(port_string[i])
 227                         s = strcat(s, port_string[i], "; ");
 228                 port_string[i] = string_null; // fully clear the string
 229         }
 230
 231         return s;
 232 }
 233
 234 entity sandbox_ObjectPort_Load(string s, float database)
 235 {
 236         // load object properties, and spawn a new object with them
 237         float n, i;
 238         entity e, parent;
 239
 240         // separate objects between the ; symbols
 241         n = tokenizebyseparator(s, "; ");
 242         for(i = 0; i < n; ++i)
 243                 port_string[i] = argv(i);
 244
 245         // now separate and apply the properties of each object
 246         for(i = 0; i < n; ++i)
 247         {
 248                 float argv_num;
 249                 argv_num = 0;
 250                 tokenize_console(port_string[i]);
 251                 e = sandbox_ObjectSpawn(database);
 252
 253                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 254                 if(i)
 255                 {
 256                         // properties stored only for child objects
 257                         if(argv(argv_num) != "-")       sandbox_ObjectAttach_Set(e, parent, argv(argv_num));    else    sandbox_ObjectAttach_Set(e, parent, "");        ++argv_num;
 258                 }
 259                 else
 260                 {
 261                         // properties stored only for parent objects
 262                         if(database)
 263                         {
 264                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 265                                 e.angles = stov(argv(argv_num));        ++argv_num;
 266                         }
 267                         parent = e; // mark parent objects as such
 268                 }
 269                 // properties stored for all objects
 270                 setmodel(e, argv(argv_num));    ++argv_num;
 271                 e.skin = stof(argv(argv_num));  ++argv_num;
 272                 e.alpha = stof(argv(argv_num)); ++argv_num;
 273                 e.colormod = stov(argv(argv_num));      ++argv_num;
 274                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 275                 e.frame = stof(argv(argv_num)); ++argv_num;
 276                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 277                 e.movetype = stof(argv(argv_num));      ++argv_num;
 278                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 279                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 280                 if(database)
 281                 {
 282                         // properties stored only for the database
 283                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 284                 }
 285         }
 286
 287         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 288                 port_string[i] = string_null; // fully clear the string
 289
 290         return e;
 291 }
 292
 293 void sandbox_Database_Save()
 294 {
 295         // saves all objects to the database file
 296         entity head;
 297         string file_name;
 298         float file_get;
 299
 300         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 301         file_get = fopen(file_name, FILE_WRITE);
 302         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 303         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 304
 305         for(head = world; (head = find(head, classname, "object")); )
 306         {
 307                 // attached objects are persisted separately, ignore them here
 308                 if(head.owner != world)
 309                         continue;
 310
 311                 // use a line of text for each object, listing all properties
 312                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 313         }
 314         fclose(file_get);
 315 }
 316
 317 void sandbox_Database_Load()
 318 {
 319         // loads all objects from the database file
 320         string file_read, file_name;
 321         float file_get, i;
 322
 323         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 324         file_get = fopen(file_name, FILE_READ);
 325         if(file_get < 0)
 326         {
 327                 if(autocvar_g_sandbox_info > 0)
 328                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 329         }
 330         else
 331         {
 332                 for(;;)
 333                 {
 334                         file_read = fgets(file_get);
 335                         if(!file_read)
 336                                 break;
 337                         if(substring(file_read, 0, 2) == "//")
 338                                 continue;
 339                         if(substring(file_read, 0, 1) == "#")
 340                                 continue;
 341
 342                         entity e;
 343                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 344
 345                         if(e.material)
 346                         {
 347                                 // since objects are being loaded for the first time, precache material sounds for each
 348                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 349                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 350                         }
 351                 }
 352                 if(autocvar_g_sandbox_info > 0)
 353                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 354         }
 355 }
 356
 357 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 358 {
 359         if(MUTATOR_RETURNVALUE) // command was already handled?
 360                 return FALSE;
 361         if(cmd_name == "g_sandbox")
 362         {
 363                 if(cmd_argc < 2)
 364                 {
 365                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 366                         return TRUE;
 367                 }
 368
 369                 switch(argv(1))
 370                 {
 371                         entity e;
 372                         float i;
 373
 374                         // ---------------- COMMAND: HELP ----------------
 375                         case "help":
 376                                 print_to(self, "You can use the following sandbox commands:");
 377                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 378                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 379                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 380                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 381                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 382                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 383                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 384                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 385                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 386                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 387                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 388                                 print_to(self, "^3alpha value ^7- sets object transparency");
 389                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 390                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 391                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 392                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 393                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 394                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 395                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 396                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 397                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 398                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 399                                 return TRUE;
 400
 401                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 402                         case "object_spawn":
 403                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 404                                 {
 405                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 406                                         return TRUE;
 407                                 }
 408                                 if(cmd_argc < 3)
 409                                 {
 410                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 411                                         return TRUE;
 412                                 }
 413                                 else if not(fexists(argv(2)))
 414                                 {
 415                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 416                                         return TRUE;
 417                                 }
 418
 419                                 e = sandbox_ObjectSpawn(FALSE);
 420                                 setmodel(e, argv(2));
 421
 422                                 if(autocvar_g_sandbox_info > 0)
 423                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 424                                 return TRUE;
 425
 426                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 427                         case "object_remove":
 428                                 e = sandbox_ObjectEdit_Get(TRUE);
 429                                 if(e != world)
 430                                 {
 431                                         if(autocvar_g_sandbox_info > 0)
 432                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 433                                         sandbox_ObjectRemove(e);
 434                                         return TRUE;
 435                                 }
 436
 437                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 438                                 return TRUE;
 439
 440                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 441                         case "object_duplicate":
 442                                 switch(argv(2))
 443                                 {
 444                                         case "copy":
 445                                                 // copies customizable properties of the selected object to the clipboard
 446                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 447                                                 if(e != world)
 448                                                 {
 449                                                         if(self.object_clipboard)
 450                                                                 strunzone(self.object_clipboard);
 451                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 452
 453                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 454                                                         return TRUE;
 455                                                 }
 456                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 457                                                 return TRUE;
 458
 459                                         case "paste":
 460                                                 // spawns a new object using the properties in the player's clipboard
 461                                                 if(!self.object_clipboard) // no object in clipboard
 462                                                 {
 463                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 464                                                         return TRUE;
 465                                                 }
 466                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 467                                                 {
 468                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 469                                                         return TRUE;
 470                                                 }
 471
 472                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 473
 474                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 475                                                 if(autocvar_g_sandbox_info > 0)
 476                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 477                                                 return TRUE;
 478                                 }
 479                                 return TRUE;
 480
 481                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 482                         case "object_attach":
 483                                 switch(argv(2))
 484                                 {
 485                                         case "get":
 486                                                 // select e as the object as meant to be attached
 487                                                 e = sandbox_ObjectEdit_Get(TRUE);
 488                                                 if(e != world)
 489                                                 {
 490                                                         self.object_attach = e;
 491                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 492                                                         return TRUE;
 493                                                 }
 494                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 495                                                 return TRUE;
 496                                         case "set":
 497                                                 if(self.object_attach == world)
 498                                                 {
 499                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 500                                                         return TRUE;
 501                                                 }
 502
 503                                                 // attaches the previously selected object to e
 504                                                 e = sandbox_ObjectEdit_Get(TRUE);
 505                                                 if(e != world)
 506                                                 {
 507                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 508                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 509                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 510                                                         if(autocvar_g_sandbox_info > 1)
 511                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 512                                                         return TRUE;
 513                                                 }
 514                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 515                                                 return TRUE;
 516                                         case "remove":
 517                                                 // removes e if it was attached
 518                                                 e = sandbox_ObjectEdit_Get(TRUE);
 519                                                 if(e != world)
 520                                                 {
 521                                                         sandbox_ObjectAttach_Remove(e);
 522                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 523                                                         if(autocvar_g_sandbox_info > 1)
 524                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 525                                                         return TRUE;
 526                                                 }
 527                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 528                                                 return TRUE;
 529                                 }
 530                                 return TRUE;
 531
 532                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 533                         case "object_edit":
 534                                 if(!argv(2))
 535                                 {
 536                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 537                                         return TRUE;
 538                                 }
 539
 540                                 e = sandbox_ObjectEdit_Get(TRUE);
 541                                 if(e != world)
 542                                 {
 543                                         switch(argv(2))
 544                                         {
 545                                                 case "skin":
 546                                                         e.skin = stof(argv(3));
 547                                                         break;
 548                                                 case "alpha":
 549                                                         e.alpha = stof(argv(3));
 550                                                         break;
 551                                                 case "color_main":
 552                                                         e.colormod = stov(argv(3));
 553                                                         break;
 554                                                 case "color_glow":
 555                                                         e.glowmod = stov(argv(3));
 556                                                         break;
 557                                                 case "frame":
 558                                                         e.frame = stof(argv(3));
 559                                                         break;
 560                                                 case "scale":
 561                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 562                                                         break;
 563                                                 case "physics":
 564                                                         switch(argv(3))
 565                                                         {
 566                                                                 case "0": // static
 567                                                                         e.movetype = MOVETYPE_NONE;
 568                                                                         break;
 569                                                                 case "1": // movable
 570                                                                         e.movetype = MOVETYPE_TOSS;
 571                                                                         break;
 572                                                                 case "2": // physical
 573                                                                         e.movetype = MOVETYPE_PHYSICS;
 574                                                                         break;
 575                                                                 default:
 576                                                                         break;
 577                                                         }
 578                                                         break;
 579                                                 case "force":
 580                                                         e.damageforcescale = stof(argv(3));
 581                                                         break;
 582                                                 case "material":
 583                                                         if(e.material)
 584                                                                 strunzone(e.material);
 585                                                         if(argv(3))
 586                                                         {
 587                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 588                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 589                                                                 e.material = strzone(argv(3));
 590                                                         }
 591                                                         else
 592                                                                 e.material = string_null; // no material
 593                                                         break;
 594                                                 default:
 595                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 596                                                         break;
 597                                         }
 598                                         if(autocvar_g_sandbox_info > 1)
 599                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 600                                         return TRUE;
 601                                 }
 602
 603                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 604                                 return TRUE;
 605
 606                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 607                         case "object_claim":
 608                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 609                                 if(self.crypto_idfp == "")
 610                                 {
 611                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 612                                         return TRUE;
 613                                 }
 614                                 e = sandbox_ObjectEdit_Get(TRUE);
 615                                 if(e != world)
 616                                 {
 617                                         if(e.crypto_idfp == self.crypto_idfp)
 618                                         {
 619                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 620                                                 return TRUE;
 621                                         }
 622
 623                                         if(e.crypto_idfp)
 624                                                 strunzone(e.crypto_idfp);
 625                                         e.crypto_idfp = self.crypto_idfp;
 626                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 627                                 }
 628                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 629                                 return TRUE;
 630
 631                         // ---------------- COMMAND: OBJECT, INFO ----------------
 632                         case "object_info":
 633                                 // prints public information about the object to the player
 634                                 e = sandbox_ObjectEdit_Get(FALSE);
 635                                 if(e != world)
 636                                 {
 637                                         switch(argv(2))
 638                                         {
 639                                                 case "mesh":
 640                                                         string tags;
 641                                                         for(i = 1; gettaginfo(e, i); i++)
 642                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 643                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 644                                                         return TRUE;
 645                                         }
 646                                 }
 647                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 648                                 return TRUE;
 649
 650                         // ---------------- COMMAND: DEFAULT ----------------
 651                         default:
 652                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 653                                 return TRUE;
 654                 }
 655         }
 656         return FALSE;
 657 }
 658
 659 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 660 {
 661         // if the player is close enough to their object, they can drag it
 662
 663         if(autocvar_sv_cheats)
 664                 return FALSE; // cheat dragging is used instead
 665
 666         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 667         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 668         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 669         // it goes out of range while slinging it around.
 670
 671         entity e;
 672         float grab;
 673
 674         e = sandbox_ObjectEdit_Get(TRUE);
 675         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 676                 grab = TRUE;
 677
 678         if(Drag(e, grab)) // execute dragging
 679                 return TRUE;
 680
 681         return FALSE;
 682 }
 683
 684 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 685 {
 686         // unzone the player's clipboard if it's not empty
 687         if(self.object_clipboard)
 688         {
 689                 strunzone(self.object_clipboard);
 690                 self.object_clipboard = string_null;
 691         }
 692
 693         return FALSE;
 694 }
 695
 696 float autosave_time;
 697 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 698 {
 699         if(!autocvar_g_sandbox_storage_autosave)
 700                 return FALSE;
 701         if(time < autosave_time)
 702                 return FALSE;
 703         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 704
 705         sandbox_Database_Save();
 706
 707         return TRUE;
 708 }
 709
 710 MUTATOR_DEFINITION(sandbox)
 711 {
 712         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 713         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 714         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 715         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 716
 717         MUTATOR_ONADD
 718         {
 719                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 720                 if(autocvar_g_sandbox_storage_autoload)
 721                         sandbox_Database_Load();
 722         }
 723
 724         return FALSE;
 725 }
 726