qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.movetype = MOVETYPE_FOLLOW;
  72         e.solid = SOLID_NOT;
  73         e.takedamage = DAMAGE_NO;
  74
  75         setattachment(e, parent, s);
  76         e.owner = parent;
  77 }
  78
  79 void sandbox_ObjectAttach_Remove(entity e)
  80 {
  81         // detaches any object attached to e
  82
  83         entity head;
  84         for(head = world; (head = find(head, classname, "object")); )
  85         {
  86                 if(head.owner == e)
  87                 {
  88                         vector org;
  89                         head.movetype = MOVETYPE_TOSS; // default
  90                         head.solid = SOLID_BBOX;
  91                         head.takedamage = DAMAGE_AIM;
  92
  93                         org = gettaginfo(head, 0);
  94                         setattachment(head, world, "");
  95                         head.owner = world;
  96
  97                         // objects change origin and angles when detached, so apply previous position
  98                         setorigin(head, org);
  99                         head.angles = e.angles; // don't allow detached objects to spin or roll
 100                 }
 101         }
 102 }
 103
 104 entity sandbox_ObjectSpawn(float database)
 105 {
 106         // spawn a new object with default properties
 107
 108         entity e;
 109         e = spawn();
 110         e.classname = "object";
 111         e.takedamage = DAMAGE_AIM;
 112         e.damageforcescale = 1;
 113         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 114         e.movetype = MOVETYPE_TOSS;
 115         e.frame = 0;
 116         e.skin = 0;
 117         e.material = string_null;
 118         e.touch = sandbox_ObjectFunction_Touch;
 119
 120         if(!database)
 121         {
 122                 // set the object's owner via player UID
 123                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 124                 if(self.crypto_idfp != "")
 125                         e.crypto_idfp = strzone(self.crypto_idfp);
 126                 else
 127                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 128
 129                 // set origin and direction based on player position and view angle
 130                 makevectors(self.v_angle);
 131                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 132                 setorigin(e, trace_endpos);
 133                 e.angles_y = self.v_angle_y;
 134         }
 135
 136         object_count += 1;
 137         return e;
 138 }
 139
 140 void sandbox_ObjectRemove(entity e)
 141 {
 142         sandbox_ObjectAttach_Remove(e); // detach child objects
 143         if(e.material)
 144         {
 145                 strunzone(e.material);
 146                 e.material = string_null;
 147         }
 148         if(e.crypto_idfp)
 149         {
 150                 strunzone(e.crypto_idfp);
 151                 e.crypto_idfp = string_null;
 152         }
 153         remove(e);
 154         e = world;
 155
 156         object_count -= 1;
 157 }
 158
 159 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 160
 161 string sandbox_ObjectPort_Save(entity e, float database)
 162 {
 163         // TODO: Store attachement bone for attached objects as well!
 164
 165         // save object properties, and return them as a string
 166         float i;
 167         string s;
 168         entity head;
 169
 170         for(head = world; (head = find(head, classname, "object")); )
 171         {
 172                 // the main object needs to be first in the array [0], with attached objects following
 173                 float slot;
 174                 if(head == e) // this is the main object, make it first
 175                         slot = 0;
 176                 else if(head.owner == e) // child object, list them in order
 177                 {
 178                         i += 1; // children start from 1
 179                         slot = i;
 180                 }
 181                 else
 182                         continue;
 183
 184                 port_string[slot] = strcat(port_string[slot], head.model, " ");
 185                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 186                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 187                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 188                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 189                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 190                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 191                 port_string[slot] = strcat(port_string[slot], ftos(head.movetype), " ");
 192                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 193                 if(head.material)       port_string[slot] = strcat(port_string[slot], head.material, " ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 194                 if(database)
 195                 {
 196                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], head.crypto_idfp, " ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 197                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 198                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 199                 }
 200         }
 201
 202         // now apply the array to a simple string, with the ; symbol separating objects
 203         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 204         {
 205                 if(port_string[i])
 206                         s = strcat(s, port_string[i], "; ");
 207                 port_string[i] = string_null; // fully clear the string
 208         }
 209
 210         return s;
 211 }
 212
 213 entity sandbox_ObjectPort_Load(string s, float database)
 214 {
 215         // TODO: Store attachement bone for attached objects as well!
 216
 217         // load object properties, and spawn a new object with them
 218         float n, i;
 219         entity e, parent;
 220
 221         // separate objects between the ; symbols
 222         n = tokenizebyseparator(s, "; ");
 223         for(i = 0; i < n; ++i)
 224                 port_string[i] = argv(i);
 225
 226         // now separate and apply the properties of each object
 227         for(i = 0; i < n; ++i)
 228         {
 229                 tokenize_console(port_string[i]);
 230                 e = sandbox_ObjectSpawn(database);
 231
 232                 setmodel(e, argv(0));
 233                 e.skin = stof(argv(1));
 234                 e.alpha = stof(argv(2));
 235                 e.colormod = stov(argv(3));
 236                 e.glowmod = stov(argv(4));
 237                 e.frame = stof(argv(5));
 238                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 239                 e.movetype = stof(argv(7));
 240                 e.damageforcescale = stof(argv(8));
 241                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 242                 if(database)
 243                 {
 244                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10) != "-")     e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 245                         setorigin(e, stov(argv(11)));
 246                         e.angles = stov(argv(12));
 247                 }
 248
 249                 if(!i) // parent object, set it as such and leave it be
 250                         parent = e;
 251                 else // child object, attach it to the parent
 252                         sandbox_ObjectAttach_Set(e, parent, "");
 253         }
 254
 255         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 256                 port_string[i] = string_null; // fully clear the string
 257
 258         return e;
 259 }
 260
 261 void sandbox_Database_Save()
 262 {
 263         // saves all objects to the database file
 264         entity head;
 265         string file_name;
 266         float file_get;
 267
 268         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 269         file_get = fopen(file_name, FILE_WRITE);
 270         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 271         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 272
 273         for(head = world; (head = find(head, classname, "object")); )
 274         {
 275                 // attached objects are persisted separately, ignore them here
 276                 if(head.owner != world)
 277                         continue;
 278
 279                 // use a line of text for each object, listing all properties
 280                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 281         }
 282         fclose(file_get);
 283 }
 284
 285 void sandbox_Database_Load()
 286 {
 287         // loads all objects from the database file
 288         string file_read, file_name;
 289         float file_get, i;
 290
 291         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 292         file_get = fopen(file_name, FILE_READ);
 293         if(file_get < 0)
 294         {
 295                 if(autocvar_g_sandbox_info > 0)
 296                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 297         }
 298         else
 299         {
 300                 for(;;)
 301                 {
 302                         file_read = fgets(file_get);
 303                         if(!file_read)
 304                                 break;
 305                         if(substring(file_read, 0, 2) == "//")
 306                                 continue;
 307                         if(substring(file_read, 0, 1) == "#")
 308                                 continue;
 309
 310                         entity e;
 311                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 312
 313                         if(e.material)
 314                         {
 315                                 // since objects are being loaded for the first time, precache material sounds for each
 316                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 317                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 318                         }
 319                 }
 320                 if(autocvar_g_sandbox_info > 0)
 321                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 322         }
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 326 {
 327         if(MUTATOR_RETURNVALUE) // command was already handled?
 328                 return FALSE;
 329         if(cmd_name == "g_sandbox")
 330         {
 331                 if(cmd_argc < 2)
 332                 {
 333                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 334                         return TRUE;
 335                 }
 336
 337                 switch(argv(1))
 338                 {
 339                         entity e;
 340                         float i;
 341
 342                         // ---------------- COMMAND: HELP ----------------
 343                         case "help":
 344                                 print_to(self, "You can use the following sandbox commands:");
 345                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 346                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 347                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 348                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 349                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 350                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 351                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 352                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 353                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 354                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 355                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 356                                 print_to(self, "^3alpha value ^7- sets object transparency");
 357                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 358                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 359                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 360                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 361                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 362                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 363                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 364                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 365                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 366                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 367                                 return TRUE;
 368
 369                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 370                         case "object_spawn":
 371                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 372                                 {
 373                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 374                                         return TRUE;
 375                                 }
 376                                 if(cmd_argc < 3)
 377                                 {
 378                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 379                                         return TRUE;
 380                                 }
 381                                 else if not(fexists(argv(2)))
 382                                 {
 383                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 384                                         return TRUE;
 385                                 }
 386
 387                                 e = sandbox_ObjectSpawn(FALSE);
 388                                 setmodel(e, argv(2));
 389
 390                                 if(autocvar_g_sandbox_info > 0)
 391                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 392                                 return TRUE;
 393
 394                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 395                         case "object_remove":
 396                                 e = sandbox_ObjectEdit_Get(TRUE);
 397                                 if(e != world)
 398                                 {
 399                                         if(autocvar_g_sandbox_info > 0)
 400                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 401                                         sandbox_ObjectRemove(e);
 402                                         return TRUE;
 403                                 }
 404
 405                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 406                                 return TRUE;
 407
 408                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 409                         case "object_duplicate":
 410                                 switch(argv(2))
 411                                 {
 412                                         case "copy":
 413                                                 // copies customizable properties of the selected object to the clipboard
 414                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 415                                                 if(e != world)
 416                                                 {
 417                                                         if(self.object_clipboard)
 418                                                                 strunzone(self.object_clipboard);
 419                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 420
 421                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 422                                                         return TRUE;
 423                                                 }
 424                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 425                                                 return TRUE;
 426
 427                                         case "paste":
 428                                                 // spawns a new object using the properties in the player's clipboard
 429                                                 if(!self.object_clipboard) // no object in clipboard
 430                                                 {
 431                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 432                                                         return TRUE;
 433                                                 }
 434                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 435                                                 {
 436                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 437                                                         return TRUE;
 438                                                 }
 439
 440                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 441
 442                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 443                                                 if(autocvar_g_sandbox_info > 0)
 444                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 445                                                 return TRUE;
 446                                 }
 447                                 return TRUE;
 448
 449                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 450                         case "object_attach":
 451                                 switch(argv(2))
 452                                 {
 453                                         case "get":
 454                                                 // select e as the object as meant to be attached
 455                                                 e = sandbox_ObjectEdit_Get(TRUE);
 456                                                 if(e != world)
 457                                                 {
 458                                                         self.object_attach = e;
 459                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 460                                                         return TRUE;
 461                                                 }
 462                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 463                                                 return TRUE;
 464                                         case "set":
 465                                                 if(self.object_attach == world)
 466                                                 {
 467                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 468                                                         return TRUE;
 469                                                 }
 470
 471                                                 // attaches the previously selected object to e
 472                                                 e = sandbox_ObjectEdit_Get(TRUE);
 473                                                 if(e != world)
 474                                                 {
 475                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 476                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 477                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 478                                                         if(autocvar_g_sandbox_info > 1)
 479                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 480                                                         return TRUE;
 481                                                 }
 482                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 483                                                 return TRUE;
 484                                         case "remove":
 485                                                 // removes e if it was attached
 486                                                 e = sandbox_ObjectEdit_Get(TRUE);
 487                                                 if(e != world)
 488                                                 {
 489                                                         sandbox_ObjectAttach_Remove(e);
 490                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 491                                                         if(autocvar_g_sandbox_info > 1)
 492                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 493                                                         return TRUE;
 494                                                 }
 495                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 496                                                 return TRUE;
 497                                 }
 498                                 return TRUE;
 499
 500                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 501                         case "object_edit":
 502                                 if(!argv(2))
 503                                 {
 504                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 505                                         return TRUE;
 506                                 }
 507
 508                                 e = sandbox_ObjectEdit_Get(TRUE);
 509                                 if(e != world)
 510                                 {
 511                                         switch(argv(2))
 512                                         {
 513                                                 case "skin":
 514                                                         e.skin = stof(argv(3));
 515                                                         break;
 516                                                 case "alpha":
 517                                                         e.alpha = stof(argv(3));
 518                                                         break;
 519                                                 case "color_main":
 520                                                         e.colormod = stov(argv(3));
 521                                                         break;
 522                                                 case "color_glow":
 523                                                         e.glowmod = stov(argv(3));
 524                                                         break;
 525                                                 case "frame":
 526                                                         e.frame = stof(argv(3));
 527                                                         break;
 528                                                 case "scale":
 529                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 530                                                         break;
 531                                                 case "physics":
 532                                                         switch(argv(3))
 533                                                         {
 534                                                                 case "0": // static
 535                                                                         e.movetype = MOVETYPE_NONE;
 536                                                                         break;
 537                                                                 case "1": // movable
 538                                                                         e.movetype = MOVETYPE_TOSS;
 539                                                                         break;
 540                                                                 case "2": // physical
 541                                                                         e.movetype = MOVETYPE_PHYSICS;
 542                                                                         break;
 543                                                                 default:
 544                                                                         break;
 545                                                         }
 546                                                         break;
 547                                                 case "force":
 548                                                         e.damageforcescale = stof(argv(3));
 549                                                         break;
 550                                                 case "material":
 551                                                         if(e.material)
 552                                                                 strunzone(e.material);
 553                                                         if(argv(3))
 554                                                         {
 555                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 556                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 557                                                                 e.material = strzone(argv(3));
 558                                                         }
 559                                                         else
 560                                                                 e.material = string_null; // no material
 561                                                         break;
 562                                                 default:
 563                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 564                                                         break;
 565                                         }
 566                                         if(autocvar_g_sandbox_info > 1)
 567                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 568                                         return TRUE;
 569                                 }
 570
 571                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 572                                 return TRUE;
 573
 574                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 575                         case "object_claim":
 576                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 577                                 if(self.crypto_idfp == "")
 578                                 {
 579                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 580                                         return TRUE;
 581                                 }
 582                                 e = sandbox_ObjectEdit_Get(TRUE);
 583                                 if(e != world)
 584                                 {
 585                                         if(e.crypto_idfp == self.crypto_idfp)
 586                                         {
 587                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 588                                                 return TRUE;
 589                                         }
 590
 591                                         if(e.crypto_idfp)
 592                                                 strunzone(e.crypto_idfp);
 593                                         e.crypto_idfp = self.crypto_idfp;
 594                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 595                                 }
 596                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 597                                 return TRUE;
 598
 599                         // ---------------- COMMAND: OBJECT, INFO ----------------
 600                         case "object_info":
 601                                 // prints public information about the object to the player
 602                                 e = sandbox_ObjectEdit_Get(FALSE);
 603                                 if(e != world)
 604                                 {
 605                                         switch(argv(2))
 606                                         {
 607                                                 case "mesh":
 608                                                         string tags;
 609                                                         for(i = 1; gettaginfo(e, i); i++)
 610                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 611                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 612                                                         return TRUE;
 613                                         }
 614                                 }
 615                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 616                                 return TRUE;
 617
 618                         // ---------------- COMMAND: DEFAULT ----------------
 619                         default:
 620                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 621                                 return TRUE;
 622                 }
 623         }
 624         return FALSE;
 625 }
 626
 627 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 628 {
 629         // if the player is close enough to their object, they can drag it
 630
 631         if(autocvar_sv_cheats)
 632                 return FALSE; // cheat dragging is used instead
 633
 634         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 635         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 636         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 637         // it goes out of range while slinging it around.
 638
 639         entity e;
 640         float grab;
 641
 642         e = sandbox_ObjectEdit_Get(TRUE);
 643         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 644                 grab = TRUE;
 645
 646         if(Drag(e, grab)) // execute dragging
 647                 return TRUE;
 648
 649         return FALSE;
 650 }
 651
 652 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 653 {
 654         // unzone the player's clipboard if it's not empty
 655         if(self.object_clipboard)
 656         {
 657                 strunzone(self.object_clipboard);
 658                 self.object_clipboard = string_null;
 659         }
 660
 661         return FALSE;
 662 }
 663
 664 float autosave_time;
 665 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 666 {
 667         if(!autocvar_g_sandbox_storage_autosave)
 668                 return FALSE;
 669         if(time < autosave_time)
 670                 return FALSE;
 671         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 672
 673         sandbox_Database_Save();
 674
 675         return TRUE;
 676 }
 677
 678 MUTATOR_DEFINITION(sandbox)
 679 {
 680         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 681         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 682         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 683         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 684
 685         MUTATOR_ONADD
 686         {
 687                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 688                 if(autocvar_g_sandbox_storage_autoload)
 689                         sandbox_Database_Load();
 690         }
 691
 692         return FALSE;
 693 }
 694