qcsrc/server/mutators/sandbox.qc

   1 float object_count;
   2 .string object_clipboard;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_ObjectFunction_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_ObjectEdit_Get()
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // attached objects are SOLID_NOT and don't risk getting traced
  36
  37         makevectors(self.v_angle);
  38         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  39
  40         if(trace_ent.classname != "object")
  41                 return world; // entity is not an object
  42         if(!trace_ent.crypto_idfp)
  43                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  44         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  45                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  46         return world;
  47 }
  48
  49 void sandbox_ObjectEdit_Scale(entity e, float f)
  50 {
  51         e.scale = f;
  52         if(e.scale)
  53         {
  54                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  55                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  56         }
  57 }
  58
  59 void sandbox_ObjectAttach_Remove(entity e);
  60 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  61 {
  62         // attaches e to parent on string s
  63
  64         // we can't attach to an attachment, for obvious reasons
  65         sandbox_ObjectAttach_Remove(e);
  66
  67         e.movetype = MOVETYPE_FOLLOW;
  68         e.solid = SOLID_NOT;
  69         e.takedamage = DAMAGE_NO;
  70
  71         setattachment(e, parent, s);
  72         e.owner = parent;
  73 }
  74
  75 void sandbox_ObjectAttach_Remove(entity e)
  76 {
  77         // detaches any object attached to e
  78
  79         entity head;
  80         for(head = world; (head = find(head, classname, "object")); )
  81         {
  82                 if(head.owner == e)
  83                 {
  84                         head.movetype = MOVETYPE_TOSS; // default
  85                         head.solid = SOLID_BBOX;
  86                         head.takedamage = DAMAGE_AIM;
  87
  88                         setattachment(head, world, "");
  89                         head.owner = world;
  90
  91                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  92                         setorigin(head, e.origin);
  93                         head.angles = e.angles;
  94                 }
  95         }
  96 }
  97
  98 entity sandbox_ObjectSpawn(float database)
  99 {
 100         // spawn a new object with default properties
 101
 102         entity e;
 103         e = spawn();
 104         e.classname = "object";
 105         e.takedamage = DAMAGE_AIM;
 106         e.damageforcescale = 1;
 107         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 108         e.movetype = MOVETYPE_TOSS;
 109         e.frame = 0;
 110         e.skin = 0;
 111         e.material = string_null;
 112         e.touch = sandbox_ObjectFunction_Touch;
 113
 114         if(!database)
 115         {
 116                 // set the object's owner via player UID
 117                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 118                 if(self.crypto_idfp != "")
 119                         e.crypto_idfp = strzone(self.crypto_idfp);
 120                 else
 121                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 122
 123                 // set origin and direction based on player position and view angle
 124                 makevectors(self.v_angle);
 125                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 126                 setorigin(e, trace_endpos);
 127                 e.angles_y = self.v_angle_y;
 128         }
 129
 130         object_count += 1;
 131         return e;
 132 }
 133
 134 void sandbox_ObjectRemove(entity e)
 135 {
 136         sandbox_ObjectAttach_Remove(e); // detach child objects
 137         if(e.material)
 138         {
 139                 strunzone(e.material);
 140                 e.material = string_null;
 141         }
 142         if(e.crypto_idfp)
 143         {
 144                 strunzone(e.crypto_idfp);
 145                 e.crypto_idfp = string_null;
 146         }
 147         remove(e);
 148         e = world;
 149
 150         object_count -= 1;
 151 }
 152
 153 string sandbox_ObjectPort_Save_string(entity e, float database)
 154 {
 155         string s;
 156         s = strcat(s, e.model, " ");
 157         s = strcat(s, ftos(e.skin), " ");
 158         s = strcat(s, ftos(e.alpha), " ");
 159         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 160         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 161         s = strcat(s, ftos(e.frame), " ");
 162         s = strcat(s, ftos(e.scale), " ");
 163         s = strcat(s, ftos(e.movetype), " ");
 164         s = strcat(s, ftos(e.damageforcescale), " ");
 165         if(e.material)  s = strcat(s, e.material, " "); else    s = strcat(s, "- "); // none
 166         if(database)
 167         {
 168                 if(e.crypto_idfp)       s = strcat(s, e.crypto_idfp, " ");      else    s = strcat(s, "- "); // none
 169                 s = strcat(s, sprintf("\"%.9v\"", e.origin), " ");
 170                 s = strcat(s, sprintf("\"%.9v\"", e.angles), " ");
 171         }
 172         s = strcat(s, "; ");
 173         return s;
 174 }
 175 string sandbox_ObjectPort_Save(entity e, float database)
 176 {
 177         // save object properties
 178         string s;
 179         entity head;
 180
 181         // first set the properties of the main object, then those of each child
 182         s = sandbox_ObjectPort_Save_string(e, database);
 183         for(head = world; (head = find(head, classname, "object")); )
 184         {
 185                 if(head.owner == e)
 186                         s = strcat(s, sandbox_ObjectPort_Save_string(head, database));
 187         }
 188
 189         return s;
 190 }
 191
 192 entity sandbox_ObjectPort_Load(string s, float database)
 193 {
 194         // load object properties
 195         float n, i;
 196         entity e;
 197
 198         for(;;)
 199         {
 200                 n = tokenizebyseparator(s, "; ");
 201                 tokenize_console(argv(i));
 202                 e = sandbox_ObjectSpawn(database);
 203
 204                 setmodel(e, argv(0));
 205                 e.skin = stof(argv(1));
 206                 e.alpha = stof(argv(2));
 207                 e.colormod = stov(argv(3));
 208                 e.glowmod = stov(argv(4));
 209                 e.frame = stof(argv(5));
 210                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 211                 e.movetype = stof(argv(7));
 212                 e.damageforcescale = stof(argv(8));
 213                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 214                 if(database)
 215                 {
 216                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10) != "-")     e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 217                         setorigin(e, stov(argv(11)));
 218                         e.angles = stov(argv(12));
 219                 }
 220
 221                 i += 1;
 222                 if(i > n)
 223                         break;
 224         }
 225
 226         return e;
 227 }
 228
 229 void sandbox_Database_Save()
 230 {
 231         // saves all objects to the database file
 232         entity head;
 233         string file_name;
 234         float file_get;
 235
 236         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 237         file_get = fopen(file_name, FILE_WRITE);
 238         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 239         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 240
 241         for(head = world; (head = find(head, classname, "object")); )
 242         {
 243                 // Unfortunately, attached objects cannot be persisted yet. That's because the parent is specified as an entity,
 244                 // but only properties can be saved to this file, leaving no way to identify the owner once all objects are spawned
 245                 // TODO: Find some way to fix this!
 246                 if(head.owner != world)
 247                         continue;
 248
 249                 // use a line for each object, listing all properties
 250                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 251         }
 252         fclose(file_get);
 253 }
 254
 255 void sandbox_Database_Load()
 256 {
 257         // loads all objects from the database file
 258         string file_read, file_name;
 259         float file_get, i;
 260
 261         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 262         file_get = fopen(file_name, FILE_READ);
 263         if(file_get < 0)
 264         {
 265                 if(autocvar_g_sandbox_info > 0)
 266                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 267         }
 268         else
 269         {
 270                 for(;;)
 271                 {
 272                         file_read = fgets(file_get);
 273                         if(!file_read)
 274                                 break;
 275                         if(substring(file_read, 0, 2) == "//")
 276                                 continue;
 277                         if(substring(file_read, 0, 1) == "#")
 278                                 continue;
 279
 280                         entity e;
 281                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 282
 283                         if(e.material)
 284                         {
 285                                 // since objects are being loaded for the first time, precache material sounds for each
 286                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 287                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 288                         }
 289                 }
 290                 if(autocvar_g_sandbox_info > 0)
 291                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 292         }
 293 }
 294
 295 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 296 {
 297         if(MUTATOR_RETURNVALUE) // command was already handled?
 298                 return FALSE;
 299         if(cmd_name == "g_sandbox")
 300         {
 301                 if(cmd_argc < 2)
 302                 {
 303                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 304                         return TRUE;
 305                 }
 306
 307                 switch(argv(1))
 308                 {
 309                         entity e;
 310                         float i;
 311
 312                         // ---------------- COMMAND: HELP ----------------
 313                         case "help":
 314                                 print_to(self, "You can use the following sandbox commands:");
 315                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 316                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 317                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 318                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 319                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 320                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 321                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 322                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 323                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 324                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 325                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 326                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 327                                 print_to(self, "^3alpha value ^7- sets object transparency");
 328                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 329                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 330                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 331                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 332                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 333                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 334                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 335                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 336                                 return TRUE;
 337
 338                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 339                         case "object_spawn":
 340                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 341                                 {
 342                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 343                                         return TRUE;
 344                                 }
 345                                 if(cmd_argc < 3)
 346                                 {
 347                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 348                                         return TRUE;
 349                                 }
 350                                 else if not(fexists(argv(2)))
 351                                 {
 352                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 353                                         return TRUE;
 354                                 }
 355
 356                                 e = sandbox_ObjectSpawn(FALSE);
 357                                 setmodel(e, argv(2));
 358
 359                                 if(autocvar_g_sandbox_info > 0)
 360                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 361                                 return TRUE;
 362
 363                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 364                         case "object_remove":
 365                                 e = sandbox_ObjectEdit_Get();
 366                                 if(e != world)
 367                                 {
 368                                         if(autocvar_g_sandbox_info > 0)
 369                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 370                                         sandbox_ObjectRemove(e);
 371                                         return TRUE;
 372                                 }
 373
 374                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 375                                 return TRUE;
 376
 377                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 378                         case "object_duplicate":
 379                                 switch(argv(2))
 380                                 {
 381                                         case "copy":
 382                                                 // copies customizable properties of the selected object to the clipboard
 383                                                 e = sandbox_ObjectEdit_Get(); // you can only copy objects you can edit, so this works
 384                                                 if(e != world)
 385                                                 {
 386                                                         if(self.object_clipboard)
 387                                                                 strunzone(self.object_clipboard);
 388                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 389
 390                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 391                                                         return TRUE;
 392                                                 }
 393                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 394                                                 return TRUE;
 395
 396                                         case "paste":
 397                                                 // spawns a new object using the properties in the player's clipboard
 398                                                 if(!self.object_clipboard) // no object in clipboard
 399                                                 {
 400                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 401                                                         return TRUE;
 402                                                 }
 403                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 404                                                 {
 405                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 406                                                         return TRUE;
 407                                                 }
 408
 409                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 410
 411                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 412                                                 if(autocvar_g_sandbox_info > 0)
 413                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 414                                                 return TRUE;
 415                                 }
 416                                 return TRUE;
 417
 418                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 419                         case "object_claim":
 420                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 421                                 if(self.crypto_idfp == "")
 422                                 {
 423                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 424                                         return TRUE;
 425                                 }
 426                                 e = sandbox_ObjectEdit_Get();
 427                                 if(e != world)
 428                                 {
 429                                         if(e.crypto_idfp == self.crypto_idfp)
 430                                         {
 431                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 432                                                 return TRUE;
 433                                         }
 434
 435                                         if(e.crypto_idfp)
 436                                                 strunzone(e.crypto_idfp);
 437                                         e.crypto_idfp = self.crypto_idfp;
 438                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 439                                 }
 440                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 441                                 return TRUE;
 442
 443                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 444                         case "object_attach":
 445                                 switch(argv(2))
 446                                 {
 447                                         case "get":
 448                                                 // select e as the object as meant to be attached
 449                                                 e = sandbox_ObjectEdit_Get();
 450                                                 if(e != world)
 451                                                 {
 452                                                         self.object_attach = e;
 453                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 454                                                         return TRUE;
 455                                                 }
 456                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 457                                                 return TRUE;
 458                                         case "set":
 459                                                 if(self.object_attach == world)
 460                                                 {
 461                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 462                                                         return TRUE;
 463                                                 }
 464
 465                                                 // attaches the previously selected object to e
 466                                                 e = sandbox_ObjectEdit_Get();
 467                                                 if(e != world)
 468                                                 {
 469                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 470                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 471                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 472                                                         if(autocvar_g_sandbox_info > 1)
 473                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 474                                                         return TRUE;
 475                                                 }
 476                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 477                                                 return TRUE;
 478                                         case "remove":
 479                                                 // removes e if it was attached
 480                                                 e = sandbox_ObjectEdit_Get();
 481                                                 if(e != world)
 482                                                 {
 483                                                         sandbox_ObjectAttach_Remove(e);
 484                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 485                                                         if(autocvar_g_sandbox_info > 1)
 486                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 487                                                         return TRUE;
 488                                                 }
 489                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 490                                                 return TRUE;
 491                                 }
 492                                 return TRUE;
 493
 494                         // ---------------- COMMAND: EDIT OBJECT ----------------
 495                         case "object_edit":
 496                                 if(!argv(2))
 497                                 {
 498                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 499                                         return TRUE;
 500                                 }
 501
 502                                 e = sandbox_ObjectEdit_Get();
 503                                 if(e != world)
 504                                 {
 505                                         switch(argv(2))
 506                                         {
 507                                                 case "skin":
 508                                                         e.skin = stof(argv(3));
 509                                                         break;
 510                                                 case "alpha":
 511                                                         e.alpha = stof(argv(3));
 512                                                         break;
 513                                                 case "color_main":
 514                                                         e.colormod = stov(argv(3));
 515                                                         break;
 516                                                 case "color_glow":
 517                                                         e.glowmod = stov(argv(3));
 518                                                         break;
 519                                                 case "frame":
 520                                                         e.frame = stof(argv(3));
 521                                                         break;
 522                                                 case "scale":
 523                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 524                                                         break;
 525                                                 case "physics":
 526                                                         switch(argv(3))
 527                                                         {
 528                                                                 case "0": // static
 529                                                                         e.movetype = MOVETYPE_NONE;
 530                                                                         break;
 531                                                                 case "1": // movable
 532                                                                         e.movetype = MOVETYPE_TOSS;
 533                                                                         break;
 534                                                                 case "2": // physical
 535                                                                         e.movetype = MOVETYPE_PHYSICS;
 536                                                                         break;
 537                                                                 default:
 538                                                                         break;
 539                                                         }
 540                                                         break;
 541                                                 case "force":
 542                                                         e.damageforcescale = stof(argv(3));
 543                                                         break;
 544                                                 case "material":
 545                                                         if(e.material)
 546                                                                 strunzone(e.material);
 547                                                         if(argv(3))
 548                                                         {
 549                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 550                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 551                                                                 e.material = strzone(argv(3));
 552                                                         }
 553                                                         else
 554                                                                 e.material = string_null; // no material
 555                                                         break;
 556                                                 default:
 557                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 558                                                         break;
 559                                         }
 560                                         if(autocvar_g_sandbox_info > 1)
 561                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 562                                         return TRUE;
 563                                 }
 564
 565                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 566                                 return TRUE;
 567
 568                         // ---------------- COMMAND: DEFAULT ----------------
 569                         default:
 570                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 571                                 return TRUE;
 572                 }
 573         }
 574         return FALSE;
 575 }
 576
 577 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 578 {
 579         // if the player is close enough to their object, they can drag it
 580
 581         if(autocvar_sv_cheats)
 582                 return FALSE; // cheat dragging is used instead
 583
 584         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 585         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 586         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 587         // it goes out of range while slinging it around.
 588
 589         entity e;
 590         float grab;
 591
 592         e = sandbox_ObjectEdit_Get();
 593         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 594                 grab = TRUE;
 595
 596         if(Drag(e, grab)) // execute dragging
 597                 return TRUE;
 598
 599         return FALSE;
 600 }
 601
 602 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 603 {
 604         // unzone the player's clipboard if it's not empty
 605         if(self.object_clipboard)
 606         {
 607                 strunzone(self.object_clipboard);
 608                 self.object_clipboard = string_null;
 609         }
 610
 611         return FALSE;
 612 }
 613
 614 float autosave_time;
 615 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 616 {
 617         if(!autocvar_g_sandbox_storage_autosave)
 618                 return FALSE;
 619         if(time < autocvar_g_sandbox_storage_autosave)
 620                 return FALSE;
 621         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 622
 623         sandbox_Database_Save();
 624
 625         return TRUE;
 626 }
 627
 628 MUTATOR_DEFINITION(sandbox)
 629 {
 630         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 631         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 632         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 633         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 634
 635         MUTATOR_ONADD
 636         {
 637                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 638                 if(autocvar_g_sandbox_storage_autoload)
 639                         sandbox_Database_Load();
 640         }
 641
 642         return FALSE;
 643 }
 644