qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get()
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // attached objects are SOLID_NOT and don't risk getting traced
  37
  38         makevectors(self.v_angle);
  39         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  40
  41         if(trace_ent.classname != "object")
  42                 return world; // entity is not an object
  43         if(!trace_ent.crypto_idfp)
  44                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  45         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  46                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  47         return world;
  48 }
  49
  50 void sandbox_ObjectEdit_Scale(entity e, float f)
  51 {
  52         e.scale = f;
  53         if(e.scale)
  54         {
  55                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  56                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  57         }
  58 }
  59
  60 void sandbox_ObjectAttach_Remove(entity e);
  61 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  62 {
  63         // attaches e to parent on string s
  64
  65         // we can't attach to an attachment, for obvious reasons
  66         sandbox_ObjectAttach_Remove(e);
  67
  68         e.movetype = MOVETYPE_FOLLOW;
  69         e.solid = SOLID_NOT;
  70         e.takedamage = DAMAGE_NO;
  71
  72         setattachment(e, parent, s);
  73         e.owner = parent;
  74 }
  75
  76 void sandbox_ObjectAttach_Remove(entity e)
  77 {
  78         // detaches any object attached to e
  79
  80         entity head;
  81         for(head = world; (head = find(head, classname, "object")); )
  82         {
  83                 if(head.owner == e)
  84                 {
  85                         head.movetype = MOVETYPE_TOSS; // default
  86                         head.solid = SOLID_BBOX;
  87                         head.takedamage = DAMAGE_AIM;
  88
  89                         setattachment(head, world, "");
  90                         head.owner = world;
  91
  92                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  93                         setorigin(head, e.origin);
  94                         head.angles = e.angles;
  95                 }
  96         }
  97 }
  98
  99 entity sandbox_ObjectSpawn(float database)
 100 {
 101         // spawn a new object with default properties
 102
 103         entity e;
 104         e = spawn();
 105         e.classname = "object";
 106         e.takedamage = DAMAGE_AIM;
 107         e.damageforcescale = 1;
 108         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 109         e.movetype = MOVETYPE_TOSS;
 110         e.frame = 0;
 111         e.skin = 0;
 112         e.material = string_null;
 113         e.touch = sandbox_ObjectFunction_Touch;
 114
 115         if(!database)
 116         {
 117                 // set the object's owner via player UID
 118                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 119                 if(self.crypto_idfp != "")
 120                         e.crypto_idfp = strzone(self.crypto_idfp);
 121                 else
 122                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 123
 124                 // set origin and direction based on player position and view angle
 125                 makevectors(self.v_angle);
 126                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 127                 setorigin(e, trace_endpos);
 128                 e.angles_y = self.v_angle_y;
 129         }
 130
 131         object_count += 1;
 132         return e;
 133 }
 134
 135 void sandbox_ObjectRemove(entity e)
 136 {
 137         sandbox_ObjectAttach_Remove(e); // detach child objects
 138         if(e.material)
 139         {
 140                 strunzone(e.material);
 141                 e.material = string_null;
 142         }
 143         if(e.crypto_idfp)
 144         {
 145                 strunzone(e.crypto_idfp);
 146                 e.crypto_idfp = string_null;
 147         }
 148         remove(e);
 149         e = world;
 150
 151         object_count -= 1;
 152 }
 153
 154 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 155
 156 string sandbox_ObjectPort_Save(entity e, float database)
 157 {
 158         // TODO: Store attachement bone for attached objects as well!
 159
 160         // save object properties, and return them as a string
 161         float i;
 162         string s;
 163         entity head;
 164
 165         for(head = world; (head = find(head, classname, "object")); )
 166         {
 167                 // the main object needs to be first in the array [0], with attached objects following
 168                 float slot;
 169                 if(head == e) // this is the main object, make it first
 170                         slot = 0;
 171                 else if(head.owner == e) // child object, list them in order
 172                 {
 173                         i += 1; // children start from 1
 174                         slot = i;
 175                 }
 176                 else
 177                         continue;
 178
 179                 port_string[slot] = strcat(port_string[slot], head.model, " ");
 180                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 181                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 182                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 183                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 184                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 185                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 186                 port_string[slot] = strcat(port_string[slot], ftos(head.movetype), " ");
 187                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 188                 if(head.material)       port_string[slot] = strcat(port_string[slot], head.material, " ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 189                 if(database)
 190                 {
 191                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], head.crypto_idfp, " ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 192                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 193                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 194                 }
 195         }
 196
 197         // now apply the array to a simple string, with the ; symbol separating objects
 198         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 199         {
 200                 if(port_string[i])
 201                         s = strcat(s, port_string[i], "; ");
 202                 port_string[i] = string_null; // fully clear the string
 203         }
 204
 205         return s;
 206 }
 207
 208 entity sandbox_ObjectPort_Load(string s, float database)
 209 {
 210         // TODO: Store attachement bone for attached objects as well!
 211
 212         // load object properties, and spawn a new object with them
 213         float n, i;
 214         entity e, parent;
 215
 216         // separate objects between the ; symbols
 217         n = tokenizebyseparator(s, "; ");
 218         for(i = 0; i < n; ++i)
 219                 port_string[i] = argv(i);
 220
 221         // now separate and apply the properties of each object
 222         for(i = 0; i < n; ++i)
 223         {
 224                 tokenize_console(port_string[i]);
 225                 e = sandbox_ObjectSpawn(database);
 226
 227                 setmodel(e, argv(0));
 228                 e.skin = stof(argv(1));
 229                 e.alpha = stof(argv(2));
 230                 e.colormod = stov(argv(3));
 231                 e.glowmod = stov(argv(4));
 232                 e.frame = stof(argv(5));
 233                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 234                 e.movetype = stof(argv(7));
 235                 e.damageforcescale = stof(argv(8));
 236                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 237                 if(database)
 238                 {
 239                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10) != "-")     e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 240                         setorigin(e, stov(argv(11)));
 241                         e.angles = stov(argv(12));
 242                 }
 243
 244                 if(!i) // parent object, set it as such and leave it be
 245                         parent = e;
 246                 else // child object, attach it to the parent
 247                         sandbox_ObjectAttach_Set(e, parent, "");
 248         }
 249
 250         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 251                 port_string[i] = string_null; // fully clear the string
 252
 253         return e;
 254 }
 255
 256 void sandbox_Database_Save()
 257 {
 258         // saves all objects to the database file
 259         entity head;
 260         string file_name;
 261         float file_get;
 262
 263         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 264         file_get = fopen(file_name, FILE_WRITE);
 265         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 266         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 267
 268         for(head = world; (head = find(head, classname, "object")); )
 269         {
 270                 // attached objects are persisted separately, ignore them here
 271                 if(head.owner != world)
 272                         continue;
 273
 274                 // use a line of text for each object, listing all properties
 275                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 276         }
 277         fclose(file_get);
 278 }
 279
 280 void sandbox_Database_Load()
 281 {
 282         // loads all objects from the database file
 283         string file_read, file_name;
 284         float file_get, i;
 285
 286         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 287         file_get = fopen(file_name, FILE_READ);
 288         if(file_get < 0)
 289         {
 290                 if(autocvar_g_sandbox_info > 0)
 291                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 292         }
 293         else
 294         {
 295                 for(;;)
 296                 {
 297                         file_read = fgets(file_get);
 298                         if(!file_read)
 299                                 break;
 300                         if(substring(file_read, 0, 2) == "//")
 301                                 continue;
 302                         if(substring(file_read, 0, 1) == "#")
 303                                 continue;
 304
 305                         entity e;
 306                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 307
 308                         if(e.material)
 309                         {
 310                                 // since objects are being loaded for the first time, precache material sounds for each
 311                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 312                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 313                         }
 314                 }
 315                 if(autocvar_g_sandbox_info > 0)
 316                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 317         }
 318 }
 319
 320 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 321 {
 322         if(MUTATOR_RETURNVALUE) // command was already handled?
 323                 return FALSE;
 324         if(cmd_name == "g_sandbox")
 325         {
 326                 if(cmd_argc < 2)
 327                 {
 328                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 329                         return TRUE;
 330                 }
 331
 332                 switch(argv(1))
 333                 {
 334                         entity e;
 335                         float i;
 336
 337                         // ---------------- COMMAND: HELP ----------------
 338                         case "help":
 339                                 print_to(self, "You can use the following sandbox commands:");
 340                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 341                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 342                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 343                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 344                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 345                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 346                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 347                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 348                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 349                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 350                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 351                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 352                                 print_to(self, "^3alpha value ^7- sets object transparency");
 353                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 354                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 355                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 356                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 357                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 358                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 359                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 360                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 361                                 return TRUE;
 362
 363                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 364                         case "object_spawn":
 365                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 366                                 {
 367                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 368                                         return TRUE;
 369                                 }
 370                                 if(cmd_argc < 3)
 371                                 {
 372                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 373                                         return TRUE;
 374                                 }
 375                                 else if not(fexists(argv(2)))
 376                                 {
 377                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 378                                         return TRUE;
 379                                 }
 380
 381                                 e = sandbox_ObjectSpawn(FALSE);
 382                                 setmodel(e, argv(2));
 383
 384                                 if(autocvar_g_sandbox_info > 0)
 385                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 386                                 return TRUE;
 387
 388                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 389                         case "object_remove":
 390                                 e = sandbox_ObjectEdit_Get();
 391                                 if(e != world)
 392                                 {
 393                                         if(autocvar_g_sandbox_info > 0)
 394                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 395                                         sandbox_ObjectRemove(e);
 396                                         return TRUE;
 397                                 }
 398
 399                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 400                                 return TRUE;
 401
 402                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 403                         case "object_duplicate":
 404                                 switch(argv(2))
 405                                 {
 406                                         case "copy":
 407                                                 // copies customizable properties of the selected object to the clipboard
 408                                                 e = sandbox_ObjectEdit_Get(); // you can only copy objects you can edit, so this works
 409                                                 if(e != world)
 410                                                 {
 411                                                         if(self.object_clipboard)
 412                                                                 strunzone(self.object_clipboard);
 413                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 414
 415                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 416                                                         return TRUE;
 417                                                 }
 418                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 419                                                 return TRUE;
 420
 421                                         case "paste":
 422                                                 // spawns a new object using the properties in the player's clipboard
 423                                                 if(!self.object_clipboard) // no object in clipboard
 424                                                 {
 425                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 426                                                         return TRUE;
 427                                                 }
 428                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 429                                                 {
 430                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 431                                                         return TRUE;
 432                                                 }
 433
 434                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 435
 436                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 437                                                 if(autocvar_g_sandbox_info > 0)
 438                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 439                                                 return TRUE;
 440                                 }
 441                                 return TRUE;
 442
 443                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 444                         case "object_claim":
 445                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 446                                 if(self.crypto_idfp == "")
 447                                 {
 448                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 449                                         return TRUE;
 450                                 }
 451                                 e = sandbox_ObjectEdit_Get();
 452                                 if(e != world)
 453                                 {
 454                                         if(e.crypto_idfp == self.crypto_idfp)
 455                                         {
 456                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 457                                                 return TRUE;
 458                                         }
 459
 460                                         if(e.crypto_idfp)
 461                                                 strunzone(e.crypto_idfp);
 462                                         e.crypto_idfp = self.crypto_idfp;
 463                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 464                                 }
 465                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 466                                 return TRUE;
 467
 468                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 469                         case "object_attach":
 470                                 switch(argv(2))
 471                                 {
 472                                         case "get":
 473                                                 // select e as the object as meant to be attached
 474                                                 e = sandbox_ObjectEdit_Get();
 475                                                 if(e != world)
 476                                                 {
 477                                                         self.object_attach = e;
 478                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 479                                                         return TRUE;
 480                                                 }
 481                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 482                                                 return TRUE;
 483                                         case "set":
 484                                                 if(self.object_attach == world)
 485                                                 {
 486                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 487                                                         return TRUE;
 488                                                 }
 489
 490                                                 // attaches the previously selected object to e
 491                                                 e = sandbox_ObjectEdit_Get();
 492                                                 if(e != world)
 493                                                 {
 494                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 495                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 496                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 497                                                         if(autocvar_g_sandbox_info > 1)
 498                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 499                                                         return TRUE;
 500                                                 }
 501                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 502                                                 return TRUE;
 503                                         case "remove":
 504                                                 // removes e if it was attached
 505                                                 e = sandbox_ObjectEdit_Get();
 506                                                 if(e != world)
 507                                                 {
 508                                                         sandbox_ObjectAttach_Remove(e);
 509                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 510                                                         if(autocvar_g_sandbox_info > 1)
 511                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 512                                                         return TRUE;
 513                                                 }
 514                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 515                                                 return TRUE;
 516                                 }
 517                                 return TRUE;
 518
 519                         // ---------------- COMMAND: EDIT OBJECT ----------------
 520                         case "object_edit":
 521                                 if(!argv(2))
 522                                 {
 523                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 524                                         return TRUE;
 525                                 }
 526
 527                                 e = sandbox_ObjectEdit_Get();
 528                                 if(e != world)
 529                                 {
 530                                         switch(argv(2))
 531                                         {
 532                                                 case "skin":
 533                                                         e.skin = stof(argv(3));
 534                                                         break;
 535                                                 case "alpha":
 536                                                         e.alpha = stof(argv(3));
 537                                                         break;
 538                                                 case "color_main":
 539                                                         e.colormod = stov(argv(3));
 540                                                         break;
 541                                                 case "color_glow":
 542                                                         e.glowmod = stov(argv(3));
 543                                                         break;
 544                                                 case "frame":
 545                                                         e.frame = stof(argv(3));
 546                                                         break;
 547                                                 case "scale":
 548                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 549                                                         break;
 550                                                 case "physics":
 551                                                         switch(argv(3))
 552                                                         {
 553                                                                 case "0": // static
 554                                                                         e.movetype = MOVETYPE_NONE;
 555                                                                         break;
 556                                                                 case "1": // movable
 557                                                                         e.movetype = MOVETYPE_TOSS;
 558                                                                         break;
 559                                                                 case "2": // physical
 560                                                                         e.movetype = MOVETYPE_PHYSICS;
 561                                                                         break;
 562                                                                 default:
 563                                                                         break;
 564                                                         }
 565                                                         break;
 566                                                 case "force":
 567                                                         e.damageforcescale = stof(argv(3));
 568                                                         break;
 569                                                 case "material":
 570                                                         if(e.material)
 571                                                                 strunzone(e.material);
 572                                                         if(argv(3))
 573                                                         {
 574                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 575                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 576                                                                 e.material = strzone(argv(3));
 577                                                         }
 578                                                         else
 579                                                                 e.material = string_null; // no material
 580                                                         break;
 581                                                 default:
 582                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 583                                                         break;
 584                                         }
 585                                         if(autocvar_g_sandbox_info > 1)
 586                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 587                                         return TRUE;
 588                                 }
 589
 590                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 591                                 return TRUE;
 592
 593                         // ---------------- COMMAND: DEFAULT ----------------
 594                         default:
 595                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 596                                 return TRUE;
 597                 }
 598         }
 599         return FALSE;
 600 }
 601
 602 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 603 {
 604         // if the player is close enough to their object, they can drag it
 605
 606         if(autocvar_sv_cheats)
 607                 return FALSE; // cheat dragging is used instead
 608
 609         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 610         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 611         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 612         // it goes out of range while slinging it around.
 613
 614         entity e;
 615         float grab;
 616
 617         e = sandbox_ObjectEdit_Get();
 618         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 619                 grab = TRUE;
 620
 621         if(Drag(e, grab)) // execute dragging
 622                 return TRUE;
 623
 624         return FALSE;
 625 }
 626
 627 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 628 {
 629         // unzone the player's clipboard if it's not empty
 630         if(self.object_clipboard)
 631         {
 632                 strunzone(self.object_clipboard);
 633                 self.object_clipboard = string_null;
 634         }
 635
 636         return FALSE;
 637 }
 638
 639 float autosave_time;
 640 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 641 {
 642         if(!autocvar_g_sandbox_storage_autosave)
 643                 return FALSE;
 644         if(time < autosave_time)
 645                 return FALSE;
 646         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 647
 648         sandbox_Database_Save();
 649
 650         return TRUE;
 651 }
 652
 653 MUTATOR_DEFINITION(sandbox)
 654 {
 655         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 656         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 657         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 658         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 659
 660         MUTATOR_ONADD
 661         {
 662                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 663                 if(autocvar_g_sandbox_storage_autoload)
 664                         sandbox_Database_Load();
 665         }
 666
 667         return FALSE;
 668 }
 669