qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 .float old_movetype;
  64 void sandbox_ObjectAttach_Remove(entity e);
  65 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  66 {
  67         // attaches e to parent on string s
  68
  69         // we can't attach to an attachment, for obvious reasons
  70         sandbox_ObjectAttach_Remove(e);
  71
  72         e.old_movetype = e.movetype; // persist physics
  73         e.movetype = MOVETYPE_FOLLOW;
  74         e.solid = SOLID_NOT;
  75         e.takedamage = DAMAGE_NO;
  76
  77         setattachment(e, parent, s);
  78         e.owner = parent;
  79 }
  80
  81 void sandbox_ObjectAttach_Remove(entity e)
  82 {
  83         // detaches any object attached to e
  84
  85         entity head;
  86         for(head = world; (head = find(head, classname, "object")); )
  87         {
  88                 if(head.owner == e)
  89                 {
  90                         vector org;
  91                         head.movetype = head.old_movetype; // restore persisted physics
  92                         head.solid = SOLID_BBOX;
  93                         head.takedamage = DAMAGE_AIM;
  94
  95                         org = gettaginfo(head, 0);
  96                         setattachment(head, world, "");
  97                         head.owner = world;
  98
  99                         // objects change origin and angles when detached, so apply previous position
 100                         setorigin(head, org);
 101                         head.angles = e.angles; // don't allow detached objects to spin or roll
 102                 }
 103         }
 104 }
 105
 106 entity sandbox_ObjectSpawn(float database)
 107 {
 108         // spawn a new object with default properties
 109
 110         entity e;
 111         e = spawn();
 112         e.classname = "object";
 113         e.takedamage = DAMAGE_AIM;
 114         e.damageforcescale = 1;
 115         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 116         e.movetype = MOVETYPE_TOSS;
 117         e.frame = 0;
 118         e.skin = 0;
 119         e.material = string_null;
 120         e.touch = sandbox_ObjectFunction_Touch;
 121
 122         if(!database)
 123         {
 124                 // set the object's owner via player UID
 125                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 126                 if(self.crypto_idfp != "")
 127                         e.crypto_idfp = strzone(self.crypto_idfp);
 128                 else
 129                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 130
 131                 // set origin and direction based on player position and view angle
 132                 makevectors(self.v_angle);
 133                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 134                 setorigin(e, trace_endpos);
 135                 e.angles_y = self.v_angle_y;
 136         }
 137
 138         object_count += 1;
 139         return e;
 140 }
 141
 142 void sandbox_ObjectRemove(entity e)
 143 {
 144         sandbox_ObjectAttach_Remove(e); // detach child objects
 145         if(e.material)
 146         {
 147                 strunzone(e.material);
 148                 e.material = string_null;
 149         }
 150         if(e.crypto_idfp)
 151         {
 152                 strunzone(e.crypto_idfp);
 153                 e.crypto_idfp = string_null;
 154         }
 155         remove(e);
 156         e = world;
 157
 158         object_count -= 1;
 159 }
 160
 161 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 162
 163 string sandbox_ObjectPort_Save(entity e, float database)
 164 {
 165         // save object properties, and return them as a string
 166         float i;
 167         string s;
 168         entity head;
 169
 170         for(head = world; (head = find(head, classname, "object")); )
 171         {
 172                 // the main object needs to be first in the array [0] with attached objects following
 173                 float slot, physics;
 174                 if(head == e) // this is the main object, place it first
 175                 {
 176                         slot = 0;
 177                         physics = head.movetype; // applied physics are normal physics for parents
 178                 }
 179                 else if(head.owner == e) // child object, list them in order
 180                 {
 181                         i += 1; // children start from 1
 182                         slot = i;
 183                         physics = head.old_movetype; // persisted physics are normal physics for children
 184                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 185                 }
 186                 else
 187                         continue;
 188
 189                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 190                 if(slot)
 191                 {
 192                         // properties stored only for child objects
 193                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 194                 }
 195                 else
 196                 {
 197                         // properties stored only for parent objects
 198                         if(database)
 199                         {
 200                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 201                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 202                         }
 203                 }
 204                 // properties stored for all objects
 205                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 206                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 207                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 208                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 209                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 210                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 212                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 213                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 214                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 215                 if(database)
 216                 {
 217                         // properties stored only for the database
 218                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 219                 }
 220         }
 221
 222         // now apply the array to a simple string, with the ; symbol separating objects
 223         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 224         {
 225                 if(port_string[i])
 226                         s = strcat(s, port_string[i], "; ");
 227                 port_string[i] = string_null; // fully clear the string
 228         }
 229
 230         return s;
 231 }
 232
 233 entity sandbox_ObjectPort_Load(string s, float database)
 234 {
 235         // load object properties, and spawn a new object with them
 236         float n, i;
 237         entity e, parent;
 238
 239         // separate objects between the ; symbols
 240         n = tokenizebyseparator(s, "; ");
 241         for(i = 0; i < n; ++i)
 242                 port_string[i] = argv(i);
 243
 244         // now separate and apply the properties of each object
 245         for(i = 0; i < n; ++i)
 246         {
 247                 float argv_num;
 248                 string tagname;
 249                 argv_num = 0;
 250                 tokenize_console(port_string[i]);
 251                 e = sandbox_ObjectSpawn(database);
 252
 253                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 254                 if(i)
 255                 {
 256                         // properties stored only for child objects
 257                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 258                 }
 259                 else
 260                 {
 261                         // properties stored only for parent objects
 262                         if(database)
 263                         {
 264                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 265                                 e.angles = stov(argv(argv_num));        ++argv_num;
 266                         }
 267                         parent = e; // mark parent objects as such
 268                 }
 269                 // properties stored for all objects
 270                 setmodel(e, argv(argv_num));    ++argv_num;
 271                 e.skin = stof(argv(argv_num));  ++argv_num;
 272                 e.alpha = stof(argv(argv_num)); ++argv_num;
 273                 e.colormod = stov(argv(argv_num));      ++argv_num;
 274                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 275                 e.frame = stof(argv(argv_num)); ++argv_num;
 276                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 277                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 278                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 279                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 280                 if(database)
 281                 {
 282                         // properties stored only for the database
 283                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 284                 }
 285
 286                 // attach last
 287                 if(i)
 288                         sandbox_ObjectAttach_Set(e, parent, tagname);
 289         }
 290
 291         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 292                 port_string[i] = string_null; // fully clear the string
 293
 294         return e;
 295 }
 296
 297 void sandbox_Database_Save()
 298 {
 299         // saves all objects to the database file
 300         entity head;
 301         string file_name;
 302         float file_get;
 303
 304         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 305         file_get = fopen(file_name, FILE_WRITE);
 306         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 307         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 308
 309         for(head = world; (head = find(head, classname, "object")); )
 310         {
 311                 // attached objects are persisted separately, ignore them here
 312                 if(head.owner != world)
 313                         continue;
 314
 315                 // use a line of text for each object, listing all properties
 316                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 317         }
 318         fclose(file_get);
 319 }
 320
 321 void sandbox_Database_Load()
 322 {
 323         // loads all objects from the database file
 324         string file_read, file_name;
 325         float file_get, i;
 326
 327         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 328         file_get = fopen(file_name, FILE_READ);
 329         if(file_get < 0)
 330         {
 331                 if(autocvar_g_sandbox_info > 0)
 332                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 333         }
 334         else
 335         {
 336                 for(;;)
 337                 {
 338                         file_read = fgets(file_get);
 339                         if(!file_read)
 340                                 break;
 341                         if(substring(file_read, 0, 2) == "//")
 342                                 continue;
 343                         if(substring(file_read, 0, 1) == "#")
 344                                 continue;
 345
 346                         entity e;
 347                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 348
 349                         if(e.material)
 350                         {
 351                                 // since objects are being loaded for the first time, precache material sounds for each
 352                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 353                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 354                         }
 355                 }
 356                 if(autocvar_g_sandbox_info > 0)
 357                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 358         }
 359 }
 360
 361 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 362 {
 363         if(MUTATOR_RETURNVALUE) // command was already handled?
 364                 return FALSE;
 365         if(cmd_name == "g_sandbox")
 366         {
 367                 if(cmd_argc < 2)
 368                 {
 369                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 370                         return TRUE;
 371                 }
 372
 373                 switch(argv(1))
 374                 {
 375                         entity e;
 376                         float i;
 377                         string s;
 378
 379                         // ---------------- COMMAND: HELP ----------------
 380                         case "help":
 381                                 print_to(self, "You can use the following sandbox commands:");
 382                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 383                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 384                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 385                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 386                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 387                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 388                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 389                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 390                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 391                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 392                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 393                                 print_to(self, "^3alpha value ^7- sets object transparency");
 394                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 395                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 396                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 397                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 398                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 399                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 400                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 401                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 402                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 403                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 404                                 return TRUE;
 405
 406                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 407                         case "object_spawn":
 408                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 409                                 {
 410                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 411                                         return TRUE;
 412                                 }
 413                                 if(cmd_argc < 3)
 414                                 {
 415                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 416                                         return TRUE;
 417                                 }
 418                                 else if not(fexists(argv(2)))
 419                                 {
 420                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 421                                         return TRUE;
 422                                 }
 423
 424                                 e = sandbox_ObjectSpawn(FALSE);
 425                                 setmodel(e, argv(2));
 426
 427                                 if(autocvar_g_sandbox_info > 0)
 428                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 429                                 return TRUE;
 430
 431                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 432                         case "object_remove":
 433                                 e = sandbox_ObjectEdit_Get(TRUE);
 434                                 if(e != world)
 435                                 {
 436                                         if(autocvar_g_sandbox_info > 0)
 437                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 438                                         sandbox_ObjectRemove(e);
 439                                         return TRUE;
 440                                 }
 441
 442                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 443                                 return TRUE;
 444
 445                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 446                         case "object_duplicate":
 447                                 switch(argv(2))
 448                                 {
 449                                         case "copy":
 450                                                 // copies customizable properties of the selected object to the clipboard
 451                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 452                                                 if(e != world)
 453                                                 {
 454                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 455                                                         s = strreplace("\"", "\\\"", s);
 456                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 457
 458                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 459                                                         return TRUE;
 460                                                 }
 461                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 462                                                 return TRUE;
 463
 464                                         case "paste":
 465                                                 // spawns a new object using the properties in the player's clipboard
 466                                                 if(!self.object_clipboard) // no object in clipboard
 467                                                 {
 468                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 469                                                         return TRUE;
 470                                                 }
 471                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 472                                                 {
 473                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 474                                                         return TRUE;
 475                                                 }
 476
 477                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 478
 479                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 480                                                 if(autocvar_g_sandbox_info > 0)
 481                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 482                                                 return TRUE;
 483                                 }
 484                                 return TRUE;
 485
 486                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 487                         case "object_attach":
 488                                 switch(argv(2))
 489                                 {
 490                                         case "get":
 491                                                 // select e as the object as meant to be attached
 492                                                 e = sandbox_ObjectEdit_Get(TRUE);
 493                                                 if(e != world)
 494                                                 {
 495                                                         self.object_attach = e;
 496                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 497                                                         return TRUE;
 498                                                 }
 499                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 500                                                 return TRUE;
 501                                         case "set":
 502                                                 if(self.object_attach == world)
 503                                                 {
 504                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 505                                                         return TRUE;
 506                                                 }
 507
 508                                                 // attaches the previously selected object to e
 509                                                 e = sandbox_ObjectEdit_Get(TRUE);
 510                                                 if(e != world)
 511                                                 {
 512                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 513                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 514                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 515                                                         if(autocvar_g_sandbox_info > 1)
 516                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 517                                                         return TRUE;
 518                                                 }
 519                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 520                                                 return TRUE;
 521                                         case "remove":
 522                                                 // removes e if it was attached
 523                                                 e = sandbox_ObjectEdit_Get(TRUE);
 524                                                 if(e != world)
 525                                                 {
 526                                                         sandbox_ObjectAttach_Remove(e);
 527                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 528                                                         if(autocvar_g_sandbox_info > 1)
 529                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 530                                                         return TRUE;
 531                                                 }
 532                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 533                                                 return TRUE;
 534                                 }
 535                                 return TRUE;
 536
 537                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 538                         case "object_edit":
 539                                 if(!argv(2))
 540                                 {
 541                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 542                                         return TRUE;
 543                                 }
 544
 545                                 e = sandbox_ObjectEdit_Get(TRUE);
 546                                 if(e != world)
 547                                 {
 548                                         switch(argv(2))
 549                                         {
 550                                                 case "skin":
 551                                                         e.skin = stof(argv(3));
 552                                                         break;
 553                                                 case "alpha":
 554                                                         e.alpha = stof(argv(3));
 555                                                         break;
 556                                                 case "color_main":
 557                                                         e.colormod = stov(argv(3));
 558                                                         break;
 559                                                 case "color_glow":
 560                                                         e.glowmod = stov(argv(3));
 561                                                         break;
 562                                                 case "frame":
 563                                                         e.frame = stof(argv(3));
 564                                                         break;
 565                                                 case "scale":
 566                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 567                                                         break;
 568                                                 case "physics":
 569                                                         switch(argv(3))
 570                                                         {
 571                                                                 case "0": // static
 572                                                                         e.movetype = MOVETYPE_NONE;
 573                                                                         break;
 574                                                                 case "1": // movable
 575                                                                         e.movetype = MOVETYPE_TOSS;
 576                                                                         break;
 577                                                                 case "2": // physical
 578                                                                         e.movetype = MOVETYPE_PHYSICS;
 579                                                                         break;
 580                                                                 default:
 581                                                                         break;
 582                                                         }
 583                                                         break;
 584                                                 case "force":
 585                                                         e.damageforcescale = stof(argv(3));
 586                                                         break;
 587                                                 case "material":
 588                                                         if(e.material)
 589                                                                 strunzone(e.material);
 590                                                         if(argv(3))
 591                                                         {
 592                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 593                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 594                                                                 e.material = strzone(argv(3));
 595                                                         }
 596                                                         else
 597                                                                 e.material = string_null; // no material
 598                                                         break;
 599                                                 default:
 600                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 601                                                         break;
 602                                         }
 603                                         if(autocvar_g_sandbox_info > 1)
 604                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 605                                         return TRUE;
 606                                 }
 607
 608                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 609                                 return TRUE;
 610
 611                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 612                         case "object_claim":
 613                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 614                                 if(self.crypto_idfp == "")
 615                                 {
 616                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 617                                         return TRUE;
 618                                 }
 619                                 e = sandbox_ObjectEdit_Get(TRUE);
 620                                 if(e != world)
 621                                 {
 622                                         if(e.crypto_idfp == self.crypto_idfp)
 623                                         {
 624                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 625                                                 return TRUE;
 626                                         }
 627
 628                                         if(e.crypto_idfp)
 629                                                 strunzone(e.crypto_idfp);
 630                                         e.crypto_idfp = self.crypto_idfp;
 631                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 632                                 }
 633                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 634                                 return TRUE;
 635
 636                         // ---------------- COMMAND: OBJECT, INFO ----------------
 637                         case "object_info":
 638                                 // prints public information about the object to the player
 639                                 e = sandbox_ObjectEdit_Get(FALSE);
 640                                 if(e != world)
 641                                 {
 642                                         switch(argv(2))
 643                                         {
 644                                                 case "mesh":
 645                                                         string tags;
 646                                                         for(i = 1; gettaginfo(e, i); i++)
 647                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 648                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 649                                                         return TRUE;
 650                                         }
 651                                 }
 652                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 653                                 return TRUE;
 654
 655                         // ---------------- COMMAND: DEFAULT ----------------
 656                         default:
 657                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 658                                 return TRUE;
 659                 }
 660         }
 661         return FALSE;
 662 }
 663
 664 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 665 {
 666         // if the player is close enough to their object, they can drag it
 667
 668         if(autocvar_sv_cheats)
 669                 return FALSE; // cheat dragging is used instead
 670
 671         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 672         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 673         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 674         // it goes out of range while slinging it around.
 675
 676         entity e;
 677         float grab;
 678
 679         e = sandbox_ObjectEdit_Get(TRUE);
 680         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 681                 grab = TRUE;
 682
 683         if(Drag(e, grab)) // execute dragging
 684                 return TRUE;
 685
 686         return FALSE;
 687 }
 688
 689 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 690 {
 691         // unzone the player's clipboard if it's not empty
 692         if(self.object_clipboard)
 693         {
 694                 strunzone(self.object_clipboard);
 695                 self.object_clipboard = string_null;
 696         }
 697
 698         return FALSE;
 699 }
 700
 701 float autosave_time;
 702 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 703 {
 704         if(!autocvar_g_sandbox_storage_autosave)
 705                 return FALSE;
 706         if(time < autosave_time)
 707                 return FALSE;
 708         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 709
 710         sandbox_Database_Save();
 711
 712         return TRUE;
 713 }
 714
 715 MUTATOR_DEFINITION(sandbox)
 716 {
 717         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 718         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 719         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 720         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 721
 722         MUTATOR_ONADD
 723         {
 724                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 725                 if(autocvar_g_sandbox_storage_autoload)
 726                         sandbox_Database_Load();
 727         }
 728
 729         return FALSE;
 730 }
 731