qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_ObjectFunction_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_ObjectEdit_Get(float permissions)
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // if permissions if FALSE, the object is returned regardless of editing rights
  36         // attached objects are SOLID_NOT and don't risk getting traced
  37
  38         makevectors(self.v_angle);
  39         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  40
  41         if(trace_ent.classname != "object")
  42                 return world; // entity is not an object
  43         if(!permissions)
  44                 return trace_ent; // don't check permissions, anyone can edit this object
  45         if(!trace_ent.crypto_idfp)
  46                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  47         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  48                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  49         return world;
  50 }
  51
  52 void sandbox_ObjectEdit_Scale(entity e, float f)
  53 {
  54         e.scale = f;
  55         if(e.scale)
  56         {
  57                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  58                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  59         }
  60 }
  61
  62 .float old_movetype;
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.old_movetype = e.movetype; // persist physics
  72         e.movetype = MOVETYPE_FOLLOW;
  73         e.solid = SOLID_NOT;
  74         e.takedamage = DAMAGE_NO;
  75
  76         setattachment(e, parent, s);
  77         e.owner = parent;
  78 }
  79
  80 void sandbox_ObjectAttach_Remove(entity e)
  81 {
  82         // detaches any object attached to e
  83
  84         entity head;
  85         for(head = world; (head = find(head, classname, "object")); )
  86         {
  87                 if(head.owner == e)
  88                 {
  89                         vector org;
  90                         head.movetype = head.old_movetype; // restore persisted physics
  91                         head.solid = SOLID_BBOX;
  92                         head.takedamage = DAMAGE_AIM;
  93
  94                         org = gettaginfo(head, 0);
  95                         setattachment(head, world, "");
  96                         head.owner = world;
  97
  98                         // objects change origin and angles when detached, so apply previous position
  99                         setorigin(head, org);
 100                         head.angles = e.angles; // don't allow detached objects to spin or roll
 101                 }
 102         }
 103 }
 104
 105 entity sandbox_ObjectSpawn(float database)
 106 {
 107         // spawn a new object with default properties
 108
 109         entity e;
 110         e = spawn();
 111         e.classname = "object";
 112         e.takedamage = DAMAGE_AIM;
 113         e.damageforcescale = 1;
 114         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 115         e.movetype = MOVETYPE_TOSS;
 116         e.frame = 0;
 117         e.skin = 0;
 118         e.material = string_null;
 119         e.touch = sandbox_ObjectFunction_Touch;
 120         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 121
 122         if(!database)
 123         {
 124                 // set the object's owner via player UID
 125                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 126                 if(self.crypto_idfp != "")
 127                         e.crypto_idfp = strzone(self.crypto_idfp);
 128                 else
 129                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 130
 131                 // set public object information
 132                 e.netname = strzone(self.netname); // name of the owner
 133                 e.message = e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation and edit time
 134
 135                 // set origin and direction based on player position and view angle
 136                 makevectors(self.v_angle);
 137                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 138                 setorigin(e, trace_endpos);
 139                 e.angles_y = self.v_angle_y;
 140         }
 141
 142         object_count += 1;
 143         return e;
 144 }
 145
 146 void sandbox_ObjectRemove(entity e)
 147 {
 148         sandbox_ObjectAttach_Remove(e); // detach child objects
 149
 150         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 151         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 152         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 153         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 154         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 155         remove(e);
 156         e = world;
 157
 158         object_count -= 1;
 159 }
 160
 161 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 162
 163 string sandbox_ObjectPort_Save(entity e, float database)
 164 {
 165         // save object properties, and return them as a string
 166         float i;
 167         string s;
 168         entity head;
 169
 170         for(head = world; (head = find(head, classname, "object")); )
 171         {
 172                 // the main object needs to be first in the array [0] with attached objects following
 173                 float slot, physics;
 174                 if(head == e) // this is the main object, place it first
 175                 {
 176                         slot = 0;
 177                         physics = head.movetype; // applied physics are normal physics for parents
 178                 }
 179                 else if(head.owner == e) // child object, list them in order
 180                 {
 181                         i += 1; // children start from 1
 182                         slot = i;
 183                         physics = head.old_movetype; // persisted physics are normal physics for children
 184                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 185                 }
 186                 else
 187                         continue;
 188
 189                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 190                 if(slot)
 191                 {
 192                         // properties stored only for child objects
 193                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 194                 }
 195                 else
 196                 {
 197                         // properties stored only for parent objects
 198                         if(database)
 199                         {
 200                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 201                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 202                         }
 203                 }
 204                 // properties stored for all objects
 205                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 206                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 207                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 208                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 209                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 210                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 212                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 213                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 214                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 215                 if(database)
 216                 {
 217                         // properties stored only for the database
 218                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 219                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 220                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 221                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 222                 }
 223         }
 224
 225         // now apply the array to a simple string, with the ; symbol separating objects
 226         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 227         {
 228                 if(port_string[i])
 229                         s = strcat(s, port_string[i], "; ");
 230                 port_string[i] = string_null; // fully clear the string
 231         }
 232
 233         return s;
 234 }
 235
 236 entity sandbox_ObjectPort_Load(string s, float database)
 237 {
 238         // load object properties, and spawn a new object with them
 239         float n, i;
 240         entity e, parent;
 241
 242         // separate objects between the ; symbols
 243         n = tokenizebyseparator(s, "; ");
 244         for(i = 0; i < n; ++i)
 245                 port_string[i] = argv(i);
 246
 247         // now separate and apply the properties of each object
 248         for(i = 0; i < n; ++i)
 249         {
 250                 float argv_num;
 251                 string tagname;
 252                 argv_num = 0;
 253                 tokenize_console(port_string[i]);
 254                 e = sandbox_ObjectSpawn(database);
 255
 256                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 257                 if(i)
 258                 {
 259                         // properties stored only for child objects
 260                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 261                 }
 262                 else
 263                 {
 264                         // properties stored only for parent objects
 265                         if(database)
 266                         {
 267                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 268                                 e.angles = stov(argv(argv_num));        ++argv_num;
 269                         }
 270                         parent = e; // mark parent objects as such
 271                 }
 272                 // properties stored for all objects
 273                 setmodel(e, argv(argv_num));    ++argv_num;
 274                 e.skin = stof(argv(argv_num));  ++argv_num;
 275                 e.alpha = stof(argv(argv_num)); ++argv_num;
 276                 e.colormod = stov(argv(argv_num));      ++argv_num;
 277                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 278                 e.frame = stof(argv(argv_num)); ++argv_num;
 279                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 280                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 281                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 282                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 283                 if(database)
 284                 {
 285                         // properties stored only for the database
 286                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 287                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));
 288                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));
 289                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));
 290                 }
 291
 292                 // attach last
 293                 if(i)
 294                         sandbox_ObjectAttach_Set(e, parent, tagname);
 295         }
 296
 297         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 298                 port_string[i] = string_null; // fully clear the string
 299
 300         return e;
 301 }
 302
 303 void sandbox_Database_Save()
 304 {
 305         // saves all objects to the database file
 306         entity head;
 307         string file_name;
 308         float file_get;
 309
 310         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 311         file_get = fopen(file_name, FILE_WRITE);
 312         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 313         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 314
 315         for(head = world; (head = find(head, classname, "object")); )
 316         {
 317                 // attached objects are persisted separately, ignore them here
 318                 if(head.owner != world)
 319                         continue;
 320
 321                 // use a line of text for each object, listing all properties
 322                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 323         }
 324         fclose(file_get);
 325 }
 326
 327 void sandbox_Database_Load()
 328 {
 329         // loads all objects from the database file
 330         string file_read, file_name;
 331         float file_get, i;
 332
 333         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 334         file_get = fopen(file_name, FILE_READ);
 335         if(file_get < 0)
 336         {
 337                 if(autocvar_g_sandbox_info > 0)
 338                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 339         }
 340         else
 341         {
 342                 for(;;)
 343                 {
 344                         file_read = fgets(file_get);
 345                         if(!file_read)
 346                                 break;
 347                         if(substring(file_read, 0, 2) == "//")
 348                                 continue;
 349                         if(substring(file_read, 0, 1) == "#")
 350                                 continue;
 351
 352                         entity e;
 353                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 354
 355                         if(e.material)
 356                         {
 357                                 // since objects are being loaded for the first time, precache material sounds for each
 358                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 359                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 360                         }
 361                 }
 362                 if(autocvar_g_sandbox_info > 0)
 363                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 364         }
 365 }
 366
 367 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 368 {
 369         if(MUTATOR_RETURNVALUE) // command was already handled?
 370                 return FALSE;
 371         if(cmd_name == "g_sandbox")
 372         {
 373                 if(cmd_argc < 2)
 374                 {
 375                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 376                         return TRUE;
 377                 }
 378
 379                 switch(argv(1))
 380                 {
 381                         entity e;
 382                         float i;
 383                         string s;
 384
 385                         // ---------------- COMMAND: HELP ----------------
 386                         case "help":
 387                                 print_to(self, "You can use the following sandbox commands:");
 388                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 389                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 390                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 391                                 print_to(self, "^Properties for ^2object_duplicate^7:");
 392                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 393                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 394                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 395                                 print_to(self, "^7Properties for ^2object_attach^7:");
 396                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 397                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 398                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 399                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 400                                 print_to(self, "^7Properties for ^2object_edit^7:");
 401                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 402                                 print_to(self, "^3alpha value ^7- sets object transparency");
 403                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 404                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 405                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 406                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 407                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 408                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 409                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 410                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 411                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 412                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 413                                 return TRUE;
 414
 415                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 416                         case "object_spawn":
 417                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 418                                 {
 419                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 420                                         return TRUE;
 421                                 }
 422                                 if(cmd_argc < 3)
 423                                 {
 424                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 425                                         return TRUE;
 426                                 }
 427                                 else if not(fexists(argv(2)))
 428                                 {
 429                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 430                                         return TRUE;
 431                                 }
 432
 433                                 e = sandbox_ObjectSpawn(FALSE);
 434                                 setmodel(e, argv(2));
 435
 436                                 if(autocvar_g_sandbox_info > 0)
 437                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 438                                 return TRUE;
 439
 440                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 441                         case "object_remove":
 442                                 e = sandbox_ObjectEdit_Get(TRUE);
 443                                 if(e != world)
 444                                 {
 445                                         if(autocvar_g_sandbox_info > 0)
 446                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 447                                         sandbox_ObjectRemove(e);
 448                                         return TRUE;
 449                                 }
 450
 451                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 452                                 return TRUE;
 453
 454                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 455                         case "object_duplicate":
 456                                 switch(argv(2))
 457                                 {
 458                                         case "copy":
 459                                                 // copies customizable properties of the selected object to the clipboard cvar
 460                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 461                                                 if(e != world)
 462                                                 {
 463                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 464                                                         s = strreplace("\"", "\\\"", s);
 465                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 466
 467                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 468                                                         return TRUE;
 469                                                 }
 470                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 471                                                 return TRUE;
 472
 473                                         case "paste":
 474                                                 // spawns a new object using the properties in the player's clipboard cvar
 475                                                 if(!argv(3)) // no object in clipboard
 476                                                 {
 477                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 478                                                         return TRUE;
 479                                                 }
 480                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 481                                                 {
 482                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 483                                                         return TRUE;
 484                                                 }
 485                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 486
 487                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 488                                                 if(autocvar_g_sandbox_info > 0)
 489                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 490                                                 return TRUE;
 491                                 }
 492                                 return TRUE;
 493
 494                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 495                         case "object_attach":
 496                                 switch(argv(2))
 497                                 {
 498                                         case "get":
 499                                                 // select e as the object as meant to be attached
 500                                                 e = sandbox_ObjectEdit_Get(TRUE);
 501                                                 if(e != world)
 502                                                 {
 503                                                         self.object_attach = e;
 504                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 505                                                         return TRUE;
 506                                                 }
 507                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 508                                                 return TRUE;
 509                                         case "set":
 510                                                 if(self.object_attach == world)
 511                                                 {
 512                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 513                                                         return TRUE;
 514                                                 }
 515
 516                                                 // attaches the previously selected object to e
 517                                                 e = sandbox_ObjectEdit_Get(TRUE);
 518                                                 if(e != world)
 519                                                 {
 520                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 521                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 522                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 523                                                         if(autocvar_g_sandbox_info > 1)
 524                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 525                                                         return TRUE;
 526                                                 }
 527                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 528                                                 return TRUE;
 529                                         case "remove":
 530                                                 // removes e if it was attached
 531                                                 e = sandbox_ObjectEdit_Get(TRUE);
 532                                                 if(e != world)
 533                                                 {
 534                                                         sandbox_ObjectAttach_Remove(e);
 535                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 536                                                         if(autocvar_g_sandbox_info > 1)
 537                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 538                                                         return TRUE;
 539                                                 }
 540                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 541                                                 return TRUE;
 542                                 }
 543                                 return TRUE;
 544
 545                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 546                         case "object_edit":
 547                                 if(!argv(2))
 548                                 {
 549                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 550                                         return TRUE;
 551                                 }
 552
 553                                 e = sandbox_ObjectEdit_Get(TRUE);
 554                                 if(e != world)
 555                                 {
 556                                         switch(argv(2))
 557                                         {
 558                                                 case "skin":
 559                                                         e.skin = stof(argv(3));
 560                                                         break;
 561                                                 case "alpha":
 562                                                         e.alpha = stof(argv(3));
 563                                                         break;
 564                                                 case "color_main":
 565                                                         e.colormod = stov(argv(3));
 566                                                         break;
 567                                                 case "color_glow":
 568                                                         e.glowmod = stov(argv(3));
 569                                                         break;
 570                                                 case "frame":
 571                                                         e.frame = stof(argv(3));
 572                                                         break;
 573                                                 case "scale":
 574                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 575                                                         break;
 576                                                 case "physics":
 577                                                         switch(argv(3))
 578                                                         {
 579                                                                 case "0": // static
 580                                                                         e.movetype = MOVETYPE_NONE;
 581                                                                         break;
 582                                                                 case "1": // movable
 583                                                                         e.movetype = MOVETYPE_TOSS;
 584                                                                         break;
 585                                                                 case "2": // physical
 586                                                                         e.movetype = MOVETYPE_PHYSICS;
 587                                                                         break;
 588                                                                 default:
 589                                                                         break;
 590                                                         }
 591                                                         break;
 592                                                 case "force":
 593                                                         e.damageforcescale = stof(argv(3));
 594                                                         break;
 595                                                 case "material":
 596                                                         if(e.material)
 597                                                                 strunzone(e.material);
 598                                                         if(argv(3))
 599                                                         {
 600                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 601                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 602                                                                 e.material = strzone(argv(3));
 603                                                         }
 604                                                         else
 605                                                                 e.material = string_null; // no material
 606                                                         break;
 607                                                 default:
 608                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 609                                                         return TRUE;
 610                                         }
 611
 612                                         // update last edit time
 613                                         if(e.message2)
 614                                                 strunzone(e.message2);
 615                                         e.message2 = strftime(TRUE, "%d-%m-%Y %H:%M:%S");
 616
 617                                         if(autocvar_g_sandbox_info > 1)
 618                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 619                                         return TRUE;
 620                                 }
 621
 622                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 623                                 return TRUE;
 624
 625                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 626                         case "object_claim":
 627                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 628                                 if(self.crypto_idfp == "")
 629                                 {
 630                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 631                                         return TRUE;
 632                                 }
 633                                 e = sandbox_ObjectEdit_Get(TRUE);
 634                                 if(e != world)
 635                                 {
 636                                         if(e.crypto_idfp == self.crypto_idfp)
 637                                         {
 638                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 639                                                 return TRUE;
 640                                         }
 641
 642                                         if(e.crypto_idfp)
 643                                                 strunzone(e.crypto_idfp);
 644                                         e.crypto_idfp = self.crypto_idfp;
 645                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 646                                 }
 647                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 648                                 return TRUE;
 649
 650                         // ---------------- COMMAND: OBJECT, INFO ----------------
 651                         case "object_info":
 652                                 // prints public information about the object to the player
 653                                 e = sandbox_ObjectEdit_Get(FALSE);
 654                                 if(e != world)
 655                                 {
 656                                         switch(argv(2))
 657                                         {
 658                                                 case "mesh":
 659                                                         string tags;
 660                                                         for(i = 1; gettaginfo(e, i); i++)
 661                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 662                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 663                                                         return TRUE;
 664                                         }
 665                                 }
 666                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 667                                 return TRUE;
 668
 669                         // ---------------- COMMAND: DEFAULT ----------------
 670                         default:
 671                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 672                                 return TRUE;
 673                 }
 674         }
 675         return FALSE;
 676 }
 677
 678 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 679 {
 680         // if the player is close enough to their object, they can drag it
 681
 682         if(autocvar_sv_cheats)
 683                 return FALSE; // cheat dragging is used instead
 684
 685         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 686         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 687         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 688         // it goes out of range while slinging it around.
 689
 690         entity e;
 691         float grab;
 692
 693         e = sandbox_ObjectEdit_Get(TRUE);
 694         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 695                 grab = TRUE;
 696
 697         if(Drag(e, grab)) // execute dragging
 698                 return TRUE;
 699
 700         return FALSE;
 701 }
 702
 703 float autosave_time;
 704 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 705 {
 706         if(!autocvar_g_sandbox_storage_autosave)
 707                 return FALSE;
 708         if(time < autosave_time)
 709                 return FALSE;
 710         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 711
 712         sandbox_Database_Save();
 713
 714         return TRUE;
 715 }
 716
 717 MUTATOR_DEFINITION(sandbox)
 718 {
 719         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 720         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 721         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 722
 723         MUTATOR_ONADD
 724         {
 725                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 726                 if(autocvar_g_sandbox_storage_autoload)
 727                         sandbox_Database_Load();
 728         }
 729
 730         return FALSE;
 731 }
 732