qcsrc/server/playerstats.qc

   1 float playerstats_db;
   2 string playerstats_last;
   3 string events_last;
   4 .float playerstats_addedglobalinfo;
   5 float playerstats_requested;
   6 .string playerstats_id;
   7
   8 void PlayerStats_Init()
   9 {
  10         string uri;
  11         playerstats_db = -1;
  12         playerstats_waitforme = TRUE;
  13         uri = autocvar_g_playerstats_uri;
  14         if(uri == "")
  15                 return;
  16         playerstats_db = db_create();
  17         if(playerstats_db >= 0)
  18                 playerstats_waitforme = FALSE; // must wait for it at match end
  19
  20         PlayerStats_AddEvent(PLAYERSTATS_ALIVETIME);
  21         PlayerStats_AddEvent(PLAYERSTATS_WINS);
  22         PlayerStats_AddEvent(PLAYERSTATS_MATCHES);
  23         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
  24 }
  25
  26 void PlayerStats_AddPlayer(entity e)
  27 {
  28         if(playerstats_db < 0)
  29                 return;
  30
  31         if(e.crypto_idfp != "")
  32                 e.playerstats_id = strzone(e.crypto_idfp);
  33         else if(clienttype(e) == CLIENTTYPE_BOT)
  34                 e.playerstats_id = strzone(sprintf("bot#%d", e.playerid));
  35         else
  36                 e.playerstats_id = strzone(sprintf("player#%d", e.playerid));
  37
  38         string key;
  39         key = sprintf("%s:*", e.playerstats_id);
  40
  41         string p;
  42         p = db_get(playerstats_db, key);
  43         if(p == "")
  44         {
  45                 if(playerstats_last)
  46                 {
  47                         db_put(playerstats_db, key, playerstats_last);
  48                         strunzone(playerstats_last);
  49                 }
  50                 else
  51                         db_put(playerstats_db, key, "#");
  52                 playerstats_last = strzone(e.playerstats_id);
  53         }
  54 }
  55
  56 void PlayerStats_AddEvent(string event_id)
  57 {
  58         if(playerstats_db < 0)
  59                 return;
  60
  61         string key;
  62         key = sprintf("*:%s", event_id);
  63
  64         string p;
  65         p = db_get(playerstats_db, key);
  66         if(p == "")
  67         {
  68                 if(events_last)
  69                 {
  70                         db_put(playerstats_db, key, events_last);
  71                         strunzone(events_last);
  72                 }
  73                 else
  74                         db_put(playerstats_db, key, "#");
  75                 events_last = strzone(event_id);
  76         }
  77 }
  78
  79 void PlayerStats_Event(entity e, string event_id, float value)
  80 {
  81         if(!e.playerstats_id || playerstats_db < 0)
  82                 return;
  83
  84         string key;
  85         float val;
  86         key = sprintf("%s:%s", e.playerstats_id, event_id);
  87         val = stof(db_get(playerstats_db, key));
  88         val += value;
  89         db_put(playerstats_db, key, ftos(val));
  90 }
  91
  92 void PlayerStats_Sent_URI_Get_Callback(float id, float status, string data)
  93 {
  94         if(playerstats_requested)
  95                 playerstats_waitforme = TRUE;
  96 }
  97
  98 //#NO AUTOCVARS START
  99 void PlayerStats_Shutdown()
 100 {
 101         string p, pn;
 102         string e, en;
 103         string nn;
 104         float b;
 105         float i;
 106         string uri;
 107
 108         if(playerstats_db < 0)
 109                 return;
 110
 111         uri = autocvar_g_playerstats_uri;
 112         if(uri != "")
 113         {
 114                 b = buf_create();
 115                 i = 0;
 116
 117                 db_dump(playerstats_db, "foo.db");
 118
 119                 bufstr_set(b, i++, "V 1");
 120                 bufstr_set(b, i++, sprintf("T %s.%06d", strftime(FALSE, "%s"), floor(random() * 1000000)));
 121                 bufstr_set(b, i++, sprintf("G %s", GetGametype()));
 122                 bufstr_set(b, i++, sprintf("M %s", GetMapname()));
 123                 bufstr_set(b, i++, sprintf("S %s", cvar_string("hostname")));
 124                 bufstr_set(b, i++, sprintf("C %d", cvar_purechanges_count));
 125                 for(p = playerstats_last; (pn = db_get(playerstats_db, sprintf("%s:*", p))) != ""; p = pn)
 126                 {
 127                         bufstr_set(b, i++, sprintf("P %s", p));
 128                         nn = db_get(playerstats_db, sprintf("%s:_netname", p));
 129                         if(nn != "")
 130                                 bufstr_set(b, i++, sprintf("n %s", nn));
 131                         for(e = events_last; (en = db_get(playerstats_db, sprintf("*:%s", e))) != ""; e = en)
 132                         {
 133                                 float v;
 134                                 v = stof(db_get(playerstats_db, sprintf("%s:%s", p, e)));
 135                                 bufstr_set(b, i++, sprintf("e %s %g", e, v));
 136                         }
 137                 }
 138                 bufstr_set(b, i++, "");
 139
 140                 if(autocvar_g_playerstats_debug)
 141                 {
 142                         for(i = 0; i < buf_getsize(b); ++i)
 143                                 print(bufstr_get(b, i), "\n");
 144                 }
 145
 146                 if(crypto_uri_postbuf(uri, URI_GET_PLAYERSTATS_SENT, "text/plain", "\n", b, 0))
 147                         playerstats_requested = TRUE;
 148                 else
 149                         playerstats_waitforme = TRUE; // if posting fails, we must continue anyway
 150
 151                 buf_del(b);
 152         }
 153         else
 154                 playerstats_waitforme = TRUE;
 155
 156         db_close(playerstats_db);
 157         playerstats_db = -1;
 158 }
 159 //#NO AUTOCVARS END
 160
 161 void PlayerStats_AddGlobalInfo(entity p)
 162 {
 163         if(playerstats_db < 0)
 164                 return;
 165         if(!p.playerstats_id || playerstats_db < 0)
 166                 return;
 167         p.playerstats_addedglobalinfo = TRUE;
 168
 169         // add global info!
 170         if(p.alivetime)
 171                 PlayerStats_Event(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 172
 173         if(p.alivetime)
 174                 PlayerStats_Event(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 175
 176         if(p.cvar_cl_allow_uid2name == 1 || clienttype(p) == CLIENTTYPE_BOT)
 177                 db_put(playerstats_db, sprintf("%s:_netname", p.playerstats_id), p.netname);
 178
 179         strunzone(p.playerstats_id);
 180         p.playerstats_id = string_null;
 181 }
 182
 183 void PlayerStats_EndMatch(float finished)
 184 {
 185         entity p;
 186         FOR_EACH_PLAYER(p)
 187         {
 188                 PlayerScore_PlayerStats(p);
 189                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_VALID, 1);
 190                 if(finished)
 191                 {
 192                         PlayerStats_Event(p, PLAYERSTATS_WINS, p.winning);
 193                         PlayerStats_Event(p, PLAYERSTATS_MATCHES, 1);
 194                 }
 195         }
 196 }