qcsrc/server/sv_main.qc

   1
   2 #include "anticheat.qh"
   3 #include "g_hook.qh"
   4 #include "g_world.qh"
   5
   6 #include "bot/bot.qh"
   7 #include "bot/waypoints.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/all.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         {
  99                 // check for falling damage
 100                 float velocity_len = vlen(this.velocity);
 101                 if(!this.hook.state)
 102                 {
 103                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 104                         if (this.deadflag)
 105                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 106                         else
 107                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 108                         if (dm > 0)
 109                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 110                 }
 111
 112                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 113                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 114         }
 115 }
 116
 117 void CreatureFrame_All()
 118 {
 119         for(entity e = world; (e = findfloat(e, damagedbycontents, true)); )
 120         {
 121                 if (e.movetype == MOVETYPE_NOCLIP) { continue; }
 122
 123                 CreatureFrame_Liquids(e);
 124                 CreatureFrame_FallDamage(e);
 125
 126         e.oldvelocity = e.velocity;
 127         }
 128 }
 129
 130 void Pause_TryPause(bool ispaused)
 131 {
 132         int n = 0;
 133         entity it;
 134         FOR_EACH_REALPLAYER(it)
 135         {
 136                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 137                 ++n;
 138         }
 139         if (!n) return;
 140         setpause(ispaused);
 141 }
 142
 143 void SV_PausedTic(float elapsedtime)
 144 {
 145         if (!server_is_dedicated) Pause_TryPause(false);
 146 }
 147
 148 /*
 149 =============
 150 StartFrame
 151
 152 Called before each frame by the server
 153 =============
 154 */
 155
 156 float game_delay;
 157 float game_delay_last;
 158
 159 float RedirectionThink();
 160 void StartFrame()
 161 {
 162         SELFPARAM();
 163         execute_next_frame();
 164         if (!server_is_dedicated) Pause_TryPause(true);
 165
 166         remove = remove_unsafely; // not during spawning!
 167         serverprevtime = servertime;
 168         servertime = time;
 169         serverframetime = frametime;
 170
 171 #ifdef PROFILING
 172         if(time > client_cefc_accumulatortime + 1)
 173         {
 174                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 175                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 176                 int c_seeing = 0;
 177                 int c_seen = 0;
 178                 entity cl;
 179                 FOR_EACH_CLIENT(cl)
 180                 {
 181                         if(IS_REAL_CLIENT(cl))
 182                                 ++c_seeing;
 183                         if(IS_PLAYER(cl))
 184                                 ++c_seen;
 185                 }
 186                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 187                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 188
 189                 client_cefc_accumulatortime = time;
 190                 client_cefc_accumulator = 0;
 191         }
 192 #endif
 193
 194         for(entity e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 195                 CSQCProjectile_Check(e);
 196
 197         if(RedirectionThink())
 198                 return;
 199
 200         UncustomizeEntitiesRun();
 201         InitializeEntitiesRun();
 202
 203         WarpZone_StartFrame();
 204
 205         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 206         if(sys_frametime <= 0)
 207                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 208
 209         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 210                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 211
 212         skill = autocvar_skill;
 213
 214         // detect when the pre-game countdown (if any) has ended and the game has started
 215         game_delay = (time < game_starttime);
 216
 217         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 218                 GameLogEcho(":startdelay_ended");
 219
 220         game_delay_last = game_delay;
 221
 222         CreatureFrame_All();
 223         CheckRules_World();
 224
 225         // if in warmup stage and limit for warmup is hit start match
 226         if(warmup_stage)
 227         if(!gameover)
 228         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 229          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 230         {
 231                 ReadyRestart();
 232                 return;
 233         }
 234
 235         bot_serverframe();
 236         anticheat_startframe();
 237         MUTATOR_CALLHOOK(SV_StartFrame);
 238         {
 239         entity e;
 240         FOR_EACH_CLIENT(e)
 241         {
 242             GlobalStats_update(e);
 243         }
 244     }
 245 }
 246
 247 .vector originjitter;
 248 .vector anglesjitter;
 249 .float anglejitter;
 250 .string gametypefilter;
 251 .string cvarfilter;
 252 float DoesQ3ARemoveThisEntity();
 253 void SV_OnEntityPreSpawnFunction()
 254 {SELFPARAM();
 255         __spawnfunc_expect = this;
 256         if (self)
 257         if (self.gametypefilter != "")
 258         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 259         {
 260                 remove(self);
 261                 return;
 262         }
 263         if(self.cvarfilter != "")
 264         {
 265                 float n, i, o, inv;
 266                 string s, k, v;
 267                 inv = 0;
 268
 269                 s = self.cvarfilter;
 270                 if(substring(s, 0, 1) == "+")
 271                 {
 272                         s = substring(s, 1, -1);
 273                 }
 274                 else if(substring(s, 0, 1) == "-")
 275                 {
 276                         inv = 1;
 277                         s = substring(s, 1, -1);
 278                 }
 279
 280                 n = tokenize_console(s);
 281                 for(i = 0; i < n; ++i)
 282                 {
 283                         s = argv(i);
 284                         // syntax:
 285                         // var>x
 286                         // var<x
 287                         // var>=x
 288                         // var<=x
 289                         // var==x
 290                         // var!=x
 291                         // var===x
 292                         // var!==x
 293                         if((o = strstrofs(s, ">=", 0)) >= 0)
 294                         {
 295                                 k = substring(s, 0, o);
 296                                 v = substring(s, o+2, -1);
 297                                 if(cvar(k) < stof(v))
 298                                         goto cvar_fail;
 299                         }
 300                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 301                         {
 302                                 k = substring(s, 0, o);
 303                                 v = substring(s, o+2, -1);
 304                                 if(cvar(k) > stof(v))
 305                                         goto cvar_fail;
 306                         }
 307                         else if((o = strstrofs(s, ">", 0)) >= 0)
 308                         {
 309                                 k = substring(s, 0, o);
 310                                 v = substring(s, o+1, -1);
 311                                 if(cvar(k) <= stof(v))
 312                                         goto cvar_fail;
 313                         }
 314                         else if((o = strstrofs(s, "<", 0)) >= 0)
 315                         {
 316                                 k = substring(s, 0, o);
 317                                 v = substring(s, o+1, -1);
 318                                 if(cvar(k) >= stof(v))
 319                                         goto cvar_fail;
 320                         }
 321                         else if((o = strstrofs(s, "==", 0)) >= 0)
 322                         {
 323                                 k = substring(s, 0, o);
 324                                 v = substring(s, o+2, -1);
 325                                 if(cvar(k) != stof(v))
 326                                         goto cvar_fail;
 327                         }
 328                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 329                         {
 330                                 k = substring(s, 0, o);
 331                                 v = substring(s, o+2, -1);
 332                                 if(cvar(k) == stof(v))
 333                                         goto cvar_fail;
 334                         }
 335                         else if((o = strstrofs(s, "===", 0)) >= 0)
 336                         {
 337                                 k = substring(s, 0, o);
 338                                 v = substring(s, o+2, -1);
 339                                 if(cvar_string(k) != v)
 340                                         goto cvar_fail;
 341                         }
 342                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 343                         {
 344                                 k = substring(s, 0, o);
 345                                 v = substring(s, o+2, -1);
 346                                 if(cvar_string(k) == v)
 347                                         goto cvar_fail;
 348                         }
 349                         else if(substring(s, 0, 1) == "!")
 350                         {
 351                                 k = substring(s, 1, -1);
 352                                 if(cvar(k))
 353                                         goto cvar_fail;
 354                         }
 355                         else
 356                         {
 357                                 k = s;
 358                                 if (!cvar(k))
 359                                         goto cvar_fail;
 360                         }
 361                 }
 362                 inv = !inv;
 363 :cvar_fail
 364                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 365                 if (!inv)
 366                 {
 367                         //print("cvarfilter fail\n");
 368                         remove(self);
 369                         return;
 370                 }
 371         }
 372
 373         if(DoesQ3ARemoveThisEntity())
 374         {
 375                 remove(self);
 376                 return;
 377         }
 378
 379         // support special -1 and -2 angle from radiant
 380         if (self.angles == '0 -1 0')
 381                 self.angles = '-90 0 0';
 382         else if (self.angles == '0 -2 0')
 383                 self.angles = '+90 0 0';
 384
 385         if(self.originjitter.x != 0)
 386                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 387         if(self.originjitter.y != 0)
 388                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 389         if(self.originjitter.z != 0)
 390                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 391         if(self.anglesjitter.x != 0)
 392                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 393         if(self.anglesjitter.y != 0)
 394                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 395         if(self.anglesjitter.z != 0)
 396                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 397         if(self.anglejitter != 0)
 398                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 399
 400         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 401         {
 402                 remove(self);
 403                 return;
 404         }
 405 }
 406
 407 void WarpZone_PostInitialize_Callback()
 408 {
 409         // create waypoint links for warpzones
 410         entity e;
 411         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 412         {
 413                 vector src, dst;
 414                 src = (e.absmin + e.absmax) * 0.5;
 415                 makevectors(e.warpzone_angles);
 416                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 417                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 418                 makevectors(e.enemy.warpzone_angles);
 419                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 420                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 421         }
 422 }