qcsrc/server/sv_main.qc

   1
   2 #include "anticheat.qh"
   3 #include "g_hook.qh"
   4 #include "g_world.qh"
   5
   6 #include "bot/bot.qh"
   7 #include "bot/waypoints.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/all.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         {
  99                 // check for falling damage
 100                 float velocity_len = vlen(this.velocity);
 101                 if(!this.hook.state)
 102                 {
 103                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 104                         if (this.deadflag)
 105                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 106                         else
 107                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 108                         if (dm > 0)
 109                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 110                 }
 111
 112                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 113                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 114         }
 115 }
 116
 117 void CreatureFrame_All()
 118 {
 119         FOREACH_ENTITY_FLOAT(damagedbycontents, true, LAMBDA(
 120                 if(it.movetype == MOVETYPE_NOCLIP) continue;
 121                 CreatureFrame_Liquids(it);
 122                 CreatureFrame_FallDamage(it);
 123                 it.oldvelocity = it.velocity;
 124         ));
 125 }
 126
 127 void Pause_TryPause(bool ispaused)
 128 {
 129         int n = 0;
 130         entity it;
 131         FOR_EACH_REALPLAYER(it)
 132         {
 133                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 134                 ++n;
 135         }
 136         if (!n) return;
 137         setpause(ispaused);
 138 }
 139
 140 void SV_PausedTic(float elapsedtime)
 141 {
 142         if (!server_is_dedicated) Pause_TryPause(false);
 143 }
 144
 145 /*
 146 =============
 147 StartFrame
 148
 149 Called before each frame by the server
 150 =============
 151 */
 152
 153 float game_delay;
 154 float game_delay_last;
 155
 156 float RedirectionThink();
 157 void StartFrame()
 158 {
 159         SELFPARAM();
 160         execute_next_frame();
 161         if (!server_is_dedicated) Pause_TryPause(true);
 162
 163         remove = remove_unsafely; // not during spawning!
 164         serverprevtime = servertime;
 165         servertime = time;
 166         serverframetime = frametime;
 167
 168 #ifdef PROFILING
 169         if(time > client_cefc_accumulatortime + 1)
 170         {
 171                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 172                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 173                 int c_seeing = 0;
 174                 int c_seen = 0;
 175                 entity cl;
 176                 FOR_EACH_CLIENT(cl)
 177                 {
 178                         if(IS_REAL_CLIENT(cl))
 179                                 ++c_seeing;
 180                         if(IS_PLAYER(cl))
 181                                 ++c_seen;
 182                 }
 183                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 184                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 185
 186                 client_cefc_accumulatortime = time;
 187                 client_cefc_accumulator = 0;
 188         }
 189 #endif
 190
 191         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, LAMBDA(CSQCProjectile_Check(it)));
 192
 193         if(RedirectionThink())
 194                 return;
 195
 196         UncustomizeEntitiesRun();
 197         InitializeEntitiesRun();
 198
 199         WarpZone_StartFrame();
 200
 201         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 202         if(sys_frametime <= 0)
 203                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 204
 205         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 206                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 207
 208         skill = autocvar_skill;
 209
 210         // detect when the pre-game countdown (if any) has ended and the game has started
 211         game_delay = (time < game_starttime);
 212
 213         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 214                 GameLogEcho(":startdelay_ended");
 215
 216         game_delay_last = game_delay;
 217
 218         CreatureFrame_All();
 219         CheckRules_World();
 220
 221         // if in warmup stage and limit for warmup is hit start match
 222         if(warmup_stage)
 223         if(!gameover)
 224         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 225          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 226         {
 227                 ReadyRestart();
 228                 return;
 229         }
 230
 231         bot_serverframe();
 232         anticheat_startframe();
 233         MUTATOR_CALLHOOK(SV_StartFrame);
 234
 235     FOREACH_CLIENT(true, LAMBDA(GlobalStats_update(it)));
 236 }
 237
 238 .vector originjitter;
 239 .vector anglesjitter;
 240 .float anglejitter;
 241 .string gametypefilter;
 242 .string cvarfilter;
 243 float DoesQ3ARemoveThisEntity();
 244 void SV_OnEntityPreSpawnFunction()
 245 {SELFPARAM();
 246         __spawnfunc_expect = this;
 247         if (self)
 248         if (self.gametypefilter != "")
 249         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 250         {
 251                 remove(self);
 252                 return;
 253         }
 254         if(self.cvarfilter != "")
 255         {
 256                 float n, i, o, inv;
 257                 string s, k, v;
 258                 inv = 0;
 259
 260                 s = self.cvarfilter;
 261                 if(substring(s, 0, 1) == "+")
 262                 {
 263                         s = substring(s, 1, -1);
 264                 }
 265                 else if(substring(s, 0, 1) == "-")
 266                 {
 267                         inv = 1;
 268                         s = substring(s, 1, -1);
 269                 }
 270
 271                 n = tokenize_console(s);
 272                 for(i = 0; i < n; ++i)
 273                 {
 274                         s = argv(i);
 275                         // syntax:
 276                         // var>x
 277                         // var<x
 278                         // var>=x
 279                         // var<=x
 280                         // var==x
 281                         // var!=x
 282                         // var===x
 283                         // var!==x
 284                         if((o = strstrofs(s, ">=", 0)) >= 0)
 285                         {
 286                                 k = substring(s, 0, o);
 287                                 v = substring(s, o+2, -1);
 288                                 if(cvar(k) < stof(v))
 289                                         goto cvar_fail;
 290                         }
 291                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 292                         {
 293                                 k = substring(s, 0, o);
 294                                 v = substring(s, o+2, -1);
 295                                 if(cvar(k) > stof(v))
 296                                         goto cvar_fail;
 297                         }
 298                         else if((o = strstrofs(s, ">", 0)) >= 0)
 299                         {
 300                                 k = substring(s, 0, o);
 301                                 v = substring(s, o+1, -1);
 302                                 if(cvar(k) <= stof(v))
 303                                         goto cvar_fail;
 304                         }
 305                         else if((o = strstrofs(s, "<", 0)) >= 0)
 306                         {
 307                                 k = substring(s, 0, o);
 308                                 v = substring(s, o+1, -1);
 309                                 if(cvar(k) >= stof(v))
 310                                         goto cvar_fail;
 311                         }
 312                         else if((o = strstrofs(s, "==", 0)) >= 0)
 313                         {
 314                                 k = substring(s, 0, o);
 315                                 v = substring(s, o+2, -1);
 316                                 if(cvar(k) != stof(v))
 317                                         goto cvar_fail;
 318                         }
 319                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 320                         {
 321                                 k = substring(s, 0, o);
 322                                 v = substring(s, o+2, -1);
 323                                 if(cvar(k) == stof(v))
 324                                         goto cvar_fail;
 325                         }
 326                         else if((o = strstrofs(s, "===", 0)) >= 0)
 327                         {
 328                                 k = substring(s, 0, o);
 329                                 v = substring(s, o+2, -1);
 330                                 if(cvar_string(k) != v)
 331                                         goto cvar_fail;
 332                         }
 333                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 334                         {
 335                                 k = substring(s, 0, o);
 336                                 v = substring(s, o+2, -1);
 337                                 if(cvar_string(k) == v)
 338                                         goto cvar_fail;
 339                         }
 340                         else if(substring(s, 0, 1) == "!")
 341                         {
 342                                 k = substring(s, 1, -1);
 343                                 if(cvar(k))
 344                                         goto cvar_fail;
 345                         }
 346                         else
 347                         {
 348                                 k = s;
 349                                 if (!cvar(k))
 350                                         goto cvar_fail;
 351                         }
 352                 }
 353                 inv = !inv;
 354 :cvar_fail
 355                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 356                 if (!inv)
 357                 {
 358                         //print("cvarfilter fail\n");
 359                         remove(self);
 360                         return;
 361                 }
 362         }
 363
 364         if(DoesQ3ARemoveThisEntity())
 365         {
 366                 remove(self);
 367                 return;
 368         }
 369
 370         // support special -1 and -2 angle from radiant
 371         if (self.angles == '0 -1 0')
 372                 self.angles = '-90 0 0';
 373         else if (self.angles == '0 -2 0')
 374                 self.angles = '+90 0 0';
 375
 376         if(self.originjitter.x != 0)
 377                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 378         if(self.originjitter.y != 0)
 379                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 380         if(self.originjitter.z != 0)
 381                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 382         if(self.anglesjitter.x != 0)
 383                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 384         if(self.anglesjitter.y != 0)
 385                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 386         if(self.anglesjitter.z != 0)
 387                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 388         if(self.anglejitter != 0)
 389                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 390
 391         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 392         {
 393                 remove(self);
 394                 return;
 395         }
 396 }
 397
 398 void WarpZone_PostInitialize_Callback()
 399 {
 400         // create waypoint links for warpzones
 401         entity e;
 402         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 403         {
 404                 vector src, dst;
 405                 src = (e.absmin + e.absmax) * 0.5;
 406                 makevectors(e.warpzone_angles);
 407                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 408                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 409                 makevectors(e.enemy.warpzone_angles);
 410                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 411                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 412         }
 413 }