qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "bot/bot.qh"
   8     #include "bot/waypoints.qh"
   9
  10     #include "mutators/all.qh"
  11
  12     #include "weapons/common.qh"
  13     #include "weapons/selection.qh"
  14     #include "weapons/weaponsystem.qh"
  15
  16     #include "../common/constants.qh"
  17     #include "../common/deathtypes/all.qh"
  18     #include "../common/notifications.qh"
  19         #include "../common/triggers/subs.qh"
  20     #include "../common/util.qh"
  21
  22     #include "../common/monsters/all.qh"
  23
  24     #include "../common/weapons/all.qh"
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #endif
  28
  29 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  30
  31 #ifdef CSQC
  32 void ItemDraw(entity self)
  33 {
  34     if(self.gravity)
  35     {
  36         Movetype_Physics_MatchServer(self, autocvar_cl_projectiles_sloppy);
  37         if(self.move_flags & FL_ONGROUND)
  38         { // For some reason move_avelocity gets set to '0 0 0' here ...
  39             self.oldorigin = self.origin;
  40             self.gravity = 0;
  41
  42             if(autocvar_cl_animate_items)
  43             { // ... so reset it if animations are requested.
  44                 if(self.ItemStatus & ITS_ANIMATE1)
  45                     self.move_avelocity = '0 180 0';
  46
  47                 if(self.ItemStatus & ITS_ANIMATE2)
  48                     self.move_avelocity = '0 -90 0';
  49             }
  50         }
  51     }
  52     else if (autocvar_cl_animate_items)
  53     {
  54         if(self.ItemStatus & ITS_ANIMATE1)
  55         {
  56             self.angles += self.move_avelocity * frametime;
  57             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  58         }
  59
  60         if(self.ItemStatus & ITS_ANIMATE2)
  61         {
  62             self.angles += self.move_avelocity * frametime;
  63             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  64         }
  65     }
  66 }
  67
  68 void ItemDrawSimple(entity this)
  69 {
  70     if(self.gravity)
  71     {
  72         Movetype_Physics_MatchServer(self, autocvar_cl_projectiles_sloppy);
  73
  74         if(self.move_flags & FL_ONGROUND)
  75             self.gravity = 0;
  76     }
  77 }
  78
  79 void Item_PreDraw()
  80 {SELFPARAM();
  81         vector org;
  82         float alph;
  83         org = getpropertyvec(VF_ORIGIN);
  84         if(!checkpvs(org, self)) // this makes sense as long as we don't support recursive warpzones
  85                 alph = 0;
  86         else if(self.fade_start)
  87                 alph = bound(0, (self.fade_end - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.fade_end - self.fade_start), 1);
  88         else
  89                 alph = 1;
  90         //printf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs));
  91         if(self.ItemStatus & ITS_AVAILABLE)
  92                 self.alpha = alph;
  93         if(alph <= 0)
  94                 self.drawmask = 0;
  95         else
  96                 self.drawmask = MASK_NORMAL;
  97 }
  98
  99 void ItemRemove()
 100 {SELFPARAM();
 101         if (self.mdl)
 102                 strunzone(self.mdl);
 103 }
 104
 105 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 106 {
 107     int sf = ReadByte();
 108
 109     if(sf & ISF_LOCATION)
 110     {
 111         self.origin_x = ReadCoord();
 112         self.origin_y = ReadCoord();
 113         self.origin_z = ReadCoord();
 114         setorigin(self, self.origin);
 115         self.oldorigin = self.origin;
 116     }
 117
 118     if(sf & ISF_ANGLES)
 119     {
 120         self.angles_x = ReadAngle();
 121         self.angles_y = ReadAngle();
 122         self.angles_z = ReadAngle();
 123         self.move_angles = self.angles;
 124     }
 125
 126     if(sf & ISF_SIZE)
 127     {
 128         float use_bigsize = ReadByte();
 129         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 130     }
 131
 132     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 133     {
 134         self.ItemStatus = ReadByte();
 135
 136         if(self.ItemStatus & ITS_AVAILABLE)
 137         {
 138             self.alpha = 1;
 139             self.colormod = self.glowmod = '1 1 1';
 140         }
 141         else
 142         {
 143             if (autocvar_cl_ghost_items_color)
 144             {
 145                 self.alpha = autocvar_cl_ghost_items;
 146                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 147             }
 148             else
 149                 self.alpha = -1;
 150         }
 151
 152         if(autocvar_cl_fullbright_items)
 153             if(self.ItemStatus & ITS_ALLOWFB)
 154                 self.effects |= EF_FULLBRIGHT;
 155
 156         if(self.ItemStatus & ITS_STAYWEP)
 157         {
 158             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 159             self.alpha = autocvar_cl_weapon_stay_alpha;
 160
 161         }
 162
 163         if(self.ItemStatus & ITS_POWERUP)
 164         {
 165             if(self.ItemStatus & ITS_AVAILABLE)
 166                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 167             else
 168                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 169         }
 170     }
 171
 172     if(sf & ISF_MODEL)
 173     {
 174         self.drawmask  = MASK_NORMAL;
 175                 self.move_movetype = self.movetype = MOVETYPE_TOSS;
 176         self.draw       = ItemDraw;
 177
 178         self.fade_end = ReadShort();
 179         self.fade_start = ReadShort();
 180         if(self.fade_start && !autocvar_cl_items_nofade)
 181                 self.predraw = Item_PreDraw;
 182
 183         if(self.mdl)
 184             strunzone(self.mdl);
 185
 186         self.mdl = "";
 187         string _fn = ReadString();
 188
 189         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 190         {
 191             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 192             self.draw = ItemDrawSimple;
 193
 194             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 195                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 196             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 197                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 198             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 199                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 200             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 201                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 202             else
 203             {
 204                 self.draw = ItemDraw;
 205                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 206             }
 207         }
 208
 209         if(self.draw != ItemDrawSimple)
 210             self.mdl = strzone(_fn);
 211
 212
 213         if(self.mdl == "")
 214             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 215
 216         precache_model(self.mdl);
 217         _setmodel(self, self.mdl);
 218     }
 219
 220     if(sf & ISF_COLORMAP)
 221         self.colormap = ReadShort();
 222
 223     if(sf & ISF_DROP)
 224     {
 225         self.gravity = 1;
 226         //self.move_angles = '0 0 0';
 227         self.move_movetype = MOVETYPE_TOSS;
 228         self.move_velocity_x = ReadCoord();
 229         self.move_velocity_y = ReadCoord();
 230         self.move_velocity_z = ReadCoord();
 231         self.velocity = self.move_velocity;
 232         self.move_origin = self.oldorigin;
 233
 234         if(!self.move_time)
 235         {
 236             self.move_time = time;
 237             self.spawntime = time;
 238         }
 239         else
 240             self.move_time = max(self.move_time, time);
 241     }
 242
 243     if(autocvar_cl_animate_items)
 244     {
 245         if(self.ItemStatus & ITS_ANIMATE1)
 246             self.move_avelocity = '0 180 0';
 247
 248         if(self.ItemStatus & ITS_ANIMATE2)
 249             self.move_avelocity = '0 -90 0';
 250     }
 251
 252     self.entremove = ItemRemove;
 253
 254     return true;
 255 }
 256
 257 #endif
 258
 259 #ifdef SVQC
 260 bool ItemSend(entity this, entity to, int sf)
 261 {
 262         if(self.gravity)
 263                 sf |= ISF_DROP;
 264         else
 265                 sf &= ~ISF_DROP;
 266
 267         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 268         WriteByte(MSG_ENTITY, sf);
 269
 270         //WriteByte(MSG_ENTITY, self.cnt);
 271         if(sf & ISF_LOCATION)
 272         {
 273                 WriteCoord(MSG_ENTITY, self.origin.x);
 274                 WriteCoord(MSG_ENTITY, self.origin.y);
 275                 WriteCoord(MSG_ENTITY, self.origin.z);
 276         }
 277
 278         if(sf & ISF_ANGLES)
 279         {
 280                 WriteAngle(MSG_ENTITY, self.angles_x);
 281                 WriteAngle(MSG_ENTITY, self.angles_y);
 282                 WriteAngle(MSG_ENTITY, self.angles_z);
 283         }
 284
 285         if(sf & ISF_SIZE)
 286         {
 287                 Pickup p = this.itemdef;
 288                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 289         }
 290
 291         if(sf & ISF_STATUS)
 292                 WriteByte(MSG_ENTITY, self.ItemStatus);
 293
 294         if(sf & ISF_MODEL)
 295         {
 296                 WriteShort(MSG_ENTITY, self.fade_end);
 297                 WriteShort(MSG_ENTITY, self.fade_start);
 298
 299                 if(self.mdl == "")
 300                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 301
 302                 WriteString(MSG_ENTITY, self.mdl);
 303         }
 304
 305
 306         if(sf & ISF_COLORMAP)
 307                 WriteShort(MSG_ENTITY, self.colormap);
 308
 309         if(sf & ISF_DROP)
 310         {
 311                 WriteCoord(MSG_ENTITY, self.velocity.x);
 312                 WriteCoord(MSG_ENTITY, self.velocity.y);
 313                 WriteCoord(MSG_ENTITY, self.velocity.z);
 314         }
 315
 316         return true;
 317 }
 318
 319 void ItemUpdate(entity item)
 320 {
 321         item.SendFlags |= ISF_LOCATION;
 322 }
 323
 324 bool have_pickup_item(entity this)
 325 {
 326         if(this.itemdef.instanceOfPowerup)
 327         {
 328                 if(autocvar_g_powerups > 0)
 329                         return true;
 330                 if(autocvar_g_powerups == 0)
 331                         return false;
 332         }
 333         else
 334         {
 335                 if(autocvar_g_pickup_items > 0)
 336                         return true;
 337                 if(autocvar_g_pickup_items == 0)
 338                         return false;
 339                 if(g_weaponarena)
 340                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 341                                 return false;
 342         }
 343         return true;
 344 }
 345
 346 /*
 347 float Item_Customize()
 348 {
 349         if(self.spawnshieldtime)
 350                 return true;
 351         if(self.weapons & ~other.weapons)
 352         {
 353                 self.colormod = '0 0 0';
 354                 self.glowmod = self.colormod;
 355                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 356                 return true;
 357         }
 358         else
 359         {
 360                 if(g_ghost_items)
 361                 {
 362                         self.colormod = stov(autocvar_g_ghost_items_color);
 363                         self.glowmod = self.colormod;
 364                         self.alpha = g_ghost_items;
 365                         return true;
 366                 }
 367                 else
 368                         return false;
 369         }
 370 }
 371 */
 372
 373 void Item_Show (entity e, float mode)
 374 {
 375         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 376         e.ItemStatus &= ~ITS_STAYWEP;
 377         if (mode > 0)
 378         {
 379                 // make the item look normal, and be touchable
 380                 e.model = e.mdl;
 381                 e.solid = SOLID_TRIGGER;
 382                 e.spawnshieldtime = 1;
 383                 e.ItemStatus |= ITS_AVAILABLE;
 384         }
 385         else if (mode < 0)
 386         {
 387                 // hide the item completely
 388                 e.model = string_null;
 389                 e.solid = SOLID_NOT;
 390                 e.spawnshieldtime = 1;
 391                 e.ItemStatus &= ~ITS_AVAILABLE;
 392         }
 393         else {
 394         entity def = e.itemdef;
 395         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 396                 || e.team // weapon stay isn't supported for teamed weapons
 397                 ;
 398         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 399         {
 400                 // make the item translucent and not touchable
 401                 e.model = e.mdl;
 402                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 403                 e.effects |= EF_STARDUST;
 404                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 405                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 406         }
 407         else
 408         {
 409                 //setmodel(e, "null");
 410                 e.solid = SOLID_NOT;
 411                 e.colormod = '0 0 0';
 412                 e.glowmod = e.colormod;
 413                 e.spawnshieldtime = 1;
 414                 e.ItemStatus &= ~ITS_AVAILABLE;
 415         }}
 416
 417         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 418                 e.ItemStatus |= ITS_POWERUP;
 419
 420         if (autocvar_g_nodepthtestitems)
 421                 e.effects |= EF_NODEPTHTEST;
 422
 423
 424         if (autocvar_g_fullbrightitems)
 425                 e.ItemStatus |= ITS_ALLOWFB;
 426
 427         if (autocvar_sv_simple_items)
 428                 e.ItemStatus |= ITS_ALLOWSI;
 429
 430         // relink entity (because solid may have changed)
 431         setorigin(e, e.origin);
 432         e.SendFlags |= ISF_STATUS;
 433 }
 434
 435 void Item_Think()
 436 {SELFPARAM();
 437         self.nextthink = time;
 438         if(self.origin != self.oldorigin)
 439         {
 440                 self.oldorigin = self.origin;
 441                 ItemUpdate(self);
 442         }
 443 }
 444
 445 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 446 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 447 float Item_ItemsTime_UpdateTime(entity e, float t);
 448 void Item_ItemsTime_SetTime(entity e, float t);
 449 void Item_ItemsTime_SetTimesForAllPlayers();
 450
 451 void Item_Respawn ()
 452 {SELFPARAM();
 453         Item_Show(self, 1);
 454         // this is ugly...
 455         if(self.items == ITEM_Strength.m_itemid)
 456                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 457         else if(self.items == ITEM_Shield.m_itemid)
 458                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 459         else
 460                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 461         setorigin (self, self.origin);
 462
 463     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 464         {
 465                 float t = Item_ItemsTime_UpdateTime(self, 0);
 466                 Item_ItemsTime_SetTime(self, t);
 467                 Item_ItemsTime_SetTimesForAllPlayers();
 468         }
 469
 470         self.think = Item_Think;
 471         self.nextthink = time;
 472
 473         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 474         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 475 }
 476
 477 void Item_RespawnCountdown ()
 478 {SELFPARAM();
 479         if(self.count >= ITEM_RESPAWN_TICKS)
 480         {
 481                 if(self.waypointsprite_attached)
 482                         WaypointSprite_Kill(self.waypointsprite_attached);
 483                 Item_Respawn();
 484         }
 485         else
 486         {
 487                 self.nextthink = time + 1;
 488                 self.count += 1;
 489                 if(self.count == 1)
 490                 {
 491                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 492                         do {
 493                                 {
 494                                         entity wi = Weapons_from(self.weapon);
 495                                         if (wi.m_id) {
 496                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
 497                                                 wp.wp_extra = wi.m_id;
 498                                                 break;
 499                                         }
 500                                 }
 501                                 {
 502                                         entity ii = self.itemdef;
 503                                         if (ii.m_id) {
 504                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
 505                                                 wp.wp_extra = ii.m_id;
 506                                                 break;
 507                                         }
 508                                 }
 509                         } while (0);
 510             if(self.waypointsprite_attached)
 511             {
 512                 GameItem def = self.itemdef;
 513                 if (Item_ItemsTime_SpectatorOnly(def))
 514                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 515                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 516             }
 517                 }
 518
 519                 if(self.waypointsprite_attached)
 520                 {
 521                         setself(self.waypointsprite_attached);
 522                         entity e;
 523                         FOR_EACH_REALCLIENT(e)
 524                                 if(self.waypointsprite_visible_for_player(e))
 525                                 {
 526                                         msg_entity = e;
 527                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 528                                 }
 529                         setself(this);
 530
 531                         WaypointSprite_Ping(self.waypointsprite_attached);
 532                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 533                 }
 534         }
 535 }
 536
 537 void Item_RespawnThink()
 538 {SELFPARAM();
 539         self.nextthink = time;
 540         if(self.origin != self.oldorigin)
 541         {
 542                 self.oldorigin = self.origin;
 543                 ItemUpdate(self);
 544         }
 545
 546         if(time >= self.wait)
 547                 Item_Respawn();
 548 }
 549
 550 void Item_ScheduleRespawnIn(entity e, float t)
 551 {
 552         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 553         {
 554                 e.think = Item_RespawnCountdown;
 555                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 556                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 557                 e.count = 0;
 558                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 559                 Item_ItemsTime_SetTime(e, t);
 560                 Item_ItemsTime_SetTimesForAllPlayers();
 561         }
 562         else
 563         {
 564                 e.think = Item_RespawnThink;
 565                 e.nextthink = time;
 566                 e.scheduledrespawntime = time + t;
 567                 e.wait = time + t;
 568         }
 569 }
 570
 571 void Item_ScheduleRespawn(entity e)
 572 {
 573         if(e.respawntime > 0)
 574         {
 575                 Item_Show(e, 0);
 576                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 577         }
 578         else // if respawntime is -1, this item does not respawn
 579                 Item_Show(e, -1);
 580 }
 581
 582 void Item_ScheduleInitialRespawn(entity e)
 583 {
 584         Item_Show(e, 0);
 585         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 586 }
 587
 588 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 589 {
 590         if (!item.(ammotype))
 591                 return false;
 592
 593         if (item.spawnshieldtime)
 594         {
 595                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 596                 {
 597                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 598                         goto YEAH;
 599                 }
 600         }
 601         else if(g_weapon_stay == 2)
 602         {
 603                 float mi = min(item.(ammotype), ammomax);
 604                 if (player.(ammotype) < mi)
 605                 {
 606                         player.(ammotype) = mi;
 607                         goto YEAH;
 608                 }
 609         }
 610
 611         return false;
 612
 613 :YEAH
 614         switch(mode)
 615         {
 616                 case ITEM_MODE_FUEL:
 617                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 618                         break;
 619                 case ITEM_MODE_HEALTH:
 620                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 621                         break;
 622                 case ITEM_MODE_ARMOR:
 623                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 624                         break;
 625                 default:
 626                         break;
 627         }
 628         return true;
 629 }
 630
 631 float Item_GiveTo(entity item, entity player)
 632 {
 633         float _switchweapon;
 634         float pickedup;
 635         float it;
 636         float i;
 637
 638         // if nothing happens to player, just return without taking the item
 639         pickedup = false;
 640         _switchweapon = false;
 641         // in case the player has autoswitch enabled do the following:
 642         // if the player is using their best weapon before items are given, they
 643         // probably want to switch to an even better weapon after items are given
 644         if (player.autoswitch)
 645         if (PS(player).m_switchweapon == w_getbestweapon(player))
 646                 _switchweapon = true;
 647
 648         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
 649                 _switchweapon = true;
 650
 651         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 652         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 653         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 654         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 655         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 656         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 657         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 658         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 659
 660         if (item.itemdef.instanceOfWeaponPickup)
 661         {
 662                 WepSet it;
 663                 it = item.weapons;
 664                 it &= ~player.weapons;
 665
 666                 if (it || (item.spawnshieldtime && item.pickup_anyway > 0))
 667                 {
 668                         pickedup = true;
 669                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 670                         if(it & WepSet_FromWeapon(Weapons_from(i)))
 671                         {
 672                                 W_DropEvent(wr_pickup, player, i, item);
 673                                 W_GiveWeapon(player, i);
 674                         }
 675                 }
 676         }
 677
 678         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 679         {
 680                 pickedup = true;
 681                 player.items |= it;
 682                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 683         }
 684
 685         if (item.strength_finished)
 686         {
 687                 pickedup = true;
 688                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 689         }
 690         if (item.invincible_finished)
 691         {
 692                 pickedup = true;
 693                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 694         }
 695         if (item.superweapons_finished)
 696         {
 697                 pickedup = true;
 698                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 699         }
 700
 701 :skip
 702
 703         // always eat teamed entities
 704         if(item.team)
 705                 pickedup = true;
 706
 707         if (!pickedup)
 708                 return 0;
 709
 710         // crude hack to enforce switching weapons
 711         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 712         {
 713                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
 714                 return 1;
 715         }
 716
 717         if (_switchweapon)
 718                 if (PS(player).m_switchweapon != w_getbestweapon(player))
 719                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 720
 721         return 1;
 722 }
 723
 724 void Item_Touch()
 725 {
 726         SELFPARAM();
 727
 728         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 729         if (this.classname == "droppedweapon")
 730         {
 731                 if (ITEM_TOUCH_NEEDKILL())
 732                 {
 733                         remove(this);
 734                         return;
 735                 }
 736         }
 737
 738         if(!(other.flags & FL_PICKUPITEMS)
 739         || other.frozen
 740         || other.deadflag
 741         || (this.solid != SOLID_TRIGGER)
 742         || (this.owner == other)
 743         || (time < this.item_spawnshieldtime)
 744         ) { return; }
 745
 746         switch (MUTATOR_CALLHOOK(ItemTouch, this, other))
 747         {
 748                 case MUT_ITEMTOUCH_RETURN: { return; }
 749                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 750         }
 751
 752         if (this.classname == "droppedweapon")
 753         {
 754                 this.strength_finished = max(0, this.strength_finished - time);
 755                 this.invincible_finished = max(0, this.invincible_finished - time);
 756                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 757         }
 758         entity it = this.itemdef;
 759         bool gave = ITEM_HANDLE(Pickup, it, this, other);
 760         if (!gave)
 761         {
 762                 if (this.classname == "droppedweapon")
 763                 {
 764                         // undo what we did above
 765                         this.strength_finished += time;
 766                         this.invincible_finished += time;
 767                         this.superweapons_finished += time;
 768                 }
 769                 return;
 770         }
 771
 772         :pickup
 773
 774         other.last_pickup = time;
 775
 776         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 777         _sound (other, CH_TRIGGER, (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 778
 779         if (this.classname == "droppedweapon")
 780                 remove (this);
 781         else if (this.spawnshieldtime)
 782         {
 783                 entity e;
 784                 if(this.team)
 785                 {
 786                         RandomSelection_Init();
 787                         for(entity head = world; (head = findfloat(head, team, this.team)); )
 788                         {
 789                                 if(head.flags & FL_ITEM)
 790                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 791                                 {
 792                                         Item_Show(head, -1);
 793                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 794                                 }
 795                         }
 796                         e = RandomSelection_chosen_ent;
 797
 798                 }
 799                 else
 800                         e = this;
 801                 Item_ScheduleRespawn(e);
 802         }
 803 }
 804
 805 void Item_Reset(entity this)
 806 {
 807         Item_Show(this, !this.state);
 808         setorigin(this, this.origin);
 809
 810         if (this.classname != "droppedweapon")
 811         {
 812                 this.think = Item_Think;
 813                 this.nextthink = time;
 814
 815                 if (this.waypointsprite_attached)
 816                         WaypointSprite_Kill(this.waypointsprite_attached);
 817
 818                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 819                         Item_ScheduleInitialRespawn(this);
 820         }
 821 }
 822 void Item_Reset_self() { SELFPARAM(); Item_Reset(this); }
 823
 824 void Item_FindTeam()
 825 {SELFPARAM();
 826         entity head, e;
 827
 828         if(self.effects & EF_NODRAW)
 829         {
 830                 // marker for item team search
 831                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 832                 RandomSelection_Init();
 833                 for(head = world; (head = findfloat(head, team, self.team)); )
 834                 if(head.flags & FL_ITEM)
 835                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 836                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 837                 e = RandomSelection_chosen_ent;
 838                 e.state = 0;
 839                 Item_Show(e, 1);
 840
 841                 for(head = world; (head = findfloat(head, team, self.team)); )
 842                 if(head.flags & FL_ITEM)
 843                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 844                 {
 845                         if(head != e)
 846                         {
 847                                 // make it a non-spawned item
 848                                 Item_Show(head, -1);
 849                                 head.state = 1; // state 1 = initially hidden item
 850                         }
 851                         head.effects &= ~EF_NODRAW;
 852                 }
 853
 854                 Item_Reset(self);
 855         }
 856 }
 857
 858 // Savage: used for item garbage-collection
 859 // TODO: perhaps nice special effect?
 860 void RemoveItem()
 861 {SELFPARAM();
 862         if(wasfreed(self) || !self) { return; }
 863         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 864         remove(self);
 865 }
 866
 867 // pickup evaluation functions
 868 // these functions decide how desirable an item is to the bots
 869
 870 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 871
 872 float weapon_pickupevalfunc(entity player, entity item)
 873 {
 874         float c;
 875
 876         // See if I have it already
 877         if(item.weapons & ~player.weapons)
 878         {
 879                 // If I can pick it up
 880                 if(!item.spawnshieldtime)
 881                         c = 0;
 882                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 883                 {
 884                         // Skilled bots will grab more
 885                         c = bound(0, skill / 10, 1) * 0.5;
 886                 }
 887                 else
 888                         c = 0;
 889         }
 890         else
 891                 c = 1;
 892
 893         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 894         if( bot_custom_weapon && c )
 895         {
 896                 // Find the highest position on any range
 897                 int position = -1;
 898                 for (int j = 0; j < WEP_LAST ; ++j){
 899                         if(
 900                                         bot_weapons_far[j] == item.weapon ||
 901                                         bot_weapons_mid[j] == item.weapon ||
 902                                         bot_weapons_close[j] == item.weapon
 903                           )
 904                         {
 905                                 position = j;
 906                                 break;
 907                         }
 908                 }
 909
 910                 // Rate it
 911                 if (position >= 0 )
 912                 {
 913                         position = WEP_LAST - position;
 914                         // item.bot_pickupbasevalue is overwritten here
 915                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 916                 }
 917         }
 918
 919         return item.bot_pickupbasevalue * c;
 920 }
 921
 922 float commodity_pickupevalfunc(entity player, entity item)
 923 {
 924         float c, i;
 925         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 926         entity wi;
 927         c = 0;
 928
 929         // Detect needed ammo
 930         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 931         {
 932                 wi = Weapons_from(i);
 933
 934                 if (!(player.weapons & (wi.m_wepset)))
 935                         continue;
 936
 937                 if(wi.items & ITEM_Shells.m_itemid)
 938                         need_shells = true;
 939                 else if(wi.items & ITEM_Bullets.m_itemid)
 940                         need_nails = true;
 941                 else if(wi.items & ITEM_Rockets.m_itemid)
 942                         need_rockets = true;
 943                 else if(wi.items & ITEM_Cells.m_itemid)
 944                         need_cells = true;
 945                 else if(wi.items & ITEM_Plasma.m_itemid)
 946                         need_plasma = true;
 947                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 948                         need_fuel = true;
 949         }
 950
 951         // TODO: figure out if the player even has the weapon this ammo is for?
 952         // may not affect strategy much though...
 953         // find out how much more ammo/armor/health the player can hold
 954         if (need_shells)
 955         if (item.ammo_shells)
 956         if (player.ammo_shells < g_pickup_shells_max)
 957                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 958         if (need_nails)
 959         if (item.ammo_nails)
 960         if (player.ammo_nails < g_pickup_nails_max)
 961                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 962         if (need_rockets)
 963         if (item.ammo_rockets)
 964         if (player.ammo_rockets < g_pickup_rockets_max)
 965                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 966         if (need_cells)
 967         if (item.ammo_cells)
 968         if (player.ammo_cells < g_pickup_cells_max)
 969                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 970         if (need_plasma)
 971         if (item.ammo_plasma)
 972         if (player.ammo_plasma < g_pickup_plasma_max)
 973                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 974         if (need_fuel)
 975         if (item.ammo_fuel)
 976         if (player.ammo_fuel < g_pickup_fuel_max)
 977                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 978         if (item.armorvalue)
 979         if (player.armorvalue < item.max_armorvalue)
 980                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 981         if (item.health)
 982         if (player.health < item.max_health)
 983                 c = c + max(0, 1 - player.health / item.max_health);
 984
 985         return item.bot_pickupbasevalue * c;
 986 }
 987
 988 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 989 {
 990         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 991                 RemoveItem();
 992 }
 993
 994 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
 995 {
 996         string itemname = def.m_name;
 997         Model itemmodel = def.m_model;
 998     Sound pickupsound = def.m_sound;
 999         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1000         float pickupbasevalue = def.m_botvalue;
1001         int itemflags = def.m_itemflags;
1002
1003         startitem_failed = false;
1004
1005         this.item_model_ent = itemmodel;
1006     this.item_pickupsound_ent = pickupsound;
1007
1008         if(!this.respawntime) // both need to be set
1009         {
1010                 this.respawntime = defaultrespawntime;
1011                 this.respawntimejitter = defaultrespawntimejitter;
1012         }
1013
1014         int itemid = def.m_itemid;
1015         this.items = itemid;
1016         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1017         this.weapon = weaponid;
1018
1019         if(!this.fade_end)
1020         {
1021                 this.fade_start = autocvar_g_items_mindist;
1022                 this.fade_end = autocvar_g_items_maxdist;
1023         }
1024
1025         if(weaponid)
1026                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1027
1028         this.flags = FL_ITEM | itemflags;
1029
1030         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1031         {
1032                 startitem_failed = true;
1033                 remove(this);
1034                 return;
1035         }
1036
1037         // is it a dropped weapon?
1038         if (this.classname == "droppedweapon")
1039         {
1040                 this.reset = SUB_Remove;
1041                 // it's a dropped weapon
1042                 this.movetype = MOVETYPE_TOSS;
1043
1044                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1045                 this.think = RemoveItem;
1046                 this.nextthink = time + 20;
1047
1048                 this.takedamage = DAMAGE_YES;
1049                 this.event_damage = Item_Damage;
1050
1051                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1052                 {
1053                         // if item is worthless after a timer, have it expire then
1054                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1055                 }
1056
1057                 // don't drop if in a NODROP zone (such as lava)
1058                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1059                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1060                 {
1061                         startitem_failed = true;
1062                         remove(this);
1063                         return;
1064                 }
1065         }
1066         else
1067         {
1068                 if(!have_pickup_item(this))
1069                 {
1070                         startitem_failed = true;
1071                         remove (this);
1072                         return;
1073                 }
1074
1075                 if(this.angles != '0 0 0')
1076                         this.SendFlags |= ISF_ANGLES;
1077
1078                 this.reset = Item_Reset;
1079                 // it's a level item
1080                 if(this.spawnflags & 1)
1081                         this.noalign = 1;
1082                 if (this.noalign > 0)
1083                         this.movetype = MOVETYPE_NONE;
1084                 else
1085                         this.movetype = MOVETYPE_TOSS;
1086                 // do item filtering according to game mode and other things
1087                 if (this.noalign <= 0)
1088                 {
1089                         // first nudge it off the floor a little bit to avoid math errors
1090                         setorigin(this, this.origin + '0 0 1');
1091                         // set item size before we spawn a spawnfunc_waypoint
1092                         setsize(this, def.m_mins, def.m_maxs);
1093                         this.SendFlags |= ISF_SIZE;
1094                         // note droptofloor returns false if stuck/or would fall too far
1095                         if (!this.noalign)
1096                                 WITH(entity, self, this, droptofloor());
1097                         waypoint_spawnforitem(this);
1098                 }
1099
1100                 /*
1101                  * can't do it that way, as it would break maps
1102                  * TODO make a target_give like entity another way, that perhaps has
1103                  * the weapon name in a key
1104                 if(this.targetname)
1105                 {
1106                         // target_give not yet supported; maybe later
1107                         print("removed targeted ", this.classname, "\n");
1108                         startitem_failed = true;
1109                         remove (this);
1110                         return;
1111                 }
1112                 */
1113
1114                 if(autocvar_spawn_debug >= 2)
1115                 {
1116                         for(entity otheritem = findradius(this.origin, 3); otheritem; otheritem = otheritem.chain)
1117                         {
1118                             // why not flags & fl_item?
1119                                 if(otheritem.is_item)
1120                                 {
1121                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1122                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1123                                         error("Mapper sucks.");
1124                                 }
1125                         }
1126                         this.is_item = true;
1127                 }
1128
1129                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1130
1131                 precache_model(this.model);
1132                 precache_sound(this.item_pickupsound);
1133
1134                 if (   def.instanceOfPowerup
1135                         || def.instanceOfWeaponPickup
1136                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1137                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1138                         || (itemid & (IT_KEY1 | IT_KEY2))
1139                 ) this.target = "###item###"; // for finding the nearest item using find()
1140
1141                 Item_ItemsTime_SetTime(this, 0);
1142         }
1143
1144         this.bot_pickup = true;
1145         this.bot_pickupevalfunc = pickupevalfunc;
1146         this.bot_pickupbasevalue = pickupbasevalue;
1147         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1148         this.netname = itemname;
1149         this.touch = Item_Touch;
1150         setmodel(this, MDL_Null); // precision set below
1151         //this.effects |= EF_LOWPRECISION;
1152
1153         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1154
1155         this.SendFlags |= ISF_SIZE;
1156
1157         if (!(this.spawnflags & 1024)) {
1158                 if(def.instanceOfPowerup)
1159                         this.ItemStatus |= ITS_ANIMATE1;
1160
1161                 if(this.armorvalue || this.health)
1162                         this.ItemStatus |= ITS_ANIMATE2;
1163         }
1164
1165         if(def.instanceOfWeaponPickup)
1166         {
1167                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1168                         this.colormap = 1024; // color shirt=0 pants=0 grey
1169                 else
1170                         this.gravity = 1;
1171                 if (!(this.spawnflags & 1024))
1172                         this.ItemStatus |= ITS_ANIMATE1;
1173                 this.ItemStatus |= ISF_COLORMAP;
1174         }
1175
1176         this.state = 0;
1177         if(this.team) // broken, no idea why.
1178         {
1179                 if(!this.cnt)
1180                         this.cnt = 1; // item probability weight
1181
1182                 this.effects |= EF_NODRAW; // marker for item team search
1183                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1184         }
1185         else
1186                 Item_Reset(this);
1187
1188         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1189
1190         // call this hook after everything else has been done
1191         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1192         {
1193                 startitem_failed = true;
1194                 remove(this);
1195                 return;
1196         }
1197 }
1198
1199 void StartItem(entity this, GameItem def)
1200 {
1201     _StartItem(
1202         this,
1203         this.itemdef = def,
1204         def.m_respawntime(), // defaultrespawntime
1205         def.m_respawntimejitter() // defaultrespawntimejitter
1206         );
1207 }
1208
1209 spawnfunc(item_rockets)
1210 {
1211         if(!this.ammo_rockets)
1212                 this.ammo_rockets = g_pickup_rockets;
1213         if(!this.pickup_anyway)
1214                 this.pickup_anyway = g_pickup_ammo_anyway;
1215     StartItem(this, ITEM_Rockets);
1216 }
1217
1218 spawnfunc(item_bullets)
1219 {
1220         if(!weaponswapping)
1221         if(autocvar_sv_q3acompat_machineshotgunswap)
1222         if(this.classname != "droppedweapon")
1223         {
1224                 weaponswapping = true;
1225                 spawnfunc_item_shells(this);
1226                 weaponswapping = false;
1227                 return;
1228         }
1229
1230         if(!this.ammo_nails)
1231                 this.ammo_nails = g_pickup_nails;
1232         if(!this.pickup_anyway)
1233                 this.pickup_anyway = g_pickup_ammo_anyway;
1234     StartItem(this, ITEM_Bullets);
1235 }
1236
1237 spawnfunc(item_cells)
1238 {
1239         if(!this.ammo_cells)
1240                 this.ammo_cells = g_pickup_cells;
1241         if(!this.pickup_anyway)
1242                 this.pickup_anyway = g_pickup_ammo_anyway;
1243         StartItem(this, ITEM_Cells);
1244 }
1245
1246 spawnfunc(item_plasma)
1247 {
1248         if(!this.ammo_plasma)
1249                 this.ammo_plasma = g_pickup_plasma;
1250         if(!this.pickup_anyway)
1251                 this.pickup_anyway = g_pickup_ammo_anyway;
1252         StartItem(this, ITEM_Plasma);
1253 }
1254
1255 spawnfunc(item_shells)
1256 {
1257         if(!weaponswapping)
1258         if(autocvar_sv_q3acompat_machineshotgunswap)
1259         if(this.classname != "droppedweapon")
1260         {
1261                 weaponswapping = true;
1262                 spawnfunc_item_bullets(this);
1263                 weaponswapping = false;
1264                 return;
1265         }
1266
1267         if(!this.ammo_shells)
1268                 this.ammo_shells = g_pickup_shells;
1269         if(!this.pickup_anyway)
1270                 this.pickup_anyway = g_pickup_ammo_anyway;
1271         StartItem(this, ITEM_Shells);
1272 }
1273
1274 spawnfunc(item_armor_small)
1275 {
1276         if(!this.armorvalue)
1277                 this.armorvalue = g_pickup_armorsmall;
1278         if(!this.max_armorvalue)
1279                 this.max_armorvalue = g_pickup_armorsmall_max;
1280         if(!this.pickup_anyway)
1281                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1282         StartItem(this, ITEM_ArmorSmall);
1283 }
1284
1285 spawnfunc(item_armor_medium)
1286 {
1287         if(!this.armorvalue)
1288                 this.armorvalue = g_pickup_armormedium;
1289         if(!this.max_armorvalue)
1290                 this.max_armorvalue = g_pickup_armormedium_max;
1291         if(!this.pickup_anyway)
1292                 this.pickup_anyway = g_pickup_armormedium_anyway;
1293         StartItem(this, ITEM_ArmorMedium);
1294 }
1295
1296 spawnfunc(item_armor_big)
1297 {
1298         if(!this.armorvalue)
1299                 this.armorvalue = g_pickup_armorbig;
1300         if(!this.max_armorvalue)
1301                 this.max_armorvalue = g_pickup_armorbig_max;
1302         if(!this.pickup_anyway)
1303                 this.pickup_anyway = g_pickup_armorbig_anyway;
1304         StartItem(this, ITEM_ArmorLarge);
1305 }
1306
1307 spawnfunc(item_armor_large)
1308 {
1309         if(!this.armorvalue)
1310                 this.armorvalue = g_pickup_armorlarge;
1311         if(!this.max_armorvalue)
1312                 this.max_armorvalue = g_pickup_armorlarge_max;
1313         if(!this.pickup_anyway)
1314                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1315         StartItem(this, ITEM_ArmorMega);
1316 }
1317
1318 spawnfunc(item_health_small)
1319 {
1320         if(!this.max_health)
1321                 this.max_health = g_pickup_healthsmall_max;
1322         if(!this.health)
1323                 this.health = g_pickup_healthsmall;
1324         if(!this.pickup_anyway)
1325                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1326         StartItem(this, ITEM_HealthSmall);
1327 }
1328
1329 spawnfunc(item_health_medium)
1330 {
1331         if(!this.max_health)
1332                 this.max_health = g_pickup_healthmedium_max;
1333         if(!this.health)
1334                 this.health = g_pickup_healthmedium;
1335         if(!this.pickup_anyway)
1336                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1337     StartItem(this, ITEM_HealthMedium);
1338 }
1339
1340 spawnfunc(item_health_large)
1341 {
1342         if(!this.max_health)
1343                 this.max_health = g_pickup_healthlarge_max;
1344         if(!this.health)
1345                 this.health = g_pickup_healthlarge;
1346         if(!this.pickup_anyway)
1347                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1348         StartItem(this, ITEM_HealthLarge);
1349 }
1350
1351 spawnfunc(item_health_mega)
1352 {
1353     if(!this.max_health)
1354         this.max_health = g_pickup_healthmega_max;
1355     if(!this.health)
1356         this.health = g_pickup_healthmega;
1357     if(!this.pickup_anyway)
1358         this.pickup_anyway = g_pickup_healthmega_anyway;
1359     StartItem(this, ITEM_HealthMega);
1360 }
1361
1362 // support old misnamed entities
1363 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1364 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1365 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1366 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1367 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1368
1369 spawnfunc(item_strength)
1370 {
1371                 if(!this.strength_finished)
1372                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1373                 StartItem(this, ITEM_Strength);
1374 }
1375
1376 spawnfunc(item_invincible)
1377 {
1378                 if(!this.invincible_finished)
1379                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1380                 StartItem(this, ITEM_Shield);
1381 }
1382
1383 // compatibility:
1384 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1385
1386 void target_items_use()
1387 {SELFPARAM();
1388         if(activator.classname == "droppedweapon")
1389         {
1390                 EXACTTRIGGER_TOUCH;
1391                 remove(activator);
1392                 return;
1393         }
1394
1395         if (!IS_PLAYER(activator))
1396                 return;
1397         if(activator.deadflag != DEAD_NO)
1398                 return;
1399         EXACTTRIGGER_TOUCH;
1400
1401         entity e;
1402         for(e = world; (e = find(e, classname, "droppedweapon")); )
1403                 if(e.enemy == activator)
1404                         remove(e);
1405
1406         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1407                 centerprint(activator, self.message);
1408 }
1409
1410 spawnfunc(target_items)
1411 {
1412         float n, i, j;
1413         entity e;
1414         string s;
1415
1416         self.use = target_items_use;
1417         if(!self.strength_finished)
1418                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1419         if(!self.invincible_finished)
1420                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1421         if(!self.superweapons_finished)
1422                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1423
1424         n = tokenize_console(self.netname);
1425         if(argv(0) == "give")
1426         {
1427                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1428         }
1429         else
1430         {
1431                 for(i = 0; i < n; ++i)
1432                 {
1433                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1434                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1435                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1436                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1437                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1438                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1439                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1440                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1441                         else
1442                         {
1443                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1444                                 {
1445                                         e = Weapons_from(j);
1446                                         s = W_UndeprecateName(argv(i));
1447                                         if(s == e.netname)
1448                                         {
1449                                                 self.weapons |= (e.m_wepset);
1450                                                 if(self.spawnflags == 0 || self.spawnflags == 2) {
1451                                                         Weapon w = Weapons_from(e.weapon);
1452                                                         w.wr_init(w);
1453                                                 }
1454                                                 break;
1455                                         }
1456                                 }
1457                                 if(j > WEP_LAST)
1458                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1459                         }
1460                 }
1461
1462                 string itemprefix, valueprefix;
1463                 if(self.spawnflags == 0)
1464                 {
1465                         itemprefix = "";
1466                         valueprefix = "";
1467                 }
1468                 else if(self.spawnflags == 1)
1469                 {
1470                         itemprefix = "max ";
1471                         valueprefix = "max ";
1472                 }
1473                 else if(self.spawnflags == 2)
1474                 {
1475                         itemprefix = "min ";
1476                         valueprefix = "min ";
1477                 }
1478                 else if(self.spawnflags == 4)
1479                 {
1480                         itemprefix = "minus ";
1481                         valueprefix = "max ";
1482                 }
1483                 else
1484                 {
1485                         error("invalid spawnflags");
1486                         itemprefix = valueprefix = string_null;
1487                 }
1488
1489                 self.netname = "";
1490                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1491                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1492                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * boolean(self.items & ITEM_Strength.m_itemid), "strength");
1493                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * boolean(self.items & ITEM_Shield.m_itemid), "invincible");
1494                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * boolean(self.items & IT_SUPERWEAPON), "superweapons");
1495                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1496                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1497                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1498                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1499                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1500                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1501                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1502                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1503                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1504                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1505                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1506                 {
1507                         e = Weapons_from(j);
1508                         if(e.weapon)
1509                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & (e.m_wepset)), e.netname);
1510                 }
1511         }
1512         self.netname = strzone(self.netname);
1513         //print(self.netname, "\n");
1514
1515         n = tokenize_console(self.netname);
1516         for(i = 0; i < n; ++i)
1517         {
1518                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1519                 {
1520                         e = Weapons_from(j);
1521                         if(argv(i) == e.netname)
1522                         {
1523                                 Weapon w = Weapons_from(e.weapon);
1524                                 w.wr_init(w);
1525                                 break;
1526                         }
1527                 }
1528         }
1529 }
1530
1531 spawnfunc(item_fuel)
1532 {
1533         if(!this.ammo_fuel)
1534                 this.ammo_fuel = g_pickup_fuel;
1535         if(!this.pickup_anyway)
1536                 this.pickup_anyway = g_pickup_ammo_anyway;
1537         StartItem(this, ITEM_JetpackFuel);
1538 }
1539
1540 spawnfunc(item_fuel_regen)
1541 {
1542         if(start_items & ITEM_JetpackRegen.m_itemid)
1543         {
1544                 spawnfunc_item_fuel(this);
1545                 return;
1546         }
1547         StartItem(this, ITEM_JetpackRegen);
1548 }
1549
1550 spawnfunc(item_jetpack)
1551 {
1552         if(!this.ammo_fuel)
1553                 this.ammo_fuel = g_pickup_fuel_jetpack;
1554         if(start_items & ITEM_Jetpack.m_itemid)
1555         {
1556                 spawnfunc_item_fuel(this);
1557                 return;
1558         }
1559         StartItem(this, ITEM_Jetpack);
1560 }
1561
1562 float GiveWeapon(entity e, float wpn, float op, float val)
1563 {
1564         WepSet v0, v1;
1565         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1566         v0 = (e.weapons & s);
1567         switch(op)
1568         {
1569                 case OP_SET:
1570                         if(val > 0)
1571                                 e.weapons |= s;
1572                         else
1573                                 e.weapons &= ~s;
1574                         break;
1575                 case OP_MIN:
1576                 case OP_PLUS:
1577                         if(val > 0)
1578                                 e.weapons |= s;
1579                         break;
1580                 case OP_MAX:
1581                         if(val <= 0)
1582                                 e.weapons &= ~s;
1583                         break;
1584                 case OP_MINUS:
1585                         if(val > 0)
1586                                 e.weapons &= ~s;
1587                         break;
1588         }
1589         v1 = (e.weapons & s);
1590         return (v0 != v1);
1591 }
1592
1593 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1594 {
1595         if(v1 == v0)
1596                 return;
1597         if(v1 <= v0 - t)
1598         {
1599                 if(snd_decr != "")
1600                         _sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1601         }
1602         else if(v0 >= v0 + t)
1603         {
1604                 if(snd_incr != "")
1605                         _sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1606         }
1607 }
1608
1609 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1610 {
1611         if(v0 < v1)
1612                 e.(rotfield) = max(e.(rotfield), time + rottime);
1613         else if(v0 > v1)
1614                 e.(regenfield) = max(e.(regenfield), time + regentime);
1615 }
1616 float GiveItems(entity e, float beginarg, float endarg)
1617 {SELFPARAM();
1618         float got, i, j, val, op;
1619         float _switchweapon;
1620         entity wi;
1621         string cmd;
1622
1623         val = 999;
1624         op = OP_SET;
1625
1626         got = 0;
1627
1628         _switchweapon = false;
1629         if (e.autoswitch)
1630                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1631                         _switchweapon = true;
1632
1633         e.strength_finished = max(0, e.strength_finished - time);
1634         e.invincible_finished = max(0, e.invincible_finished - time);
1635         e.superweapons_finished = max(0, e.superweapons_finished - time);
1636
1637         PREGIVE(e, items);
1638         PREGIVE_WEAPONS(e);
1639         PREGIVE(e, strength_finished);
1640         PREGIVE(e, invincible_finished);
1641         PREGIVE(e, superweapons_finished);
1642         PREGIVE(e, ammo_nails);
1643         PREGIVE(e, ammo_cells);
1644         PREGIVE(e, ammo_plasma);
1645         PREGIVE(e, ammo_shells);
1646         PREGIVE(e, ammo_rockets);
1647         PREGIVE(e, ammo_fuel);
1648         PREGIVE(e, armorvalue);
1649         PREGIVE(e, health);
1650
1651         for(i = beginarg; i < endarg; ++i)
1652         {
1653                 cmd = argv(i);
1654
1655                 if(cmd == "0" || stof(cmd))
1656                 {
1657                         val = stof(cmd);
1658                         continue;
1659                 }
1660                 switch(cmd)
1661                 {
1662                         case "no":
1663                                 op = OP_MAX;
1664                                 val = 0;
1665                                 continue;
1666                         case "max":
1667                                 op = OP_MAX;
1668                                 continue;
1669                         case "min":
1670                                 op = OP_MIN;
1671                                 continue;
1672                         case "plus":
1673                                 op = OP_PLUS;
1674                                 continue;
1675                         case "minus":
1676                                 op = OP_MINUS;
1677                                 continue;
1678                         case "ALL":
1679                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1680                                 got += GiveValue(e, strength_finished, op, val);
1681                                 got += GiveValue(e, invincible_finished, op, val);
1682                                 got += GiveValue(e, superweapons_finished, op, val);
1683                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1684                         case "all":
1685                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1686                                 got += GiveValue(e, health, op, val);
1687                                 got += GiveValue(e, armorvalue, op, val);
1688                         case "allweapons":
1689                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1690                                 {
1691                                         wi = Weapons_from(j);
1692                                         if(wi.weapon)
1693                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1694                                                         got += GiveWeapon(e, j, op, val);
1695                                 }
1696                         case "allammo":
1697                                 got += GiveValue(e, ammo_cells, op, val);
1698                                 got += GiveValue(e, ammo_plasma, op, val);
1699                                 got += GiveValue(e, ammo_shells, op, val);
1700                                 got += GiveValue(e, ammo_nails, op, val);
1701                                 got += GiveValue(e, ammo_rockets, op, val);
1702                                 got += GiveValue(e, ammo_fuel, op, val);
1703                                 break;
1704                         case "unlimited_ammo":
1705                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1706                                 break;
1707                         case "unlimited_weapon_ammo":
1708                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1709                                 break;
1710                         case "unlimited_superweapons":
1711                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1712                                 break;
1713                         case "jetpack":
1714                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1715                                 break;
1716                         case "fuel_regen":
1717                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1718                                 break;
1719                         case "strength":
1720                                 got += GiveValue(e, strength_finished, op, val);
1721                                 break;
1722                         case "invincible":
1723                                 got += GiveValue(e, invincible_finished, op, val);
1724                                 break;
1725                         case "superweapons":
1726                                 got += GiveValue(e, superweapons_finished, op, val);
1727                                 break;
1728                         case "cells":
1729                                 got += GiveValue(e, ammo_cells, op, val);
1730                                 break;
1731                         case "plasma":
1732                                 got += GiveValue(e, ammo_plasma, op, val);
1733                                 break;
1734                         case "shells":
1735                                 got += GiveValue(e, ammo_shells, op, val);
1736                                 break;
1737                         case "nails":
1738                         case "bullets":
1739                                 got += GiveValue(e, ammo_nails, op, val);
1740                                 break;
1741                         case "rockets":
1742                                 got += GiveValue(e, ammo_rockets, op, val);
1743                                 break;
1744                         case "health":
1745                                 got += GiveValue(e, health, op, val);
1746                                 break;
1747                         case "armor":
1748                                 got += GiveValue(e, armorvalue, op, val);
1749                                 break;
1750                         case "fuel":
1751                                 got += GiveValue(e, ammo_fuel, op, val);
1752                                 break;
1753                         default:
1754                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1755                                 {
1756                                         wi = Weapons_from(j);
1757                                         if(cmd == wi.netname)
1758                                         {
1759                                                 got += GiveWeapon(e, j, op, val);
1760                                                 break;
1761                                         }
1762                                 }
1763                                 if(j > WEP_LAST)
1764                                         LOG_INFO("give: invalid item ", cmd, "\n");
1765                                 break;
1766                 }
1767                 val = 999;
1768                 op = OP_SET;
1769         }
1770
1771         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND(ITEMPICKUP), string_null);
1772         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND(POWERUP), SND(POWEROFF));
1773         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND(POWERUP), SND(POWEROFF));
1774         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND(ITEMPICKUP), string_null);
1775         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1776         {
1777                 wi = Weapons_from(j);
1778                 if(wi.weapon)
1779                 {
1780                         POSTGIVE_WEAPON(e, Weapons_from(j), SND(WEAPONPICKUP), string_null);
1781                         if (!(save_weapons & (wi.m_wepset)))
1782                                 if(e.weapons & (wi.m_wepset)) {
1783                                         Weapon w = Weapons_from(wi.weapon);
1784                                         w.wr_init(w);
1785                                 }
1786                 }
1787         }
1788         POSTGIVE_VALUE(e, strength_finished, 1, SND(POWERUP), SND(POWEROFF));
1789         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", SND(POWEROFF));
1790         POSTGIVE_VALUE(e, ammo_nails, 0, SND(ITEMPICKUP), string_null);
1791         POSTGIVE_VALUE(e, ammo_cells, 0, SND(ITEMPICKUP), string_null);
1792         POSTGIVE_VALUE(e, ammo_plasma, 0, SND(ITEMPICKUP), string_null);
1793         POSTGIVE_VALUE(e, ammo_shells, 0, SND(ITEMPICKUP), string_null);
1794         POSTGIVE_VALUE(e, ammo_rockets, 0, SND(ITEMPICKUP), string_null);
1795         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND(ITEMPICKUP), string_null);
1796         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(ARMOR25), string_null);
1797         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(MEGAHEALTH), string_null);
1798
1799         if(e.superweapons_finished <= 0)
1800                 if(self.weapons & WEPSET_SUPERWEAPONS)
1801                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1802
1803         if(e.strength_finished <= 0)
1804                 e.strength_finished = 0;
1805         else
1806                 e.strength_finished += time;
1807         if(e.invincible_finished <= 0)
1808                 e.invincible_finished = 0;
1809         else
1810                 e.invincible_finished += time;
1811         if(e.superweapons_finished <= 0)
1812                 e.superweapons_finished = 0;
1813         else
1814                 e.superweapons_finished += time;
1815
1816         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1817                 _switchweapon = true;
1818         if(_switchweapon)
1819                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1820
1821         return got;
1822 }
1823 #endif