qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "g_subs.qh"
   9     #include "waypointsprites.qh"
  10
  11     #include "bot/bot.qh"
  12     #include "bot/waypoints.qh"
  13
  14     #include "mutators/mutators_include.qh"
  15
  16     #include "weapons/common.qh"
  17     #include "weapons/selection.qh"
  18     #include "weapons/weaponsystem.qh"
  19
  20     #include "../common/constants.qh"
  21     #include "../common/deathtypes.qh"
  22     #include "../common/notifications.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/monsters.qh"
  26
  27     #include "../common/weapons/weapons.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 void Item_Respawn (void)
 416 {
 417         Item_Show(self, 1);
 418         // this is ugly...
 419         if(self.items == IT_STRENGTH)
 420                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 421         else if(self.items == IT_INVINCIBLE)
 422                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 423         else
 424                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 425         setorigin (self, self.origin);
 426
 427         self.think = Item_Think;
 428         self.nextthink = time;
 429
 430         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 431         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 432 }
 433
 434 void Item_RespawnCountdown (void)
 435 {
 436         if(self.count >= ITEM_RESPAWN_TICKS)
 437         {
 438                 if(self.waypointsprite_attached)
 439                         WaypointSprite_Kill(self.waypointsprite_attached);
 440                 Item_Respawn();
 441         }
 442         else
 443         {
 444                 self.nextthink = time + 1;
 445                 self.count += 1;
 446                 if(self.count == 1)
 447                 {
 448                         string name;
 449                         vector rgb = '1 0 1';
 450                         name = string_null;
 451                         switch(self.items)
 452                         {
 453                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 454                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 455                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 456                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 457                         }
 458                         item_name = name;
 459                         item_color = rgb;
 460                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 461                         name = item_name;
 462                         rgb = item_color;
 463                         if(self.flags & FL_WEAPON)
 464                         {
 465                                 entity wi = get_weaponinfo(self.weapon);
 466                                 if(wi)
 467                                 {
 468                                         name = wi.wpmodel;
 469                                         rgb = '1 0 0';
 470                                 }
 471                         }
 472                         if(name)
 473                         {
 474                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 475                                 if(self.waypointsprite_attached)
 476                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 477                         }
 478                         else
 479                         {
 480                                 print("Unknown powerup-marked item is wanting to respawn\n");
 481                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 482                         }
 483                 }
 484                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 485                 if(self.waypointsprite_attached)
 486                 {
 487                         WaypointSprite_Ping(self.waypointsprite_attached);
 488                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 489                 }
 490         }
 491 }
 492
 493 void Item_RespawnThink()
 494 {
 495         self.nextthink = time;
 496         if(self.origin != self.oldorigin)
 497         {
 498                 self.oldorigin = self.origin;
 499                 ItemUpdate(self);
 500         }
 501
 502         if(time >= self.wait)
 503                 Item_Respawn();
 504 }
 505
 506 void Item_ScheduleRespawnIn(entity e, float t)
 507 {
 508         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS))
 509         {
 510                 e.think = Item_RespawnCountdown;
 511                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 512                 e.count = 0;
 513         }
 514         else
 515         {
 516                 e.think = Item_RespawnThink;
 517                 e.nextthink = time;
 518                 e.wait = time + t;
 519         }
 520 }
 521
 522 void Item_ScheduleRespawn(entity e)
 523 {
 524         if(e.respawntime > 0)
 525         {
 526                 Item_Show(e, 0);
 527                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 528         }
 529         else // if respawntime is -1, this item does not respawn
 530                 Item_Show(e, -1);
 531 }
 532
 533 void Item_ScheduleInitialRespawn(entity e)
 534 {
 535         Item_Show(e, 0);
 536         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 537 }
 538
 539 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 540 {
 541         if (!item.(ammotype))
 542                 return false;
 543
 544         if (item.spawnshieldtime)
 545         {
 546                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 547                 {
 548                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 549                         goto YEAH;
 550                 }
 551         }
 552         else if(g_weapon_stay == 2)
 553         {
 554                 float mi = min(item.(ammotype), ammomax);
 555                 if (player.(ammotype) < mi)
 556                 {
 557                         player.(ammotype) = mi;
 558                         goto YEAH;
 559                 }
 560         }
 561
 562         return false;
 563
 564 :YEAH
 565         switch(mode)
 566         {
 567                 case ITEM_MODE_FUEL:
 568                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 569                         break;
 570                 case ITEM_MODE_HEALTH:
 571                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 572                         break;
 573                 case ITEM_MODE_ARMOR:
 574                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 575                         break;
 576                 default:
 577                         break;
 578         }
 579         return true;
 580 }
 581
 582 float Item_GiveTo(entity item, entity player)
 583 {
 584         float _switchweapon;
 585         float pickedup;
 586         float it;
 587         float i;
 588
 589         // if nothing happens to player, just return without taking the item
 590         pickedup = false;
 591         _switchweapon = false;
 592         // in case the player has autoswitch enabled do the following:
 593         // if the player is using their best weapon before items are given, they
 594         // probably want to switch to an even better weapon after items are given
 595         if (player.autoswitch)
 596         if (player.switchweapon == w_getbestweapon(player))
 597                 _switchweapon = true;
 598
 599         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 600                 _switchweapon = true;
 601
 602         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 603         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 604         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 605         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 606         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 607         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 608         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 609         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 610
 611         if (item.flags & FL_WEAPON)
 612         {
 613                 WepSet it;
 614                 it = item.weapons;
 615                 it &= ~player.weapons;
 616
 617                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 618                 {
 619                         pickedup = true;
 620                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 621                         if(it & WepSet_FromWeapon(i))
 622                         {
 623                                 W_DropEvent(WR_PICKUP, player, i, item);
 624                                 W_GiveWeapon(player, i);
 625                         }
 626                 }
 627         }
 628
 629         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 630         {
 631                 pickedup = true;
 632                 player.items |= it;
 633                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 634         }
 635
 636         if (item.strength_finished)
 637         {
 638                 pickedup = true;
 639                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 640         }
 641         if (item.invincible_finished)
 642         {
 643                 pickedup = true;
 644                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 645         }
 646         if (item.superweapons_finished)
 647         {
 648                 pickedup = true;
 649                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 650         }
 651
 652 :skip
 653
 654         // always eat teamed entities
 655         if(item.team)
 656                 pickedup = true;
 657
 658         if (!pickedup)
 659                 return 0;
 660
 661         if (_switchweapon)
 662                 if (player.switchweapon != w_getbestweapon(player))
 663                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 664
 665         return 1;
 666 }
 667
 668 void Item_Touch (void)
 669 {
 670         entity e, head;
 671
 672         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 673         if(self.classname == "droppedweapon")
 674         {
 675                 if (ITEM_TOUCH_NEEDKILL())
 676                 {
 677                         remove(self);
 678                         return;
 679                 }
 680         }
 681
 682         if (!IS_PLAYER(other))
 683                 return;
 684         if (other.frozen)
 685                 return;
 686         if (other.deadflag)
 687                 return;
 688         if (self.solid != SOLID_TRIGGER)
 689                 return;
 690         if (self.owner == other)
 691                 return;
 692         if (time < self.item_spawnshieldtime)
 693                 return;
 694
 695         switch(MUTATOR_CALLHOOK(ItemTouch))
 696         {
 697                 case MUT_ITEMTOUCH_RETURN: { return; }
 698                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 699         }
 700
 701         if (self.classname == "droppedweapon")
 702         {
 703                 self.strength_finished = max(0, self.strength_finished - time);
 704                 self.invincible_finished = max(0, self.invincible_finished - time);
 705                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 706         }
 707
 708         if(!Item_GiveTo(self, other))
 709         {
 710                 if (self.classname == "droppedweapon")
 711                 {
 712                         // undo what we did above
 713                         self.strength_finished += time;
 714                         self.invincible_finished += time;
 715                         self.superweapons_finished += time;
 716                 }
 717                 return;
 718         }
 719
 720         :pickup
 721
 722         other.last_pickup = time;
 723
 724         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 725         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 726
 727         if (self.classname == "droppedweapon")
 728                 remove (self);
 729         else if (!self.spawnshieldtime)
 730                 return;
 731         else
 732         {
 733                 if(self.team)
 734                 {
 735                         RandomSelection_Init();
 736                         for(head = world; (head = findfloat(head, team, self.team)); )
 737                         {
 738                                 if(head.flags & FL_ITEM)
 739                                 {
 740                                         Item_Show(head, -1);
 741                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 742                                 }
 743                         }
 744                         e = RandomSelection_chosen_ent;
 745
 746                 }
 747                 else
 748                         e = self;
 749                 Item_ScheduleRespawn(e);
 750         }
 751 }
 752
 753 void Item_Reset()
 754 {
 755         Item_Show(self, !self.state);
 756         setorigin (self, self.origin);
 757
 758         if(self.classname != "droppedweapon")
 759         {
 760                 self.think = Item_Think;
 761                 self.nextthink = time;
 762
 763                 if(self.waypointsprite_attached)
 764                         WaypointSprite_Kill(self.waypointsprite_attached);
 765
 766                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 767                         Item_ScheduleInitialRespawn(self);
 768         }
 769 }
 770
 771 void Item_FindTeam()
 772 {
 773         entity head, e;
 774
 775         if(self.effects & EF_NODRAW)
 776         {
 777                 // marker for item team search
 778                 dprint("Initializing item team ", ftos(self.team), "\n");
 779                 RandomSelection_Init();
 780                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 781                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 782                 e = RandomSelection_chosen_ent;
 783                 e.state = 0;
 784                 Item_Show(e, 1);
 785
 786                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 787                 {
 788                         if(head != e)
 789                         {
 790                                 // make it a non-spawned item
 791                                 Item_Show(head, -1);
 792                                 head.state = 1; // state 1 = initially hidden item
 793                         }
 794                         head.effects &= ~EF_NODRAW;
 795                 }
 796
 797                 Item_Reset();
 798         }
 799 }
 800
 801 // Savage: used for item garbage-collection
 802 // TODO: perhaps nice special effect?
 803 void RemoveItem(void)
 804 {
 805         remove(self);
 806 }
 807
 808 // pickup evaluation functions
 809 // these functions decide how desirable an item is to the bots
 810
 811 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 812
 813 float weapon_pickupevalfunc(entity player, entity item)
 814 {
 815         float c;
 816
 817         // See if I have it already
 818         if(item.weapons & ~player.weapons)
 819         {
 820                 // If I can pick it up
 821                 if(!item.spawnshieldtime)
 822                         c = 0;
 823                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 824                 {
 825                         // Skilled bots will grab more
 826                         c = bound(0, skill / 10, 1) * 0.5;
 827                 }
 828                 else
 829                         c = 0;
 830         }
 831         else
 832                 c = 1;
 833
 834         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 835         if( bot_custom_weapon && c )
 836         {
 837                 // Find the highest position on any range
 838                 int position = -1;
 839                 for (int j = 0; j < WEP_LAST ; ++j){
 840                         if(
 841                                         bot_weapons_far[j] == item.weapon ||
 842                                         bot_weapons_mid[j] == item.weapon ||
 843                                         bot_weapons_close[j] == item.weapon
 844                           )
 845                         {
 846                                 position = j;
 847                                 break;
 848                         }
 849                 }
 850
 851                 // Rate it
 852                 if (position >= 0 )
 853                 {
 854                         position = WEP_LAST - position;
 855                         // item.bot_pickupbasevalue is overwritten here
 856                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 857                 }
 858         }
 859
 860         return item.bot_pickupbasevalue * c;
 861 }
 862
 863 float commodity_pickupevalfunc(entity player, entity item)
 864 {
 865         float c, i;
 866         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 867         entity wi;
 868         c = 0;
 869
 870         // Detect needed ammo
 871         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 872         {
 873                 wi = get_weaponinfo(i);
 874
 875                 if (!(player.weapons & WepSet_FromWeapon(i)))
 876                         continue;
 877
 878                 if(wi.items & IT_SHELLS)
 879                         need_shells = true;
 880                 else if(wi.items & IT_NAILS)
 881                         need_nails = true;
 882                 else if(wi.items & IT_ROCKETS)
 883                         need_rockets = true;
 884                 else if(wi.items & IT_CELLS)
 885                         need_cells = true;
 886                 else if(wi.items & IT_PLASMA)
 887                         need_plasma = true;
 888                 else if(wi.items & IT_FUEL)
 889                         need_fuel = true;
 890         }
 891
 892         // TODO: figure out if the player even has the weapon this ammo is for?
 893         // may not affect strategy much though...
 894         // find out how much more ammo/armor/health the player can hold
 895         if (need_shells)
 896         if (item.ammo_shells)
 897         if (player.ammo_shells < g_pickup_shells_max)
 898                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 899         if (need_nails)
 900         if (item.ammo_nails)
 901         if (player.ammo_nails < g_pickup_nails_max)
 902                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 903         if (need_rockets)
 904         if (item.ammo_rockets)
 905         if (player.ammo_rockets < g_pickup_rockets_max)
 906                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 907         if (need_cells)
 908         if (item.ammo_cells)
 909         if (player.ammo_cells < g_pickup_cells_max)
 910                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 911         if (need_plasma)
 912         if (item.ammo_plasma)
 913         if (player.ammo_plasma < g_pickup_plasma_max)
 914                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 915         if (need_fuel)
 916         if (item.ammo_fuel)
 917         if (player.ammo_fuel < g_pickup_fuel_max)
 918                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 919         if (item.armorvalue)
 920         if (player.armorvalue < item.max_armorvalue)
 921                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 922         if (item.health)
 923         if (player.health < item.max_health)
 924                 c = c + max(0, 1 - player.health / item.max_health);
 925
 926         return item.bot_pickupbasevalue * c;
 927 }
 928
 929 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 930 {
 931         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 932                 RemoveItem();
 933 }
 934
 935 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 936 {
 937         startitem_failed = false;
 938
 939         if(self.model == "")
 940                 self.model = itemmodel;
 941
 942         if(self.model == "")
 943     {
 944         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 945         return;
 946     }
 947
 948         if(self.item_pickupsound == "")
 949                 self.item_pickupsound = pickupsound;
 950
 951         if(!self.respawntime) // both need to be set
 952         {
 953                 self.respawntime = defaultrespawntime;
 954                 self.respawntimejitter = defaultrespawntimejitter;
 955         }
 956
 957         self.items = itemid;
 958         self.weapon = weaponid;
 959
 960         if(weaponid)
 961                 self.weapons = WepSet_FromWeapon(weaponid);
 962
 963         self.flags = FL_ITEM | itemflags;
 964
 965         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 966         {
 967                 startitem_failed = true;
 968                 remove(self);
 969                 return;
 970         }
 971
 972         // is it a dropped weapon?
 973         if (self.classname == "droppedweapon")
 974         {
 975                 self.reset = SUB_Remove;
 976                 // it's a dropped weapon
 977                 self.movetype = MOVETYPE_TOSS;
 978
 979                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 980                 self.think = RemoveItem;
 981                 self.nextthink = time + 20;
 982
 983                 self.takedamage = DAMAGE_YES;
 984                 self.event_damage = Item_Damage;
 985
 986                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 987                 /*
 988                 if(self.items == 0)
 989                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
 990                 if(self.ammo_nails == 0)
 991                 if(self.ammo_cells == 0)
 992                 if(self.ammo_rockets == 0)
 993                 if(self.ammo_shells == 0)
 994                 if(self.ammo_fuel == 0)
 995                 if(self.health == 0)
 996                 if(self.armorvalue == 0)
 997                 */
 998                 {
 999                         // if item is worthless after a timer, have it expire then
1000                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1001                 }
1002
1003                 // don't drop if in a NODROP zone (such as lava)
1004                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1005                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1006                 {
1007                         startitem_failed = true;
1008                         remove(self);
1009                         return;
1010                 }
1011         }
1012         else
1013         {
1014                 if(!have_pickup_item())
1015                 {
1016                         startitem_failed = true;
1017                         remove (self);
1018                         return;
1019                 }
1020
1021                 self.reset = Item_Reset;
1022                 // it's a level item
1023                 if(self.spawnflags & 1)
1024                         self.noalign = 1;
1025                 if (self.noalign)
1026                         self.movetype = MOVETYPE_NONE;
1027                 else
1028                         self.movetype = MOVETYPE_TOSS;
1029                 // do item filtering according to game mode and other things
1030                 if (!self.noalign)
1031                 {
1032                         // first nudge it off the floor a little bit to avoid math errors
1033                         setorigin(self, self.origin + '0 0 1');
1034                         // set item size before we spawn a spawnfunc_waypoint
1035                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1036                                 setsize (self, '-16 -16 0', '16 16 48');
1037                         else
1038                                 setsize (self, '-16 -16 0', '16 16 32');
1039
1040                         // note droptofloor returns false if stuck/or would fall too far
1041                         droptofloor();
1042                         waypoint_spawnforitem(self);
1043                 }
1044
1045                 /*
1046                  * can't do it that way, as it would break maps
1047                  * TODO make a target_give like entity another way, that perhaps has
1048                  * the weapon name in a key
1049                 if(self.targetname)
1050                 {
1051                         // target_give not yet supported; maybe later
1052                         print("removed targeted ", self.classname, "\n");
1053                         startitem_failed = true;
1054                         remove (self);
1055                         return;
1056                 }
1057                 */
1058
1059                 if(autocvar_spawn_debug >= 2)
1060                 {
1061                         entity otheritem;
1062                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1063                         {
1064                             // why not flags & fl_item?
1065                                 if(otheritem.is_item)
1066                                 {
1067                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1068                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1069                                         error("Mapper sucks.");
1070                                 }
1071                         }
1072                         self.is_item = true;
1073                 }
1074
1075                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1076
1077                 precache_model (self.model);
1078                 precache_sound (self.item_pickupsound);
1079
1080                 precache_sound ("misc/itemrespawncountdown.wav");
1081                 if(itemid == IT_STRENGTH)
1082                         precache_sound ("misc/strength_respawn.wav");
1083                 else if(itemid == IT_INVINCIBLE)
1084                         precache_sound ("misc/shield_respawn.wav");
1085                 else
1086                         precache_sound ("misc/itemrespawn.wav");
1087
1088                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1089                         self.target = "###item###"; // for finding the nearest item using find()
1090         }
1091
1092         self.bot_pickup = true;
1093         self.bot_pickupevalfunc = pickupevalfunc;
1094         self.bot_pickupbasevalue = pickupbasevalue;
1095         self.mdl = self.model;
1096         self.netname = itemname;
1097         self.touch = Item_Touch;
1098         setmodel(self, "null"); // precision set below
1099         //self.effects |= EF_LOWPRECISION;
1100
1101         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1102     {
1103         self.pos1 = '-16 -16 0';
1104         self.pos2 = '16 16 48';
1105     }
1106         else
1107     {
1108         self.pos1 = '-16 -16 0';
1109         self.pos2 = '16 16 32';
1110     }
1111     setsize (self, self.pos1, self.pos2);
1112
1113     if(itemflags & FL_POWERUP)
1114         self.ItemStatus |= ITS_ANIMATE1;
1115
1116         if(self.armorvalue || self.health)
1117         self.ItemStatus |= ITS_ANIMATE2;
1118
1119         if(itemflags & FL_WEAPON)
1120         {
1121                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1122             self.colormap = 1024; // color shirt=0 pants=0 grey
1123         else
1124             self.gravity = 1;
1125
1126                 self.ItemStatus |= ITS_ANIMATE1;
1127                 self.ItemStatus |= ISF_COLORMAP;
1128         }
1129
1130         self.state = 0;
1131         if(self.team) // broken, no idea why.
1132         {
1133                 if(!self.cnt)
1134                         self.cnt = 1; // item probability weight
1135
1136                 self.effects |= EF_NODRAW; // marker for item team search
1137                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1138         }
1139         else
1140                 Item_Reset();
1141
1142     Net_LinkEntity(self, false, 0, ItemSend);
1143
1144         self.SendFlags |= ISF_SIZE;
1145         if(self.angles)
1146                 self.SendFlags |= ISF_ANGLES;
1147
1148         // call this hook after everything else has been done
1149         if(MUTATOR_CALLHOOK(Item_Spawn))
1150         {
1151                 startitem_failed = true;
1152                 remove(self);
1153                 return;
1154         }
1155 }
1156
1157 void StartItemA (entity a)
1158 {
1159     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1160 }
1161
1162 void spawnfunc_item_rockets (void) {
1163         if(!self.ammo_rockets)
1164                 self.ammo_rockets = g_pickup_rockets;
1165         if(!self.pickup_anyway)
1166                 self.pickup_anyway = g_pickup_ammo_anyway;
1167     StartItemA (ITEM_Rockets);
1168 }
1169
1170 void spawnfunc_item_bullets (void) {
1171         if(!weaponswapping)
1172         if(autocvar_sv_q3acompat_machineshotgunswap)
1173         if(self.classname != "droppedweapon")
1174         {
1175                 weaponswapping = true;
1176                 spawnfunc_item_shells();
1177                 weaponswapping = false;
1178                 return;
1179         }
1180
1181         if(!self.ammo_nails)
1182                 self.ammo_nails = g_pickup_nails;
1183         if(!self.pickup_anyway)
1184                 self.pickup_anyway = g_pickup_ammo_anyway;
1185     StartItemA (ITEM_Bullets);
1186 }
1187
1188 void spawnfunc_item_cells (void) {
1189         if(!self.ammo_cells)
1190                 self.ammo_cells = g_pickup_cells;
1191         if(!self.pickup_anyway)
1192                 self.pickup_anyway = g_pickup_ammo_anyway;
1193         StartItemA (ITEM_Cells);
1194 }
1195
1196 void spawnfunc_item_plasma()
1197 {
1198         if(!self.ammo_plasma)
1199                 self.ammo_plasma = g_pickup_plasma;
1200         if(!self.pickup_anyway)
1201                 self.pickup_anyway = g_pickup_ammo_anyway;
1202         StartItemA (ITEM_Plasma);
1203 }
1204
1205 void spawnfunc_item_shells (void) {
1206         if(!weaponswapping)
1207         if(autocvar_sv_q3acompat_machineshotgunswap)
1208         if(self.classname != "droppedweapon")
1209         {
1210                 weaponswapping = true;
1211                 spawnfunc_item_bullets();
1212                 weaponswapping = false;
1213                 return;
1214         }
1215
1216         if(!self.ammo_shells)
1217                 self.ammo_shells = g_pickup_shells;
1218         if(!self.pickup_anyway)
1219                 self.pickup_anyway = g_pickup_ammo_anyway;
1220         StartItemA (ITEM_Shells);
1221 }
1222
1223 void spawnfunc_item_armor_small (void) {
1224         if(!self.armorvalue)
1225                 self.armorvalue = g_pickup_armorsmall;
1226         if(!self.max_armorvalue)
1227                 self.max_armorvalue = g_pickup_armorsmall_max;
1228         if(!self.pickup_anyway)
1229                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1230         StartItemA (ITEM_ArmorSmall);
1231 }
1232
1233 void spawnfunc_item_armor_medium (void) {
1234         if(!self.armorvalue)
1235                 self.armorvalue = g_pickup_armormedium;
1236         if(!self.max_armorvalue)
1237                 self.max_armorvalue = g_pickup_armormedium_max;
1238         if(!self.pickup_anyway)
1239                 self.pickup_anyway = g_pickup_armormedium_anyway;
1240         StartItemA (ITEM_ArmorMedium);
1241 }
1242
1243 void spawnfunc_item_armor_big (void) {
1244         if(!self.armorvalue)
1245                 self.armorvalue = g_pickup_armorbig;
1246         if(!self.max_armorvalue)
1247                 self.max_armorvalue = g_pickup_armorbig_max;
1248         if(!self.pickup_anyway)
1249                 self.pickup_anyway = g_pickup_armorbig_anyway;
1250         StartItemA (ITEM_ArmorBig);
1251 }
1252
1253 void spawnfunc_item_armor_large (void) {
1254         if(!self.armorvalue)
1255                 self.armorvalue = g_pickup_armorlarge;
1256         if(!self.max_armorvalue)
1257                 self.max_armorvalue = g_pickup_armorlarge_max;
1258         if(!self.pickup_anyway)
1259                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1260         StartItemA (ITEM_ArmorLarge);
1261 }
1262
1263 void spawnfunc_item_health_small (void) {
1264         if(!self.max_health)
1265                 self.max_health = g_pickup_healthsmall_max;
1266         if(!self.health)
1267                 self.health = g_pickup_healthsmall;
1268         if(!self.pickup_anyway)
1269                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1270         StartItemA (ITEM_HealthSmall);
1271 }
1272
1273 void spawnfunc_item_health_medium (void) {
1274         if(!self.max_health)
1275                 self.max_health = g_pickup_healthmedium_max;
1276         if(!self.health)
1277                 self.health = g_pickup_healthmedium;
1278         if(!self.pickup_anyway)
1279                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1280     StartItemA (ITEM_HealthMedium);
1281 }
1282
1283 void spawnfunc_item_health_large (void) {
1284         if(!self.max_health)
1285                 self.max_health = g_pickup_healthlarge_max;
1286         if(!self.health)
1287                 self.health = g_pickup_healthlarge;
1288         if(!self.pickup_anyway)
1289                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1290         StartItemA (ITEM_HealthLarge);
1291 }
1292
1293 void spawnfunc_item_health_mega (void) {
1294     if(!self.max_health)
1295         self.max_health = g_pickup_healthmega_max;
1296     if(!self.health)
1297         self.health = g_pickup_healthmega;
1298     if(!self.pickup_anyway)
1299         self.pickup_anyway = g_pickup_healthmega_anyway;
1300     StartItemA (ITEM_HealthMega);
1301 }
1302
1303 // support old misnamed entities
1304 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1305 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1306 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1307 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1308 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1309
1310 void spawnfunc_item_strength (void) {
1311                 precache_sound("weapons/strength_fire.wav");
1312                 if(!self.strength_finished)
1313                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1314                 StartItemA (ITEM_Strength);
1315 }
1316
1317 void spawnfunc_item_invincible (void) {
1318                 if(!self.invincible_finished)
1319                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1320                 StartItemA (ITEM_Shield);
1321 }
1322
1323 // compatibility:
1324 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1325
1326 void target_items_use (void)
1327 {
1328         if(activator.classname == "droppedweapon")
1329         {
1330                 EXACTTRIGGER_TOUCH;
1331                 remove(activator);
1332                 return;
1333         }
1334
1335         if (!IS_PLAYER(activator))
1336                 return;
1337         if(activator.deadflag != DEAD_NO)
1338                 return;
1339         EXACTTRIGGER_TOUCH;
1340
1341         entity e;
1342         for(e = world; (e = find(e, classname, "droppedweapon")); )
1343                 if(e.enemy == activator)
1344                         remove(e);
1345
1346         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1347                 centerprint(activator, self.message);
1348 }
1349
1350 void spawnfunc_target_items (void)
1351 {
1352         float n, i, j;
1353         entity e;
1354         string s;
1355
1356         self.use = target_items_use;
1357         if(!self.strength_finished)
1358                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1359         if(!self.invincible_finished)
1360                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1361         if(!self.superweapons_finished)
1362                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1363
1364         precache_sound("misc/itempickup.wav");
1365         precache_sound("misc/megahealth.wav");
1366         precache_sound("misc/armor25.wav");
1367         precache_sound("misc/powerup.wav");
1368         precache_sound("misc/poweroff.wav");
1369         precache_sound("weapons/weaponpickup.wav");
1370
1371         n = tokenize_console(self.netname);
1372         if(argv(0) == "give")
1373         {
1374                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1375         }
1376         else
1377         {
1378                 for(i = 0; i < n; ++i)
1379                 {
1380                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1381                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1382                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1383                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1384                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1385                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1386                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1387                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1388                         else
1389                         {
1390                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1391                                 {
1392                                         e = get_weaponinfo(j);
1393                                         s = W_UndeprecateName(argv(i));
1394                                         if(s == e.netname)
1395                                         {
1396                                                 self.weapons |= WepSet_FromWeapon(j);
1397                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1398                                                         WEP_ACTION(e.weapon, WR_INIT);
1399                                                 break;
1400                                         }
1401                                 }
1402                                 if(j > WEP_LAST)
1403                                         print("target_items: invalid item ", argv(i), "\n");
1404                         }
1405                 }
1406
1407                 string itemprefix, valueprefix;
1408                 if(self.spawnflags == 0)
1409                 {
1410                         itemprefix = "";
1411                         valueprefix = "";
1412                 }
1413                 else if(self.spawnflags == 1)
1414                 {
1415                         itemprefix = "max ";
1416                         valueprefix = "max ";
1417                 }
1418                 else if(self.spawnflags == 2)
1419                 {
1420                         itemprefix = "min ";
1421                         valueprefix = "min ";
1422                 }
1423                 else if(self.spawnflags == 4)
1424                 {
1425                         itemprefix = "minus ";
1426                         valueprefix = "max ";
1427                 }
1428                 else
1429                 {
1430                         error("invalid spawnflags");
1431                         itemprefix = valueprefix = string_null;
1432                 }
1433
1434                 self.netname = "";
1435                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1436                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1437                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1438                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1439                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1440                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1441                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1442                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1443                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1444                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1445                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1446                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1447                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1448                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1449                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1450                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1451                 {
1452                         e = get_weaponinfo(j);
1453                         if(e.weapon)
1454                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1455                 }
1456         }
1457         self.netname = strzone(self.netname);
1458         //print(self.netname, "\n");
1459
1460         n = tokenize_console(self.netname);
1461         for(i = 0; i < n; ++i)
1462         {
1463                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1464                 {
1465                         e = get_weaponinfo(j);
1466                         if(argv(i) == e.netname)
1467                         {
1468                                 WEP_ACTION(e.weapon, WR_INIT);
1469                                 break;
1470                         }
1471                 }
1472         }
1473 }
1474
1475 void spawnfunc_item_fuel(void)
1476 {
1477         if(!self.ammo_fuel)
1478                 self.ammo_fuel = g_pickup_fuel;
1479         if(!self.pickup_anyway)
1480                 self.pickup_anyway = g_pickup_ammo_anyway;
1481         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1482 }
1483
1484 void spawnfunc_item_fuel_regen(void)
1485 {
1486         if(start_items & IT_FUEL_REGEN)
1487         {
1488                 spawnfunc_item_fuel();
1489                 return;
1490         }
1491         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1492 }
1493
1494 void spawnfunc_item_jetpack(void)
1495 {
1496         if(!self.ammo_fuel)
1497                 self.ammo_fuel = g_pickup_fuel_jetpack;
1498         if(start_items & IT_JETPACK)
1499         {
1500                 spawnfunc_item_fuel();
1501                 return;
1502         }
1503         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1504 }
1505
1506 float GiveWeapon(entity e, float wpn, float op, float val)
1507 {
1508         WepSet v0, v1;
1509         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1510         switch(op)
1511         {
1512                 case OP_SET:
1513                         if(val > 0)
1514                                 e.weapons |= WepSet_FromWeapon(wpn);
1515                         else
1516                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1517                         break;
1518                 case OP_MIN:
1519                 case OP_PLUS:
1520                         if(val > 0)
1521                                 e.weapons |= WepSet_FromWeapon(wpn);
1522                         break;
1523                 case OP_MAX:
1524                         if(val <= 0)
1525                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1526                         break;
1527                 case OP_MINUS:
1528                         if(val > 0)
1529                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1530                         break;
1531         }
1532         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1533         return (v0 != v1);
1534 }
1535
1536 float GiveBit(entity e, .float fld, float bit, float op, float val)
1537 {
1538         float v0, v1;
1539         v0 = (e.(fld) & bit);
1540         switch(op)
1541         {
1542                 case OP_SET:
1543                         if(val > 0)
1544                                 e.(fld) |= bit;
1545                         else
1546                                 e.(fld) &= ~bit;
1547                         break;
1548                 case OP_MIN:
1549                 case OP_PLUS:
1550                         if(val > 0)
1551                                 e.(fld) |= bit;
1552                         break;
1553                 case OP_MAX:
1554                         if(val <= 0)
1555                                 e.(fld) &= ~bit;
1556                         break;
1557                 case OP_MINUS:
1558                         if(val > 0)
1559                                 e.(fld) &= ~bit;
1560                         break;
1561         }
1562         v1 = (e.(fld) & bit);
1563         return (v0 != v1);
1564 }
1565
1566 float GiveValue(entity e, .float fld, float op, float val)
1567 {
1568         float v0, v1;
1569         v0 = e.(fld);
1570         switch(op)
1571         {
1572                 case OP_SET:
1573                         e.(fld) = val;
1574                         break;
1575                 case OP_MIN:
1576                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1577                         break;
1578                 case OP_MAX:
1579                         e.(fld) = min(e.(fld), val);
1580                         break;
1581                 case OP_PLUS:
1582                         e.(fld) += val;
1583                         break;
1584                 case OP_MINUS:
1585                         e.(fld) -= val;
1586                         break;
1587         }
1588         v1 = e.(fld);
1589         return (v0 != v1);
1590 }
1591
1592 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1593 {
1594         if(v1 == v0)
1595                 return;
1596         if(v1 <= v0 - t)
1597         {
1598                 if(snd_decr != "")
1599                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1600         }
1601         else if(v0 >= v0 + t)
1602         {
1603                 if(snd_incr != "")
1604                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1605         }
1606 }
1607
1608 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1609 {
1610         if(v0 < v1)
1611                 e.(rotfield) = max(e.(rotfield), time + rottime);
1612         else if(v0 > v1)
1613                 e.(regenfield) = max(e.(regenfield), time + regentime);
1614 }
1615 float GiveItems(entity e, float beginarg, float endarg)
1616 {
1617         float got, i, j, val, op;
1618         float _switchweapon;
1619         entity wi;
1620         string cmd;
1621
1622         val = 999;
1623         op = OP_SET;
1624
1625         got = 0;
1626
1627         _switchweapon = false;
1628         if (e.autoswitch)
1629                 if (e.switchweapon == w_getbestweapon(e))
1630                         _switchweapon = true;
1631
1632         e.strength_finished = max(0, e.strength_finished - time);
1633         e.invincible_finished = max(0, e.invincible_finished - time);
1634         e.superweapons_finished = max(0, e.superweapons_finished - time);
1635
1636         PREGIVE(e, items);
1637         PREGIVE_WEAPONS(e);
1638         PREGIVE(e, strength_finished);
1639         PREGIVE(e, invincible_finished);
1640         PREGIVE(e, superweapons_finished);
1641         PREGIVE(e, ammo_nails);
1642         PREGIVE(e, ammo_cells);
1643         PREGIVE(e, ammo_plasma);
1644         PREGIVE(e, ammo_shells);
1645         PREGIVE(e, ammo_rockets);
1646         PREGIVE(e, ammo_fuel);
1647         PREGIVE(e, armorvalue);
1648         PREGIVE(e, health);
1649
1650         for(i = beginarg; i < endarg; ++i)
1651         {
1652                 cmd = argv(i);
1653
1654                 if(cmd == "0" || stof(cmd))
1655                 {
1656                         val = stof(cmd);
1657                         continue;
1658                 }
1659                 switch(cmd)
1660                 {
1661                         case "no":
1662                                 op = OP_MAX;
1663                                 val = 0;
1664                                 continue;
1665                         case "max":
1666                                 op = OP_MAX;
1667                                 continue;
1668                         case "min":
1669                                 op = OP_MIN;
1670                                 continue;
1671                         case "plus":
1672                                 op = OP_PLUS;
1673                                 continue;
1674                         case "minus":
1675                                 op = OP_MINUS;
1676                                 continue;
1677                         case "ALL":
1678                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1679                                 got += GiveValue(e, strength_finished, op, val);
1680                                 got += GiveValue(e, invincible_finished, op, val);
1681                                 got += GiveValue(e, superweapons_finished, op, val);
1682                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1683                         case "all":
1684                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1685                                 got += GiveValue(e, health, op, val);
1686                                 got += GiveValue(e, armorvalue, op, val);
1687                         case "allweapons":
1688                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1689                                 {
1690                                         wi = get_weaponinfo(j);
1691                                         if(wi.weapon)
1692                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1693                                                         got += GiveWeapon(e, j, op, val);
1694                                 }
1695                         case "allammo":
1696                                 got += GiveValue(e, ammo_cells, op, val);
1697                                 got += GiveValue(e, ammo_plasma, op, val);
1698                                 got += GiveValue(e, ammo_shells, op, val);
1699                                 got += GiveValue(e, ammo_nails, op, val);
1700                                 got += GiveValue(e, ammo_rockets, op, val);
1701                                 got += GiveValue(e, ammo_fuel, op, val);
1702                                 break;
1703                         case "unlimited_ammo":
1704                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1705                                 break;
1706                         case "unlimited_weapon_ammo":
1707                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1708                                 break;
1709                         case "unlimited_superweapons":
1710                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1711                                 break;
1712                         case "jetpack":
1713                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1714                                 break;
1715                         case "fuel_regen":
1716                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1717                                 break;
1718                         case "strength":
1719                                 got += GiveValue(e, strength_finished, op, val);
1720                                 break;
1721                         case "invincible":
1722                                 got += GiveValue(e, invincible_finished, op, val);
1723                                 break;
1724                         case "superweapons":
1725                                 got += GiveValue(e, superweapons_finished, op, val);
1726                                 break;
1727                         case "cells":
1728                                 got += GiveValue(e, ammo_cells, op, val);
1729                                 break;
1730                         case "plasma":
1731                                 got += GiveValue(e, ammo_plasma, op, val);
1732                                 break;
1733                         case "shells":
1734                                 got += GiveValue(e, ammo_shells, op, val);
1735                                 break;
1736                         case "nails":
1737                         case "bullets":
1738                                 got += GiveValue(e, ammo_nails, op, val);
1739                                 break;
1740                         case "rockets":
1741                                 got += GiveValue(e, ammo_rockets, op, val);
1742                                 break;
1743                         case "health":
1744                                 got += GiveValue(e, health, op, val);
1745                                 break;
1746                         case "armor":
1747                                 got += GiveValue(e, armorvalue, op, val);
1748                                 break;
1749                         case "fuel":
1750                                 got += GiveValue(e, ammo_fuel, op, val);
1751                                 break;
1752                         default:
1753                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1754                                 {
1755                                         wi = get_weaponinfo(j);
1756                                         if(cmd == wi.netname)
1757                                         {
1758                                                 got += GiveWeapon(e, j, op, val);
1759                                                 break;
1760                                         }
1761                                 }
1762                                 if(j > WEP_LAST)
1763                                         print("give: invalid item ", cmd, "\n");
1764                                 break;
1765                 }
1766                 val = 999;
1767                 op = OP_SET;
1768         }
1769
1770         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1771         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1772         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1773         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1774         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1775         {
1776                 wi = get_weaponinfo(j);
1777                 if(wi.weapon)
1778                 {
1779                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1780                         if (!(save_weapons & WepSet_FromWeapon(j)))
1781                                 if(e.weapons & WepSet_FromWeapon(j))
1782                                         WEP_ACTION(wi.weapon, WR_INIT);
1783                 }
1784         }
1785         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1786         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1787         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1788         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1789         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1790         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1791         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1792         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1793         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1794         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1795
1796         if(e.superweapons_finished <= 0)
1797                 if(self.weapons & WEPSET_SUPERWEAPONS)
1798                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1799
1800         if(e.strength_finished <= 0)
1801                 e.strength_finished = 0;
1802         else
1803                 e.strength_finished += time;
1804         if(e.invincible_finished <= 0)
1805                 e.invincible_finished = 0;
1806         else
1807                 e.invincible_finished += time;
1808         if(e.superweapons_finished <= 0)
1809                 e.superweapons_finished = 0;
1810         else
1811                 e.superweapons_finished += time;
1812
1813         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1814                 _switchweapon = true;
1815         if(_switchweapon)
1816                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1817
1818         return got;
1819 }
1820 #endif