qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb = '1 0 1';
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         player.health = 100;
 382                 }
 383
 384                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 385                 {
 386                         pickedup = TRUE;
 387                         player.items |= it;
 388                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 389                 }
 390
 391                 // extralife powerup
 392                 if (item.max_health)
 393                 {
 394                         pickedup = TRUE;
 395                         // sound not available
 396                         // AnnounceTo(player, "_lives");
 397                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 398                         sprint(player, "^3You picked up some extra lives\n");
 399                 }
 400
 401                 // invis powerup
 402                 if (item.strength_finished)
 403                 {
 404                         pickedup = TRUE;
 405                         // sound not available
 406                         // AnnounceTo(player, "invisible");
 407                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 408                 }
 409
 410                 // speed powerup
 411                 if (item.invincible_finished)
 412                 {
 413                         pickedup = TRUE;
 414                         // sound not available
 415                         // AnnounceTo(player, "speed");
 416                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 417                 }
 418         }
 419         else
 420         {
 421                 // in case the player has autoswitch enabled do the following:
 422                 // if the player is using their best weapon before items are given, they
 423                 // probably want to switch to an even better weapon after items are given
 424                 if (player.autoswitch)
 425                 if (player.switchweapon == w_getbestweapon(player))
 426                         _switchweapon = TRUE;
 427
 428                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 429                         _switchweapon = TRUE;
 430
 431                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 432                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 437                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 438
 439                 if (item.flags & FL_WEAPON)
 440                 {
 441                         WEPSET_DECLARE_A(it);
 442                         WEPSET_COPY_AE(it, item);
 443                         WEPSET_ANDNOT_AE(it, player);
 444
 445                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 446                         {
 447                                 pickedup = TRUE;
 448                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 449                                         if(WEPSET_CONTAINS_AW(it, i))
 450                                                 W_GiveWeapon (player, i, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         if (_switchweapon)
 487                 if (player.switchweapon != w_getbestweapon(player))
 488                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 489
 490         return 1;
 491 }
 492
 493 void Item_Touch (void)
 494 {
 495         entity e, head;
 496
 497         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 498         if(self.classname == "droppedweapon")
 499         {
 500                 if (ITEM_TOUCH_NEEDKILL())
 501                 {
 502                         remove(self);
 503                         return;
 504                 }
 505         }
 506
 507         if (other.classname != "player")
 508                 return;
 509         if (other.deadflag)
 510                 return;
 511         if (self.solid != SOLID_TRIGGER)
 512                 return;
 513         if (self.owner == other)
 514                 return;
 515
 516         if (self.classname == "droppedweapon")
 517         {
 518                 self.strength_finished = max(0, self.strength_finished - time);
 519                 self.invincible_finished = max(0, self.invincible_finished - time);
 520                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 521         }
 522
 523         if(!Item_GiveTo(self, other))
 524         {
 525                 if (self.classname == "droppedweapon")
 526                 {
 527                         // undo what we did above
 528                         self.strength_finished += time;
 529                         self.invincible_finished += time;
 530                         self.superweapons_finished += time;
 531                 }
 532                 return;
 533         }
 534
 535         other.last_pickup = time;
 536
 537         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 538         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 539
 540         if (self.classname == "droppedweapon")
 541                 remove (self);
 542         else if not(self.spawnshieldtime)
 543                 return;
 544         else
 545         {
 546                 if(self.team)
 547                 {
 548                         RandomSelection_Init();
 549                         for(head = world; (head = findfloat(head, team, self.team)); )
 550                         {
 551                                 if(head.flags & FL_ITEM)
 552                                 {
 553                                         Item_Show(head, -1);
 554                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 555                                 }
 556                         }
 557                         e = RandomSelection_chosen_ent;
 558                 }
 559                 else
 560                         e = self;
 561                 Item_ScheduleRespawn(e);
 562         }
 563 }
 564
 565 void Item_Reset()
 566 {
 567         Item_Show(self, !self.state);
 568         setorigin (self, self.origin);
 569
 570         if(self.classname != "droppedweapon")
 571         {
 572                 self.think = SUB_Null;
 573                 self.nextthink = 0;
 574
 575                 if(self.waypointsprite_attached)
 576                         WaypointSprite_Kill(self.waypointsprite_attached);
 577
 578                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 579                         Item_ScheduleInitialRespawn(self);
 580         }
 581 }
 582
 583 void Item_FindTeam()
 584 {
 585         entity head, e;
 586
 587         if(self.effects & EF_NODRAW)
 588         {
 589                 // marker for item team search
 590                 dprint("Initializing item team ", ftos(self.team), "\n");
 591                 RandomSelection_Init();
 592                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 593                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 594                 e = RandomSelection_chosen_ent;
 595                 e.state = 0;
 596                 Item_Show(e, 1);
 597
 598                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 599                 {
 600                         if(head != e)
 601                         {
 602                                 // make it a non-spawned item
 603                                 Item_Show(head, -1);
 604                                 head.state = 1; // state 1 = initially hidden item
 605                         }
 606                         head.effects &~= EF_NODRAW;
 607                 }
 608
 609                 Item_Reset();
 610         }
 611 }
 612
 613 // Savage: used for item garbage-collection
 614 // TODO: perhaps nice special effect?
 615 void RemoveItem(void)
 616 {
 617         remove(self);
 618 }
 619
 620 // pickup evaluation functions
 621 // these functions decide how desirable an item is to the bots
 622
 623 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 624
 625 float weapon_pickupevalfunc(entity player, entity item)
 626 {
 627         float c, j, position;
 628
 629         // See if I have it already
 630         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 631         {
 632                 // If I can pick it up
 633                 if(!item.spawnshieldtime)
 634                         c = 0;
 635                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 636                 {
 637                         // Skilled bots will grab more
 638                         c = bound(0, skill / 10, 1) * 0.5;
 639                 }
 640                 else
 641                         c = 0;
 642         }
 643         else
 644                 c = 1;
 645
 646         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 647         if( bot_custom_weapon && c )
 648         {
 649                 // Find the highest position on any range
 650                 position = -1;
 651                 for(j = 0; j < WEP_LAST ; ++j){
 652                         if(
 653                                         bot_weapons_far[j] == item.weapon ||
 654                                         bot_weapons_mid[j] == item.weapon ||
 655                                         bot_weapons_close[j] == item.weapon
 656                           )
 657                         {
 658                                 position = j;
 659                                 break;
 660                         }
 661                 }
 662
 663                 // Rate it
 664                 if (position >= 0 )
 665                 {
 666                         position = WEP_LAST - position;
 667                         // item.bot_pickupbasevalue is overwritten here
 668                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 669                 }
 670         }
 671
 672         return item.bot_pickupbasevalue * c;
 673 }
 674
 675 float commodity_pickupevalfunc(entity player, entity item)
 676 {
 677         float c, i;
 678         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 679         entity wi;
 680         c = 0;
 681
 682         // Detect needed ammo
 683         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 684         {
 685                 wi = get_weaponinfo(i);
 686
 687                 if not(WEPSET_CONTAINS_EW(player, i))
 688                         continue;
 689
 690                 if(wi.items & IT_SHELLS)
 691                         need_shells = TRUE;
 692                 else if(wi.items & IT_NAILS)
 693                         need_nails = TRUE;
 694                 else if(wi.items & IT_ROCKETS)
 695                         need_rockets = TRUE;
 696                 else if(wi.items & IT_CELLS)
 697                         need_cells = TRUE;
 698                 else if(wi.items & IT_FUEL)
 699                         need_cells = TRUE;
 700         }
 701
 702         // TODO: figure out if the player even has the weapon this ammo is for?
 703         // may not affect strategy much though...
 704         // find out how much more ammo/armor/health the player can hold
 705         if (need_shells)
 706         if (item.ammo_shells)
 707         if (player.ammo_shells < g_pickup_shells_max)
 708                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 709         if (need_nails)
 710         if (item.ammo_nails)
 711         if (player.ammo_nails < g_pickup_nails_max)
 712                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 713         if (need_rockets)
 714         if (item.ammo_rockets)
 715         if (player.ammo_rockets < g_pickup_rockets_max)
 716                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 717         if (need_cells)
 718         if (item.ammo_cells)
 719         if (player.ammo_cells < g_pickup_cells_max)
 720                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 721         if (need_fuel)
 722         if (item.ammo_fuel)
 723         if (player.ammo_fuel < g_pickup_fuel_max)
 724                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 725         if (item.armorvalue)
 726         if (player.armorvalue < item.max_armorvalue)
 727                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 728         if (item.health)
 729         if (player.health < item.max_health)
 730                 c = c + max(0, 1 - player.health / item.max_health);
 731
 732         return item.bot_pickupbasevalue * c;
 733 }
 734
 735 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 736 {
 737         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 738                 RemoveItem();
 739 }
 740
 741 .float is_item;
 742 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 743 {
 744         startitem_failed = FALSE;
 745
 746         if(self.model == "")
 747                 self.model = itemmodel;
 748         if(self.item_pickupsound == "")
 749                 self.item_pickupsound = pickupsound;
 750         if(!self.respawntime) // both need to be set
 751         {
 752                 self.respawntime = defaultrespawntime;
 753                 self.respawntimejitter = defaultrespawntimejitter;
 754         }
 755
 756         self.items = itemid;
 757         self.weapon = weaponid;
 758
 759         if(weaponid)
 760                 WEPSET_COPY_EW(self, weaponid);
 761         self.flags = FL_ITEM | itemflags;
 762
 763         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 764         {
 765                 startitem_failed = TRUE;
 766                 remove(self);
 767                 return;
 768         }
 769
 770         // is it a dropped weapon?
 771         if (self.classname == "droppedweapon")
 772         {
 773                 self.reset = SUB_Remove;
 774                 // it's a dropped weapon
 775                 self.movetype = MOVETYPE_TOSS;
 776
 777                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 778                 self.think = RemoveItem;
 779                 self.nextthink = time + 20;
 780
 781                 self.takedamage = DAMAGE_YES;
 782                 self.event_damage = Item_Damage;
 783
 784                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 785                 /*
 786                 if(self.items == 0)
 787                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 788                 if(self.ammo_nails == 0)
 789                 if(self.ammo_cells == 0)
 790                 if(self.ammo_rockets == 0)
 791                 if(self.ammo_shells == 0)
 792                 if(self.ammo_fuel == 0)
 793                 if(self.health == 0)
 794                 if(self.armorvalue == 0)
 795                 */
 796                 {
 797                         // if item is worthless after a timer, have it expire then
 798                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 799                 }
 800
 801                 // don't drop if in a NODROP zone (such as lava)
 802                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 803                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove(self);
 807                         return;
 808                 }
 809         }
 810         else
 811         {
 812                 if(!have_pickup_item())
 813                 {
 814                         startitem_failed = TRUE;
 815                         remove (self);
 816                         return;
 817                 }
 818
 819                 self.reset = Item_Reset;
 820                 // it's a level item
 821                 if(self.spawnflags & 1)
 822                         self.noalign = 1;
 823                 if (self.noalign)
 824                         self.movetype = MOVETYPE_NONE;
 825                 else
 826                         self.movetype = MOVETYPE_TOSS;
 827                 // do item filtering according to game mode and other things
 828                 if (!self.noalign)
 829                 {
 830                         // first nudge it off the floor a little bit to avoid math errors
 831                         setorigin(self, self.origin + '0 0 1');
 832                         // set item size before we spawn a spawnfunc_waypoint
 833                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 834                                 setsize (self, '-16 -16 0', '16 16 48');
 835                         else
 836                                 setsize (self, '-16 -16 0', '16 16 32');
 837                         // note droptofloor returns FALSE if stuck/or would fall too far
 838                         droptofloor();
 839                         waypoint_spawnforitem(self);
 840                 }
 841
 842                 /*
 843                  * can't do it that way, as it would break maps
 844                  * TODO make a target_give like entity another way, that perhaps has
 845                  * the weapon name in a key
 846                 if(self.targetname)
 847                 {
 848                         // target_give not yet supported; maybe later
 849                         print("removed targeted ", self.classname, "\n");
 850                         startitem_failed = TRUE;
 851                         remove (self);
 852                         return;
 853                 }
 854                 */
 855
 856                 if(autocvar_spawn_debug >= 2)
 857                 {
 858                         entity otheritem;
 859                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 860                         {
 861                                 if(otheritem.is_item)
 862                                 {
 863                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 864                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 865                                         error("Mapper sucks.");
 866                                 }
 867                         }
 868                         self.is_item = TRUE;
 869                 }
 870
 871                 WEPSET_OR_AW(weaponsInMap, weaponid);
 872
 873                 precache_model (self.model);
 874                 precache_sound (self.item_pickupsound);
 875
 876                 precache_sound ("misc/itemrespawncountdown.wav");
 877                 if(!g_minstagib && itemid == IT_STRENGTH)
 878                         precache_sound ("misc/strength_respawn.wav");
 879                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 880                         precache_sound ("misc/shield_respawn.wav");
 881                 else
 882                         precache_sound ("misc/itemrespawn.wav");
 883
 884                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 885                         self.target = "###item###"; // for finding the nearest item using find()
 886         }
 887
 888         self.bot_pickup = TRUE;
 889         self.bot_pickupevalfunc = pickupevalfunc;
 890         self.bot_pickupbasevalue = pickupbasevalue;
 891         self.mdl = self.model;
 892         self.netname = itemname;
 893         self.touch = Item_Touch;
 894         setmodel (self, self.mdl); // precision set below
 895         self.effects |= EF_LOWPRECISION;
 896         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 897                 setsize (self, '-16 -16 0', '16 16 48');
 898         else
 899                 setsize (self, '-16 -16 0', '16 16 32');
 900         if(itemflags & FL_WEAPON)
 901                 self.modelflags |= MF_ROTATE;
 902
 903         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 904         if (itemflags & FL_WEAPON)
 905         {
 906                 // neutral team color for pickup weapons
 907                 self.colormap = 1024; // color shirt=0 pants=0 grey
 908         }
 909
 910         self.state = 0;
 911         if(self.team)
 912         {
 913                 if(!self.cnt)
 914                         self.cnt = 1; // item probability weight
 915                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 916                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 917         }
 918         else
 919                 Item_Reset();
 920
 921         // call this hook after everything else has been done
 922         if(MUTATOR_CALLHOOK(Item_Spawn))
 923         {
 924                 startitem_failed = TRUE;
 925                 remove(self);
 926                 return;
 927         }
 928 }
 929
 930 /* replace items in minstagib
 931  * IT_STRENGTH   = invisibility
 932  * IT_NAILS      = extra lives
 933  * IT_INVINCIBLE = speed
 934  */
 935 void minstagib_items (float itemid)
 936 {
 937         float rnd;
 938         self.classname = "minstagib";
 939
 940         // replace rocket launchers and nex guns with ammo cells
 941         if (itemid == IT_CELLS)
 942         {
 943                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 944                 StartItem ("models/items/a_cells.md3",
 945                         "misc/itempickup.wav", 45, 0,
 946                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 947                 return;
 948         }
 949
 950         // randomize
 951         rnd = random() * 3;
 952         if (rnd <= 1)
 953                 itemid = IT_STRENGTH;
 954         else if (rnd <= 2)
 955                 itemid = IT_NAILS;
 956         else
 957                 itemid = IT_INVINCIBLE;
 958
 959         // replace with invis
 960         if (itemid == IT_STRENGTH)
 961         {
 962                 if(!self.strength_finished)
 963                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 964                 StartItem ("models/items/g_strength.md3",
 965                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 966                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 967         }
 968         // replace with extra lives
 969         if (itemid == IT_NAILS)
 970         {
 971                 self.max_health = 1;
 972                 StartItem ("models/items/g_h100.md3",
 973                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 974                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 975         }
 976         // replace with speed
 977         if (itemid == IT_INVINCIBLE)
 978         {
 979                 if(!self.invincible_finished)
 980                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 981                 StartItem ("models/items/g_invincible.md3",
 982                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 983                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 984         }
 985 }
 986
 987 float minst_no_auto_cells;
 988 void minst_remove_item (void) {
 989         if(minst_no_auto_cells)
 990                 remove(self);
 991 }
 992
 993 float weaponswapping;
 994 float internalteam;
 995
 996 void weapon_defaultspawnfunc(float wpn)
 997 {
 998         entity e;
 999         float t;
1000         var .float ammofield;
1001         string s;
1002         entity oldself;
1003         float i, j;
1004         float f;
1005
1006         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1007         {
1008                 e = get_weaponinfo(wpn);
1009
1010                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1011                 {
1012                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1013                         /*
1014                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1015                         startitem_failed = TRUE;
1016                         return;
1017                         */
1018                 }
1019
1020                 s = W_Apply_Weaponreplace(e.netname);
1021                 ret_string = s;
1022                 other = e;
1023                 MUTATOR_CALLHOOK(SetWeaponreplace);
1024                 s = ret_string;
1025                 if(s == "")
1026                 {
1027                         remove(self);
1028                         startitem_failed = TRUE;
1029                         return;
1030                 }
1031                 t = tokenize_console(s);
1032                 if(t >= 2)
1033                 {
1034                         self.team = --internalteam;
1035                         oldself = self;
1036                         for(i = 1; i < t; ++i)
1037                         {
1038                                 s = argv(i);
1039                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                                 {
1041                                         e = get_weaponinfo(j);
1042                                         if(e.netname == s)
1043                                         {
1044                                                 self = spawn();
1045                                                 copyentity(oldself, self);
1046                                                 self.classname = "replacedweapon";
1047                                                 weapon_defaultspawnfunc(j);
1048                                                 break;
1049                                         }
1050                                 }
1051                                 if(j > WEP_LAST)
1052                                 {
1053                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1054                                 }
1055                         }
1056                         self = oldself;
1057                 }
1058                 if(t >= 1) // always the case!
1059                 {
1060                         s = argv(0);
1061                         wpn = 0;
1062                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1063                         {
1064                                 e = get_weaponinfo(j);
1065                                 if(e.netname == s)
1066                                 {
1067                                         wpn = j;
1068                                         break;
1069                                 }
1070                         }
1071                         if(j > WEP_LAST)
1072                         {
1073                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1074                         }
1075                 }
1076                 if(wpn == 0)
1077                 {
1078                         remove(self);
1079                         startitem_failed = TRUE;
1080                         return;
1081                 }
1082         }
1083
1084         e = get_weaponinfo(wpn);
1085
1086         if(!self.respawntime)
1087         {
1088                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1089                 {
1090                         self.respawntime = g_pickup_respawntime_superweapon;
1091                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1092                 }
1093                 else
1094                 {
1095                         self.respawntime = g_pickup_respawntime_weapon;
1096                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1097                 }
1098         }
1099
1100         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1101                 if(!self.superweapons_finished)
1102                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1103
1104         if(e.items)
1105         {
1106                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1107                 {
1108                         if(e.items & j)
1109                         {
1110                                 ammofield = Item_CounterField(j);
1111                                 if(!self.ammofield)
1112                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1113                         }
1114                 }
1115         }
1116
1117         // pickup anyway
1118         if(g_pickup_weapons_anyway)
1119                 self.pickup_anyway = TRUE;
1120
1121         f = FL_WEAPON;
1122
1123         // no weapon-stay on superweapons
1124         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1125                 f |= FL_NO_WEAPON_STAY;
1126
1127         // weapon stay isn't supported for teamed weapons
1128         if(self.team)
1129                 f |= FL_NO_WEAPON_STAY;
1130
1131         // stupid minstagib hack, don't ask
1132         if(g_minstagib)
1133                 if(self.ammo_cells)
1134                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1135
1136         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1137         if (self.modelindex) // don't precache if self was removed
1138                 weapon_action(e.weapon, WR_PRECACHE);
1139 }
1140
1141 void spawnfunc_weapon_shotgun (void);
1142 void spawnfunc_weapon_uzi (void) {
1143         if(autocvar_sv_q3acompat_machineshotgunswap)
1144         if(self.classname != "droppedweapon")
1145         {
1146                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1147                 return;
1148         }
1149         weapon_defaultspawnfunc(WEP_UZI);
1150 }
1151
1152 void spawnfunc_weapon_shotgun (void) {
1153         if(autocvar_sv_q3acompat_machineshotgunswap)
1154         if(self.classname != "droppedweapon")
1155         {
1156                 weapon_defaultspawnfunc(WEP_UZI);
1157                 return;
1158         }
1159         weapon_defaultspawnfunc(WEP_SHOTGUN);
1160 }
1161
1162 void spawnfunc_weapon_nex (void)
1163 {
1164         if (g_minstagib)
1165         {
1166                 minstagib_items(IT_CELLS);
1167                 self.think = minst_remove_item;
1168                 self.nextthink = time;
1169                 return;
1170         }
1171         weapon_defaultspawnfunc(WEP_NEX);
1172 }
1173
1174 void spawnfunc_weapon_minstanex (void)
1175 {
1176         if (g_minstagib)
1177         {
1178                 minstagib_items(IT_CELLS);
1179                 self.think = minst_remove_item;
1180                 self.nextthink = time;
1181                 return;
1182         }
1183         weapon_defaultspawnfunc(WEP_MINSTANEX);
1184 }
1185
1186 void spawnfunc_weapon_rocketlauncher (void)
1187 {
1188         if (g_minstagib)
1189         {
1190                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1191                 self.think = minst_remove_item;
1192                 self.nextthink = time;
1193                 return;
1194         }
1195         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1196 }
1197
1198 void spawnfunc_item_rockets (void) {
1199         if(!self.ammo_rockets)
1200                 self.ammo_rockets = g_pickup_rockets;
1201         if(!self.pickup_anyway)
1202                 self.pickup_anyway = g_pickup_ammo_anyway;
1203         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1204 }
1205
1206 void spawnfunc_item_shells (void);
1207 void spawnfunc_item_bullets (void) {
1208         if(!weaponswapping)
1209         if(autocvar_sv_q3acompat_machineshotgunswap)
1210         if(self.classname != "droppedweapon")
1211         {
1212                 weaponswapping = TRUE;
1213                 spawnfunc_item_shells();
1214                 weaponswapping = FALSE;
1215                 return;
1216         }
1217
1218         if(!self.ammo_nails)
1219                 self.ammo_nails = g_pickup_nails;
1220         if(!self.pickup_anyway)
1221                 self.pickup_anyway = g_pickup_ammo_anyway;
1222         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1223 }
1224
1225 void spawnfunc_item_cells (void) {
1226         if(!self.ammo_cells)
1227                 self.ammo_cells = g_pickup_cells;
1228         if(!self.pickup_anyway)
1229                 self.pickup_anyway = g_pickup_ammo_anyway;
1230         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1231 }
1232
1233 void spawnfunc_item_shells (void) {
1234         if(!weaponswapping)
1235         if(autocvar_sv_q3acompat_machineshotgunswap)
1236         if(self.classname != "droppedweapon")
1237         {
1238                 weaponswapping = TRUE;
1239                 spawnfunc_item_bullets();
1240                 weaponswapping = FALSE;
1241                 return;
1242         }
1243
1244         if(!self.ammo_shells)
1245                 self.ammo_shells = g_pickup_shells;
1246         if(!self.pickup_anyway)
1247                 self.pickup_anyway = g_pickup_ammo_anyway;
1248         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1249 }
1250
1251 void spawnfunc_item_armor_small (void) {
1252         if(!self.armorvalue)
1253                 self.armorvalue = g_pickup_armorsmall;
1254         if(!self.max_armorvalue)
1255                 self.max_armorvalue = g_pickup_armorsmall_max;
1256         if(!self.pickup_anyway)
1257                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1258         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1259 }
1260
1261 void spawnfunc_item_armor_medium (void) {
1262         if(!self.armorvalue)
1263                 self.armorvalue = g_pickup_armormedium;
1264         if(!self.max_armorvalue)
1265                 self.max_armorvalue = g_pickup_armormedium_max;
1266         if(!self.pickup_anyway)
1267                 self.pickup_anyway = g_pickup_armormedium_anyway;
1268         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1269 }
1270
1271 void spawnfunc_item_armor_big (void) {
1272         if(!self.armorvalue)
1273                 self.armorvalue = g_pickup_armorbig;
1274         if(!self.max_armorvalue)
1275                 self.max_armorvalue = g_pickup_armorbig_max;
1276         if(!self.pickup_anyway)
1277                 self.pickup_anyway = g_pickup_armorbig_anyway;
1278         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1279 }
1280
1281 void spawnfunc_item_armor_large (void) {
1282         if(!self.armorvalue)
1283                 self.armorvalue = g_pickup_armorlarge;
1284         if(!self.max_armorvalue)
1285                 self.max_armorvalue = g_pickup_armorlarge_max;
1286         if(!self.pickup_anyway)
1287                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1288         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1289 }
1290
1291 void spawnfunc_item_health_small (void) {
1292         if(!self.max_health)
1293                 self.max_health = g_pickup_healthsmall_max;
1294         if(!self.health)
1295                 self.health = g_pickup_healthsmall;
1296         if(!self.pickup_anyway)
1297                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1298         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1299 }
1300
1301 void spawnfunc_item_health_medium (void) {
1302         if(!self.max_health)
1303                 self.max_health = g_pickup_healthmedium_max;
1304         if(!self.health)
1305                 self.health = g_pickup_healthmedium;
1306         if(!self.pickup_anyway)
1307                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1308         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1309 }
1310
1311 void spawnfunc_item_health_large (void) {
1312         if(!self.max_health)
1313                 self.max_health = g_pickup_healthlarge_max;
1314         if(!self.health)
1315                 self.health = g_pickup_healthlarge;
1316         if(!self.pickup_anyway)
1317                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1318         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1319 }
1320
1321 void spawnfunc_item_health_mega (void) {
1322         if(g_minstagib) {
1323                 minstagib_items(IT_NAILS);
1324         } else {
1325                 if(!self.max_health)
1326                         self.max_health = g_pickup_healthmega_max;
1327                 if(!self.health)
1328                         self.health = g_pickup_healthmega;
1329                 if(!self.pickup_anyway)
1330                         self.pickup_anyway = g_pickup_healthmega_anyway;
1331                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1332         }
1333 }
1334
1335 // support old misnamed entities
1336 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1337 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1338 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1339 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1340 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1341
1342 void spawnfunc_item_strength (void) {
1343         if(g_minstagib) {
1344                 minstagib_items(IT_STRENGTH);
1345         } else {
1346                 precache_sound("weapons/strength_fire.wav");
1347                 if(!self.strength_finished)
1348                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1349                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1350         }
1351 }
1352
1353 void spawnfunc_item_invincible (void) {
1354         if(g_minstagib) {
1355                 minstagib_items(IT_INVINCIBLE);
1356         } else {
1357                 if(!self.invincible_finished)
1358                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1359                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1360         }
1361 }
1362
1363 void spawnfunc_item_minst_cells (void) {
1364         if (g_minstagib)
1365         {
1366                 minst_no_auto_cells = 1;
1367                 minstagib_items(IT_CELLS);
1368         }
1369         else
1370                 remove(self);
1371 }
1372
1373 // compatibility:
1374 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1375
1376 float GiveItems(entity e, float beginarg, float endarg);
1377 void target_items_use (void)
1378 {
1379         if(activator.classname == "droppedweapon")
1380         {
1381                 EXACTTRIGGER_TOUCH;
1382                 remove(activator);
1383                 return;
1384         }
1385
1386         if(activator.classname != "player")
1387                 return;
1388         if(activator.deadflag != DEAD_NO)
1389                 return;
1390         EXACTTRIGGER_TOUCH;
1391
1392         entity e;
1393         for(e = world; (e = find(e, classname, "droppedweapon")); )
1394                 if(e.enemy == activator)
1395                         remove(e);
1396
1397         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1398                 centerprint(activator, self.message);
1399 }
1400
1401 void spawnfunc_target_items (void)
1402 {
1403         float n, i, j;
1404         entity e;
1405
1406         self.use = target_items_use;
1407         if(!self.strength_finished)
1408                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1409         if(!self.invincible_finished)
1410                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1411         if(!self.superweapons_finished)
1412                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1413
1414         precache_sound("misc/itempickup.wav");
1415         precache_sound("misc/megahealth.wav");
1416         precache_sound("misc/armor25.wav");
1417         precache_sound("misc/powerup.wav");
1418         precache_sound("misc/poweroff.wav");
1419         precache_sound("weapons/weaponpickup.wav");
1420
1421         n = tokenize_console(self.netname);
1422         if(argv(0) == "give")
1423         {
1424                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1425         }
1426         else
1427         {
1428                 for(i = 0; i < n; ++i)
1429                 {
1430                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1431                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1432                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1433                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1434                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1435                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1436                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1437                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1438                         else
1439                         {
1440                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1441                                 {
1442                                         e = get_weaponinfo(j);
1443                                         if(argv(i) == e.netname)
1444                                         {
1445                                                 WEPSET_OR_EW(self, j);
1446                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1447                                                         weapon_action(e.weapon, WR_PRECACHE);
1448                                                 break;
1449                                         }
1450                                 }
1451                                 if(j > WEP_LAST)
1452                                         print("target_items: invalid item ", argv(i), "\n");
1453                         }
1454                 }
1455
1456                 string itemprefix, valueprefix;
1457                 if(self.spawnflags == 0)
1458                 {
1459                         itemprefix = "";
1460                         valueprefix = "";
1461                 }
1462                 else if(self.spawnflags == 1)
1463                 {
1464                         itemprefix = "max ";
1465                         valueprefix = "max ";
1466                 }
1467                 else if(self.spawnflags == 2)
1468                 {
1469                         itemprefix = "min ";
1470                         valueprefix = "min ";
1471                 }
1472                 else if(self.spawnflags == 4)
1473                 {
1474                         itemprefix = "minus ";
1475                         valueprefix = "max ";
1476                 }
1477                 else
1478                         error("invalid spawnflags");
1479
1480                 self.netname = "";
1481                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1482                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1483                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1484                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1485                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1486                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1487                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1488                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1489                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1490                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1491                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1492                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1493                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1494                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1495                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1496                 {
1497                         e = get_weaponinfo(j);
1498                         if(e.weapon)
1499                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1500                 }
1501         }
1502         self.netname = strzone(self.netname);
1503         //print(self.netname, "\n");
1504
1505         n = tokenize_console(self.netname);
1506         for(i = 0; i < n; ++i)
1507         {
1508                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1509                 {
1510                         e = get_weaponinfo(j);
1511                         if(argv(i) == e.netname)
1512                         {
1513                                 weapon_action(e.weapon, WR_PRECACHE);
1514                                 break;
1515                         }
1516                 }
1517         }
1518 }
1519
1520 void spawnfunc_item_fuel(void)
1521 {
1522         if(!self.ammo_fuel)
1523                 self.ammo_fuel = g_pickup_fuel;
1524         if(!self.pickup_anyway)
1525                 self.pickup_anyway = g_pickup_ammo_anyway;
1526         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1527 }
1528
1529 void spawnfunc_item_fuel_regen(void)
1530 {
1531         if(start_items & IT_FUEL_REGEN)
1532         {
1533                 spawnfunc_item_fuel();
1534                 return;
1535         }
1536         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1537 }
1538
1539 void spawnfunc_item_jetpack(void)
1540 {
1541         if(g_grappling_hook)
1542                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1543         if(!self.ammo_fuel)
1544                 self.ammo_fuel = g_pickup_fuel_jetpack;
1545         if(start_items & IT_JETPACK)
1546         {
1547                 spawnfunc_item_fuel();
1548                 return;
1549         }
1550         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1551 }
1552
1553
1554 #define OP_SET 0
1555 #define OP_MIN 1
1556 #define OP_MAX 2
1557 #define OP_PLUS 3
1558 #define OP_MINUS 4
1559
1560 float GiveWeapon(entity e, float wpn, float op, float val)
1561 {
1562         float v0, v1;
1563         v0 = WEPSET_CONTAINS_EW(e, wpn);
1564         switch(op)
1565         {
1566                 case OP_SET:
1567                         if(val > 0)
1568                                 WEPSET_OR_EW(e, wpn);
1569                         else
1570                                 WEPSET_ANDNOT_EW(e, wpn);
1571                         break;
1572                 case OP_MIN:
1573                 case OP_PLUS:
1574                         if(val > 0)
1575                                 WEPSET_OR_EW(e, wpn);
1576                         break;
1577                 case OP_MAX:
1578                         if(val <= 0)
1579                                 WEPSET_ANDNOT_EW(e, wpn);
1580                         break;
1581                 case OP_MINUS:
1582                         if(val > 0)
1583                                 WEPSET_ANDNOT_EW(e, wpn);
1584                         break;
1585         }
1586         v1 = WEPSET_CONTAINS_EW(e, wpn);
1587         return (v0 != v1);
1588 }
1589
1590 float GiveBit(entity e, .float fld, float bit, float op, float val)
1591 {
1592         float v0, v1;
1593         v0 = (e.fld & bit);
1594         switch(op)
1595         {
1596                 case OP_SET:
1597                         if(val > 0)
1598                                 e.fld |= bit;
1599                         else
1600                                 e.fld &~= bit;
1601                         break;
1602                 case OP_MIN:
1603                 case OP_PLUS:
1604                         if(val > 0)
1605                                 e.fld |= bit;
1606                         break;
1607                 case OP_MAX:
1608                         if(val <= 0)
1609                                 e.fld &~= bit;
1610                         break;
1611                 case OP_MINUS:
1612                         if(val > 0)
1613                                 e.fld &~= bit;
1614                         break;
1615         }
1616         v1 = (e.fld & bit);
1617         return (v0 != v1);
1618 }
1619
1620 float GiveValue(entity e, .float fld, float op, float val)
1621 {
1622         float v0, v1;
1623         v0 = e.fld;
1624         switch(op)
1625         {
1626                 case OP_SET:
1627                         e.fld = val;
1628                         break;
1629                 case OP_MIN:
1630                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1631                         break;
1632                 case OP_MAX:
1633                         e.fld = min(e.fld, val);
1634                         break;
1635                 case OP_PLUS:
1636                         e.fld += val;
1637                         break;
1638                 case OP_MINUS:
1639                         e.fld -= val;
1640                         break;
1641         }
1642         v1 = e.fld;
1643         return (v0 != v1);
1644 }
1645
1646 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1647 {
1648         if(v1 == v0)
1649                 return;
1650         if(v1 <= v0 - t)
1651         {
1652                 if(snd_decr != "")
1653                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1654         }
1655         else if(v0 >= v0 + t)
1656         {
1657                 if(snd_incr != "")
1658                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1659         }
1660 }
1661
1662 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1663 {
1664         if(v0 < v1)
1665                 e.rotfield = max(e.rotfield, time + rottime);
1666         else if(v0 > v1)
1667                 e.regenfield = max(e.regenfield, time + regentime);
1668 }
1669
1670 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1671 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1672 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1673 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1674 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1675 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1676
1677 float GiveItems(entity e, float beginarg, float endarg)
1678 {
1679         float got, i, j, val, op;
1680         float _switchweapon;
1681         entity wi;
1682         string cmd;
1683
1684         val = 999;
1685         op = OP_SET;
1686
1687         got = 0;
1688
1689         _switchweapon = FALSE;
1690         if (e.autoswitch)
1691                 if (e.switchweapon == w_getbestweapon(e))
1692                         _switchweapon = TRUE;
1693
1694         e.strength_finished = max(0, e.strength_finished - time);
1695         e.invincible_finished = max(0, e.invincible_finished - time);
1696         e.superweapons_finished = max(0, e.superweapons_finished - time);
1697
1698         PREGIVE(e, items);
1699         PREGIVE_WEAPONS(e);
1700         PREGIVE(e, strength_finished);
1701         PREGIVE(e, invincible_finished);
1702         PREGIVE(e, superweapons_finished);
1703         PREGIVE(e, ammo_nails);
1704         PREGIVE(e, ammo_cells);
1705         PREGIVE(e, ammo_shells);
1706         PREGIVE(e, ammo_rockets);
1707         PREGIVE(e, ammo_fuel);
1708         PREGIVE(e, armorvalue);
1709         PREGIVE(e, health);
1710
1711         for(i = beginarg; i < endarg; ++i)
1712         {
1713                 cmd = argv(i);
1714
1715                 if(cmd == "0" || stof(cmd))
1716                 {
1717                         val = stof(cmd);
1718                         continue;
1719                 }
1720                 switch(cmd)
1721                 {
1722                         case "no":
1723                                 op = OP_MAX;
1724                                 val = 0;
1725                                 continue;
1726                         case "max":
1727                                 op = OP_MAX;
1728                                 continue;
1729                         case "min":
1730                                 op = OP_MIN;
1731                                 continue;
1732                         case "plus":
1733                                 op = OP_PLUS;
1734                                 continue;
1735                         case "minus":
1736                                 op = OP_MINUS;
1737                                 continue;
1738                         case "ALL":
1739                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1740                                 got += GiveValue(e, strength_finished, op, val);
1741                                 got += GiveValue(e, invincible_finished, op, val);
1742                                 got += GiveValue(e, superweapons_finished, op, val);
1743                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1744                         case "all":
1745                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1746                                 got += GiveValue(e, health, op, val);
1747                                 got += GiveValue(e, armorvalue, op, val);
1748                         case "allweapons":
1749                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1750                                 {
1751                                         wi = get_weaponinfo(j);
1752                                         if(wi.weapon)
1753                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1754                                                         got += GiveWeapon(e, j, op, val);
1755                                 }
1756                         case "allammo":
1757                                 got += GiveValue(e, ammo_cells, op, val);
1758                                 got += GiveValue(e, ammo_shells, op, val);
1759                                 got += GiveValue(e, ammo_nails, op, val);
1760                                 got += GiveValue(e, ammo_rockets, op, val);
1761                                 got += GiveValue(e, ammo_fuel, op, val);
1762                                 break;
1763                         case "unlimited_ammo":
1764                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1765                                 break;
1766                         case "unlimited_weapon_ammo":
1767                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1768                                 break;
1769                         case "unlimited_superweapons":
1770                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1771                                 break;
1772                         case "jetpack":
1773                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1774                                 break;
1775                         case "fuel_regen":
1776                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1777                                 break;
1778                         case "strength":
1779                                 got += GiveValue(e, strength_finished, op, val);
1780                                 break;
1781                         case "invincible":
1782                                 got += GiveValue(e, invincible_finished, op, val);
1783                                 break;
1784                         case "superweapons":
1785                                 got += GiveValue(e, superweapons_finished, op, val);
1786                                 break;
1787                         case "cells":
1788                                 got += GiveValue(e, ammo_cells, op, val);
1789                                 break;
1790                         case "shells":
1791                                 got += GiveValue(e, ammo_shells, op, val);
1792                                 break;
1793                         case "nails":
1794                         case "bullets":
1795                                 got += GiveValue(e, ammo_nails, op, val);
1796                                 break;
1797                         case "rockets":
1798                                 got += GiveValue(e, ammo_rockets, op, val);
1799                                 break;
1800                         case "health":
1801                                 got += GiveValue(e, health, op, val);
1802                                 break;
1803                         case "armor":
1804                                 got += GiveValue(e, armorvalue, op, val);
1805                                 break;
1806                         case "fuel":
1807                                 got += GiveValue(e, ammo_fuel, op, val);
1808                                 break;
1809                         default:
1810                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1811                                 {
1812                                         wi = get_weaponinfo(j);
1813                                         if(cmd == wi.netname)
1814                                         {
1815                                                 got += GiveWeapon(e, j, op, val);
1816                                                 break;
1817                                         }
1818                                 }
1819                                 if(j > WEP_LAST)
1820                                         print("give: invalid item ", cmd, "\n");
1821                                 break;
1822                 }
1823                 val = 999;
1824                 op = OP_SET;
1825         }
1826
1827         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1828         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1829         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1830         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1831         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1832         {
1833                 wi = get_weaponinfo(j);
1834                 if(wi.weapon)
1835                 {
1836                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1837                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1838                                 if(WEPSET_CONTAINS_EW(e, j))
1839                                         weapon_action(wi.weapon, WR_PRECACHE);
1840                 }
1841         }
1842         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1843         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1844         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1845         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1846         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1847         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1848         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1849         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1850         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1851
1852         if(e.superweapons_finished <= 0)
1853                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1854                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1855
1856         if (g_minstagib)
1857         {
1858                 e.health = bound(0, e.health, 100);
1859                 e.armorvalue = bound(0, e.armorvalue, 999);
1860         }
1861
1862         if(e.strength_finished <= 0)
1863                 e.strength_finished = 0;
1864         else
1865                 e.strength_finished += time;
1866         if(e.invincible_finished <= 0)
1867                 e.invincible_finished = 0;
1868         else
1869                 e.invincible_finished += time;
1870         if(e.superweapons_finished <= 0)
1871                 e.superweapons_finished = 0;
1872         else
1873                 e.superweapons_finished += time;
1874
1875         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1876                 _switchweapon = TRUE;
1877         if(_switchweapon)
1878                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1879
1880         return got;
1881 }