qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 void trigger_push_use()
  12 {
  13         if(teamplay)
  14                 self.team = activator.team;
  15 }
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         local float grav, sdist, zdist, vs, vz, jumpheight;
  34         local vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = autocvar_sv_gravity;
  39
  40         zdist = torg_z - org_z;
  41         sdist = vlen(torg - org - zdist * '0 0 1');
  42         sdir = normalize(torg - org - zdist * '0 0 1');
  43
  44         // how high do we need to push the player?
  45         jumpheight = fabs(ht);
  46         if(zdist > 0)
  47                 jumpheight = jumpheight + zdist;
  48
  49         /*
  50                 STOP.
  51
  52                 You will not understand the following equations anyway...
  53                 But here is what I did to get them.
  54
  55                 I used the functions
  56
  57                   s(t) = t * vs
  58                   z(t) = t * vz - 1/2 grav t^2
  59
  60                 and solved for:
  61
  62                   s(ti) = sdist
  63                   z(ti) = zdist
  64                   max(z, ti) = jumpheight
  65
  66                 From these three equations, you will find the three parameters vs, vz
  67                 and ti.
  68          */
  69
  70         // push him so high...
  71         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  72
  73         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  74         if(ht < 0)
  75                 if(zdist < 0)
  76                         vz = -vz;
  77
  78         vector solution;
  79         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  80         // ALWAYS solvable because jumpheight >= zdist
  81         if(!solution_z)
  82                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  83         if(zdist == 0)
  84                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  85
  86         if(zdist < 0)
  87         {
  88                 // down-jump
  89                 if(ht < 0)
  90                 {
  91                         // almost straight line type
  92                         // jump apex is before the jump
  93                         // we must take the larger one
  94                         trigger_push_calculatevelocity_flighttime = solution_y;
  95                 }
  96                 else
  97                 {
  98                         // regular jump
  99                         // jump apex is during the jump
 100                         // we must take the larger one too
 101                         trigger_push_calculatevelocity_flighttime = solution_y;
 102                 }
 103         }
 104         else
 105         {
 106                 // up-jump
 107                 if(ht < 0)
 108                 {
 109                         // almost straight line type
 110                         // jump apex is after the jump
 111                         // we must take the smaller one
 112                         trigger_push_calculatevelocity_flighttime = solution_x;
 113                 }
 114                 else
 115                 {
 116                         // regular jump
 117                         // jump apex is during the jump
 118                         // we must take the larger one
 119                         trigger_push_calculatevelocity_flighttime = solution_y;
 120                 }
 121         }
 122         vs = sdist / trigger_push_calculatevelocity_flighttime;
 123
 124         // finally calculate the velocity
 125         return sdir * vs + '0 0 1' * vz;
 126 }
 127
 128 void trigger_push_touch()
 129 {
 130         if (self.active == ACTIVE_NOT)
 131                 return;
 132
 133         if not(other.iscreature)
 134         if (other.classname != "body")
 135         if (other.classname != "casing")
 136         if (other.classname != "corpse")
 137         if (other.classname != "droppedweapon")
 138         if (other.classname != "gib")
 139         if (other.classname != "keepawayball")
 140         if (other.classname != "nexball_basketball")
 141         if (other.classname != "nexball_football")
 142         if (!other.projectiledeathtype || other.classname == "bullet")
 143                 return;
 144
 145         if(!isPushable(other))
 146                 return;
 147
 148         if (other.deadflag && other.iscreature)
 149                 return;
 150
 151         if(self.team)
 152                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 153                         return;
 154
 155         EXACTTRIGGER_TOUCH;
 156
 157         if(self.target)
 158                 self.movedir = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 159
 160         other.flags &~= FL_ONGROUND;
 161
 162         other.velocity = self.movedir;
 163
 164         if (other.classname == "player")
 165         {
 166                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 167                 other.oldvelocity = other.velocity;
 168
 169                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 170                 {
 171                         // flash when activated
 172                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 173                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 174                         self.pushltime = time + 0.2;
 175                 }
 176                 local float ct;
 177                 ct = clienttype(other);
 178                 if( ct == CLIENTTYPE_REAL || ct == CLIENTTYPE_BOT)
 179                 {
 180                         local float i;
 181                         local float found;
 182                         found = FALSE;
 183                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 184                                 if(other.(jumppadsused[i]) == self)
 185                                         found = TRUE;
 186                         if(!found)
 187                         {
 188                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 189                                 other.jumppadcount = other.jumppadcount + 1;
 190                         }
 191
 192                         if(ct == CLIENTTYPE_REAL)
 193                         {
 194                                 if(self.message)
 195                                         centerprint(other, self.message);
 196                         }
 197                         else
 198                                 other.lastteleporttime = time;
 199                 }
 200                 else
 201                         other.jumppadcount = TRUE;
 202
 203                 // reset tracking of who pushed you into a hazard (for kill credit)
 204                 other.pushltime = 0;
 205         }
 206
 207         if(self.enemy.target)
 208         {
 209                 entity oldself;
 210                 oldself = self;
 211                 activator = other;
 212                 self = self.enemy;
 213                 SUB_UseTargets();
 214                 self = oldself;
 215         }
 216
 217         if (other.flags & FL_PROJECTILE)
 218         {
 219                 other.angles = vectoangles (other.velocity);
 220                 switch(other.movetype)
 221                 {
 222                         case MOVETYPE_FLY:
 223                                 other.movetype = MOVETYPE_TOSS;
 224                                 other.gravity = 1;
 225                                 break;
 226                         case MOVETYPE_BOUNCEMISSILE:
 227                                 other.movetype = MOVETYPE_BOUNCE;
 228                                 other.gravity = 1;
 229                                 break;
 230                 }
 231                 UpdateCSQCProjectile(other);
 232         }
 233
 234         if (self.spawnflags & PUSH_ONCE)
 235         {
 236                 self.touch = SUB_Null;
 237                 self.think = SUB_Remove;
 238                 self.nextthink = time;
 239         }
 240 };
 241
 242 .vector dest;
 243 void trigger_push_findtarget()
 244 {
 245         local entity e;
 246         local vector org;
 247         local float flighttime;
 248
 249         // first calculate a typical start point for the jump
 250         org = (self.absmin + self.absmax) * 0.5;
 251         org_z = self.absmax_z - PL_MIN_z;
 252
 253         if (self.target)
 254         {
 255                 // find the target
 256                 self.enemy = find(world, targetname, self.target);
 257                 if (!self.enemy)
 258                 {
 259                         objerror("trigger_push: target not found\n");
 260                         remove(self);
 261                         return;
 262                 }
 263
 264                 self.movedir = trigger_push_calculatevelocity(org, self.enemy, self.height);
 265                 flighttime = trigger_push_calculatevelocity_flighttime;
 266         }
 267         else
 268                 flighttime = 0;
 269
 270         // calculate the destination and spawn a teleporter spawnfunc_waypoint
 271         e = spawn();
 272         setorigin(e, org);
 273         setsize(e, PL_MIN, PL_MAX);
 274         e.velocity = self.movedir;
 275         tracetoss(e, e);
 276         self.dest = trace_endpos;
 277         remove(e);
 278
 279         waypoint_spawnforteleporter(self, self.dest, flighttime);
 280 };
 281
 282 /*
 283  * ENTITY PARAMETERS:
 284  *
 285  *   target:  target of jump
 286  *   height:  the absolute value is the height of the highest point of the jump
 287  *            trajectory above the higher one of the player and the target.
 288  *            the sign indicates whether the highest point is INSIDE (positive)
 289  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 290  *            positive values for targets mounted on the floor, and use negative
 291  *            values to target a point on the ceiling.
 292  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 293  */
 294 void spawnfunc_trigger_push()
 295 {
 296         SetMovedir ();
 297
 298         EXACTTRIGGER_INIT;
 299
 300         self.active = ACTIVE_ACTIVE;
 301         self.use = trigger_push_use;
 302         self.touch = trigger_push_touch;
 303
 304         // normal push setup
 305         if (!self.speed)
 306                 self.speed = 1000;
 307         self.movedir = self.movedir * self.speed * 10;
 308
 309         if not(self.noise)
 310                 self.noise = "misc/jumppad.wav";
 311         precache_sound (self.noise);
 312
 313         // this must be called to spawn the teleport waypoints for bots
 314         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 315 };
 316
 317 void spawnfunc_target_push() {};
 318 void spawnfunc_info_notnull() {};
 319 void spawnfunc_target_position() {};