qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teamplay)
   4                 self.team = activator.team;
   5 }
   6
   7 #define TDEATHLOOP(o) \
   8         entity head; \
   9         vector deathmin; \
  10         vector deathmax; \
  11         float deathradius; \
  12         deathmin = (o) + player.mins; \
  13         deathmax = (o) + player.maxs; \
  14         if(telefragmin != telefragmax) \
  15         { \
  16                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x; \
  17                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y; \
  18                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z; \
  19                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x; \
  20                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y; \
  21                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z; \
  22         } \
  23         deathradius = max(vlen(deathmin), vlen(deathmax)); \
  24         for(head = findradius(o, deathradius); head; head = head.chain) \
  25                 if(head != player) \
  26                         if(head.takedamage) \
  27                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  28
  29
  30 float check_tdeath(entity player, vector org, vector telefragmin, vector telefragmax)
  31 {
  32         if (player.classname == "player" && player.health >= 1)
  33         {
  34                 TDEATHLOOP(org)
  35                 {
  36                         if not(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team)
  37                                 if(head.classname == "player")
  38                                         if(head.health >= 1)
  39                                                 return 1;
  40                 }
  41         }
  42         return 0;
  43 }
  44 float tdeath_hit;
  45 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
  46 {
  47         TDEATHLOOP(player.origin)
  48         {
  49                 if (player.classname == "player" && player.health >= 1)
  50                 {
  51                         if not(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team)
  52                         {
  53                                 if(head.classname == "player")
  54                                         if(head.health >= 1)
  55                                                 ++tdeath_hit;
  56                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                         }
  58                 }
  59                 else // dead bodies and monsters gib themselves instead of telefragging
  60                         Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  61         }
  62 }
  63
  64 void spawn_tdeath(vector v0, entity e, vector v)
  65 {
  66         tdeath(e, e, e, '0 0 0', '0 0 0');
  67 }
  68
  69 .entity pusher;
  70 #define TELEPORT_FLAG_SOUND 1
  71 #define TELEPORT_FLAG_PARTICLES 2
  72 #define TELEPORT_FLAG_TDEATH 4
  73 #define TELEPORT_FLAG_FORCE_TDEATH 8
  74
  75 #define TELEPORT_FLAGS_WARPZONE   0
  76 #define TELEPORT_FLAGS_PORTAL     (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH | TELEPORT_FLAG_FORCE_TDEATH)
  77 #define TELEPORT_FLAGS_TELEPORTER (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH)
  78 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax, float tflags)
  79 {
  80         entity telefragger;
  81         vector from;
  82
  83         if(teleporter.owner)
  84                 telefragger = teleporter.owner;
  85         else
  86                 telefragger = player;
  87
  88         makevectors (to_angles);
  89
  90         if(player.classname == "player") // don't play sounds or show particles for anything that isn't a player, maybe change later to block only observers
  91         {
  92                 if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  93                 {
  94                         if(tflags & TELEPORT_FLAG_SOUND)
  95                                 sound (player, CH_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  96                         if(tflags & TELEPORT_FLAG_PARTICLES)
  97                         {
  98                                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  99                                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
 100                         }
 101                         self.pushltime = time + 0.2;
 102                 }
 103         }
 104
 105         // Relocate the player
 106         // assuming to allows PL_MIN to PL_MAX box and some more
 107         from = player.origin;
 108         setorigin (player, to);
 109         player.oldorigin = to; // don't undo the teleport by unsticking
 110         player.angles = to_angles;
 111         player.fixangle = TRUE;
 112         player.velocity = to_velocity;
 113         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
 114
 115         UpdateCSQCProjectileAfterTeleport(player);
 116
 117         if(player.classname == "player")
 118         {
 119                 if(tflags & TELEPORT_FLAG_TDEATH)
 120                         if(player.takedamage && player.deadflag == DEAD_NO && !g_race && !g_cts && (autocvar_g_telefrags || (tflags & TELEPORT_FLAG_FORCE_TDEATH)))
 121                                 tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
 122
 123                 // player no longer is on ground
 124                 player.flags &~= FL_ONGROUND;
 125
 126                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 127                 player.oldvelocity = player.velocity;
 128
 129                 // reset tracking of who pushed you into a hazard (for kill credit)
 130                 if(teleporter.owner)
 131                 {
 132                         player.pusher = teleporter.owner;
 133                         player.pushltime = time + autocvar_g_maxpushtime;
 134                 }
 135                 else
 136                 {
 137                         player.pushltime = 0;
 138                 }
 139
 140                 player.lastteleporttime = time;
 141         }
 142 }
 143
 144 entity Simple_TeleportPlayer(entity teleporter, entity player)
 145 {
 146         vector locout;
 147         entity e;
 148         float p;
 149
 150         // Find the output teleporter
 151         if(teleporter.enemy)
 152         {
 153                 e = teleporter.enemy;
 154         }
 155         else
 156         {
 157                 RandomSelection_Init();
 158                 for(e = world; (e = find(e, targetname, teleporter.target)); )
 159                 {
 160                         p = 1;
 161                         if(autocvar_g_telefrags_avoid)
 162                         {
 163                                 locout = e.origin + '0 0 1' * (1 - player.mins_z - 24);
 164                                 if(check_tdeath(player, locout, '0 0 0', '0 0 0'))
 165                                         p = 0;
 166                         }
 167                         RandomSelection_Add(e, 0, string_null, (e.cnt ? e.cnt : 1), p);
 168                 }
 169                 e = RandomSelection_chosen_ent;
 170         }
 171
 172         if(!e) { sprint(player, "Teleport destination vanished. Sorry... please complain to the mapper.\n"); }
 173
 174         makevectors(e.mangle);
 175
 176         if(e.speed)
 177                 if(vlen(player.velocity) > e.speed)
 178                         player.velocity = normalize(player.velocity) * max(0, e.speed);
 179
 180         if(autocvar_g_teleport_maxspeed)
 181                 if(vlen(player.velocity) > autocvar_g_teleport_maxspeed)
 182                         player.velocity = normalize(player.velocity) * max(0, autocvar_g_teleport_maxspeed);
 183
 184         locout = e.origin + '0 0 1' * (1 - player.mins_z - 24);
 185         TeleportPlayer(teleporter, player, locout, e.mangle, v_forward * vlen(player.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 186
 187         return e;
 188 }
 189
 190 void Teleport_Touch (void)
 191 {
 192         entity oldself;
 193         string s;
 194
 195         if (self.active != ACTIVE_ACTIVE)
 196                 return;
 197
 198         if not(other.iscreature)
 199                 return;
 200
 201         // for gameplay: vehicles can't teleport
 202         if (other.vehicle_flags & VHF_ISVEHICLE)
 203                 return;
 204
 205     if(other.vehicle)
 206         return;
 207
 208     if(other.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 209         return;
 210
 211         if (other.deadflag != DEAD_NO)
 212                 return;
 213
 214         if(self.team)
 215                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 216                         return;
 217
 218         EXACTTRIGGER_TOUCH;
 219
 220         if(other.classname == "player")
 221                 RemoveGrapplingHook(other);
 222
 223         entity e;
 224         e = Simple_TeleportPlayer(self, other);
 225
 226         activator = other;
 227         s = self.target; self.target = string_null;
 228         SUB_UseTargets();
 229         if not(self.target) self.target = s;
 230
 231         oldself = self;
 232         self = e;
 233         SUB_UseTargets();
 234         self = oldself;
 235 }
 236
 237 void spawnfunc_info_teleport_destination (void)
 238 {
 239         self.classname = "info_teleport_destination";
 240
 241         self.mangle = self.angles;
 242         self.angles = '0 0 0';
 243
 244         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 245         setorigin (self, self.origin);
 246
 247         IFTARGETED
 248         {
 249         }
 250         else
 251                 objerror ("^3Teleport destination without a targetname");
 252 }
 253
 254 void spawnfunc_misc_teleporter_dest (void)
 255 {
 256         spawnfunc_info_teleport_destination();
 257 }
 258
 259 void spawnfunc_target_teleporter (void)
 260 {
 261         spawnfunc_info_teleport_destination();
 262 }
 263
 264 void teleport_findtarget (void)
 265 {
 266         entity e;
 267         float n;
 268
 269         n = 0;
 270         for(e = world; (e = find(e, targetname, self.target)); )
 271         {
 272                 ++n;
 273                 if(e.movetype == MOVETYPE_NONE)
 274                         waypoint_spawnforteleporter(self, e.origin, 0);
 275                 if(e.classname != "info_teleport_destination")
 276                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 277         }
 278
 279         if(n == 0)
 280         {
 281                 // no dest!
 282                 objerror ("Teleporter with nonexistant target");
 283                 return;
 284         }
 285         else if(n == 1)
 286         {
 287                 // exactly one dest - bots love that
 288                 self.enemy = find(e, targetname, self.target);
 289         }
 290         else
 291         {
 292                 // have to use random selection every single time
 293                 self.enemy = world;
 294         }
 295
 296         // now enable touch
 297         self.touch = Teleport_Touch;
 298 }
 299
 300 entity Teleport_Find(vector mi, vector ma)
 301 {
 302         entity e;
 303         for(e = world; (e = find(e, classname, "trigger_teleport")); )
 304                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 305                         return e;
 306         return world;
 307 }
 308
 309 entity teleport_first;
 310 .entity teleport_next;
 311 void spawnfunc_trigger_teleport (void)
 312 {
 313         self.angles = '0 0 0';
 314
 315         EXACTTRIGGER_INIT;
 316
 317         self.active = ACTIVE_ACTIVE;
 318
 319         self.use = trigger_teleport_use;
 320
 321         // this must be called to spawn the teleport waypoints for bots
 322         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 323
 324         if (!self.target)
 325         {
 326                 objerror ("Teleporter with no target");
 327                 return;
 328         }
 329
 330         self.teleport_next = teleport_first;
 331         teleport_first = self;
 332 }
 333
 334 void WarpZone_PostTeleportPlayer_Callback(entity pl)
 335 {
 336         UpdateCSQCProjectileAfterTeleport(pl);
 337         // "disown" projectiles after teleport
 338         if(pl.owner)
 339         if(pl.owner == pl.realowner)
 340         {
 341                 if(!(pl.flags & FL_PROJECTILE))
 342                         print("A non-projectile got through a warpzone and its owner cleared. It's a ", pl.classname, ".\n");
 343                 pl.owner = world;
 344         }
 345         if(pl.classname == "player")
 346         {
 347                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 348                 pl.oldvelocity = pl.velocity;
 349                 // reset teleport time tracking too (or multijump can cause insane speeds)
 350                 pl.lastteleporttime = time;
 351         }
 352 }