qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teamplay)
   4                 self.team = activator.team;
   5 }
   6
   7 #define TDEATHLOOP(o) \
   8         entity head; \
   9         vector deathmin; \
  10         vector deathmax; \
  11         float deathradius; \
  12         deathmin = (o) + player.mins; \
  13         deathmax = (o) + player.maxs; \
  14         if(telefragmin != telefragmax) \
  15         { \
  16                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x; \
  17                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y; \
  18                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z; \
  19                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x; \
  20                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y; \
  21                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z; \
  22         } \
  23         deathradius = max(vlen(deathmin), vlen(deathmax)); \
  24         for(head = findradius(o, deathradius); head; head = head.chain) \
  25                 if(head != player) \
  26                         if(head.takedamage) \
  27                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  28
  29
  30 float check_tdeath(entity player, vector org, vector telefragmin, vector telefragmax)
  31 {
  32         if (player.classname == "player" && player.health >= 1)
  33         {
  34                 TDEATHLOOP(org)
  35                 {
  36                         if not(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team)
  37                                 if(head.classname == "player")
  38                                         if(head.health >= 1)
  39                                                 return 1;
  40                 }
  41         }
  42         return 0;
  43 }
  44 float tdeath_hit;
  45 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
  46 {
  47         TDEATHLOOP(player.origin)
  48         {
  49                 if (player.classname == "player" && player.health >= 1)
  50                 {
  51                         if not(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team)
  52                         {
  53                                 if(head.classname == "player")
  54                                         if(head.health >= 1)
  55                                                 ++tdeath_hit;
  56                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                         }
  58                 }
  59                 else // dead bodies and monsters gib themselves instead of telefragging
  60                         Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  61         }
  62 }
  63
  64 void spawn_tdeath(vector v0, entity e, vector v)
  65 {
  66         tdeath(e, e, e, '0 0 0', '0 0 0');
  67 }
  68
  69 .entity pusher;
  70 #define TELEPORT_FLAG_SOUND 1
  71 #define TELEPORT_FLAG_PARTICLES 2
  72 #define TELEPORT_FLAG_TDEATH 4
  73 #define TELEPORT_FLAG_FORCE_TDEATH 8
  74
  75 #define TELEPORT_FLAGS_WARPZONE   0
  76 #define TELEPORT_FLAGS_PORTAL     (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH | TELEPORT_FLAG_FORCE_TDEATH)
  77 #define TELEPORT_FLAGS_TELEPORTER (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH)
  78 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax, float tflags)
  79 {
  80         entity telefragger;
  81         vector from;
  82
  83         if(teleporter.owner)
  84                 telefragger = teleporter.owner;
  85         else
  86                 telefragger = player;
  87
  88         makevectors (to_angles);
  89
  90         if(player.classname == "player") // don't play sounds or show particles for anything that isn't a player, maybe change later to block only observers
  91         {
  92                 if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  93                 {
  94                         if(tflags & TELEPORT_FLAG_SOUND)
  95                                 sound (player, CH_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  96                         if(tflags & TELEPORT_FLAG_PARTICLES)
  97                         {
  98                                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  99                                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
 100                         }
 101                         self.pushltime = time + 0.2;
 102                 }
 103         }
 104
 105         // Relocate the player
 106         // assuming to allows PL_MIN to PL_MAX box and some more
 107         from = player.origin;
 108         setorigin (player, to);
 109         player.oldorigin = to; // don't undo the teleport by unsticking
 110         player.angles = to_angles;
 111         player.fixangle = TRUE;
 112         player.velocity = to_velocity;
 113         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
 114
 115         UpdateCSQCProjectileAfterTeleport(player);
 116
 117         if(player.classname == "player")
 118         {
 119                 if(tflags & TELEPORT_FLAG_TDEATH)
 120                         if(player.takedamage && player.deadflag == DEAD_NO && !g_race && !g_cts && (autocvar_g_telefrags || (tflags & TELEPORT_FLAG_FORCE_TDEATH)))
 121                                 tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
 122
 123                 // player no longer is on ground
 124                 player.flags &~= FL_ONGROUND;
 125
 126                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 127                 player.oldvelocity = player.velocity;
 128
 129                 // reset tracking of who pushed you into a hazard (for kill credit)
 130                 if(teleporter.owner)
 131                 {
 132                         player.pusher = teleporter.owner;
 133                         player.pushltime = time + autocvar_g_maxpushtime;
 134                 }
 135                 else
 136                 {
 137                         player.pushltime = 0;
 138                 }
 139
 140                 player.lastteleporttime = time;
 141         }
 142 }
 143
 144 entity Simple_TeleportPlayer(entity teleporter, entity player)
 145 {
 146         vector locout;
 147         entity e;
 148         float p;
 149
 150         // Find the output teleporter
 151         if(teleporter.enemy)
 152         {
 153                 e = teleporter.enemy;
 154         }
 155         else
 156         {
 157                 RandomSelection_Init();
 158                 for(e = world; (e = find(e, targetname, teleporter.target)); )
 159                 {
 160                         p = 1;
 161                         if(autocvar_g_telefrags_avoid)
 162                         {
 163                                 locout = e.origin + '0 0 1' * (1 - player.mins_z - 24);
 164                                 if(check_tdeath(player, locout, '0 0 0', '0 0 0'))
 165                                         p = 0;
 166                         }
 167                         RandomSelection_Add(e, 0, string_null, (e.cnt ? e.cnt : 1), p);
 168                 }
 169                 e = RandomSelection_chosen_ent;
 170         }
 171
 172         if(!e) { sprint(player, "Teleport destination vanished. Sorry... please complain to the mapper.\n"); }
 173
 174         makevectors(e.mangle);
 175
 176         if(e.speed)
 177                 if(vlen(player.velocity) > e.speed)
 178                         player.velocity = normalize(player.velocity) * max(0, e.speed);
 179
 180         if(autocvar_g_teleport_maxspeed)
 181                 if(vlen(player.velocity) > autocvar_g_teleport_maxspeed)
 182                         player.velocity = normalize(player.velocity) * max(0, autocvar_g_teleport_maxspeed);
 183
 184         locout = e.origin + '0 0 1' * (1 - player.mins_z - 24);
 185         TeleportPlayer(teleporter, player, locout, e.mangle, v_forward * vlen(player.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 186
 187         return e;
 188 }
 189
 190 void Teleport_Touch (void)
 191 {
 192         entity oldself;
 193         string s;
 194
 195         if (self.active != ACTIVE_ACTIVE)
 196                 return;
 197
 198         if not(other.iscreature)
 199                 return;
 200
 201         // for gameplay: vehicles can't teleport
 202         if (other.vehicle_flags & VHF_ISVEHICLE)
 203                 return;
 204
 205         if (other.deadflag != DEAD_NO)
 206                 return;
 207
 208         if(self.team)
 209                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 210                         return;
 211
 212         EXACTTRIGGER_TOUCH;
 213
 214         if(other.classname == "player")
 215                 RemoveGrapplingHook(other);
 216
 217         entity e;
 218         e = Simple_TeleportPlayer(self, other);
 219
 220         activator = other;
 221         s = self.target; self.target = string_null;
 222         SUB_UseTargets();
 223         if not(self.target) self.target = s;
 224
 225         oldself = self;
 226         self = e;
 227         SUB_UseTargets();
 228         self = oldself;
 229 }
 230
 231 void spawnfunc_info_teleport_destination (void)
 232 {
 233         self.classname = "info_teleport_destination";
 234
 235         self.mangle = self.angles;
 236         self.angles = '0 0 0';
 237
 238         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 239         setorigin (self, self.origin);
 240
 241         IFTARGETED
 242         {
 243         }
 244         else
 245                 objerror ("^3Teleport destination without a targetname");
 246 }
 247
 248 void spawnfunc_misc_teleporter_dest (void)
 249 {
 250         spawnfunc_info_teleport_destination();
 251 }
 252
 253 void spawnfunc_target_teleporter (void)
 254 {
 255         spawnfunc_info_teleport_destination();
 256 }
 257
 258 void teleport_findtarget (void)
 259 {
 260         entity e;
 261         float n;
 262
 263         n = 0;
 264         for(e = world; (e = find(e, targetname, self.target)); )
 265         {
 266                 ++n;
 267                 if(e.movetype == MOVETYPE_NONE)
 268                         waypoint_spawnforteleporter(self, e.origin, 0);
 269                 if(e.classname != "info_teleport_destination")
 270                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 271         }
 272
 273         if(n == 0)
 274         {
 275                 // no dest!
 276                 objerror ("Teleporter with nonexistant target");
 277                 return;
 278         }
 279         else if(n == 1)
 280         {
 281                 // exactly one dest - bots love that
 282                 self.enemy = find(e, targetname, self.target);
 283         }
 284         else
 285         {
 286                 // have to use random selection every single time
 287                 self.enemy = world;
 288         }
 289
 290         // now enable touch
 291         self.touch = Teleport_Touch;
 292 }
 293
 294 entity Teleport_Find(vector mi, vector ma)
 295 {
 296         entity e;
 297         for(e = world; (e = find(e, classname, "trigger_teleport")); )
 298                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 299                         return e;
 300         return world;
 301 }
 302
 303 entity teleport_first;
 304 .entity teleport_next;
 305 void spawnfunc_trigger_teleport (void)
 306 {
 307         self.angles = '0 0 0';
 308
 309         EXACTTRIGGER_INIT;
 310
 311         self.active = ACTIVE_ACTIVE;
 312
 313         self.use = trigger_teleport_use;
 314
 315         // this must be called to spawn the teleport waypoints for bots
 316         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 317
 318         if (!self.target)
 319         {
 320                 objerror ("Teleporter with no target");
 321                 return;
 322         }
 323
 324         self.teleport_next = teleport_first;
 325         teleport_first = self;
 326 }
 327
 328 void WarpZone_PostTeleportPlayer_Callback(entity pl)
 329 {
 330         UpdateCSQCProjectileAfterTeleport(pl);
 331         // "disown" projectiles after teleport
 332         if(pl.owner)
 333         if(pl.owner == pl.realowner)
 334         {
 335                 if(!(pl.flags & FL_PROJECTILE))
 336                         print("A non-projectile got through a warpzone and its owner cleared. It's a ", pl.classname, ".\n");
 337                 pl.owner = world;
 338         }
 339         if(pl.classname == "player")
 340         {
 341                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 342                 pl.oldvelocity = pl.velocity;
 343                 // reset teleport time tracking too (or multijump can cause insane speeds)
 344                 pl.lastteleporttime = time;
 345         }
 346 }