qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teams_matter)
   4                 self.team = activator.team;
   5 }
   6
   7 #define TDEATHLOOP(o) \
   8         entity head; \
   9         vector deathmin; \
  10         vector deathmax; \
  11         float deathradius; \
  12         deathmin = (o) + player.mins; \
  13         deathmax = (o) + player.maxs; \
  14         if(telefragmin != telefragmax) \
  15         { \
  16                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x; \
  17                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y; \
  18                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z; \
  19                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x; \
  20                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y; \
  21                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z; \
  22         } \
  23         deathradius = max(vlen(deathmin), vlen(deathmax)); \
  24         for(head = findradius(o, deathradius); head; head = head.chain) \
  25                 if(head != player) \
  26                         if(head.takedamage) \
  27                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  28
  29
  30 float check_tdeath(entity player, vector org, vector telefragmin, vector telefragmax)
  31 {
  32         if (player.classname == "player" && player.health >= 1)
  33         {
  34                 TDEATHLOOP(org)
  35                 {
  36                         if not(teams_matter && autocvar_g_telefrags_teamplay && head.team == player.team)
  37                                 if(head.classname == "player")
  38                                         if(head.health >= 1)
  39                                                 return 1;
  40                 }
  41         }
  42         return 0;
  43 }
  44 float tdeath_hit;
  45 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
  46 {
  47         TDEATHLOOP(player.origin)
  48         {
  49                 if (player.classname == "player" && player.health >= 1)
  50                 {
  51                         if not(teams_matter && autocvar_g_telefrags_teamplay && head.team == player.team)
  52                         {
  53                                 if(head.classname == "player")
  54                                         if(head.health >= 1)
  55                                                 ++tdeath_hit;
  56                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                         }
  58                 }
  59                 else // dead bodies and monsters gib themselves instead of telefragging
  60                         Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  61         }
  62 }
  63
  64 void spawn_tdeath(vector v0, entity e, vector v)
  65 {
  66         tdeath(e, e, e, '0 0 0', '0 0 0');
  67 }
  68
  69 .entity pusher;
  70 #define TELEPORT_FLAG_SOUND 1
  71 #define TELEPORT_FLAG_PARTICLES 2
  72 #define TELEPORT_FLAG_TDEATH 4
  73 #define TELEPORT_FLAG_FORCE_TDEATH 8
  74
  75 #define TELEPORT_FLAGS_WARPZONE   0
  76 #define TELEPORT_FLAGS_PORTAL     (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH | TELEPORT_FLAG_FORCE_TDEATH)
  77 #define TELEPORT_FLAGS_TELEPORTER (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH)
  78 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax, float tflags)
  79 {
  80         entity telefragger;
  81         vector from;
  82
  83         if(teleporter.owner)
  84                 telefragger = teleporter.owner;
  85         else
  86                 telefragger = player;
  87
  88         makevectors (to_angles);
  89
  90         if(player.classname == "player") // don't play sounds or show particles for anything that isn't a player, maybe change later to block only observers
  91         {
  92                 if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  93                 {
  94                         if(tflags & TELEPORT_FLAG_SOUND)
  95                                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  96                         if(tflags & TELEPORT_FLAG_PARTICLES)
  97                         {
  98                                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  99                                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
 100                         }
 101                         self.pushltime = time + 0.2;
 102                 }
 103         }
 104
 105         // Relocate the player
 106         // assuming to allows PL_MIN to PL_MAX box and some more
 107         from = player.origin;
 108         setorigin (player, to);
 109         player.oldorigin = to; // don't undo the teleport by unsticking
 110         player.angles = to_angles;
 111         player.fixangle = TRUE;
 112         player.velocity = to_velocity;
 113         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
 114
 115         UpdateCSQCProjectileAfterTeleport(player);
 116
 117         if(player.classname == "player")
 118         {
 119                 if(tflags & TELEPORT_FLAG_TDEATH)
 120                         if(player.takedamage && player.deadflag == DEAD_NO && !g_race && !g_cts && (autocvar_g_telefrags || (tflags & TELEPORT_FLAG_FORCE_TDEATH)))
 121                                 tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
 122
 123                 // player no longer is on ground
 124                 player.flags &~= FL_ONGROUND;
 125
 126                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 127                 player.oldvelocity = player.velocity;
 128
 129                 // reset tracking of who pushed you into a hazard (for kill credit)
 130                 if(teleporter.owner)
 131                 {
 132                         player.pusher = teleporter.owner;
 133                         player.pushltime = time + autocvar_g_maxpushtime;
 134                 }
 135                 else
 136                 {
 137                         player.pushltime = 0;
 138                 }
 139
 140                 player.lastteleporttime = time;
 141         }
 142 }
 143
 144 void Simple_TeleportPlayer(entity teleporter, entity player)
 145 {
 146         vector locout;
 147         entity e;
 148         float p;
 149
 150         // Find the output teleporter
 151         if(!teleporter.enemy)
 152         {
 153                 RandomSelection_Init();
 154                 for(e = world; (e = find(e, targetname, teleporter.target)); )
 155                 {
 156                         p = 1;
 157                         if(autocvar_g_telefrags_avoid)
 158                         {
 159                                 locout = e.origin + '0 0 1' * (1 - player.mins_z - 24);
 160                                 if(check_tdeath(player, locout, '0 0 0', '0 0 0'))
 161                                         p = 0;
 162                         }
 163                         RandomSelection_Add(e, 0, string_null, (e.cnt ? e.cnt : 1), p);
 164                 }
 165                 teleporter.enemy = RandomSelection_chosen_ent;
 166         }
 167
 168         if(!teleporter.enemy) { sprint(player, "Teleport destination vanished. Sorry... please complain to the mapper.\n"); }
 169
 170         makevectors(teleporter.enemy.mangle);
 171
 172         if(teleporter.enemy.speed)
 173                 if(vlen(player.velocity) > teleporter.enemy.speed)
 174                         player.velocity = normalize(player.velocity) * max(0, teleporter.enemy.speed);
 175
 176         if(autocvar_g_teleport_maxspeed)
 177                 if(vlen(player.velocity) > autocvar_g_teleport_maxspeed)
 178                         player.velocity = normalize(player.velocity) * max(0, autocvar_g_teleport_maxspeed);
 179
 180         locout = teleporter.enemy.origin + '0 0 1' * (1 - player.mins_z - 24);
 181         TeleportPlayer(teleporter, player, locout, teleporter.enemy.mangle, v_forward * vlen(player.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 182 }
 183
 184 void Teleport_Touch (void)
 185 {
 186         entity oldself;
 187         string s;
 188
 189         if (self.active != ACTIVE_ACTIVE)
 190                 return;
 191
 192         if (other.deadflag != DEAD_NO)
 193                 return;
 194         if not(other.flags & FL_CLIENT) // FIXME: Make missiles firable through the teleport too
 195                 return;
 196
 197         if(self.team)
 198                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 199                         return;
 200
 201         EXACTTRIGGER_TOUCH;
 202
 203         if(other.classname == "player")
 204                 RemoveGrapplingHook(other);
 205
 206         Simple_TeleportPlayer(self, other);
 207
 208         activator = other;
 209         s = self.target; self.target = string_null;
 210         SUB_UseTargets();
 211         if not(self.target) self.target = s;
 212
 213         oldself = self;
 214         self = self.enemy;
 215         SUB_UseTargets();
 216         self = oldself;
 217 }
 218
 219 void spawnfunc_info_teleport_destination (void)
 220 {
 221         self.classname = "info_teleport_destination";
 222
 223         self.mangle = self.angles;
 224         self.angles = '0 0 0';
 225
 226         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 227         setorigin (self, self.origin);
 228
 229         IFTARGETED
 230         {
 231         }
 232         else
 233                 objerror ("^3Teleport destination without a targetname");
 234 }
 235
 236 void spawnfunc_misc_teleporter_dest (void)
 237 {
 238         spawnfunc_info_teleport_destination();
 239 }
 240
 241 void spawnfunc_target_teleporter (void)
 242 {
 243         spawnfunc_info_teleport_destination();
 244 }
 245
 246 void teleport_findtarget (void)
 247 {
 248         entity e;
 249         float n;
 250
 251         RandomSelection_Init();
 252         n = 0;
 253         for(e = world; (e = find(e, targetname, self.target)); )
 254         {
 255                 ++n;
 256                 if(e.movetype == MOVETYPE_NONE)
 257                         RandomSelection_Add(e, 0, string_null, 1, 1);
 258                 if(e.classname != "info_teleport_destination")
 259                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 260         }
 261         if(RandomSelection_chosen_ent)
 262                 waypoint_spawnforteleporter(self, RandomSelection_chosen_ent.origin, 0);
 263
 264         if(n == 0)
 265         {
 266                 // no dest!
 267                 objerror ("Teleporter with nonexistant target");
 268                 return;
 269         }
 270         else if(n == 1)
 271         {
 272                 // exactly one dest - bots love that
 273                 self.enemy = find(e, targetname, self.target);
 274                 self.dest = self.enemy.origin;
 275         }
 276         else
 277         {
 278                 // have to use random selection every single time
 279                 self.enemy = world;
 280         }
 281
 282         // now enable touch
 283         self.touch = Teleport_Touch;
 284 }
 285
 286 entity Teleport_Find(vector mi, vector ma)
 287 {
 288         entity e;
 289         for(e = world; (e = find(e, classname, "trigger_teleport")); )
 290                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 291                         return e;
 292         return world;
 293 }
 294
 295 entity teleport_first;
 296 .entity teleport_next;
 297 void spawnfunc_trigger_teleport (void)
 298 {
 299         self.angles = '0 0 0';
 300
 301         EXACTTRIGGER_INIT;
 302
 303         self.active = ACTIVE_ACTIVE;
 304
 305         self.use = trigger_teleport_use;
 306
 307         // this must be called to spawn the teleport waypoints for bots
 308         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 309
 310         if (!self.target)
 311         {
 312                 objerror ("Teleporter with no target");
 313                 return;
 314         }
 315
 316         self.teleport_next = teleport_first;
 317         teleport_first = self;
 318 }
 319
 320 void WarpZone_PostTeleportPlayer_Callback(entity pl)
 321 {
 322         UpdateCSQCProjectileAfterTeleport(pl);
 323         if(pl.classname == "player")
 324         {
 325                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 326                 pl.oldvelocity = pl.velocity;
 327                 // reset teleport time tracking too (or multijump can cause insane speeds)
 328                 pl.lastteleporttime = time;
 329         }
 330 }