qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teams_matter)
   4                 self.team = activator.team;
   5 }
   6
   7 #define TDEATHLOOP(o) \
   8         entity head; \
   9         vector deathmin; \
  10         vector deathmax; \
  11         float deathradius; \
  12         deathmin = (o) + player.mins; \
  13         deathmax = (o) + player.maxs; \
  14         if(telefragmin != telefragmax) \
  15         { \
  16                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x; \
  17                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y; \
  18                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z; \
  19                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x; \
  20                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y; \
  21                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z; \
  22         } \
  23         deathradius = max(vlen(deathmin), vlen(deathmax)); \
  24         for(head = findradius(o, deathradius); head; head = head.chain) \
  25                 if(head != player) \
  26                         if(head.takedamage) \
  27                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  28
  29
  30 float check_tdeath(entity player, vector org, vector telefragmin, vector telefragmax)
  31 {
  32         if (player.classname == "player" && player.health >= 1)
  33         {
  34                 TDEATHLOOP(org)
  35                 {
  36                         if not(teams_matter && autocvar_g_telefrags_teamplay && head.team == player.team)
  37                                 if(head.classname == "player")
  38                                         if(head.health >= 1)
  39                                                 return 1;
  40                 }
  41         }
  42         return 0;
  43 }
  44 float tdeath_hit;
  45 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
  46 {
  47         TDEATHLOOP(player.origin)
  48         {
  49                 if (player.classname == "player" && player.health >= 1)
  50                 {
  51                         if not(teams_matter && autocvar_g_telefrags_teamplay && head.team == player.team)
  52                         {
  53                                 if(head.classname == "player")
  54                                         if(head.health >= 1)
  55                                                 ++tdeath_hit;
  56                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                         }
  58                 }
  59                 else // dead bodies and monsters gib themselves instead of telefragging
  60                         Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  61         }
  62 }
  63
  64 void spawn_tdeath(vector v0, entity e, vector v)
  65 {
  66         tdeath(e, e, e, '0 0 0', '0 0 0');
  67 }
  68
  69 .entity pusher;
  70 #define TELEPORT_FLAG_SOUND 1
  71 #define TELEPORT_FLAG_PARTICLES 2
  72 #define TELEPORT_FLAG_TDEATH 4
  73 #define TELEPORT_FLAG_FORCE_TDEATH 8
  74
  75 #define TELEPORT_FLAGS_WARPZONE   0
  76 #define TELEPORT_FLAGS_PORTAL     (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH | TELEPORT_FLAG_FORCE_TDEATH)
  77 #define TELEPORT_FLAGS_TELEPORTER (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH)
  78 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax, float tflags)
  79 {
  80         entity telefragger;
  81         vector from;
  82
  83         if(teleporter.owner)
  84                 telefragger = teleporter.owner;
  85         else
  86                 telefragger = player;
  87
  88         makevectors (to_angles);
  89
  90         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  91         {
  92                 if(tflags & TELEPORT_FLAG_SOUND)
  93                         sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  94                 if(tflags & TELEPORT_FLAG_PARTICLES)
  95                 {
  96                         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  97                         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  98                 }
  99                 self.pushltime = time + 0.2;
 100         }
 101
 102         // Relocate the player
 103         // assuming to allows PL_MIN to PL_MAX box and some more
 104         from = player.origin;
 105         setorigin (player, to);
 106         player.oldorigin = to; // don't undo the teleport by unsticking
 107         player.angles = to_angles;
 108         player.fixangle = TRUE;
 109         player.velocity = to_velocity;
 110         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
 111
 112         UpdateCSQCProjectileAfterTeleport(player);
 113
 114         if(player.classname == "player")
 115         {
 116                 if(tflags & TELEPORT_FLAG_TDEATH)
 117                         if(player.takedamage && player.deadflag == DEAD_NO && !g_race && !g_cts && (autocvar_g_telefrags || (tflags & TELEPORT_FLAG_FORCE_TDEATH)))
 118                                 tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
 119
 120                 // player no longer is on ground
 121                 player.flags &~= FL_ONGROUND;
 122
 123                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 124                 player.oldvelocity = player.velocity;
 125
 126                 // reset tracking of who pushed you into a hazard (for kill credit)
 127                 if(teleporter.owner)
 128                 {
 129                         player.pusher = teleporter.owner;
 130                         player.pushltime = time + autocvar_g_maxpushtime;
 131                 }
 132                 else
 133                 {
 134                         player.pushltime = 0;
 135                 }
 136
 137                 player.lastteleporttime = time;
 138         }
 139 }
 140
 141 void Teleport_Touch (void)
 142 {
 143         entity oldself, e;
 144         vector o;
 145         float p;
 146         string s;
 147
 148         if (self.active != ACTIVE_ACTIVE)
 149                 return;
 150
 151         if (other.health < 1)
 152                 return;
 153         if not(other.flags & FL_CLIENT) // FIXME: Make missiles firable through the teleport too
 154                 return;
 155
 156         if(self.team)
 157                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 158                         return;
 159
 160         EXACTTRIGGER_TOUCH;
 161
 162         makevectors(self.enemy.mangle);
 163
 164         if(other.classname == "player")
 165                 RemoveGrapplingHook(other);
 166
 167         if(self.enemy)
 168         {
 169                 e = self.enemy;
 170         }
 171         else
 172         {
 173                 RandomSelection_Init();
 174                 for(e = world; (e = find(e, targetname, self.target)); )
 175                 {
 176                         p = 1;
 177                         if(autocvar_g_telefrags_avoid)
 178                         {
 179                                 o = e.origin + '0 0 1' * (1 - other.mins_z - 24);
 180                                 if(check_tdeath(other, o, '0 0 0', '0 0 0'))
 181                                         p = 0;
 182                         }
 183                         if(e.cnt)
 184                                 RandomSelection_Add(e, 0, string_null, e.cnt, p);
 185                         else
 186                                 RandomSelection_Add(e, 0, string_null, 1, p);
 187                 }
 188                 e = RandomSelection_chosen_ent;
 189         }
 190
 191         if(!e)
 192         {
 193                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 194         }
 195
 196         if(e.speed)
 197                 if(vlen(other.velocity) > e.speed)
 198                         other.velocity = normalize(other.velocity) * max(0, e.speed);
 199         if(autocvar_g_teleport_maxspeed)
 200                 if(vlen(other.velocity) > autocvar_g_teleport_maxspeed)
 201                         other.velocity = normalize(other.velocity) * max(0, autocvar_g_teleport_maxspeed);
 202
 203         o = e.origin + '0 0 1' * (1 - other.mins_z - 24);
 204         TeleportPlayer(self, other, o, e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 205
 206         activator = other;
 207         s = self.target; self.target = string_null;
 208         SUB_UseTargets();
 209         if not(self.target) self.target = s;
 210
 211         oldself = self;
 212         self = e;
 213         SUB_UseTargets();
 214         self = oldself;
 215 }
 216
 217 void spawnfunc_info_teleport_destination (void)
 218 {
 219         self.classname = "info_teleport_destination";
 220
 221         self.mangle = self.angles;
 222         self.angles = '0 0 0';
 223
 224         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 225         setorigin (self, self.origin);
 226
 227         IFTARGETED
 228         {
 229         }
 230         else
 231                 objerror ("^3Teleport destination without a targetname");
 232 }
 233
 234 void spawnfunc_misc_teleporter_dest (void)
 235 {
 236         spawnfunc_info_teleport_destination();
 237 }
 238
 239 void spawnfunc_target_teleporter (void)
 240 {
 241         spawnfunc_info_teleport_destination();
 242 }
 243
 244 void teleport_findtarget (void)
 245 {
 246         entity e;
 247         float n;
 248
 249         RandomSelection_Init();
 250         n = 0;
 251         for(e = world; (e = find(e, targetname, self.target)); )
 252         {
 253                 ++n;
 254                 if(e.movetype == MOVETYPE_NONE)
 255                         RandomSelection_Add(e, 0, string_null, 1, 1);
 256                 if(e.classname != "info_teleport_destination")
 257                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 258         }
 259         if(RandomSelection_chosen_ent)
 260                 waypoint_spawnforteleporter(self, RandomSelection_chosen_ent.origin, 0);
 261
 262         if(n == 0)
 263         {
 264                 // no dest!
 265                 objerror ("Teleporter with nonexistant target");
 266                 return;
 267         }
 268         else if(n == 1)
 269         {
 270                 // exactly one dest - bots love that
 271                 self.enemy = find(e, targetname, self.target);
 272                 self.dest = self.enemy.origin;
 273         }
 274         else
 275         {
 276                 // have to use random selection every single time
 277                 self.enemy = world;
 278         }
 279
 280         // now enable touch
 281         self.touch = Teleport_Touch;
 282 }
 283
 284 void spawnfunc_trigger_teleport (void)
 285 {
 286         self.angles = '0 0 0';
 287
 288         EXACTTRIGGER_INIT;
 289
 290         self.active = ACTIVE_ACTIVE;
 291
 292         self.use = trigger_teleport_use;
 293
 294         // this must be called to spawn the teleport waypoints for bots
 295         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 296
 297         if (!self.target)
 298         {
 299                 objerror ("Teleporter with no target");
 300                 return;
 301         }
 302 }
 303
 304 void WarpZone_PostTeleportPlayer_Callback(entity pl)
 305 {
 306         UpdateCSQCProjectileAfterTeleport(pl);
 307         if(pl.classname == "player")
 308         {
 309                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 310                 pl.oldvelocity = pl.velocity;
 311                 // reset teleport time tracking too (or multijump can cause insane speeds)
 312                 pl.lastteleporttime = time;
 313         }
 314 }