Merged master
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / teamplay.qc
1 #include "teamplay.qh"
2
3 #include "client.qh"
4 #include "race.qh"
5 #include "scores.qh"
6 #include "scores_rules.qh"
7
8 #include "bot/api.qh"
9
10 #include "command/vote.qh"
11
12 #include "mutators/_mod.qh"
13
14 #include "../common/deathtypes/all.qh"
15 #include "../common/gamemodes/_mod.qh"
16 #include "../common/teams.qh"
17
18 void TeamchangeFrags(entity e)
19 {
20         PlayerScore_Clear(e);
21 }
22
23 void LogTeamchange(float player_id, float team_number, float type)
24 {
25         if(!autocvar_sv_eventlog)
26                 return;
27
28         if(player_id < 1)
29                 return;
30
31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
32 }
33
34 void default_delayedinit(entity this)
35 {
36         if(!scores_initialized)
37                 ScoreRules_generic();
38 }
39
40 void ActivateTeamplay()
41 {
42         serverflags |= SERVERFLAG_TEAMPLAY;
43         teamplay = 1;
44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
45 }
46
47 void InitGameplayMode()
48 {
49         VoteReset();
50
51         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
52         get_mi_min_max(1);
53         world.mins = mi_min;
54         world.maxs = mi_max;
55         // currently, NetRadiant's limit is 131072 qu for each side
56         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
57         // set the distance according to map size but don't go over the limit to avoid issues with float precision
58         // in case somebody makes extremely large maps
59         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
60
61         MapInfo_LoadMapSettings(mapname);
62         serverflags &= ~SERVERFLAG_TEAMPLAY;
63         teamplay = 0;
64         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
65
66         if (!cvar_value_issafe(world.fog))
67         {
68                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
69                 world.fog = string_null;
70         }
71         if(MapInfo_Map_fog != "")
72                 if(MapInfo_Map_fog == "none")
73                         world.fog = string_null;
74                 else
75                         world.fog = strzone(MapInfo_Map_fog);
76         clientstuff = strzone(MapInfo_Map_clientstuff);
77
78         MapInfo_ClearTemps();
79
80         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
81
82         cache_mutatormsg = strzone("");
83         cache_lastmutatormsg = strzone("");
84
85         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
86 }
87
88 string GetClientVersionMessage(entity this)
89 {
90         if (CS(this).version_mismatch) {
91                 if(CS(this).version < autocvar_gameversion) {
92                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
93                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
94                 } else {
95                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
96                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
97                 }
98         } else {
99                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
100         }
101 }
102
103 string getwelcomemessage(entity this)
104 {
105         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
106         string modifications = M_ARGV(0, string);
107
108         if(g_weaponarena)
109         {
110                 if(g_weaponarena_random)
111                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
112                 else
113                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
114         }
115         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
116                 modifications = strcat(modifications, ", No start weapons");
117         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
118                 modifications = strcat(modifications, ", Low gravity");
119         if(g_weapon_stay && !g_cts)
120                 modifications = strcat(modifications, ", Weapons stay");
121         if(g_jetpack)
122                 modifications = strcat(modifications, ", Jet pack");
123         if(autocvar_g_powerups == 0)
124                 modifications = strcat(modifications, ", No powerups");
125         if(autocvar_g_powerups > 0)
126                 modifications = strcat(modifications, ", Powerups");
127         modifications = substring(modifications, 2, strlen(modifications) - 2);
128
129         string versionmessage = GetClientVersionMessage(this);
130         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
131
132         if(modifications != "")
133                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
134
135         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
136         {
137                 if(cache_lastmutatormsg)
138                         strunzone(cache_lastmutatormsg);
139                 if(cache_mutatormsg)
140                         strunzone(cache_mutatormsg);
141                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
142                 cache_mutatormsg = strzone(cache_lastmutatormsg);
143         }
144
145         if (cache_mutatormsg != "") {
146                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
147         }
148
149         string mutator_msg = "";
150         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
151         mutator_msg = M_ARGV(0, string);
152
153         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
154
155         string motd = autocvar_sv_motd;
156         if (motd != "") {
157                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
158         }
159         return s;
160 }
161
162 void setcolor(entity this, int clr)
163 {
164 #if 0
165         this.clientcolors = clr;
166         this.team = (clr & 15) + 1;
167 #else
168         builtin_setcolor(this, clr);
169 #endif
170 }
171
172 void SetPlayerColors(entity player, float _color)
173 {
174         float pants = _color & 0x0F;
175         float shirt = _color & 0xF0;
176         if (teamplay)
177         {
178                 setcolor(player, 16 * pants + pants);
179         }
180         else
181         {
182                 setcolor(player, shirt + pants);
183         }
184 }
185
186 bool SetPlayerTeamSimple(entity player, int teamnum)
187 {
188         if (player.team == teamnum)
189         {
190                 // This is important when players join the game and one of their color
191                 // matches the team color while other doesn't. For example [BOT]Lion.
192                 SetPlayerColors(player, teamnum - 1);
193                 return true;
194         }
195         if (MUTATOR_CALLHOOK(Player_ChangeTeam, player, Team_TeamToNumber(
196                 player.team), Team_TeamToNumber(teamnum)) == true)
197         {
198                 // Mutator has blocked team change.
199                 return false;
200         }
201         int oldteam = player.team;
202         SetPlayerColors(player, teamnum - 1);
203         MUTATOR_CALLHOOK(Player_ChangedTeam, player, oldteam, player.team);
204         return true;
205 }
206
207 void SetPlayerTeam(entity player, int destinationteam, int sourceteam, bool noprint)
208 {
209         int teamnum = Team_NumberToTeam(destinationteam);
210         if (!SetPlayerTeamSimple(player, teamnum))
211         {
212                 return;
213         }
214         LogTeamchange(player.playerid, player.team, 3);  // log manual team join
215         if (noprint)
216         {
217                 return;
218         }
219         bprint(playername(player, false), "^7 has changed from ", Team_NumberToColoredFullName(sourceteam), "^7 to ", Team_NumberToColoredFullName(destinationteam), "\n");
220 }
221
222 // set c1...c4 to show what teams are allowed
223 void CheckAllowedTeams (entity for_whom)
224 {
225         int teams_mask = 0;
226
227         c1 = c2 = c3 = c4 = -1;
228         numbotsteam1 = numbotsteam2 = numbotsteam3 = numbotsteam4 = 0;
229
230         string teament_name = string_null;
231
232         bool mutator_returnvalue = MUTATOR_CALLHOOK(CheckAllowedTeams, teams_mask, teament_name, for_whom);
233         teams_mask = M_ARGV(0, float);
234         teament_name = M_ARGV(1, string);
235
236         if(!mutator_returnvalue)
237         {
238                 if(teams_mask & BIT(0)) c1 = 0;
239                 if(teams_mask & BIT(1)) c2 = 0;
240                 if(teams_mask & BIT(2)) c3 = 0;
241                 if(teams_mask & BIT(3)) c4 = 0;
242         }
243
244         // find out what teams are allowed if necessary
245         if(teament_name)
246         {
247                 entity head = find(NULL, classname, teament_name);
248                 while(head)
249                 {
250                         switch(head.team)
251                         {
252                                 case NUM_TEAM_1: c1 = 0; break;
253                                 case NUM_TEAM_2: c2 = 0; break;
254                                 case NUM_TEAM_3: c3 = 0; break;
255                                 case NUM_TEAM_4: c4 = 0; break;
256                         }
257
258                         head = find(head, classname, teament_name);
259                 }
260         }
261
262         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
263         if(AvailableTeams() == 2)
264         if(autocvar_bot_vs_human && for_whom)
265         {
266                 if(autocvar_bot_vs_human > 0)
267                 {
268                         // find last team available
269
270                         if(IS_BOT_CLIENT(for_whom))
271                         {
272                                 if(c4 >= 0) { c3 = c2 = c1 = -1; }
273                                 else if(c3 >= 0) { c4 = c2 = c1 = -1; }
274                                 else { c4 = c3 = c1 = -1; }
275                                 // no further cases, we know at least 2 teams exist
276                         }
277                         else
278                         {
279                                 if(c1 >= 0) { c2 = c3 = c4 = -1; }
280                                 else if(c2 >= 0) { c1 = c3 = c4 = -1; }
281                                 else { c1 = c2 = c4 = -1; }
282                                 // no further cases, bots have one of the teams
283                         }
284                 }
285                 else
286                 {
287                         // find first team available
288
289                         if(IS_BOT_CLIENT(for_whom))
290                         {
291                                 if(c1 >= 0) { c2 = c3 = c4 = -1; }
292                                 else if(c2 >= 0) { c1 = c3 = c4 = -1; }
293                                 else { c1 = c2 = c4 = -1; }
294                                 // no further cases, we know at least 2 teams exist
295                         }
296                         else
297                         {
298                                 if(c4 >= 0) { c3 = c2 = c1 = -1; }
299                                 else if(c3 >= 0) { c4 = c2 = c1 = -1; }
300                                 else { c4 = c3 = c1 = -1; }
301                                 // no further cases, bots have one of the teams
302                         }
303                 }
304         }
305
306         if(!for_whom)
307                 return;
308
309         // if player has a forced team, ONLY allow that one
310         if(for_whom.team_forced == NUM_TEAM_1 && c1 >= 0)
311                 c2 = c3 = c4 = -1;
312         else if(for_whom.team_forced == NUM_TEAM_2 && c2 >= 0)
313                 c1 = c3 = c4 = -1;
314         else if(for_whom.team_forced == NUM_TEAM_3 && c3 >= 0)
315                 c1 = c2 = c4 = -1;
316         else if(for_whom.team_forced == NUM_TEAM_4 && c4 >= 0)
317                 c1 = c2 = c3 = -1;
318 }
319
320 float PlayerValue(entity p)
321 {
322         return 1;
323         // FIXME: it always returns 1...
324 }
325
326 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
327 // teams that are allowed will now have their player counts stored in c1...c4
328 void GetTeamCounts(entity ignore)
329 {
330         if (MUTATOR_CALLHOOK(GetTeamCounts) == true)
331         {
332                 if (c1 >= 0)
333                 {
334                         MUTATOR_CALLHOOK(GetTeamCount, NUM_TEAM_1, ignore, c1, numbotsteam1,
335                                 lowestplayerteam1, lowestbotteam1);
336                         c1 = M_ARGV(2, float);
337                         numbotsteam1 = M_ARGV(3, float);
338                         lowestplayerteam1 = M_ARGV(4, entity);
339                         lowestbotteam1 = M_ARGV(5, entity);
340                 }
341                 if (c2 >= 0)
342                 {
343                         MUTATOR_CALLHOOK(GetTeamCount, NUM_TEAM_2, ignore, c2, numbotsteam2,
344                                 lowestplayerteam2, lowestbotteam2);
345                         c2 = M_ARGV(2, float);
346                         numbotsteam2 = M_ARGV(3, float);
347                         lowestplayerteam2 = M_ARGV(4, entity);
348                         lowestbotteam2 = M_ARGV(5, entity);
349                 }
350                 if (c3 >= 0)
351                 {
352                         MUTATOR_CALLHOOK(GetTeamCount, NUM_TEAM_3, ignore, c3, numbotsteam3,
353                                 lowestplayerteam3, lowestbotteam3);
354                         c3 = M_ARGV(2, float);
355                         numbotsteam3 = M_ARGV(3, float);
356                         lowestplayerteam3 = M_ARGV(4, entity);
357                         lowestbotteam3 = M_ARGV(5, entity);
358                 }
359                 if (c4 >= 0)
360                 {
361                         MUTATOR_CALLHOOK(GetTeamCount, NUM_TEAM_4, ignore, c4, numbotsteam4,
362                                 lowestplayerteam4, lowestbotteam4);
363                         c4 = M_ARGV(2, float);
364                         numbotsteam4 = M_ARGV(3, float);
365                         lowestplayerteam4 = M_ARGV(4, entity);
366                         lowestbotteam4 = M_ARGV(5, entity);
367                 }
368         }
369         else
370         {
371                 float value, bvalue;
372                 // now count how many players are on each team already
373                 float lowestplayerscore1 = FLOAT_MAX;
374                 float lowestbotscore1 = FLOAT_MAX;
375                 float lowestplayerscore2 = FLOAT_MAX;
376                 float lowestbotscore2 = FLOAT_MAX;
377                 float lowestplayerscore3 = FLOAT_MAX;
378                 float lowestbotscore3 = FLOAT_MAX;
379                 float lowestplayerscore4 = FLOAT_MAX;
380                 float lowestbotscore4 = FLOAT_MAX;
381                 FOREACH_CLIENT(true, LAMBDA(
382                         float t;
383                         if (IS_PLAYER(it) || it.caplayer)
384                         {
385                                 t = it.team;
386                         }
387                         else if (it.team_forced > 0)
388                         {
389                                 t = it.team_forced; // reserve the spot
390                         }
391                         else
392                         {
393                                 continue;
394                         }
395                         if (it == ignore)
396                         {
397                                 continue;
398                         }
399                         value = PlayerValue(it);
400                         if (IS_BOT_CLIENT(it))
401                         {
402                                 bvalue = value;
403                         }
404                         else
405                         {
406                                 bvalue = 0;
407                         }
408                         if (value == 0)
409                         {
410                                 continue;
411                         }
412                         switch (t)
413                         {
414                                 case NUM_TEAM_1:
415                                 {
416                                         if (c1 < 0)
417                                         {
418                                                 break;
419                                         }
420                                         c1 += value;
421                                         numbotsteam1 += bvalue;
422                                         float tempscore = PlayerScore_Get(it, SP_SCORE);
423                                         if (!bvalue)
424                                         {
425                                                 if (tempscore < lowestplayerscore1)
426                                                 {
427                                                         lowestplayerteam1 = it;
428                                                         lowestplayerscore1 = tempscore;
429                                                 }
430                                                 break;
431                                         }
432                                         if (tempscore < lowestbotscore1)
433                                         {
434                                                 lowestbotteam1 = it;
435                                                 lowestbotscore1 = tempscore;
436                                         }
437                                         break;
438                                 }
439                                 case NUM_TEAM_2:
440                                 {
441                                         if (c2 < 0)
442                                         {
443                                                 break;
444                                         }
445                                         c2 += value;
446                                         numbotsteam2 += bvalue;
447                                         float tempscore = PlayerScore_Get(it, SP_SCORE);
448                                         if (!bvalue)
449                                         {
450                                                 if (tempscore < lowestplayerscore2)
451                                                 {
452                                                         lowestplayerteam2 = it;
453                                                         lowestplayerscore2 = tempscore;
454                                                 }
455                                                 break;
456                                         }
457                                         if (tempscore < lowestbotscore2)
458                                         {
459                                                 lowestbotteam2 = it;
460                                                 lowestbotscore2 = tempscore;
461                                         }
462                                         break;
463                                 }
464                                 case NUM_TEAM_3:
465                                 {
466                                         if (c3 < 0)
467                                         {
468                                                 break;
469                                         }
470                                         c3 += value;
471                                         numbotsteam3 += bvalue;
472                                         float tempscore = PlayerScore_Get(it, SP_SCORE);
473                                         if (!bvalue)
474                                         {
475                                                 if (tempscore < lowestplayerscore3)
476                                                 {
477                                                         lowestplayerteam3 = it;
478                                                         lowestplayerscore3 = tempscore;
479                                                 }
480                                                 break;
481                                         }
482                                         if (tempscore < lowestbotscore3)
483                                         {
484                                                 lowestbotteam3 = it;
485                                                 lowestbotscore3 = tempscore;
486                                         }
487                                         break;
488                                 }
489                                 case NUM_TEAM_4:
490                                 {
491                                         if (c4 < 0)
492                                         {
493                                                 break;
494                                         }
495                                         c4 += value;
496                                         numbotsteam4 += bvalue;
497                                         float tempscore = PlayerScore_Get(it, SP_SCORE);
498                                         if (!bvalue)
499                                         {
500                                                 if (tempscore < lowestplayerscore4)
501                                                 {
502                                                         lowestplayerteam4 = it;
503                                                         lowestplayerscore4 = tempscore;
504                                                 }
505                                                 break;
506                                         }
507                                         if (tempscore < lowestbotscore4)
508                                         {
509                                                 lowestbotteam4 = it;
510                                                 lowestbotscore4 = tempscore;
511                                         }
512                                         break;
513                                 }
514                         }
515                 ));
516         }
517
518         // if the player who has a forced team has not joined yet, reserve the spot
519         if(autocvar_g_campaign)
520         {
521                 switch(autocvar_g_campaign_forceteam)
522                 {
523                         case 1: if(c1 == numbotsteam1) ++c1; break;
524                         case 2: if(c2 == numbotsteam2) ++c2; break;
525                         case 3: if(c3 == numbotsteam3) ++c3; break;
526                         case 4: if(c4 == numbotsteam4) ++c4; break;
527                 }
528         }
529 }
530
531 bool IsTeamSmallerThanTeam(int teama, int teamb, entity e, bool usescore)
532 {
533         // equal
534         if (teama == teamb)
535         {
536                 return false;
537         }
538         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
539         float numplayersteama = -1, numplayersteamb = -1;
540         float numbotsteama = 0, numbotsteamb = 0;
541         float scoreteama = 0, scoreteamb = 0;
542
543         switch (teama)
544         {
545                 case 1: numplayersteama = c1; numbotsteama = numbotsteam1; scoreteama = team1_score; break;
546                 case 2: numplayersteama = c2; numbotsteama = numbotsteam2; scoreteama = team2_score; break;
547                 case 3: numplayersteama = c3; numbotsteama = numbotsteam3; scoreteama = team3_score; break;
548                 case 4: numplayersteama = c4; numbotsteama = numbotsteam4; scoreteama = team4_score; break;
549         }
550         switch (teamb)
551         {
552                 case 1: numplayersteamb = c1; numbotsteamb = numbotsteam1; scoreteamb = team1_score; break;
553                 case 2: numplayersteamb = c2; numbotsteamb = numbotsteam2; scoreteamb = team2_score; break;
554                 case 3: numplayersteamb = c3; numbotsteamb = numbotsteam3; scoreteamb = team3_score; break;
555                 case 4: numplayersteamb = c4; numbotsteamb = numbotsteam4; scoreteamb = team4_score; break;
556         }
557
558         // invalid
559         if (numplayersteama < 0 || numplayersteamb < 0)
560                 return false;
561
562         if ((IS_REAL_CLIENT(e) && bots_would_leave))
563         {
564                 numplayersteama -= numbotsteama;
565                 numplayersteamb -= numbotsteamb;
566         }
567         if (!usescore)
568         {
569                 return numplayersteama < numplayersteamb;
570         }
571         if (numplayersteama < numplayersteamb)
572         {
573                 return true;
574         }
575         if (numplayersteama > numplayersteamb)
576         {
577                 return false;
578         }
579         return scoreteama < scoreteamb; 
580 }
581
582 bool IsTeamEqualToTeam(int teama, int teamb, entity e, bool usescore)
583 {
584         // equal
585         if (teama == teamb)
586         {
587                 return true;
588         }
589         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
590         float numplayersteama = -1, numplayersteamb = -1;
591         float numbotsteama = 0, numbotsteamb = 0;
592         float scoreteama = 0, scoreteamb = 0;
593
594         switch (teama)
595         {
596                 case 1: numplayersteama = c1; numbotsteama = numbotsteam1; scoreteama = team1_score; break;
597                 case 2: numplayersteama = c2; numbotsteama = numbotsteam2; scoreteama = team2_score; break;
598                 case 3: numplayersteama = c3; numbotsteama = numbotsteam3; scoreteama = team3_score; break;
599                 case 4: numplayersteama = c4; numbotsteama = numbotsteam4; scoreteama = team4_score; break;
600         }
601         switch (teamb)
602         {
603                 case 1: numplayersteamb = c1; numbotsteamb = numbotsteam1; scoreteamb = team1_score; break;
604                 case 2: numplayersteamb = c2; numbotsteamb = numbotsteam2; scoreteamb = team2_score; break;
605                 case 3: numplayersteamb = c3; numbotsteamb = numbotsteam3; scoreteamb = team3_score; break;
606                 case 4: numplayersteamb = c4; numbotsteamb = numbotsteam4; scoreteamb = team4_score; break;
607         }
608
609         // invalid
610         if (numplayersteama < 0 || numplayersteamb < 0)
611                 return false;
612
613         if ((IS_REAL_CLIENT(e) && bots_would_leave))
614         {
615                 numplayersteama -= numbotsteama;
616                 numplayersteamb -= numbotsteamb;
617         }
618         if (!usescore)
619         {
620                 return numplayersteama == numplayersteamb;
621         }
622         if (numplayersteama < numplayersteamb)
623         {
624                 return false;
625         }
626         if (numplayersteama > numplayersteamb)
627         {
628                 return false;
629         }
630         return scoreteama == scoreteamb;        
631 }
632
633 int FindBestTeams(entity player, bool usescore)
634 {
635         if (MUTATOR_CALLHOOK(FindBestTeams, player) == true)
636         {
637                 return M_ARGV(1, float);
638         }
639         int teambits = 0;
640         int previousteam = 0;
641         if (c1 >= 0)
642         {
643                 teambits = BIT(0);
644                 previousteam = 1;
645         }
646         if (c2 >= 0)
647         {
648                 if (previousteam == 0)
649                 {
650                         teambits = BIT(1);
651                         previousteam = 2;
652                 }
653                 else if (IsTeamSmallerThanTeam(2, previousteam, player, usescore))
654                 {
655                         teambits = BIT(1);
656                         previousteam = 2;
657                 }
658                 else if (IsTeamEqualToTeam(2, previousteam, player, usescore))
659                 {
660                         teambits |= BIT(1);
661                         previousteam = 2;
662                 }
663         }
664         if (c3 >= 0)
665         {
666                 if (previousteam == 0)
667                 {
668                         teambits = BIT(2);
669                         previousteam = 3;
670                 }
671                 else if (IsTeamSmallerThanTeam(3, previousteam, player, usescore))
672                 {
673                         teambits = BIT(2);
674                         previousteam = 3;
675                 }
676                 else if (IsTeamEqualToTeam(3, previousteam, player, usescore))
677                 {
678                         teambits |= BIT(2);
679                         previousteam = 3;
680                 }
681         }
682         if (c4 >= 0)
683         {
684                 if (previousteam == 0)
685                 {
686                         teambits = BIT(3);
687                 }
688                 else if (IsTeamSmallerThanTeam(4, previousteam, player, usescore))
689                 {
690                         teambits = BIT(3);
691                 }
692                 else if (IsTeamEqualToTeam(4, previousteam, player, usescore))
693                 {
694                         teambits |= BIT(3);
695                 }
696         }
697         return teambits;
698 }
699
700 // returns # of smallest team (1, 2, 3, 4)
701 // NOTE: Assumes CheckAllowedTeams has already been called!
702 float FindSmallestTeam(entity pl, float ignore_pl)
703 {
704         // count how many players are in each team
705         if (ignore_pl)
706         {
707                 GetTeamCounts(pl);
708         }
709         else
710         {
711                 GetTeamCounts(NULL);
712         }
713         int teambits = FindBestTeams(pl, true);
714         if (teambits == 0)
715         {
716                 error(sprintf("No teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
717         }
718         RandomSelection_Init();
719         if ((teambits & BIT(0)) != 0)
720         {
721                 RandomSelection_AddFloat(1, 1, 1);
722         }
723         if ((teambits & BIT(1)) != 0)
724         {
725                 RandomSelection_AddFloat(2, 1, 1);
726         }
727         if ((teambits & BIT(2)) != 0)
728         {
729                 RandomSelection_AddFloat(3, 1, 1);
730         }
731         if ((teambits & BIT(3)) != 0)
732         {
733                 RandomSelection_AddFloat(4, 1, 1);
734         }
735         return RandomSelection_chosen_float;
736 }
737
738 int JoinBestTeam(entity this, bool only_return_best, bool forcebestteam)
739 {
740         // don't join a team if we're not playing a team game
741         if (!teamplay)
742         {
743                 return 0;
744         }
745
746         // find out what teams are available
747         CheckAllowedTeams(this);
748
749         float selectedteam;
750
751         // if we don't care what team he ends up on, put him on whatever team he entered as.
752         // if he's not on a valid team, then let other code put him on the smallest team
753         if (!forcebestteam)
754         {
755                 if(     c1 >= 0 && this.team == NUM_TEAM_1)
756                         selectedteam = this.team;
757                 else if(c2 >= 0 && this.team == NUM_TEAM_2)
758                         selectedteam = this.team;
759                 else if(c3 >= 0 && this.team == NUM_TEAM_3)
760                         selectedteam = this.team;
761                 else if(c4 >= 0 && this.team == NUM_TEAM_4)
762                         selectedteam = this.team;
763                 else
764                         selectedteam = -1;
765
766                 if (selectedteam > 0)
767                 {
768                         if (!only_return_best)
769                         {
770                                 SetPlayerTeamSimple(this, selectedteam);
771
772                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
773                                 // when JoinBestTeam is called by client.qc/ClientConnect the player_id is 0 the log attempt is rejected
774                                 LogTeamchange(this.playerid, this.team, 99);
775                         }
776                         return selectedteam;
777                 }
778                 // otherwise end up on the smallest team (handled below)
779         }
780
781         float bestteam = FindSmallestTeam(this, true);
782         if (only_return_best || this.bot_forced_team)
783         {
784                 return bestteam;
785         }
786         bestteam = Team_NumberToTeam(bestteam);
787         if (bestteam == -1)
788         {
789                 error("JoinBestTeam: invalid team\n");
790         }
791         int oldteam = Team_TeamToNumber(this.team);
792         TeamchangeFrags(this);
793         SetPlayerTeamSimple(this, bestteam);
794         LogTeamchange(this.playerid, this.team, 2); // log auto join
795         if (!IS_BOT_CLIENT(this))
796         {
797                 AutoBalanceBots(oldteam, Team_TeamToNumber(bestteam));
798         }
799         if (!IS_DEAD(this) && (MUTATOR_CALLHOOK(Player_ChangeTeamKill, this) ==
800                 false))
801         {
802                 Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
803         }
804         return bestteam;
805 }
806
807 void SV_ChangeTeam(entity this, float _color)
808 {
809         float sourcecolor, destinationcolor, sourceteam, destinationteam;
810
811         // in normal deathmatch we can just apply the color and we're done
812         if(!teamplay)
813                 SetPlayerColors(this, _color);
814
815         if(!IS_CLIENT(this))
816         {
817                 // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
818                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
819                 return;
820         }
821
822         if(!teamplay)
823                 return;
824
825         sourcecolor = this.clientcolors & 0x0F;
826         destinationcolor = _color & 0x0F;
827
828         sourceteam = Team_TeamToNumber(sourcecolor + 1);
829         destinationteam = Team_TeamToNumber(destinationcolor + 1);
830         
831         CheckAllowedTeams(this);
832
833         if (destinationteam == 1 && c1 < 0) destinationteam = 4;
834         if (destinationteam == 4 && c4 < 0) destinationteam = 3;
835         if (destinationteam == 3 && c3 < 0) destinationteam = 2;
836         if (destinationteam == 2 && c2 < 0) destinationteam = 1;
837
838         // not changing teams
839         if (sourcecolor == destinationcolor)
840         {
841                 SetPlayerTeam(this, destinationteam, sourceteam, true);
842                 return;
843         }
844
845         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && CS(this).wasplayer)) {
846                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
847                 return; // changing teams is not allowed
848         }
849
850         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
851         if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
852         {
853                 GetTeamCounts(this);
854                 if ((BIT(destinationteam - 1) & FindBestTeams(this, false)) == 0)
855                 {
856                         Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
857                         return;
858                 }
859         }
860         if(IS_PLAYER(this) && sourceteam != destinationteam)
861         {
862                 // reduce frags during a team change
863                 TeamchangeFrags(this);
864         }
865         SetPlayerTeam(this, destinationteam, sourceteam, !IS_CLIENT(this));
866         AutoBalanceBots(sourceteam, destinationteam);
867         if (!IS_PLAYER(this) || (sourceteam == destinationteam))
868         {
869                 return;
870         }
871         // kill player when changing teams
872         if (IS_DEAD(this) || (MUTATOR_CALLHOOK(Player_ChangeTeamKill, this) == true))
873         {
874                 return;
875         }
876         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
877 }
878
879 void AutoBalanceBots(int sourceteam, int destinationteam)
880 {
881         if ((sourceteam == -1) || (destinationteam == -1))
882         {
883                 return;
884         }
885         if (!autocvar_g_balance_teams ||
886                 !autocvar_g_balance_teams_prevent_imbalance)
887         {
888                 return;
889         }
890         int numplayerssourceteam = 0;
891         int numplayersdestinationteam = 0;
892         entity lowestbotdestinationteam = NULL;
893         switch (sourceteam)
894         {
895                 case 1:
896                 {
897                         numplayerssourceteam = c1;
898                         break;
899                 }
900                 case 2:
901                 {
902                         numplayerssourceteam = c2;
903                         break;
904                 }
905                 case 3:
906                 {
907                         numplayerssourceteam = c3;
908                         break;
909                 }
910                 case 4:
911                 {
912                         numplayerssourceteam = c4;
913                         break;
914                 }
915         }
916         switch (destinationteam)
917         {
918                 case 1:
919                 {
920                         numplayersdestinationteam = c1;
921                         lowestbotdestinationteam = lowestbotteam1;
922                         break;
923                 }
924                 case 2:
925                 {
926                         numplayersdestinationteam = c2;
927                         lowestbotdestinationteam = lowestbotteam2;
928                         break;
929                 }
930                 case 3:
931                 {
932                         numplayersdestinationteam = c3;
933                         lowestbotdestinationteam = lowestbotteam3;
934                         break;
935                 }
936                 case 4:
937                 {
938                         numplayersdestinationteam = c4;
939                         lowestbotdestinationteam = lowestbotteam4;
940                         break;
941                 }
942         }
943         if ((numplayersdestinationteam <= numplayerssourceteam) ||
944                 (lowestbotdestinationteam == NULL))
945         {
946                 return;
947         }
948         SetPlayerTeamSimple(lowestbotdestinationteam, Team_NumberToTeam(sourceteam));
949         if (IS_DEAD(lowestbotdestinationteam) || (MUTATOR_CALLHOOK(
950                 Player_ChangeTeamKill, lowestbotdestinationteam) == true))
951         {
952                 return;
953         }
954         Damage(lowestbotdestinationteam, lowestbotdestinationteam,
955                 lowestbotdestinationteam, 100000, DEATH_TEAMCHANGE.m_id,
956                 lowestbotdestinationteam.origin, '0 0 0');
957 }
958
959 void ShufflePlayerOutOfTeam (float source_team)
960 {
961         float smallestteam, smallestteam_count, steam;
962         float lowest_bot_score, lowest_player_score;
963         entity lowest_bot, lowest_player, selected;
964
965         smallestteam = 0;
966         smallestteam_count = 999999999;
967
968         if(c1 >= 0 && c1 < smallestteam_count)
969         {
970                 smallestteam = 1;
971                 smallestteam_count = c1;
972         }
973         if(c2 >= 0 && c2 < smallestteam_count)
974         {
975                 smallestteam = 2;
976                 smallestteam_count = c2;
977         }
978         if(c3 >= 0 && c3 < smallestteam_count)
979         {
980                 smallestteam = 3;
981                 smallestteam_count = c3;
982         }
983         if(c4 >= 0 && c4 < smallestteam_count)
984         {
985                 smallestteam = 4;
986                 smallestteam_count = c4;
987         }
988
989         if(!smallestteam)
990         {
991                 bprint("warning: no smallest team\n");
992                 return;
993         }
994
995         if(source_team == 1)
996                 steam = NUM_TEAM_1;
997         else if(source_team == 2)
998                 steam = NUM_TEAM_2;
999         else if(source_team == 3)
1000                 steam = NUM_TEAM_3;
1001         else // if(source_team == 4)
1002                 steam = NUM_TEAM_4;
1003
1004         lowest_bot = NULL;
1005         lowest_bot_score = 999999999;
1006         lowest_player = NULL;
1007         lowest_player_score = 999999999;
1008
1009         // find the lowest-scoring player & bot of that team
1010         FOREACH_CLIENT(IS_PLAYER(it) && it.team == steam, LAMBDA(
1011                 if(it.isbot)
1012                 {
1013                         if(it.totalfrags < lowest_bot_score)
1014                         {
1015                                 lowest_bot = it;
1016                                 lowest_bot_score = it.totalfrags;
1017                         }
1018                 }
1019                 else
1020                 {
1021                         if(it.totalfrags < lowest_player_score)
1022                         {
1023                                 lowest_player = it;
1024                                 lowest_player_score = it.totalfrags;
1025                         }
1026                 }
1027         ));
1028
1029         // prefers to move a bot...
1030         if(lowest_bot != NULL)
1031                 selected = lowest_bot;
1032         // but it will move a player if it has to
1033         else
1034                 selected = lowest_player;
1035         // don't do anything if it couldn't find anyone
1036         if(!selected)
1037         {
1038                 bprint("warning: couldn't find a player to move from team\n");
1039                 return;
1040         }
1041
1042         // smallest team gains a member
1043         if(smallestteam == 1)
1044         {
1045                 c1 = c1 + 1;
1046         }
1047         else if(smallestteam == 2)
1048         {
1049                 c2 = c2 + 1;
1050         }
1051         else if(smallestteam == 3)
1052         {
1053                 c3 = c3 + 1;
1054         }
1055         else if(smallestteam == 4)
1056         {
1057                 c4 = c4 + 1;
1058         }
1059         else
1060         {
1061                 bprint("warning: destination team invalid\n");
1062                 return;
1063         }
1064         // source team loses a member
1065         if(source_team == 1)
1066         {
1067                 c1 = c1 + 1;
1068         }
1069         else if(source_team == 2)
1070         {
1071                 c2 = c2 + 2;
1072         }
1073         else if(source_team == 3)
1074         {
1075                 c3 = c3 + 3;
1076         }
1077         else if(source_team == 4)
1078         {
1079                 c4 = c4 + 4;
1080         }
1081         else
1082         {
1083                 bprint("warning: source team invalid\n");
1084                 return;
1085         }
1086
1087         // move the player to the new team
1088         TeamchangeFrags(selected);
1089         SetPlayerTeam(selected, smallestteam, source_team, false);
1090
1091         if (IS_DEAD(selected) || MUTATOR_CALLHOOK(Player_ChangeTeamKill, selected) == true)
1092         {
1093                 return;
1094         }
1095         Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE.m_id, selected.origin, '0 0 0');
1096         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
1097 }