qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &~= SERVERFLAG_TEAMPLAY;
  58
  59         if not(cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_arena)
 119         {
 120                 fraglimit_override = autocvar_g_arena_point_limit;
 121                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 122                 MUTATOR_ADD(gamemode_arena);
 123         }
 124
 125         if(g_ca)
 126         {
 127                 ActivateTeamplay();
 128                 fraglimit_override = autocvar_g_ca_point_limit;
 129                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 130                 MUTATOR_ADD(gamemode_ca);
 131         }
 132
 133         if(g_keyhunt)
 134         {
 135                 ActivateTeamplay();
 136                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 137                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 138                 MUTATOR_ADD(gamemode_keyhunt);
 139         }
 140
 141         if(g_freezetag)
 142         {
 143                 ActivateTeamplay();
 144                 fraglimit_override = autocvar_g_freezetag_point_limit;
 145                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 146                 MUTATOR_ADD(gamemode_freezetag);
 147         }
 148
 149         if(g_assault)
 150         {
 151                 ActivateTeamplay();
 152                 MUTATOR_ADD(gamemode_assault);
 153                 have_team_spawns = -1; // request team spawns
 154         }
 155
 156         if(g_onslaught)
 157         {
 158                 ActivateTeamplay();
 159                 have_team_spawns = -1; // request team spawns
 160                 MUTATOR_ADD(gamemode_onslaught);
 161         }
 162
 163         if(g_race)
 164         {
 165
 166                 if(autocvar_g_race_teams)
 167                 {
 168                         ActivateTeamplay();
 169                         race_teams = bound(2, autocvar_g_race_teams, 4);
 170                         have_team_spawns = -1; // request team spawns
 171                 }
 172                 else
 173                         race_teams = 0;
 174
 175                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 176                 fraglimit_override = autocvar_g_race_laps_limit;
 177                 leadlimit_override = 0; // currently not supported by race
 178         }
 179
 180         if(g_cts)
 181         {
 182                 g_race_qualifying = 1;
 183                 fraglimit_override = 0;
 184                 leadlimit_override = 0;
 185         }
 186
 187         if(g_nexball)
 188         {
 189         fraglimit_override = autocvar_g_nexball_goallimit;
 190         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 191         ActivateTeamplay();
 192         have_team_spawns = -1; // request team spawns
 193             MUTATOR_ADD(gamemode_nexball);
 194         }
 195
 196         if(g_keepaway)
 197         {
 198                 MUTATOR_ADD(gamemode_keepaway);
 199         }
 200
 201         if(g_invasion)
 202         {
 203                 timelimit_override = 0; // no timelimit in invasion, round based
 204                 fraglimit_override = autocvar_g_invasion_round_limit;
 205                 maxrounds = fraglimit_override;
 206                 fraglimit_override = 0; // also no frag limit
 207                 MUTATOR_ADD(gamemode_invasion);
 208         }
 209
 210         if(teamplay)
 211                 entcs_init();
 212
 213         cache_mutatormsg = strzone("");
 214         cache_lastmutatormsg = strzone("");
 215
 216         // enforce the server's universal frag/time limits
 217         if(!autocvar_g_campaign)
 218         {
 219                 if(fraglimit_override >= 0)
 220                         cvar_set("fraglimit", ftos(fraglimit_override));
 221                 if(timelimit_override >= 0)
 222                         cvar_set("timelimit", ftos(timelimit_override));
 223                 if(leadlimit_override >= 0)
 224                         cvar_set("leadlimit", ftos(leadlimit_override));
 225                 if(qualifying_override >= 0)
 226                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 227         }
 228
 229         if(g_race)
 230         {
 231                 // we need to find out the correct value for g_race_qualifying
 232                 if(autocvar_g_campaign)
 233                 {
 234                         g_race_qualifying = 1;
 235                 }
 236                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 237                 {
 238                         g_race_qualifying = 2;
 239                         race_fraglimit = autocvar_fraglimit;
 240                         race_leadlimit = autocvar_leadlimit;
 241                         race_timelimit = autocvar_timelimit;
 242                         cvar_set("fraglimit", "0");
 243                         cvar_set("leadlimit", "0");
 244                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 245                 }
 246                 else
 247                         g_race_qualifying = 0;
 248         }
 249
 250         if(g_race || g_cts)
 251         {
 252                 if(g_race_qualifying)
 253                         independent_players = 1;
 254
 255                 ScoreRules_race();
 256         }
 257
 258         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 259 }
 260
 261 string GetClientVersionMessage() {
 262         string versionmsg;
 263         if (self.version_mismatch) {
 264                 if(self.version < autocvar_gameversion) {
 265                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 266                 } else {
 267                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 268                 }
 269         } else {
 270                 versionmsg = "^2client version and server version are compatible.^8";
 271         }
 272         return versionmsg;
 273 }
 274
 275 string getwelcomemessage(void)
 276 {
 277         string s, modifications, motd;
 278
 279         ret_string = "";
 280         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 281         modifications = ret_string;
 282
 283         if(g_weaponarena)
 284         {
 285                 if(g_weaponarena_random)
 286                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 287                 else
 288                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 289         }
 290         if(autocvar_g_start_weapon_laser == 0)
 291                 modifications = strcat(modifications, ", No start weapons");
 292         if(autocvar_sv_gravity < 800)
 293                 modifications = strcat(modifications, ", Low gravity");
 294         if(g_cloaked && !g_cts)
 295                 modifications = strcat(modifications, ", Cloaked");
 296         if(g_grappling_hook)
 297                 modifications = strcat(modifications, ", Hook");
 298         if(g_midair)
 299                 modifications = strcat(modifications, ", Midair");
 300         if(g_pinata)
 301                 modifications = strcat(modifications, ", Piñata");
 302         if(g_weapon_stay && !g_cts)
 303                 modifications = strcat(modifications, ", Weapons stay");
 304         if(g_bloodloss > 0)
 305                 modifications = strcat(modifications, ", Blood loss");
 306         if(g_jetpack)
 307                 modifications = strcat(modifications, ", Jet pack");
 308         if(autocvar_g_powerups == 0)
 309                 modifications = strcat(modifications, ", No powerups");
 310         if(autocvar_g_powerups > 0)
 311                 modifications = strcat(modifications, ", Powerups");
 312         modifications = substring(modifications, 2, strlen(modifications) - 2);
 313
 314         string versionmessage;
 315         versionmessage = GetClientVersionMessage();
 316
 317         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 318         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 319
 320         if(modifications != "")
 321                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 322
 323         if (g_grappling_hook)
 324                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 325
 326         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 327         {
 328                 if(cache_lastmutatormsg)
 329                         strunzone(cache_lastmutatormsg);
 330                 if(cache_mutatormsg)
 331                         strunzone(cache_mutatormsg);
 332                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 333                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 334         }
 335
 336         if (cache_mutatormsg != "") {
 337                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 338         }
 339
 340         motd = autocvar_sv_motd;
 341         if (motd != "") {
 342                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 343         }
 344         return s;
 345 }
 346
 347 void SetPlayerColors(entity pl, float _color)
 348 {
 349         /*string s;
 350         s = ftos(cl);
 351         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 352         pl.team = cl + 1;
 353         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 354         pl.clientcolors = 16*cl + cl;*/
 355
 356         float pants, shirt;
 357         pants = _color & 0x0F;
 358         shirt = _color & 0xF0;
 359
 360
 361         if(teamplay) {
 362                 setcolor(pl, 16*pants + pants);
 363         } else {
 364                 setcolor(pl, shirt + pants);
 365         }
 366 }
 367
 368 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 369 {
 370         float _color;
 371
 372         if(t == 4)
 373                 _color = NUM_TEAM_4 - 1;
 374         else if(t == 3)
 375                 _color = NUM_TEAM_3 - 1;
 376         else if(t == 2)
 377                 _color = NUM_TEAM_2 - 1;
 378         else
 379                 _color = NUM_TEAM_1 - 1;
 380
 381         SetPlayerColors(pl,_color);
 382
 383         if(t != s) {
 384                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 385
 386                 if(!noprint)
 387                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 388         }
 389
 390 }
 391
 392 // set c1...c4 to show what teams are allowed
 393 void CheckAllowedTeams (entity for_whom)
 394 {
 395         float dm;
 396         entity head;
 397         string teament_name;
 398
 399         c1 = c2 = c3 = c4 = -1;
 400         cb1 = cb2 = cb3 = cb4 = 0;
 401
 402         teament_name = string_null;
 403         if(g_onslaught)
 404         {
 405                 // onslaught is special
 406                 head = findchain(classname, "onslaught_generator");
 407                 while (head)
 408                 {
 409                         if (head.team == NUM_TEAM_1) c1 = 0;
 410                         if (head.team == NUM_TEAM_2) c2 = 0;
 411                         if (head.team == NUM_TEAM_3) c3 = 0;
 412                         if (head.team == NUM_TEAM_4) c4 = 0;
 413                         head = head.chain;
 414                 }
 415         }
 416         else if(g_domination)
 417                 teament_name = "dom_team";
 418         else if(g_ctf)
 419                 teament_name = "ctf_team";
 420         else if(g_tdm)
 421                 teament_name = "tdm_team";
 422         else if(g_nexball)
 423                 teament_name = "nexball_team";
 424         else if(g_assault)
 425                 c1 = c2 = 0; // Assault always has 2 teams
 426         else
 427         {
 428                 // cover anything else by treating it like tdm with no teams spawned
 429                 if(g_race)
 430                         dm = race_teams;
 431                 else
 432                         dm = 2;
 433
 434                 ret_float = dm;
 435                 MUTATOR_CALLHOOK(GetTeamCount);
 436                 dm = ret_float;
 437
 438                 if(dm >= 4)
 439                         c1 = c2 = c3 = c4 = 0;
 440                 else if(dm >= 3)
 441                         c1 = c2 = c3 = 0;
 442                 else
 443                         c1 = c2 = 0;
 444         }
 445
 446         // find out what teams are allowed if necessary
 447         if(teament_name)
 448         {
 449                 head = find(world, classname, teament_name);
 450                 while(head)
 451                 {
 452                         if(!(g_domination && head.netname == ""))
 453                         {
 454                                 if(head.team == NUM_TEAM_1)
 455                                         c1 = 0;
 456                                 else if(head.team == NUM_TEAM_2)
 457                                         c2 = 0;
 458                                 else if(head.team == NUM_TEAM_3)
 459                                         c3 = 0;
 460                                 else if(head.team == NUM_TEAM_4)
 461                                         c4 = 0;
 462                         }
 463                         head = find(head, classname, teament_name);
 464                 }
 465         }
 466
 467         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 468         if(c3==-1 && c4==-1)
 469         if(autocvar_bot_vs_human && for_whom)
 470         {
 471                 if(autocvar_bot_vs_human > 0)
 472                 {
 473                         // bots are all blue
 474                         if(IS_BOT_CLIENT(for_whom))
 475                                 c1 = c3 = c4 = -1;
 476                         else
 477                                 c2 = -1;
 478                 }
 479                 else
 480                 {
 481                         // bots are all red
 482                         if(IS_BOT_CLIENT(for_whom))
 483                                 c2 = c3 = c4 = -1;
 484                         else
 485                                 c1 = -1;
 486                 }
 487         }
 488
 489         // if player has a forced team, ONLY allow that one
 490         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 491                 c2 = c3 = c4 = -1;
 492         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 493                 c1 = c3 = c4 = -1;
 494         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 495                 c1 = c2 = c4 = -1;
 496         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 497                 c1 = c2 = c3 = -1;
 498 }
 499
 500 float PlayerValue(entity p)
 501 {
 502         return 1;
 503         // FIXME: it always returns 1...
 504 }
 505
 506 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 507 // teams that are allowed will now have their player counts stored in c1...c4
 508 void GetTeamCounts(entity ignore)
 509 {
 510         entity head;
 511         float value, bvalue;
 512         // now count how many players are on each team already
 513
 514         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 515         // also remember the lowest-scoring player
 516
 517         FOR_EACH_CLIENT(head)
 518         {
 519                 float t;
 520                 if(IS_PLAYER(head))
 521                         t = head.team;
 522                 else if(head.team_forced > 0)
 523                         t = head.team_forced; // reserve the spot
 524                 else
 525                         continue;
 526                 if(head != ignore)// && head.netname != "")
 527                 {
 528                         value = PlayerValue(head);
 529                         if(IS_BOT_CLIENT(head))
 530                                 bvalue = value;
 531                         else
 532                                 bvalue = 0;
 533                         if(t == NUM_TEAM_1)
 534                         {
 535                                 if(c1 >= 0)
 536                                 {
 537                                         c1 = c1 + value;
 538                                         cb1 = cb1 + bvalue;
 539                                 }
 540                         }
 541                         if(t == NUM_TEAM_2)
 542                         {
 543                                 if(c2 >= 0)
 544                                 {
 545                                         c2 = c2 + value;
 546                                         cb2 = cb2 + bvalue;
 547                                 }
 548                         }
 549                         if(t == NUM_TEAM_3)
 550                         {
 551                                 if(c3 >= 0)
 552                                 {
 553                                         c3 = c3 + value;
 554                                         cb3 = cb3 + bvalue;
 555                                 }
 556                         }
 557                         if(t == NUM_TEAM_4)
 558                         {
 559                                 if(c4 >= 0)
 560                                 {
 561                                         c4 = c4 + value;
 562                                         cb4 = cb4 + bvalue;
 563                                 }
 564                         }
 565                 }
 566         }
 567
 568         // if the player who has a forced team has not joined yet, reserve the spot
 569         if(autocvar_g_campaign)
 570         {
 571                 switch(autocvar_g_campaign_forceteam)
 572                 {
 573                         case 1: if(c1 == cb1) ++c1; break;
 574                         case 2: if(c2 == cb2) ++c2; break;
 575                         case 3: if(c3 == cb3) ++c3; break;
 576                         case 4: if(c4 == cb4) ++c4; break;
 577                 }
 578         }
 579 }
 580
 581 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 582 {
 583         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 584         float f;
 585         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 586
 587         switch(ta)
 588         {
 589                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 590                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 591                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 592                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 593         }
 594         switch(tb)
 595         {
 596                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 597                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 598                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 599                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 600         }
 601
 602         // invalid
 603         if(ca < 0 || cb < 0)
 604                 return FALSE;
 605
 606         // equal
 607         if(ta == tb)
 608                 return TRUE;
 609
 610         if(IS_REAL_CLIENT(e))
 611         {
 612                 if(bots_would_leave)
 613                 {
 614                         ca -= cba * 0.999;
 615                         cb -= cbb * 0.999;
 616                 }
 617         }
 618
 619         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 620         if(ca < 1)
 621                 if(cb >= 1)
 622                         return TRUE;
 623         if(ca >= 1)
 624                 if(cb < 1)
 625                         return FALSE;
 626
 627         // first, normalize
 628         f = max(ca, cb, 1);
 629         ca /= f;
 630         cb /= f;
 631         f = max(sa, sb, 1);
 632         sa /= f;
 633         sb /= f;
 634
 635         // the more we're at the end of the match, the more take scores into account
 636         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 637         ca += (sa - ca) * f;
 638         cb += (sb - cb) * f;
 639
 640         return ca <= cb;
 641 }
 642
 643 // returns # of smallest team (1, 2, 3, 4)
 644 // NOTE: Assumes CheckAllowedTeams has already been called!
 645 float FindSmallestTeam(entity pl, float ignore_pl)
 646 {
 647         float totalteams, t;
 648         totalteams = 0;
 649
 650         // find out what teams are available
 651         //CheckAllowedTeams();
 652
 653         // make sure there are at least 2 teams to join
 654         if(c1 >= 0)
 655                 totalteams = totalteams + 1;
 656         if(c2 >= 0)
 657                 totalteams = totalteams + 1;
 658         if(c3 >= 0)
 659                 totalteams = totalteams + 1;
 660         if(c4 >= 0)
 661                 totalteams = totalteams + 1;
 662
 663         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 664                 totalteams += 1;
 665
 666         if(totalteams <= 1)
 667         {
 668                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 669                         return 1; // special case for campaign and player joining
 670                 else if(g_domination)
 671                         error("Too few teams available for domination\n");
 672                 else if(g_ctf)
 673                         error("Too few teams available for ctf\n");
 674                 else if(g_keyhunt)
 675                         error("Too few teams available for key hunt\n");
 676                 else if(g_freezetag)
 677                         error("Too few teams available for freeze tag\n");
 678                 else
 679                         error("Too few teams available for team deathmatch\n");
 680         }
 681
 682         // count how many players are in each team
 683         if(ignore_pl)
 684                 GetTeamCounts(pl);
 685         else
 686                 GetTeamCounts(world);
 687
 688         RandomSelection_Init();
 689
 690         t = 1;
 691         if(TeamSmallerEqThanTeam(2, t, pl))
 692                 t = 2;
 693         if(TeamSmallerEqThanTeam(3, t, pl))
 694                 t = 3;
 695         if(TeamSmallerEqThanTeam(4, t, pl))
 696                 t = 4;
 697
 698         // now t is the minimum, or A minimum!
 699         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 700                 RandomSelection_Add(world, 1, string_null, 1, 1);
 701         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 702                 RandomSelection_Add(world, 2, string_null, 1, 1);
 703         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 704                 RandomSelection_Add(world, 3, string_null, 1, 1);
 705         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 706                 RandomSelection_Add(world, 4, string_null, 1, 1);
 707
 708         return RandomSelection_chosen_float;
 709 }
 710
 711 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 712 {
 713         float smallest, selectedteam;
 714
 715         // don't join a team if we're not playing a team game
 716         if(!teamplay)
 717                 return 0;
 718
 719         // find out what teams are available
 720         CheckAllowedTeams(pl);
 721
 722         // if we don't care what team he ends up on, put him on whatever team he entered as.
 723         // if he's not on a valid team, then let other code put him on the smallest team
 724         if(!forcebestteam)
 725         {
 726                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 727                         selectedteam = pl.team;
 728                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 729                         selectedteam = pl.team;
 730                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 731                         selectedteam = pl.team;
 732                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 733                         selectedteam = pl.team;
 734                 else
 735                         selectedteam = -1;
 736
 737                 if(selectedteam > 0)
 738                 {
 739                         if(!only_return_best)
 740                         {
 741                                 SetPlayerColors(pl, selectedteam - 1);
 742
 743                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 744                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 745                                 LogTeamchange(pl.playerid, pl.team, 99);
 746                         }
 747                         return selectedteam;
 748                 }
 749                 // otherwise end up on the smallest team (handled below)
 750         }
 751
 752         smallest = FindSmallestTeam(pl, TRUE);
 753
 754         if(!only_return_best && !pl.bot_forced_team)
 755         {
 756                 TeamchangeFrags(self);
 757                 if(smallest == 1)
 758                 {
 759                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 760                 }
 761                 else if(smallest == 2)
 762                 {
 763                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 764                 }
 765                 else if(smallest == 3)
 766                 {
 767                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 768                 }
 769                 else if(smallest == 4)
 770                 {
 771                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 772                 }
 773                 else
 774                 {
 775                         error("smallest team: invalid team\n");
 776                 }
 777
 778                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 779
 780                 if(pl.deadflag == DEAD_NO)
 781                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 782         }
 783
 784         return smallest;
 785 }
 786
 787 //void() ctf_playerchanged;
 788 void SV_ChangeTeam(float _color)
 789 {
 790         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 791
 792         // in normal deathmatch we can just apply the color and we're done
 793         if(!teamplay) {
 794                 SetPlayerColors(self, _color);
 795                 return;
 796         }
 797
 798         scolor = self.clientcolors & 0x0F;
 799         dcolor = _color & 0x0F;
 800
 801         if(scolor == NUM_TEAM_1 - 1)
 802                 steam = 1;
 803         else if(scolor == NUM_TEAM_2 - 1)
 804                 steam = 2;
 805         else if(scolor == NUM_TEAM_3 - 1)
 806                 steam = 3;
 807         else // if(scolor == NUM_TEAM_4 - 1)
 808                 steam = 4;
 809         if(dcolor == NUM_TEAM_1 - 1)
 810                 dteam = 1;
 811         else if(dcolor == NUM_TEAM_2 - 1)
 812                 dteam = 2;
 813         else if(dcolor == NUM_TEAM_3 - 1)
 814                 dteam = 3;
 815         else // if(dcolor == NUM_TEAM_4 - 1)
 816                 dteam = 4;
 817
 818         CheckAllowedTeams(self);
 819
 820         if(dteam == 1 && c1 < 0) dteam = 4;
 821         if(dteam == 4 && c4 < 0) dteam = 3;
 822         if(dteam == 3 && c3 < 0) dteam = 2;
 823         if(dteam == 2 && c2 < 0) dteam = 1;
 824
 825         // not changing teams
 826         if(scolor == dcolor)
 827         {
 828                 //bprint("same team change\n");
 829                 SetPlayerTeam(self, dteam, steam, TRUE);
 830                 return;
 831         }
 832
 833         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 834                 sprint(self, "Team changes not allowed\n");
 835                 return; // changing teams is not allowed
 836         }
 837
 838         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 839         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 840         {
 841                 GetTeamCounts(self);
 842                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 843                 {
 844                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 845                         return;
 846                 }
 847         }
 848
 849 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 850
 851         if(IS_PLAYER(self) && steam != dteam)
 852         {
 853                 // reduce frags during a team change
 854                 TeamchangeFrags(self);
 855         }
 856
 857         SetPlayerTeam(self, dteam, steam, FALSE);
 858
 859         if(IS_PLAYER(self) && steam != dteam)
 860         {
 861                 // kill player when changing teams
 862                 if(self.deadflag == DEAD_NO)
 863                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 864         }
 865 }
 866
 867 void ShufflePlayerOutOfTeam (float source_team)
 868 {
 869         float smallestteam, smallestteam_count, steam;
 870         float lowest_bot_score, lowest_player_score;
 871         entity head, lowest_bot, lowest_player, selected;
 872
 873         smallestteam = 0;
 874         smallestteam_count = 999999999;
 875
 876         if(c1 >= 0 && c1 < smallestteam_count)
 877         {
 878                 smallestteam = 1;
 879                 smallestteam_count = c1;
 880         }
 881         if(c2 >= 0 && c2 < smallestteam_count)
 882         {
 883                 smallestteam = 2;
 884                 smallestteam_count = c2;
 885         }
 886         if(c3 >= 0 && c3 < smallestteam_count)
 887         {
 888                 smallestteam = 3;
 889                 smallestteam_count = c3;
 890         }
 891         if(c4 >= 0 && c4 < smallestteam_count)
 892         {
 893                 smallestteam = 4;
 894                 smallestteam_count = c4;
 895         }
 896
 897         if(!smallestteam)
 898         {
 899                 bprint("warning: no smallest team\n");
 900                 return;
 901         }
 902
 903         if(source_team == 1)
 904                 steam = NUM_TEAM_1;
 905         else if(source_team == 2)
 906                 steam = NUM_TEAM_2;
 907         else if(source_team == 3)
 908                 steam = NUM_TEAM_3;
 909         else // if(source_team == 4)
 910                 steam = NUM_TEAM_4;
 911
 912         lowest_bot = world;
 913         lowest_bot_score = 999999999;
 914         lowest_player = world;
 915         lowest_player_score = 999999999;
 916
 917         // find the lowest-scoring player & bot of that team
 918         FOR_EACH_PLAYER(head)
 919         {
 920                 if(head.team == steam)
 921                 {
 922                         if(head.isbot)
 923                         {
 924                                 if(head.totalfrags < lowest_bot_score)
 925                                 {
 926                                         lowest_bot = head;
 927                                         lowest_bot_score = head.totalfrags;
 928                                 }
 929                         }
 930                         else
 931                         {
 932                                 if(head.totalfrags < lowest_player_score)
 933                                 {
 934                                         lowest_player = head;
 935                                         lowest_player_score = head.totalfrags;
 936                                 }
 937                         }
 938                 }
 939         }
 940
 941         // prefers to move a bot...
 942         if(lowest_bot != world)
 943                 selected = lowest_bot;
 944         // but it will move a player if it has to
 945         else
 946                 selected = lowest_player;
 947         // don't do anything if it couldn't find anyone
 948         if(!selected)
 949         {
 950                 bprint("warning: couldn't find a player to move from team\n");
 951                 return;
 952         }
 953
 954         // smallest team gains a member
 955         if(smallestteam == 1)
 956         {
 957                 c1 = c1 + 1;
 958         }
 959         else if(smallestteam == 2)
 960         {
 961                 c2 = c2 + 1;
 962         }
 963         else if(smallestteam == 3)
 964         {
 965                 c3 = c3 + 1;
 966         }
 967         else if(smallestteam == 4)
 968         {
 969                 c4 = c4 + 1;
 970         }
 971         else
 972         {
 973                 bprint("warning: destination team invalid\n");
 974                 return;
 975         }
 976         // source team loses a member
 977         if(source_team == 1)
 978         {
 979                 c1 = c1 + 1;
 980         }
 981         else if(source_team == 2)
 982         {
 983                 c2 = c2 + 2;
 984         }
 985         else if(source_team == 3)
 986         {
 987                 c3 = c3 + 3;
 988         }
 989         else if(source_team == 4)
 990         {
 991                 c4 = c4 + 4;
 992         }
 993         else
 994         {
 995                 bprint("warning: source team invalid\n");
 996                 return;
 997         }
 998
 999         // move the player to the new team
1000         TeamchangeFrags(selected);
1001         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1002
1003         if(selected.deadflag == DEAD_NO)
1004                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1005         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1006 }
1007
1008 // code from here on is just to support maps that don't have team entities
1009 void tdm_spawnteam (string teamname, float teamcolor)
1010 {
1011         entity e;
1012         e = spawn();
1013         e.classname = "tdm_team";
1014         e.netname = teamname;
1015         e.cnt = teamcolor;
1016         e.team = e.cnt + 1;
1017 }
1018
1019 // spawn some default teams if the map is not set up for tdm
1020 void tdm_spawnteams()
1021 {
1022         float numteams;
1023
1024         numteams = autocvar_g_tdm_teams_override;
1025         if(numteams < 2)
1026                 numteams = autocvar_g_tdm_teams;
1027         numteams = bound(2, numteams, 4);
1028
1029         tdm_spawnteam("Red", NUM_TEAM_1-1);
1030         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1031         if(numteams >= 3)
1032                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1033         if(numteams >= 4)
1034                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1035 }
1036
1037 void tdm_delayedinit()
1038 {
1039         // if no teams are found, spawn defaults
1040         if (find(world, classname, "tdm_team") == world)
1041                 tdm_spawnteams();
1042 }
1043
1044 void tdm_init()
1045 {
1046         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1047 }