qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 vector TeamColor(float teem)
  17 {
  18         switch(teem)
  19         {
  20                 case COLOR_TEAM1:
  21                         return '1 0.0625 0.0625';
  22                 case COLOR_TEAM2:
  23                         return '0.0625 0.0625 1';
  24                 case COLOR_TEAM3:
  25                         return '1 1 0.0625';
  26                 case COLOR_TEAM4:
  27                         return '1 0.0625 1';
  28                 default:
  29                         return '1 1 1';
  30         }
  31 }
  32
  33 string TeamName(float t)
  34 {
  35         return strcat(Team_ColorName(t), " Team");
  36 }
  37 string ColoredTeamName(float t)
  38 {
  39         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  40 }
  41 string TeamNoName(float t)
  42 {
  43         // fixme: Search for team entities and get their .netname's!
  44         if(t == 1)
  45                 return "Red Team";
  46         if(t == 2)
  47                 return "Blue Team";
  48         if(t == 3)
  49                 return "Yellow Team";
  50         if(t == 4)
  51                 return "Pink Team";
  52         return "Neutral Team";
  53 }
  54
  55 void dom_init();
  56 void runematch_init();
  57 void tdm_init();
  58 void entcs_init();
  59
  60 void LogTeamchange(float player_id, float team_number, float type)
  61 {
  62         if(!autocvar_sv_eventlog)
  63                 return;
  64
  65         if(player_id < 1)
  66                 return;
  67
  68         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  69 }
  70
  71 void default_delayedinit()
  72 {
  73         if(!scores_initialized)
  74                 ScoreRules_generic();
  75 }
  76
  77 void ActivateTeamplay()
  78 {
  79         serverflags |= SERVERFLAG_TEAMPLAY;
  80         teamplay = 1;
  81 }
  82
  83 void InitGameplayMode()
  84 {
  85         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  86
  87         qualifying_override = -1;
  88
  89         VoteReset();
  90
  91         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  92         get_mi_min_max(1);
  93         world.mins = mi_min;
  94         world.maxs = mi_max;
  95
  96         MapInfo_LoadMapSettings(mapname);
  97         teamplay = 0;
  98         serverflags &~= SERVERFLAG_TEAMPLAY;
  99
 100         if not(cvar_value_issafe(world.fog))
 101         {
 102                 print("The current map contains a potentially harmful fog setting, ignored\n");
 103                 world.fog = string_null;
 104         }
 105         if(MapInfo_Map_fog != "")
 106                 if(MapInfo_Map_fog == "none")
 107                         world.fog = string_null;
 108                 else
 109                         world.fog = strzone(MapInfo_Map_fog);
 110         clientstuff = strzone(MapInfo_Map_clientstuff);
 111
 112         MapInfo_ClearTemps();
 113
 114         // set both here, gamemode can override it later
 115         timelimit_override = autocvar_timelimit_override;
 116         fraglimit_override = autocvar_fraglimit_override;
 117         leadlimit_override = autocvar_leadlimit_override;
 118         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 119
 120         if(g_dm)
 121         {
 122         }
 123
 124         if(g_tdm)
 125         {
 126                 ActivateTeamplay();
 127                 tdm_init();
 128                 if(autocvar_g_tdm_team_spawns)
 129                         have_team_spawns = -1; // request team spawns
 130         }
 131
 132         if(g_domination)
 133         {
 134                 ActivateTeamplay();
 135                 fraglimit_override = autocvar_g_domination_point_limit;
 136                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 137                 dom_init();
 138                 have_team_spawns = -1; // request team spawns
 139         }
 140
 141         if(g_ctf)
 142         {
 143                 ActivateTeamplay();
 144                 fraglimit_override = autocvar_capturelimit_override;
 145                 leadlimit_override = autocvar_captureleadlimit_override;
 146                 MUTATOR_ADD(gamemode_ctf);
 147                 have_team_spawns = -1; // request team spawns
 148         }
 149
 150         if(g_runematch)
 151         {
 152                 // ActivateTeamplay();
 153                 fraglimit_override = autocvar_g_runematch_point_limit;
 154                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 155                 runematch_init();
 156         }
 157
 158         if(g_lms)
 159         {
 160                 fraglimit_override = autocvar_g_lms_lives_override;
 161                 leadlimit_override = 0; // not supported by LMS
 162                 if(fraglimit_override == 0)
 163                         fraglimit_override = -1;
 164                 lms_lowest_lives = 9999;
 165                 lms_next_place = 0;
 166                 ScoreRules_lms();
 167         }
 168
 169         if(g_arena)
 170         {
 171                 fraglimit_override = autocvar_g_arena_point_limit;
 172                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 173                 maxspawned = autocvar_g_arena_maxspawned;
 174                 if(maxspawned < 2)
 175                         maxspawned = 2;
 176                 arena_roundbased = autocvar_g_arena_roundbased;
 177         }
 178
 179         if(g_ca)
 180         {
 181                 ActivateTeamplay();
 182                 fraglimit_override = autocvar_g_ca_point_limit;
 183                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 184                 precache_sound("ctf/red_capture.wav");
 185                 precache_sound("ctf/blue_capture.wav");
 186         }
 187         if(g_keyhunt)
 188         {
 189                 ActivateTeamplay();
 190                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 191                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 192                 MUTATOR_ADD(gamemode_keyhunt);
 193         }
 194
 195         if(g_freezetag)
 196         {
 197                 ActivateTeamplay();
 198                 fraglimit_override = autocvar_g_freezetag_point_limit;
 199                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 200                 MUTATOR_ADD(gamemode_freezetag);
 201         }
 202
 203         if(g_assault)
 204         {
 205                 ActivateTeamplay();
 206                 ScoreRules_assault();
 207                 have_team_spawns = -1; // request team spawns
 208         }
 209
 210         if(g_onslaught)
 211         {
 212                 ActivateTeamplay();
 213                 have_team_spawns = -1; // request team spawns
 214                 MUTATOR_ADD(gamemode_onslaught);
 215         }
 216
 217         if(g_race)
 218         {
 219
 220                 if(autocvar_g_race_teams)
 221                 {
 222                         ActivateTeamplay();
 223                         race_teams = bound(2, autocvar_g_race_teams, 4);
 224                         have_team_spawns = -1; // request team spawns
 225                 }
 226                 else
 227                         race_teams = 0;
 228
 229                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 230                 fraglimit_override = autocvar_g_race_laps_limit;
 231                 leadlimit_override = 0; // currently not supported by race
 232         }
 233
 234         if(g_cts)
 235         {
 236                 g_race_qualifying = 1;
 237                 fraglimit_override = 0;
 238                 leadlimit_override = 0;
 239         }
 240
 241         if(g_nexball)
 242         {
 243         fraglimit_override = autocvar_g_nexball_goallimit;
 244         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 245         ActivateTeamplay();
 246         have_team_spawns = -1; // request team spawns
 247             MUTATOR_ADD(gamemode_nexball);
 248         }
 249
 250         if(g_keepaway)
 251         {
 252                 MUTATOR_ADD(gamemode_keepaway);
 253         }
 254
 255         if(teamplay)
 256                 entcs_init();
 257
 258         cache_mutatormsg = strzone("");
 259         cache_lastmutatormsg = strzone("");
 260
 261         // enforce the server's universal frag/time limits
 262         if(!autocvar_g_campaign)
 263         {
 264                 if(fraglimit_override >= 0)
 265                         cvar_set("fraglimit", ftos(fraglimit_override));
 266                 if(timelimit_override >= 0)
 267                         cvar_set("timelimit", ftos(timelimit_override));
 268                 if(leadlimit_override >= 0)
 269                         cvar_set("leadlimit", ftos(leadlimit_override));
 270                 if(qualifying_override >= 0)
 271                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 272         }
 273
 274         if(g_race)
 275         {
 276                 // we need to find out the correct value for g_race_qualifying
 277                 if(autocvar_g_campaign)
 278                 {
 279                         g_race_qualifying = 1;
 280                 }
 281                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 282                 {
 283                         g_race_qualifying = 2;
 284                         race_fraglimit = autocvar_fraglimit;
 285                         race_leadlimit = autocvar_leadlimit;
 286                         race_timelimit = autocvar_timelimit;
 287                         cvar_set("fraglimit", "0");
 288                         cvar_set("leadlimit", "0");
 289                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 290                 }
 291                 else
 292                         g_race_qualifying = 0;
 293         }
 294
 295         if(g_race || g_cts)
 296         {
 297                 if(g_race_qualifying)
 298                         independent_players = 1;
 299
 300                 ScoreRules_race();
 301         }
 302
 303         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 304 }
 305
 306 string GetClientVersionMessage() {
 307         string versionmsg;
 308         if (self.version_mismatch) {
 309                 if(self.version < autocvar_gameversion) {
 310                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 311                 } else {
 312                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 313                 }
 314         } else {
 315                 versionmsg = "^2client version and server version are compatible.^8";
 316         }
 317         return versionmsg;
 318 }
 319
 320 string getwelcomemessage(void)
 321 {
 322         string s, modifications, motd;
 323
 324         ret_string = "";
 325         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 326         modifications = ret_string;
 327
 328         if(g_weaponarena)
 329         {
 330                 if(g_weaponarena_random)
 331                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 332                 else
 333                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 334         }
 335         if(autocvar_g_start_weapon_laser == 0)
 336                 modifications = strcat(modifications, ", No start weapons");
 337         if(autocvar_sv_gravity < 800)
 338                 modifications = strcat(modifications, ", Low gravity");
 339         if(g_cloaked && !g_cts)
 340                 modifications = strcat(modifications, ", Cloaked");
 341         if(g_grappling_hook)
 342                 modifications = strcat(modifications, ", Hook");
 343         if(g_midair)
 344                 modifications = strcat(modifications, ", Midair");
 345         if(g_pinata)
 346                 modifications = strcat(modifications, ", Piñata");
 347         if(g_weapon_stay && !g_cts)
 348                 modifications = strcat(modifications, ", Weapons stay");
 349         if(g_bloodloss > 0)
 350                 modifications = strcat(modifications, ", Blood loss");
 351         if(g_jetpack)
 352                 modifications = strcat(modifications, ", Jet pack");
 353         if(autocvar_g_powerups == 0)
 354                 modifications = strcat(modifications, ", No powerups");
 355         if(autocvar_g_powerups > 0)
 356                 modifications = strcat(modifications, ", Powerups");
 357         modifications = substring(modifications, 2, strlen(modifications) - 2);
 358
 359         string versionmessage;
 360         versionmessage = GetClientVersionMessage();
 361
 362         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 363         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 364
 365         if(modifications != "")
 366                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 367
 368         if (g_grappling_hook)
 369                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 370
 371         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 372         {
 373                 if(cache_lastmutatormsg)
 374                         strunzone(cache_lastmutatormsg);
 375                 if(cache_mutatormsg)
 376                         strunzone(cache_mutatormsg);
 377                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 378                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 379         }
 380
 381         if (cache_mutatormsg != "") {
 382                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 383         }
 384
 385         motd = autocvar_sv_motd;
 386         if (motd != "") {
 387                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 388         }
 389         return s;
 390 }
 391
 392 void SetPlayerColors(entity pl, float _color)
 393 {
 394         /*string s;
 395         s = ftos(cl);
 396         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 397         pl.team = cl + 1;
 398         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 399         pl.clientcolors = 16*cl + cl;*/
 400
 401         float pants, shirt;
 402         pants = _color & 0x0F;
 403         shirt = _color & 0xF0;
 404
 405
 406         if(teamplay) {
 407                 setcolor(pl, 16*pants + pants);
 408         } else {
 409                 setcolor(pl, shirt + pants);
 410         }
 411 }
 412
 413 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 414 {
 415         float _color;
 416
 417         if(t == 4)
 418                 _color = COLOR_TEAM4 - 1;
 419         else if(t == 3)
 420                 _color = COLOR_TEAM3 - 1;
 421         else if(t == 2)
 422                 _color = COLOR_TEAM2 - 1;
 423         else
 424                 _color = COLOR_TEAM1 - 1;
 425
 426         SetPlayerColors(pl,_color);
 427
 428         if(t != s) {
 429                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 430
 431                 if(!noprint)
 432                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 433         }
 434
 435 }
 436
 437 // set c1...c4 to show what teams are allowed
 438 void CheckAllowedTeams (entity for_whom)
 439 {
 440         float dm;
 441         entity head;
 442         string teament_name;
 443
 444         c1 = c2 = c3 = c4 = -1;
 445         cb1 = cb2 = cb3 = cb4 = 0;
 446
 447         teament_name = string_null;
 448         if(g_onslaught)
 449         {
 450                 // onslaught is special
 451                 head = findchain(classname, "onslaught_generator");
 452                 while (head)
 453                 {
 454                         if (head.team == COLOR_TEAM1) c1 = 0;
 455                         if (head.team == COLOR_TEAM2) c2 = 0;
 456                         if (head.team == COLOR_TEAM3) c3 = 0;
 457                         if (head.team == COLOR_TEAM4) c4 = 0;
 458                         head = head.chain;
 459                 }
 460         }
 461         else if(g_domination)
 462                 teament_name = "dom_team";
 463         else if(g_ctf)
 464                 teament_name = "ctf_team";
 465         else if(g_tdm)
 466                 teament_name = "tdm_team";
 467         else if(g_nexball)
 468                 teament_name = "nexball_team";
 469         else if(g_assault)
 470                 c1 = c2 = 0; // Assault always has 2 teams
 471         else
 472         {
 473                 // cover anything else by treating it like tdm with no teams spawned
 474                 if(g_race)
 475                         dm = race_teams;
 476                 else
 477                         dm = 2;
 478
 479                 ret_float = dm;
 480                 MUTATOR_CALLHOOK(GetTeamCount);
 481                 dm = ret_float;
 482
 483                 if(dm >= 4)
 484                         c1 = c2 = c3 = c4 = 0;
 485                 else if(dm >= 3)
 486                         c1 = c2 = c3 = 0;
 487                 else
 488                         c1 = c2 = 0;
 489         }
 490
 491         // find out what teams are allowed if necessary
 492         if(teament_name)
 493         {
 494                 head = find(world, classname, teament_name);
 495                 while(head)
 496                 {
 497                         if(!(g_domination && head.netname == ""))
 498                         {
 499                                 if(head.team == COLOR_TEAM1)
 500                                         c1 = 0;
 501                                 else if(head.team == COLOR_TEAM2)
 502                                         c2 = 0;
 503                                 else if(head.team == COLOR_TEAM3)
 504                                         c3 = 0;
 505                                 else if(head.team == COLOR_TEAM4)
 506                                         c4 = 0;
 507                         }
 508                         head = find(head, classname, teament_name);
 509                 }
 510         }
 511
 512         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 513         if(c3==-1 && c4==-1)
 514         if(autocvar_bot_vs_human && for_whom)
 515         {
 516                 if(autocvar_bot_vs_human > 0)
 517                 {
 518                         // bots are all blue
 519                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 520                                 c1 = c3 = c4 = -1;
 521                         else
 522                                 c2 = -1;
 523                 }
 524                 else
 525                 {
 526                         // bots are all red
 527                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 528                                 c2 = c3 = c4 = -1;
 529                         else
 530                                 c1 = -1;
 531                 }
 532         }
 533
 534         // if player has a forced team, ONLY allow that one
 535         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 536                 c2 = c3 = c4 = -1;
 537         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 538                 c1 = c3 = c4 = -1;
 539         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 540                 c1 = c2 = c4 = -1;
 541         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 542                 c1 = c2 = c3 = -1;
 543 }
 544
 545 float PlayerValue(entity p)
 546 {
 547         return 1;
 548         // FIXME: it always returns 1...
 549 }
 550
 551 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 552 // teams that are allowed will now have their player counts stored in c1...c4
 553 void GetTeamCounts(entity ignore)
 554 {
 555         entity head;
 556         float value, bvalue;
 557         // now count how many players are on each team already
 558
 559         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 560         // also remember the lowest-scoring player
 561
 562         FOR_EACH_CLIENT(head)
 563         {
 564                 float t;
 565                 if(head.classname == "player")
 566                         t = head.team;
 567                 else if(head.team_forced > 0)
 568                         t = head.team_forced; // reserve the spot
 569                 else
 570                         continue;
 571                 if(head != ignore)// && head.netname != "")
 572                 {
 573                         value = PlayerValue(head);
 574                         if(clienttype(head) == CLIENTTYPE_BOT)
 575                                 bvalue = value;
 576                         else
 577                                 bvalue = 0;
 578                         if(t == COLOR_TEAM1)
 579                         {
 580                                 if(c1 >= 0)
 581                                 {
 582                                         c1 = c1 + value;
 583                                         cb1 = cb1 + bvalue;
 584                                 }
 585                         }
 586                         if(t == COLOR_TEAM2)
 587                         {
 588                                 if(c2 >= 0)
 589                                 {
 590                                         c2 = c2 + value;
 591                                         cb2 = cb2 + bvalue;
 592                                 }
 593                         }
 594                         if(t == COLOR_TEAM3)
 595                         {
 596                                 if(c3 >= 0)
 597                                 {
 598                                         c3 = c3 + value;
 599                                         cb3 = cb3 + bvalue;
 600                                 }
 601                         }
 602                         if(t == COLOR_TEAM4)
 603                         {
 604                                 if(c4 >= 0)
 605                                 {
 606                                         c4 = c4 + value;
 607                                         cb4 = cb4 + bvalue;
 608                                 }
 609                         }
 610                 }
 611         }
 612
 613         // if the player who has a forced team has not joined yet, reserve the spot
 614         if(autocvar_g_campaign)
 615         {
 616                 switch(autocvar_g_campaign_forceteam)
 617                 {
 618                         case 1: if(c1 == cb1) ++c1; break;
 619                         case 2: if(c2 == cb2) ++c2; break;
 620                         case 3: if(c3 == cb3) ++c3; break;
 621                         case 4: if(c4 == cb4) ++c4; break;
 622                 }
 623         }
 624 }
 625
 626 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 627 {
 628         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 629         float f;
 630         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 631
 632         switch(ta)
 633         {
 634                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 635                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 636                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 637                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 638         }
 639         switch(tb)
 640         {
 641                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 642                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 643                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 644                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 645         }
 646
 647         // invalid
 648         if(ca < 0 || cb < 0)
 649                 return FALSE;
 650
 651         // equal
 652         if(ta == tb)
 653                 return TRUE;
 654
 655         if(clienttype(e) == CLIENTTYPE_REAL)
 656         {
 657                 if(bots_would_leave)
 658                 {
 659                         ca -= cba * 0.999;
 660                         cb -= cbb * 0.999;
 661                 }
 662         }
 663
 664         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 665         if(ca < 1)
 666                 if(cb >= 1)
 667                         return TRUE;
 668         if(ca >= 1)
 669                 if(cb < 1)
 670                         return FALSE;
 671
 672         // first, normalize
 673         f = max(ca, cb, 1);
 674         ca /= f;
 675         cb /= f;
 676         f = max(sa, sb, 1);
 677         sa /= f;
 678         sb /= f;
 679
 680         // the more we're at the end of the match, the more take scores into account
 681         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 682         ca += (sa - ca) * f;
 683         cb += (sb - cb) * f;
 684
 685         return ca <= cb;
 686 }
 687
 688 // returns # of smallest team (1, 2, 3, 4)
 689 // NOTE: Assumes CheckAllowedTeams has already been called!
 690 float FindSmallestTeam(entity pl, float ignore_pl)
 691 {
 692         float totalteams, t;
 693         totalteams = 0;
 694
 695         // find out what teams are available
 696         //CheckAllowedTeams();
 697
 698         // make sure there are at least 2 teams to join
 699         if(c1 >= 0)
 700                 totalteams = totalteams + 1;
 701         if(c2 >= 0)
 702                 totalteams = totalteams + 1;
 703         if(c3 >= 0)
 704                 totalteams = totalteams + 1;
 705         if(c4 >= 0)
 706                 totalteams = totalteams + 1;
 707
 708         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 709                 totalteams += 1;
 710
 711         if(totalteams <= 1)
 712         {
 713                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 714                         return 1; // special case for campaign and player joining
 715                 else if(g_domination)
 716                         error("Too few teams available for domination\n");
 717                 else if(g_ctf)
 718                         error("Too few teams available for ctf\n");
 719                 else if(g_keyhunt)
 720                         error("Too few teams available for key hunt\n");
 721                 else if(g_freezetag)
 722                         error("Too few teams available for freeze tag\n");
 723                 else
 724                         error("Too few teams available for team deathmatch\n");
 725         }
 726
 727         // count how many players are in each team
 728         if(ignore_pl)
 729                 GetTeamCounts(pl);
 730         else
 731                 GetTeamCounts(world);
 732
 733         RandomSelection_Init();
 734
 735         t = 1;
 736         if(TeamSmallerEqThanTeam(2, t, pl))
 737                 t = 2;
 738         if(TeamSmallerEqThanTeam(3, t, pl))
 739                 t = 3;
 740         if(TeamSmallerEqThanTeam(4, t, pl))
 741                 t = 4;
 742
 743         // now t is the minimum, or A minimum!
 744         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 745                 RandomSelection_Add(world, 1, string_null, 1, 1);
 746         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 747                 RandomSelection_Add(world, 2, string_null, 1, 1);
 748         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 749                 RandomSelection_Add(world, 3, string_null, 1, 1);
 750         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 751                 RandomSelection_Add(world, 4, string_null, 1, 1);
 752
 753         return RandomSelection_chosen_float;
 754 }
 755
 756 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 757 {
 758         float smallest, selectedteam;
 759
 760         // don't join a team if we're not playing a team game
 761         if(!teamplay)
 762                 return 0;
 763
 764         // find out what teams are available
 765         CheckAllowedTeams(pl);
 766
 767         // if we don't care what team he ends up on, put him on whatever team he entered as.
 768         // if he's not on a valid team, then let other code put him on the smallest team
 769         if(!forcebestteam)
 770         {
 771                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 772                         selectedteam = pl.team;
 773                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 774                         selectedteam = pl.team;
 775                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 776                         selectedteam = pl.team;
 777                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 778                         selectedteam = pl.team;
 779                 else
 780                         selectedteam = -1;
 781
 782                 if(selectedteam > 0)
 783                 {
 784                         if(!only_return_best)
 785                         {
 786                                 SetPlayerColors(pl, selectedteam - 1);
 787
 788                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 789                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 790                                 LogTeamchange(pl.playerid, pl.team, 99);
 791                         }
 792                         return selectedteam;
 793                 }
 794                 // otherwise end up on the smallest team (handled below)
 795         }
 796
 797         smallest = FindSmallestTeam(pl, TRUE);
 798
 799         if(!only_return_best && !pl.bot_forced_team)
 800         {
 801                 TeamchangeFrags(self);
 802                 if(smallest == 1)
 803                 {
 804                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 805                 }
 806                 else if(smallest == 2)
 807                 {
 808                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 809                 }
 810                 else if(smallest == 3)
 811                 {
 812                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 813                 }
 814                 else if(smallest == 4)
 815                 {
 816                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 817                 }
 818                 else
 819                 {
 820                         error("smallest team: invalid team\n");
 821                 }
 822
 823                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 824
 825                 if(pl.deadflag == DEAD_NO)
 826                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 827         }
 828
 829         return smallest;
 830 }
 831
 832 //void() ctf_playerchanged;
 833 void SV_ChangeTeam(float _color)
 834 {
 835         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 836
 837         // in normal deathmatch we can just apply the color and we're done
 838         if(!teamplay) {
 839                 SetPlayerColors(self, _color);
 840                 return;
 841         }
 842
 843         scolor = self.clientcolors & 0x0F;
 844         dcolor = _color & 0x0F;
 845
 846         if(scolor == COLOR_TEAM1 - 1)
 847                 steam = 1;
 848         else if(scolor == COLOR_TEAM2 - 1)
 849                 steam = 2;
 850         else if(scolor == COLOR_TEAM3 - 1)
 851                 steam = 3;
 852         else // if(scolor == COLOR_TEAM4 - 1)
 853                 steam = 4;
 854         if(dcolor == COLOR_TEAM1 - 1)
 855                 dteam = 1;
 856         else if(dcolor == COLOR_TEAM2 - 1)
 857                 dteam = 2;
 858         else if(dcolor == COLOR_TEAM3 - 1)
 859                 dteam = 3;
 860         else // if(dcolor == COLOR_TEAM4 - 1)
 861                 dteam = 4;
 862
 863         CheckAllowedTeams(self);
 864
 865         if(dteam == 1 && c1 < 0) dteam = 4;
 866         if(dteam == 4 && c4 < 0) dteam = 3;
 867         if(dteam == 3 && c3 < 0) dteam = 2;
 868         if(dteam == 2 && c2 < 0) dteam = 1;
 869
 870         // not changing teams
 871         if(scolor == dcolor)
 872         {
 873                 //bprint("same team change\n");
 874                 SetPlayerTeam(self, dteam, steam, TRUE);
 875                 return;
 876         }
 877
 878         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 879                 sprint(self, "Team changes not allowed\n");
 880                 return; // changing teams is not allowed
 881         }
 882
 883         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 884         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 885         {
 886                 GetTeamCounts(self);
 887                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 888                 {
 889                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 890                         return;
 891                 }
 892         }
 893
 894 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 895
 896         if(self.classname == "player" && steam != dteam)
 897         {
 898                 // reduce frags during a team change
 899                 TeamchangeFrags(self);
 900         }
 901
 902         SetPlayerTeam(self, dteam, steam, FALSE);
 903
 904         if(self.classname == "player" && steam != dteam)
 905         {
 906                 // kill player when changing teams
 907                 if(self.deadflag == DEAD_NO)
 908                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 909         }
 910 }
 911
 912 void ShufflePlayerOutOfTeam (float source_team)
 913 {
 914         float smallestteam, smallestteam_count, steam;
 915         float lowest_bot_score, lowest_player_score;
 916         entity head, lowest_bot, lowest_player, selected;
 917
 918         smallestteam = 0;
 919         smallestteam_count = 999999999;
 920
 921         if(c1 >= 0 && c1 < smallestteam_count)
 922         {
 923                 smallestteam = 1;
 924                 smallestteam_count = c1;
 925         }
 926         if(c2 >= 0 && c2 < smallestteam_count)
 927         {
 928                 smallestteam = 2;
 929                 smallestteam_count = c2;
 930         }
 931         if(c3 >= 0 && c3 < smallestteam_count)
 932         {
 933                 smallestteam = 3;
 934                 smallestteam_count = c3;
 935         }
 936         if(c4 >= 0 && c4 < smallestteam_count)
 937         {
 938                 smallestteam = 4;
 939                 smallestteam_count = c4;
 940         }
 941
 942         if(!smallestteam)
 943         {
 944                 bprint("warning: no smallest team\n");
 945                 return;
 946         }
 947
 948         if(source_team == 1)
 949                 steam = COLOR_TEAM1;
 950         else if(source_team == 2)
 951                 steam = COLOR_TEAM2;
 952         else if(source_team == 3)
 953                 steam = COLOR_TEAM3;
 954         else // if(source_team == 4)
 955                 steam = COLOR_TEAM4;
 956
 957         lowest_bot = world;
 958         lowest_bot_score = 999999999;
 959         lowest_player = world;
 960         lowest_player_score = 999999999;
 961
 962         // find the lowest-scoring player & bot of that team
 963         FOR_EACH_PLAYER(head)
 964         {
 965                 if(head.team == steam)
 966                 {
 967                         if(head.isbot)
 968                         {
 969                                 if(head.totalfrags < lowest_bot_score)
 970                                 {
 971                                         lowest_bot = head;
 972                                         lowest_bot_score = head.totalfrags;
 973                                 }
 974                         }
 975                         else
 976                         {
 977                                 if(head.totalfrags < lowest_player_score)
 978                                 {
 979                                         lowest_player = head;
 980                                         lowest_player_score = head.totalfrags;
 981                                 }
 982                         }
 983                 }
 984         }
 985
 986         // prefers to move a bot...
 987         if(lowest_bot != world)
 988                 selected = lowest_bot;
 989         // but it will move a player if it has to
 990         else
 991                 selected = lowest_player;
 992         // don't do anything if it couldn't find anyone
 993         if(!selected)
 994         {
 995                 bprint("warning: couldn't find a player to move from team\n");
 996                 return;
 997         }
 998
 999         // smallest team gains a member
1000         if(smallestteam == 1)
1001         {
1002                 c1 = c1 + 1;
1003         }
1004         else if(smallestteam == 2)
1005         {
1006                 c2 = c2 + 1;
1007         }
1008         else if(smallestteam == 3)
1009         {
1010                 c3 = c3 + 1;
1011         }
1012         else if(smallestteam == 4)
1013         {
1014                 c4 = c4 + 1;
1015         }
1016         else
1017         {
1018                 bprint("warning: destination team invalid\n");
1019                 return;
1020         }
1021         // source team loses a member
1022         if(source_team == 1)
1023         {
1024                 c1 = c1 + 1;
1025         }
1026         else if(source_team == 2)
1027         {
1028                 c2 = c2 + 2;
1029         }
1030         else if(source_team == 3)
1031         {
1032                 c3 = c3 + 3;
1033         }
1034         else if(source_team == 4)
1035         {
1036                 c4 = c4 + 4;
1037         }
1038         else
1039         {
1040                 bprint("warning: source team invalid\n");
1041                 return;
1042         }
1043
1044         // move the player to the new team
1045         TeamchangeFrags(selected);
1046         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1047
1048         if(selected.deadflag == DEAD_NO)
1049                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1050         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1051 }
1052
1053 // code from here on is just to support maps that don't have team entities
1054 void tdm_spawnteam (string teamname, float teamcolor)
1055 {
1056         entity e;
1057         e = spawn();
1058         e.classname = "tdm_team";
1059         e.netname = teamname;
1060         e.cnt = teamcolor;
1061         e.team = e.cnt + 1;
1062 }
1063
1064 // spawn some default teams if the map is not set up for tdm
1065 void tdm_spawnteams()
1066 {
1067         float numteams;
1068
1069         numteams = autocvar_g_tdm_teams_override;
1070         if(numteams < 2)
1071                 numteams = autocvar_g_tdm_teams;
1072         numteams = bound(2, numteams, 4);
1073
1074         tdm_spawnteam("Red", COLOR_TEAM1-1);
1075         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1076         if(numteams >= 3)
1077                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1078         if(numteams >= 4)
1079                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1080 }
1081
1082 void tdm_delayedinit()
1083 {
1084         // if no teams are found, spawn defaults
1085         if (find(world, classname, "tdm_team") == world)
1086                 tdm_spawnteams();
1087 }
1088
1089 void tdm_init()
1090 {
1091         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1092 }