qcsrc/server/vehicles/bumblebee.qc

   1 #define BRG_SETUP 2
   2 #define BRG_START 4
   3 #define BRG_END 8
   4
   5 #ifdef SVQC
   6 // Auto cvars
   7 float autocvar_g_vehicle_bumblebee_speed_forward;
   8 float autocvar_g_vehicle_bumblebee_speed_strafe;
   9 float autocvar_g_vehicle_bumblebee_speed_up;
  10 float autocvar_g_vehicle_bumblebee_speed_down;
  11 float autocvar_g_vehicle_bumblebee_turnspeed;
  12 float autocvar_g_vehicle_bumblebee_pitchspeed;
  13 float autocvar_g_vehicle_bumblebee_pitchlimit;
  14 float autocvar_g_vehicle_bumblebee_friction;
  15
  16 float autocvar_g_vehicle_bumblebee_energy;
  17 float autocvar_g_vehicle_bumblebee_energy_regen;
  18 float autocvar_g_vehicle_bumblebee_energy_regen_pause;
  19
  20 float autocvar_g_vehicle_bumblebee_health;
  21 float autocvar_g_vehicle_bumblebee_health_regen;
  22 float autocvar_g_vehicle_bumblebee_health_regen_pause;
  23
  24 float autocvar_g_vehicle_bumblebee_shield;
  25 float autocvar_g_vehicle_bumblebee_shield_regen;
  26 float autocvar_g_vehicle_bumblebee_shield_regen_pause;
  27
  28 float autocvar_g_vehicle_bumblebee_cannon_cost;
  29 float autocvar_g_vehicle_bumblebee_cannon_damage;
  30 float autocvar_g_vehicle_bumblebee_cannon_radius;
  31 float autocvar_g_vehicle_bumblebee_cannon_refire;
  32 float autocvar_g_vehicle_bumblebee_cannon_speed;
  33 float autocvar_g_vehicle_bumblebee_cannon_spread;
  34 float autocvar_g_vehicle_bumblebee_cannon_force;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo;
  37 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen;
  38 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause;
  39
  40 var float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  41
  42 float autocvar_g_vehicle_bumblebee_cannon_turnspeed;
  43 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down;
  44 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up;
  45 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  46 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  47
  48
  49 float autocvar_g_vehicle_bumblebee_raygun_turnspeed;
  50 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down;
  51 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up;
  52 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides;
  53
  54 float autocvar_g_vehicle_bumblebee_raygun_range;
  55 float autocvar_g_vehicle_bumblebee_raygun_dps;
  56 float autocvar_g_vehicle_bumblebee_raygun_aps;
  57 float autocvar_g_vehicle_bumblebee_raygun_fps;
  58
  59 float autocvar_g_vehicle_bumblebee_raygun;
  60 float autocvar_g_vehicle_bumblebee_healgun_hps;
  61 float autocvar_g_vehicle_bumblebee_healgun_hmax;
  62 float autocvar_g_vehicle_bumblebee_healgun_aps;
  63 float autocvar_g_vehicle_bumblebee_healgun_amax;
  64 float autocvar_g_vehicle_bumblebee_healgun_sps;
  65
  66 float autocvar_g_vehicle_bumblebee_respawntime;
  67
  68 float autocvar_g_vehicle_bumblebee_blowup_radius;
  69 float autocvar_g_vehicle_bumblebee_blowup_coredamage;
  70 float autocvar_g_vehicle_bumblebee_blowup_edgedamage;
  71 float autocvar_g_vehicle_bumblebee_blowup_forceintensity;
  72
  73 var float autocvar_g_vehicle_bumblebee = 0;
  74
  75
  76 float bumble_raygun_send(entity to, float sf);
  77
  78 #define BUMB_MIN '-120 -120 -120'
  79 #define BUMB_MAX '120 120 120'
  80
  81 void bumb_fire_cannon(entity _gun, string _tagname, entity _owner)
  82 {
  83         vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
  84         vehicles_projectile("bigplasma_muzzleflash", "weapons/flacexp3.wav",
  85                                                 v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  86                                                 autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  87                                                 DEATH_BUMB_GUN, PROJECTILE_BUMBLE_GUN, 0, TRUE, TRUE, _owner);
  88 }
  89
  90 float bumb_gunner_frame()
  91 {
  92         entity vehic    = self.vehicle.owner;
  93         entity gun      = self.vehicle;
  94         entity gunner   = self;
  95         self = vehic;
  96
  97         vehic.solid = SOLID_NOT;
  98         setorigin(gunner, vehic.origin);
  99         gunner.velocity = vehic.velocity;
 100         crosshair_trace(gunner);
 101         vector _ct = trace_endpos;
 102         vector ad;
 103
 104         float _in = ((gun == vehic.gun1) ? autocvar_g_vehicle_bumblebee_cannon_turnlimit_in : autocvar_g_vehicle_bumblebee_cannon_turnlimit_out);
 105         float _out = ((gun == vehic.gun1) ? autocvar_g_vehicle_bumblebee_cannon_turnlimit_out : autocvar_g_vehicle_bumblebee_cannon_turnlimit_in);
 106
 107         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 108         {
 109                 if(gun.lock_time < time)
 110                         gun.enemy = world;
 111
 112                 if(trace_ent)
 113                         if(trace_ent.movetype)
 114                                 if(trace_ent.takedamage)
 115                                         if(!trace_ent.deadflag)
 116                                         {
 117                                                 if(teamplay)
 118                                                 {
 119                                                         if(trace_ent.team != gunner.team)
 120                                                         {
 121                                                                 gun.enemy = trace_ent;
 122                                                                 gun.lock_time = time + 5;
 123                                                         }
 124                                                 }
 125                                                 else
 126                                                 {
 127                                                         gun.enemy = trace_ent;
 128                                                         gun.lock_time = time + 5;
 129                                                 }
 130                                         }
 131         }
 132
 133         if(gun.enemy)
 134         {
 135                 float i, distance, impact_time;
 136
 137                 vector vf = real_origin(gun.enemy);
 138                 vector _vel = gun.enemy.velocity;
 139                 if(gun.enemy.movetype == MOVETYPE_WALK)
 140                         _vel_z *= 0.1;
 141
 142
 143                 ad = vf;
 144                 for(i = 0; i < 4; ++i)
 145                 {
 146                         distance = vlen(ad - gunner.origin);
 147                         impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 148                         ad = vf + _vel * impact_time;
 149                 }
 150                 trace_endpos = ad;
 151
 152
 153                 UpdateAuxiliaryXhair(gunner, ad, '1 0 1', 1);
 154                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 155                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 156                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 157
 158         }
 159         else
 160                 vehicle_aimturret(vehic, _ct, gun, "fire",
 161                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 162                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 163
 164         if(gunner.BUTTON_ATCK)
 165                 if(time > gun.attack_finished_single)
 166                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 167                         {
 168                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 169                                 bumb_fire_cannon(gun, "fire", gunner);
 170                                 gun.delay = time;
 171                                 gun.attack_finished_single = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 172                         }
 173
 174         VEHICLE_UPDATE_PLAYER(gunner, health, bumblebee);
 175
 176         if(vehic.vehicle_flags & VHF_HASSHIELD)
 177                 VEHICLE_UPDATE_PLAYER(gunner, shield, bumblebee);
 178
 179         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 180         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 181
 182         UpdateAuxiliaryXhair(gunner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), 0);
 183
 184         if(vehic.owner)
 185                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), ((gunner == vehic.gunner1) ? 1 : 2));
 186
 187         vehic.solid = SOLID_BBOX;
 188         gunner.BUTTON_ATCK = gunner.BUTTON_ATCK2 = gunner.BUTTON_CROUCH = 0;
 189         gunner.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 190
 191         self = gunner;
 192         return 1;
 193 }
 194
 195 void bumb_gunner_exit(float _exitflag)
 196 {
 197         if(clienttype(self) == CLIENTTYPE_REAL)
 198         {
 199                 msg_entity = self;
 200                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 201                 WriteEntity(MSG_ONE, self);
 202
 203                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 204                 WriteAngle(MSG_ONE, 0);
 205                 WriteAngle(MSG_ONE, self.vehicle.angles_y);
 206                 WriteAngle(MSG_ONE, 0);
 207         }
 208
 209         CSQCVehicleSetup(self, HUD_NORMAL);
 210         setsize(self, PL_MIN, PL_MAX);
 211
 212         self.takedamage     = DAMAGE_AIM;
 213         self.solid          = SOLID_SLIDEBOX;
 214         self.movetype       = MOVETYPE_WALK;
 215         self.effects        &~= EF_NODRAW;
 216         self.alpha          = 1;
 217         self.PlayerPhysplug = SUB_Null;
 218         self.view_ofs       = PL_VIEW_OFS;
 219         self.event_damage   = PlayerDamage;
 220         self.hud            = HUD_NORMAL;
 221         self.switchweapon   = self.vehicle.switchweapon;
 222
 223         if(self.flagcarried)
 224         {
 225                 self.flagcarried.scale = 0.6;
 226                 setattachment(self.flagcarried, self, "");
 227                 setorigin(self.flagcarried, FLAG_CARRY_POS);
 228         }
 229
 230         self.vehicle.vehicle_hudmodel.viewmodelforclient = self.vehicle;
 231
 232         if(self == self.vehicle.owner.gunner1)
 233                 self.vehicle.owner.gunner1 = world;
 234         else if(self == self.vehicle.owner.gunner2)
 235                 self.vehicle.owner.gunner2 = world;
 236         else
 237                 dprint("^1self != gunner1 or gunner2, this is a BIG PROBLEM, tell tZork this happend.\n");
 238
 239         self.vehicle.phase = time + 5;
 240         self.vehicle        = world;
 241 }
 242
 243 float bumb_gunner_enter()
 244 {
 245         RemoveGrapplingHook(other);
 246         entity _gun, _gunner;
 247         if(!self.gunner1)
 248         {
 249                 _gun = self.gun1;
 250                 _gunner = self.gunner1;
 251                 self.gunner1 = other;
 252         }
 253         else if(!self.gunner2)
 254         {
 255                 _gun = self.gun2;
 256                 _gunner = self.gunner2;
 257                 self.gunner2 = other;
 258         }
 259         else
 260         {
 261                 dprint("^1ERROR:^7Tried to enter a fully occupied vehicle!\n");
 262                 return FALSE;
 263         }
 264
 265         _gunner            = other;
 266         _gunner.vehicle    = _gun;
 267         _gun.switchweapon  = other.switchweapon;
 268         _gun.vehicle_exit  = bumb_gunner_exit;
 269
 270         other.angles            = self.angles;
 271         other.takedamage        = DAMAGE_NO;
 272         other.solid             = SOLID_NOT;
 273         other.movetype          = MOVETYPE_NOCLIP;
 274         other.alpha             = -1;
 275         other.event_damage      = SUB_Null;
 276         other.view_ofs          = '0 0 0';
 277         other.hud               = _gun.hud;
 278         other.PlayerPhysplug    = _gun.PlayerPhysplug;
 279         other.vehicle_ammo1     = self.vehicle_ammo1;
 280         other.vehicle_ammo2     = self.vehicle_ammo2;
 281         other.vehicle_reload1   = self.vehicle_reload1;
 282         other.vehicle_reload2   = self.vehicle_reload2;
 283         other.vehicle_energy    = self.vehicle_energy;
 284         other.PlayerPhysplug    = bumb_gunner_frame;
 285         other.flags             &~= FL_ONGROUND;
 286
 287         msg_entity = other;
 288         WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 289         WriteEntity(MSG_ONE, _gun.vehicle_viewport);
 290         WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 291         WriteAngle(MSG_ONE, _gun.angles_x + self.angles_x);    // tilt
 292         WriteAngle(MSG_ONE, _gun.angles_y + self.angles_y);    // yaw
 293         WriteAngle(MSG_ONE, 0);                             // roll
 294         _gun.vehicle_hudmodel.viewmodelforclient = other;
 295
 296         CSQCVehicleSetup(other, other.hud);
 297
 298     if(other.flagcarried)
 299     {
 300         if(!autocvar_g_vehicles_allow_flagcarry)
 301             DropFlag(other.flagcarried, world, world);
 302         else
 303         {
 304             other.flagcarried.scale = 1;
 305             setattachment(other.flagcarried, self, "");
 306             setorigin(other.flagcarried, '0 0 1' * self.maxs_z);
 307         }
 308     }
 309
 310         return TRUE;
 311 }
 312
 313 float vehicles_valid_pilot()
 314 {
 315         if(other.classname != "player")
 316                 return FALSE;
 317
 318         if(other.deadflag != DEAD_NO)
 319                 return FALSE;
 320
 321         if(other.vehicle != world)
 322                 return FALSE;
 323
 324         if(clienttype(other) != CLIENTTYPE_REAL)
 325                 if(!autocvar_g_vehicles_allow_bots)
 326                         return FALSE;
 327
 328         if(teamplay && other.team != self.team)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 void bumb_touch()
 335 {
 336
 337         if(self.gunner1 != world && self.gunner2 != world)
 338         {
 339                 vehicles_touch();
 340                 return;
 341         }
 342
 343         if(vehicles_valid_pilot())
 344         {
 345                 if(self.gun1.phase <= time)
 346                         if(bumb_gunner_enter())
 347                                 return;
 348
 349                 if(self.gun2.phase <= time)
 350                         if(bumb_gunner_enter())
 351                                 return;
 352         }
 353
 354         vehicles_touch();
 355 }
 356
 357 void bumb_regen()
 358 {
 359         if(self.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 360                 self.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 361                                                                            self.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 362
 363         if(self.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 364                 self.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 365                                                                            self.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 366
 367         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 368                 vehicles_regen(self.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, TRUE);
 369
 370         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 371                 vehicles_regen(self.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, FALSE);
 372
 373         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 374                 vehicles_regen(self.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, FALSE);
 375
 376 }
 377
 378 float bumb_pilot_frame()
 379 {
 380         entity pilot, vehic;
 381         vector newvel;
 382
 383         pilot = self;
 384         vehic = self.vehicle;
 385         self   = vehic;
 386
 387
 388         if(vehic.deadflag != DEAD_NO)
 389         {
 390                 self = pilot;
 391                 pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = 0;
 392                 return 1;
 393         }
 394
 395         bumb_regen();
 396
 397         crosshair_trace(pilot);
 398
 399         vector vang;
 400         float ftmp;
 401
 402         vang = vehic.angles;
 403         newvel = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 404         vang_x *= -1;
 405         newvel_x *= -1;
 406         if(newvel_x > 180)  newvel_x -= 360;
 407         if(newvel_x < -180) newvel_x += 360;
 408         if(newvel_y > 180)  newvel_y -= 360;
 409         if(newvel_y < -180) newvel_y += 360;
 410
 411         ftmp = shortangle_f(pilot.v_angle_y - vang_y, vang_y);
 412         if(ftmp > 180)  ftmp -= 360;
 413         if(ftmp < -180) ftmp += 360;
 414         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 415
 416         // Pitch
 417         ftmp = 0;
 418         if(pilot.movement_x > 0 && vang_x < autocvar_g_vehicle_bumblebee_pitchlimit) ftmp = 5;
 419         else if(pilot.movement_x < 0 && vang_x > -autocvar_g_vehicle_bumblebee_pitchlimit) ftmp = -20;
 420
 421         newvel_x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x , autocvar_g_vehicle_bumblebee_pitchlimit);
 422         ftmp = vang_x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 423         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 424
 425         vehic.angles_x = anglemods(vehic.angles_x);
 426         vehic.angles_y = anglemods(vehic.angles_y);
 427         vehic.angles_z = anglemods(vehic.angles_z);
 428
 429         makevectors('0 1 0' * vehic.angles_y);
 430         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 431
 432         if(pilot.movement_x != 0)
 433         {
 434                 if(pilot.movement_x > 0)
 435                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 436                 else if(pilot.movement_x < 0)
 437                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 438         }
 439
 440         if(pilot.movement_y != 0)
 441         {
 442                 if(pilot.movement_y < 0)
 443                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 444                 else if(pilot.movement_y > 0)
 445                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 446                 ftmp = newvel * v_right;
 447                 ftmp *= frametime * 0.1;
 448                 vehic.angles_z = bound(-15, vehic.angles_z + ftmp, 15);
 449         }
 450         else
 451         {
 452                 vehic.angles_z *= 0.95;
 453                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 454                         vehic.angles_z = 0;
 455         }
 456
 457         if(pilot.BUTTON_CROUCH)
 458                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 459         else if(pilot.BUTTON_JUMP)
 460                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 461
 462         vehic.velocity  += newvel * frametime;
 463         pilot.velocity = pilot.movement  = vehic.velocity;
 464         setorigin(pilot, vehic.origin + '0 0 32');
 465
 466         vehicle_aimturret(vehic, trace_endpos, self.gun3, "fire",
 467                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 468                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 469
 470
 471         if((pilot.BUTTON_ATCK || pilot.BUTTON_ATCK2) && vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime)
 472         {
 473
 474                 if(vehic.gun3.enemy == world)
 475                 {
 476                         vehic.gun3.enemy = spawn();
 477                         Net_LinkEntity(vehic.gun3.enemy, FALSE, 0, bumble_raygun_send);
 478                         vehic.gun3.enemy.SendFlags = BRG_SETUP;
 479                         vehic.gun3.enemy.think = SUB_Remove;
 480                         vehic.gun3.enemy.realowner = pilot;
 481                         vehic.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 482                 }
 483
 484                 vehic.gun3.enemy.nextthink = time + 0.1;
 485                 setorigin(vehic.gun3.enemy, gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire")));
 486                 traceline(vehic.gun3.enemy.origin, vehic.gun3.enemy.origin + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 487                 if(trace_ent)
 488                 {
 489                         if(autocvar_g_vehicle_bumblebee_raygun)
 490                         {
 491                                 Damage(trace_ent, vehic, pilot, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 492                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 493                         }
 494                         else
 495                         {
 496                                 if(trace_ent.deadflag == DEAD_NO)
 497                                         if((teamplay && trace_ent.team == pilot.team) || !teamplay)
 498                                         {
 499
 500                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 501                                                 {
 502                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.tur_health)
 503                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.tur_health);
 504
 505                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 506                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 507                                                 }
 508                                                 else if(trace_ent.flags & FL_CLIENT)
 509                                                 {
 510                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 511                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 512
 513                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 514                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 515
 516                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 517                                                 }
 518                                                 else if(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 519                                                 {
 520                                                         if(trace_ent.health  <= trace_ent.tur_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 521                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 522                                                         //else ..hmmm what? ammo?
 523
 524                                                         trace_ent.SendFlags |= TNSF_STATUS;
 525                                                 }
 526                                         }
 527                         }
 528                 }
 529                 vehic.gun3.enemy.hook_end = trace_endpos;
 530                 vehic.gun3.enemy.SendFlags |= BRG_START;
 531                 vehic.gun3.enemy.SendFlags |= BRG_END;
 532                 vehic.wait = time + 1;
 533         }
 534         else
 535         {
 536                 if(vehic.gun3.enemy)
 537                         remove(vehic.gun3.enemy);
 538
 539                 vehic.gun3.enemy = world;
 540         }
 541
 542         VEHICLE_UPDATE_PLAYER(pilot, health, bumblebee);
 543         VEHICLE_UPDATE_PLAYER(pilot, energy, bumblebee);
 544
 545         pilot.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 546         pilot.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 547
 548         if(vehic.vehicle_flags & VHF_HASSHIELD)
 549                 VEHICLE_UPDATE_PLAYER(pilot, shield, bumblebee);
 550
 551
 552         pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = pilot.BUTTON_CROUCH = 0;
 553         self = pilot;
 554
 555         return 1;
 556 }
 557
 558 void bumb_think()
 559 {
 560         self.velocity = self.velocity * 0.99;
 561         self.nextthink = time + 0.1;
 562 }
 563
 564 void bumb_enter()
 565 {
 566         self.touch  = bumb_touch;
 567 }
 568
 569 void bumb_exit(float eject)
 570 {
 571         self.owner = world;
 572         self.touch = vehicles_touch;
 573 }
 574
 575 void bumb_blowup()
 576 {
 577         self.deadflag    = DEAD_DEAD;
 578
 579         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 580                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 581                                  autocvar_g_vehicle_bumblebee_blowup_radius, self,
 582                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 583                                  DEATH_WAKIBLOWUP, world);
 584
 585         self.movetype       = MOVETYPE_NONE;
 586         self.effects        = EF_NODRAW;
 587         self.colormod       = '0 0 0';
 588         self.avelocity      = '0 0 0';
 589         self.velocity       = '0 0 0';
 590
 591         //entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime)
 592         fixedmakevectors(self.angles);
 593         vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 300);
 594         vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 300);
 595         vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 596
 597         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 598         pointparticles(particleeffectnum("explosion_large"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 599
 600         setorigin(self, self.pos1);
 601         self.touch = SUB_Null;
 602         self.nextthink = 0;
 603 }
 604
 605 void bumb_diethink()
 606 {
 607         if(time >= self.wait)
 608                 self.think = bumb_blowup;
 609
 610         if(random() < 0.1)
 611         {
 612                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 613                 pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 614         }
 615
 616         self.nextthink = time + 0.1;
 617 }
 618
 619 void bumb_die()
 620 {
 621         entity oldself = self;
 622         if(self.gunner1)
 623         {
 624                 self = self.gunner1;
 625                 oldself.gun1.vehicle_exit(VHEF_EJECT);
 626                 self = oldself;
 627         }
 628
 629         if(self.gunner2)
 630         {
 631                 self = self.gunner2;
 632                 oldself.gun2.vehicle_exit(VHEF_EJECT);
 633                 self = oldself;
 634         }
 635
 636         self.vehicle_exit(VHEF_EJECT);
 637
 638         self.health       = 0;
 639         self.event_damage = SUB_Null;
 640         self.solid        = SOLID_CORPSE;
 641         self.takedamage   = DAMAGE_NO;
 642         self.deadflag     = DEAD_DYING;
 643         self.movetype     = MOVETYPE_BOUNCE;
 644         self.think        = bumb_diethink;
 645         self.nextthink    = time;
 646         self.wait         = time + 2 + (random() * 8);
 647
 648         self.avelocity = '0 0.5 1' * (random() * 400);
 649         self.avelocity -= '0 0.5 1' * (random() * 400);
 650
 651         self.colormod = '-0.5 -0.5 -0.5';
 652         self.touch     = bumb_blowup;
 653
 654         pointparticles(particleeffectnum("explosion_medium"), findbetterlocation(self.origin, 16), '0 0 0', 1);
 655 }
 656
 657
 658 void bumb_spawn(float _f)
 659 {
 660         /*
 661         float i;
 662         for(i=1; gettaginfo(self.gun1, i), gettaginfo_name; ++i)
 663         {
 664
 665             dprint(" ------- ^1gettaginfo_name^2(",ftos(i),") ^3=", gettaginfo_name, "\n");
 666         }
 667         */
 668
 669         if(!self.gun1)
 670         {
 671                 // for some reason, autosizing of the shiled entity refuses to work for this one so set it up in advance.
 672                 self.vehicle_shieldent = spawn();
 673                 self.vehicle_shieldent.effects = EF_LOWPRECISION;
 674                 setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 675                 setattachment(self.vehicle_shieldent, self, "");
 676                 setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 677                 self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 678                 self.vehicle_shieldent.think       = shieldhit_think;
 679                 self.vehicle_shieldent.alpha = -1;
 680                 self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 681
 682                 self.gun1 = spawn();
 683                 self.gun2 = spawn();
 684                 self.gun3 = spawn();
 685
 686                 self.vehicle_flags |= VHF_MULTISLOT;
 687
 688                 self.gun1.owner = self;
 689                 self.gun2.owner = self;
 690                 self.gun3.owner = self;
 691
 692                 setmodel(self.gun1, "models/vehicles/bumblebee_plasma_right.dpm");
 693                 setmodel(self.gun2, "models/vehicles/bumblebee_plasma_left.dpm");
 694                 setmodel(self.gun3, "models/vehicles/bumblebee_ray.dpm");
 695
 696                 setattachment(self.gun1, self, "cannon_right");
 697                 setattachment(self.gun2, self, "cannon_left");
 698
 699                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 700                 self.gun3.pos1 = self.angles;
 701                 self.angles = '0 0 0';
 702                 vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 703                 ofs -= self.origin;
 704                 setattachment(self.gun3, self, "");
 705                 setorigin(self.gun3, ofs);
 706                 self.angles = self.gun3.pos1;
 707
 708                 vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 709                 vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 710
 711                 setorigin(self.vehicle_hudmodel, '45 0 45');    // Move cockpit up-forward.
 712                 setorigin(self.vehicle_viewport, '8 0 5');    // Move camera up-forward too.
 713
 714                 //fixme-model-bones
 715                 setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 716                 setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 717                 //fixme-model-bones
 718                 setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 719                 setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 720
 721                 self.scale = 1.5;
 722         }
 723
 724         self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 725         self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 726         self.movetype       = MOVETYPE_TOSS;
 727         self.solid          = SOLID_BBOX;
 728         self.movetype = MOVETYPE_FLY;
 729         setorigin(self, self.origin + '0 0 25');
 730 }
 731
 732 void spawnfunc_vehicle_bumblebee()
 733 {
 734         if(!autocvar_g_vehicle_bumblebee)
 735         {
 736                 remove(self);
 737                 return;
 738         }
 739
 740         precache_model("models/vehicles/bumblebee_body.dpm");
 741         precache_model("models/vehicles/bumblebee_plasma_left.dpm");
 742         precache_model("models/vehicles/bumblebee_plasma_right.dpm");
 743         precache_model("models/vehicles/bumblebee_ray.dpm");
 744         precache_model("models/vehicles/wakizashi_cockpit.dpm");
 745         precache_model("models/vehicles/spiderbot_cockpit.dpm");
 746         precache_model("models/vehicles/raptor_cockpit.dpm");
 747
 748         if(autocvar_g_vehicle_bumblebee_energy)
 749                 if(autocvar_g_vehicle_bumblebee_energy_regen)
 750                         self.vehicle_flags |= VHF_ENERGYREGEN;
 751
 752         if(autocvar_g_vehicle_bumblebee_shield)
 753                 self.vehicle_flags |= VHF_HASSHIELD;
 754
 755         if(autocvar_g_vehicle_bumblebee_shield_regen)
 756                 self.vehicle_flags |= VHF_SHIELDREGEN;
 757
 758         if(autocvar_g_vehicle_bumblebee_health_regen)
 759                 self.vehicle_flags |= VHF_HEALTHREGEN;
 760
 761         if not(vehicle_initialize(
 762                            "Bumblebee", "models/vehicles/bumblebee_body.dpm",
 763                            "", "models/vehicles/spiderbot_cockpit.dpm", "", "", "tag_viewport",
 764                            HUD_BUMBLEBEE, BUMB_MIN, BUMB_MAX, FALSE,
 765                            bumb_spawn, autocvar_g_vehicle_bumblebee_respawntime,
 766                            bumb_pilot_frame, bumb_enter, bumb_exit,
 767                            bumb_die, bumb_think, FALSE, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_shield))
 768         {
 769                 remove(self);
 770                 return;
 771         }
 772 }
 773
 774 float bumble_raygun_send(entity to, float sf)
 775 {
 776         WriteByte(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
 777
 778         WriteByte(MSG_ENTITY, sf);
 779         if(sf & BRG_SETUP)
 780         {
 781                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 782                 WriteByte(MSG_ENTITY, self.realowner.team);
 783                 WriteByte(MSG_ENTITY, self.cnt);
 784
 785                 //WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 786         }
 787
 788         if(sf & BRG_START)
 789         {
 790                 WriteCoord(MSG_ENTITY, self.origin_x);
 791                 WriteCoord(MSG_ENTITY, self.origin_y);
 792                 WriteCoord(MSG_ENTITY, self.origin_z);
 793         }
 794
 795         if(sf & BRG_END)
 796         {
 797                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 798                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 799                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 800         }
 801
 802         return TRUE;
 803 }
 804 #endif // SVQC
 805
 806 #ifdef CSQC
 807 /*
 808 .vector raygun_l1
 809 .vector raygun_l2;
 810 .vector raygun_l3;
 811 */
 812
 813 void bumble_raygun_draw()
 814 {
 815         float _len;
 816         vector _dir;
 817         vector _vtmp1, _vtmp2;
 818
 819         _len = vlen(self.origin - self.move_origin);
 820         _dir = normalize(self.move_origin - self.origin);
 821
 822         float i, df, sz, al;
 823
 824         for(i = -0.1; i < 0.2; i += 0.1)
 825         {
 826                 df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
 827                 sz = 2 + random() * 6;
 828                 al = 0.25 + random() * 0.5;
 829                 _vtmp1 = self.origin + _dir * _len * (0.25 + i);
 830                 _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //self.raygun_l1;
 831                 Draw_CylindricLine(self.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 832
 833                 _vtmp2 = self.origin + _dir * _len * (0.5 + i);
 834                 _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //self.raygun_l2;
 835                 Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 836
 837                 _vtmp1 = self.origin + _dir * _len * (0.75 + i);
 838                 _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //self.raygun_l3;
 839                 Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 840
 841                 Draw_CylindricLine(_vtmp1, self.move_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 842         }
 843
 844 }
 845
 846 void bumble_raygun_read(float bIsNew)
 847 {
 848         float sf = ReadByte();
 849
 850         if(sf & BRG_SETUP)
 851         {
 852                 self.cnt  = ReadByte();
 853                 self.team = ReadByte();
 854                 self.cnt  = ReadByte();
 855                 if(self.cnt)
 856                         self.colormod = '1 0 0';
 857                 else
 858                         self.colormod = '0 1 0';
 859
 860                 self.draw = bumble_raygun_draw;
 861         }
 862
 863         if(sf & BRG_START)
 864         {
 865                 self.origin_x = ReadCoord();
 866                 self.origin_y = ReadCoord();
 867                 self.origin_z = ReadCoord();
 868                 setorigin(self, self.origin);
 869         }
 870
 871         if(sf & BRG_END)
 872         {
 873                 self.move_origin_x = ReadCoord();
 874                 self.move_origin_y = ReadCoord();
 875                 self.move_origin_z = ReadCoord();
 876         }
 877 }
 878
 879 void bumblebee_draw()
 880 {
 881
 882 }
 883
 884 void bumblebee_draw2d()
 885 {
 886
 887 }
 888
 889 void bumblebee_read_extra()
 890 {
 891
 892 }
 893
 894 void vehicle_bumblebee_assemble()
 895 {
 896
 897 }
 898 #endif //CSQC