qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3
   4 #ifdef SVQC
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19 float autocvar_g_vehicle_racer_friction;
  20
  21 float autocvar_g_vehicle_racer_hovertype;
  22 float autocvar_g_vehicle_racer_hoverpower;
  23
  24 float autocvar_g_vehicle_racer_turnroll;
  25 float autocvar_g_vehicle_racer_turnspeed;
  26 float autocvar_g_vehicle_racer_pitchspeed;
  27
  28 float autocvar_g_vehicle_racer_energy;
  29 float autocvar_g_vehicle_racer_energy_regen;
  30 float autocvar_g_vehicle_racer_energy_regen_pause;
  31
  32 float autocvar_g_vehicle_racer_health;
  33 float autocvar_g_vehicle_racer_health_regen;
  34 float autocvar_g_vehicle_racer_health_regen_pause;
  35
  36 float autocvar_g_vehicle_racer_shield;
  37 float autocvar_g_vehicle_racer_shield_regen;
  38 float autocvar_g_vehicle_racer_shield_regen_pause;
  39
  40 float autocvar_g_vehicle_racer_cannon_cost;
  41 float autocvar_g_vehicle_racer_cannon_damage;
  42 float autocvar_g_vehicle_racer_cannon_radius;
  43 float autocvar_g_vehicle_racer_cannon_refire;
  44 float autocvar_g_vehicle_racer_cannon_speed;
  45 float autocvar_g_vehicle_racer_cannon_spread;
  46 float autocvar_g_vehicle_racer_cannon_force;
  47
  48 float autocvar_g_vehicle_racer_rocket_accel;
  49 float autocvar_g_vehicle_racer_rocket_damage;
  50 float autocvar_g_vehicle_racer_rocket_radius;
  51 float autocvar_g_vehicle_racer_rocket_force;
  52 float autocvar_g_vehicle_racer_rocket_refire;
  53 float autocvar_g_vehicle_racer_rocket_speed;
  54 float autocvar_g_vehicle_racer_rocket_turnrate;
  55
  56 float autocvar_g_vehicle_racer_rocket_locktarget;
  57 float autocvar_g_vehicle_racer_rocket_locking_time;
  58 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  59 float autocvar_g_vehicle_racer_rocket_locked_time;
  60 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  61
  62 float autocvar_g_vehicle_racer_respawntime;
  63
  64 float autocvar_g_vehicle_racer_blowup_radius;
  65 float autocvar_g_vehicle_racer_blowup_coredamage;
  66 float autocvar_g_vehicle_racer_blowup_edgedamage;
  67 float autocvar_g_vehicle_racer_blowup_forceintensity;
  68
  69 float autocvar_g_vehicle_racer_bouncefactor;
  70 float autocvar_g_vehicle_racer_bouncestop;
  71 vector autocvar_g_vehicle_racer_bouncepain;
  72
  73 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  74
  75 void racer_align4point(float _delta)
  76 {
  77     vector push_vector;
  78     float fl_push, fr_push, bl_push, br_push;
  79
  80     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  81     fr_push      = force_fromtag_normpower;
  82     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  83
  84     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  85     fl_push      = force_fromtag_normpower;
  86     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  87
  88     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  89     br_push      = force_fromtag_normpower;
  90     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  91
  92     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  93     bl_push      = force_fromtag_normpower;
  94     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  95
  96    self.velocity += push_vector * _delta;
  97
  98     // Anti ocilation
  99     if(self.velocity_z > 0)
 100         self.velocity_z *= 1 - autocvar_g_vehicle_racer_upforcedamper * _delta;
 101
 102     push_vector_x =  (fl_push - bl_push);
 103     push_vector_x += (fr_push - br_push);
 104     push_vector_x *= 360;
 105
 106     push_vector_z = (fr_push - fl_push);
 107     push_vector_z += (br_push - bl_push);
 108     push_vector_z *= 360;
 109
 110     // Apply angle diffrance
 111     self.angles_z += push_vector_z * _delta;
 112     self.angles_x += push_vector_x * _delta;
 113
 114     // Apply stabilizer
 115     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 116     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 117 }
 118
 119 void racer_fire_cannon(string tagname)
 120 {
 121     vector v;
 122     entity bolt;
 123
 124     v = gettaginfo(self, gettagindex(self, tagname));
 125     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 126                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 127                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 128                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 129
 130         // Fix z-aim (for chase mode)
 131     v = normalize(trace_endpos - bolt.origin);
 132     v_forward_z = v_z * 0.5;
 133     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 134 }
 135
 136 void racer_rocket_groundhugger()
 137 {
 138     vector olddir, newdir;
 139     float oldvel, newvel;
 140
 141     self.nextthink  = time;
 142
 143     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 144     {
 145         self.use();
 146         return;
 147     }
 148
 149     if not (self.realowner.vehicle)
 150     {
 151         UpdateCSQCProjectile(self);
 152         return;
 153     }
 154
 155     olddir = normalize(self.velocity);
 156     oldvel = vlen(self.velocity);
 157     newvel = oldvel + self.lip;
 158
 159     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 160     if(trace_fraction <= 0.5)
 161     {
 162         // Hitting somethign soon, just speed ahead
 163         self.velocity = olddir * newvel;
 164         UpdateCSQCProjectile(self);
 165         return;
 166     }
 167
 168     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 169     if(trace_fraction != 1.0)
 170     {
 171         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 172         self.velocity = normalize(olddir + newdir) * newvel;
 173     }
 174     else
 175     {
 176         self.velocity = olddir * newvel;
 177         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 178     }
 179
 180     UpdateCSQCProjectile(self);
 181     return;
 182 }
 183
 184 void racer_rocket_tracker()
 185 {
 186     vector olddir, newdir;
 187     float oldvel, newvel;
 188
 189     self.nextthink  = time;
 190
 191     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 192     {
 193         self.use();
 194         return;
 195     }
 196
 197     if not (self.realowner.vehicle)
 198     {
 199         UpdateCSQCProjectile(self);
 200         return;
 201     }
 202
 203     olddir = normalize(self.velocity);
 204     oldvel = vlen(self.velocity);
 205     newvel = oldvel + self.lip;
 206     makevectors(vectoangles(olddir));
 207
 208     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 209     newdir = normalize(self.enemy.origin - self.origin);
 210
 211     //vector
 212         float height_diff = self.enemy.origin_z - self.origin_z;
 213
 214     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 215     {
 216         //bprint("Target lost!\n");
 217         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 218         self.think = racer_rocket_groundhugger;
 219         return;
 220     }
 221
 222     if(trace_fraction != 1.0 && trace_ent != self.enemy)
 223         newdir_z += 16 * sys_frametime;
 224
 225     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 226     self.velocity_z -= 800 * sys_frametime ;
 227     self.velocity_z += max(height_diff, cvar("bajs")) * sys_frametime ;
 228
 229     UpdateCSQCProjectile(self);
 230     return;
 231 }
 232
 233 void racer_fire_rocket(string tagname, entity trg)
 234 {
 235     vector v = gettaginfo(self, gettagindex(self, tagname));
 236     entity rocket = rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259         if(intermission_running)
 260                 return 1;
 261
 262     player  = self;
 263     racer   = self.vehicle;
 264     self    = racer;
 265
 266     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 267
 268     vehicles_painframe();
 269
 270     if(racer.deadflag != DEAD_NO)
 271     {
 272         self = player;
 273         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 274         return 1;
 275     }
 276
 277     racer_align4point(frametime);
 278
 279     crosshair_trace(player);
 280
 281     racer.angles_x *= -1;
 282
 283     // Yaw
 284     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 285     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 286     racer.angles_y = anglemods(racer.angles_y + ftmp);
 287
 288     // Roll
 289     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 290
 291     // Pitch
 292     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 293     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 294     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 295
 296     makevectors(racer.angles);
 297     racer.angles_x *= -1;
 298
 299     //ftmp = racer.velocity_z;
 300     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 301     //racer.velocity_z = ftmp;
 302
 303     if(vlen(player.movement) != 0)
 304     {
 305         if(player.movement_x)
 306             df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward);
 307
 308         if(player.movement_y)
 309             df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe);
 310
 311         if(self.sound_nexttime < time || self.sounds != 1)
 312         {
 313             self.sounds = 1;
 314             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 315             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 316         }
 317     }
 318     else
 319     {
 320         if(self.sound_nexttime < time || self.sounds != 0)
 321         {
 322             self.sounds = 0;
 323             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 324             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 325         }
 326     }
 327
 328     // Afterburn
 329     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 330     {
 331         if(time - racer.wait > 0.2)
 332             pointparticles(particleeffectnum("wakizashi_booster_smoke"), self.origin, '0 0 0', 1);
 333
 334         racer.wait = time;
 335         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 336         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 337
 338         if(racer.invincible_finished < time)
 339         {
 340             traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 341             if(trace_fraction != 1.0)
 342                 pointparticles(particleeffectnum("smoke_small"), trace_endpos, '0 0 0', 1);
 343
 344             racer.invincible_finished = time + 0.1 + (random() * 0.1);
 345         }
 346
 347         if(racer.strength_finished < time)
 348         {
 349             racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 350             sound (racer.tur_head, CH_TRIGGER_SINGLE, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 351         }
 352     }
 353     else
 354     {
 355         racer.strength_finished = 0;
 356         sound (racer.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 357     }
 358
 359         df -= v_up * (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce);
 360     player.movement = racer.velocity += df * frametime;
 361
 362     if(player.BUTTON_ATCK)
 363     if(time > racer.attack_finished_single)
 364     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 365     {
 366         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 367         racer.wait = time;
 368
 369         crosshair_trace(player);
 370         if(racer.cnt)
 371         {
 372             racer_fire_cannon("tag_fire1");
 373             racer.cnt = 0;
 374         }
 375         else
 376         {
 377             racer_fire_cannon("tag_fire2");
 378             racer.cnt = 1;
 379         }
 380         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 381     }
 382
 383     if(autocvar_g_vehicle_racer_rocket_locktarget)
 384     {
 385         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 386                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 387                          autocvar_g_vehicle_racer_rocket_locked_time);
 388
 389         if(self.lock_target)
 390         {
 391             if(racer.lock_strength == 1)
 392                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 393             else if(self.lock_strength > 0.5)
 394                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 395             else if(self.lock_strength < 0.5)
 396                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 397         }
 398     }
 399
 400     if(time > racer.delay)
 401     if(player.BUTTON_ATCK2)
 402     {
 403         racer.misc_bulletcounter += 1;
 404         racer.delay = time + 0.3;
 405
 406         if(racer.misc_bulletcounter == 1)
 407             racer_fire_rocket("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 408         else if(racer.misc_bulletcounter == 2)
 409         {
 410             racer_fire_rocket("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 411             racer.lock_strength  = 0;
 412             racer.lock_target    = world;
 413             racer.misc_bulletcounter = 0;
 414
 415             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 416             racer.lip = time;
 417         }
 418     }
 419     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 420
 421     if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 422         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 423
 424     if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 425         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 426
 427     if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 428         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 429
 430
 431     VEHICLE_UPDATE_PLAYER(health, racer);
 432     VEHICLE_UPDATE_PLAYER(energy, racer);
 433
 434     if(racer.vehicle_flags & VHF_HASSHIELD)
 435         VEHICLE_UPDATE_PLAYER(shield, racer);
 436
 437     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 438     setorigin(player,racer.origin + '0 0 32');
 439     player.velocity = racer.velocity;
 440
 441     self = player;
 442     return 1;
 443 }
 444
 445 void racer_think()
 446 {
 447     self.nextthink = time;
 448
 449     float pushdeltatime = time - self.lastpushtime;
 450     if (pushdeltatime > 0.15) pushdeltatime = 0;
 451     self.lastpushtime = time;
 452     if(!pushdeltatime) return;
 453
 454     tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NORMAL, self);
 455
 456     vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 457         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 458
 459         self.velocity += df * pushdeltatime;
 460     if(self.velocity_z > 0)
 461         self.velocity_z *= 1 - autocvar_g_vehicle_racer_upforcedamper * pushdeltatime;
 462
 463     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 464     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 465 }
 466
 467 void racer_enter()
 468 {
 469     self.movetype = MOVETYPE_BOUNCE;
 470     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 471     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 472
 473     if(self.owner.flagcarried)
 474        setorigin(self.owner.flagcarried, '-190 0 96');
 475 }
 476
 477 void racer_exit(float eject)
 478 {
 479     vector spot;
 480
 481     self.think      = racer_think;
 482     self.nextthink  = time;
 483     self.movetype   = MOVETYPE_BOUNCE;
 484     sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 485
 486     if not (self.owner)
 487         return;
 488
 489         makevectors(self.angles);
 490         if(eject)
 491         {
 492             spot = self.origin + v_forward * 100 + '0 0 64';
 493             spot = vehicles_findgoodexit(spot);
 494             setorigin(self.owner , spot);
 495             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 496             self.owner.oldvelocity = self.owner.velocity;
 497         }
 498         else
 499         {
 500                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 501                 {
 502                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 503                         self.owner.velocity_z += 200;
 504                         spot = self.origin + v_forward * 32 + '0 0 32';
 505                         spot = vehicles_findgoodexit(spot);
 506                 }
 507                 else
 508                 {
 509                         self.owner.velocity = self.velocity * 0.5;
 510                         self.owner.velocity_z += 10;
 511                         spot = self.origin - v_forward * 200 + '0 0 32';
 512                         spot = vehicles_findgoodexit(spot);
 513                 }
 514             self.owner.oldvelocity = self.owner.velocity;
 515             setorigin(self.owner , spot);
 516         }
 517         antilag_clear(self.owner);
 518     self.owner = world;
 519 }
 520
 521 void racer_impact()
 522 {
 523     if(autocvar_g_vehicle_racer_bouncepain_x)
 524         vehilces_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 525 }
 526
 527 void racer_spawn()
 528 {
 529     self.think          = racer_think;
 530     self.nextthink      = time;
 531     self.vehicle_health = autocvar_g_vehicle_racer_health;
 532     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 533
 534     self.movetype       = MOVETYPE_TOSS;
 535     self.solid          = SOLID_SLIDEBOX;
 536     self.delay          = time;
 537     self.scale          = 0.5;
 538
 539     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 540     self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 541     self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 542     self.vehicle_impact = racer_impact;
 543     //self.destvec = autocvar_g_vehicle_racer_bouncepain;
 544 }
 545
 546
 547 void racer_blowup()
 548 {
 549     self.deadflag    = DEAD_DEAD;
 550     self.vehicle_exit(VHEF_NORMAL);
 551
 552     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 553                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 554                                         autocvar_g_vehicle_racer_blowup_radius, world,
 555                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 556                                         DEATH_WAKIBLOWUP, world);
 557
 558     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 559     self.think      = racer_spawn;
 560     self.movetype   = MOVETYPE_NONE;
 561     self.effects    = EF_NODRAW;
 562
 563     self.colormod  = '0 0 0';
 564     self.avelocity = '0 0 0';
 565     self.velocity  = '0 0 0';
 566
 567     setorigin(self, self.pos1);
 568         self.think     = racer_spawn;
 569         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 570 }
 571
 572 void racer_deadtouch()
 573 {
 574     self.avelocity_x *= 0.7;
 575     self.cnt -= 1;
 576     if(self.cnt <= 0)
 577         racer_blowup();
 578 }
 579
 580 void racer_die()
 581 {
 582     self.health       = 0;
 583     self.event_damage = SUB_Null;
 584     self.solid        = SOLID_CORPSE;
 585     self.takedamage   = DAMAGE_NO;
 586     self.deadflag     = DEAD_DYING;
 587     self.movetype     = MOVETYPE_BOUNCE;
 588     self.wait         = time;
 589     self.cnt          = 1 + random() * 2;
 590     self.touch        = racer_deadtouch;
 591
 592     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 593
 594     if(random() < 0.5)
 595         self.avelocity_z  = 32;
 596     else
 597         self.avelocity_z  = -32;
 598
 599     self.avelocity_x = -vlen(self.velocity) * 0.2;
 600     self.velocity   += '0 0 700';
 601     self.colormod    = '-0.5 -0.5 -0.5';
 602
 603         self.think     = racer_blowup;
 604         self.nextthink = 2 + time + random() * 3;
 605 }
 606
 607 void racer_dinit()
 608 {
 609     if not (vehicle_initialize(
 610              "Wakizashi",
 611              "models/vehicles/wakizashi.dpm",
 612              "null", // we need this so tur_head is networked and usable for sounds
 613              "models/vehicles/wakizashi_cockpit.dpm",
 614              "", "", "tag_viewport",
 615              HUD_WAKIZASHI,
 616              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 617              FALSE,
 618              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 619              racer_frame,
 620              racer_enter, racer_exit,
 621              racer_die,   racer_think,
 622              TRUE))
 623     {
 624         remove(self);
 625         return;
 626     }
 627
 628     if(autocvar_g_vehicle_racer_hovertype != 0)
 629         racer_force_from_tag = vehicles_force_fromtag_maglev;
 630     else
 631         racer_force_from_tag = vehicles_force_fromtag_hover;
 632
 633     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 634     self.scale = 0.5;
 635     setattachment(self.vehicle_hudmodel, self, "");
 636     setattachment(self.vehicle_viewport, self, "tag_viewport");
 637
 638     self.mass               = 900;
 639 }
 640
 641 void spawnfunc_vehicle_racer()
 642 {
 643     self.vehicle_flags |= VHF_DMGSHAKE;
 644     self.vehicle_flags |= VHF_DMGROLL;
 645
 646     precache_sound ("weapons/lasergun_fire.wav");
 647     precache_sound ("weapons/rocket_fire.wav");
 648
 649     precache_sound ("vehicles/racer_idle.wav");
 650     precache_sound ("vehicles/racer_move.wav");
 651     precache_sound ("vehicles/racer_boost.wav");
 652
 653     precache_model ("models/vhshield.md3");
 654     precache_model ("models/vehicles/wakizashi.dpm");
 655     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 656
 657     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 658     if(autocvar_g_vehicle_racer_energy)
 659         if(autocvar_g_vehicle_racer_energy_regen)
 660             self.vehicle_flags |= VHF_ENERGYREGEN;
 661
 662     if(autocvar_g_vehicle_racer_shield)
 663         self.vehicle_flags |= VHF_HASSHIELD;
 664
 665     if(autocvar_g_vehicle_racer_shield_regen)
 666         self.vehicle_flags |= VHF_SHIELDREGEN;
 667
 668     if(autocvar_g_vehicle_racer_health_regen)
 669         self.vehicle_flags |= VHF_HEALTHREGEN;
 670
 671     self.think = racer_dinit;
 672
 673     if(g_assault)
 674         self.nextthink = time + 0.5;
 675     else
 676         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 677 }
 678 #endif // SVQC