qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45 float autocvar_g_vehicle_raptor_cannon_force;
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 float raptor_frame();
  61 float raptor_takeoff();
  62
  63 .entity bomb1;
  64 .entity bomb2;
  65
  66 //#define RAPTOR_RETARDCAMERA
  67
  68 float raptor_altitude(float amax)
  69 {
  70         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  71     return vlen(self.origin - trace_endpos);
  72 }
  73
  74
  75 void raptor_bomblet_boom()
  76 {
  77     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  78     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  79     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  80                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  81                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  82                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  83     remove(self);
  84 }
  85
  86 void raptor_bomblet_touch()
  87 {
  88     if(other == self.owner)
  89         return;
  90
  91     PROJECTILE_TOUCH;
  92     self.think = raptor_bomblet_boom;
  93     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  94 }
  95
  96 void raptor_bomb_burst()
  97 {
  98     if(self.cnt > time)
  99     if(autocvar_g_vehicle_raptor_bomblet_alt)
 100     {
 101         UpdateCSQCProjectile(self);
 102         self.nextthink = time;
 103         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 104         if(trace_fraction == 1.0)
 105             return;
 106
 107         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 108             return;
 109     }
 110
 111     entity bomblet;
 112     float i;
 113
 114     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 115     pointparticles(particleeffectnum("rocket_explode"), self.origin, self.velocity, 1);
 116
 117     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 118     {
 119         bomblet = spawn();
 120         setorigin(bomblet, self.origin);
 121
 122         //bomblet.solid       = SOLID_TRIGGER;
 123         bomblet.movetype    = MOVETYPE_TOSS;
 124         bomblet.touch       = raptor_bomblet_touch;
 125         bomblet.think       = raptor_bomblet_boom;
 126         bomblet.nextthink   = time + 5;
 127         bomblet.owner       = self.owner;
 128         bomblet.realowner   = self.realowner;
 129         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 130         PROJECTILE_MAKETRIGGER(bomblet);
 131         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 132     }
 133
 134     remove(self);
 135 }
 136
 137 void raptor_bomb_touch()
 138 {
 139     raptor_bomb_burst();
 140 }
 141
 142 void raptor_bombdrop()
 143 {
 144     entity bomb_1, bomb_2;
 145
 146     //self.bomb1.alpha = 0;
 147     //self.bomb2.alpha = 0;
 148
 149     bomb_1 = spawn();
 150     bomb_2 = spawn();
 151
 152     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 153     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 154
 155     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 156     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 157     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 158     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 159     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 160
 161     if(autocvar_g_vehicle_raptor_bomblet_alt)
 162         bomb_1.nextthink = bomb_2.nextthink  = time;
 163     else
 164         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 165
 166     bomb_1.owner     = bomb_2.owner      = self;
 167     bomb_1.realowner = bomb_2.realowner  = self.owner;
 168     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 169     bomb_1.gravity   = bomb_2.gravity    = 1;
 170
 171     PROJECTILE_MAKETRIGGER(bomb_1);
 172     PROJECTILE_MAKETRIGGER(bomb_2);
 173
 174     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 176
 177 }
 178
 179
 180 void raptor_fire_cannon(entity gun, string tagname)
 181 {
 182     entity bolt;
 183     vector b_org;
 184     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 185     bolt = vehicles_projectile("raptor_cannon_impact", "weapons/laserimpact.wav", "raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 186                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 187                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 188                            DEATH_WAKIGUN, PROJECTILE_RAPTORCANNON, 0);
 189 }
 190
 191 void raptor_think()
 192 {
 193 }
 194
 195 void raptor_enter()
 196 {
 197     self.owner.PlayerPhysplug = raptor_takeoff;
 198     self.movetype       = MOVETYPE_FLY;
 199     self.solid          = SOLID_BBOX;
 200     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 201     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 202     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 203     self.tur_head.exteriormodeltoclient = self.owner;
 204
 205 #ifdef RAPTOR_RETARDCAMERA
 206     setorigin(self.vehicle_viewport, self.origin);
 207 #endif
 208 }
 209
 210 void raptor_land()
 211 {
 212     float hgt;
 213
 214     hgt = raptor_altitude(512);
 215     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 216     self.angles_x *= 0.95;
 217     self.angles_z *= 0.95;
 218
 219     if(hgt < 128)
 220         if(self.frame != 0)
 221             self.frame = max(self.frame - 0.25, 0);
 222
 223     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 224     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 225
 226     if(hgt < 16)
 227     {
 228         self.movetype   = MOVETYPE_TOSS;
 229         self.think      = raptor_think;
 230     }
 231
 232     self.nextthink  = time;
 233 }
 234
 235 void raptor_exit(float eject)
 236 {
 237     self.tur_head.exteriormodeltoclient = world;
 238
 239     if(self.deadflag == DEAD_NO)
 240     {
 241         self.think      = raptor_land;
 242         self.nextthink  = time;
 243     }
 244
 245     if not (self.owner)
 246         return;
 247
 248         makevectors(self.angles);
 249         if(eject)
 250         {
 251             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 252             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 253         }
 254         else
 255         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 256
 257     self.owner = world;
 258 }
 259
 260 float raptor_takeoff()
 261 {
 262     entity player, raptor;
 263
 264     player = self;
 265     raptor = self.vehicle;
 266     self   = raptor;
 267
 268     // Takeoff sequense
 269     if(raptor.frame < 25)
 270     {
 271         raptor.frame += 0.25;
 272         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 273         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 274         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 275         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 276
 277         setorigin(player, raptor.origin + '0 0 32');
 278     }
 279     else
 280         player.PlayerPhysplug = raptor_frame;
 281
 282     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 283     self = player;
 284     return 1;
 285 }
 286
 287 float raptor_frame()
 288 {
 289     entity player, raptor;
 290     float ftmp, ftmp2;
 291     vector df;
 292
 293     player = self;
 294     raptor = self.vehicle;
 295     self   = raptor;
 296
 297     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 298     {
 299         self = raptor;
 300         vehicles_exit(VHEF_NORMAL);
 301         self = player;
 302         return 0;
 303     }
 304
 305     if(raptor.deadflag != DEAD_NO)
 306     {
 307         self = player;
 308         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 309         return 1;
 310     }
 311
 312
 313
 314     crosshair_trace(player);
 315
 316 #if VEHICLES_VIEWROTATE_CROSSHAIR
 317     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 318     if(df_x > 180)  df_x -= 360;
 319     if(df_x < -180) df_x += 360;
 320     if(df_y > 180)  df_y -= 360;
 321     if(df_y < -180) df_y += 360;
 322
 323     // Rotate Body
 324     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 325     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 326
 327     // Turn
 328     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 329     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 330
 331     // Pitch Body
 332     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 333     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 334
 335     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 336     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 337 #else
 338     vector vang;
 339     vang = raptor.angles;
 340     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 341     vang_x *= -1;
 342     df_x *= -1;
 343     if(df_x > 180)  df_x -= 360;
 344     if(df_x < -180) df_x += 360;
 345     if(df_y > 180)  df_y -= 360;
 346     if(df_y < -180) df_y += 360;
 347
 348     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 349     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 350     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 351
 352     // Pitch
 353     ftmp = 0;
 354     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 355     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 356
 357     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 358     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 359     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 360
 361     raptor.angles_x = anglemods(raptor.angles_x);
 362     raptor.angles_y = anglemods(raptor.angles_y);
 363     raptor.angles_z = anglemods(raptor.angles_z);
 364
 365 #endif
 366
 367     if(autocvar_g_vehicle_raptor_movestyle == 1)
 368         makevectors('0 1 0' * raptor.angles_y);
 369     else
 370         makevectors(player.v_angle);
 371
 372 #ifdef RAPTOR_RETARDCAMERA
 373     float spd, back, up;
 374     spd = vlen(self.velocity) + 0.01;
 375     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 376     up = 1 - back;
 377     back = back;
 378     back = back * 1250;
 379     back += 150;
 380     up = up * 200;
 381     up = up + 100;
 382
 383     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 384 #endif
 385
 386     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 387
 388     if(player.movement_x != 0)
 389     {
 390         if(player.movement_x > 0)
 391             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 392         else if(player.movement_x < 0)
 393             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 394     }
 395
 396     if(player.movement_y != 0)
 397     {
 398         if(player.movement_y < 0)
 399             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 400         else if(player.movement_y > 0)
 401             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 402
 403         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 404     }
 405     else
 406     {
 407         raptor.angles_z *= 0.95;
 408         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 409             raptor.angles_z = 0;
 410     }
 411
 412     if(player.BUTTON_CROUCH)
 413         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 414     else if (player.BUTTON_JUMP)
 415         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 416
 417     raptor.velocity  += df * frametime;
 418     player.velocity = player.movement  = raptor.velocity;
 419     setorigin(player,raptor.origin + '0 0 32');
 420
 421     vector vf, ad;
 422     // Target lock & predict
 423     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 424     {
 425
 426         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 427                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 428                              autocvar_g_vehicle_raptor_cannon_locked_time);
 429
 430         if(self.lock_target != world)
 431         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 432         if(self.lock_strength == 1)
 433         {
 434             float i, distance, impact_time;
 435
 436             vf = real_origin(raptor.lock_target);
 437             ad = vf;
 438             for(i = 0; i < 4; ++i)
 439             {
 440                 distance = vlen(ad - raptor.origin);
 441                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 442                 ad = vf + raptor.lock_target.velocity * impact_time;
 443             }
 444             trace_endpos = ad;
 445             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 446         }
 447
 448         if(self.lock_target)
 449         {
 450             if(raptor.lock_strength == 1)
 451                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 452             else if(self.lock_strength > 0.5)
 453                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 454             else if(self.lock_strength < 0.5)
 455                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 456         }
 457     }
 458
 459     // Aim the gunz
 460     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 461     ftmp = -ftmp2;
 462
 463     // Gun1
 464     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 465     //ad = df;
 466     //vf = v_forward;
 467     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 468     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 469     // Bind to aimspeed
 470     df_x = bound(ftmp, df_x, ftmp2);
 471     df_y = bound(ftmp, df_y, ftmp2);
 472     // Bind to limts
 473     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 474     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 475
 476     //df = vectoangles(normalize(trace_endpos - df));
 477
 478     //Gun 2
 479     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 480     //ad += df;
 481     //vf += v_forward;
 482     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 483     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 484     // Bind to aimspeed
 485     df_x = bound(ftmp, df_x, ftmp2);
 486     df_y = bound(ftmp, df_y, ftmp2);
 487     // Bind to limts
 488     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 489     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 490
 491     /*
 492     ad = ad * 0.5;
 493     v_forward = vf * 0.5;
 494     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 495     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 496     */
 497
 498     if(player.BUTTON_ATCK)
 499     if(raptor.attack_finished_single <= time)
 500     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 501     {
 502         raptor.misc_bulletcounter += 1;
 503         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 504         if(raptor.misc_bulletcounter <= 2)
 505             raptor_fire_cannon(self.gun1, "fire1");
 506         else if(raptor.misc_bulletcounter == 3)
 507             raptor_fire_cannon(self.gun2, "fire1");
 508         else
 509         {
 510             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 511             raptor_fire_cannon(self.gun2, "fire1");
 512             raptor.misc_bulletcounter = 0;
 513         }
 514         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 515         self.cnt = time;
 516     }
 517
 518     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 519         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 520
 521     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 522         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 523
 524     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 525         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 526
 527
 528     if(time > raptor.delay)
 529     if(player.BUTTON_ATCK2)
 530     {
 531         raptor_bombdrop();
 532         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 533         raptor.lip   = time;
 534     }
 535
 536     player.vehicle_reload1 = (time - raptor.lip) / (raptor.delay - raptor.lip);
 537     raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 538
 539     VEHICLE_UPDATE_PLAYER(health, raptor);
 540     VEHICLE_UPDATE_PLAYER(energy, raptor);
 541     if(self.vehicle_flags & VHF_HASSHIELD)
 542         VEHICLE_UPDATE_PLAYER(shield, raptor);
 543
 544
 545
 546     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 547     return 1;
 548 }
 549
 550 void raptor_blowup()
 551 {
 552     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 553     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 554
 555     self.deadflag    = DEAD_DEAD;
 556     self.vehicle_exit(VHEF_NORMAL);
 557     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 558
 559     self.alpha          = -1;
 560     self.movetype       = MOVETYPE_NONE;
 561     self.effects        = EF_NODRAW;
 562     self.colormod       = '0 0 0';
 563     self.avelocity      = '0 0 0';
 564     self.velocity       = '0 0 0';
 565
 566     setorigin(self, self.pos1);
 567     self.touch = SUB_Null;
 568 }
 569
 570 void raptor_die()
 571 {
 572     self.health       = 0;
 573     self.event_damage = SUB_Null;
 574     self.iscreature   = FALSE;
 575     self.solid        = SOLID_CORPSE;
 576     self.takedamage   = DAMAGE_NO;
 577     self.deadflag     = DEAD_DYING;
 578     self.movetype     = MOVETYPE_BOUNCE;
 579
 580     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 581
 582     self.velocity_z += 128;
 583
 584     if(random() < 0.5)
 585         self.avelocity_z  = 45 + random() * 270;
 586     else
 587         self.avelocity_z  = -45 + random() * -270;
 588
 589     self.colormod = '-0.5 -0.5 -0.5';
 590         self.touch     = raptor_blowup;
 591 }
 592
 593 void raptor_spawn()
 594 {
 595     self.frame          = 0;
 596     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 597     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 598     self.movetype       = MOVETYPE_TOSS;
 599     self.solid          = SOLID_BBOX;
 600     self.vehicle_energy = 1;
 601
 602     self.bomb1.gun1.avelocity_y = 90;
 603     self.bomb1.gun2.avelocity_y = -90;
 604
 605     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 606     self.delay = time;
 607 }
 608
 609 // If we dont do this ever now and then, the raptors rotors
 610 // stop working, presumably due to angle overflow. cute.
 611 void raptor_rotor_anglefix()
 612 {
 613     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 614     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 615     self.nextthink = time + 15;
 616 }
 617
 618 void raptor_dinit()
 619 {
 620     entity spinner;
 621     vector ofs;
 622
 623     if not (vehicle_initialize(
 624              "Raptor",
 625              "models/vehicles/raptor.dpm",
 626              "",
 627              "models/vehicles/raptor_cockpit.dpm",
 628              "", "tag_hud", "tag_camera",
 629              HUD_RAPTOR,
 630              RAPTOR_MIN, RAPTOR_MAX,
 631              FALSE,
 632              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 633              raptor_frame,
 634              raptor_enter, raptor_exit,
 635              raptor_die,   raptor_think))
 636     {
 637         remove(self);
 638         return;
 639     }
 640
 641     //FIXME: Camera is in a bad place in HUD model.
 642     //setorigin(self.vehicle_viewport, '25 0 5');
 643
 644     self.frame = 0;
 645
 646     self.bomb1 = spawn();
 647     self.bomb2 = spawn();
 648     self.gun1  = spawn();
 649     self.gun2  = spawn();
 650
 651 #ifdef RAPTOR_RETARDCAMERA
 652     setattachment(self.vehicle_viewport, world, "");
 653 #endif
 654
 655     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 656     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 657     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 658     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 659     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 660
 661     setattachment(self.bomb1, self,"bombmount_left");
 662     setattachment(self.bomb2, self,"bombmount_right");
 663     setattachment(self.tur_head, self,"root");
 664
 665
 666     // FIXME Guns mounts to angled bones
 667     self.bomb1.angles = self.angles;
 668     self.angles = '0 0 0';
 669     // This messes up gun-aim, so work arround it.
 670     //setattachment(self.gun1, self, "gunmount_left");
 671     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 672     ofs -= self.origin;
 673     setattachment(self.gun1, self, "");
 674     setorigin(self.gun1, ofs);
 675
 676     //setattachment(self.gun2, self, "gunmount_right");
 677     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 678     ofs -= self.origin;
 679     setattachment(self.gun2, self, "");
 680     setorigin(self.gun2, ofs);
 681
 682     self.angles = self.bomb1.angles;
 683     self.bomb1.angles = '0 0 0';
 684
 685     spinner = spawn();
 686     spinner.owner = self;
 687     setmodel(spinner,"models/vehicles/spinner.dpm");
 688     setattachment(spinner, self, "engine_left");
 689     spinner.movetype = MOVETYPE_NOCLIP;
 690     spinner.avelocity = '0 90 0';
 691     self.bomb1.gun1 = spinner;
 692
 693     spinner = spawn();
 694     spinner.owner = self;
 695     setmodel(spinner,"models/vehicles/spinner.dpm");
 696     setattachment(spinner, self, "engine_right");
 697     spinner.movetype = MOVETYPE_NOCLIP;
 698     spinner.avelocity = '0 -90 0';
 699     self.bomb1.gun2 = spinner;
 700
 701     // Sigh.
 702     self.bomb1.think = raptor_rotor_anglefix;
 703     self.bomb1.nextthink = time;
 704
 705     self.mass               = 1 ;
 706 }
 707
 708 void spawnfunc_vehicle_raptor()
 709 {
 710     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 711
 712     if(autocvar_g_vehicle_raptor_shield)
 713         self.vehicle_flags |= VHF_HASSHIELD;
 714
 715     if(autocvar_g_vehicle_raptor_shield_regen)
 716         self.vehicle_flags |= VHF_SHIELDREGEN;
 717
 718     if(autocvar_g_vehicle_raptor_health_regen)
 719         self.vehicle_flags |= VHF_HEALTHREGEN;
 720
 721     if(autocvar_g_vehicle_raptor_energy_regen)
 722         self.vehicle_flags |= VHF_ENERGYREGEN;
 723
 724     precache_model ("models/vehicles/raptor.dpm");
 725     precache_model ("models/vehicles/raptor_gun.dpm");
 726     precache_model ("models/vehicles/spinner.dpm");
 727     precache_model ("models/vehicles/raptor_cockpit.dpm");
 728     precache_model ("models/vehicles/clusterbomb.md3");
 729     precache_model ("models/vehicles/clusterbomb_folded.md3");
 730     precache_model ("models/vehicles/raptor_body.dpm");
 731
 732     self.think = raptor_dinit;
 733     self.nextthink = time + 1;
 734 }