qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 float autocvar_g_vehicle_raptor_bouncefactor;
  61 float autocvar_g_vehicle_raptor_bouncestop;
  62 vector autocvar_g_vehicle_raptor_bouncepain;
  63
  64 void raptor_spawn();
  65 float raptor_frame();
  66 float raptor_takeoff();
  67
  68 .entity bomb1;
  69 .entity bomb2;
  70
  71 float raptor_altitude(float amax)
  72 {
  73         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  74     return vlen(self.origin - trace_endpos);
  75 }
  76
  77
  78 void raptor_bomblet_boom()
  79 {
  80     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  81                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  82                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  83                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  84     remove(self);
  85 }
  86
  87 void raptor_bomblet_touch()
  88 {
  89     if(other == self.owner)
  90         return;
  91
  92     PROJECTILE_TOUCH;
  93     self.think = raptor_bomblet_boom;
  94     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  95 }
  96
  97 void raptor_bomb_burst()
  98 {
  99     if(self.cnt > time)
 100     if(autocvar_g_vehicle_raptor_bomblet_alt)
 101     {
 102         self.nextthink = time;
 103         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 104         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 105         {
 106             UpdateCSQCProjectile(self);
 107             return;
 108         }
 109     }
 110
 111     entity bomblet;
 112     float i;
 113
 114     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, 0, self);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         bomblet.movetype    = MOVETYPE_TOSS;
 122         bomblet.touch       = raptor_bomblet_touch;
 123         bomblet.think       = raptor_bomblet_boom;
 124         bomblet.nextthink   = time + 5;
 125         bomblet.owner       = self.owner;
 126         bomblet.realowner   = self.realowner;
 127         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 128
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bombdrop()
 137 {
 138     entity bomb_1, bomb_2;
 139
 140     bomb_1 = spawn();
 141     bomb_2 = spawn();
 142
 143     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 144     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 145
 146     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 147     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 148     bomb_1.touch        = bomb_2.touch      = raptor_bomb_burst;
 149     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 150     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 151
 152     if(autocvar_g_vehicle_raptor_bomblet_alt)
 153         bomb_1.nextthink = bomb_2.nextthink  = time;
 154     else
 155         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 156
 157     bomb_1.owner     = bomb_2.owner      = self;
 158     bomb_1.realowner = bomb_2.realowner  = self.owner;
 159     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 160     bomb_1.gravity   = bomb_2.gravity    = 1;
 161
 162     PROJECTILE_MAKETRIGGER(bomb_1);
 163     PROJECTILE_MAKETRIGGER(bomb_2);
 164
 165     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 166     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167 }
 168
 169
 170 void raptor_fire_cannon(entity gun, string tagname)
 171 {
 172     vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 173                            gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 174                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 175                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 176 }
 177
 178 void raptor_think()
 179 {
 180 }
 181
 182 void raptor_enter()
 183 {
 184     self.owner.PlayerPhysplug = raptor_takeoff;
 185     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 186     self.solid          = SOLID_SLIDEBOX;
 187     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 188     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 189     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 190     self.tur_head.exteriormodeltoclient = self.owner;
 191
 192     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 193     self.lip   = time;
 194
 195     if(self.owner.flagcarried)
 196        setorigin(self.owner.flagcarried, '-20 0 96');
 197
 198 }
 199
 200 void raptor_land()
 201 {
 202     float hgt;
 203
 204     hgt = raptor_altitude(512);
 205     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 206     self.angles_x *= 0.95;
 207     self.angles_z *= 0.95;
 208
 209     if(hgt < 128)
 210     if(hgt > 0)
 211         self.frame = (hgt / 128) * 25;
 212
 213     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 214     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 215
 216     if(hgt < 16)
 217     {
 218         self.movetype = MOVETYPE_TOSS;
 219         self.think    = raptor_think;
 220         self.frame    = 0;
 221     }
 222
 223     self.nextthink  = time;
 224 }
 225
 226 void raptor_exit(float eject)
 227 {
 228     vector spot;
 229     self.tur_head.exteriormodeltoclient = world;
 230
 231     if(self.deadflag == DEAD_NO)
 232     {
 233         self.think      = raptor_land;
 234         self.nextthink  = time;
 235     }
 236
 237     if not (self.owner)
 238         return;
 239
 240         makevectors(self.angles);
 241         if(eject)
 242         {
 243             spot = self.origin + v_forward * 100 + '0 0 64';
 244             spot = vehicles_findgoodexit(spot);
 245             setorigin(self.owner , spot);
 246             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 247         }
 248         else
 249         {
 250             self.owner.velocity = '0 0 0';
 251             spot = self.origin - v_forward * 200 + '0 0 64';
 252             spot = vehicles_findgoodexit(spot);
 253             setorigin(self.owner , spot);
 254         }
 255         antilag_clear(self.owner);
 256     self.owner = world;
 257 }
 258
 259 float raptor_takeoff()
 260 {
 261     entity player, raptor;
 262
 263     player = self;
 264     raptor = self.vehicle;
 265     self   = raptor;
 266     if(self.sound_nexttime < time)
 267     {
 268         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 269         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 270     }
 271
 272     // Takeoff sequense
 273     if(raptor.frame < 25)
 274     {
 275         raptor.frame += 0.25;
 276         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 277         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 278         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 279         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 280
 281         setorigin(player, raptor.origin + '0 0 32');
 282     }
 283     else
 284         player.PlayerPhysplug = raptor_frame;
 285
 286     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 287         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 288
 289     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 290         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 291
 292     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 293         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 294
 295
 296     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 297     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 298
 299     VEHICLE_UPDATE_PLAYER(health, raptor);
 300     VEHICLE_UPDATE_PLAYER(energy, raptor);
 301     if(self.vehicle_flags & VHF_HASSHIELD)
 302         VEHICLE_UPDATE_PLAYER(shield, raptor);
 303
 304     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 305     self = player;
 306     return 1;
 307 }
 308
 309 float raptor_frame()
 310 {
 311     entity player, raptor;
 312     float ftmp, ftmp2;
 313     vector df;
 314
 315         if(intermission_running)
 316                 return 1;
 317
 318     player = self;
 319     raptor = self.vehicle;
 320     self   = raptor;
 321     vehicles_painframe();
 322     /*
 323     ftmp = vlen(self.velocity);
 324     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 325         ftmp = 1;
 326     else
 327         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 328     */
 329
 330     if(self.sound_nexttime < time)
 331     {
 332         self.sound_nexttime = time + 7.955812;
 333         //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 334         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 335         self.wait = ftmp;
 336     }
 337     /*
 338     else if(fabs(ftmp - self.wait) > 0.2)
 339     {
 340         sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTN_NORM );
 341         sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTN_NORM);
 342         self.wait = ftmp;
 343     }
 344     */
 345
 346     if(raptor.deadflag != DEAD_NO)
 347     {
 348         self = player;
 349         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 350         return 1;
 351     }
 352     crosshair_trace(player);
 353
 354     vector vang;
 355     vang = raptor.angles;
 356     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 357     vang_x *= -1;
 358     df_x *= -1;
 359     if(df_x > 180)  df_x -= 360;
 360     if(df_x < -180) df_x += 360;
 361     if(df_y > 180)  df_y -= 360;
 362     if(df_y < -180) df_y += 360;
 363
 364     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 365     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 366     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 367
 368     // Pitch
 369     ftmp = 0;
 370     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 371     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 372
 373     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 374     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 375     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 376
 377     raptor.angles_x = anglemods(raptor.angles_x);
 378     raptor.angles_y = anglemods(raptor.angles_y);
 379     raptor.angles_z = anglemods(raptor.angles_z);
 380
 381     if(autocvar_g_vehicle_raptor_movestyle == 1)
 382         makevectors('0 1 0' * raptor.angles_y);
 383     else
 384         makevectors(player.v_angle);
 385
 386     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 387
 388     if(player.movement_x != 0)
 389     {
 390         if(player.movement_x > 0)
 391             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 392         else if(player.movement_x < 0)
 393             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 394     }
 395
 396     if(player.movement_y != 0)
 397     {
 398         if(player.movement_y < 0)
 399             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 400         else if(player.movement_y > 0)
 401             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 402
 403         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 404     }
 405     else
 406     {
 407         raptor.angles_z *= 0.95;
 408         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 409             raptor.angles_z = 0;
 410     }
 411
 412     if(player.BUTTON_CROUCH)
 413         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 414     else if (player.BUTTON_JUMP)
 415         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 416
 417     raptor.velocity  += df * frametime;
 418     player.velocity = player.movement  = raptor.velocity;
 419     setorigin(player, raptor.origin + '0 0 32');
 420
 421     vector vf, ad;
 422     // Target lock & predict
 423     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 424     {
 425
 426         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 427                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 428                              autocvar_g_vehicle_raptor_cannon_locked_time);
 429
 430         if(self.lock_target != world)
 431         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 432         if(self.lock_strength == 1)
 433         {
 434             float i, distance, impact_time;
 435
 436             vf = real_origin(raptor.lock_target);
 437             ad = vf;
 438             for(i = 0; i < 4; ++i)
 439             {
 440                 distance = vlen(ad - raptor.origin);
 441                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 442                 ad = vf + raptor.lock_target.velocity * impact_time;
 443             }
 444             trace_endpos = ad;
 445         }
 446
 447         if(self.lock_target)
 448         {
 449             if(raptor.lock_strength == 1)
 450                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 451             else if(self.lock_strength > 0.5)
 452                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 453             else if(self.lock_strength < 0.5)
 454                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 455         }
 456     }
 457
 458     // Aim the gunz
 459     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 460     ftmp = -ftmp2;
 461
 462     // Gun1
 463     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 464     //ad = df;
 465     //vf = v_forward;
 466     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 467     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun1.angles;
 468     df = shortangle_vxy(df, raptor.gun1.angles);
 469
 470     // Bind to aimspeed
 471     df_x = bound(ftmp, df_x, ftmp2);
 472     df_y = bound(ftmp, df_y, ftmp2);
 473     // Bind to limts
 474     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 475     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 476
 477     // Gun2
 478     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 479     //ad += df;
 480     //vf += v_forward;
 481     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 482     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun2.angles;
 483     df = shortangle_vxy(df, raptor.gun2.angles);
 484
 485     // Bind to aimspeed
 486     df_x = bound(ftmp, df_x, ftmp2);
 487     df_y = bound(ftmp, df_y, ftmp2);
 488     // Bind to limts
 489     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 490     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 491
 492     /*
 493     ad = ad * 0.5;
 494     v_forward = vf * 0.5;
 495     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 496     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 497     */
 498
 499     if(player.BUTTON_ATCK)
 500     if(raptor.attack_finished_single <= time)
 501     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 502     {
 503         raptor.misc_bulletcounter += 1;
 504         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 505         if(raptor.misc_bulletcounter <= 2)
 506             raptor_fire_cannon(self.gun1, "fire1");
 507         else if(raptor.misc_bulletcounter == 3)
 508             raptor_fire_cannon(self.gun2, "fire1");
 509         else
 510         {
 511             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 512             raptor_fire_cannon(self.gun2, "fire1");
 513             raptor.misc_bulletcounter = 0;
 514         }
 515         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 516         self.cnt = time;
 517     }
 518
 519     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 520         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 521
 522     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 523         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 524
 525     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 526         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 527
 528
 529     if(time > raptor.delay)
 530     if(player.BUTTON_ATCK2)
 531     {
 532         raptor_bombdrop();
 533         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 534         raptor.lip   = time;
 535     }
 536
 537     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 538     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 539
 540     VEHICLE_UPDATE_PLAYER(health, raptor);
 541     VEHICLE_UPDATE_PLAYER(energy, raptor);
 542     if(self.vehicle_flags & VHF_HASSHIELD)
 543         VEHICLE_UPDATE_PLAYER(shield, raptor);
 544
 545     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 546
 547     self = player;
 548     return 1;
 549 }
 550
 551 void raptor_blowup()
 552 {
 553     self.deadflag    = DEAD_DEAD;
 554     self.vehicle_exit(VHEF_NORMAL);
 555     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 556
 557     self.alpha          = -1;
 558     self.movetype       = MOVETYPE_NONE;
 559     self.effects        = EF_NODRAW;
 560     self.colormod       = '0 0 0';
 561     self.avelocity      = '0 0 0';
 562     self.velocity       = '0 0 0';
 563
 564     setorigin(self, self.pos1);
 565     self.touch = SUB_Null;
 566     self.nextthink = 0;
 567 }
 568
 569 void raptor_diethink()
 570 {
 571     if(random() < 0.1)
 572     {
 573         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 574         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 575     }
 576     self.nextthink = time + 0.1;
 577 }
 578
 579 void raptor_die()
 580 {
 581     self.health       = 0;
 582     self.event_damage = SUB_Null;
 583     self.solid        = SOLID_CORPSE;
 584     self.takedamage   = DAMAGE_NO;
 585     self.deadflag     = DEAD_DYING;
 586     self.movetype     = MOVETYPE_BOUNCE;
 587     self.think        = raptor_diethink;
 588     self.nextthink    = time;
 589
 590     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 591
 592     self.velocity_z += 600;
 593
 594     self.avelocity = '0 0.5 1' * (random() * 400);
 595     self.avelocity -= '0 0.5 1' * (random() * 400);
 596
 597     self.colormod = '-0.5 -0.5 -0.5';
 598         self.touch     = raptor_blowup;
 599 }
 600
 601 void raptor_impact()
 602 {
 603     if(autocvar_g_vehicle_raptor_bouncepain_x)
 604         vehilces_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 605 }
 606
 607 void raptor_spawn()
 608 {
 609     self.frame          = 0;
 610     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 611     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 612     self.movetype       = MOVETYPE_TOSS;
 613     self.solid          = SOLID_SLIDEBOX;
 614     self.vehicle_energy = 1;
 615
 616     self.bomb1.gun1.avelocity_y = 90;
 617     self.bomb1.gun2.avelocity_y = -90;
 618
 619     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 620     self.delay = time;
 621
 622     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 623     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 624     self.vehicle_impact = raptor_impact;
 625 }
 626
 627 // If we dont do this ever now and then, the raptors rotors
 628 // stop working, presumably due to angle overflow. cute.
 629 void raptor_rotor_anglefix()
 630 {
 631     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 632     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 633     self.nextthink = time + 15;
 634 }
 635
 636 void raptor_dinit()
 637 {
 638     entity spinner;
 639     vector ofs;
 640
 641     if not (vehicle_initialize(
 642              "Raptor",
 643              "models/vehicles/raptor.dpm",
 644              "",
 645              "models/vehicles/raptor_cockpit.dpm",
 646              "", "tag_hud", "tag_camera",
 647              HUD_RAPTOR,
 648              RAPTOR_MIN, RAPTOR_MAX,
 649              FALSE,
 650              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 651              raptor_frame,
 652              raptor_enter, raptor_exit,
 653              raptor_die,   raptor_think,
 654              FALSE))
 655     {
 656         remove(self);
 657         return;
 658     }
 659
 660     //FIXME: Camera is in a bad place in HUD model.
 661     //setorigin(self.vehicle_viewport, '25 0 5');
 662
 663     self.frame = 0;
 664
 665     self.bomb1 = spawn();
 666     self.bomb2 = spawn();
 667     self.gun1  = spawn();
 668     self.gun2  = spawn();
 669
 670     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 671     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 672     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 673     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 674     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 675
 676     setattachment(self.bomb1, self,"bombmount_left");
 677     setattachment(self.bomb2, self,"bombmount_right");
 678     setattachment(self.tur_head, self,"root");
 679
 680
 681     // FIXME Guns mounts to angled bones
 682     self.bomb1.angles = self.angles;
 683     self.angles = '0 0 0';
 684     // This messes up gun-aim, so work arround it.
 685     //setattachment(self.gun1, self, "gunmount_left");
 686     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 687     ofs -= self.origin;
 688     setattachment(self.gun1, self, "");
 689     setorigin(self.gun1, ofs);
 690
 691     //setattachment(self.gun2, self, "gunmount_right");
 692     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 693     ofs -= self.origin;
 694     setattachment(self.gun2, self, "");
 695     setorigin(self.gun2, ofs);
 696
 697     self.angles = self.bomb1.angles;
 698     self.bomb1.angles = '0 0 0';
 699
 700     spinner = spawn();
 701     spinner.owner = self;
 702     setmodel(spinner,"models/vehicles/spinner.dpm");
 703     setattachment(spinner, self, "engine_left");
 704     spinner.movetype = MOVETYPE_NOCLIP;
 705     spinner.avelocity = '0 90 0';
 706     self.bomb1.gun1 = spinner;
 707
 708     spinner = spawn();
 709     spinner.owner = self;
 710     setmodel(spinner,"models/vehicles/spinner.dpm");
 711     setattachment(spinner, self, "engine_right");
 712     spinner.movetype = MOVETYPE_NOCLIP;
 713     spinner.avelocity = '0 -90 0';
 714     self.bomb1.gun2 = spinner;
 715
 716     // Sigh.
 717     self.bomb1.think = raptor_rotor_anglefix;
 718     self.bomb1.nextthink = time;
 719
 720     self.mass               = 1 ;
 721 }
 722
 723 void spawnfunc_vehicle_raptor()
 724 {
 725     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 726
 727     self.vehicle_flags |= VHF_DMGSHAKE;
 728     self.vehicle_flags |= VHF_DMGROLL;
 729
 730     if(autocvar_g_vehicle_raptor_shield)
 731         self.vehicle_flags |= VHF_HASSHIELD;
 732
 733     if(autocvar_g_vehicle_raptor_shield_regen)
 734         self.vehicle_flags |= VHF_SHIELDREGEN;
 735
 736     if(autocvar_g_vehicle_raptor_health_regen)
 737         self.vehicle_flags |= VHF_HEALTHREGEN;
 738
 739     if(autocvar_g_vehicle_raptor_energy_regen)
 740         self.vehicle_flags |= VHF_ENERGYREGEN;
 741
 742     precache_model ("models/vehicles/raptor.dpm");
 743     precache_model ("models/vehicles/raptor_gun.dpm");
 744     precache_model ("models/vehicles/spinner.dpm");
 745     precache_model ("models/vehicles/raptor_cockpit.dpm");
 746     //precache_model ("models/vehicles/clusterbomb.md3");
 747     precache_model ("models/vehicles/clusterbomb_folded.md3");
 748     precache_model ("models/vehicles/raptor_body.dpm");
 749
 750     precache_sound ("vehicles/raptor_fly.wav");
 751     precache_sound ("vehicles/raptor_speed.wav");
 752
 753     self.think = raptor_dinit;
 754
 755     if(g_assault)
 756         self.nextthink = time + 0.5;
 757     else
 758         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 759 }
 760 #endif // SVQC