qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4
   5 float autocvar_g_vehicle_raptor_respawntime;
   6 float autocvar_g_vehicle_raptor_takeofftime;
   7
   8 float autocvar_g_vehicle_raptor_movestyle;
   9 float autocvar_g_vehicle_raptor_turnspeed;
  10 float autocvar_g_vehicle_raptor_pitchspeed;
  11 float autocvar_g_vehicle_raptor_pitchlimit;
  12
  13 float autocvar_g_vehicle_raptor_speed_forward;
  14 float autocvar_g_vehicle_raptor_speed_strafe;
  15 float autocvar_g_vehicle_raptor_speed_up;
  16 float autocvar_g_vehicle_raptor_speed_down;
  17 float autocvar_g_vehicle_raptor_friction;
  18
  19 float autocvar_g_vehicle_raptor_bomblets;
  20 float autocvar_g_vehicle_raptor_bomblet_alt;
  21 float autocvar_g_vehicle_raptor_bomblet_time;
  22 float autocvar_g_vehicle_raptor_bomblet_damage;
  23 float autocvar_g_vehicle_raptor_bomblet_spread;
  24 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  25 float autocvar_g_vehicle_raptor_bomblet_radius;
  26 float autocvar_g_vehicle_raptor_bomblet_force;
  27 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  28 float autocvar_g_vehicle_raptor_bombs_refire;
  29
  30 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  31 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  33 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  34
  35 float autocvar_g_vehicle_raptor_cannon_locktarget;
  36 float autocvar_g_vehicle_raptor_cannon_locking_time;
  37 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  38 float autocvar_g_vehicle_raptor_cannon_locked_time;
  39 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  40
  41 float autocvar_g_vehicle_raptor_cannon_cost;
  42 float autocvar_g_vehicle_raptor_cannon_damage;
  43 float autocvar_g_vehicle_raptor_cannon_radius;
  44 float autocvar_g_vehicle_raptor_cannon_refire;
  45 float autocvar_g_vehicle_raptor_cannon_speed;
  46 float autocvar_g_vehicle_raptor_cannon_spread;
  47 float autocvar_g_vehicle_raptor_cannon_force;
  48
  49 float autocvar_g_vehicle_raptor_energy;
  50 float autocvar_g_vehicle_raptor_energy_regen;
  51 float autocvar_g_vehicle_raptor_energy_regen_pause;
  52
  53 float autocvar_g_vehicle_raptor_health;
  54 float autocvar_g_vehicle_raptor_health_regen;
  55 float autocvar_g_vehicle_raptor_health_regen_pause;
  56
  57 float autocvar_g_vehicle_raptor_shield;
  58 float autocvar_g_vehicle_raptor_shield_regen;
  59 float autocvar_g_vehicle_raptor_shield_regen_pause;
  60
  61 float autocvar_g_vehicle_raptor_bouncefactor;
  62 float autocvar_g_vehicle_raptor_bouncestop;
  63 vector autocvar_g_vehicle_raptor_bouncepain;
  64
  65 void raptor_spawn();
  66 float raptor_frame();
  67 float raptor_takeoff();
  68
  69 .entity bomb1;
  70 .entity bomb2;
  71
  72 float raptor_altitude(float amax)
  73 {
  74         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  75     return vlen(self.origin - trace_endpos);
  76 }
  77
  78
  79 void raptor_bomblet_boom()
  80 {
  81     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  82                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  83                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  84                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  85     remove(self);
  86 }
  87
  88 void raptor_bomblet_touch()
  89 {
  90     if(other == self.owner)
  91         return;
  92
  93     PROJECTILE_TOUCH;
  94     self.think = raptor_bomblet_boom;
  95     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  96 }
  97
  98 void raptor_bomb_burst()
  99 {
 100     if(self.cnt > time)
 101     if(autocvar_g_vehicle_raptor_bomblet_alt)
 102     {
 103         self.nextthink = time;
 104         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 105         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 106         {
 107             UpdateCSQCProjectile(self);
 108             return;
 109         }
 110     }
 111
 112     entity bomblet;
 113     float i;
 114
 115     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, 0, self);
 116
 117     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 118     {
 119         bomblet = spawn();
 120         setorigin(bomblet, self.origin);
 121
 122         bomblet.movetype    = MOVETYPE_TOSS;
 123         bomblet.touch       = raptor_bomblet_touch;
 124         bomblet.think       = raptor_bomblet_boom;
 125         bomblet.nextthink   = time + 5;
 126         bomblet.owner       = self.owner;
 127         bomblet.realowner   = self.realowner;
 128         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 129
 130         PROJECTILE_MAKETRIGGER(bomblet);
 131         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 132     }
 133
 134     remove(self);
 135 }
 136
 137 void raptor_bombdrop()
 138 {
 139     entity bomb_1, bomb_2;
 140
 141     bomb_1 = spawn();
 142     bomb_2 = spawn();
 143
 144     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 145     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 146
 147     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 148     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 149     bomb_1.touch        = bomb_2.touch      = raptor_bomb_burst;
 150     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 151     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 152
 153     if(autocvar_g_vehicle_raptor_bomblet_alt)
 154         bomb_1.nextthink = bomb_2.nextthink  = time;
 155     else
 156         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 157
 158     bomb_1.owner     = bomb_2.owner      = self;
 159     bomb_1.realowner = bomb_2.realowner  = self.owner;
 160     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 161     bomb_1.gravity   = bomb_2.gravity    = 1;
 162
 163     PROJECTILE_MAKETRIGGER(bomb_1);
 164     PROJECTILE_MAKETRIGGER(bomb_2);
 165
 166     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 168 }
 169
 170
 171 void raptor_fire_cannon(entity gun, string tagname)
 172 {
 173     vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 174                            gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 175                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 176                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 177 }
 178
 179 void raptor_think()
 180 {
 181 }
 182
 183 void raptor_enter()
 184 {
 185     self.owner.PlayerPhysplug = raptor_takeoff;
 186     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 187     self.solid          = SOLID_SLIDEBOX;
 188     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 189     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 190     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 191     self.tur_head.exteriormodeltoclient = self.owner;
 192
 193     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 194     self.lip   = time;
 195
 196     if(self.owner.flagcarried)
 197        setorigin(self.owner.flagcarried, '-20 0 96');
 198
 199 }
 200
 201 void raptor_land()
 202 {
 203     float hgt;
 204
 205     hgt = raptor_altitude(512);
 206     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 207     self.angles_x *= 0.95;
 208     self.angles_z *= 0.95;
 209
 210     if(hgt < 128)
 211     if(hgt > 0)
 212         self.frame = (hgt / 128) * 25;
 213
 214     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 215     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 216
 217     if(hgt < 16)
 218     {
 219         self.movetype = MOVETYPE_TOSS;
 220         self.think    = raptor_think;
 221         self.frame    = 0;
 222     }
 223
 224     self.nextthink  = time;
 225 }
 226
 227 void raptor_exit(float eject)
 228 {
 229     vector spot;
 230     self.tur_head.exteriormodeltoclient = world;
 231
 232     if(self.deadflag == DEAD_NO)
 233     {
 234         self.think      = raptor_land;
 235         self.nextthink  = time;
 236     }
 237
 238     if not (self.owner)
 239         return;
 240
 241         makevectors(self.angles);
 242         if(eject)
 243         {
 244             spot = self.origin + v_forward * 100 + '0 0 64';
 245             spot = vehicles_findgoodexit(spot);
 246             setorigin(self.owner , spot);
 247             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 248             self.owner.oldvelocity = self.owner.velocity;
 249         }
 250         else
 251         {
 252             self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed;
 253             self.owner.oldvelocity = self.owner.velocity;
 254             spot = self.origin - v_forward * 200 + '0 0 64';
 255             spot = vehicles_findgoodexit(spot);
 256             setorigin(self.owner , spot);
 257         }
 258         antilag_clear(self.owner);
 259     self.owner = world;
 260 }
 261
 262 float raptor_takeoff()
 263 {
 264     entity player, raptor;
 265
 266     player = self;
 267     raptor = self.vehicle;
 268     self   = raptor;
 269     if(self.sound_nexttime < time)
 270     {
 271         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 272         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 273     }
 274
 275     // Takeoff sequense
 276     if(raptor.frame < 25)
 277     {
 278         raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 279         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 280         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 281         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 282         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 283
 284         setorigin(player, raptor.origin + '0 0 32');
 285     }
 286     else
 287         player.PlayerPhysplug = raptor_frame;
 288
 289     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 290         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 291
 292     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 293         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 294
 295     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 296         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 297
 298
 299     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 300     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 301
 302     VEHICLE_UPDATE_PLAYER(health, raptor);
 303     VEHICLE_UPDATE_PLAYER(energy, raptor);
 304     if(self.vehicle_flags & VHF_HASSHIELD)
 305         VEHICLE_UPDATE_PLAYER(shield, raptor);
 306
 307     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 308     self = player;
 309     return 1;
 310 }
 311
 312 float raptor_frame()
 313 {
 314     entity player, raptor;
 315     float ftmp = 0;
 316     vector df;
 317
 318         if(intermission_running)
 319                 return 1;
 320
 321     player = self;
 322     raptor = self.vehicle;
 323     self   = raptor;
 324     vehicles_painframe();
 325     /*
 326     ftmp = vlen(self.velocity);
 327     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 328         ftmp = 1;
 329     else
 330         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 331     */
 332
 333     if(self.sound_nexttime < time)
 334     {
 335         self.sound_nexttime = time + 7.955812;
 336         //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 337         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 338         self.wait = ftmp;
 339     }
 340     /*
 341     else if(fabs(ftmp - self.wait) > 0.2)
 342     {
 343         sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTN_NORM );
 344         sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTN_NORM);
 345         self.wait = ftmp;
 346     }
 347     */
 348
 349     if(raptor.deadflag != DEAD_NO)
 350     {
 351         self = player;
 352         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 353         return 1;
 354     }
 355     crosshair_trace(player);
 356
 357     vector vang;
 358     vang = raptor.angles;
 359     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 360     vang_x *= -1;
 361     df_x *= -1;
 362     if(df_x > 180)  df_x -= 360;
 363     if(df_x < -180) df_x += 360;
 364     if(df_y > 180)  df_y -= 360;
 365     if(df_y < -180) df_y += 360;
 366
 367     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 368     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 369     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 370
 371     // Pitch
 372     ftmp = 0;
 373     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 374     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 375
 376     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 377     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 378     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 379
 380     raptor.angles_x = anglemods(raptor.angles_x);
 381     raptor.angles_y = anglemods(raptor.angles_y);
 382     raptor.angles_z = anglemods(raptor.angles_z);
 383
 384     if(autocvar_g_vehicle_raptor_movestyle == 1)
 385         makevectors('0 1 0' * raptor.angles_y);
 386     else
 387         makevectors(player.v_angle);
 388
 389     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 390
 391     if(player.movement_x != 0)
 392     {
 393         if(player.movement_x > 0)
 394             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 395         else if(player.movement_x < 0)
 396             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 397     }
 398
 399     if(player.movement_y != 0)
 400     {
 401         if(player.movement_y < 0)
 402             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 403         else if(player.movement_y > 0)
 404             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 405
 406         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 407     }
 408     else
 409     {
 410         raptor.angles_z *= 0.95;
 411         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 412             raptor.angles_z = 0;
 413     }
 414
 415     if(player.BUTTON_CROUCH)
 416         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 417     else if (player.BUTTON_JUMP)
 418         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 419
 420     raptor.velocity  += df * frametime;
 421     player.velocity = player.movement  = raptor.velocity;
 422     setorigin(player, raptor.origin + '0 0 32');
 423
 424     vector vf, ad;
 425     // Target lock & predict
 426     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 427     {
 428
 429         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 430                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 431                              autocvar_g_vehicle_raptor_cannon_locked_time);
 432
 433         if(self.lock_target != world)
 434         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 435         if(self.lock_strength == 1)
 436         {
 437             float i, distance, impact_time;
 438
 439             vf = real_origin(raptor.lock_target);
 440             ad = vf;
 441             for(i = 0; i < 4; ++i)
 442             {
 443                 distance = vlen(ad - raptor.origin);
 444                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 445                 ad = vf + raptor.lock_target.velocity * impact_time;
 446             }
 447             trace_endpos = ad;
 448         }
 449
 450         if(self.lock_target)
 451         {
 452             if(raptor.lock_strength == 1)
 453                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 454             else if(self.lock_strength > 0.5)
 455                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 456             else if(self.lock_strength < 0.5)
 457                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 458         }
 459     }
 460
 461
 462     vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 463                           autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 464                           autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 465
 466     vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 467                           autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 468                           autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 469
 470     /*
 471     ad = ad * 0.5;
 472     v_forward = vf * 0.5;
 473     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 474     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 475     */
 476
 477     if(player.BUTTON_ATCK)
 478     if(raptor.attack_finished_single <= time)
 479     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 480     {
 481         raptor.misc_bulletcounter += 1;
 482         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 483         if(raptor.misc_bulletcounter <= 2)
 484             raptor_fire_cannon(self.gun1, "fire1");
 485         else if(raptor.misc_bulletcounter == 3)
 486             raptor_fire_cannon(self.gun2, "fire1");
 487         else
 488         {
 489             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 490             raptor_fire_cannon(self.gun2, "fire1");
 491             raptor.misc_bulletcounter = 0;
 492         }
 493         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 494         self.cnt = time;
 495     }
 496
 497     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 498         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 499
 500     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 501         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 502
 503     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 504         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 505
 506
 507     if(time > raptor.delay)
 508     if(player.BUTTON_ATCK2)
 509     {
 510         raptor_bombdrop();
 511         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 512         raptor.lip   = time;
 513     }
 514
 515     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 516     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 517
 518     VEHICLE_UPDATE_PLAYER(health, raptor);
 519     VEHICLE_UPDATE_PLAYER(energy, raptor);
 520     if(self.vehicle_flags & VHF_HASSHIELD)
 521         VEHICLE_UPDATE_PLAYER(shield, raptor);
 522
 523     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 524
 525     self = player;
 526     return 1;
 527 }
 528
 529 void raptor_blowup()
 530 {
 531     self.deadflag    = DEAD_DEAD;
 532     self.vehicle_exit(VHEF_NORMAL);
 533     RadiusDamage (self, self.enemy, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 534
 535     self.alpha          = -1;
 536     self.movetype       = MOVETYPE_NONE;
 537     self.effects        = EF_NODRAW;
 538     self.colormod       = '0 0 0';
 539     self.avelocity      = '0 0 0';
 540     self.velocity       = '0 0 0';
 541
 542     setorigin(self, self.pos1);
 543     self.touch = SUB_Null;
 544     self.nextthink = 0;
 545 }
 546
 547 void raptor_diethink()
 548 {
 549     if(random() < 0.1)
 550     {
 551         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 552         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 553     }
 554     self.nextthink = time + 0.1;
 555 }
 556
 557 void raptor_die()
 558 {
 559     self.health       = 0;
 560     self.event_damage = SUB_Null;
 561     self.solid        = SOLID_CORPSE;
 562     self.takedamage   = DAMAGE_NO;
 563     self.deadflag     = DEAD_DYING;
 564     self.movetype     = MOVETYPE_BOUNCE;
 565     self.think        = raptor_diethink;
 566     self.nextthink    = time;
 567
 568     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 569
 570     self.velocity_z += 600;
 571
 572     self.avelocity = '0 0.5 1' * (random() * 400);
 573     self.avelocity -= '0 0.5 1' * (random() * 400);
 574
 575     self.colormod = '-0.5 -0.5 -0.5';
 576         self.touch     = raptor_blowup;
 577 }
 578
 579 void raptor_impact()
 580 {
 581     if(autocvar_g_vehicle_raptor_bouncepain_x)
 582         vehilces_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 583 }
 584
 585 void raptor_spawn()
 586 {
 587     self.frame          = 0;
 588     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 589     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 590     self.movetype       = MOVETYPE_TOSS;
 591     self.solid          = SOLID_SLIDEBOX;
 592     self.vehicle_energy = 1;
 593
 594     self.bomb1.gun1.avelocity_y = 90;
 595     self.bomb1.gun2.avelocity_y = -90;
 596
 597     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 598     self.delay = time;
 599
 600     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 601     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 602     self.vehicle_impact = raptor_impact;
 603 }
 604
 605 // If we dont do this ever now and then, the raptors rotors
 606 // stop working, presumably due to angle overflow. cute.
 607 void raptor_rotor_anglefix()
 608 {
 609     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 610     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 611     self.nextthink = time + 15;
 612 }
 613
 614 void raptor_dinit()
 615 {
 616     entity spinner;
 617     vector ofs;
 618
 619     if not (vehicle_initialize(
 620              "Raptor",
 621              "models/vehicles/raptor.dpm",
 622              "",
 623              "models/vehicles/raptor_cockpit.dpm",
 624              "", "tag_hud", "tag_camera",
 625              HUD_RAPTOR,
 626              RAPTOR_MIN, RAPTOR_MAX,
 627              FALSE,
 628              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 629              raptor_frame,
 630              raptor_enter, raptor_exit,
 631              raptor_die,   raptor_think,
 632              FALSE))
 633     {
 634         remove(self);
 635         return;
 636     }
 637
 638     //FIXME: Camera is in a bad place in HUD model.
 639     //setorigin(self.vehicle_viewport, '25 0 5');
 640
 641     self.frame = 0;
 642
 643     self.bomb1 = spawn();
 644     self.bomb2 = spawn();
 645     self.gun1  = spawn();
 646     self.gun2  = spawn();
 647
 648     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 649     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 650     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 651     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 652     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 653
 654     setattachment(self.bomb1, self,"bombmount_left");
 655     setattachment(self.bomb2, self,"bombmount_right");
 656     setattachment(self.tur_head, self,"root");
 657
 658
 659     // FIXMODEL Guns mounts to angled bones
 660     self.bomb1.angles = self.angles;
 661     self.angles = '0 0 0';
 662     // This messes up gun-aim, so work arround it.
 663     //setattachment(self.gun1, self, "gunmount_left");
 664     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 665     ofs -= self.origin;
 666     setattachment(self.gun1, self, "");
 667     setorigin(self.gun1, ofs);
 668
 669     //setattachment(self.gun2, self, "gunmount_right");
 670     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 671     ofs -= self.origin;
 672     setattachment(self.gun2, self, "");
 673     setorigin(self.gun2, ofs);
 674
 675     self.angles = self.bomb1.angles;
 676     self.bomb1.angles = '0 0 0';
 677
 678     spinner = spawn();
 679     spinner.owner = self;
 680     setmodel(spinner,"models/vehicles/spinner.dpm");
 681     setattachment(spinner, self, "engine_left");
 682     spinner.movetype = MOVETYPE_NOCLIP;
 683     spinner.avelocity = '0 90 0';
 684     self.bomb1.gun1 = spinner;
 685
 686     spinner = spawn();
 687     spinner.owner = self;
 688     setmodel(spinner,"models/vehicles/spinner.dpm");
 689     setattachment(spinner, self, "engine_right");
 690     spinner.movetype = MOVETYPE_NOCLIP;
 691     spinner.avelocity = '0 -90 0';
 692     self.bomb1.gun2 = spinner;
 693
 694     // Sigh.
 695     self.bomb1.think = raptor_rotor_anglefix;
 696     self.bomb1.nextthink = time;
 697
 698     self.mass               = 1 ;
 699 }
 700
 701 void spawnfunc_vehicle_raptor()
 702 {
 703     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 704
 705     self.vehicle_flags |= VHF_DMGSHAKE;
 706     self.vehicle_flags |= VHF_DMGROLL;
 707
 708     if(autocvar_g_vehicle_raptor_shield)
 709         self.vehicle_flags |= VHF_HASSHIELD;
 710
 711     if(autocvar_g_vehicle_raptor_shield_regen)
 712         self.vehicle_flags |= VHF_SHIELDREGEN;
 713
 714     if(autocvar_g_vehicle_raptor_health_regen)
 715         self.vehicle_flags |= VHF_HEALTHREGEN;
 716
 717     if(autocvar_g_vehicle_raptor_energy_regen)
 718         self.vehicle_flags |= VHF_ENERGYREGEN;
 719
 720     precache_model ("models/vehicles/raptor.dpm");
 721     precache_model ("models/vehicles/raptor_gun.dpm");
 722     precache_model ("models/vehicles/spinner.dpm");
 723     precache_model ("models/vehicles/raptor_cockpit.dpm");
 724     //precache_model ("models/vehicles/clusterbomb.md3");
 725     precache_model ("models/vehicles/clusterbomb_folded.md3");
 726     precache_model ("models/vehicles/raptor_body.dpm");
 727
 728     precache_sound ("vehicles/raptor_fly.wav");
 729     precache_sound ("vehicles/raptor_speed.wav");
 730
 731     self.think = raptor_dinit;
 732
 733     if(g_assault)
 734         self.nextthink = time + 0.5;
 735     else
 736         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 737 }
 738 #endif // SVQC